New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

sbcice_lim.F90 in branches/2016/dev_v3_6_STABLE_r6506_AGRIF_LIM3/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

Context Navigation

source: branches/2016/dev_v3_6_STABLE_r6506_AGRIF_LIM3/NEMOGCM/NEMO/OPA_SRC/SBC/sbcice_lim.F90 @ 6994

Last change on this file since 6994 was 6994, checked in by clem, 8 years ago
clean online sea ice diagnostics
Property svn:keywords set to `Id`
File size: 35.1 KB

Line
1	MODULE sbcice_lim
2	!!======================================================================
3	!! * MODULE sbcice_lim *
4	!! Surface module : update the ocean surface boundary condition over ice
5	!! & covered area using LIM sea-ice model
6	!! Sea-Ice model : LIM-3 Sea ice model time-stepping
7	!!=====================================================================
8	!! History : 2.0 ! 2006-12 (M. Vancoppenolle) Original code
9	!! 3.0 ! 2008-02 (C. Talandier) Surface module from icestp.F90
10	!! - ! 2008-04 (G. Madec) sltyle and lim_ctl routine
11	!! 3.3 ! 2010-11 (G. Madec) ice-ocean stress always computed at each ocean time-step
12	!! 3.4 ! 2011-01 (A Porter) dynamical allocation
13	!! - ! 2012-10 (C. Rousset) add lim_diahsb
14	!! 3.6 ! 2014-07 (M. Vancoppenolle, G. Madec, O. Marti) revise coupled interface
15	!!----------------------------------------------------------------------
16	#if defined key_lim3
17	!!----------------------------------------------------------------------
18	!! 'key_lim3' : LIM 3.0 sea-ice model
19	!!----------------------------------------------------------------------
20	!! sbc_ice_lim : sea-ice model time-stepping and update ocean sbc over ice-covered area
21	!!----------------------------------------------------------------------
22	USE oce ! ocean dynamics and tracers
23	USE dom_oce ! ocean space and time domain
24	USE ice ! LIM-3: ice variables
25	USE thd_ice ! LIM-3: thermodynamical variables
26
27	USE sbc_oce ! Surface boundary condition: ocean fields
28	USE sbc_ice ! Surface boundary condition: ice fields
29	USE sbcblk_core ! Surface boundary condition: CORE bulk
30	USE sbcblk_clio ! Surface boundary condition: CLIO bulk
31	USE sbccpl ! Surface boundary condition: coupled interface
32	USE albedo ! ocean & ice albedo
33
34	USE phycst ! Define parameters for the routines
35	USE eosbn2 ! equation of state
36	USE limdyn ! Ice dynamics
37	USE limtrp ! Ice transport
38	USE limhdf ! Ice horizontal diffusion
39	USE limthd ! Ice thermodynamics
40	USE limitd_me ! Mechanics on ice thickness distribution
41	USE limsbc ! sea surface boundary condition
42	USE limdiahsb ! Ice budget diagnostics
43	USE limwri ! Ice outputs
44	USE limrst ! Ice restarts
45	USE limupdate1 ! update of global variables
46	USE limupdate2 ! update of global variables
47	USE limvar ! Ice variables switch
48
49	USE limistate ! LIM initial state
50	USE limthd_sal ! LIM ice thermodynamics: salinity
51
52	USE c1d ! 1D vertical configuration
53	USE lbclnk ! lateral boundary condition - MPP link
54	USE lib_mpp ! MPP library
55	USE wrk_nemo ! work arrays
56	USE timing ! Timing
57	USE iom ! I/O manager library
58	USE in_out_manager ! I/O manager
59	USE prtctl ! Print control
60	USE lib_fortran !
61	USE limctl
62
63	#if defined key_bdy
64	USE bdyice_lim ! unstructured open boundary data (bdy_ice_lim routine)
65	#endif
66	# if defined key_agrif
67	USE agrif_ice
68	USE agrif_lim3_update
69	USE agrif_lim3_interp
70	# endif
71
72	IMPLICIT NONE
73	PRIVATE
74
75	PUBLIC sbc_ice_lim ! routine called by sbcmod.F90
76	PUBLIC sbc_lim_init ! routine called by sbcmod.F90
77
78	!! * Substitutions
79	# include "domzgr_substitute.h90"
80	# include "vectopt_loop_substitute.h90"
81	!!----------------------------------------------------------------------
82	!! NEMO/OPA 4.0 , UCL NEMO Consortium (2011)
83	!! $Id$
84	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
85	!!----------------------------------------------------------------------
86	CONTAINS
87
88	!!======================================================================
89
90	SUBROUTINE sbc_ice_lim( kt, kblk )
91	!!---------------------------------------------------------------------
92	!! * ROUTINE sbc_ice_lim *
93	!!
94	!! ** Purpose : update the ocean surface boundary condition via the
95	!! Louvain la Neuve Sea Ice Model time stepping
96	!!
97	!! ** Method : ice model time stepping
98	!! - call the ice dynamics routine
99	!! - call the ice advection/diffusion routine
100	!! - call the ice thermodynamics routine
101	!! - call the routine that computes mass and
102	!! heat fluxes at the ice/ocean interface
103	!! - save the outputs
104	!! - save the outputs for restart when necessary
105	!!
106	!! ** Action : - time evolution of the LIM sea-ice model
107	!! - update all sbc variables below sea-ice:
108	!! utau, vtau, taum, wndm, qns , qsr, emp , sfx
109	!!---------------------------------------------------------------------
110	INTEGER, INTENT(in) :: kt ! ocean time step
111	INTEGER, INTENT(in) :: kblk ! type of bulk (=3 CLIO, =4 CORE, =5 COUPLED)
112	!!
113	INTEGER :: jl ! dummy loop index
114	REAL(wp), POINTER, DIMENSION(:,:,:) :: zalb_os, zalb_cs ! ice albedo under overcast/clear sky
115	REAL(wp), POINTER, DIMENSION(:,: ) :: zutau_ice, zvtau_ice
116	!!----------------------------------------------------------------------
117
118	IF( nn_timing == 1 ) CALL timing_start('sbc_ice_lim')
119
120	!-----------------------!
121	! --- Ice time step --- !
122	!-----------------------!
123	IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
124
125	# if defined key_agrif
126	IF( .NOT. Agrif_Root() ) THEN
127	lim_nbstep = MOD( lim_nbstep, Agrif_irhot() * Agrif_Parent(nn_fsbc) / nn_fsbc ) + 1
128	ENDIF
129	# endif
130
131	! mean surface ocean current at ice velocity point (C-grid dynamics : U- & V-points as the ocean)
132	u_oce(:,:) = ssu_m(:,:) * umask(:,:,1)
133	v_oce(:,:) = ssv_m(:,:) * vmask(:,:,1)
134
135	! masked sea surface freezing temperature [Kelvin] (set to rt0 over land)
136	CALL eos_fzp( sss_m(:,:) , t_bo(:,:) )
137	t_bo(:,:) = ( t_bo(:,:) + rt0 ) * tmask(:,:,1) + rt0 * ( 1._wp - tmask(:,:,1) )
138
139	! Mask sea ice surface temperature (set to rt0 over land)
140	DO jl = 1, jpl
141	t_su(:,:,jl) = t_su(:,:,jl) * tmask(:,:,1) + rt0 * ( 1._wp - tmask(:,:,1) )
142	END DO
143	!
144	!------------------------------------------------!
145	! --- Dynamical coupling with the atmosphere --- !
146	!------------------------------------------------!
147	! It provides the following fields:
148	! utau_ice, vtau_ice : surface ice stress (U- & V-points) [N/m2]
149	!-----------------------------------------------------------------
150	SELECT CASE( kblk )
151	CASE( jp_clio ) ; CALL blk_ice_clio_tau ! CLIO bulk formulation
152	CASE( jp_core ) ; CALL blk_ice_core_tau ! CORE bulk formulation
153	CASE( jp_purecpl ) ; CALL sbc_cpl_ice_tau( utau_ice , vtau_ice ) ! Coupled formulation
154	END SELECT
155
156	IF( ln_mixcpl) THEN ! Case of a mixed Bulk/Coupled formulation
157	CALL wrk_alloc( jpi,jpj , zutau_ice, zvtau_ice)
158	CALL sbc_cpl_ice_tau( zutau_ice , zvtau_ice )
159	utau_ice(:,:) = utau_ice(:,:) * xcplmask(:,:,0) + zutau_ice(:,:) * ( 1. - xcplmask(:,:,0) )
160	vtau_ice(:,:) = vtau_ice(:,:) * xcplmask(:,:,0) + zvtau_ice(:,:) * ( 1. - xcplmask(:,:,0) )
161	CALL wrk_dealloc( jpi,jpj , zutau_ice, zvtau_ice)
162	ENDIF
163
164	!-------------------------------------------------------!
165	! --- ice dynamics and transport (except in 1D case) ---!
166	!-------------------------------------------------------!
167	numit = numit + nn_fsbc ! Ice model time step
168	!
169	CALL sbc_lim_bef ! Store previous ice values
170	CALL sbc_lim_diag0 ! set diag of mass, heat and salt fluxes to 0
171	CALL lim_rst_opn( kt ) ! Open Ice restart file
172	!
173	#if defined key_agrif
174	IF( .NOT. Agrif_Root() ) CALL agrif_interp_lim3('T')
175	#endif
176	! --- zap this if no ice dynamics --- !
177	IF( .NOT. lk_c1d .AND. ln_limdyn ) THEN
178	!
179	IF( nn_limdyn /= 0 ) THEN ! -- Ice dynamics
180	CALL lim_dyn( kt ) ! rheology
181	ELSE
182	u_ice(:,:) = rn_uice * umask(:,:,1) ! or prescribed velocity
183	v_ice(:,:) = rn_vice * vmask(:,:,1)
184	ENDIF
185	CALL lim_trp( kt ) ! -- Ice transport (Advection/diffusion)
186	IF( nn_limdyn == 2 .AND. nn_monocat /= 2 ) & ! -- Mechanical redistribution (ridging/rafting)
187	& CALL lim_itd_me
188	IF( nn_limdyn == 2 ) CALL lim_update1( kt ) ! -- Corrections
189	!
190	ENDIF
191	! ---
192	#if defined key_agrif
193	IF( .NOT. Agrif_Root() ) CALL agrif_interp_lim3('T')
194	#endif
195	#if defined key_bdy
196	IF( ln_limthd ) CALL bdy_ice_lim( kt ) ! -- bdy ice thermo
197	#endif
198
199	! previous lead fraction and ice volume for flux calculations
200	CALL sbc_lim_bef
201	CALL lim_var_glo2eqv ! ht_i and ht_s for ice albedo calculation
202	CALL lim_var_agg(1) ! at_i for coupling (via pfrld)
203	!
204	pfrld(:,:) = 1._wp - at_i(:,:)
205	phicif(:,:) = vt_i(:,:)
206
207	!------------------------------------------------------!
208	! --- Thermodynamical coupling with the atmosphere --- !
209	!------------------------------------------------------!
210	! It provides the following fields:
211	! qsr_ice , qns_ice : solar & non solar heat flux over ice (T-point) [W/m2]
212	! qla_ice : latent heat flux over ice (T-point) [W/m2]
213	! dqns_ice, dqla_ice : non solar & latent heat sensistivity (T-point) [W/m2]
214	! tprecip , sprecip : total & solid precipitation (T-point) [Kg/m2/s]
215	! fr1_i0 , fr2_i0 : 1sr & 2nd fraction of qsr penetration in ice [%]
216	!----------------------------------------------------------------------------------------
217	CALL wrk_alloc( jpi,jpj,jpl, zalb_os, zalb_cs )
218
219	CALL albedo_ice( t_su, ht_i, ht_s, zalb_cs, zalb_os ) ! cloud-sky and overcast-sky ice albedos
220	SELECT CASE( kblk )
221
222	CASE( jp_clio ) ! CLIO bulk formulation
223	! In CLIO the cloud fraction is read in the climatology and the all-sky albedo
224	! (alb_ice) is computed within the bulk routine
225	CALL blk_ice_clio_flx( t_su, zalb_cs, zalb_os, alb_ice )
226	IF( ln_mixcpl ) CALL sbc_cpl_ice_flx( p_frld=pfrld, palbi=alb_ice, psst=sst_m, pist=t_su )
227	IF( nn_limflx /= 2 ) CALL ice_lim_flx( t_su, alb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_limflx )
228
229	CASE( jp_core ) ! CORE bulk formulation
230	! albedo depends on cloud fraction because of non-linear spectral effects
231	alb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:)
232	CALL blk_ice_core_flx( t_su, alb_ice )
233	IF( ln_mixcpl ) CALL sbc_cpl_ice_flx( p_frld=pfrld, palbi=alb_ice, psst=sst_m, pist=t_su )
234	IF( nn_limflx /= 2 ) CALL ice_lim_flx( t_su, alb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_limflx )
235
236	CASE ( jp_purecpl ) ! Coupled formulation
237	! albedo depends on cloud fraction because of non-linear spectral effects
238	alb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:)
239	CALL sbc_cpl_ice_flx( p_frld=pfrld, palbi=alb_ice, psst=sst_m, pist=t_su )
240	IF( nn_limflx == 2 ) CALL ice_lim_flx( t_su, alb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_limflx )
241
242	END SELECT
243
244	CALL wrk_dealloc( jpi,jpj,jpl, zalb_os, zalb_cs )
245
246	!----------------------------!
247	! --- ice thermodynamics --- !
248	!----------------------------!
249	! --- zap this if no ice thermo --- !
250	IF( ln_limthd ) CALL lim_thd( kt ) ! -- Ice thermodynamics
251	IF( ln_limthd ) CALL lim_update2( kt ) ! -- Corrections
252	! ---
253	# if defined key_agrif
254	IF( .NOT. Agrif_Root() ) CALL agrif_update_lim3( kt )
255	# endif
256	CALL lim_var_glo2eqv ! necessary calls (at least for coupling)
257	CALL lim_var_agg( 2 ) ! necessary calls (at least for coupling)
258	!
259	CALL lim_sbc_flx( kt ) ! -- Update surface ocean mass, heat and salt fluxes
260	!
261	IF( ln_limdiahsb ) CALL lim_diahsb( kt ) ! -- Diagnostics and outputs
262	!
263	CALL lim_wri( 1 ) ! -- Ice outputs
264	!
265	IF( kt == nit000 .AND. ln_rstart ) &
266	& CALL iom_close( numrir ) ! close input ice restart file
267	!
268	IF( lrst_ice ) CALL lim_rst_write( kt ) ! -- Ice restart file
269	!
270	IF( ln_limctl ) CALL lim_ctl( kt ) ! alerts in case of model crash
271	!
272	ENDIF ! End sea-ice time step only
273
274	!-------------------------!
275	! --- Ocean time step --- !
276	!-------------------------!
277	! Update surface ocean stresses (only in ice-dynamic case) otherwise the atm.-ocean stresses are used everywhere
278	! using before instantaneous surf. currents
279	IF( ln_limdyn ) CALL lim_sbc_tau( kt, ub(:,:,1), vb(:,:,1) )
280	!!gm remark, the ocean-ice stress is not saved in ice diag call above ..... find a solution!!!
281	!
282	IF( nn_timing == 1 ) CALL timing_stop('sbc_ice_lim')
283	!
284	END SUBROUTINE sbc_ice_lim
285
286
287	SUBROUTINE sbc_lim_init
288	!!----------------------------------------------------------------------
289	!! * ROUTINE sbc_lim_init *
290	!!
291	!! ** purpose : Allocate all the dynamic arrays of the LIM-3 modules
292	!!----------------------------------------------------------------------
293	INTEGER :: ierr
294	INTEGER :: ji, jj
295	!!----------------------------------------------------------------------
296	IF(lwp) WRITE(numout,*)
297	IF(lwp) WRITE(numout,*) 'sbc_lim_init : update ocean surface boudary condition'
298	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ via Louvain la Neuve Ice Model (LIM-3) time stepping'
299	!
300	! Open the reference and configuration namelist files and namelist output file
301	CALL ctl_opn( numnam_ice_ref, 'namelist_ice_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp )
302	CALL ctl_opn( numnam_ice_cfg, 'namelist_ice_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp )
303	IF(lwm) CALL ctl_opn( numoni, 'output.namelist.ice', 'UNKNOWN', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, 1 )
304
305	CALL ice_run ! set some ice run parameters
306	!
307	! ! Allocate the ice arrays
308	ierr = ice_alloc () ! ice variables
309	ierr = ierr + sbc_ice_alloc () ! surface forcing
310	ierr = ierr + thd_ice_alloc () ! thermodynamics
311	IF( ln_limdyn ) ierr = ierr + lim_itd_me_alloc () ! ice thickness distribution - mechanics
312	!
313	IF( lk_mpp ) CALL mpp_sum( ierr )
314	IF( ierr /= 0 ) CALL ctl_stop('STOP', 'sbc_lim_init : unable to allocate ice arrays')
315	!
316	! ! adequation jpk versus ice/snow layers/categories
317	IF( jpl > jpk .OR. (nlay_i+1) > jpk .OR. nlay_s > jpk ) &
318	& CALL ctl_stop( 'STOP', &
319	& 'sbc_lim_init: the 3rd dimension of workspace arrays is too small.', &
320	& 'use more ocean levels or less ice/snow layers/categories.' )
321	!
322	CALL lim_dyn_init ! set ice dynamics parameters
323	!
324	CALL lim_itd_init ! ice thickness distribution initialization
325	!
326	CALL lim_hdf_init ! set ice horizontal diffusion computation parameters
327	!
328	CALL lim_thd_init ! set ice thermodynics parameters
329	!
330	CALL lim_thd_sal_init ! set ice salinity parameters
331	!
332	IF( ln_limdyn ) CALL lim_itd_me_init ! ice thickness distribution initialization for mecanical deformation
333	! ! Initial sea-ice state
334	IF( .NOT. ln_rstart ) THEN ! start from rest: sea-ice deduced from sst
335	numit = 0
336	numit = nit000 - 1
337	CALL lim_istate
338	ELSE ! start from a restart file
339	CALL lim_rst_read
340	numit = nit000 - 1
341	ENDIF
342	CALL lim_var_agg(2)
343	CALL lim_var_glo2eqv
344	!
345	CALL lim_sbc_init ! ice surface boundary condition
346	!
347	IF( ln_limdiahsb) CALL lim_diahsb_init ! initialization for diags
348	!
349	fr_i(:,:) = at_i(:,:) ! initialisation of sea-ice fraction
350	tn_ice(:,:,:) = t_su(:,:,:) ! initialisation of surface temp for coupled simu
351	!
352	DO jj = 1, jpj
353	DO ji = 1, jpi
354	IF( gphit(ji,jj) > 0._wp ) THEN ; rn_amax_2d(ji,jj) = rn_amax_n ! NH
355	ELSE ; rn_amax_2d(ji,jj) = rn_amax_s ! SH
356	ENDIF
357	ENDDO
358	ENDDO
359	!
360	nstart = numit + nn_fsbc
361	nitrun = nitend - nit000 + 1
362	nlast = numit + nitrun
363	!
364	IF( nstock == 0 ) nstock = nlast + 1
365	!
366	# if defined key_agrif
367	IF( .NOT. Agrif_Root() ) CALL Agrif_InitValues_cont_lim3
368	# endif
369	!
370	END SUBROUTINE sbc_lim_init
371
372
373	SUBROUTINE ice_run
374	!!-------------------------------------------------------------------
375	!! * ROUTINE ice_run *
376	!!
377	!! ** Purpose : Definition some run parameter for ice model
378	!!
379	!! ** Method : Read the namicerun namelist and check the parameter
380	!! values called at the first timestep (nit000)
381	!!
382	!! ** input : Namelist namicerun
383	!!-------------------------------------------------------------------
384	INTEGER :: ios ! Local integer output status for namelist read
385	NAMELIST/namicerun/ jpl, nlay_i, nlay_s, rn_amax_n, rn_amax_s, cn_icerst_in, cn_icerst_indir, &
386	& cn_icerst_out, cn_icerst_outdir, ln_limthd, ln_limdyn, nn_limdyn, rn_uice, rn_vice
387	NAMELIST/namicediag/ ln_limdiachk, ln_limdiahsb, ln_limctl, iiceprt, jiceprt
388	!!-------------------------------------------------------------------
389	!
390	REWIND( numnam_ice_ref ) ! Namelist namicerun in reference namelist : Parameters for ice
391	READ ( numnam_ice_ref, namicerun, IOSTAT = ios, ERR = 901)
392	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicerun in reference namelist', lwp )
393
394	REWIND( numnam_ice_cfg ) ! Namelist namicerun in configuration namelist : Parameters for ice
395	READ ( numnam_ice_cfg, namicerun, IOSTAT = ios, ERR = 902 )
396	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicerun in configuration namelist', lwp )
397	IF(lwm) WRITE ( numoni, namicerun )
398	!
399	REWIND( numnam_ice_ref ) ! Namelist namicediag in reference namelist : Parameters for ice
400	READ ( numnam_ice_ref, namicediag, IOSTAT = ios, ERR = 903)
401	903 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicediag in reference namelist', lwp )
402
403	REWIND( numnam_ice_cfg ) ! Namelist namicediag in configuration namelist : Parameters for ice
404	READ ( numnam_ice_cfg, namicediag, IOSTAT = ios, ERR = 904 )
405	904 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicediag in configuration namelist', lwp )
406	IF(lwm) WRITE ( numoni, namicediag )
407	!
408	IF(lwp) THEN ! control print
409	WRITE(numout,*)
410	WRITE(numout,*) 'ice_run : ice share~d parameters for dynamics/advection/thermo of sea-ice'
411	WRITE(numout,*) ' ~~~~~~'
412	WRITE(numout,*) ' number of ice categories = ', jpl
413	WRITE(numout,*) ' number of ice layers = ', nlay_i
414	WRITE(numout,*) ' number of snow layers = ', nlay_s
415	WRITE(numout,*) ' maximum ice concentration for NH = ', rn_amax_n
416	WRITE(numout,*) ' maximum ice concentration for SH = ', rn_amax_s
417	WRITE(numout,*) ' Ice thermodynamics (T) or not (F) ln_limthd = ', ln_limthd
418	WRITE(numout,*) ' Ice dynamics (T) or not (F) ln_limdyn = ', ln_limdyn
419	WRITE(numout,*) ' (ln_limdyn=T) Ice dynamics switch nn_limdyn = ', nn_limdyn
420	WRITE(numout,*) ' 2: total'
421	WRITE(numout,*) ' 1: advection only (no diffusion, no ridging/rafting)'
422	WRITE(numout,*) ' 0: advection only (as 1 + prescribed velocity, bypass rheology)'
423	WRITE(numout,*) ' (ln_limdyn=T) prescribed u-vel (case nn_limdyn=0) = ', rn_uice
424	WRITE(numout,*) ' (ln_limdyn=T) prescribed v-vel (case nn_limdyn=0) = ', rn_vice
425	WRITE(numout,*)
426	WRITE(numout,*) '...and ice diagnostics'
427	WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~'
428	WRITE(numout,*) ' Diagnose online heat/mass/salt budget ln_limdiachk = ', ln_limdiachk
429	WRITE(numout,*) ' Output heat/mass/salt budget ln_limdiahsb = ', ln_limdiahsb
430	WRITE(numout,*) ' control prints in ocean.out for (i,j)=(iiceprt,jiceprt) = ', ln_limctl
431	WRITE(numout,*) ' i-index for control prints (ln_limctl=true) = ', iiceprt
432	WRITE(numout,*) ' j-index for control prints (ln_limctl=true) = ', jiceprt
433	ENDIF
434	!
435	! sea-ice timestep and inverse
436	rdt_ice = nn_fsbc * rdttra(1)
437	r1_rdtice = 1._wp / rdt_ice
438
439	! inverse of nlay_i and nlay_s
440	r1_nlay_i = 1._wp / REAL( nlay_i, wp )
441	r1_nlay_s = 1._wp / REAL( nlay_s, wp )
442	!
443	#if defined key_bdy
444	IF( lwp .AND. ln_limdiachk ) CALL ctl_warn('online conservation check activated but it does not work with BDY')
445	#endif
446	!
447	END SUBROUTINE ice_run
448
449
450	SUBROUTINE lim_itd_init
451	!!------------------------------------------------------------------
452	!! * ROUTINE lim_itd_init *
453	!!
454	!! ** Purpose : Initializes the ice thickness distribution
455	!! ** Method : ...
456	!! ** input : Namelist namiceitd
457	!!-------------------------------------------------------------------
458	INTEGER :: ios ! Local integer output status for namelist read
459	NAMELIST/namiceitd/ nn_catbnd, rn_himean
460	!
461	INTEGER :: jl ! dummy loop index
462	REAL(wp) :: zc1, zc2, zc3, zx1 ! local scalars
463	REAL(wp) :: zhmax, znum, zden, zalpha !
464	!!------------------------------------------------------------------
465	!
466	REWIND( numnam_ice_ref ) ! Namelist namiceitd in reference namelist : Parameters for ice
467	READ ( numnam_ice_ref, namiceitd, IOSTAT = ios, ERR = 905)
468	905 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namiceitd in reference namelist', lwp )
469
470	REWIND( numnam_ice_cfg ) ! Namelist namiceitd in configuration namelist : Parameters for ice
471	READ ( numnam_ice_cfg, namiceitd, IOSTAT = ios, ERR = 906 )
472	906 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namiceitd in configuration namelist', lwp )
473	IF(lwm) WRITE ( numoni, namiceitd )
474	!
475	IF(lwp) THEN ! control print
476	WRITE(numout,*)
477	WRITE(numout,*) 'lim_itd_init : Initialization of ice cat distribution '
478	WRITE(numout,*) '~~~~~~~~~~~~'
479	WRITE(numout,*) ' shape of ice categories distribution nn_catbnd = ', nn_catbnd
480	WRITE(numout,*) ' mean ice thickness in the domain (only active if nn_catbnd=2) rn_himean = ', rn_himean
481	ENDIF
482
483	!----------------------------------
484	!- Thickness categories boundaries
485	!----------------------------------
486	hi_max(:) = 0._wp
487
488	SELECT CASE ( nn_catbnd )
489	!----------------------
490	CASE (1) ! tanh function (CICE)
491	!----------------------
492	zc1 = 3._wp / REAL( jpl, wp )
493	zc2 = 10._wp * zc1
494	zc3 = 3._wp
495
496	DO jl = 1, jpl
497	zx1 = REAL( jl-1, wp ) / REAL( jpl, wp )
498	hi_max(jl) = hi_max(jl-1) + zc1 + zc2 * (1._wp + TANH( zc3 * (zx1 - 1._wp ) ) )
499	END DO
500
501	!----------------------
502	CASE (2) ! h^(-alpha) function
503	!----------------------
504	zalpha = 0.05 ! exponent of the transform function
505
506	zhmax = 3.*rn_himean
507
508	DO jl = 1, jpl
509	znum = jpl * ( zhmax+1 )**zalpha
510	zden = ( jpl - jl ) * ( zhmax+1 )**zalpha + jl
511	hi_max(jl) = ( znum / zden )**(1./zalpha) - 1
512	END DO
513
514	END SELECT
515
516	DO jl = 1, jpl
517	hi_mean(jl) = ( hi_max(jl) + hi_max(jl-1) ) * 0.5_wp
518	END DO
519
520	! Set hi_max(jpl) to a big value to ensure that all ice is thinner than hi_max(jpl)
521	hi_max(jpl) = 99._wp
522
523	IF(lwp) WRITE(numout,*) ' Thickness category boundaries '
524	IF(lwp) WRITE(numout,*) ' hi_max ', hi_max(0:jpl)
525	!
526	END SUBROUTINE lim_itd_init
527
528
529	SUBROUTINE ice_lim_flx( ptn_ice, palb_ice, pqns_ice, pqsr_ice, pdqn_ice, pevap_ice, pdevap_ice, k_limflx )
530	!!---------------------------------------------------------------------
531	!! * ROUTINE ice_lim_flx *
532	!!
533	!! ** Purpose : update the ice surface boundary condition by averaging and / or
534	!! redistributing fluxes on ice categories
535	!!
536	!! ** Method : average then redistribute
537	!!
538	!! ** Action :
539	!!---------------------------------------------------------------------
540	INTEGER , INTENT(in ) :: k_limflx ! =-1 do nothing; =0 average ;
541	! =1 average and redistribute ; =2 redistribute
542	REAL(wp), DIMENSION(:,:,:), INTENT(in ) :: ptn_ice ! ice surface temperature
543	REAL(wp), DIMENSION(:,:,:), INTENT(in ) :: palb_ice ! ice albedo
544	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pqns_ice ! non solar flux
545	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pqsr_ice ! net solar flux
546	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pdqn_ice ! non solar flux sensitivity
547	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pevap_ice ! sublimation
548	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pdevap_ice ! sublimation sensitivity
549	!
550	INTEGER :: jl ! dummy loop index
551	!
552	REAL(wp), POINTER, DIMENSION(:,:) :: zalb_m ! Mean albedo over all categories
553	REAL(wp), POINTER, DIMENSION(:,:) :: ztem_m ! Mean temperature over all categories
554	!
555	REAL(wp), POINTER, DIMENSION(:,:) :: z_qsr_m ! Mean solar heat flux over all categories
556	REAL(wp), POINTER, DIMENSION(:,:) :: z_qns_m ! Mean non solar heat flux over all categories
557	REAL(wp), POINTER, DIMENSION(:,:) :: z_evap_m ! Mean sublimation over all categories
558	REAL(wp), POINTER, DIMENSION(:,:) :: z_dqn_m ! Mean d(qns)/dT over all categories
559	REAL(wp), POINTER, DIMENSION(:,:) :: z_devap_m ! Mean d(evap)/dT over all categories
560	!!----------------------------------------------------------------------
561
562	IF( nn_timing == 1 ) CALL timing_start('ice_lim_flx')
563	!
564	!
565	SELECT CASE( k_limflx ) !== averaged on all ice categories ==!
566	CASE( 0 , 1 )
567	CALL wrk_alloc( jpi,jpj, z_qsr_m, z_qns_m, z_evap_m, z_dqn_m, z_devap_m)
568	!
569	z_qns_m (:,:) = fice_ice_ave ( pqns_ice (:,:,:) )
570	z_qsr_m (:,:) = fice_ice_ave ( pqsr_ice (:,:,:) )
571	z_dqn_m (:,:) = fice_ice_ave ( pdqn_ice (:,:,:) )
572	z_evap_m (:,:) = fice_ice_ave ( pevap_ice (:,:,:) )
573	z_devap_m(:,:) = fice_ice_ave ( pdevap_ice (:,:,:) )
574	DO jl = 1, jpl
575	pdqn_ice (:,:,jl) = z_dqn_m(:,:)
576	pdevap_ice(:,:,jl) = z_devap_m(:,:)
577	END DO
578	!
579	DO jl = 1, jpl
580	pqns_ice (:,:,jl) = z_qns_m(:,:)
581	pqsr_ice (:,:,jl) = z_qsr_m(:,:)
582	pevap_ice(:,:,jl) = z_evap_m(:,:)
583	END DO
584	!
585	CALL wrk_dealloc( jpi,jpj, z_qsr_m, z_qns_m, z_evap_m, z_dqn_m, z_devap_m)
586	END SELECT
587
588	SELECT CASE( k_limflx ) !== redistribution on all ice categories ==!
589	CASE( 1 , 2 )
590	CALL wrk_alloc( jpi,jpj, zalb_m, ztem_m )
591	!
592	zalb_m(:,:) = fice_ice_ave ( palb_ice (:,:,:) )
593	ztem_m(:,:) = fice_ice_ave ( ptn_ice (:,:,:) )
594	DO jl = 1, jpl
595	pqns_ice (:,:,jl) = pqns_ice (:,:,jl) + pdqn_ice (:,:,jl) * ( ptn_ice(:,:,jl) - ztem_m(:,:) )
596	pevap_ice(:,:,jl) = pevap_ice(:,:,jl) + pdevap_ice(:,:,jl) * ( ptn_ice(:,:,jl) - ztem_m(:,:) )
597	pqsr_ice (:,:,jl) = pqsr_ice (:,:,jl) * ( 1._wp - palb_ice(:,:,jl) ) / ( 1._wp - zalb_m(:,:) )
598	END DO
599	!
600	CALL wrk_dealloc( jpi,jpj, zalb_m, ztem_m )
601	END SELECT
602	!
603	IF( nn_timing == 1 ) CALL timing_stop('ice_lim_flx')
604	!
605	END SUBROUTINE ice_lim_flx
606
607	SUBROUTINE sbc_lim_bef
608	!!----------------------------------------------------------------------
609	!! * ROUTINE sbc_lim_bef *
610	!!
611	!! ** purpose : store ice variables at "before" time step
612	!!----------------------------------------------------------------------
613	a_i_b (:,:,:) = a_i (:,:,:) ! ice area
614	e_i_b (:,:,:,:) = e_i (:,:,:,:) ! ice thermal energy
615	v_i_b (:,:,:) = v_i (:,:,:) ! ice volume
616	v_s_b (:,:,:) = v_s (:,:,:) ! snow volume
617	e_s_b (:,:,:,:) = e_s (:,:,:,:) ! snow thermal energy
618	smv_i_b(:,:,:) = smv_i(:,:,:) ! salt content
619	oa_i_b (:,:,:) = oa_i (:,:,:) ! areal age content
620	u_ice_b(:,:) = u_ice(:,:)
621	v_ice_b(:,:) = v_ice(:,:)
622	at_i_b (:,:) = SUM( a_i_b(:,:,:), dim=3 )
623
624	END SUBROUTINE sbc_lim_bef
625
626	SUBROUTINE sbc_lim_diag0
627	!!----------------------------------------------------------------------
628	!! * ROUTINE sbc_lim_diag0 *
629	!!
630	!! ** purpose : set ice-ocean and ice-atm. fluxes to zeros at the beggining
631	!! of the time step
632	!!----------------------------------------------------------------------
633	sfx (:,:) = 0._wp ;
634	sfx_bri(:,:) = 0._wp ; sfx_lam(:,:) = 0._wp
635	sfx_sni(:,:) = 0._wp ; sfx_opw(:,:) = 0._wp
636	sfx_bog(:,:) = 0._wp ; sfx_dyn(:,:) = 0._wp
637	sfx_bom(:,:) = 0._wp ; sfx_sum(:,:) = 0._wp
638	sfx_res(:,:) = 0._wp ; sfx_sub(:,:) = 0._wp
639
640	wfx_snw(:,:) = 0._wp ; wfx_ice(:,:) = 0._wp
641	wfx_sni(:,:) = 0._wp ; wfx_opw(:,:) = 0._wp
642	wfx_bog(:,:) = 0._wp ; wfx_dyn(:,:) = 0._wp
643	wfx_bom(:,:) = 0._wp ; wfx_sum(:,:) = 0._wp
644	wfx_res(:,:) = 0._wp ; wfx_sub(:,:) = 0._wp
645	wfx_spr(:,:) = 0._wp ; wfx_lam(:,:) = 0._wp
646
647	hfx_thd(:,:) = 0._wp ;
648	hfx_snw(:,:) = 0._wp ; hfx_opw(:,:) = 0._wp
649	hfx_bog(:,:) = 0._wp ; hfx_dyn(:,:) = 0._wp
650	hfx_bom(:,:) = 0._wp ; hfx_sum(:,:) = 0._wp
651	hfx_res(:,:) = 0._wp ; hfx_sub(:,:) = 0._wp
652	hfx_spr(:,:) = 0._wp ; hfx_dif(:,:) = 0._wp
653	hfx_err(:,:) = 0._wp ; hfx_err_rem(:,:) = 0._wp
654	hfx_err_dif(:,:) = 0._wp
655	wfx_err_sub(:,:) = 0._wp
656
657	afx_tot(:,:) = 0._wp ;
658	afx_dyn(:,:) = 0._wp ; afx_thd(:,:) = 0._wp
659
660	diag_heat(:,:) = 0._wp ; diag_smvi(:,:) = 0._wp ;
661	diag_vice(:,:) = 0._wp ; diag_vsnw(:,:) = 0._wp ;
662
663	tau_icebfr(:,:) = 0._wp; ! landfast ice param only (clem: important to keep the init here)
664
665	END SUBROUTINE sbc_lim_diag0
666
667
668	FUNCTION fice_cell_ave ( ptab )
669	!!--------------------------------------------------------------------------
670	!! * Compute average over categories, for grid cell (ice covered and free ocean)
671	!!--------------------------------------------------------------------------
672	REAL (wp), DIMENSION (jpi,jpj) :: fice_cell_ave
673	REAL (wp), DIMENSION (jpi,jpj,jpl), INTENT (in) :: ptab
674	INTEGER :: jl ! Dummy loop index
675
676	fice_cell_ave (:,:) = 0.0_wp
677	DO jl = 1, jpl
678	fice_cell_ave (:,:) = fice_cell_ave (:,:) + a_i (:,:,jl) * ptab (:,:,jl)
679	END DO
680
681	END FUNCTION fice_cell_ave
682
683
684	FUNCTION fice_ice_ave ( ptab )
685	!!--------------------------------------------------------------------------
686	!! * Compute average over categories, for ice covered part of grid cell
687	!!--------------------------------------------------------------------------
688	REAL (kind=wp), DIMENSION (jpi,jpj) :: fice_ice_ave
689	REAL (kind=wp), DIMENSION (jpi,jpj,jpl), INTENT(in) :: ptab
690
691	fice_ice_ave (:,:) = 0.0_wp
692	WHERE ( at_i (:,:) > 0.0_wp ) fice_ice_ave (:,:) = fice_cell_ave ( ptab (:,:,:)) / at_i (:,:)
693
694	END FUNCTION fice_ice_ave
695
696
697	#else
698	!!----------------------------------------------------------------------
699	!! Default option Dummy module NO LIM 3.0 sea-ice model
700	!!----------------------------------------------------------------------
701	CONTAINS
702	SUBROUTINE sbc_ice_lim ( kt, kblk ) ! Dummy routine
703	WRITE(,) 'sbc_ice_lim: You should not have seen this print! error?', kt, kblk
704	END SUBROUTINE sbc_ice_lim
705	SUBROUTINE sbc_lim_init ! Dummy routine
706	END SUBROUTINE sbc_lim_init
707	#endif
708
709	!!======================================================================
710	END MODULE sbcice_lim

Note: See TracBrowser for help on using the repository browser.

Download in other formats: