New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynhpg.F90 in branches/2017/dev_merge_2017/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/2017/dev_merge_2017/NEMOGCM/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 9023

Last change on this file since 9023 was 9023, checked in by timgraham, 7 years ago

Merged METO_MERCATOR branch and resolved all conflicts in OPA_SRC
  • Property svn:keywords set to Id
File size: 71.6 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  OPA  !  1987-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  1991-11  (G. Madec)
8   !!            7.0  !  1996-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  1997-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  2002-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  2002-08  (A. Bozec)  hpg_zps: Original code
12   !!   NEMO     1.0  !  2005-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                 !         Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!             -   !  2005-11  (G. Madec) style & small optimisation
15   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
16   !!            3.4  !  2011-11  (H. Liu) hpg_prj: Original code for s-coordinates
17   !!                 !           (A. Coward) suppression of hel, wdj and rot options
18   !!            3.6  !  2014-11  (P. Mathiot) hpg_isf: original code for ice shelf cavity
19   !!----------------------------------------------------------------------
20
21   !!----------------------------------------------------------------------
22   !!   dyn_hpg      : update the momentum trend with the now horizontal
23   !!                  gradient of the hydrostatic pressure
24   !!   dyn_hpg_init : initialisation and control of options
25   !!       hpg_zco  : z-coordinate scheme
26   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
27   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
28   !!       hpg_isf  : s-coordinate (sco formulation) adapted to ice shelf
29   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
30   !!       hpg_prj  : s-coordinate (Pressure Jacobian with Cubic polynomial)
31   !!----------------------------------------------------------------------
32   USE oce             ! ocean dynamics and tracers
33   USE sbc_oce         ! surface variable (only for the flag with ice shelf)
34   USE dom_oce         ! ocean space and time domain
35   USE wet_dry         ! wetting and drying
36   USE phycst          ! physical constants
37   USE trd_oce         ! trends: ocean variables
38   USE trddyn          ! trend manager: dynamics
39!jc   USE zpshde          ! partial step: hor. derivative     (zps_hde routine)
40   !
41   USE in_out_manager  ! I/O manager
42   USE prtctl          ! Print control
43   USE lbclnk          ! lateral boundary condition
44   USE lib_mpp         ! MPP library
45   USE eosbn2          ! compute density
46   USE timing          ! Timing
47   USE iom
48
49   IMPLICIT NONE
50   PRIVATE
51
52   PUBLIC   dyn_hpg        ! routine called by step module
53   PUBLIC   dyn_hpg_init   ! routine called by opa module
54
55   !                                 !!* Namelist namdyn_hpg : hydrostatic pressure gradient
56   LOGICAL , PUBLIC ::   ln_hpg_zco   !: z-coordinate - full steps
57   LOGICAL , PUBLIC ::   ln_hpg_zps   !: z-coordinate - partial steps (interpolation)
58   LOGICAL , PUBLIC ::   ln_hpg_sco   !: s-coordinate (standard jacobian formulation)
59   LOGICAL , PUBLIC ::   ln_hpg_djc   !: s-coordinate (Density Jacobian with Cubic polynomial)
60   LOGICAL , PUBLIC ::   ln_hpg_prj   !: s-coordinate (Pressure Jacobian scheme)
61   LOGICAL , PUBLIC ::   ln_hpg_isf   !: s-coordinate similar to sco modify for isf
62
63   INTEGER , PUBLIC ::   nhpg  =  0   ! = 0 to 7, type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
64
65   !! * Substitutions
66#  include "vectopt_loop_substitute.h90"
67   !!----------------------------------------------------------------------
68   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
69   !! $Id$
70   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
71   !!----------------------------------------------------------------------
72CONTAINS
73
74   SUBROUTINE dyn_hpg( kt )
75      !!---------------------------------------------------------------------
76      !!                  ***  ROUTINE dyn_hpg  ***
77      !!
78      !! ** Method  :   Call the hydrostatic pressure gradient routine
79      !!              using the scheme defined in the namelist
80      !!
81      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
82      !!             - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
83      !!----------------------------------------------------------------------
84      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
85      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   ztrdu, ztrdv
86      !!----------------------------------------------------------------------
87      !
88      IF( ln_timing )   CALL timing_start('dyn_hpg')
89      !
90      IF( l_trddyn ) THEN                    ! Temporary saving of ua and va trends (l_trddyn)
91         ALLOCATE( ztrdu(jpi,jpj,jpk) , ztrdv(jpi,jpj,jpk) )
92         ztrdu(:,:,:) = ua(:,:,:)
93         ztrdv(:,:,:) = va(:,:,:)
94      ENDIF
95      !
96      SELECT CASE ( nhpg )      ! Hydrostatic pressure gradient computation
97      CASE (  0 )   ;   CALL hpg_zco    ( kt )      ! z-coordinate
98      CASE (  1 )   ;   CALL hpg_zps    ( kt )      ! z-coordinate plus partial steps (interpolation)
99      CASE (  2 )   ;   CALL hpg_sco    ( kt )      ! s-coordinate (standard jacobian formulation)
100      CASE (  3 )   ;   CALL hpg_djc    ( kt )      ! s-coordinate (Density Jacobian with Cubic polynomial)
101      CASE (  4 )   ;   CALL hpg_prj    ( kt )      ! s-coordinate (Pressure Jacobian scheme)
102      CASE (  5 )   ;   CALL hpg_isf    ( kt )      ! s-coordinate similar to sco modify for ice shelf
103      END SELECT
104      !
105      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
106         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
107         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
108         CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt )
109         DEALLOCATE( ztrdu , ztrdv )
110      ENDIF
111      !
112      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg  - Ua: ', mask1=umask,   &
113         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
114      !
115      IF( ln_timing )   CALL timing_stop('dyn_hpg')
116      !
117   END SUBROUTINE dyn_hpg
118
119
120   SUBROUTINE dyn_hpg_init
121      !!----------------------------------------------------------------------
122      !!                 ***  ROUTINE dyn_hpg_init  ***
123      !!
124      !! ** Purpose :   initializations for the hydrostatic pressure gradient
125      !!              computation and consistency control
126      !!
127      !! ** Action  :   Read the namelist namdyn_hpg and check the consistency
128      !!      with the type of vertical coordinate used (zco, zps, sco)
129      !!----------------------------------------------------------------------
130      INTEGER ::   ioptio = 0      ! temporary integer
131      INTEGER ::   ios             ! Local integer output status for namelist read
132      !!
133      INTEGER  ::   ji, jj, jk, ikt    ! dummy loop indices      ISF
134      REAL(wp) ::   znad
135      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::  zts_top, zrhd   ! hypothesys on isf density
136      REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::  zrhdtop_isf    ! density at bottom of ISF
137      REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::  ziceload       ! density at bottom of ISF
138      !!
139      NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco,     &
140         &                 ln_hpg_djc, ln_hpg_prj, ln_hpg_isf
141      !!----------------------------------------------------------------------
142      !
143      REWIND( numnam_ref )              ! Namelist namdyn_hpg in reference namelist : Hydrostatic pressure gradient
144      READ  ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
145901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist', lwp )
146      !
147      REWIND( numnam_cfg )              ! Namelist namdyn_hpg in configuration namelist : Hydrostatic pressure gradient
148      READ  ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
149902   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist', lwp )
150      IF(lwm) WRITE ( numond, namdyn_hpg )
151      !
152      IF(lwp) THEN                   ! Control print
153         WRITE(numout,*)
154         WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
155         WRITE(numout,*) '~~~~~~~~~~~~'
156         WRITE(numout,*) '   Namelist namdyn_hpg : choice of hpg scheme'
157         WRITE(numout,*) '      z-coord. - full steps                             ln_hpg_zco    = ', ln_hpg_zco
158         WRITE(numout,*) '      z-coord. - partial steps (interpolation)          ln_hpg_zps    = ', ln_hpg_zps
159         WRITE(numout,*) '      s-coord. (standard jacobian formulation)          ln_hpg_sco    = ', ln_hpg_sco
160         WRITE(numout,*) '      s-coord. (standard jacobian formulation) for isf  ln_hpg_isf    = ', ln_hpg_isf
161         WRITE(numout,*) '      s-coord. (Density Jacobian: Cubic polynomial)     ln_hpg_djc    = ', ln_hpg_djc
162         WRITE(numout,*) '      s-coord. (Pressure Jacobian: Cubic polynomial)    ln_hpg_prj    = ', ln_hpg_prj
163      ENDIF
164      !
165      IF( ln_hpg_djc )   &
166         &   CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method',   &
167         &                 '   currently disabled (bugs under investigation).'        ,   &
168         &                 '   Please select either  ln_hpg_sco or  ln_hpg_prj instead' )
169         !
170      IF( .NOT.ln_linssh .AND. .NOT.(ln_hpg_sco.OR.ln_hpg_prj.OR.ln_hpg_isf) )          &
171         &   CALL ctl_stop('dyn_hpg_init : non-linear free surface requires either ',   &
172         &                 '   the standard jacobian formulation hpg_sco    or '    ,   &
173         &                 '   the pressure jacobian formulation hpg_prj'             )
174         !
175      IF( ln_hpg_isf ) THEN
176         IF( .NOT. ln_isfcav )   CALL ctl_stop( ' hpg_isf not available if ln_isfcav = false ' )
177       ELSE
178         IF(       ln_isfcav )   CALL ctl_stop( 'Only hpg_isf has been corrected to work with ice shelf cavity.' )
179      ENDIF
180      !
181      !                               ! Set nhpg from ln_hpg_... flags
182      IF( ln_hpg_zco )   nhpg = 0
183      IF( ln_hpg_zps )   nhpg = 1
184      IF( ln_hpg_sco )   nhpg = 2
185      IF( ln_hpg_djc )   nhpg = 3
186      IF( ln_hpg_prj )   nhpg = 4
187      IF( ln_hpg_isf )   nhpg = 5
188      !
189      !                               ! Consistency check
190      ioptio = 0
191      IF( ln_hpg_zco )   ioptio = ioptio + 1
192      IF( ln_hpg_zps )   ioptio = ioptio + 1
193      IF( ln_hpg_sco )   ioptio = ioptio + 1
194      IF( ln_hpg_djc )   ioptio = ioptio + 1
195      IF( ln_hpg_prj )   ioptio = ioptio + 1
196      IF( ln_hpg_isf )   ioptio = ioptio + 1
197      IF( ioptio /= 1 )   CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
198      !
199      !                         
200      IF ( .NOT. ln_isfcav ) THEN     !--- no ice shelf load
201         riceload(:,:) = 0._wp
202         !
203      ELSE                            !--- set an ice shelf load
204         !
205         IF(lwp) WRITE(numout,*)
206         IF(lwp) WRITE(numout,*) '   ice shelf case: set the ice-shelf load'
207         ALLOCATE( zts_top(jpi,jpj,jpts) , zrhd(jpi,jpj,jpk) , zrhdtop_isf(jpi,jpj) , ziceload(jpi,jpj) ) 
208         !
209         znad = 1._wp                     !- To use density and not density anomaly
210         !
211         !                                !- assume water displaced by the ice shelf is at T=-1.9 and S=34.4 (rude)
212         zts_top(:,:,jp_tem) = -1.9_wp   ;   zts_top(:,:,jp_sal) = 34.4_wp
213         !
214         DO jk = 1, jpk                   !- compute density of the water displaced by the ice shelf
215            CALL eos( zts_top(:,:,:), gdept_n(:,:,jk), zrhd(:,:,jk) )
216         END DO
217         !
218         !                                !- compute rhd at the ice/oce interface (ice shelf side)
219         CALL eos( zts_top , risfdep, zrhdtop_isf )
220         !
221         !                                !- Surface value + ice shelf gradient
222         ziceload = 0._wp                       ! compute pressure due to ice shelf load
223         DO jj = 1, jpj                         ! (used to compute hpgi/j for all the level from 1 to miku/v)
224            DO ji = 1, jpi                      ! divided by 2 later
225               ikt = mikt(ji,jj)
226               ziceload(ji,jj) = ziceload(ji,jj) + (znad + zrhd(ji,jj,1) ) * e3w_n(ji,jj,1) * (1._wp - tmask(ji,jj,1))
227               DO jk = 2, ikt-1
228                  ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhd(ji,jj,jk-1) + zrhd(ji,jj,jk)) * e3w_n(ji,jj,jk) &
229                     &                              * (1._wp - tmask(ji,jj,jk))
230               END DO
231               IF (ikt  >=  2) ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhdtop_isf(ji,jj) + zrhd(ji,jj,ikt-1)) &
232                  &                                              * ( risfdep(ji,jj) - gdept_1d(ikt-1) )
233            END DO
234         END DO
235         riceload(:,:) = ziceload(:,:)  ! need to be saved for diaar5
236         !
237         DEALLOCATE( zts_top , zrhd , zrhdtop_isf , ziceload ) 
238      ENDIF
239      !
240   END SUBROUTINE dyn_hpg_init
241
242
243   SUBROUTINE hpg_zco( kt )
244      !!---------------------------------------------------------------------
245      !!                  ***  ROUTINE hpg_zco  ***
246      !!
247      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
248      !!      The now hydrostatic pressure gradient at a given level, jk,
249      !!      is computed by taking the vertical integral of the in-situ
250      !!      density gradient along the model level from the suface to that
251      !!      level:    zhpi = grav .....
252      !!                zhpj = grav .....
253      !!      add it to the general momentum trend (ua,va).
254      !!            ua = ua - 1/e1u * zhpi
255      !!            va = va - 1/e2v * zhpj
256      !!
257      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
258      !!----------------------------------------------------------------------
259      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
260      !
261      INTEGER  ::   ji, jj, jk       ! dummy loop indices
262      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
263      REAL(wp), DIMENSION(jpi,jpj,jpk) ::  zhpi, zhpj
264      !!----------------------------------------------------------------------
265      !
266      IF( kt == nit000 ) THEN
267         IF(lwp) WRITE(numout,*)
268         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
269         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
270      ENDIF
271
272      zcoef0 = - grav * 0.5_wp      ! Local constant initialization
273
274      ! Surface value
275      DO jj = 2, jpjm1
276         DO ji = fs_2, fs_jpim1   ! vector opt.
277            zcoef1 = zcoef0 * e3w_n(ji,jj,1)
278            ! hydrostatic pressure gradient
279            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
280            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
281            ! add to the general momentum trend
282            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
283            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
284         END DO
285      END DO
286
287      !
288      ! interior value (2=<jk=<jpkm1)
289      DO jk = 2, jpkm1
290         DO jj = 2, jpjm1
291            DO ji = fs_2, fs_jpim1   ! vector opt.
292               zcoef1 = zcoef0 * e3w_n(ji,jj,jk)
293               ! hydrostatic pressure gradient
294               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
295                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )    &
296                  &                       - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) * r1_e1u(ji,jj)
297
298               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
299                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )    &
300                  &                       - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) * r1_e2v(ji,jj)
301               ! add to the general momentum trend
302               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
303               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
304            END DO
305         END DO
306      END DO
307      !
308   END SUBROUTINE hpg_zco
309
310
311   SUBROUTINE hpg_zps( kt )
312      !!---------------------------------------------------------------------
313      !!                 ***  ROUTINE hpg_zps  ***
314      !!
315      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
316      !!
317      !! ** Action  : - Update (ua,va) with the now hydrastatic pressure trend
318      !!----------------------------------------------------------------------
319      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
320      !!
321      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
322      INTEGER  ::   iku, ikv                         ! temporary integers
323      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
324      REAL(wp), DIMENSION(jpi,jpj,jpk) ::  zhpi, zhpj
325      !!----------------------------------------------------------------------
326      !
327      IF( kt == nit000 ) THEN
328         IF(lwp) WRITE(numout,*)
329         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
330         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
331      ENDIF
332
333      ! Partial steps: bottom before horizontal gradient of t, s, rd at the last ocean level
334!jc      CALL zps_hde    ( kt, jpts, tsn, gtsu, gtsv, rhd, gru , grv )
335
336      ! Local constant initialization
337      zcoef0 = - grav * 0.5_wp
338
339      !  Surface value (also valid in partial step case)
340      DO jj = 2, jpjm1
341         DO ji = fs_2, fs_jpim1   ! vector opt.
342            zcoef1 = zcoef0 * e3w_n(ji,jj,1)
343            ! hydrostatic pressure gradient
344            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
345            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
346            ! add to the general momentum trend
347            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
348            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
349         END DO
350      END DO
351
352      ! interior value (2=<jk=<jpkm1)
353      DO jk = 2, jpkm1
354         DO jj = 2, jpjm1
355            DO ji = fs_2, fs_jpim1   ! vector opt.
356               zcoef1 = zcoef0 * e3w_n(ji,jj,jk)
357               ! hydrostatic pressure gradient
358               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
359                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
360                  &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) * r1_e1u(ji,jj)
361
362               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
363                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
364                  &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) * r1_e2v(ji,jj)
365               ! add to the general momentum trend
366               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
367               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
368            END DO
369         END DO
370      END DO
371
372      ! partial steps correction at the last level  (use gru & grv computed in zpshde.F90)
373      DO jj = 2, jpjm1
374         DO ji = 2, jpim1
375            iku = mbku(ji,jj)
376            ikv = mbkv(ji,jj)
377            zcoef2 = zcoef0 * MIN( e3w_n(ji,jj,iku), e3w_n(ji+1,jj  ,iku) )
378            zcoef3 = zcoef0 * MIN( e3w_n(ji,jj,ikv), e3w_n(ji  ,jj+1,ikv) )
379            IF( iku > 1 ) THEN            ! on i-direction (level 2 or more)
380               ua  (ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku)         ! subtract old value
381               zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1)                   &   ! compute the new one
382                  &            + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) * r1_e1u(ji,jj)
383               ua  (ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku)         ! add the new one to the general momentum trend
384            ENDIF
385            IF( ikv > 1 ) THEN            ! on j-direction (level 2 or more)
386               va  (ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv)         ! subtract old value
387               zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1)                   &   ! compute the new one
388                  &            + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) * r1_e2v(ji,jj)
389               va  (ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv)         ! add the new one to the general momentum trend
390            ENDIF
391         END DO
392      END DO
393      !
394   END SUBROUTINE hpg_zps
395
396
397   SUBROUTINE hpg_sco( kt )
398      !!---------------------------------------------------------------------
399      !!                  ***  ROUTINE hpg_sco  ***
400      !!
401      !! ** Method  :   s-coordinate case. Jacobian scheme.
402      !!      The now hydrostatic pressure gradient at a given level, jk,
403      !!      is computed by taking the vertical integral of the in-situ
404      !!      density gradient along the model level from the suface to that
405      !!      level. s-coordinates (ln_sco): a corrective term is added
406      !!      to the horizontal pressure gradient :
407      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
408      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
409      !!      add it to the general momentum trend (ua,va).
410      !!         ua = ua - 1/e1u * zhpi
411      !!         va = va - 1/e2v * zhpj
412      !!
413      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
414      !!----------------------------------------------------------------------
415      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
416      !!
417      INTEGER  ::   ji, jj, jk, jii, jjj                 ! dummy loop indices
418      REAL(wp) ::   zcoef0, zuap, zvap, znad, ztmp       ! temporary scalars
419      LOGICAL  ::   ll_tmp1, ll_tmp2                     ! local logical variables
420      REAL(wp), DIMENSION(jpi,jpj,jpk)      ::   zhpi, zhpj
421      REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   zcpx, zcpy   !W/D pressure filter
422      !!----------------------------------------------------------------------
423      !
424      IF( ln_wd_il ) CALL wrk_alloc( jpi,jpj, zcpx, zcpy )
425      !
426      IF( kt == nit000 ) THEN
427         IF(lwp) WRITE(numout,*)
428         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
429         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
430      ENDIF
431      !
432      zcoef0 = - grav * 0.5_wp
433      IF ( ln_linssh ) THEN   ;   znad = 0._wp         ! Fixed    volume: density anomaly
434      ELSE                    ;   znad = 1._wp         ! Variable volume: density
435      ENDIF
436      !
437      IF( ln_wd_il ) THEN
438        DO jj = 2, jpjm1
439           DO ji = 2, jpim1 
440             ll_tmp1 = MIN(  sshn(ji,jj)               ,  sshn(ji+1,jj) ) >                &
441                  &    MAX( -ht_0(ji,jj)               , -ht_0(ji+1,jj) ) .AND.            &
442                  &    MAX(  sshn(ji,jj) +  ht_0(ji,jj),  sshn(ji+1,jj) + ht_0(ji+1,jj) )  &
443                  &                                                       > rn_wdmin1 + rn_wdmin2
444             ll_tmp2 = ( ABS( sshn(ji,jj)              -  sshn(ji+1,jj) ) > 1.E-12 ) .AND. (       &
445                  &    MAX(   sshn(ji,jj)              ,  sshn(ji+1,jj) ) >                &
446                  &    MAX(  -ht_0(ji,jj)              , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
447
448             IF(ll_tmp1) THEN
449               zcpx(ji,jj) = 1.0_wp
450             ELSE IF(ll_tmp2) THEN
451               ! no worries about  sshn(ji+1,jj) -  sshn(ji  ,jj) = 0, it won't happen ! here
452               zcpx(ji,jj) = ABS( (sshn(ji+1,jj) + ht_0(ji+1,jj) - sshn(ji,jj) - ht_0(ji,jj)) &
453                           &    / (sshn(ji+1,jj) - sshn(ji  ,jj)) )
454             ELSE
455               zcpx(ji,jj) = 0._wp
456             END IF
457     
458             ll_tmp1 = MIN(  sshn(ji,jj)              ,  sshn(ji,jj+1) ) >                &
459                  &    MAX( -ht_0(ji,jj)              , -ht_0(ji,jj+1) ) .AND.            &
460                  &    MAX(  sshn(ji,jj) + ht_0(ji,jj),  sshn(ji,jj+1) + ht_0(ji,jj+1) )  &
461                  &                                                      > rn_wdmin1 + rn_wdmin2
462             ll_tmp2 = ( ABS( sshn(ji,jj)             -  sshn(ji,jj+1) ) > 1.E-12 ) .AND. (        &
463                  &    MAX(   sshn(ji,jj)             ,  sshn(ji,jj+1) ) >                &
464                  &    MAX(  -ht_0(ji,jj)             , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
465                  !
466               IF(ll_tmp1) THEN
467                  zcpy(ji,jj) = 1.0_wp
468               ELSE IF(ll_tmp2) THEN
469                  ! no worries about  sshn(ji,jj+1) -  sshn(ji,jj  ) = 0, it won't happen ! here
470                  zcpy(ji,jj) = ABS(   ( sshn(ji,jj+1)+ht_wd(ji,jj+1) - sshn(ji,jj) - ht_wd(ji,jj) )   &
471                     &               / ( sshn(ji,jj+1)                - sshn(ji,jj)                )   )
472               ELSE
473                  zcpy(ji,jj) = 0._wp
474               ENDIF
475            END DO
476         END DO
477         CALL lbc_lnk( zcpx, 'U', 1._wp )    ;   CALL lbc_lnk( zcpy, 'V', 1._wp )
478      ENDIF
479
480             IF(ll_tmp1) THEN
481               zcpy(ji,jj) = 1.0_wp
482             ELSE IF(ll_tmp2) THEN
483               ! no worries about  sshn(ji,jj+1) -  sshn(ji,jj  ) = 0, it won't happen ! here
484               zcpy(ji,jj) = ABS( (sshn(ji,jj+1) + ht_0(ji,jj+1) - sshn(ji,jj) - ht_0(ji,jj)) &
485                           &    / (sshn(ji,jj+1) - sshn(ji,jj  )) )
486             ELSE
487               zcpy(ji,jj) = 0._wp
488             END IF
489           END DO
490        END DO
491        CALL lbc_lnk( zcpx, 'U', 1._wp )    ;   CALL lbc_lnk( zcpy, 'V', 1._wp )
492      END IF
493
494      ! Surface value
495      DO jj = 2, jpjm1
496         DO ji = fs_2, fs_jpim1   ! vector opt.
497            ! hydrostatic pressure gradient along s-surfaces
498            zhpi(ji,jj,1) = zcoef0 * (  e3w_n(ji+1,jj  ,1) * ( znad + rhd(ji+1,jj  ,1) )    &
499               &                      - e3w_n(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) )  ) * r1_e1u(ji,jj)
500            zhpj(ji,jj,1) = zcoef0 * (  e3w_n(ji  ,jj+1,1) * ( znad + rhd(ji  ,jj+1,1) )    &
501               &                      - e3w_n(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) )  ) * r1_e2v(ji,jj)
502            ! s-coordinate pressure gradient correction
503            zuap = -zcoef0 * ( rhd    (ji+1,jj,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
504               &           * ( gde3w_n(ji+1,jj,1) - gde3w_n(ji,jj,1) ) * r1_e1u(ji,jj)
505            zvap = -zcoef0 * ( rhd    (ji,jj+1,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
506               &           * ( gde3w_n(ji,jj+1,1) - gde3w_n(ji,jj,1) ) * r1_e2v(ji,jj)
507            !
508            IF( ln_wd_il ) THEN
509               zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
510               zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj) 
511               zuap = zuap * zcpx(ji,jj)
512               zvap = zvap * zcpy(ji,jj)
513            ENDIF
514            !
515            ! add to the general momentum trend
516            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
517            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
518         END DO
519      END DO
520
521      ! interior value (2=<jk=<jpkm1)
522      DO jk = 2, jpkm1
523         DO jj = 2, jpjm1
524            DO ji = fs_2, fs_jpim1   ! vector opt.
525               ! hydrostatic pressure gradient along s-surfaces
526               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 * r1_e1u(ji,jj)   &
527                  &           * (  e3w_n(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad )   &
528                  &              - e3w_n(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad )  )
529               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 * r1_e2v(ji,jj)   &
530                  &           * (  e3w_n(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad )   &
531                  &              - e3w_n(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad )  )
532               ! s-coordinate pressure gradient correction
533               zuap = -zcoef0 * ( rhd    (ji+1,jj  ,jk) + rhd    (ji,jj,jk) + 2._wp * znad )   &
534                  &           * ( gde3w_n(ji+1,jj  ,jk) - gde3w_n(ji,jj,jk) ) * r1_e1u(ji,jj)
535               zvap = -zcoef0 * ( rhd    (ji  ,jj+1,jk) + rhd    (ji,jj,jk) + 2._wp * znad )   &
536                  &           * ( gde3w_n(ji  ,jj+1,jk) - gde3w_n(ji,jj,jk) ) * r1_e2v(ji,jj)
537               !
538               IF( ln_wd_il ) THEN
539                  zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
540                  zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj) 
541                  zuap = zuap * zcpx(ji,jj)
542                  zvap = zvap * zcpy(ji,jj)
543               ENDIF
544               !
545               ! add to the general momentum trend
546               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
547               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
548            END DO
549         END DO
550      END DO
551      !
552      IF( ln_wd_il )   DEALLOCATE( zcpx , zcpy )
553      !
554   END SUBROUTINE hpg_sco
555
556
557   SUBROUTINE hpg_isf( kt )
558      !!---------------------------------------------------------------------
559      !!                  ***  ROUTINE hpg_isf  ***
560      !!
561      !! ** Method  :   s-coordinate case. Jacobian scheme.
562      !!      The now hydrostatic pressure gradient at a given level, jk,
563      !!      is computed by taking the vertical integral of the in-situ
564      !!      density gradient along the model level from the suface to that
565      !!      level. s-coordinates (ln_sco): a corrective term is added
566      !!      to the horizontal pressure gradient :
567      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
568      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
569      !!      add it to the general momentum trend (ua,va).
570      !!         ua = ua - 1/e1u * zhpi
571      !!         va = va - 1/e2v * zhpj
572      !!      iceload is added and partial cell case are added to the top and bottom
573      !!     
574      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
575      !!----------------------------------------------------------------------
576      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
577      !!
578      INTEGER  ::   ji, jj, jk, ikt, iktp1i, iktp1j   ! dummy loop indices
579      REAL(wp) ::   zcoef0, zuap, zvap, znad          ! temporary scalars
580      REAL(wp), DIMENSION(jpi,jpj,jpk ) ::  zhpi, zhpj
581      REAL(wp), DIMENSION(jpi,jpj,jpts) ::  zts_top
582      REAL(wp), DIMENSION(jpi,jpj)      ::  zrhdtop_oce
583      !!----------------------------------------------------------------------
584      !
585      zcoef0 = - grav * 0.5_wp   ! Local constant initialization
586      !
587      znad=1._wp                 ! To use density and not density anomaly
588      !
589      !                          ! iniitialised to 0. zhpi zhpi
590      zhpi(:,:,:) = 0._wp   ;   zhpj(:,:,:) = 0._wp
591
592      ! compute rhd at the ice/oce interface (ocean side)
593      ! usefull to reduce residual current in the test case ISOMIP with no melting
594      DO ji = 1, jpi
595        DO jj = 1, jpj
596          ikt = mikt(ji,jj)
597          zts_top(ji,jj,1) = tsn(ji,jj,ikt,1)
598          zts_top(ji,jj,2) = tsn(ji,jj,ikt,2)
599        END DO
600      END DO
601      CALL eos( zts_top, risfdep, zrhdtop_oce )
602
603!==================================================================================     
604!===== Compute surface value =====================================================
605!==================================================================================
606      DO jj = 2, jpjm1
607         DO ji = fs_2, fs_jpim1   ! vector opt.
608            ikt    = mikt(ji,jj)
609            iktp1i = mikt(ji+1,jj)
610            iktp1j = mikt(ji,jj+1)
611            ! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
612            ! we assume ISF is in isostatic equilibrium
613            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( 0.5_wp * e3w_n(ji+1,jj,iktp1i)                                    &
614               &                                    * ( 2._wp * znad + rhd(ji+1,jj,iktp1i) + zrhdtop_oce(ji+1,jj) )   &
615               &                                  - 0.5_wp * e3w_n(ji,jj,ikt)                                         &
616               &                                    * ( 2._wp * znad + rhd(ji,jj,ikt) + zrhdtop_oce(ji,jj) )          &
617               &                                  + ( riceload(ji+1,jj) - riceload(ji,jj))                            ) 
618            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( 0.5_wp * e3w_n(ji,jj+1,iktp1j)                                    &
619               &                                    * ( 2._wp * znad + rhd(ji,jj+1,iktp1j) + zrhdtop_oce(ji,jj+1) )   &
620               &                                  - 0.5_wp * e3w_n(ji,jj,ikt)                                         & 
621               &                                    * ( 2._wp * znad + rhd(ji,jj,ikt) + zrhdtop_oce(ji,jj) )          &
622               &                                  + ( riceload(ji,jj+1) - riceload(ji,jj))                            ) 
623            ! s-coordinate pressure gradient correction (=0 if z coordinate)
624            zuap = -zcoef0 * ( rhd    (ji+1,jj,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
625               &           * ( gde3w_n(ji+1,jj,1) - gde3w_n(ji,jj,1) ) * r1_e1u(ji,jj)
626            zvap = -zcoef0 * ( rhd    (ji,jj+1,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
627               &           * ( gde3w_n(ji,jj+1,1) - gde3w_n(ji,jj,1) ) * r1_e2v(ji,jj)
628            ! add to the general momentum trend
629            ua(ji,jj,1) = ua(ji,jj,1) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
630            va(ji,jj,1) = va(ji,jj,1) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
631         END DO
632      END DO
633!==================================================================================     
634!===== Compute interior value =====================================================
635!==================================================================================
636      ! interior value (2=<jk=<jpkm1)
637      DO jk = 2, jpkm1
638         DO jj = 2, jpjm1
639            DO ji = fs_2, fs_jpim1   ! vector opt.
640               ! hydrostatic pressure gradient along s-surfaces
641               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   &
642                  &           * (  e3w_n(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad ) * wmask(ji+1,jj,jk)   &
643                  &              - e3w_n(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad ) * wmask(ji  ,jj,jk)   )
644               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
645                  &           * (  e3w_n(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad ) * wmask(ji,jj+1,jk)   &
646                  &              - e3w_n(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad ) * wmask(ji,jj  ,jk)   )
647               ! s-coordinate pressure gradient correction
648               zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
649                  &           * ( gde3w_n(ji+1,jj  ,jk) - gde3w_n(ji,jj,jk) ) / e1u(ji,jj)
650               zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
651                  &           * ( gde3w_n(ji  ,jj+1,jk) - gde3w_n(ji,jj,jk) ) / e2v(ji,jj)
652               ! add to the general momentum trend
653               ua(ji,jj,jk) = ua(ji,jj,jk) + (zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
654               va(ji,jj,jk) = va(ji,jj,jk) + (zhpj(ji,jj,jk) + zvap) * vmask(ji,jj,jk)
655            END DO
656         END DO
657      END DO
658      !
659   END SUBROUTINE hpg_isf
660
661
662   SUBROUTINE hpg_djc( kt )
663      !!---------------------------------------------------------------------
664      !!                  ***  ROUTINE hpg_djc  ***
665      !!
666      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
667      !!
668      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
669      !!----------------------------------------------------------------------
670      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
671      !!
672      INTEGER  ::   ji, jj, jk          ! dummy loop indices
673      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
674      REAL(wp) ::   z1_10, cffu, cffx   !    "         "
675      REAL(wp) ::   z1_12, cffv, cffy   !    "         "
676      LOGICAL  ::   ll_tmp1, ll_tmp2    ! local logical variables
677      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zhpi, zhpj
678      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   dzx, dzy, dzz, dzu, dzv, dzw
679      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   drhox, drhoy, drhoz, drhou, drhov, drhow
680      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   rho_i, rho_j, rho_k
681      REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   zcpx, zcpy   !W/D pressure filter
682      !!----------------------------------------------------------------------
683      !
684      IF( ln_wd_il ) THEN
685         ALLOCATE( zcpx(jpi,jpj) , zcpy(jpi,jpj) )
686        DO jj = 2, jpjm1
687           DO ji = 2, jpim1 
688             ll_tmp1 = MIN(  sshn(ji,jj)              ,  sshn(ji+1,jj) ) >                &
689                  &    MAX( -ht_0(ji,jj)              , -ht_0(ji+1,jj) ) .AND.            &
690                  &    MAX(  sshn(ji,jj) + ht_0(ji,jj),  sshn(ji+1,jj) + ht_0(ji+1,jj) )  &
691                  &                                                      > rn_wdmin1 + rn_wdmin2
692             ll_tmp2 = ( ABS( sshn(ji,jj)             -  sshn(ji+1,jj) ) > 1.E-12 ) .AND. (        &
693                  &    MAX(   sshn(ji,jj)             ,  sshn(ji+1,jj) ) >                &
694                  &    MAX(  -ht_0(ji,jj)             , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
695             IF(ll_tmp1) THEN
696               zcpx(ji,jj) = 1.0_wp
697             ELSE IF(ll_tmp2) THEN
698               ! no worries about  sshn(ji+1,jj) -  sshn(ji  ,jj) = 0, it won't happen ! here
699               zcpx(ji,jj) = ABS( (sshn(ji+1,jj) + ht_0(ji+1,jj) - sshn(ji,jj) - ht_0(ji,jj)) &
700                           &    / (sshn(ji+1,jj) - sshn(ji  ,jj)) )
701             ELSE
702               zcpx(ji,jj) = 0._wp
703             END IF
704     
705             ll_tmp1 = MIN(  sshn(ji,jj)              ,  sshn(ji,jj+1) ) >                &
706                  &    MAX( -ht_0(ji,jj)              , -ht_0(ji,jj+1) ) .AND.            &
707                  &    MAX(  sshn(ji,jj) + ht_0(ji,jj),  sshn(ji,jj+1) + ht_0(ji,jj+1) )  &
708                  &                                                      > rn_wdmin1 + rn_wdmin2
709             ll_tmp2 = ( ABS( sshn(ji,jj)             -  sshn(ji,jj+1) ) > 1.E-12 ) .AND. (        &
710                  &    MAX(   sshn(ji,jj)             ,  sshn(ji,jj+1) ) >                &
711                  &    MAX(  -ht_0(ji,jj)             , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
712
713             IF(ll_tmp1) THEN
714               zcpy(ji,jj) = 1.0_wp
715             ELSE IF(ll_tmp2) THEN
716               ! no worries about  sshn(ji,jj+1) -  sshn(ji,jj  ) = 0, it won't happen ! here
717               zcpy(ji,jj) = ABS( (sshn(ji,jj+1) + ht_0(ji,jj+1) - sshn(ji,jj) - ht_0(ji,jj)) &
718                           &    / (sshn(ji,jj+1) - sshn(ji,jj  )) )
719             ELSE
720               zcpy(ji,jj) = 0._wp
721             END IF
722           END DO
723        END DO
724        CALL lbc_lnk( zcpx, 'U', 1._wp )    ;   CALL lbc_lnk( zcpy, 'V', 1._wp )
725      END IF
726
727      IF( kt == nit000 ) THEN
728         IF(lwp) WRITE(numout,*)
729         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
730         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
731      ENDIF
732
733      ! Local constant initialization
734      zcoef0 = - grav * 0.5_wp
735      z1_10  = 1._wp / 10._wp
736      z1_12  = 1._wp / 12._wp
737
738      !----------------------------------------------------------------------------------------
739      !  compute and store in provisional arrays elementary vertical and horizontal differences
740      !----------------------------------------------------------------------------------------
741
742!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
743
744      DO jk = 2, jpkm1
745         DO jj = 2, jpjm1
746            DO ji = fs_2, fs_jpim1   ! vector opt.
747               drhoz(ji,jj,jk) = rhd    (ji  ,jj  ,jk) - rhd    (ji,jj,jk-1)
748               dzz  (ji,jj,jk) = gde3w_n(ji  ,jj  ,jk) - gde3w_n(ji,jj,jk-1)
749               drhox(ji,jj,jk) = rhd    (ji+1,jj  ,jk) - rhd    (ji,jj,jk  )
750               dzx  (ji,jj,jk) = gde3w_n(ji+1,jj  ,jk) - gde3w_n(ji,jj,jk  )
751               drhoy(ji,jj,jk) = rhd    (ji  ,jj+1,jk) - rhd    (ji,jj,jk  )
752               dzy  (ji,jj,jk) = gde3w_n(ji  ,jj+1,jk) - gde3w_n(ji,jj,jk  )
753            END DO
754         END DO
755      END DO
756
757      !-------------------------------------------------------------------------
758      ! compute harmonic averages using eq. 5.18
759      !-------------------------------------------------------------------------
760      zep = 1.e-15
761
762!!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
763!!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
764
765      DO jk = 2, jpkm1
766         DO jj = 2, jpjm1
767            DO ji = fs_2, fs_jpim1   ! vector opt.
768               cffw = 2._wp * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
769
770               cffu = 2._wp * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
771               cffx = 2._wp * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
772
773               cffv = 2._wp * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
774               cffy = 2._wp * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
775
776               IF( cffw > zep) THEN
777                  drhow(ji,jj,jk) = 2._wp *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
778                     &                    / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
779               ELSE
780                  drhow(ji,jj,jk) = 0._wp
781               ENDIF
782
783               dzw(ji,jj,jk) = 2._wp *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
784                  &                  / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
785
786               IF( cffu > zep ) THEN
787                  drhou(ji,jj,jk) = 2._wp *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
788                     &                    / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
789               ELSE
790                  drhou(ji,jj,jk ) = 0._wp
791               ENDIF
792
793               IF( cffx > zep ) THEN
794                  dzu(ji,jj,jk) = 2._wp *   dzx(ji+1,jj,jk) * dzx(ji,jj,jk)   &
795                     &                  / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
796               ELSE
797                  dzu(ji,jj,jk) = 0._wp
798               ENDIF
799
800               IF( cffv > zep ) THEN
801                  drhov(ji,jj,jk) = 2._wp *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
802                     &                    / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
803               ELSE
804                  drhov(ji,jj,jk) = 0._wp
805               ENDIF
806
807               IF( cffy > zep ) THEN
808                  dzv(ji,jj,jk) = 2._wp *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
809                     &                  / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
810               ELSE
811                  dzv(ji,jj,jk) = 0._wp
812               ENDIF
813
814            END DO
815         END DO
816      END DO
817
818      !----------------------------------------------------------------------------------
819      ! apply boundary conditions at top and bottom using 5.36-5.37
820      !----------------------------------------------------------------------------------
821      drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5_wp * drhow(:,:,  2  )
822      drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5_wp * drhou(:,:,  2  )
823      drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5_wp * drhov(:,:,  2  )
824
825      drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
826      drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
827      drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
828
829
830      !--------------------------------------------------------------
831      ! Upper half of top-most grid box, compute and store
832      !-------------------------------------------------------------
833
834!!bug gm   :  e3w-gde3w = 0.5*e3w  ....  and gde3w(2)-gde3w(1)=e3w(2) ....   to be verified
835!          true if gde3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
836
837      DO jj = 2, jpjm1
838         DO ji = fs_2, fs_jpim1   ! vector opt.
839            rho_k(ji,jj,1) = -grav * ( e3w_n(ji,jj,1) - gde3w_n(ji,jj,1) )               &
840               &                   * (  rhd(ji,jj,1)                                     &
841               &                     + 0.5_wp * ( rhd    (ji,jj,2) - rhd    (ji,jj,1) )  &
842               &                              * ( e3w_n  (ji,jj,1) - gde3w_n(ji,jj,1) )  &
843               &                              / ( gde3w_n(ji,jj,2) - gde3w_n(ji,jj,1) )  )
844         END DO
845      END DO
846
847!!bug gm    : here also, simplification is possible
848!!bug gm    : optimisation: 1/10 and 1/12 the division should be done before the loop
849
850      DO jk = 2, jpkm1
851         DO jj = 2, jpjm1
852            DO ji = fs_2, fs_jpim1   ! vector opt.
853
854               rho_k(ji,jj,jk) = zcoef0 * ( rhd    (ji,jj,jk) + rhd    (ji,jj,jk-1) )                                   &
855                  &                     * ( gde3w_n(ji,jj,jk) - gde3w_n(ji,jj,jk-1) )                                   &
856                  &            - grav * z1_10 * (                                                                   &
857                  &     ( drhow  (ji,jj,jk) - drhow  (ji,jj,jk-1) )                                                     &
858                  &   * ( gde3w_n(ji,jj,jk) - gde3w_n(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
859                  &   - ( dzw    (ji,jj,jk) - dzw    (ji,jj,jk-1) )                                                     &
860                  &   * ( rhd    (ji,jj,jk) - rhd    (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
861                  &                             )
862
863               rho_i(ji,jj,jk) = zcoef0 * ( rhd    (ji+1,jj,jk) + rhd    (ji,jj,jk) )                                   &
864                  &                     * ( gde3w_n(ji+1,jj,jk) - gde3w_n(ji,jj,jk) )                                   &
865                  &            - grav* z1_10 * (                                                                    &
866                  &     ( drhou  (ji+1,jj,jk) - drhou  (ji,jj,jk) )                                                     &
867                  &   * ( gde3w_n(ji+1,jj,jk) - gde3w_n(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
868                  &   - ( dzu    (ji+1,jj,jk) - dzu    (ji,jj,jk) )                                                     &
869                  &   * ( rhd    (ji+1,jj,jk) - rhd    (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
870                  &                            )
871
872               rho_j(ji,jj,jk) = zcoef0 * ( rhd    (ji,jj+1,jk) + rhd    (ji,jj,jk) )                                 &
873                  &                     * ( gde3w_n(ji,jj+1,jk) - gde3w_n(ji,jj,jk) )                                   &
874                  &            - grav* z1_10 * (                                                                    &
875                  &     ( drhov  (ji,jj+1,jk) - drhov  (ji,jj,jk) )                                                     &
876                  &   * ( gde3w_n(ji,jj+1,jk) - gde3w_n(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
877                  &   - ( dzv    (ji,jj+1,jk) - dzv    (ji,jj,jk) )                                                     &
878                  &   * ( rhd    (ji,jj+1,jk) - rhd    (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
879                  &                            )
880
881            END DO
882         END DO
883      END DO
884      CALL lbc_lnk( rho_k, 'W', 1. )
885      CALL lbc_lnk( rho_i, 'U', 1. )
886      CALL lbc_lnk( rho_j, 'V', 1. )
887
888
889      ! ---------------
890      !  Surface value
891      ! ---------------
892      DO jj = 2, jpjm1
893         DO ji = fs_2, fs_jpim1   ! vector opt.
894            zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) * r1_e1u(ji,jj)
895            zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) * r1_e2v(ji,jj)
896            IF( ln_wd_il ) THEN
897              zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
898              zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj) 
899            ENDIF
900            ! add to the general momentum trend
901            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
902            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
903         END DO
904      END DO
905
906      ! ----------------
907      !  interior value   (2=<jk=<jpkm1)
908      ! ----------------
909      DO jk = 2, jpkm1
910         DO jj = 2, jpjm1
911            DO ji = fs_2, fs_jpim1   ! vector opt.
912               ! hydrostatic pressure gradient along s-surfaces
913               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
914                  &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
915                  &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) * r1_e1u(ji,jj)
916               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
917                  &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
918                  &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) * r1_e2v(ji,jj)
919               IF( ln_wd_il ) THEN
920                 zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
921                 zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj) 
922               ENDIF
923               ! add to the general momentum trend
924               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
925               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
926            END DO
927         END DO
928      END DO
929      !
930      IF( ln_wd_il )   DEALLOCATE( zcpx, zcpy )
931      !
932   END SUBROUTINE hpg_djc
933
934
935   SUBROUTINE hpg_prj( kt )
936      !!---------------------------------------------------------------------
937      !!                  ***  ROUTINE hpg_prj  ***
938      !!
939      !! ** Method  :   s-coordinate case.
940      !!      A Pressure-Jacobian horizontal pressure gradient method
941      !!      based on the constrained cubic-spline interpolation for
942      !!      all vertical coordinate systems
943      !!
944      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
945      !!----------------------------------------------------------------------
946      INTEGER, PARAMETER  :: polynomial_type = 1    ! 1: cubic spline, 2: linear
947      INTEGER, INTENT(in) ::   kt                   ! ocean time-step index
948      !!
949      INTEGER  ::   ji, jj, jk, jkk                 ! dummy loop indices
950      REAL(wp) ::   zcoef0, znad                    ! local scalars
951      !
952      !! The local variables for the correction term
953      INTEGER  :: jk1, jis, jid, jjs, jjd
954      LOGICAL  :: ll_tmp1, ll_tmp2                  ! local logical variables
955      REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
956      REAL(wp) :: zrhdt1
957      REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
958      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zdept, zrhh
959      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
960      REAL(wp), DIMENSION(jpi,jpj)   ::   zsshu_n, zsshv_n
961      REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   zcpx, zcpy   !W/D pressure filter
962      !!----------------------------------------------------------------------
963      !
964      IF( kt == nit000 ) THEN
965         IF(lwp) WRITE(numout,*)
966         IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
967         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, cubic spline pressure Jacobian'
968      ENDIF
969
970      ! Local constant initialization
971      zcoef0 = - grav
972      znad = 1._wp
973      IF( ln_linssh )   znad = 0._wp
974
975      IF( ln_wd_il ) THEN
976         ALLOCATE( zcpx(jpi,jpj) , zcpy(jpi,jpj) )
977         DO jj = 2, jpjm1
978           DO ji = 2, jpim1 
979             ll_tmp1 = MIN(  sshn(ji,jj)              ,  sshn(ji+1,jj) ) >                &
980                  &    MAX( -ht_0(ji,jj)              , -ht_0(ji+1,jj) ) .AND.            &
981                  &    MAX(  sshn(ji,jj) + ht_0(ji,jj),  sshn(ji+1,jj) + ht_0(ji+1,jj) )  &
982                  &                                                      > rn_wdmin1 + rn_wdmin2
983             ll_tmp2 = ( ABS( sshn(ji,jj)             -  sshn(ji+1,jj) ) > 1.E-12 ) .AND. (         &
984                  &    MAX(   sshn(ji,jj)             ,  sshn(ji+1,jj) ) >                &
985                  &    MAX(  -ht_0(ji,jj)             , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
986
987             IF(ll_tmp1) THEN
988               zcpx(ji,jj) = 1.0_wp
989             ELSE IF(ll_tmp2) THEN
990               ! no worries about  sshn(ji+1,jj) -  sshn(ji  ,jj) = 0, it won't happen ! here
991               zcpx(ji,jj) = ABS( (sshn(ji+1,jj) + ht_0(ji+1,jj) - sshn(ji,jj) - ht_0(ji,jj)) &
992                           &    / (sshn(ji+1,jj) -  sshn(ji  ,jj)) )
993             
994                zcpx(ji,jj) = max(min( zcpx(ji,jj) , 1.0_wp),0.0_wp)
995             ELSE
996               zcpx(ji,jj) = 0._wp
997             END IF
998     
999             ll_tmp1 = MIN(  sshn(ji,jj)              ,  sshn(ji,jj+1) ) >                &
1000                  &    MAX( -ht_0(ji,jj)              , -ht_0(ji,jj+1) ) .AND.            &
1001                  &    MAX(  sshn(ji,jj) + ht_0(ji,jj),  sshn(ji,jj+1) + ht_0(ji,jj+1) )  &
1002                  &                                                      > rn_wdmin1 + rn_wdmin2
1003             ll_tmp2 = ( ABS( sshn(ji,jj)             -  sshn(ji,jj+1) ) > 1.E-12 ) .AND. (      &
1004                  &    MAX(   sshn(ji,jj)             ,  sshn(ji,jj+1) ) >                &
1005                  &    MAX(  -ht_0(ji,jj)             , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
1006
1007             IF(ll_tmp1) THEN
1008               zcpy(ji,jj) = 1.0_wp
1009             ELSE IF(ll_tmp2) THEN
1010               ! no worries about  sshn(ji,jj+1) -  sshn(ji,jj  ) = 0, it won't happen ! here
1011               zcpy(ji,jj) = ABS( (sshn(ji,jj+1) + ht_0(ji,jj+1) - sshn(ji,jj) - ht_0(ji,jj)) &
1012                           &    / (sshn(ji,jj+1) - sshn(ji,jj  )) )
1013                zcpy(ji,jj) = max(min( zcpy(ji,jj) , 1.0_wp),0.0_wp)
1014
1015               ELSE
1016                  zcpy(ji,jj) = 0._wp
1017               ENDIF
1018            END DO
1019         END DO
1020         CALL lbc_lnk( zcpx, 'U', 1._wp )    ;   CALL lbc_lnk( zcpy, 'V', 1._wp )
1021      ENDIF
1022
1023      ! Clean 3-D work arrays
1024      zhpi(:,:,:) = 0._wp
1025      zrhh(:,:,:) = rhd(:,:,:)
1026
1027      ! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
1028      DO jj = 1, jpj
1029        DO ji = 1, jpi
1030          jk = mbkt(ji,jj)+1
1031          IF(     jk <=  0   ) THEN   ;   zrhh(ji,jj,    :   ) = 0._wp
1032          ELSEIF( jk ==  1   ) THEN   ;   zrhh(ji,jj,jk+1:jpk) = rhd(ji,jj,jk)
1033          ELSEIF( jk < jpkm1 ) THEN
1034             DO jkk = jk+1, jpk
1035                zrhh(ji,jj,jkk) = interp1(gde3w_n(ji,jj,jkk  ), gde3w_n(ji,jj,jkk-1),   &
1036                   &                      gde3w_n(ji,jj,jkk-2), rhd    (ji,jj,jkk-1), rhd(ji,jj,jkk-2))
1037             END DO
1038          ENDIF
1039        END DO
1040      END DO
1041
1042      ! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
1043      DO jj = 1, jpj
1044         DO ji = 1, jpi
1045            zdept(ji,jj,1) = 0.5_wp * e3w_n(ji,jj,1) - sshn(ji,jj) * znad
1046         END DO
1047      END DO
1048
1049      DO jk = 2, jpk
1050         DO jj = 1, jpj
1051            DO ji = 1, jpi
1052               zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + e3w_n(ji,jj,jk)
1053            END DO
1054         END DO
1055      END DO
1056
1057      fsp(:,:,:) = zrhh (:,:,:)
1058      xsp(:,:,:) = zdept(:,:,:)
1059
1060      ! Construct the vertical density profile with the
1061      ! constrained cubic spline interpolation
1062      ! rho(z) = asp + bsp*z + csp*z^2 + dsp*z^3
1063      CALL cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
1064
1065      ! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
1066      DO jj = 2, jpj
1067        DO ji = 2, jpi
1068          zrhdt1 = zrhh(ji,jj,1) - interp3( zdept(ji,jj,1), asp(ji,jj,1), bsp(ji,jj,1),  &
1069             &                                              csp(ji,jj,1), dsp(ji,jj,1) ) * 0.25_wp * e3w_n(ji,jj,1)
1070
1071          ! assuming linear profile across the top half surface layer
1072          zhpi(ji,jj,1) =  0.5_wp * e3w_n(ji,jj,1) * zrhdt1
1073        END DO
1074      END DO
1075
1076      ! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
1077      DO jk = 2, jpkm1
1078        DO jj = 2, jpj
1079          DO ji = 2, jpi
1080            zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) +                                  &
1081               &             integ_spline( zdept(ji,jj,jk-1), zdept(ji,jj,jk),   &
1082               &                           asp  (ji,jj,jk-1), bsp  (ji,jj,jk-1), &
1083               &                           csp  (ji,jj,jk-1), dsp  (ji,jj,jk-1)  )
1084          END DO
1085        END DO
1086      END DO
1087
1088      ! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
1089
1090      ! Prepare zsshu_n and zsshv_n
1091      DO jj = 2, jpjm1
1092        DO ji = 2, jpim1
1093!!gm BUG ?    if it is ssh at u- & v-point then it should be:
1094!          zsshu_n(ji,jj) = (e1e2t(ji,jj) * sshn(ji,jj) + e1e2t(ji+1,jj) * sshn(ji+1,jj)) * &
1095!                         & r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp
1096!          zsshv_n(ji,jj) = (e1e2t(ji,jj) * sshn(ji,jj) + e1e2t(ji,jj+1) * sshn(ji,jj+1)) * &
1097!                         & r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp
1098!!gm not this:
1099          zsshu_n(ji,jj) = (e1e2u(ji,jj) * sshn(ji,jj) + e1e2u(ji+1, jj) * sshn(ji+1,jj)) * &
1100                         & r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp 
1101          zsshv_n(ji,jj) = (e1e2v(ji,jj) * sshn(ji,jj) + e1e2v(ji+1, jj) * sshn(ji,jj+1)) * &
1102                         & r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp 
1103        END DO
1104      END DO
1105
1106      CALL lbc_lnk (zsshu_n, 'U', 1.)
1107      CALL lbc_lnk (zsshv_n, 'V', 1.)
1108
1109      DO jj = 2, jpjm1
1110        DO ji = 2, jpim1
1111          zu(ji,jj,1) = - ( e3u_n(ji,jj,1) - zsshu_n(ji,jj) * znad) 
1112          zv(ji,jj,1) = - ( e3v_n(ji,jj,1) - zsshv_n(ji,jj) * znad)
1113        END DO
1114      END DO
1115
1116      DO jk = 2, jpkm1
1117        DO jj = 2, jpjm1
1118          DO ji = 2, jpim1
1119            zu(ji,jj,jk) = zu(ji,jj,jk-1) - e3u_n(ji,jj,jk)
1120            zv(ji,jj,jk) = zv(ji,jj,jk-1) - e3v_n(ji,jj,jk)
1121          END DO
1122        END DO
1123      END DO
1124
1125      DO jk = 1, jpkm1
1126        DO jj = 2, jpjm1
1127          DO ji = 2, jpim1
1128            zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * e3u_n(ji,jj,jk)
1129            zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * e3v_n(ji,jj,jk)
1130          END DO
1131        END DO
1132      END DO
1133
1134      DO jk = 1, jpkm1
1135        DO jj = 2, jpjm1
1136          DO ji = 2, jpim1
1137            zu(ji,jj,jk) = MIN(  zu(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) )  )
1138            zu(ji,jj,jk) = MAX(  zu(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) )  )
1139            zv(ji,jj,jk) = MIN(  zv(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) )  )
1140            zv(ji,jj,jk) = MAX(  zv(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) )  )
1141          END DO
1142        END DO
1143      END DO
1144
1145
1146      DO jk = 1, jpkm1
1147        DO jj = 2, jpjm1
1148          DO ji = 2, jpim1
1149            zpwes = 0._wp; zpwed = 0._wp
1150            zpnss = 0._wp; zpnsd = 0._wp
1151            zuijk = zu(ji,jj,jk)
1152            zvijk = zv(ji,jj,jk)
1153
1154            !!!!!     for u equation
1155            IF( jk <= mbku(ji,jj) ) THEN
1156               IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1157                 jis = ji + 1; jid = ji
1158               ELSE
1159                 jis = ji;     jid = ji +1
1160               ENDIF
1161
1162               ! integrate the pressure on the shallow side
1163               jk1 = jk
1164               DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1165                 IF( jk1 == mbku(ji,jj) ) THEN
1166                   zuijk = -zdept(jis,jj,jk1)
1167                   EXIT
1168                 ENDIF
1169                 zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1170                 zpwes = zpwes +                                    &
1171                      integ_spline(zdept(jis,jj,jk1), zdeps,            &
1172                             asp(jis,jj,jk1),    bsp(jis,jj,jk1), &
1173                             csp(jis,jj,jk1),    dsp(jis,jj,jk1))
1174                 jk1 = jk1 + 1
1175               END DO
1176
1177               ! integrate the pressure on the deep side
1178               jk1 = jk
1179               DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1180                 IF( jk1 == 1 ) THEN
1181                   zdeps = zdept(jid,jj,1) + MIN(zuijk, sshn(jid,jj)*znad)
1182                   zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1183                                                     bsp(jid,jj,1),   csp(jid,jj,1), &
1184                                                     dsp(jid,jj,1)) * zdeps
1185                   zpwed  = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1186                   EXIT
1187                 ENDIF
1188                 zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1189                 zpwed = zpwed +                                        &
1190                        integ_spline(zdeps,              zdept(jid,jj,jk1), &
1191                               asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1),  &
1192                               csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1193                 jk1 = jk1 - 1
1194               END DO
1195
1196               ! update the momentum trends in u direction
1197
1198               zdpdx1 = zcoef0 * r1_e1u(ji,jj) * ( zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk) )
1199               IF( .NOT.ln_linssh ) THEN
1200                 zdpdx2 = zcoef0 * r1_e1u(ji,jj) * &
1201                    &    ( REAL(jis-jid, wp) * (zpwes + zpwed) + (sshn(ji+1,jj)-sshn(ji,jj)) )
1202                ELSE
1203                 zdpdx2 = zcoef0 * r1_e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1204               ENDIF
1205               IF( ln_wd_il ) THEN
1206                  zdpdx1 = zdpdx1 * zcpx(ji,jj) * wdrampu(ji,jj)
1207                  zdpdx2 = zdpdx2 * zcpx(ji,jj) * wdrampu(ji,jj)
1208               ENDIF
1209               ua(ji,jj,jk) = ua(ji,jj,jk) + (zdpdx1 + zdpdx2) * umask(ji,jj,jk) 
1210            ENDIF
1211
1212            !!!!!     for v equation
1213            IF( jk <= mbkv(ji,jj) ) THEN
1214               IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1215                 jjs = jj + 1; jjd = jj
1216               ELSE
1217                 jjs = jj    ; jjd = jj + 1
1218               ENDIF
1219
1220               ! integrate the pressure on the shallow side
1221               jk1 = jk
1222               DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1223                 IF( jk1 == mbkv(ji,jj) ) THEN
1224                   zvijk = -zdept(ji,jjs,jk1)
1225                   EXIT
1226                 ENDIF
1227                 zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1228                 zpnss = zpnss +                                      &
1229                        integ_spline(zdept(ji,jjs,jk1), zdeps,            &
1230                               asp(ji,jjs,jk1),    bsp(ji,jjs,jk1), &
1231                               csp(ji,jjs,jk1),    dsp(ji,jjs,jk1) )
1232                 jk1 = jk1 + 1
1233               END DO
1234
1235               ! integrate the pressure on the deep side
1236               jk1 = jk
1237               DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1238                 IF( jk1 == 1 ) THEN
1239                   zdeps = zdept(ji,jjd,1) + MIN(zvijk, sshn(ji,jjd)*znad)
1240                   zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1241                                                     bsp(ji,jjd,1),   csp(ji,jjd,1), &
1242                                                     dsp(ji,jjd,1) ) * zdeps
1243                   zpnsd  = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1244                   EXIT
1245                 ENDIF
1246                 zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1247                 zpnsd = zpnsd +                                        &
1248                        integ_spline(zdeps,              zdept(ji,jjd,jk1), &
1249                               asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1250                               csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1251                 jk1 = jk1 - 1
1252               END DO
1253
1254
1255               ! update the momentum trends in v direction
1256
1257               zdpdy1 = zcoef0 * r1_e2v(ji,jj) * ( zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk) )
1258               IF( .NOT.ln_linssh ) THEN
1259                  zdpdy2 = zcoef0 * r1_e2v(ji,jj) * &
1260                          ( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (sshn(ji,jj+1)-sshn(ji,jj)) )
1261               ELSE
1262                  zdpdy2 = zcoef0 * r1_e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1263               ENDIF
1264               IF( ln_wd_il ) THEN
1265                  zdpdy1 = zdpdy1 * zcpy(ji,jj) * wdrampv(ji,jj) 
1266                  zdpdy2 = zdpdy2 * zcpy(ji,jj) * wdrampv(ji,jj) 
1267               ENDIF
1268
1269               va(ji,jj,jk) = va(ji,jj,jk) + (zdpdy1 + zdpdy2) * vmask(ji,jj,jk)
1270            ENDIF
1271               !
1272            END DO
1273         END DO
1274      END DO
1275      !
1276      IF( ln_wd_il )   DEALLOCATE( zcpx, zcpy )
1277      !
1278   END SUBROUTINE hpg_prj
1279
1280
1281   SUBROUTINE cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
1282      !!----------------------------------------------------------------------
1283      !!                 ***  ROUTINE cspline  ***
1284      !!
1285      !! ** Purpose :   constrained cubic spline interpolation
1286      !!
1287      !! ** Method  :   f(x) = asp + bsp*x + csp*x^2 + dsp*x^3
1288      !!
1289      !! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1290      !!----------------------------------------------------------------------
1291      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   fsp, xsp           ! value and coordinate
1292      REAL(wp), DIMENSION(:,:,:), INTENT(  out) ::   asp, bsp, csp, dsp ! coefficients of the interpoated function
1293      INTEGER                   , INTENT(in   ) ::   polynomial_type    ! 1: cubic spline   ;   2: Linear
1294      !
1295      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
1296      INTEGER  ::   jpi, jpj, jpkm1
1297      REAL(wp) ::   zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1298      REAL(wp) ::   zdxtmp1, zdxtmp2, zalpha
1299      REAL(wp) ::   zdf(size(fsp,3))
1300      !!----------------------------------------------------------------------
1301      !
1302!!gm  WHAT !!!!!   THIS IS VERY DANGEROUS !!!!! 
1303      jpi   = size(fsp,1)
1304      jpj   = size(fsp,2)
1305      jpkm1 = MAX( 1, size(fsp,3) - 1 )
1306      !
1307      IF (polynomial_type == 1) THEN     ! Constrained Cubic Spline
1308         DO ji = 1, jpi
1309            DO jj = 1, jpj
1310           !!Fritsch&Butland's method, 1984 (preferred, but more computation)
1311           !    DO jk = 2, jpkm1-1
1312           !       zdxtmp1 = xsp(ji,jj,jk)   - xsp(ji,jj,jk-1)
1313           !       zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1314           !       zdf1    = ( fsp(ji,jj,jk)   - fsp(ji,jj,jk-1) ) / zdxtmp1
1315           !       zdf2    = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk)   ) / zdxtmp2
1316           !
1317           !       zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1318           !
1319           !       IF(zdf1 * zdf2 <= 0._wp) THEN
1320           !           zdf(jk) = 0._wp
1321           !       ELSE
1322           !         zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1323           !       ENDIF
1324           !    END DO
1325
1326           !!Simply geometric average
1327               DO jk = 2, jpkm1-1
1328                  zdf1 = (fsp(ji,jj,jk  ) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk  ) - xsp(ji,jj,jk-1))
1329                  zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk  )) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk  ))
1330
1331                  IF(zdf1 * zdf2 <= 0._wp) THEN
1332                     zdf(jk) = 0._wp
1333                  ELSE
1334                     zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1335                  ENDIF
1336               END DO
1337
1338               zdf(1)     = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1339                          &          ( xsp(ji,jj,2) - xsp(ji,jj,1) )           -  0.5_wp * zdf(2)
1340               zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1341                          &          ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - 0.5_wp * zdf(jpkm1 - 1)
1342
1343               DO jk = 1, jpkm1 - 1
1344                 zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1345                 ztmp1  = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1346                 ztmp2  =  6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1347                 zddf1  = -2._wp * ztmp1 + ztmp2
1348                 ztmp1  = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1349                 zddf2  =  2._wp * ztmp1 - ztmp2
1350
1351                 dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1352                 csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1353                 bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1354                               & csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1355                               & dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1356                               &                   xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1357                 asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1358                               &                (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1359                               &                 dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1360               END DO
1361            END DO
1362         END DO
1363
1364      ELSEIF ( polynomial_type == 2 ) THEN     ! Linear
1365         DO ji = 1, jpi
1366            DO jj = 1, jpj
1367               DO jk = 1, jpkm1-1
1368                  zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1369                  ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1370
1371                  dsp(ji,jj,jk) = 0._wp
1372                  csp(ji,jj,jk) = 0._wp
1373                  bsp(ji,jj,jk) = ztmp1 / zdxtmp
1374                  asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1375               END DO
1376            END DO
1377         END DO
1378         !
1379      ELSE
1380         CALL ctl_stop( 'invalid polynomial type in cspline' )
1381      ENDIF
1382      !
1383   END SUBROUTINE cspline
1384
1385
1386   FUNCTION interp1(x, xl, xr, fl, fr)  RESULT(f)
1387      !!----------------------------------------------------------------------
1388      !!                 ***  ROUTINE interp1  ***
1389      !!
1390      !! ** Purpose :   1-d linear interpolation
1391      !!
1392      !! ** Method  :   interpolation is straight forward
1393      !!                extrapolation is also permitted (no value limit)
1394      !!----------------------------------------------------------------------
1395      REAL(wp), INTENT(in) ::  x, xl, xr, fl, fr
1396      REAL(wp)             ::  f ! result of the interpolation (extrapolation)
1397      REAL(wp)             ::  zdeltx
1398      !!----------------------------------------------------------------------
1399      !
1400      zdeltx = xr - xl
1401      IF( abs(zdeltx) <= 10._wp * EPSILON(x) ) THEN
1402         f = 0.5_wp * (fl + fr)
1403      ELSE
1404         f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1405      ENDIF
1406      !
1407   END FUNCTION interp1
1408
1409
1410   FUNCTION interp2( x, a, b, c, d )  RESULT(f)
1411      !!----------------------------------------------------------------------
1412      !!                 ***  ROUTINE interp1  ***
1413      !!
1414      !! ** Purpose :   1-d constrained cubic spline interpolation
1415      !!
1416      !! ** Method  :  cubic spline interpolation
1417      !!
1418      !!----------------------------------------------------------------------
1419      REAL(wp), INTENT(in) ::  x, a, b, c, d
1420      REAL(wp)             ::  f ! value from the interpolation
1421      !!----------------------------------------------------------------------
1422      !
1423      f = a + x* ( b + x * ( c + d * x ) )
1424      !
1425   END FUNCTION interp2
1426
1427
1428   FUNCTION interp3( x, a, b, c, d )  RESULT(f)
1429      !!----------------------------------------------------------------------
1430      !!                 ***  ROUTINE interp1  ***
1431      !!
1432      !! ** Purpose :   Calculate the first order of derivative of
1433      !!                a cubic spline function y=a+b*x+c*x^2+d*x^3
1434      !!
1435      !! ** Method  :   f=dy/dx=b+2*c*x+3*d*x^2
1436      !!
1437      !!----------------------------------------------------------------------
1438      REAL(wp), INTENT(in) ::  x, a, b, c, d
1439      REAL(wp)             ::  f ! value from the interpolation
1440      !!----------------------------------------------------------------------
1441      !
1442      f = b + x * ( 2._wp * c + 3._wp * d * x)
1443      !
1444   END FUNCTION interp3
1445
1446
1447   FUNCTION integ_spline( xl, xr, a, b, c, d )  RESULT(f)
1448      !!----------------------------------------------------------------------
1449      !!                 ***  ROUTINE interp1  ***
1450      !!
1451      !! ** Purpose :   1-d constrained cubic spline integration
1452      !!
1453      !! ** Method  :  integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1454      !!
1455      !!----------------------------------------------------------------------
1456      REAL(wp), INTENT(in) ::  xl, xr, a, b, c, d
1457      REAL(wp)             ::  za1, za2, za3
1458      REAL(wp)             ::  f                   ! integration result
1459      !!----------------------------------------------------------------------
1460      !
1461      za1 = 0.5_wp * b
1462      za2 = c / 3.0_wp
1463      za3 = 0.25_wp * d
1464      !
1465      f  = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1466         & xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1467      !
1468   END FUNCTION integ_spline
1469
1470   !!======================================================================
1471END MODULE dynhpg
1472
Note: See TracBrowser for help on using the repository browser.