source: branches/2017/dev_merge_2017/NEMOGCM/NEMO/OPA_SRC/SBC/sbcmod.F90 @ 9033

Last change on this file since 9033 was 9033, checked in by timgraham, 3 years ago

Commit final files from merge of NEMOGCM and some fixes for waves (taooc renamed tauwoc)

  • Property svn:keywords set to Id
File size: 31.6 KB
Line 
1MODULE sbcmod
2   !!======================================================================
3   !!                       ***  MODULE  sbcmod  ***
4   !! Surface module :  provide to the ocean its surface boundary condition
5   !!======================================================================
6   !! History :  3.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.1  ! 2008-08  (S. Masson, A. Caubel, E. Maisonnave, G. Madec) coupled interface
8   !!            3.3  ! 2010-04  (M. Leclair, G. Madec)  Forcing averaged over 2 time steps
9   !!            3.3  ! 2010-10  (S. Masson)  add diurnal cycle
10   !!            3.3  ! 2010-09  (D. Storkey) add ice boundary conditions (BDY)
11   !!             -   ! 2010-11  (G. Madec) ice-ocean stress always computed at each ocean time-step
12   !!             -   ! 2010-10  (J. Chanut, C. Bricaud, G. Madec)  add the surface pressure forcing
13   !!            3.4  ! 2011-11  (C. Harris) CICE added as an option
14   !!            3.5  ! 2012-11  (A. Coward, G. Madec) Rethink of heat, mass and salt surface fluxes
15   !!            3.6  ! 2014-11  (P. Mathiot, C. Harris) add ice shelves melting
16   !!            4.0  ! 2016-06  (L. Brodeau) new general bulk formulation
17   !!----------------------------------------------------------------------
18
19   !!----------------------------------------------------------------------
20   !!   sbc_init      : read namsbc namelist
21   !!   sbc           : surface ocean momentum, heat and freshwater boundary conditions
22   !!   sbc_final     : Finalize CICE ice model (if used)
23   !!----------------------------------------------------------------------
24   USE oce            ! ocean dynamics and tracers
25   USE dom_oce        ! ocean space and time domain
26   USE phycst         ! physical constants
27   USE sbc_oce        ! Surface boundary condition: ocean fields
28   USE trc_oce        ! shared ocean-passive tracers variables
29   USE sbc_ice        ! Surface boundary condition: ice fields
30   USE sbcdcy         ! surface boundary condition: diurnal cycle
31   USE sbcssm         ! surface boundary condition: sea-surface mean variables
32   USE sbcflx         ! surface boundary condition: flux formulation
33   USE sbcblk         ! surface boundary condition: bulk formulation
34   USE sbcice_if      ! surface boundary condition: ice-if sea-ice model
35#if defined key_lim3
36   USE icestp         ! surface boundary condition: LIM 3.0 sea-ice model
37#endif
38   USE sbcice_cice    ! surface boundary condition: CICE    sea-ice model
39   USE sbcisf         ! surface boundary condition: ice-shelf
40   USE sbccpl         ! surface boundary condition: coupled formulation
41   USE cpl_oasis3     ! OASIS routines for coupling
42   USE sbcssr         ! surface boundary condition: sea surface restoring
43   USE sbcrnf         ! surface boundary condition: runoffs
44   USE sbcapr         ! surface boundary condition: atmo pressure
45   USE sbcisf         ! surface boundary condition: ice shelf
46   USE sbcfwb         ! surface boundary condition: freshwater budget
47   USE icbstp         ! Icebergs
48   USE traqsr         ! active tracers: light penetration
49   USE sbcwave        ! Wave module
50   USE bdy_oce   , ONLY: ln_bdy
51   USE usrdef_sbc     ! user defined: surface boundary condition
52   USE usrdef_closea  ! user defined: closed sea
53   !
54   USE prtctl         ! Print control                    (prt_ctl routine)
55   USE iom            ! IOM library
56   USE in_out_manager ! I/O manager
57   USE lib_mpp        ! MPP library
58   USE timing         ! Timing
59
60   USE diurnal_bulk, ONLY:   ln_diurnal_only   ! diurnal SST diagnostic
61
62   IMPLICIT NONE
63   PRIVATE
64
65   PUBLIC   sbc        ! routine called by step.F90
66   PUBLIC   sbc_init   ! routine called by opa.F90
67
68   INTEGER ::   nsbc   ! type of surface boundary condition (deduced from namsbc informations)
69
70   !!----------------------------------------------------------------------
71   !! NEMO/OPA 4.0 , NEMO-consortium (2016)
72   !! $Id$
73   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
74   !!----------------------------------------------------------------------
75CONTAINS
76
77   SUBROUTINE sbc_init
78      !!---------------------------------------------------------------------
79      !!                    ***  ROUTINE sbc_init ***
80      !!
81      !! ** Purpose :   Initialisation of the ocean surface boundary computation
82      !!
83      !! ** Method  :   Read the namsbc namelist and set derived parameters
84      !!                Call init routines for all other SBC modules that have one
85      !!
86      !! ** Action  : - read namsbc parameters
87      !!              - nsbc: type of sbc
88      !!----------------------------------------------------------------------
89      INTEGER ::   ios, icpt                         ! local integer
90      LOGICAL ::   ll_purecpl, ll_opa, ll_not_nemo   ! local logical
91      !!
92      NAMELIST/namsbc/ nn_fsbc  ,                                                    &
93         &             ln_usr   , ln_flx   , ln_blk       ,                          &
94         &             ln_cpl   , ln_mixcpl, nn_components,                          &
95         &             nn_ice   , ln_ice_embd,                                       &
96         &             ln_traqsr, ln_dm2dc ,                                         &
97         &             ln_rnf   , nn_fwb   , ln_ssr   , ln_isf    , ln_apr_dyn ,     &
98         &             ln_wave  , ln_cdgw  , ln_sdw   , ln_tauwoc  , ln_stcor   ,     &
99         &             ln_tauw  , nn_lsm, nn_sdrift
100      !!----------------------------------------------------------------------
101      !
102      IF(lwp) THEN
103         WRITE(numout,*)
104         WRITE(numout,*) 'sbc_init : surface boundary condition setting'
105         WRITE(numout,*) '~~~~~~~~ '
106      ENDIF
107      !
108      !                       !**  read Surface Module namelist
109      REWIND( numnam_ref )          !* Namelist namsbc in reference namelist : Surface boundary
110      READ  ( numnam_ref, namsbc, IOSTAT = ios, ERR = 901)
111901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namsbc in reference namelist', lwp )
112      !
113      REWIND( numnam_cfg )          !* Namelist namsbc in configuration namelist : Parameters of the run
114      READ  ( numnam_cfg, namsbc, IOSTAT = ios, ERR = 902 )
115902   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namsbc in configuration namelist', lwp )
116      IF(lwm) WRITE( numond, namsbc )
117      !
118      !                             !* overwrite namelist parameter using CPP key information
119#if defined key_agrif
120      IF( Agrif_Root() ) THEN                ! AGRIF zoom (cf r1242: possibility to run without ice in fine grid)
121         IF( lk_lim3 )   nn_ice      = 2
122         IF( lk_cice )   nn_ice      = 3
123      ENDIF
124#else
125      IF( lk_lim3 )   nn_ice      = 2
126      IF( lk_cice )   nn_ice      = 3
127#endif
128      !
129      IF(lwp) THEN                  !* Control print
130         WRITE(numout,*) '   Namelist namsbc (partly overwritten with CPP key setting)'
131         WRITE(numout,*) '      frequency update of sbc (and ice)             nn_fsbc       = ', nn_fsbc
132         WRITE(numout,*) '      Type of air-sea fluxes : '
133         WRITE(numout,*) '         user defined formulation                   ln_usr        = ', ln_usr
134         WRITE(numout,*) '         flux         formulation                   ln_flx        = ', ln_flx
135         WRITE(numout,*) '         bulk         formulation                   ln_blk        = ', ln_blk
136         WRITE(numout,*) '      Type of coupling (Ocean/Ice/Atmosphere) : '
137         WRITE(numout,*) '         ocean-atmosphere coupled formulation       ln_cpl        = ', ln_cpl
138         WRITE(numout,*) '         mixed forced-coupled     formulation       ln_mixcpl     = ', ln_mixcpl
139!!gm  lk_oasis is controlled by key_oasis3  ===>>>  It shoud be removed from the namelist
140         WRITE(numout,*) '         OASIS coupling (with atm or sas)           lk_oasis      = ', lk_oasis
141         WRITE(numout,*) '         components of your executable              nn_components = ', nn_components
142         WRITE(numout,*) '      Sea-ice : '
143         WRITE(numout,*) '         ice management in the sbc (=0/1/2/3)       nn_ice        = ', nn_ice
144         WRITE(numout,*) '         ice embedded into ocean                    ln_ice_embd   = ', ln_ice_embd
145         WRITE(numout,*) '      Misc. options of sbc : '
146         WRITE(numout,*) '         Light penetration in temperature Eq.       ln_traqsr     = ', ln_traqsr
147         WRITE(numout,*) '            daily mean to diurnal cycle qsr            ln_dm2dc   = ', ln_dm2dc
148         WRITE(numout,*) '         Sea Surface Restoring on SST and/or SSS    ln_ssr        = ', ln_ssr
149         WRITE(numout,*) '         FreshWater Budget control  (=0/1/2)        nn_fwb        = ', nn_fwb
150         WRITE(numout,*) '         Patm gradient added in ocean & ice Eqs.    ln_apr_dyn    = ', ln_apr_dyn
151         WRITE(numout,*) '         runoff / runoff mouths                     ln_rnf        = ', ln_rnf
152         WRITE(numout,*) '         iceshelf formulation                       ln_isf        = ', ln_isf
153         WRITE(numout,*) '         closed sea (=0/1) (set in namdom)          nn_closea     = ', nn_closea
154         WRITE(numout,*) '         nb of iterations if land-sea-mask applied  nn_lsm        = ', nn_lsm
155         WRITE(numout,*) '         surface wave                               ln_wave       = ', ln_wave
156         WRITE(numout,*) '               Stokes drift corr. to vert. velocity ln_sdw        = ', ln_sdw
157         WRITE(numout,*) '                  vertical parametrization          nn_sdrift     = ', nn_sdrift
158         WRITE(numout,*) '               wave modified ocean stress           ln_tauwoc      = ', ln_tauwoc
159         WRITE(numout,*) '               wave modified ocean stress component ln_tauw       = ', ln_tauw
160         WRITE(numout,*) '               Stokes coriolis term                 ln_stcor      = ', ln_stcor
161         WRITE(numout,*) '               neutral drag coefficient (CORE, MFS) ln_cdgw       = ', ln_cdgw
162      ENDIF
163      !
164      IF( ln_sdw ) THEN
165         IF( .NOT.(nn_sdrift==jp_breivik .OR. nn_sdrift==jp_phillips .OR. nn_sdrift==jp_peakfr) ) &
166            CALL ctl_stop( 'The chosen nn_sdrift for Stokes drift vertical velocity must be 0, 1, or 2' )
167      ENDIF
168      IF( ln_tauwoc .AND. ln_tauw ) &
169         CALL ctl_stop( 'More than one method for modifying the ocean stress has been selected ', &
170                                  '(ln_tauwoc=.true. and ln_tauw=.true.)' )
171      IF( ln_tauwoc ) &
172         CALL ctl_warn( 'You are subtracting the wave stress to the ocean (ln_tauwoc=.true.)' )
173      IF( ln_tauw ) &
174         CALL ctl_warn( 'The wave modified ocean stress components are used (ln_tauw=.true.) ', &
175                              'This will override any other specification of the ocean stress' )
176      !
177      IF( .NOT.ln_usr ) THEN     ! the model calendar needs some specificities (except in user defined case)
178         IF( MOD( rday , rdt ) /= 0. )   CALL ctl_stop( 'the time step must devide the number of second of in a day' )
179         IF( MOD( rday , 2.  ) /= 0. )   CALL ctl_stop( 'the number of second of in a day must be an even number'    )
180         IF( MOD( rdt  , 2.  ) /= 0. )   CALL ctl_stop( 'the time step (in second) must be an even number'           )
181      ENDIF
182      !                       !**  check option consistency
183      !
184      IF(lwp) WRITE(numout,*)       !* Single / Multi - executable (NEMO / OPA+SAS)
185      SELECT CASE( nn_components )
186      CASE( jp_iam_nemo )
187         IF(lwp) WRITE(numout,*) '   NEMO configured as a single executable (i.e. including both OPA and Surface module'
188      CASE( jp_iam_opa  )
189         IF(lwp) WRITE(numout,*) '   Multi executable configuration. Here, OPA component'
190         IF( .NOT.lk_oasis )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but key_oasis3 disabled' )
191         IF( ln_cpl        )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_cpl = T in OPA'   )
192         IF( ln_mixcpl     )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_mixcpl = T in OPA' )
193      CASE( jp_iam_sas  )
194         IF(lwp) WRITE(numout,*) '   Multi executable configuration. Here, SAS component'
195         IF( .NOT.lk_oasis )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but key_oasis3 disabled' )
196         IF( ln_mixcpl     )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_mixcpl = T in OPA' )
197      CASE DEFAULT
198         CALL ctl_stop( 'sbc_init : unsupported value for nn_components' )
199      END SELECT
200      !                             !* coupled options
201      IF( ln_cpl ) THEN
202         IF( .NOT. lk_oasis )   CALL ctl_stop( 'sbc_init : coupled mode with an atmosphere model (ln_cpl=T)',   &
203            &                                  '           required to defined key_oasis3' )
204      ENDIF
205      IF( ln_mixcpl ) THEN
206         IF( .NOT. lk_oasis )   CALL ctl_stop( 'sbc_init : mixed forced-coupled mode (ln_mixcpl=T) ',   &
207            &                                  '           required to defined key_oasis3' )
208         IF( .NOT.ln_cpl    )   CALL ctl_stop( 'sbc_init : mixed forced-coupled mode (ln_mixcpl=T) requires ln_cpl = T' )
209         IF( nn_components /= jp_iam_nemo )    &
210            &                   CALL ctl_stop( 'sbc_init : the mixed forced-coupled mode (ln_mixcpl=T) ',   &
211            &                                   '          not yet working with sas-opa coupling via oasis' )
212      ENDIF
213      !                             !* sea-ice
214      SELECT CASE( nn_ice )
215      CASE( 0 )                        !- no ice in the domain
216      CASE( 1 )                        !- Ice-cover climatology ("Ice-if" model) 
217      CASE( 2 )                        !- LIM3 ice model
218      CASE( 3 )                        !- CICE ice model
219         IF( .NOT.( ln_blk .OR. ln_cpl ) )   CALL ctl_stop( 'sbc_init : CICE sea-ice model requires ln_blk or ln_cpl = T' )
220         IF( lk_agrif                    )   CALL ctl_stop( 'sbc_init : CICE sea-ice model not currently available with AGRIF' ) 
221      CASE DEFAULT                     !- not supported
222      END SELECT
223      !
224      !                       !**  allocate and set required variables
225      !
226      !                             !* allocate sbc arrays
227      IF( sbc_oce_alloc() /= 0 )   CALL ctl_stop( 'sbc_init : unable to allocate sbc_oce arrays' )
228#if ! defined key_lim3 && ! defined key_cice
229      IF( sbc_ice_alloc() /= 0 )   CALL ctl_stop( 'sbc_init : unable to allocate sbc_ice arrays' )
230#endif
231      !
232      IF( .NOT.ln_isf ) THEN        !* No ice-shelf in the domain : allocate and set to zero
233         IF( sbc_isf_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_isf arrays' )
234         fwfisf  (:,:)   = 0._wp   ;   risf_tsc  (:,:,:) = 0._wp
235         fwfisf_b(:,:)   = 0._wp   ;   risf_tsc_b(:,:,:) = 0._wp
236      END IF
237      IF( nn_ice == 0 ) THEN        !* No sea-ice in the domain : ice fraction is always zero
238         IF( nn_components /= jp_iam_opa )   fr_i(:,:) = 0._wp    ! except for OPA in SAS-OPA coupled case
239      ENDIF
240      !
241      sfx   (:,:) = 0._wp           !* salt flux due to freezing/melting
242      fmmflx(:,:) = 0._wp           !* freezing minus melting flux
243
244      taum(:,:) = 0._wp             !* wind stress module (needed in GLS in case of reduced restart)
245
246      !                          ! Choice of the Surface Boudary Condition (set nsbc)
247      IF( ln_dm2dc ) THEN           !* daily mean to diurnal cycle
248         nday_qsr = -1   ! allow initialization at the 1st call
249         IF( .NOT.( ln_flx .OR. ln_blk ) .AND. nn_components /= jp_iam_opa )   &
250            &   CALL ctl_stop( 'qsr diurnal cycle from daily values requires a flux or bulk formulation' )
251      ENDIF
252      !                             !* Choice of the Surface Boudary Condition
253      !                             (set nsbc)
254      !
255      ll_purecpl  = ln_cpl .AND. .NOT.ln_mixcpl
256      ll_opa      = nn_components == jp_iam_opa
257      ll_not_nemo = nn_components /= jp_iam_nemo
258      icpt = 0
259      !
260      IF( ln_usr          ) THEN   ;   nsbc = jp_usr     ; icpt = icpt + 1   ;   ENDIF       ! user defined         formulation
261      IF( ln_flx          ) THEN   ;   nsbc = jp_flx     ; icpt = icpt + 1   ;   ENDIF       ! flux                 formulation
262      IF( ln_blk          ) THEN   ;   nsbc = jp_blk     ; icpt = icpt + 1   ;   ENDIF       ! bulk                 formulation
263      IF( ll_purecpl      ) THEN   ;   nsbc = jp_purecpl ; icpt = icpt + 1   ;   ENDIF       ! Pure Coupled         formulation
264      IF( ll_opa          ) THEN   ;   nsbc = jp_none    ; icpt = icpt + 1   ;   ENDIF       ! opa coupling via SAS module
265      !
266      IF( icpt /= 1 )    CALL ctl_stop( 'sbc_init : choose ONE and only ONE sbc option' )
267      !
268      IF(lwp) THEN                     !- print the choice of surface flux formulation
269         WRITE(numout,*)
270         SELECT CASE( nsbc )
271         CASE( jp_usr     )   ;   WRITE(numout,*) '   user defined formulation'
272         CASE( jp_flx     )   ;   WRITE(numout,*) '      ===>>   flux formulation'
273         CASE( jp_blk     )   ;   WRITE(numout,*) '      ===>>   bulk formulation'
274         CASE( jp_purecpl )   ;   WRITE(numout,*) '      ===>>   pure coupled formulation'
275!!gm abusive use of jp_none ??   ===>>> need to be check and changed by adding a jp_sas parameter
276         CASE( jp_none    )   ;   WRITE(numout,*) '      ===>>   OPA coupled to SAS via oasis'
277            IF( ln_mixcpl )       WRITE(numout,*) '                  + forced-coupled mixed formulation'
278         END SELECT
279         IF( ll_not_nemo  )       WRITE(numout,*) '                  + OASIS coupled SAS'
280      ENDIF
281      !
282      !                             !* OASIS initialization
283      !
284      IF( lk_oasis )   CALL sbc_cpl_init( nn_ice )   ! Must be done before: (1) first time step
285      !                                              !                      (2) the use of nn_fsbc
286      !     nn_fsbc initialization if OPA-SAS coupling via OASIS
287      !     SAS time-step has to be declared in OASIS (mandatory) -> nn_fsbc has to be modified accordingly
288      IF( nn_components /= jp_iam_nemo ) THEN
289         IF( nn_components == jp_iam_opa )   nn_fsbc = cpl_freq('O_SFLX') / NINT(rdt)
290         IF( nn_components == jp_iam_sas )   nn_fsbc = cpl_freq('I_SFLX') / NINT(rdt)
291         !
292         IF(lwp)THEN
293            WRITE(numout,*)
294            WRITE(numout,*)"   OPA-SAS coupled via OASIS : nn_fsbc re-defined from OASIS namcouple ", nn_fsbc
295            WRITE(numout,*)
296         ENDIF
297      ENDIF
298      !
299      !                             !* check consistency between model timeline and nn_fsbc
300      IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 .OR.   &
301          MOD( nstock             , nn_fsbc) /= 0 ) THEN
302         WRITE(ctmp1,*) 'sbc_init : experiment length (', nitend - nit000 + 1, ') or nstock (', nstock,   &
303            &           ' is NOT a multiple of nn_fsbc (', nn_fsbc, ')'
304         CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' )
305      ENDIF
306      !
307      IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 )   &
308         &  CALL ctl_warn( 'sbc_init : nn_fsbc is NOT a multiple of the number of time steps in a day' )
309      !
310      IF( ln_dm2dc .AND. NINT(rday) / ( nn_fsbc * NINT(rdt) ) < 8  )   &
311         &   CALL ctl_warn( 'sbc_init : diurnal cycle for qsr: the sampling of the diurnal cycle is too small...' )
312      !
313   
314      !                       !**  associated modules : initialization
315      !
316                          CALL sbc_ssm_init            ! Sea-surface mean fields initialization
317      !
318      IF( ln_blk      )   CALL sbc_blk_init            ! bulk formulae initialization
319
320      IF( ln_ssr      )   CALL sbc_ssr_init            ! Sea-Surface Restoring initialization
321      !
322      IF( ln_isf      )   CALL sbc_isf_init            ! Compute iceshelves
323      !
324                          CALL sbc_rnf_init            ! Runof initialization
325      !
326      IF( ln_apr_dyn )    CALL sbc_apr_init            ! Atmo Pressure Forcing initialization
327      !
328#if defined key_lim3
329      IF( lk_agrif .AND. nn_ice == 0 ) THEN            ! allocate ice arrays in case agrif + ice-model + no-ice in child grid
330                          IF( sbc_ice_alloc() /= 0 )   CALL ctl_stop('STOP', 'sbc_ice_alloc : unable to allocate arrays' )
331      ELSEIF( nn_ice == 2 ) THEN
332                          CALL ice_init                ! ICE initialization
333      ENDIF
334#endif
335      IF( nn_ice == 3 )   CALL cice_sbc_init( nsbc )   ! CICE initialization
336      !
337      IF( ln_wave     )   CALL sbc_wave_init           ! surface wave initialisation
338      !
339   END SUBROUTINE sbc_init
340
341
342   SUBROUTINE sbc( kt )
343      !!---------------------------------------------------------------------
344      !!                    ***  ROUTINE sbc  ***
345      !!
346      !! ** Purpose :   provide at each time-step the ocean surface boundary
347      !!                condition (momentum, heat and freshwater fluxes)
348      !!
349      !! ** Method  :   blah blah  to be written ?????????
350      !!                CAUTION : never mask the surface stress field (tke sbc)
351      !!
352      !! ** Action  : - set the ocean surface boundary condition at before and now
353      !!                time step, i.e.
354      !!                utau_b, vtau_b, qns_b, qsr_b, emp_n, sfx_b, qrp_b, erp_b
355      !!                utau  , vtau  , qns  , qsr  , emp  , sfx  , qrp  , erp
356      !!              - updte the ice fraction : fr_i
357      !!----------------------------------------------------------------------
358      INTEGER, INTENT(in) ::   kt   ! ocean time step
359      !
360      LOGICAL ::   ll_sas, ll_opa   ! local logical
361      !!---------------------------------------------------------------------
362      !
363      IF( nn_timing == 1 )  CALL timing_start('sbc')
364      !
365      !                                            ! ---------------------------------------- !
366      IF( kt /= nit000 ) THEN                      !          Swap of forcing fields          !
367         !                                         ! ---------------------------------------- !
368         utau_b(:,:) = utau(:,:)                         ! Swap the ocean forcing fields
369         vtau_b(:,:) = vtau(:,:)                         ! (except at nit000 where before fields
370         qns_b (:,:) = qns (:,:)                         !  are set at the end of the routine)
371         emp_b (:,:) = emp (:,:)
372         sfx_b (:,:) = sfx (:,:)
373         IF ( ln_rnf ) THEN
374            rnf_b    (:,:  ) = rnf    (:,:  )
375            rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)
376         ENDIF
377         IF( ln_isf )  THEN
378            fwfisf_b  (:,:  ) = fwfisf  (:,:  )               
379            risf_tsc_b(:,:,:) = risf_tsc(:,:,:)             
380         ENDIF
381        !
382      ENDIF
383      !                                            ! ---------------------------------------- !
384      !                                            !        forcing field computation         !
385      !                                            ! ---------------------------------------- !
386      !
387      ll_sas = nn_components == jp_iam_sas               ! component flags
388      ll_opa = nn_components == jp_iam_opa
389      !
390      IF( .NOT.ll_sas )   CALL sbc_ssm ( kt )            ! mean ocean sea surface variables (sst_m, sss_m, ssu_m, ssv_m)
391      IF( ln_wave     )   CALL sbc_wave( kt )            ! surface waves
392
393      !
394      !                                            !==  sbc formulation  ==!
395      !                                                   
396      SELECT CASE( nsbc )                                ! Compute ocean surface boundary condition
397      !                                                  ! (i.e. utau,vtau, qns, qsr, emp, sfx)
398      CASE( jp_usr   )     ;   CALL usrdef_sbc_oce( kt )                    ! user defined formulation
399      CASE( jp_flx     )   ;   CALL sbc_flx       ( kt )                    ! flux formulation
400      CASE( jp_blk     )
401         IF( ll_sas    )       CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! OPA-SAS coupling: SAS receiving fields from OPA
402                               CALL sbc_blk       ( kt )                    ! bulk formulation for the ocean
403                               !
404      CASE( jp_purecpl )   ;   CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! pure coupled formulation
405      CASE( jp_none    )
406         IF( ll_opa    )       CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! OPA-SAS coupling: OPA receiving fields from SAS
407      END SELECT
408      !
409      IF( ln_mixcpl )          CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! forced-coupled mixed formulation after forcing
410      !
411      IF ( ln_wave .AND. (ln_tauwoc .OR. ln_tauw) ) CALL sbc_wstress( )      ! Wind stress provided by waves
412      !
413      !                                            !==  Misc. Options  ==!
414      !
415      SELECT CASE( nn_ice )                                       ! Update heat and freshwater fluxes over sea-ice areas
416      CASE(  1 )   ;         CALL sbc_ice_if   ( kt )             ! Ice-cover climatology ("Ice-if" model)
417#if defined key_lim3
418      CASE(  2 )   ;         CALL ice_stp  ( kt, nsbc )           ! LIM-3 ice model
419#endif
420      CASE(  3 )   ;         CALL sbc_ice_cice ( kt, nsbc )       ! CICE ice model
421      END SELECT
422
423      IF( ln_icebergs    )   CALL icb_stp( kt )                   ! compute icebergs
424
425      IF( ln_isf         )   CALL sbc_isf( kt )                   ! compute iceshelves
426
427      IF( ln_rnf         )   CALL sbc_rnf( kt )                   ! add runoffs to fresh water fluxes
428
429      IF( ln_ssr         )   CALL sbc_ssr( kt )                   ! add SST/SSS damping term
430
431      IF( nn_fwb    /= 0 )   CALL sbc_fwb( kt, nn_fwb, nn_fsbc )  ! control the freshwater budget
432
433      ! treatment of closed sea in the model domain   (update freshwater fluxes)
434      ! Should not be ran if ln_diurnal_only
435      IF( .NOT.ln_diurnal_only .AND. nn_closea == 1 )   CALL sbc_clo( kt, cn_cfg, nn_cfg )   
436
437!RBbug do not understand why see ticket 667
438!clem: it looks like it is necessary for the north fold (in certain circumstances). Don't know why.
439      CALL lbc_lnk( emp, 'T', 1. )
440      !
441      IF( kt == nit000 ) THEN                          !   set the forcing field at nit000 - 1    !
442         !                                             ! ---------------------------------------- !
443         IF( ln_rstart .AND.    &                               !* Restart: read in restart file
444            & iom_varid( numror, 'utau_b', ldstop = .FALSE. ) > 0 ) THEN
445            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields red in the restart file'
446            CALL iom_get( numror, jpdom_autoglo, 'utau_b', utau_b )   ! before i-stress  (U-point)
447            CALL iom_get( numror, jpdom_autoglo, 'vtau_b', vtau_b )   ! before j-stress  (V-point)
448            CALL iom_get( numror, jpdom_autoglo, 'qns_b' , qns_b  )   ! before non solar heat flux (T-point)
449            ! The 3D heat content due to qsr forcing is treated in traqsr
450            ! CALL iom_get( numror, jpdom_autoglo, 'qsr_b' , qsr_b  ) ! before     solar heat flux (T-point)
451            CALL iom_get( numror, jpdom_autoglo, 'emp_b', emp_b  )    ! before     freshwater flux (T-point)
452            ! To ensure restart capability with 3.3x/3.4 restart files    !! to be removed in v3.6
453            IF( iom_varid( numror, 'sfx_b', ldstop = .FALSE. ) > 0 ) THEN
454               CALL iom_get( numror, jpdom_autoglo, 'sfx_b', sfx_b )  ! before salt flux (T-point)
455            ELSE
456               sfx_b (:,:) = sfx(:,:)
457            ENDIF
458         ELSE                                                   !* no restart: set from nit000 values
459            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields set to nit000'
460            utau_b(:,:) = utau(:,:)
461            vtau_b(:,:) = vtau(:,:)
462            qns_b (:,:) = qns (:,:)
463            emp_b (:,:) = emp (:,:)
464            sfx_b (:,:) = sfx (:,:)
465         ENDIF
466      ENDIF
467      !                                                ! ---------------------------------------- !
468      IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
469         !                                             ! ---------------------------------------- !
470         IF(lwp) WRITE(numout,*)
471         IF(lwp) WRITE(numout,*) 'sbc : ocean surface forcing fields written in ocean restart file ',   &
472            &                    'at it= ', kt,' date= ', ndastp
473         IF(lwp) WRITE(numout,*) '~~~~'
474         CALL iom_rstput( kt, nitrst, numrow, 'utau_b' , utau )
475         CALL iom_rstput( kt, nitrst, numrow, 'vtau_b' , vtau )
476         CALL iom_rstput( kt, nitrst, numrow, 'qns_b'  , qns  )
477         ! The 3D heat content due to qsr forcing is treated in traqsr
478         ! CALL iom_rstput( kt, nitrst, numrow, 'qsr_b'  , qsr  )
479         CALL iom_rstput( kt, nitrst, numrow, 'emp_b'  , emp  )
480         CALL iom_rstput( kt, nitrst, numrow, 'sfx_b'  , sfx  )
481      ENDIF
482      !                                                ! ---------------------------------------- !
483      !                                                !        Outputs and control print         !
484      !                                                ! ---------------------------------------- !
485      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
486         CALL iom_put( "empmr"  , emp    - rnf )                ! upward water flux
487         CALL iom_put( "empbmr" , emp_b  - rnf )                ! before upward water flux ( needed to recalculate the time evolution of ssh in offline )
488         CALL iom_put( "saltflx", sfx  )                        ! downward salt flux (includes virtual salt flux beneath ice in linear free surface case)
489         CALL iom_put( "fmmflx", fmmflx  )                      ! Freezing-melting water flux
490         CALL iom_put( "qt"    , qns  + qsr )                   ! total heat flux
491         CALL iom_put( "qns"   , qns        )                   ! solar heat flux
492         CALL iom_put( "qsr"   ,       qsr  )                   ! solar heat flux
493         IF( nn_ice > 0 .OR. ll_opa )   CALL iom_put( "ice_cover", fr_i )   ! ice fraction
494         CALL iom_put( "taum"  , taum       )                   ! wind stress module
495         CALL iom_put( "wspd"  , wndm       )                   ! wind speed  module over free ocean or leads in presence of sea-ice
496      ENDIF
497      !
498      CALL iom_put( "utau", utau )   ! i-wind stress   (stress can be updated at each time step in sea-ice)
499      CALL iom_put( "vtau", vtau )   ! j-wind stress
500      !
501      IF(ln_ctl) THEN         ! print mean trends (used for debugging)
502         CALL prt_ctl(tab2d_1=fr_i              , clinfo1=' fr_i    - : ', mask1=tmask, ovlap=1 )
503         CALL prt_ctl(tab2d_1=(emp-rnf + fwfisf), clinfo1=' emp-rnf - : ', mask1=tmask, ovlap=1 )
504         CALL prt_ctl(tab2d_1=(sfx-rnf + fwfisf), clinfo1=' sfx-rnf - : ', mask1=tmask, ovlap=1 )
505         CALL prt_ctl(tab2d_1=qns              , clinfo1=' qns      - : ', mask1=tmask, ovlap=1 )
506         CALL prt_ctl(tab2d_1=qsr              , clinfo1=' qsr      - : ', mask1=tmask, ovlap=1 )
507         CALL prt_ctl(tab3d_1=tmask            , clinfo1=' tmask    - : ', mask1=tmask, ovlap=1, kdim=jpk )
508         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_tem), clinfo1=' sst      - : ', mask1=tmask, ovlap=1, kdim=1   )
509         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_sal), clinfo1=' sss      - : ', mask1=tmask, ovlap=1, kdim=1   )
510         CALL prt_ctl(tab2d_1=utau             , clinfo1=' utau     - : ', mask1=umask,                      &
511            &         tab2d_2=vtau             , clinfo2=' vtau     - : ', mask2=vmask, ovlap=1 )
512      ENDIF
513
514      IF( kt == nitend )   CALL sbc_final         ! Close down surface module if necessary
515      !
516      IF( nn_timing == 1 )  CALL timing_stop('sbc')
517      !
518   END SUBROUTINE sbc
519
520
521   SUBROUTINE sbc_final
522      !!---------------------------------------------------------------------
523      !!                    ***  ROUTINE sbc_final  ***
524      !!
525      !! ** Purpose :   Finalize CICE (if used)
526      !!---------------------------------------------------------------------
527      !
528      IF( nn_ice == 3 )   CALL cice_sbc_final
529      !
530   END SUBROUTINE sbc_final
531
532   !!======================================================================
533END MODULE sbcmod
Note: See TracBrowser for help on using the repository browser.