New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcmod.F90 in branches/2017/dev_METO_2017/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/2017/dev_METO_2017/NEMOGCM/NEMO/OPA_SRC/SBC/sbcmod.F90 @ 8910

Last change on this file since 8910 was 8910, checked in by timgraham, 7 years ago

Merged 2017/dev_r8600_xios_read_write_v2

  • Property svn:keywords set to Id
File size: 33.9 KB
Line 
1MODULE sbcmod
2   !!======================================================================
3   !!                       ***  MODULE  sbcmod  ***
4   !! Surface module :  provide to the ocean its surface boundary condition
5   !!======================================================================
6   !! History :  3.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.1  ! 2008-08  (S. Masson, A. Caubel, E. Maisonnave, G. Madec) coupled interface
8   !!            3.3  ! 2010-04  (M. Leclair, G. Madec)  Forcing averaged over 2 time steps
9   !!            3.3  ! 2010-10  (S. Masson)  add diurnal cycle
10   !!            3.3  ! 2010-09  (D. Storkey) add ice boundary conditions (BDY)
11   !!             -   ! 2010-11  (G. Madec) ice-ocean stress always computed at each ocean time-step
12   !!             -   ! 2010-10  (J. Chanut, C. Bricaud, G. Madec)  add the surface pressure forcing
13   !!            3.4  ! 2011-11  (C. Harris) CICE added as an option
14   !!            3.5  ! 2012-11  (A. Coward, G. Madec) Rethink of heat, mass and salt surface fluxes
15   !!            3.6  ! 2014-11  (P. Mathiot, C. Harris) add ice shelves melting
16   !!            4.0  ! 2016-06  (L. Brodeau) new general bulk formulation
17   !!----------------------------------------------------------------------
18
19   !!----------------------------------------------------------------------
20   !!   sbc_init      : read namsbc namelist
21   !!   sbc           : surface ocean momentum, heat and freshwater boundary conditions
22   !!   sbc_final     : Finalize CICE ice model (if used)
23   !!----------------------------------------------------------------------
24   USE oce            ! ocean dynamics and tracers
25   USE dom_oce        ! ocean space and time domain
26   USE phycst         ! physical constants
27   USE sbc_oce        ! Surface boundary condition: ocean fields
28   USE trc_oce        ! shared ocean-passive tracers variables
29   USE sbc_ice        ! Surface boundary condition: ice fields
30   USE sbcdcy         ! surface boundary condition: diurnal cycle
31   USE sbcssm         ! surface boundary condition: sea-surface mean variables
32   USE sbcflx         ! surface boundary condition: flux formulation
33   USE sbcblk         ! surface boundary condition: bulk formulation
34   USE sbcice_if      ! surface boundary condition: ice-if sea-ice model
35   USE sbcice_lim     ! surface boundary condition: LIM 3.0 sea-ice model
36   USE sbcice_lim_2   ! surface boundary condition: LIM 2.0 sea-ice model
37   USE sbcice_cice    ! surface boundary condition: CICE    sea-ice model
38   USE sbcisf         ! surface boundary condition: ice-shelf
39   USE sbccpl         ! surface boundary condition: coupled formulation
40   USE cpl_oasis3     ! OASIS routines for coupling
41   USE sbcssr         ! surface boundary condition: sea surface restoring
42   USE sbcrnf         ! surface boundary condition: runoffs
43   USE sbcapr         ! surface boundary condition: atmo pressure
44   USE sbcisf         ! surface boundary condition: ice shelf
45   USE sbcfwb         ! surface boundary condition: freshwater budget
46   USE icbstp         ! Icebergs
47   USE traqsr         ! active tracers: light penetration
48   USE sbcwave        ! Wave module
49   USE bdy_oce   , ONLY: ln_bdy
50   USE usrdef_sbc     ! user defined: surface boundary condition
51   USE usrdef_closea  ! user defined: closed sea
52   !
53   USE prtctl         ! Print control                    (prt_ctl routine)
54   USE iom            ! IOM library
55   USE in_out_manager ! I/O manager
56   USE lib_mpp        ! MPP library
57   USE timing         ! Timing
58   USE diurnal_bulk, ONLY:   ln_diurnal_only   ! diurnal SST diagnostic
59
60   IMPLICIT NONE
61   PRIVATE
62
63   PUBLIC   sbc        ! routine called by step.F90
64   PUBLIC   sbc_init   ! routine called by opa.F90
65
66   INTEGER ::   nsbc   ! type of surface boundary condition (deduced from namsbc informations)
67
68   !!----------------------------------------------------------------------
69   !! NEMO/OPA 4.0 , NEMO-consortium (2016)
70   !! $Id$
71   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
72   !!----------------------------------------------------------------------
73CONTAINS
74
75   SUBROUTINE sbc_init
76      !!---------------------------------------------------------------------
77      !!                    ***  ROUTINE sbc_init ***
78      !!
79      !! ** Purpose :   Initialisation of the ocean surface boundary computation
80      !!
81      !! ** Method  :   Read the namsbc namelist and set derived parameters
82      !!                Call init routines for all other SBC modules that have one
83      !!
84      !! ** Action  : - read namsbc parameters
85      !!              - nsbc: type of sbc
86      !!----------------------------------------------------------------------
87      INTEGER ::   ios, icpt                         ! local integer
88      LOGICAL ::   ll_purecpl, ll_opa, ll_not_nemo   ! local logical
89      !!
90      NAMELIST/namsbc/ nn_fsbc  ,                                                    &
91         &             ln_usr   , ln_flx   , ln_blk       ,                          &
92         &             ln_cpl   , ln_mixcpl, nn_components, nn_limflx,               &
93         &             nn_ice   , nn_ice_embd,                                       &
94         &             ln_traqsr, ln_dm2dc ,                                         &
95         &             ln_rnf   , nn_fwb   , ln_ssr   , ln_isf    , ln_apr_dyn ,     &
96         &             ln_wave  , ln_cdgw  , ln_sdw   , ln_tauoc  , ln_stcor   ,     &
97         &             ln_tauw  , nn_lsm, nn_sdrift
98      !!----------------------------------------------------------------------
99      !
100      IF(lwp) THEN
101         WRITE(numout,*)
102         WRITE(numout,*) 'sbc_init : surface boundary condition setting'
103         WRITE(numout,*) '~~~~~~~~ '
104      ENDIF
105      !
106      !                       !**  read Surface Module namelist
107      REWIND( numnam_ref )          !* Namelist namsbc in reference namelist : Surface boundary
108      READ  ( numnam_ref, namsbc, IOSTAT = ios, ERR = 901)
109901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namsbc in reference namelist', lwp )
110      !
111      REWIND( numnam_cfg )          !* Namelist namsbc in configuration namelist : Parameters of the run
112      READ  ( numnam_cfg, namsbc, IOSTAT = ios, ERR = 902 )
113902   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namsbc in configuration namelist', lwp )
114      IF(lwm) WRITE( numond, namsbc )
115      !
116      !                             !* overwrite namelist parameter using CPP key information
117#if defined key_agrif
118      IF( Agrif_Root() ) THEN                ! AGRIF zoom (cf r1242: possibility to run without ice in fine grid)
119         IF( lk_lim2 )   nn_ice      = 2
120         IF( lk_lim3 )   nn_ice      = 3
121         IF( lk_cice )   nn_ice      = 4
122      ENDIF
123#else
124      IF( lk_lim2 )   nn_ice      = 2
125      IF( lk_lim3 )   nn_ice      = 3
126      IF( lk_cice )   nn_ice      = 4
127#endif
128      !
129      IF(lwp) THEN                  !* Control print
130         WRITE(numout,*) '   Namelist namsbc (partly overwritten with CPP key setting)'
131         WRITE(numout,*) '      frequency update of sbc (and ice)             nn_fsbc       = ', nn_fsbc
132         WRITE(numout,*) '      Type of air-sea fluxes : '
133         WRITE(numout,*) '         user defined formulation                   ln_usr        = ', ln_usr
134         WRITE(numout,*) '         flux         formulation                   ln_flx        = ', ln_flx
135         WRITE(numout,*) '         bulk         formulation                   ln_blk        = ', ln_blk
136         WRITE(numout,*) '      Type of coupling (Ocean/Ice/Atmosphere) : '
137         WRITE(numout,*) '         ocean-atmosphere coupled formulation       ln_cpl        = ', ln_cpl
138         WRITE(numout,*) '         mixed forced-coupled     formulation       ln_mixcpl     = ', ln_mixcpl
139!!gm  lk_oasis is controlled by key_oasis3  ===>>>  It shoud be removed from the namelist
140         WRITE(numout,*) '         OASIS coupling (with atm or sas)           lk_oasis      = ', lk_oasis
141         WRITE(numout,*) '         components of your executable              nn_components = ', nn_components
142         WRITE(numout,*) '         Multicategory heat flux formulation (LIM3) nn_limflx     = ', nn_limflx
143         WRITE(numout,*) '      Sea-ice : '
144         WRITE(numout,*) '         ice management in the sbc (=0/1/2/3)       nn_ice        = ', nn_ice
145         WRITE(numout,*) '         ice-ocean embedded/levitating (=0/1/2)     nn_ice_embd   = ', nn_ice_embd
146         WRITE(numout,*) '      Misc. options of sbc : '
147         WRITE(numout,*) '         Light penetration in temperature Eq.       ln_traqsr     = ', ln_traqsr
148         WRITE(numout,*) '            daily mean to diurnal cycle qsr            ln_dm2dc   = ', ln_dm2dc
149         WRITE(numout,*) '         Sea Surface Restoring on SST and/or SSS    ln_ssr        = ', ln_ssr
150         WRITE(numout,*) '         FreshWater Budget control  (=0/1/2)        nn_fwb        = ', nn_fwb
151         WRITE(numout,*) '         Patm gradient added in ocean & ice Eqs.    ln_apr_dyn    = ', ln_apr_dyn
152         WRITE(numout,*) '         runoff / runoff mouths                     ln_rnf        = ', ln_rnf
153         WRITE(numout,*) '         iceshelf formulation                       ln_isf        = ', ln_isf
154         WRITE(numout,*) '         closed sea (=0/1) (set in namdom)          nn_closea     = ', nn_closea
155         WRITE(numout,*) '         nb of iterations if land-sea-mask applied  nn_lsm        = ', nn_lsm
156         WRITE(numout,*) '         surface wave                               ln_wave       = ', ln_wave
157         WRITE(numout,*) '               Stokes drift corr. to vert. velocity ln_sdw        = ', ln_sdw
158         WRITE(numout,*) '                  vertical parametrization          nn_sdrift     = ', nn_sdrift
159         WRITE(numout,*) '               wave modified ocean stress           ln_tauoc      = ', ln_tauoc
160         WRITE(numout,*) '               wave modified ocean stress component ln_tauw       = ', ln_tauw
161         WRITE(numout,*) '               Stokes coriolis term                 ln_stcor      = ', ln_stcor
162         WRITE(numout,*) '               neutral drag coefficient (CORE, MFS) ln_cdgw       = ', ln_cdgw
163      ENDIF
164      !
165      IF( ln_sdw ) THEN
166         IF( .NOT.(nn_sdrift==jp_breivik .OR. nn_sdrift==jp_phillips .OR. nn_sdrift==jp_peakfr) ) &
167            CALL ctl_stop( 'The chosen nn_sdrift for Stokes drift vertical velocity must be 0, 1, or 2' )
168      ENDIF
169      IF( ln_tauoc .AND. ln_tauw ) &
170         CALL ctl_stop( 'More than one method for modifying the ocean stress has been selected ', &
171                                  '(ln_tauoc=.true. and ln_tauw=.true.)' )
172      IF( ln_tauoc ) &
173         CALL ctl_warn( 'You are subtracting the wave stress to the ocean (ln_tauoc=.true.)' )
174      IF( ln_tauw ) &
175         CALL ctl_warn( 'The wave modified ocean stress components are used (ln_tauw=.true.) ', &
176                              'This will override any other specification of the ocean stress' )
177      !
178      IF( .NOT.ln_usr ) THEN     ! the model calendar needs some specificities (except in user defined case)
179         IF( MOD( rday , rdt ) /= 0. )   CALL ctl_stop( 'the time step must devide the number of second of in a day' )
180         IF( MOD( rday , 2.  ) /= 0. )   CALL ctl_stop( 'the number of second of in a day must be an even number'    )
181         IF( MOD( rdt  , 2.  ) /= 0. )   CALL ctl_stop( 'the time step (in second) must be an even number'           )
182      ENDIF
183      !                       !**  check option consistency
184      !
185      IF(lwp) WRITE(numout,*)       !* Single / Multi - executable (NEMO / OPA+SAS)
186      SELECT CASE( nn_components )
187      CASE( jp_iam_nemo )
188         IF(lwp) WRITE(numout,*) '   NEMO configured as a single executable (i.e. including both OPA and Surface module'
189      CASE( jp_iam_opa  )
190         IF(lwp) WRITE(numout,*) '   Multi executable configuration. Here, OPA component'
191         IF( .NOT.lk_oasis )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but key_oasis3 disabled' )
192         IF( ln_cpl        )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_cpl = T in OPA'   )
193         IF( ln_mixcpl     )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_mixcpl = T in OPA' )
194      CASE( jp_iam_sas  )
195         IF(lwp) WRITE(numout,*) '   Multi executable configuration. Here, SAS component'
196         IF( .NOT.lk_oasis )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but key_oasis3 disabled' )
197         IF( ln_mixcpl     )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_mixcpl = T in OPA' )
198      CASE DEFAULT
199         CALL ctl_stop( 'sbc_init : unsupported value for nn_components' )
200      END SELECT
201      !                             !* coupled options
202      IF( ln_cpl ) THEN
203         IF( .NOT. lk_oasis )   CALL ctl_stop( 'sbc_init : coupled mode with an atmosphere model (ln_cpl=T)',   &
204            &                                  '           required to defined key_oasis3' )
205      ENDIF
206      IF( ln_mixcpl ) THEN
207         IF( .NOT. lk_oasis )   CALL ctl_stop( 'sbc_init : mixed forced-coupled mode (ln_mixcpl=T) ',   &
208            &                                  '           required to defined key_oasis3' )
209         IF( .NOT.ln_cpl    )   CALL ctl_stop( 'sbc_init : mixed forced-coupled mode (ln_mixcpl=T) requires ln_cpl = T' )
210         IF( nn_components /= jp_iam_nemo )    &
211            &                   CALL ctl_stop( 'sbc_init : the mixed forced-coupled mode (ln_mixcpl=T) ',   &
212            &                                   '          not yet working with sas-opa coupling via oasis' )
213      ENDIF
214      !                             !* sea-ice
215      SELECT CASE( nn_ice )
216      CASE( 0 )                        !- no ice in the domain
217      CASE( 1 )                        !- Ice-cover climatology ("Ice-if" model) 
218      CASE( 2 )                        !- LIM2 ice model
219         IF( .NOT.( ln_blk .OR. ln_cpl ) )   CALL ctl_stop( 'sbc_init : LIM2 sea-ice model requires ln_blk or ln_cpl = T' )
220      CASE( 3 )                        !- LIM3 ice model
221         IF( nn_ice_embd == 0            )   CALL ctl_stop( 'sbc_init : LIM3 sea-ice models require nn_ice_embd = 1 or 2' )
222      CASE( 4 )                        !- CICE ice model
223         IF( .NOT.( ln_blk .OR. ln_cpl ) )   CALL ctl_stop( 'sbc_init : CICE sea-ice model requires ln_blk or ln_cpl = T' )
224         IF( nn_ice_embd == 0            )   CALL ctl_stop( 'sbc_init : CICE sea-ice models require nn_ice_embd = 1 or 2' )
225         IF( lk_agrif                    )   CALL ctl_stop( 'sbc_init : CICE sea-ice model not currently available with AGRIF' ) 
226      CASE DEFAULT                     !- not supported
227      END SELECT
228      !
229      IF( nn_ice == 3 ) THEN           !- LIM3 case: multi-category flux option
230         IF(lwp) WRITE(numout,*)
231         SELECT CASE( nn_limflx )         ! LIM3 Multi-category heat flux formulation
232         CASE ( -1 )
233            IF(lwp) WRITE(numout,*) '   LIM3: use per-category fluxes (nn_limflx = -1) '
234            IF( ln_cpl )   CALL ctl_stop( 'sbc_init : the chosen nn_limflx for LIM3 in coupled mode must be 0 or 2' )
235         CASE ( 0  )
236            IF(lwp) WRITE(numout,*) '   LIM3: use average per-category fluxes (nn_limflx = 0) '
237         CASE ( 1  )
238            IF(lwp) WRITE(numout,*) '   LIM3: use average then redistribute per-category fluxes (nn_limflx = 1) '
239            IF( ln_cpl )   CALL ctl_stop( 'sbc_init : the chosen nn_limflx for LIM3 in coupled mode must be 0 or 2' )
240         CASE ( 2  )
241            IF(lwp) WRITE(numout,*) '   LIM3: Redistribute a single flux over categories (nn_limflx = 2) '
242            IF( .NOT.ln_cpl )   CALL ctl_stop( 'sbc_init : the chosen nn_limflx for LIM3 in forced mode cannot be 2' )
243         CASE DEFAULT
244            CALL ctl_stop( 'sbcmod: LIM3 option, nn_limflx, should be between -1 and 2' )
245         END SELECT
246      ELSE                             ! other sea-ice model
247         IF( nn_limflx >= 0  )   CALL ctl_warn( 'sbc_init : multi-category flux option (nn_limflx) only available in LIM3' )
248      ENDIF
249      !
250      !                       !**  allocate and set required variables
251      !
252      !                             !* allocate sbc arrays
253      IF( sbc_oce_alloc() /= 0 )   CALL ctl_stop( 'sbc_init : unable to allocate sbc_oce arrays' )
254      !
255      IF( .NOT.ln_isf ) THEN        !* No ice-shelf in the domain : allocate and set to zero
256         IF( sbc_isf_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_isf arrays' )
257         fwfisf  (:,:)   = 0._wp   ;   risf_tsc  (:,:,:) = 0._wp
258         fwfisf_b(:,:)   = 0._wp   ;   risf_tsc_b(:,:,:) = 0._wp
259      END IF
260      IF( nn_ice == 0 ) THEN        !* No sea-ice in the domain : ice fraction is always zero
261         IF( nn_components /= jp_iam_opa )   fr_i(:,:) = 0._wp    ! except for OPA in SAS-OPA coupled case
262      ENDIF
263      !
264      sfx   (:,:) = 0._wp           !* salt flux due to freezing/melting
265      fmmflx(:,:) = 0._wp           !* freezing minus melting flux
266
267      taum(:,:) = 0._wp             !* wind stress module (needed in GLS in case of reduced restart)
268
269      !                          ! Choice of the Surface Boudary Condition (set nsbc)
270      IF( ln_dm2dc ) THEN           !* daily mean to diurnal cycle
271         nday_qsr = -1   ! allow initialization at the 1st call
272         IF( .NOT.( ln_flx .OR. ln_blk ) .AND. nn_components /= jp_iam_opa )   &
273            &   CALL ctl_stop( 'qsr diurnal cycle from daily values requires a flux or bulk formulation' )
274      ENDIF
275      !                             !* Choice of the Surface Boudary Condition
276      !                             (set nsbc)
277      !
278      ll_purecpl  = ln_cpl .AND. .NOT.ln_mixcpl
279      ll_opa      = nn_components == jp_iam_opa
280      ll_not_nemo = nn_components /= jp_iam_nemo
281      icpt = 0
282      !
283      IF( ln_usr          ) THEN   ;   nsbc = jp_usr     ; icpt = icpt + 1   ;   ENDIF       ! user defined         formulation
284      IF( ln_flx          ) THEN   ;   nsbc = jp_flx     ; icpt = icpt + 1   ;   ENDIF       ! flux                 formulation
285      IF( ln_blk          ) THEN   ;   nsbc = jp_blk     ; icpt = icpt + 1   ;   ENDIF       ! bulk                 formulation
286      IF( ll_purecpl      ) THEN   ;   nsbc = jp_purecpl ; icpt = icpt + 1   ;   ENDIF       ! Pure Coupled         formulation
287      IF( ll_opa          ) THEN   ;   nsbc = jp_none    ; icpt = icpt + 1   ;   ENDIF       ! opa coupling via SAS module
288      !
289      IF( icpt /= 1 )    CALL ctl_stop( 'sbc_init : choose ONE and only ONE sbc option' )
290      !
291      IF(lwp) THEN                     !- print the choice of surface flux formulation
292         WRITE(numout,*)
293         SELECT CASE( nsbc )
294         CASE( jp_usr     )   ;   WRITE(numout,*) '   user defined formulation'
295         CASE( jp_flx     )   ;   WRITE(numout,*) '      ===>>   flux formulation'
296         CASE( jp_blk     )   ;   WRITE(numout,*) '      ===>>   bulk formulation'
297         CASE( jp_purecpl )   ;   WRITE(numout,*) '      ===>>   pure coupled formulation'
298!!gm abusive use of jp_none ??   ===>>> need to be check and changed by adding a jp_sas parameter
299         CASE( jp_none    )   ;   WRITE(numout,*) '      ===>>   OPA coupled to SAS via oasis'
300            IF( ln_mixcpl )       WRITE(numout,*) '                  + forced-coupled mixed formulation'
301         END SELECT
302         IF( ll_not_nemo  )       WRITE(numout,*) '                  + OASIS coupled SAS'
303      ENDIF
304      !
305      !                             !* OASIS initialization
306      !
307      IF( lk_oasis )   CALL sbc_cpl_init( nn_ice )   ! Must be done before: (1) first time step
308      !                                              !                      (2) the use of nn_fsbc
309      !     nn_fsbc initialization if OPA-SAS coupling via OASIS
310      !     SAS time-step has to be declared in OASIS (mandatory) -> nn_fsbc has to be modified accordingly
311      IF( nn_components /= jp_iam_nemo ) THEN
312         IF( nn_components == jp_iam_opa )   nn_fsbc = cpl_freq('O_SFLX') / NINT(rdt)
313         IF( nn_components == jp_iam_sas )   nn_fsbc = cpl_freq('I_SFLX') / NINT(rdt)
314         !
315         IF(lwp)THEN
316            WRITE(numout,*)
317            WRITE(numout,*)"   OPA-SAS coupled via OASIS : nn_fsbc re-defined from OASIS namcouple ", nn_fsbc
318            WRITE(numout,*)
319         ENDIF
320      ENDIF
321      !
322      !                             !* check consistency between model timeline and nn_fsbc
323      IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 .OR.   &
324          MOD( nstock             , nn_fsbc) /= 0 ) THEN
325         WRITE(ctmp1,*) 'sbc_init : experiment length (', nitend - nit000 + 1, ') or nstock (', nstock,   &
326            &           ' is NOT a multiple of nn_fsbc (', nn_fsbc, ')'
327         CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' )
328      ENDIF
329      !
330      IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 )   &
331         &  CALL ctl_warn( 'sbc_init : nn_fsbc is NOT a multiple of the number of time steps in a day' )
332      !
333      IF( ln_dm2dc .AND. NINT(rday) / ( nn_fsbc * NINT(rdt) ) < 8  )   &
334         &   CALL ctl_warn( 'sbc_init : diurnal cycle for qsr: the sampling of the diurnal cycle is too small...' )
335      !
336   
337      !                       !**  associated modules : initialization
338      !
339                          CALL sbc_ssm_init            ! Sea-surface mean fields initialization
340      !
341      IF( ln_blk      )   CALL sbc_blk_init            ! bulk formulae initialization
342
343      IF( ln_ssr      )   CALL sbc_ssr_init            ! Sea-Surface Restoring initialization
344      !
345      IF( ln_isf      )   CALL sbc_isf_init               ! Compute iceshelves
346      !
347                          CALL sbc_rnf_init            ! Runof initialization
348      !
349      IF( ln_apr_dyn )    CALL sbc_apr_init            ! Atmo Pressure Forcing initialization
350      !
351      IF( nn_ice == 3 )   CALL sbc_lim_init            ! LIM3 initialization
352      !
353      IF( nn_ice == 4 )   CALL cice_sbc_init( nsbc )   ! CICE initialization
354      !
355      IF( ln_wave     )   CALL sbc_wave_init              ! surface wave initialisation
356      !
357      IF( lwxios ) THEN
358         CALL iom_set_rstw_var_active('utau_b')
359         CALL iom_set_rstw_var_active('vtau_b')
360         CALL iom_set_rstw_var_active('qns_b')
361         ! The 3D heat content due to qsr forcing is treated in traqsr
362         ! CALL iom_set_rstw_var_active('qsr_b')
363         CALL iom_set_rstw_var_active('emp_b')
364         CALL iom_set_rstw_var_active('sfx_b')
365      ENDIF
366
367   END SUBROUTINE sbc_init
368
369
370   SUBROUTINE sbc( kt )
371      !!---------------------------------------------------------------------
372      !!                    ***  ROUTINE sbc  ***
373      !!
374      !! ** Purpose :   provide at each time-step the ocean surface boundary
375      !!                condition (momentum, heat and freshwater fluxes)
376      !!
377      !! ** Method  :   blah blah  to be written ?????????
378      !!                CAUTION : never mask the surface stress field (tke sbc)
379      !!
380      !! ** Action  : - set the ocean surface boundary condition at before and now
381      !!                time step, i.e.
382      !!                utau_b, vtau_b, qns_b, qsr_b, emp_n, sfx_b, qrp_b, erp_b
383      !!                utau  , vtau  , qns  , qsr  , emp  , sfx  , qrp  , erp
384      !!              - updte the ice fraction : fr_i
385      !!----------------------------------------------------------------------
386      INTEGER, INTENT(in) ::   kt   ! ocean time step
387      !
388      LOGICAL ::   ll_sas, ll_opa   ! local logical
389      !!---------------------------------------------------------------------
390      !
391      IF( nn_timing == 1 )  CALL timing_start('sbc')
392      !
393      !                                            ! ---------------------------------------- !
394      IF( kt /= nit000 ) THEN                      !          Swap of forcing fields          !
395         !                                         ! ---------------------------------------- !
396         utau_b(:,:) = utau(:,:)                         ! Swap the ocean forcing fields
397         vtau_b(:,:) = vtau(:,:)                         ! (except at nit000 where before fields
398         qns_b (:,:) = qns (:,:)                         !  are set at the end of the routine)
399         emp_b (:,:) = emp (:,:)
400         sfx_b (:,:) = sfx (:,:)
401         IF ( ln_rnf ) THEN
402            rnf_b    (:,:  ) = rnf    (:,:  )
403            rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)
404         ENDIF
405         IF( ln_isf )  THEN
406            fwfisf_b  (:,:  ) = fwfisf  (:,:  )               
407            risf_tsc_b(:,:,:) = risf_tsc(:,:,:)             
408         ENDIF
409        !
410      ENDIF
411      !                                            ! ---------------------------------------- !
412      !                                            !        forcing field computation         !
413      !                                            ! ---------------------------------------- !
414      !
415      ll_sas = nn_components == jp_iam_sas               ! component flags
416      ll_opa = nn_components == jp_iam_opa
417      !
418      IF( .NOT.ll_sas )   CALL sbc_ssm ( kt )            ! mean ocean sea surface variables (sst_m, sss_m, ssu_m, ssv_m)
419      IF( ln_wave     )   CALL sbc_wave( kt )            ! surface waves
420
421      !
422      !                                            !==  sbc formulation  ==!
423      !                                                   
424      SELECT CASE( nsbc )                                ! Compute ocean surface boundary condition
425      !                                                  ! (i.e. utau,vtau, qns, qsr, emp, sfx)
426      CASE( jp_usr   )     ;   CALL usrdef_sbc_oce( kt )                    ! user defined formulation
427      CASE( jp_flx     )   ;   CALL sbc_flx       ( kt )                    ! flux formulation
428      CASE( jp_blk     )
429         IF( ll_sas    )       CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! OPA-SAS coupling: SAS receiving fields from OPA
430                               CALL sbc_blk       ( kt )                    ! bulk formulation for the ocean
431                               !
432      CASE( jp_purecpl )   ;   CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! pure coupled formulation
433      CASE( jp_none    )
434         IF( ll_opa    )       CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! OPA-SAS coupling: OPA receiving fields from SAS
435      END SELECT
436      !
437      IF( ln_mixcpl )          CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! forced-coupled mixed formulation after forcing
438      !
439      IF ( ln_wave .AND. (ln_tauoc .OR. ln_tauw) ) CALL sbc_wstress( )      ! Wind stress provided by waves
440      !
441      !                                            !==  Misc. Options  ==!
442      !
443      SELECT CASE( nn_ice )                                       ! Update heat and freshwater fluxes over sea-ice areas
444      CASE(  1 )   ;         CALL sbc_ice_if   ( kt )                ! Ice-cover climatology ("Ice-if" model)
445      CASE(  2 )   ;         CALL sbc_ice_lim_2( kt, nsbc )          ! LIM-2 ice model
446      CASE(  3 )   ;         CALL sbc_ice_lim  ( kt, nsbc )          ! LIM-3 ice model
447      CASE(  4 )   ;         CALL sbc_ice_cice ( kt, nsbc )          ! CICE ice model
448      END SELECT
449
450      IF( ln_icebergs    )   CALL icb_stp( kt )                   ! compute icebergs
451
452      IF( ln_isf         )   CALL sbc_isf( kt )                   ! compute iceshelves
453
454      IF( ln_rnf         )   CALL sbc_rnf( kt )                   ! add runoffs to fresh water fluxes
455
456      IF( ln_ssr         )   CALL sbc_ssr( kt )                   ! add SST/SSS damping term
457
458      IF( nn_fwb    /= 0 )   CALL sbc_fwb( kt, nn_fwb, nn_fsbc )  ! control the freshwater budget
459
460      ! treatment of closed sea in the model domain   (update freshwater fluxes)
461      ! Should not be ran if ln_diurnal_only
462      IF( .NOT.ln_diurnal_only .AND. nn_closea == 1 )   CALL sbc_clo( kt, cn_cfg, nn_cfg )   
463
464!RBbug do not understand why see ticket 667
465!clem: it looks like it is necessary for the north fold (in certain circumstances). Don't know why.
466      CALL lbc_lnk( emp, 'T', 1. )
467      !
468      IF( kt == nit000 ) THEN                          !   set the forcing field at nit000 - 1    !
469         !                                             ! ---------------------------------------- !
470         IF( ln_rstart .AND.    &                               !* Restart: read in restart file
471            & iom_varid( numror, 'utau_b', ldstop = .FALSE. ) > 0 ) THEN
472            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields red in the restart file'
473            CALL iom_get( numror, jpdom_autoglo, 'utau_b', utau_b, ldxios = lrxios )   ! before i-stress  (U-point)
474            CALL iom_get( numror, jpdom_autoglo, 'vtau_b', vtau_b, ldxios = lrxios )   ! before j-stress  (V-point)
475            CALL iom_get( numror, jpdom_autoglo, 'qns_b' , qns_b, ldxios = lrxios  )   ! before non solar heat flux (T-point)
476            ! The 3D heat content due to qsr forcing is treated in traqsr
477            ! CALL iom_get( numror, jpdom_autoglo, 'qsr_b' , qsr_b, ldxios = lrxios  ) ! before     solar heat flux (T-point)
478            CALL iom_get( numror, jpdom_autoglo, 'emp_b', emp_b, ldxios = lrxios  )    ! before     freshwater flux (T-point)
479            ! To ensure restart capability with 3.3x/3.4 restart files    !! to be removed in v3.6
480            IF( iom_varid( numror, 'sfx_b', ldstop = .FALSE. ) > 0 ) THEN
481               CALL iom_get( numror, jpdom_autoglo, 'sfx_b', sfx_b, ldxios = lrxios )  ! before salt flux (T-point)
482            ELSE
483               sfx_b (:,:) = sfx(:,:)
484            ENDIF
485         ELSE                                                   !* no restart: set from nit000 values
486            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields set to nit000'
487            utau_b(:,:) = utau(:,:)
488            vtau_b(:,:) = vtau(:,:)
489            qns_b (:,:) = qns (:,:)
490            emp_b (:,:) = emp (:,:)
491            sfx_b (:,:) = sfx (:,:)
492         ENDIF
493      ENDIF
494      !                                                ! ---------------------------------------- !
495      IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
496         !                                             ! ---------------------------------------- !
497         IF(lwp) WRITE(numout,*)
498         IF(lwp) WRITE(numout,*) 'sbc : ocean surface forcing fields written in ocean restart file ',   &
499            &                    'at it= ', kt,' date= ', ndastp
500         IF(lwp) WRITE(numout,*) '~~~~'
501         IF( lwxios ) CALL iom_swap(      cwxios_context          )
502         CALL iom_rstput( kt, nitrst, numrow, 'utau_b' , utau, ldxios = lwxios )
503         CALL iom_rstput( kt, nitrst, numrow, 'vtau_b' , vtau, ldxios = lwxios )
504         CALL iom_rstput( kt, nitrst, numrow, 'qns_b'  , qns, ldxios = lwxios  )
505         ! The 3D heat content due to qsr forcing is treated in traqsr
506         ! CALL iom_rstput( kt, nitrst, numrow, 'qsr_b'  , qsr  )
507         CALL iom_rstput( kt, nitrst, numrow, 'emp_b'  , emp, ldxios = lwxios  )
508         CALL iom_rstput( kt, nitrst, numrow, 'sfx_b'  , sfx, ldxios = lwxios  )
509         IF( lwxios ) CALL iom_swap(      cxios_context          )
510      ENDIF
511      !                                                ! ---------------------------------------- !
512      !                                                !        Outputs and control print         !
513      !                                                ! ---------------------------------------- !
514      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
515         CALL iom_put( "empmr"  , emp    - rnf )                ! upward water flux
516         CALL iom_put( "empbmr" , emp_b  - rnf )                ! before upward water flux ( needed to recalculate the time evolution of ssh in offline )
517         CALL iom_put( "saltflx", sfx  )                        ! downward salt flux (includes virtual salt flux beneath ice in linear free surface case)
518         CALL iom_put( "fmmflx", fmmflx  )                      ! Freezing-melting water flux
519         CALL iom_put( "qt"    , qns  + qsr )                   ! total heat flux
520         CALL iom_put( "qns"   , qns        )                   ! solar heat flux
521         CALL iom_put( "qsr"   ,       qsr  )                   ! solar heat flux
522         IF( nn_ice > 0 .OR. ll_opa )   CALL iom_put( "ice_cover", fr_i )   ! ice fraction
523         CALL iom_put( "taum"  , taum       )                   ! wind stress module
524         CALL iom_put( "wspd"  , wndm       )                   ! wind speed  module over free ocean or leads in presence of sea-ice
525      ENDIF
526      !
527      CALL iom_put( "utau", utau )   ! i-wind stress   (stress can be updated at each time step in sea-ice)
528      CALL iom_put( "vtau", vtau )   ! j-wind stress
529      !
530      IF(ln_ctl) THEN         ! print mean trends (used for debugging)
531         CALL prt_ctl(tab2d_1=fr_i              , clinfo1=' fr_i    - : ', mask1=tmask, ovlap=1 )
532         CALL prt_ctl(tab2d_1=(emp-rnf + fwfisf), clinfo1=' emp-rnf - : ', mask1=tmask, ovlap=1 )
533         CALL prt_ctl(tab2d_1=(sfx-rnf + fwfisf), clinfo1=' sfx-rnf - : ', mask1=tmask, ovlap=1 )
534         CALL prt_ctl(tab2d_1=qns              , clinfo1=' qns      - : ', mask1=tmask, ovlap=1 )
535         CALL prt_ctl(tab2d_1=qsr              , clinfo1=' qsr      - : ', mask1=tmask, ovlap=1 )
536         CALL prt_ctl(tab3d_1=tmask            , clinfo1=' tmask    - : ', mask1=tmask, ovlap=1, kdim=jpk )
537         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_tem), clinfo1=' sst      - : ', mask1=tmask, ovlap=1, kdim=1   )
538         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_sal), clinfo1=' sss      - : ', mask1=tmask, ovlap=1, kdim=1   )
539         CALL prt_ctl(tab2d_1=utau             , clinfo1=' utau     - : ', mask1=umask,                      &
540            &         tab2d_2=vtau             , clinfo2=' vtau     - : ', mask2=vmask, ovlap=1 )
541      ENDIF
542
543      IF( kt == nitend )   CALL sbc_final         ! Close down surface module if necessary
544      !
545      IF( nn_timing == 1 )  CALL timing_stop('sbc')
546      !
547   END SUBROUTINE sbc
548
549
550   SUBROUTINE sbc_final
551      !!---------------------------------------------------------------------
552      !!                    ***  ROUTINE sbc_final  ***
553      !!
554      !! ** Purpose :   Finalize CICE (if used)
555      !!---------------------------------------------------------------------
556      !
557      IF( nn_ice == 4 )   CALL cice_sbc_final
558      !
559   END SUBROUTINE sbc_final
560
561   !!======================================================================
562END MODULE sbcmod
Note: See TracBrowser for help on using the repository browser.