source: branches/2017/dev_merge_2017/NEMOGCM/NEMO/OFF_SRC/nemogcm.F90 @ 9544

Last change on this file since 9544 was 9544, checked in by cetlod, 3 years ago

No need to initialize solar penetration for Offline since qsr is read in file

  • Property svn:keywords set to Id
File size: 23.9 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Off-line Ocean   : passive tracer evolution, dynamics read in files
5   !!======================================================================
6   !! History :  3.3  ! 2010-05  (C. Ethe)  Full reorganization of the off-line: phasing with the on-line
7   !!            3.4  ! 2011-01  (C. Ethe, A. R. Porter, STFC Daresbury) dynamical allocation
8   !!            4.0  ! 2016-10  (C. Ethe, G. Madec, S. Flavoni)  domain configuration / user defined interface
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   nemo_gcm      : off-line: solve ocean tracer only
13   !!   nemo_gcm      : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
14   !!   nemo_init     : initialization of the NEMO system
15   !!   nemo_ctl      : initialisation of the contol print
16   !!   nemo_closefile: close remaining open files
17   !!   nemo_alloc    : dynamical allocation
18   !!   istate_init   : simple initialization to zero of ocean fields
19   !!   stp_ctl       : reduced step control (no dynamics in off-line)
20   !!----------------------------------------------------------------------
21   USE dom_oce        ! ocean space domain variables
22   USE oce            ! dynamics and tracers variables
23   USE trc_oce        ! Shared ocean/passive tracers variables
24   USE c1d            ! 1D configuration
25   USE domain         ! domain initialization from coordinate & bathymetry (dom_init routine)
26   USE closea         ! treatment of closed seas (for ln_closea)
27   USE usrdef_nam     ! user defined configuration
28   USE eosbn2         ! equation of state            (eos bn2 routine)
29   !              ! ocean physics
30   USE ldftra         ! lateral diffusivity setting    (ldf_tra_init routine)
31   USE ldfslp         ! slopes of neutral surfaces     (ldf_slp_init routine)
32   USE trabbl         ! bottom boundary layer          (tra_bbl_init routine)
33   USE traldf         ! lateral physics                (tra_ldf_init routine)
34   USE sbcmod         ! surface boundary condition     (sbc_init     routine)
35   USE phycst         ! physical constant                   (par_cst routine)
36   USE dtadyn         ! Lecture and Interpolation of the dynamical fields
37   USE trcini         ! Initilization of the passive tracers
38   USE daymod         ! calendar                            (day     routine)
39   USE trcstp         ! passive tracer time-stepping        (trc_stp routine)
40   USE dtadyn         ! Lecture and interpolation of the dynamical fields
41   !              ! Passive tracers needs
42   USE trc            ! passive tracer : variables
43   USE trcnam         ! passive tracer : namelist
44   USE trcrst         ! passive tracer restart
45   USE diaptr         ! Need to initialise this as some variables are used in if statements later
46   USE sbc_oce , ONLY : ln_rnf
47   USE sbcrnf         ! surface boundary condition : runoffs
48   !              ! I/O & MPP
49   USE iom            ! I/O library
50   USE in_out_manager ! I/O manager
51   USE mppini         ! shared/distributed memory setting (mpp_init routine)
52   USE lib_mpp        ! distributed memory computing
53#if defined key_iomput
54   USE xios           ! xIOserver
55#endif
56   USE prtctl         ! Print control                    (prt_ctl_init routine)
57   USE timing         ! Timing
58   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
59   USE lbcnfd  , ONLY : isendto, nsndto, nfsloop, nfeloop   ! Setup of north fold exchanges
60
61   IMPLICIT NONE
62   PRIVATE
63   
64   PUBLIC   nemo_gcm   ! called by nemo.F90
65
66   CHARACTER (len=64) ::   cform_aaa="( /, 'AAAAAAAA', / ) "   ! flag for output listing
67
68   !!----------------------------------------------------------------------
69   !! NEMO/OFF 4.0 , NEMO Consortium (2018)
70   !! $Id$
71   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
72   !!----------------------------------------------------------------------
73CONTAINS
74
75   SUBROUTINE nemo_gcm
76      !!----------------------------------------------------------------------
77      !!                     ***  ROUTINE nemo_gcm  ***
78      !!
79      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
80      !!              curvilinear mesh on the sphere.
81      !!
82      !! ** Method  : - model general initialization
83      !!              - launch the time-stepping (dta_dyn and trc_stp)
84      !!              - finalize the run by closing files and communications
85      !!
86      !! References : Madec, Delecluse,Imbard, and Levy, 1997:  internal report, IPSL.
87      !!              Madec, 2008, internal report, IPSL.
88      !!----------------------------------------------------------------------
89      INTEGER :: istp, indic       ! time step index
90      !!----------------------------------------------------------------------
91
92      CALL nemo_init  ! Initializations
93
94      ! check that all process are still there... If some process have an error,
95      ! they will never enter in step and other processes will wait until the end of the cpu time!
96      IF( lk_mpp )   CALL mpp_max( nstop )
97
98      !                            !-----------------------!
99      !                            !==   time stepping   ==!
100      !                            !-----------------------!
101      istp = nit000
102      !
103      IF( ln_rnf )   CALL sbc_rnf(istp)   ! runoffs initialization
104      !
105      CALL iom_init( cxios_context )      ! iom_put initialization (must be done after nemo_init for AGRIF+XIOS+OASIS)
106      !
107      DO WHILE ( istp <= nitend .AND. nstop == 0 )    !==  OFF time-stepping  ==!
108         !
109         IF( istp /= nit000 )   CALL day        ( istp )         ! Calendar (day was already called at nit000 in day_init)
110                                CALL iom_setkt  ( istp - nit000 + 1, cxios_context )   ! say to iom that we are at time step kstp
111                                CALL dta_dyn    ( istp )         ! Interpolation of the dynamical fields
112         IF( .NOT.ln_linssh )   CALL dta_dyn_swp( istp )         ! swap of sea  surface height and vertical scale factors
113
114                                CALL trc_stp    ( istp )         ! time-stepping
115                                CALL stp_ctl    ( istp, indic )  ! Time loop: control and print
116         istp = istp + 1
117      END DO
118      !
119#if defined key_iomput
120      CALL iom_context_finalize( cxios_context ) ! needed for XIOS+AGRIF
121#endif
122
123      !                            !------------------------!
124      !                            !==  finalize the run  ==!
125      !                            !------------------------!
126      IF(lwp) WRITE(numout,cform_aaa)                 ! Flag AAAAAAA
127
128      IF( nstop /= 0 .AND. lwp ) THEN                 ! error print
129         WRITE(numout,cform_err)
130         WRITE(numout,*) '   ==>>>   nemo_gcm: a total of ', nstop, ' errors have been found'
131         WRITE(numout,*)
132      ENDIF
133      !
134      IF( ln_timing )   CALL timing_finalize
135      !
136      CALL nemo_closefile
137      !
138#if defined key_iomput
139                     CALL xios_finalize   ! end mpp communications with xios
140#else
141      IF( lk_mpp )   CALL mppstop         ! end mpp communications
142#endif
143      !
144   END SUBROUTINE nemo_gcm
145
146
147   SUBROUTINE nemo_init
148      !!----------------------------------------------------------------------
149      !!                     ***  ROUTINE nemo_init  ***
150      !!
151      !! ** Purpose :   initialization of the nemo model in off-line mode
152      !!----------------------------------------------------------------------
153      INTEGER  ::   ji                 ! dummy loop indices
154      INTEGER  ::   ios, ilocal_comm   ! local integers
155      CHARACTER(len=120), DIMENSION(30) ::   cltxt, cltxt2, clnam
156      !!
157      NAMELIST/namctl/ ln_ctl   , nn_print, nn_ictls, nn_ictle,   &
158         &             nn_isplt , nn_jsplt, nn_jctls, nn_jctle,   &
159         &             ln_timing, ln_diacfl
160      NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
161      !!----------------------------------------------------------------------
162      !
163      cltxt  = ''
164      cltxt2 = ''
165      clnam  = '' 
166      cxios_context = 'nemo'
167      !
168      !                             ! Open reference namelist and configuration namelist files
169      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
170      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
171      !
172      REWIND( numnam_ref )              ! Namelist namctl in reference namelist
173      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
174901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
175      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist
176      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
177902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
178      !
179      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist
180      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
181903   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
182      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist
183      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
184904   IF( ios >  0 )   CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
185
186      !                             !--------------------------!
187      !                             !  Set global domain size  !   (control print return in cltxt2)
188      !                             !--------------------------!
189      IF( ln_read_cfg ) THEN              ! Read sizes in domain configuration file
190         CALL domain_cfg ( cltxt2,        cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
191         !
192      ELSE                                ! user-defined namelist
193         CALL usr_def_nam( cltxt2, clnam, cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
194      ENDIF
195      !
196      l_offline = .true.                  ! passive tracers are run offline
197      !
198      !                             !--------------------------------------------!
199      !                             !  set communicator & select the local node  !
200      !                             !  NB: mynode also opens output.namelist.dyn !
201      !                             !      on unit number numond on first proc   !
202      !                             !--------------------------------------------!
203#if defined key_iomput
204      CALL  xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm )
205      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )   ! Nodes selection
206#else
207      ilocal_comm = 0
208      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )                ! Nodes selection (control print return in cltxt)
209#endif
210
211      narea = narea + 1                       ! mynode return the rank of proc (0 --> jpnij -1 )
212
213      lwm = (narea == 1)                      ! control of output namelists
214      lwp = (narea == 1) .OR. ln_ctl          ! control of all listing output print
215
216      IF(lwm) THEN               ! write merged namelists from earlier to output namelist
217         !                       ! now that the file has been opened in call to mynode.
218         !                       ! NB: nammpp has already been written in mynode (if lk_mpp_mpi)
219         WRITE( numond, namctl )
220         WRITE( numond, namcfg )
221         IF( .NOT.ln_read_cfg ) THEN
222            DO ji = 1, SIZE(clnam)
223               IF( TRIM(clnam(ji)) /= '' )   WRITE(numond, * ) clnam(ji)     ! namusr_def print
224            END DO
225         ENDIF
226      ENDIF
227
228      IF(lwp) THEN                            ! open listing units
229         !
230         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
231         !
232         WRITE(numout,*)
233         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
234         WRITE(numout,*) '                       NEMO team'
235         WRITE(numout,*) '                   Off-line TOP Model'
236         WRITE(numout,*) '                NEMO version 4.0  (2017) '
237         WRITE(numout,*)
238         WRITE(numout,*)
239         DO ji = 1, SIZE(cltxt)
240            IF( TRIM(cltxt (ji)) /= '' )   WRITE(numout,*) cltxt(ji)    ! control print of mynode
241         END DO
242         WRITE(numout,*)
243         WRITE(numout,*)
244         DO ji = 1, SIZE(cltxt2)
245            IF( TRIM(cltxt2(ji)) /= '' )   WRITE(numout,*) cltxt2(ji)   ! control print of domain size
246         END DO
247         !
248         WRITE(numout,cform_aaa)                                        ! Flag AAAAAAA
249         !
250      ENDIF
251      !                                      ! Domain decomposition
252      CALL mpp_init                          ! MPP
253
254      ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
255      CALL nemo_alloc()
256
257      !                             !-------------------------------!
258      !                             !  NEMO general initialization  !
259      !                             !-------------------------------!
260
261      CALL nemo_ctl                          ! Control prints
262      !
263      !                                      ! General initialization
264      IF( ln_timing    )   CALL timing_init
265      IF( ln_timing    )   CALL timing_start( 'nemo_init')
266      !
267                           CALL     phy_cst         ! Physical constants
268                           CALL     eos_init        ! Equation of state
269      IF( lk_c1d       )   CALL     c1d_init        ! 1D column configuration
270                           CALL     dom_init("OPA") ! Domain
271      IF( ln_ctl       )   CALL prt_ctl_init        ! Print control
272
273                           CALL  istate_init    ! ocean initial state (Dynamics and tracers)
274
275                           CALL     sbc_init    ! Forcings : surface module
276
277      !                                      ! Tracer physics
278                           CALL ldf_tra_init    ! Lateral ocean tracer physics
279                           CALL ldf_eiv_init    ! Eddy induced velocity param
280                           CALL tra_ldf_init    ! lateral mixing
281      IF( l_ldfslp     )   CALL ldf_slp_init    ! slope of lateral mixing
282      IF( ln_trabbl    )   CALL tra_bbl_init    ! advective (and/or diffusive) bottom boundary layer scheme
283
284      !                                      ! Passive tracers
285                           CALL trc_nam_run    ! Needed to get restart parameters for passive tracers
286                           CALL trc_rst_cal( nit000, 'READ' )   ! calendar
287                           CALL dta_dyn_init   ! Initialization for the dynamics
288
289                           CALL     trc_init   ! Passive tracers initialization
290                           CALL dia_ptr_init   ! Poleward TRansports initialization
291                           
292      IF(lwp) WRITE(numout,cform_aaa)           ! Flag AAAAAAA
293      !
294      IF( ln_timing    )   CALL timing_stop( 'nemo_init')
295      !
296   END SUBROUTINE nemo_init
297
298
299   SUBROUTINE nemo_ctl
300      !!----------------------------------------------------------------------
301      !!                     ***  ROUTINE nemo_ctl  ***
302      !!
303      !! ** Purpose :   control print setting
304      !!
305      !! ** Method  : - print namctl information and check some consistencies
306      !!----------------------------------------------------------------------
307      !
308      IF(lwp) THEN                  ! control print
309         WRITE(numout,*)
310         WRITE(numout,*) 'nemo_ctl: Control prints'
311         WRITE(numout,*) '~~~~~~~~'
312         WRITE(numout,*) '   Namelist namctl'
313         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
314         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
315         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
316         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
317         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
318         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
319         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
320         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
321         WRITE(numout,*) '      timing by routine               ln_timing  = ', ln_timing
322         WRITE(numout,*) '      CFL diagnostics                 ln_diacfl  = ', ln_diacfl
323      ENDIF
324      !
325      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
326      nictls    = nn_ictls
327      nictle    = nn_ictle
328      njctls    = nn_jctls
329      njctle    = nn_jctle
330      isplt     = nn_isplt
331      jsplt     = nn_jsplt
332
333      IF(lwp) THEN                  ! control print
334         WRITE(numout,*)
335         WRITE(numout,*) '   Namelist namcfg'
336         WRITE(numout,*) '      read domain configuration file              ln_read_cfg      = ', ln_read_cfg
337         WRITE(numout,*) '         filename to be read                         cn_domcfg     = ', TRIM(cn_domcfg)
338         WRITE(numout,*) '         keep closed seas in the domain (if exist)   ln_closea     = ', ln_closea
339         WRITE(numout,*) '      create a configuration definition file      ln_write_cfg     = ', ln_write_cfg
340         WRITE(numout,*) '         filename to be written                      cn_domcfg_out = ', TRIM(cn_domcfg_out)
341         WRITE(numout,*) '      use file attribute if exists as i/p j-start ln_use_jattr     = ', ln_use_jattr
342      ENDIF
343      IF( .NOT.ln_read_cfg )   ln_closea = .false.   ! dealing possible only with a domcfg file
344      !
345      !                             ! Parameter control
346      !
347      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
348         IF( lk_mpp .AND. jpnij > 1 ) THEN
349            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
350         ELSE
351            IF( isplt == 1 .AND. jsplt == 1  ) THEN
352               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
353                  &           ' - the print control will be done over the whole domain' )
354            ENDIF
355            ijsplt = isplt * jsplt            ! total number of processors ijsplt
356         ENDIF
357         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
358         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
359         !
360         !                              ! indices used for the SUM control
361         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
362            lsp_area = .FALSE.
363         ELSE                                             ! print control done over a specific  area
364            lsp_area = .TRUE.
365            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
366               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
367               nictls = 1
368            ENDIF
369            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
370               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
371               nictle = jpiglo
372            ENDIF
373            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
374               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
375               njctls = 1
376            ENDIF
377            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
378               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
379               njctle = jpjglo
380            ENDIF
381         ENDIF
382      ENDIF
383      !
384      IF( 1._wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.',  &
385         &                                                'Compile with key_nosignedzero enabled' )
386      !
387   END SUBROUTINE nemo_ctl
388
389
390   SUBROUTINE nemo_closefile
391      !!----------------------------------------------------------------------
392      !!                     ***  ROUTINE nemo_closefile  ***
393      !!
394      !! ** Purpose :   Close the files
395      !!----------------------------------------------------------------------
396      !
397      IF( lk_mpp )   CALL mppsync
398      !
399      CALL iom_close                                 ! close all input/output files managed by iom_*
400      !
401      IF( numstp     /= -1 )   CLOSE( numstp     )   ! time-step file
402      IF( numnam_ref /= -1 )   CLOSE( numnam_ref )   ! oce reference namelist
403      IF( numnam_cfg /= -1 )   CLOSE( numnam_cfg )   ! oce configuration namelist
404      IF( numout     /=  6 )   CLOSE( numout     )   ! standard model output file
405      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
406      !
407      numout = 6                                     ! redefine numout in case it is used after this point...
408      !
409   END SUBROUTINE nemo_closefile
410
411
412   SUBROUTINE nemo_alloc
413      !!----------------------------------------------------------------------
414      !!                     ***  ROUTINE nemo_alloc  ***
415      !!
416      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
417      !!
418      !! ** Method  :
419      !!----------------------------------------------------------------------
420      USE diawri ,   ONLY : dia_wri_alloc
421      USE dom_oce,   ONLY : dom_oce_alloc
422      USE zdf_oce,   ONLY : zdf_oce_alloc
423      USE trc_oce,   ONLY : trc_oce_alloc
424      !
425      INTEGER :: ierr
426      !!----------------------------------------------------------------------
427      !
428      ierr =        oce_alloc    ()          ! ocean
429      ierr = ierr + dia_wri_alloc()
430      ierr = ierr + dom_oce_alloc()          ! ocean domain
431      ierr = ierr + zdf_oce_alloc()          ! ocean vertical physics
432      ierr = ierr + trc_oce_alloc()          ! shared TRC / TRA arrays
433      !
434      IF( lk_mpp    )   CALL mpp_sum( ierr )
435      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
436      !
437   END SUBROUTINE nemo_alloc
438
439   SUBROUTINE istate_init
440      !!----------------------------------------------------------------------
441      !!                   ***  ROUTINE istate_init  ***
442      !!
443      !! ** Purpose :   Initialization to zero of the dynamics and tracers.
444      !!----------------------------------------------------------------------
445      !
446      !     now fields         !     after fields      !
447      un   (:,:,:)   = 0._wp   ;   ua(:,:,:) = 0._wp   !
448      vn   (:,:,:)   = 0._wp   ;   va(:,:,:) = 0._wp   !
449      wn   (:,:,:)   = 0._wp   !                       !
450      hdivn(:,:,:)   = 0._wp   !                       !
451      tsn  (:,:,:,:) = 0._wp   !                       !
452      !
453      rhd  (:,:,:) = 0.e0
454      rhop (:,:,:) = 0.e0
455      rn2  (:,:,:) = 0.e0
456      !
457   END SUBROUTINE istate_init
458
459
460   SUBROUTINE stp_ctl( kt, kindic )
461      !!----------------------------------------------------------------------
462      !!                    ***  ROUTINE stp_ctl  ***
463      !!
464      !! ** Purpose :   Control the run
465      !!
466      !! ** Method  : - Save the time step in numstp
467      !!
468      !! ** Actions :   'time.step' file containing the last ocean time-step
469      !!----------------------------------------------------------------------
470      INTEGER, INTENT(in   ) ::   kt      ! ocean time-step index
471      INTEGER, INTENT(inout) ::   kindic  ! indicator of solver convergence
472      !!----------------------------------------------------------------------
473      !
474      IF( kt == nit000 .AND. lwp ) THEN
475         WRITE(numout,*)
476         WRITE(numout,*) 'stp_ctl : time-stepping control'
477         WRITE(numout,*) '~~~~~~~'
478         ! open time.step file
479         CALL ctl_opn( numstp, 'time.step', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
480      ENDIF
481      !
482      IF(lwp) WRITE ( numstp, '(1x, i8)' )   kt      !* save the current time step in numstp
483      IF(lwp) REWIND( numstp )                       ! --------------------------
484      !
485   END SUBROUTINE stp_ctl
486   !!======================================================================
487END MODULE nemogcm
Note: See TracBrowser for help on using the repository browser.