New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limthd.F90 in branches/2016/dev_v3_6_STABLE_r6506_AGRIF_LIM3/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/2016/dev_v3_6_STABLE_r6506_AGRIF_LIM3/NEMOGCM/NEMO/LIM_SRC_3/limthd.F90 @ 8480

Last change on this file since 8480 was 8480, checked in by clem, 5 years ago

bug fix following #1937

  • Property svn:keywords set to Id
File size: 34.5 KB
Line 
1MODULE limthd
2   !!======================================================================
3   !!                  ***  MODULE limthd   ***
4   !!  LIM-3 :   ice thermodynamic
5   !!======================================================================
6   !! History :  LIM  ! 2000-01 (M.A. Morales Maqueda, H. Goosse, T. Fichefet) LIM-1
7   !!            2.0  ! 2002-07 (C. Ethe, G. Madec)  LIM-2 (F90 rewriting)
8   !!            3.0  ! 2005-11 (M. Vancoppenolle)  LIM-3 : Multi-layer thermodynamics + salinity variations
9   !!             -   ! 2007-04 (M. Vancoppenolle) add lim_thd_glohec, lim_thd_con_dh and lim_thd_con_dif
10   !!            3.2  ! 2009-07 (M. Vancoppenolle, Y. Aksenov, G. Madec) bug correction in wfx_snw
11   !!            3.3  ! 2010-11 (G. Madec) corrected snow melting heat (due to factor betas)
12   !!            4.0  ! 2011-02 (G. Madec) dynamical allocation
13   !!             -   ! 2012-05 (C. Rousset) add penetration solar flux
14   !!----------------------------------------------------------------------
15#if defined key_lim3
16   !!----------------------------------------------------------------------
17   !!   'key_lim3'                                      LIM3 sea-ice model
18   !!----------------------------------------------------------------------
19   !!   lim_thd       : thermodynamic of sea ice
20   !!   lim_thd_init  : initialisation of sea-ice thermodynamic
21   !!----------------------------------------------------------------------
22   USE phycst         ! physical constants
23   USE dom_oce        ! ocean space and time domain variables
24   USE ice            ! sea-ice variables
25   USE sbc_oce        ! Surface boundary condition: ocean fields
26   USE sbc_ice        ! Surface boundary condition: ice fields
27   USE thd_ice        ! thermodynamic sea-ice variables
28   USE limthd_dif     ! vertical diffusion
29   USE limthd_dh      ! ice-snow growth and melt
30   USE limthd_da      ! lateral melting
31   USE limthd_sal     ! ice salinity
32   USE limthd_ent     ! ice enthalpy redistribution
33   USE limthd_lac     ! lateral accretion
34   USE limitd_th      ! remapping thickness distribution
35   USE limtab         ! 1D <==> 2D transformation
36   USE limvar         !
37   USE limcons        ! conservation tests
38   USE limctl         ! control print
39   !
40   USE in_out_manager ! I/O manager
41   USE lbclnk         ! lateral boundary condition - MPP links
42   USE lib_mpp        ! MPP library
43   USE wrk_nemo       ! work arrays
44   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
45   USE timing         ! Timing
46
47   IMPLICIT NONE
48   PRIVATE
49
50   PUBLIC   lim_thd         ! called by limstp module
51   PUBLIC   lim_thd_init    ! called by sbc_lim_init
52
53   !! * Substitutions
54#  include "domzgr_substitute.h90"
55#  include "vectopt_loop_substitute.h90"
56   !!----------------------------------------------------------------------
57   !! NEMO/LIM3 3.3 , UCL - NEMO Consortium (2010)
58   !! $Id$
59   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
60   !!----------------------------------------------------------------------
61CONTAINS
62
63   SUBROUTINE lim_thd( kt )
64      !!-------------------------------------------------------------------
65      !!                ***  ROUTINE lim_thd  ***       
66      !! 
67      !! ** Purpose : This routine manages ice thermodynamics
68      !!         
69      !! ** Action : - Initialisation of some variables
70      !!             - Some preliminary computation (oceanic heat flux
71      !!               at the ice base, snow acc.,heat budget of the leads)
72      !!             - selection of the icy points and put them in an array
73      !!             - call lim_thd_dif  for vertical heat diffusion
74      !!             - call lim_thd_dh   for vertical ice growth and melt
75      !!             - call lim_thd_ent  for enthalpy remapping
76      !!             - call lim_thd_sal  for ice desalination
77      !!             - call lim_thd_temp to  retrieve temperature from ice enthalpy
78      !!             - back to the geographic grid
79      !!     
80      !! ** References :
81      !!---------------------------------------------------------------------
82      INTEGER, INTENT(in) :: kt    ! number of iteration
83      !
84      INTEGER  :: ji, jj, jk, jl   ! dummy loop indices
85      INTEGER  :: nbpb             ! nb of icy pts for vertical thermo calculations
86      REAL(wp) :: zfric_u, zqld, zqfr
87      REAL(wp) :: zvi_b, zsmv_b, zei_b, zfs_b, zfw_b, zft_b 
88      REAL(wp), PARAMETER :: zfric_umin = 0._wp           ! lower bound for the friction velocity (cice value=5.e-04)
89      REAL(wp), PARAMETER :: zch        = 0.0057_wp       ! heat transfer coefficient
90      REAL(wp), POINTER, DIMENSION(:,:) ::   zu_io, zv_io, zfric   ! ice-ocean velocity (m/s) and frictional velocity (m2/s2)
91      !
92      !!-------------------------------------------------------------------
93
94      IF( nn_timing == 1 )   CALL timing_start('limthd')
95
96      CALL wrk_alloc( jpi,jpj, zu_io, zv_io, zfric )
97
98      IF( kt == nit000 .AND. lwp ) THEN
99         WRITE(numout,*)'' 
100         WRITE(numout,*)' lim_thd '
101         WRITE(numout,*)' ~~~~~~~~'
102      ENDIF
103     
104      ! conservation test
105      IF( ln_limdiachk ) CALL lim_cons_hsm(0, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
106
107      CALL lim_var_glo2eqv
108
109      !---------------------------------------------!
110      ! computation of friction velocity at T points
111      !---------------------------------------------!
112      IF( ln_limdyn ) THEN
113         zu_io(:,:) = u_ice(:,:) - ssu_m(:,:)
114         zv_io(:,:) = v_ice(:,:) - ssv_m(:,:)
115         DO jj = 2, jpjm1 
116            DO ji = fs_2, fs_jpim1
117               zfric(ji,jj) = rn_cio * ( 0.5_wp *  &
118                  &                    (  zu_io(ji,jj) * zu_io(ji,jj) + zu_io(ji-1,jj) * zu_io(ji-1,jj)   &
119                  &                     + zv_io(ji,jj) * zv_io(ji,jj) + zv_io(ji,jj-1) * zv_io(ji,jj-1) ) ) * tmask(ji,jj,1)
120            END DO
121         END DO
122      ELSE      !  if no ice dynamics => transmit directly the atmospheric stress to the ocean
123         DO jj = 2, jpjm1
124            DO ji = fs_2, fs_jpim1
125               zfric(ji,jj) = r1_rau0 * SQRT( 0.5_wp *  &
126                  &                         (  utau(ji,jj) * utau(ji,jj) + utau(ji-1,jj) * utau(ji-1,jj)   &
127                  &                          + vtau(ji,jj) * vtau(ji,jj) + vtau(ji,jj-1) * vtau(ji,jj-1) ) ) * tmask(ji,jj,1)
128            END DO
129         END DO
130      ENDIF
131      CALL lbc_lnk( zfric, 'T',  1. )
132      !
133      !----------------------------------!
134      ! Initialization and units change
135      !----------------------------------!
136      ftr_ice(:,:,:) = 0._wp  ! part of solar radiation transmitted through the ice
137
138      ! Change the units of heat content; from J/m2 to J/m3
139      DO jl = 1, jpl
140         DO jk = 1, nlay_i
141            DO jj = 1, jpj
142               DO ji = 1, jpi
143                  rswitch = MAX(  0._wp , SIGN( 1._wp , v_i(ji,jj,jl) - epsi20 )  )
144                  !Energy of melting q(S,T) [J.m-3]
145                  e_i(ji,jj,jk,jl) = rswitch * e_i(ji,jj,jk,jl) / MAX( v_i(ji,jj,jl) , epsi20 ) * REAL( nlay_i )
146               END DO
147            END DO
148         END DO
149         DO jk = 1, nlay_s
150            DO jj = 1, jpj
151               DO ji = 1, jpi
152                  rswitch = MAX(  0._wp , SIGN( 1._wp , v_s(ji,jj,jl) - epsi20 )  )
153                  !Energy of melting q(S,T) [J.m-3]
154                  e_s(ji,jj,jk,jl) = rswitch * e_s(ji,jj,jk,jl) / MAX( v_s(ji,jj,jl) , epsi20 ) * REAL( nlay_s )
155               END DO
156            END DO
157         END DO
158      END DO
159
160      !--------------------------------------------------------------------!
161      ! Partial computation of forcing for the thermodynamic sea ice model
162      !--------------------------------------------------------------------!
163      DO jj = 1, jpj
164         DO ji = 1, jpi
165            rswitch  = tmask(ji,jj,1) * MAX( 0._wp , SIGN( 1._wp , at_i(ji,jj) - epsi10 ) ) ! 0 if no ice
166            !
167            !           !  solar irradiance transmission at the mixed layer bottom and used in the lead heat budget
168            !           !  practically no "direct lateral ablation"
169            !           
170            !           !  net downward heat flux from the ice to the ocean, expressed as a function of ocean
171            !           !  temperature and turbulent mixing (McPhee, 1992)
172            !
173            ! --- Energy received in the lead, zqld is defined everywhere (J.m-2) --- !
174            zqld =  tmask(ji,jj,1) * rdt_ice *  &
175               &    ( pfrld(ji,jj) * qsr_oce(ji,jj) * frq_m(ji,jj) + pfrld(ji,jj) * qns_oce(ji,jj) + qemp_oce(ji,jj) )
176
177            ! --- Energy needed to bring ocean surface layer until its freezing (<0, J.m-2) --- !
178            zqfr = tmask(ji,jj,1) * rau0 * rcp * fse3t_m(ji,jj) * ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) )
179
180            ! --- Energy from the turbulent oceanic heat flux (W/m2) --- !
181            zfric_u      = MAX( SQRT( zfric(ji,jj) ), zfric_umin ) 
182            fhtur(ji,jj) = MAX( 0._wp, rswitch * rau0 * rcp * zch  * zfric_u * ( ( sst_m(ji,jj) + rt0 ) - t_bo(ji,jj) ) ) ! W.m-2
183            fhtur(ji,jj) = rswitch * MIN( fhtur(ji,jj), - zqfr * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) )
184            ! upper bound for fhtur: the heat retrieved from the ocean must be smaller than the heat necessary to reach
185            !                        the freezing point, so that we do not have SST < T_freeze
186            !                        This implies: - ( fhtur(ji,jj) * at_i(ji,jj) * rtdice ) - zqfr >= 0
187
188            !-- Energy Budget of the leads (J.m-2). Must be < 0 to form ice
189            qlead(ji,jj) = MIN( 0._wp , zqld - ( fhtur(ji,jj) * at_i(ji,jj) * rdt_ice ) - zqfr )
190
191            ! If there is ice and leads are warming, then transfer energy from the lead budget and use it for bottom melting
192            IF( zqld > 0._wp ) THEN
193               fhld (ji,jj) = rswitch * zqld * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) ! divided by at_i since this is (re)multiplied by a_i in limthd_dh.F90
194               qlead(ji,jj) = 0._wp
195            ELSE
196               fhld (ji,jj) = 0._wp
197            ENDIF
198            !
199            ! Net heat flux on top of the ice-ocean [W.m-2]
200            ! ---------------------------------------------
201            hfx_in(ji,jj) = qns_tot(ji,jj) + qsr_tot(ji,jj) 
202         END DO
203      END DO
204     
205      ! In case we bypass open-water ice formation
206      IF( .NOT. ln_limdO )  qlead(:,:) = 0._wp
207      ! In case we bypass growing/melting from top and bottom: we suppose ice is impermeable => ocean is isolated from atmosphere
208      IF( .NOT. ln_limdH ) THEN
209         hfx_in(:,:) = pfrld(:,:) * ( qns_oce(:,:) + qsr_oce(:,:) ) + qemp_oce(:,:)
210         fhtur (:,:) = 0._wp
211         fhld  (:,:) = 0._wp
212      ENDIF
213
214      ! ---------------------------------------------------------------------
215      ! Net heat flux on top of the ocean after ice thermo (1st step) [W.m-2]
216      ! ---------------------------------------------------------------------
217      !     First  step here              :  non solar + precip - qlead - qturb
218      !     Second step in limthd_dh      :  heat remaining if total melt (zq_rema)
219      !     Third  step in limsbc         :  heat from ice-ocean mass exchange (zf_mass) + solar
220      DO jj = 1, jpj
221         DO ji = 1, jpi
222            hfx_out(ji,jj) =   pfrld(ji,jj) * qns_oce(ji,jj) + qemp_oce(ji,jj)  &  ! Non solar heat flux received by the ocean               
223               &             - qlead(ji,jj) * r1_rdtice                         &  ! heat flux taken from the ocean where there is open water ice formation
224               &             - at_i(ji,jj) * fhtur(ji,jj)                       &  ! heat flux taken by turbulence
225               &             - at_i(ji,jj) *  fhld(ji,jj)                          ! heat flux taken during bottom growth/melt
226                                                                                   !    (fhld should be 0 while bott growth)
227         END DO
228      END DO
229
230      !------------------------------------------------------------------------------!
231      ! Thermodynamic computation (only on grid points covered by ice)
232      !------------------------------------------------------------------------------!
233
234      DO jl = 1, jpl      !loop over ice categories
235
236         ! select ice covered grid points
237         nbpb = 0
238         DO jj = 1, jpj
239            DO ji = 1, jpi
240               IF ( a_i(ji,jj,jl) > epsi10 ) THEN     
241                  nbpb      = nbpb  + 1
242                  npb(nbpb) = (jj - 1) * jpi + ji
243               ENDIF
244            END DO
245         END DO
246
247         ! debug point to follow
248         jiindex_1d = 0
249         IF( ln_limctl ) THEN
250            DO ji = mi0(iiceprt), mi1(iiceprt)
251               DO jj = mj0(jiceprt), mj1(jiceprt)
252                  jiindex_1d = (jj - 1) * jpi + ji
253                  WRITE(numout,*) ' lim_thd : Category no : ', jl 
254               END DO
255            END DO
256         ENDIF
257
258         IF( lk_mpp )         CALL mpp_ini_ice( nbpb , numout )
259
260         IF( nbpb > 0 ) THEN  ! If there is no ice, do nothing.
261            !                                                               
262            s_i_new   (:) = 0._wp ; dh_s_tot (:) = 0._wp                     ! --- some init --- !
263            dh_i_surf (:) = 0._wp ; dh_i_bott(:) = 0._wp
264            dh_snowice(:) = 0._wp ; dh_i_sub (:) = 0._wp
265
266                              CALL lim_thd_1d2d( nbpb, jl, 1 )               ! --- Move to 1D arrays --- !
267            !
268            IF( ln_limdH )    CALL lim_thd_dif( 1, nbpb )                    ! --- Ice/Snow Temperature profile --- !
269            !
270            IF( ln_limdH )    CALL lim_thd_dh( 1, nbpb )                     ! --- Ice/Snow thickness --- !   
271            !
272            IF( ln_limdH )    CALL lim_thd_ent( 1, nbpb, q_i_1d(1:nbpb,:) )  ! --- Ice enthalpy remapping --- !
273            !
274                              CALL lim_thd_sal( 1, nbpb )                    ! --- Ice salinity --- !   
275            !
276                              CALL lim_thd_temp( 1, nbpb )                   ! --- temperature update --- !
277            !
278            IF( ln_limdH ) THEN
279               IF ( ( nn_monocat == 1 .OR. nn_monocat == 4 ) .AND. jpl == 1 ) THEN
280                              CALL lim_thd_lam( 1, nbpb )                    ! --- extra lateral melting if monocat --- !
281               END IF
282            END IF
283            !
284                              CALL lim_thd_1d2d( nbpb, jl, 2 )               ! --- Move to 2D arrays --- !
285            !
286            IF( lk_mpp )      CALL mpp_comm_free( ncomm_ice ) !RB necessary ??
287         ENDIF
288         !
289      END DO !jl
290
291      IF( ln_limdA)           CALL lim_thd_da                                ! --- lateral melting --- !
292
293      ! Enthalpies are global variables we have to readjust the units (heat content in J/m2)
294      DO jl = 1, jpl
295         DO jk = 1, nlay_i
296            e_i(:,:,jk,jl) = e_i(:,:,jk,jl) * a_i(:,:,jl) * ht_i(:,:,jl) * r1_nlay_i
297         END DO
298         DO jk = 1, nlay_s
299            e_s(:,:,jk,jl) = e_s(:,:,jk,jl) * a_i(:,:,jl) * ht_s(:,:,jl) * r1_nlay_s
300         END DO
301      END DO
302 
303      ! Change thickness to volume
304      v_i(:,:,:)   = ht_i(:,:,:) * a_i(:,:,:)
305      v_s(:,:,:)   = ht_s(:,:,:) * a_i(:,:,:)
306      smv_i(:,:,:) = sm_i(:,:,:) * v_i(:,:,:)
307
308      ! update ice age (in case a_i changed, i.e. becomes 0 or lateral melting)
309      DO jl  = 1, jpl
310         DO jj = 1, jpj
311            DO ji = 1, jpi
312               rswitch = MAX( 0._wp , SIGN( 1._wp, a_i_b(ji,jj,jl) - epsi10 ) )
313               oa_i(ji,jj,jl) = rswitch * oa_i(ji,jj,jl) * a_i(ji,jj,jl) / MAX( a_i_b(ji,jj,jl), epsi10 )
314            END DO
315         END DO
316      END DO
317
318      CALL lim_var_zapsmall
319
320      ! control checks
321      IF( ln_limctl )    CALL lim_prt( kt, iiceprt, jiceprt, 1, ' - ice thermodyn. - ' )   ! control print
322      !
323      IF( ln_limdiachk ) CALL lim_cons_hsm(1, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
324
325      !------------------------------------------------!
326      !  Transport ice between thickness categories
327      !------------------------------------------------!
328      ! Given thermodynamic growth rates, transport ice between thickness categories.
329      IF( ln_limdiachk ) CALL lim_cons_hsm(0, 'limitd_th_rem', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
330
331      IF( jpl > 1 )      CALL lim_itd_th_rem( 1, jpl, kt )
332
333      IF( ln_limdiachk ) CALL lim_cons_hsm(1, 'limitd_th_rem', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
334
335      !------------------------------------------------!
336      !  Add frazil ice growing in leads
337      !------------------------------------------------!
338      IF( ln_limdiachk ) CALL lim_cons_hsm(0, 'limthd_lac', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
339
340      IF( ln_limdO )     CALL lim_thd_lac
341     
342      ! conservation test
343      IF( ln_limdiachk ) CALL lim_cons_hsm(1, 'limthd_lac', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
344
345      ! Control print
346      IF( ln_ctl )       CALL lim_prt3D( 'limthd' )
347      !
348      CALL wrk_dealloc( jpi,jpj, zu_io, zv_io, zfric )
349      !
350      IF( nn_timing == 1 )  CALL timing_stop('limthd')
351
352   END SUBROUTINE lim_thd 
353
354 
355   SUBROUTINE lim_thd_temp( kideb, kiut )
356      !!-----------------------------------------------------------------------
357      !!                   ***  ROUTINE lim_thd_temp ***
358      !!                 
359      !! ** Purpose :   Computes sea ice temperature (Kelvin) from enthalpy
360      !!
361      !! ** Method  :   Formula (Bitz and Lipscomb, 1999)
362      !!-------------------------------------------------------------------
363      INTEGER, INTENT(in) ::   kideb, kiut   ! bounds for the spatial loop
364      !
365      INTEGER  ::   ji, jk   ! dummy loop indices
366      REAL(wp) ::   ztmelts, zaaa, zbbb, zccc, zdiscrim  ! local scalar
367      !!-------------------------------------------------------------------
368      ! Recover ice temperature
369      DO jk = 1, nlay_i
370         DO ji = kideb, kiut
371            ztmelts       =  -tmut * s_i_1d(ji,jk) + rt0
372            ! Conversion q(S,T) -> T (second order equation)
373            zaaa          =  cpic
374            zbbb          =  ( rcp - cpic ) * ( ztmelts - rt0 ) + q_i_1d(ji,jk) * r1_rhoic - lfus
375            zccc          =  lfus * ( ztmelts - rt0 )
376            zdiscrim      =  SQRT( MAX( zbbb * zbbb - 4._wp * zaaa * zccc, 0._wp ) )
377            t_i_1d(ji,jk) =  rt0 - ( zbbb + zdiscrim ) / ( 2._wp * zaaa )
378           
379            ! mask temperature
380            rswitch       =  1._wp - MAX( 0._wp , SIGN( 1._wp , - ht_i_1d(ji) ) ) 
381            t_i_1d(ji,jk) =  rswitch * t_i_1d(ji,jk) + ( 1._wp - rswitch ) * rt0
382         END DO
383      END DO 
384      !
385   END SUBROUTINE lim_thd_temp
386
387
388   SUBROUTINE lim_thd_lam( kideb, kiut )
389      !!-----------------------------------------------------------------------
390      !!                   ***  ROUTINE lim_thd_lam ***
391      !!                 
392      !! ** Purpose :   Lateral melting in case monocategory
393      !!                          ( dA = A/2h dh )
394      !!-----------------------------------------------------------------------
395      INTEGER, INTENT(in) ::   kideb, kiut        ! bounds for the spatial loop
396      !
397      INTEGER  ::   ji                 ! dummy loop indices
398      REAL(wp) ::   zhi_bef            ! ice thickness before thermo
399      REAL(wp) ::   zdh_mel, zda_mel   ! net melting
400      REAL(wp) ::   zvi, zvs           ! ice/snow volumes
401      !!-----------------------------------------------------------------------
402      !
403      DO ji = kideb, kiut
404         zdh_mel = MIN( 0._wp, dh_i_surf(ji) + dh_i_bott(ji) + dh_snowice(ji) + dh_i_sub(ji) )
405         IF( zdh_mel < 0._wp .AND. a_i_1d(ji) > 0._wp )  THEN
406            zvi          = a_i_1d(ji) * ht_i_1d(ji)
407            zvs          = a_i_1d(ji) * ht_s_1d(ji)
408            ! lateral melting = concentration change
409            zhi_bef     = ht_i_1d(ji) - zdh_mel
410            rswitch     = MAX( 0._wp , SIGN( 1._wp , zhi_bef - epsi20 ) )
411            zda_mel     = rswitch * a_i_1d(ji) * zdh_mel / ( 2._wp * MAX( zhi_bef, epsi20 ) )
412            a_i_1d(ji)  = MAX( epsi20, a_i_1d(ji) + zda_mel ) 
413            ! adjust thickness
414            ht_i_1d(ji) = zvi / a_i_1d(ji)           
415            ht_s_1d(ji) = zvs / a_i_1d(ji)           
416            ! retrieve total concentration
417            at_i_1d(ji) = a_i_1d(ji)
418         END IF
419      END DO
420      !
421   END SUBROUTINE lim_thd_lam
422
423
424   SUBROUTINE lim_thd_1d2d( nbpb, jl, kn )
425      !!-----------------------------------------------------------------------
426      !!                   ***  ROUTINE lim_thd_1d2d ***
427      !!                 
428      !! ** Purpose :   move arrays from 1d to 2d and the reverse
429      !!-----------------------------------------------------------------------
430      INTEGER, INTENT(in) ::   kn       ! 1= from 2D to 1D   ;   2= from 1D to 2D
431      INTEGER, INTENT(in) ::   nbpb     ! size of 1D arrays
432      INTEGER, INTENT(in) ::   jl       ! ice cat
433      !
434      INTEGER             ::   jk       ! dummy loop indices
435      !!-----------------------------------------------------------------------
436      !
437      SELECT CASE( kn )
438      !
439      CASE( 1 )            ! from 2D to 1D
440         !
441         CALL tab_2d_1d( nbpb, at_i_1d     (1:nbpb), at_i            , jpi, jpj, npb(1:nbpb) )
442         CALL tab_2d_1d( nbpb, a_i_1d      (1:nbpb), a_i(:,:,jl)     , jpi, jpj, npb(1:nbpb) )
443         CALL tab_2d_1d( nbpb, ht_i_1d     (1:nbpb), ht_i(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
444         CALL tab_2d_1d( nbpb, ht_s_1d     (1:nbpb), ht_s(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
445         !
446         CALL tab_2d_1d( nbpb, t_su_1d     (1:nbpb), t_su(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
447         CALL tab_2d_1d( nbpb, sm_i_1d     (1:nbpb), sm_i(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
448         DO jk = 1, nlay_s
449            CALL tab_2d_1d( nbpb, t_s_1d(1:nbpb,jk), t_s(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
450            CALL tab_2d_1d( nbpb, q_s_1d(1:nbpb,jk), e_s(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
451         END DO
452         DO jk = 1, nlay_i
453            CALL tab_2d_1d( nbpb, t_i_1d(1:nbpb,jk), t_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
454            CALL tab_2d_1d( nbpb, q_i_1d(1:nbpb,jk), e_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
455            CALL tab_2d_1d( nbpb, s_i_1d(1:nbpb,jk), s_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
456         END DO
457         !
458         CALL tab_2d_1d( nbpb, qprec_ice_1d(1:nbpb), qprec_ice(:,:) , jpi, jpj, npb(1:nbpb) )
459         CALL tab_2d_1d( nbpb, qevap_ice_1d(1:nbpb), qevap_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
460         CALL tab_2d_1d( nbpb, qsr_ice_1d (1:nbpb), qsr_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
461         CALL tab_2d_1d( nbpb, fr1_i0_1d  (1:nbpb), fr1_i0          , jpi, jpj, npb(1:nbpb) )
462         CALL tab_2d_1d( nbpb, fr2_i0_1d  (1:nbpb), fr2_i0          , jpi, jpj, npb(1:nbpb) )
463         CALL tab_2d_1d( nbpb, qns_ice_1d (1:nbpb), qns_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
464         CALL tab_2d_1d( nbpb, ftr_ice_1d (1:nbpb), ftr_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
465         CALL tab_2d_1d( nbpb, evap_ice_1d (1:nbpb), evap_ice(:,:,jl), jpi, jpj, npb(1:nbpb) )
466         CALL tab_2d_1d( nbpb, dqns_ice_1d(1:nbpb), dqns_ice(:,:,jl), jpi, jpj, npb(1:nbpb) )
467         CALL tab_2d_1d( nbpb, t_bo_1d     (1:nbpb), t_bo            , jpi, jpj, npb(1:nbpb) )
468         CALL tab_2d_1d( nbpb, sprecip_1d (1:nbpb), sprecip         , jpi, jpj, npb(1:nbpb) ) 
469         CALL tab_2d_1d( nbpb, fhtur_1d   (1:nbpb), fhtur           , jpi, jpj, npb(1:nbpb) )
470         CALL tab_2d_1d( nbpb, qlead_1d   (1:nbpb), qlead           , jpi, jpj, npb(1:nbpb) )
471         CALL tab_2d_1d( nbpb, fhld_1d    (1:nbpb), fhld            , jpi, jpj, npb(1:nbpb) )
472         !
473         CALL tab_2d_1d( nbpb, wfx_snw_1d (1:nbpb), wfx_snw         , jpi, jpj, npb(1:nbpb) )
474         CALL tab_2d_1d( nbpb, wfx_sub_1d (1:nbpb), wfx_sub         , jpi, jpj, npb(1:nbpb) )
475         !
476         CALL tab_2d_1d( nbpb, wfx_bog_1d (1:nbpb), wfx_bog         , jpi, jpj, npb(1:nbpb) )
477         CALL tab_2d_1d( nbpb, wfx_bom_1d (1:nbpb), wfx_bom         , jpi, jpj, npb(1:nbpb) )
478         CALL tab_2d_1d( nbpb, wfx_sum_1d (1:nbpb), wfx_sum         , jpi, jpj, npb(1:nbpb) )
479         CALL tab_2d_1d( nbpb, wfx_sni_1d (1:nbpb), wfx_sni         , jpi, jpj, npb(1:nbpb) )
480         CALL tab_2d_1d( nbpb, wfx_res_1d (1:nbpb), wfx_res         , jpi, jpj, npb(1:nbpb) )
481         CALL tab_2d_1d( nbpb, wfx_spr_1d (1:nbpb), wfx_spr         , jpi, jpj, npb(1:nbpb) )
482         !
483         CALL tab_2d_1d( nbpb, sfx_bog_1d (1:nbpb), sfx_bog         , jpi, jpj, npb(1:nbpb) )
484         CALL tab_2d_1d( nbpb, sfx_bom_1d (1:nbpb), sfx_bom         , jpi, jpj, npb(1:nbpb) )
485         CALL tab_2d_1d( nbpb, sfx_sum_1d (1:nbpb), sfx_sum         , jpi, jpj, npb(1:nbpb) )
486         CALL tab_2d_1d( nbpb, sfx_sni_1d (1:nbpb), sfx_sni         , jpi, jpj, npb(1:nbpb) )
487         CALL tab_2d_1d( nbpb, sfx_bri_1d (1:nbpb), sfx_bri         , jpi, jpj, npb(1:nbpb) )
488         CALL tab_2d_1d( nbpb, sfx_res_1d (1:nbpb), sfx_res         , jpi, jpj, npb(1:nbpb) )
489         CALL tab_2d_1d( nbpb, sfx_sub_1d (1:nbpb), sfx_sub         , jpi, jpj,npb(1:nbpb) )
490         !
491         CALL tab_2d_1d( nbpb, hfx_thd_1d (1:nbpb), hfx_thd         , jpi, jpj, npb(1:nbpb) )
492         CALL tab_2d_1d( nbpb, hfx_spr_1d (1:nbpb), hfx_spr         , jpi, jpj, npb(1:nbpb) )
493         CALL tab_2d_1d( nbpb, hfx_sum_1d (1:nbpb), hfx_sum         , jpi, jpj, npb(1:nbpb) )
494         CALL tab_2d_1d( nbpb, hfx_bom_1d (1:nbpb), hfx_bom         , jpi, jpj, npb(1:nbpb) )
495         CALL tab_2d_1d( nbpb, hfx_bog_1d (1:nbpb), hfx_bog         , jpi, jpj, npb(1:nbpb) )
496         CALL tab_2d_1d( nbpb, hfx_dif_1d (1:nbpb), hfx_dif         , jpi, jpj, npb(1:nbpb) )
497         CALL tab_2d_1d( nbpb, hfx_opw_1d (1:nbpb), hfx_opw         , jpi, jpj, npb(1:nbpb) )
498         CALL tab_2d_1d( nbpb, hfx_snw_1d (1:nbpb), hfx_snw         , jpi, jpj, npb(1:nbpb) )
499         CALL tab_2d_1d( nbpb, hfx_sub_1d (1:nbpb), hfx_sub         , jpi, jpj, npb(1:nbpb) )
500         CALL tab_2d_1d( nbpb, hfx_err_1d (1:nbpb), hfx_err         , jpi, jpj, npb(1:nbpb) )
501         CALL tab_2d_1d( nbpb, hfx_res_1d (1:nbpb), hfx_res         , jpi, jpj, npb(1:nbpb) )
502         CALL tab_2d_1d( nbpb, hfx_err_dif_1d (1:nbpb), hfx_err_dif , jpi, jpj, npb(1:nbpb) )
503         CALL tab_2d_1d( nbpb, hfx_err_rem_1d (1:nbpb), hfx_err_rem , jpi, jpj, npb(1:nbpb) )
504         !
505      CASE( 2 )            ! from 1D to 2D
506         !
507         CALL tab_1d_2d( nbpb, at_i          , npb, at_i_1d    (1:nbpb)   , jpi, jpj )
508         CALL tab_1d_2d( nbpb, ht_i(:,:,jl)  , npb, ht_i_1d    (1:nbpb)   , jpi, jpj )
509         CALL tab_1d_2d( nbpb, ht_s(:,:,jl)  , npb, ht_s_1d    (1:nbpb)   , jpi, jpj )
510         CALL tab_1d_2d( nbpb, a_i (:,:,jl)  , npb, a_i_1d     (1:nbpb)   , jpi, jpj )
511         CALL tab_1d_2d( nbpb, t_su(:,:,jl)  , npb, t_su_1d    (1:nbpb)   , jpi, jpj )
512         CALL tab_1d_2d( nbpb, sm_i(:,:,jl)  , npb, sm_i_1d    (1:nbpb)   , jpi, jpj )
513         DO jk = 1, nlay_s
514            CALL tab_1d_2d( nbpb, t_s(:,:,jk,jl), npb, t_s_1d     (1:nbpb,jk), jpi, jpj)
515            CALL tab_1d_2d( nbpb, e_s(:,:,jk,jl), npb, q_s_1d     (1:nbpb,jk), jpi, jpj)
516         END DO
517         DO jk = 1, nlay_i
518            CALL tab_1d_2d( nbpb, t_i(:,:,jk,jl), npb, t_i_1d     (1:nbpb,jk), jpi, jpj)
519            CALL tab_1d_2d( nbpb, e_i(:,:,jk,jl), npb, q_i_1d     (1:nbpb,jk), jpi, jpj)
520            CALL tab_1d_2d( nbpb, s_i(:,:,jk,jl), npb, s_i_1d     (1:nbpb,jk), jpi, jpj)
521         END DO
522         CALL tab_1d_2d( nbpb, qlead         , npb, qlead_1d  (1:nbpb)   , jpi, jpj )
523         !
524         CALL tab_1d_2d( nbpb, wfx_snw       , npb, wfx_snw_1d(1:nbpb)   , jpi, jpj )
525         CALL tab_1d_2d( nbpb, wfx_sub       , npb, wfx_sub_1d(1:nbpb)   , jpi, jpj )
526         !
527         CALL tab_1d_2d( nbpb, wfx_bog       , npb, wfx_bog_1d(1:nbpb)   , jpi, jpj )
528         CALL tab_1d_2d( nbpb, wfx_bom       , npb, wfx_bom_1d(1:nbpb)   , jpi, jpj )
529         CALL tab_1d_2d( nbpb, wfx_sum       , npb, wfx_sum_1d(1:nbpb)   , jpi, jpj )
530         CALL tab_1d_2d( nbpb, wfx_sni       , npb, wfx_sni_1d(1:nbpb)   , jpi, jpj )
531         CALL tab_1d_2d( nbpb, wfx_res       , npb, wfx_res_1d(1:nbpb)   , jpi, jpj )
532         CALL tab_1d_2d( nbpb, wfx_spr       , npb, wfx_spr_1d(1:nbpb)   , jpi, jpj )
533         !
534         CALL tab_1d_2d( nbpb, sfx_bog       , npb, sfx_bog_1d(1:nbpb)   , jpi, jpj )
535         CALL tab_1d_2d( nbpb, sfx_bom       , npb, sfx_bom_1d(1:nbpb)   , jpi, jpj )
536         CALL tab_1d_2d( nbpb, sfx_sum       , npb, sfx_sum_1d(1:nbpb)   , jpi, jpj )
537         CALL tab_1d_2d( nbpb, sfx_sni       , npb, sfx_sni_1d(1:nbpb)   , jpi, jpj )
538         CALL tab_1d_2d( nbpb, sfx_res       , npb, sfx_res_1d(1:nbpb)   , jpi, jpj )
539         CALL tab_1d_2d( nbpb, sfx_bri       , npb, sfx_bri_1d(1:nbpb)   , jpi, jpj )
540         CALL tab_1d_2d( nbpb, sfx_sub       , npb, sfx_sub_1d(1:nbpb)   , jpi, jpj )       
541         !
542         CALL tab_1d_2d( nbpb, hfx_thd       , npb, hfx_thd_1d(1:nbpb)   , jpi, jpj )
543         CALL tab_1d_2d( nbpb, hfx_spr       , npb, hfx_spr_1d(1:nbpb)   , jpi, jpj )
544         CALL tab_1d_2d( nbpb, hfx_sum       , npb, hfx_sum_1d(1:nbpb)   , jpi, jpj )
545         CALL tab_1d_2d( nbpb, hfx_bom       , npb, hfx_bom_1d(1:nbpb)   , jpi, jpj )
546         CALL tab_1d_2d( nbpb, hfx_bog       , npb, hfx_bog_1d(1:nbpb)   , jpi, jpj )
547         CALL tab_1d_2d( nbpb, hfx_dif       , npb, hfx_dif_1d(1:nbpb)   , jpi, jpj )
548         CALL tab_1d_2d( nbpb, hfx_opw       , npb, hfx_opw_1d(1:nbpb)   , jpi, jpj )
549         CALL tab_1d_2d( nbpb, hfx_snw       , npb, hfx_snw_1d(1:nbpb)   , jpi, jpj )
550         CALL tab_1d_2d( nbpb, hfx_sub       , npb, hfx_sub_1d(1:nbpb)   , jpi, jpj )
551         CALL tab_1d_2d( nbpb, hfx_err       , npb, hfx_err_1d(1:nbpb)   , jpi, jpj )
552         CALL tab_1d_2d( nbpb, hfx_res       , npb, hfx_res_1d(1:nbpb)   , jpi, jpj )
553         CALL tab_1d_2d( nbpb, hfx_err_rem   , npb, hfx_err_rem_1d(1:nbpb), jpi, jpj )
554         CALL tab_1d_2d( nbpb, hfx_err_dif   , npb, hfx_err_dif_1d(1:nbpb), jpi, jpj )
555         !
556         CALL tab_1d_2d( nbpb, qns_ice(:,:,jl), npb, qns_ice_1d(1:nbpb) , jpi, jpj)
557         CALL tab_1d_2d( nbpb, ftr_ice(:,:,jl), npb, ftr_ice_1d(1:nbpb) , jpi, jpj )
558         !         
559      END SELECT
560      !
561   END SUBROUTINE lim_thd_1d2d
562
563
564   SUBROUTINE lim_thd_init
565      !!-----------------------------------------------------------------------
566      !!                   ***  ROUTINE lim_thd_init ***
567      !!                 
568      !! ** Purpose :   Physical constants and parameters linked to the ice
569      !!              thermodynamics
570      !!
571      !! ** Method  :   Read the namicethd namelist and check the ice-thermo
572      !!              parameter values called at the first timestep (nit000)
573      !!
574      !! ** input   :   Namelist namicether
575      !!-------------------------------------------------------------------
576      INTEGER  ::   ios                 ! Local integer output status for namelist read
577      NAMELIST/namicethd/ rn_kappa_i, nn_conv_dif, rn_terr_dif, nn_ice_thcon,ln_it_qnsice,nn_monocat,  &
578         &                ln_limdH, rn_betas,                                                          &
579         &                ln_limdA, rn_beta, rn_dmin,                                                  &
580         &                ln_limdO, rn_hnewice, ln_frazil, rn_maxfrazb, rn_vfrazb, rn_Cfrazb, rn_himin
581      !!-------------------------------------------------------------------
582      !
583      REWIND( numnam_ice_ref )              ! Namelist namicethd in reference namelist : Ice thermodynamics
584      READ  ( numnam_ice_ref, namicethd, IOSTAT = ios, ERR = 901)
585901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in reference namelist', lwp )
586
587      REWIND( numnam_ice_cfg )              ! Namelist namicethd in configuration namelist : Ice thermodynamics
588      READ  ( numnam_ice_cfg, namicethd, IOSTAT = ios, ERR = 902 )
589902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in configuration namelist', lwp )
590      IF(lwm) WRITE ( numoni, namicethd )
591      !
592      IF(lwp) THEN                          ! control print
593         WRITE(numout,*)
594         WRITE(numout,*) 'lim_thd_init : Ice Thermodynamics'
595         WRITE(numout,*) '~~~~~~~~~~~~~'
596         WRITE(numout,*)'   -- limthd_dif --'
597         WRITE(numout,*)'      extinction radiation parameter in sea ice               rn_kappa_i   = ', rn_kappa_i
598         WRITE(numout,*)'      maximal n. of iter. for heat diffusion computation      nn_conv_dif  = ', nn_conv_dif
599         WRITE(numout,*)'      maximal err. on T for heat diffusion computation        rn_terr_dif  = ', rn_terr_dif
600         WRITE(numout,*)'      switch for comp. of thermal conductivity in the ice     nn_ice_thcon = ', nn_ice_thcon
601         WRITE(numout,*)'      iterate the surface non-solar flux (T) or not (F)       ln_it_qnsice = ', ln_it_qnsice
602         WRITE(numout,*)'      virtual ITD mono-category parameterizations (1) or not  nn_monocat   = ', nn_monocat
603         WRITE(numout,*)'   -- limthd_dh --'
604         WRITE(numout,*)'      activate ice thick change from top/bot (T) or not (F)   ln_limdH     = ', ln_limdH
605         WRITE(numout,*)'      coefficient for ice-lead partition of snowfall          rn_betas     = ', rn_betas
606         WRITE(numout,*)'   -- limthd_da --'
607         WRITE(numout,*)'      activate lateral melting (T) or not (F)                 ln_limdA     = ', ln_limdA
608         WRITE(numout,*)'      Coef. beta for lateral melting param.                   rn_beta      = ', rn_beta
609         WRITE(numout,*)'      Minimum floe diameter for lateral melting param.        rn_dmin      = ', rn_dmin
610         WRITE(numout,*)'   -- limthd_lac --'
611         WRITE(numout,*)'      activate ice growth in open-water (T) or not (F)        ln_limdO     = ', ln_limdO
612         WRITE(numout,*)'      ice thick. for lateral accretion                        rn_hnewice   = ', rn_hnewice
613         WRITE(numout,*)'      Frazil ice thickness as a function of wind or not       ln_frazil    = ', ln_frazil
614         WRITE(numout,*)'      Maximum proportion of frazil ice collecting at bottom   rn_maxfrazb  = ', rn_maxfrazb
615         WRITE(numout,*)'      Thresold relative drift speed for collection of frazil  rn_vfrazb    = ', rn_vfrazb
616         WRITE(numout,*)'      Squeezing coefficient for collection of frazil          rn_Cfrazb    = ', rn_Cfrazb
617         WRITE(numout,*)'   -- limitd_th --'
618         WRITE(numout,*)'      minimum ice thickness                                   rn_himin     = ', rn_himin 
619         WRITE(numout,*)'      check heat conservation in the ice/snow                 con_i        = ', con_i
620      ENDIF
621      IF( jpl > 1 .AND. nn_monocat == 1 ) THEN
622         nn_monocat = 0
623         IF(lwp) WRITE(numout,*)
624         IF(lwp) WRITE(numout,*) '   nn_monocat forced to 0 as jpl>1, i.e. multi-category case is chosen'
625      ENDIF
626      !
627   END SUBROUTINE lim_thd_init
628
629#else
630   !!----------------------------------------------------------------------
631   !!   Default option         Dummy module          NO  LIM3 sea-ice model
632   !!----------------------------------------------------------------------
633#endif
634
635   !!======================================================================
636END MODULE limthd
Note: See TracBrowser for help on using the repository browser.