New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zdfsh2.F90 in branches/2017/dev_merge_2017/NEMOGCM/NEMO/OPA_SRC/ZDF – NEMO

source: branches/2017/dev_merge_2017/NEMOGCM/NEMO/OPA_SRC/ZDF/zdfsh2.F90 @ 9019

Last change on this file since 9019 was 9019, checked in by timgraham, 6 years ago

Merge of dev_CNRS_2017 into branch

File size: 4.4 KB
Line 
1MODULE zdfsh2
2   !!======================================================================
3   !!                       ***  MODULE  zdfsh2  ***
4   !! Ocean physics:  shear production term of TKE
5   !!=====================================================================
6   !! History :   -   !  2014-10  (A. Barthelemy, G. Madec)  original code
7   !!   NEMO     4.0  !  2017-04  (G. Madec)  remove u-,v-pts avm
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   zdf_sh2       : compute mixing the shear production term of TKE
12   !!----------------------------------------------------------------------
13   USE dom_oce        ! domain: ocean
14   !
15   USE in_out_manager ! I/O manager
16   USE lib_mpp        ! MPP library
17   USE timing         ! Timing
18
19   IMPLICIT NONE
20   PRIVATE
21
22   PUBLIC   zdf_sh2        ! called by zdftke, zdfglf, and zdfric
23   
24   !!----------------------------------------------------------------------
25   !! NEMO/OPA 4.0 , NEMO Consortium (2017)
26   !! $Id: $
27   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
28   !!----------------------------------------------------------------------
29CONTAINS
30
31   SUBROUTINE zdf_sh2( pub, pvb, pun, pvn, p_avm, p_sh2  ) 
32      !!----------------------------------------------------------------------
33      !!                   ***  ROUTINE zdf_sh2  ***
34      !!
35      !! ** Purpose :   Compute the shear production term of a TKE equation
36      !!
37      !! ** Method  : - a stable discretization of this term is linked to the
38      !!                time-space discretization of the vertical diffusion
39      !!                of the OGCM. NEMO uses C-grid, a leap-frog environment
40      !!                and an implicit computation of vertical mixing term,
41      !!                so the shear production at w-point is given by:
42      !!                   sh2 = mi[   mi(avm) * dk[ub]/e3ub * dk[un]/e3un   ]
43      !!                       + mj[   mj(avm) * dk[vb]/e3vb * dk[vn]/e3vn   ]
44      !!                NB: wet-point only horizontal averaging of shear
45      !!
46      !! ** Action  : - p_sh2 shear prod. term at w-point (inner domain only)
47      !!                                                   *****
48      !! References :   Bruchard, OM 2002
49      !! ---------------------------------------------------------------------
50      REAL(wp), DIMENSION(:,:,:) , INTENT(in   ) ::   pub, pvb, pun, pvn   ! before, now horizontal velocities
51      REAL(wp), DIMENSION(:,:,:) , INTENT(in   ) ::   p_avm                ! vertical eddy viscosity (w-points)
52      REAL(wp), DIMENSION(:,:,:) , INTENT(  out) ::   p_sh2                ! shear production of TKE (w-points)
53      !
54      INTEGER  ::   ji, jj, jk   ! dummy loop arguments
55      REAL(wp), DIMENSION(jpi,jpj) ::   zsh2u, zsh2v   ! 2D workspace
56      !!--------------------------------------------------------------------
57      !
58      IF( ln_timing )   CALL timing_start('zdf_sh2')
59      !
60      DO jk = 2, jpkm1
61         DO jj = 1, jpjm1        !* 2 x shear production at uw- and vw-points (energy conserving form)
62            DO ji = 1, jpim1
63               zsh2u(ji,jj) = ( p_avm(ji+1,jj,jk) + p_avm(ji,jj,jk) ) &
64                  &         * (   pun(ji,jj,jk-1) -   pun(ji,jj,jk) ) &
65                  &         * (   pub(ji,jj,jk-1) -   pub(ji,jj,jk) ) / ( e3uw_n(ji,jj,jk) * e3uw_b(ji,jj,jk) ) * wumask(ji,jj,jk)
66               zsh2v(ji,jj) = ( p_avm(ji,jj+1,jk) + p_avm(ji,jj,jk) ) &
67                  &         * (   pvn(ji,jj,jk-1) -   pvn(ji,jj,jk) ) &
68                  &         * (   pvb(ji,jj,jk-1) -   pvb(ji,jj,jk) ) / ( e3vw_n(ji,jj,jk) * e3vw_b(ji,jj,jk) ) * wvmask(ji,jj,jk)
69            END DO
70         END DO
71         DO jj = 2, jpjm1        !* shear production at w-point
72            DO ji = 2, jpim1           ! coast mask: =2 at the coast ; =1 otherwise (NB: wmask useless as zsh2 are masked)
73               p_sh2(ji,jj,jk) = 0.25 * (   ( zsh2u(ji-1,jj) + zsh2u(ji,jj) ) * ( 2. - umask(ji-1,jj,jk) * umask(ji,jj,jk) )   &
74                  &                       + ( zsh2v(ji,jj-1) + zsh2v(ji,jj) ) * ( 2. - vmask(ji,jj-1,jk) * vmask(ji,jj,jk) )   )
75            END DO
76         END DO
77      END DO 
78      !
79      IF( ln_timing )   CALL timing_stop('zdf_sh2')     
80      !
81   END SUBROUTINE zdf_sh2
82
83   !!======================================================================
84END MODULE zdfsh2
Note: See TracBrowser for help on using the repository browser.