New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
icethd.F90 in branches/2017/dev_r8183_ICEMODEL/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/2017/dev_r8183_ICEMODEL/NEMOGCM/NEMO/LIM_SRC_3/icethd.F90 @ 8424

Last change on this file since 8424 was 8424, checked in by clem, 7 years ago

continue naming
File size: 35.4 KB
Line 
1MODULE icethd
2   !!======================================================================
3   !!                  ***  MODULE icethd   ***
4   !!  LIM-3 :   ice thermodynamic
5   !!======================================================================
6   !! History :  LIM  ! 2000-01 (M.A. Morales Maqueda, H. Goosse, T. Fichefet) LIM-1
7   !!            2.0  ! 2002-07 (C. Ethe, G. Madec)  LIM-2 (F90 rewriting)
8   !!            3.0  ! 2005-11 (M. Vancoppenolle)  LIM-3 : Multi-layer thermodynamics + salinity variations
9   !!             -   ! 2007-04 (M. Vancoppenolle) add ice_thd_glohec, ice_thd_con_dh and ice_thd_con_dif
10   !!            3.2  ! 2009-07 (M. Vancoppenolle, Y. Aksenov, G. Madec) bug correction in wfx_snw
11   !!            3.3  ! 2010-11 (G. Madec) corrected snow melting heat (due to factor betas)
12   !!            4.0  ! 2011-02 (G. Madec) dynamical allocation
13   !!             -   ! 2012-05 (C. Rousset) add penetration solar flux
14   !!----------------------------------------------------------------------
15#if defined key_lim3
16   !!----------------------------------------------------------------------
17   !!   'key_lim3'                                      LIM3 sea-ice model
18   !!----------------------------------------------------------------------
19   !!   ice_thd       : thermodynamic of sea ice
20   !!   ice_thd_init  : initialisation of sea-ice thermodynamic
21   !!----------------------------------------------------------------------
22   USE phycst         ! physical constants
23   USE dom_oce        ! ocean space and time domain variables
24   USE ice            ! sea-ice variables
25   USE sbc_oce , ONLY : sss_m, sst_m, e3t_m, utau, vtau, ssu_m, ssv_m, frq_m, qns_tot, qsr_tot, sprecip, ln_cpl
26   USE sbc_ice , ONLY : qsr_oce, qns_oce, qemp_oce, qsr_ice, qns_ice, dqns_ice, evap_ice, qprec_ice, qevap_ice, &
27      &                 fr1_i0, fr2_i0, nn_limflx
28   USE ice1D          ! thermodynamic sea-ice variables
29   USE icethd_dif     ! vertical diffusion
30   USE icethd_dh      ! ice-snow growth and melt
31   USE icethd_da      ! lateral melting
32   USE icethd_sal     ! ice salinity
33   USE icethd_ent     ! ice enthalpy redistribution
34   USE icethd_lac     ! lateral accretion
35   USE iceitd         ! remapping thickness distribution
36   USE icetab         ! 1D <==> 2D transformation
37   USE icevar         !
38   USE icecons        ! conservation tests
39   USE icectl         ! control print
40   !
41   USE in_out_manager ! I/O manager
42   USE lbclnk         ! lateral boundary condition - MPP links
43   USE lib_mpp        ! MPP library
44   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
45   USE timing         ! Timing
46
47   IMPLICIT NONE
48   PRIVATE
49
50   PUBLIC   ice_thd         ! called by limstp module
51   PUBLIC   ice_thd_init    ! called by ice_init
52
53   !! * Substitutions
54#  include "vectopt_loop_substitute.h90"
55   !!----------------------------------------------------------------------
56   !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2010)
57   !! $Id: icethd.F90 8420 2017-08-08 12:18:46Z clem $
58   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
59   !!----------------------------------------------------------------------
60CONTAINS
61
62   SUBROUTINE ice_thd( kt )
63      !!-------------------------------------------------------------------
64      !!                ***  ROUTINE ice_thd  ***       
65      !! 
66      !! ** Purpose : This routine manages ice thermodynamics
67      !!         
68      !! ** Action : - Initialisation of some variables
69      !!             - Some preliminary computation (oceanic heat flux
70      !!               at the ice base, snow acc.,heat budget of the leads)
71      !!             - selection of the icy points and put them in an array
72      !!             - call ice_thd_dif  for vertical heat diffusion
73      !!             - call ice_thd_dh   for vertical ice growth and melt
74      !!             - call ice_thd_ent  for enthalpy remapping
75      !!             - call ice_thd_sal  for ice desalination
76      !!             - call ice_thd_temp to  retrieve temperature from ice enthalpy
77      !!             - back to the geographic grid
78      !!     
79      !! ** References :
80      !!---------------------------------------------------------------------
81      INTEGER, INTENT(in) :: kt    ! number of iteration
82      !
83      INTEGER  :: ji, jj, jk, jl   ! dummy loop indices
84      REAL(wp) :: zfric_u, zqld, zqfr, zqfr_neg
85      REAL(wp) :: zvi_b, zsmv_b, zei_b, zfs_b, zfw_b, zft_b ! conservation check
86      REAL(wp), PARAMETER :: zfric_umin = 0._wp           ! lower bound for the friction velocity (cice value=5.e-04)
87      REAL(wp), PARAMETER :: zch        = 0.0057_wp       ! heat transfer coefficient
88      REAL(wp), DIMENSION(jpi,jpj) ::   zu_io, zv_io, zfric   ! ice-ocean velocity (m/s) and frictional velocity (m2/s2)
89      !
90      !!-------------------------------------------------------------------
91
92      IF( nn_timing == 1 )   CALL timing_start('icethd')
93
94      IF( kt == nit000 .AND. lwp ) THEN
95         WRITE(numout,*)'' 
96         WRITE(numout,*)' ice_thd '
97         WRITE(numout,*)' ~~~~~~~~'
98      ENDIF
99     
100      ! conservation test
101      IF( ln_limdiachk ) CALL ice_cons_hsm(0, 'icethd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
102
103      CALL ice_var_glo2eqv
104
105      !---------------------------------------------!
106      ! computation of friction velocity at T points
107      !---------------------------------------------!
108      IF( ln_limdyn ) THEN
109         zu_io(:,:) = u_ice(:,:) - ssu_m(:,:)
110         zv_io(:,:) = v_ice(:,:) - ssv_m(:,:)
111         DO jj = 2, jpjm1 
112            DO ji = fs_2, fs_jpim1
113               zfric(ji,jj) = rn_cio * ( 0.5_wp *  &
114                  &                    (  zu_io(ji,jj) * zu_io(ji,jj) + zu_io(ji-1,jj) * zu_io(ji-1,jj)   &
115                  &                     + zv_io(ji,jj) * zv_io(ji,jj) + zv_io(ji,jj-1) * zv_io(ji,jj-1) ) ) * tmask(ji,jj,1)
116            END DO
117         END DO
118      ELSE      !  if no ice dynamics => transmit directly the atmospheric stress to the ocean
119         DO jj = 2, jpjm1
120            DO ji = fs_2, fs_jpim1
121               zfric(ji,jj) = r1_rau0 * SQRT( 0.5_wp *  &
122                  &                         (  utau(ji,jj) * utau(ji,jj) + utau(ji-1,jj) * utau(ji-1,jj)   &
123                  &                          + vtau(ji,jj) * vtau(ji,jj) + vtau(ji,jj-1) * vtau(ji,jj-1) ) ) * tmask(ji,jj,1)
124            END DO
125         END DO
126      ENDIF
127      CALL lbc_lnk( zfric, 'T',  1. )
128      !
129      ftr_ice(:,:,:) = 0._wp  ! initialization (part of solar radiation transmitted through the ice)
130
131      !--------------------------------------------------------------------!
132      ! Partial computation of forcing for the thermodynamic sea ice model
133      !--------------------------------------------------------------------!
134      DO jj = 1, jpj
135         DO ji = 1, jpi
136            rswitch  = tmask(ji,jj,1) * MAX( 0._wp , SIGN( 1._wp , at_i(ji,jj) - epsi10 ) ) ! 0 if no ice
137            !
138            !           !  solar irradiance transmission at the mixed layer bottom and used in the lead heat budget
139            !           !  practically no "direct lateral ablation"
140            !           
141            !           !  net downward heat flux from the ice to the ocean, expressed as a function of ocean
142            !           !  temperature and turbulent mixing (McPhee, 1992)
143            !
144            ! --- Energy received in the lead, zqld is defined everywhere (J.m-2) --- !
145            zqld =  tmask(ji,jj,1) * rdt_ice *  &
146               &    ( ( 1._wp - at_i_b(ji,jj) ) * qsr_oce(ji,jj) * frq_m(ji,jj) +  &
147               &      ( 1._wp - at_i_b(ji,jj) ) * qns_oce(ji,jj) + qemp_oce(ji,jj) )
148
149            ! --- Energy needed to bring ocean surface layer until its freezing (<0, J.m-2) --- !
150            ! includes supercooling potential energy (>0) or "above-freezing" energy (<0)
151            zqfr = tmask(ji,jj,1) * rau0 * rcp * e3t_m(ji,jj) * ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) )
152
153            ! --- Above-freezing sensible heat content (J/m2 grid)
154            zqfr_neg = tmask(ji,jj,1) * rau0 * rcp * e3t_m(ji,jj) * MIN( ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) ), 0._wp )
155
156            ! --- Sensible ocean-to-ice heat flux (W/m2)
157            zfric_u      = MAX( SQRT( zfric(ji,jj) ), zfric_umin ) 
158            fhtur(ji,jj) = rswitch * rau0 * rcp * zch  * zfric_u * ( ( sst_m(ji,jj) + rt0 ) - t_bo(ji,jj) ) ! W.m-2
159
160            fhtur(ji,jj) = rswitch * MIN( fhtur(ji,jj), - zqfr_neg * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) )
161            ! upper bound for fhtur: the heat retrieved from the ocean must be smaller than the heat necessary to reach
162            !                        the freezing point, so that we do not have SST < T_freeze
163            !                        This implies: - ( fhtur(ji,jj) * at_i(ji,jj) * rtdice ) - zqfr >= 0
164
165            !-- Energy Budget of the leads (J.m-2), source of lateral accretion. Must be < 0 to form ice
166            qlead(ji,jj) = MIN( 0._wp , zqld - ( fhtur(ji,jj) * at_i(ji,jj) * rdt_ice ) - zqfr )
167
168            ! If there is ice and leads are warming, then transfer energy from the lead budget and use it for bottom melting
169            IF( zqld > 0._wp ) THEN
170               fhld (ji,jj) = rswitch * zqld * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) ! divided by at_i since this is (re)multiplied by a_i in icethd_dh.F90
171               qlead(ji,jj) = 0._wp
172            ELSE
173               fhld (ji,jj) = 0._wp
174            ENDIF
175            !
176            ! Net heat flux on top of the ice-ocean [W.m-2]
177            ! ---------------------------------------------
178            hfx_in(ji,jj) = qns_tot(ji,jj) + qsr_tot(ji,jj) 
179         END DO
180      END DO
181     
182      ! In case we bypass open-water ice formation
183      IF( .NOT. ln_limdO )  qlead(:,:) = 0._wp
184      ! In case we bypass growing/melting from top and bottom: we suppose ice is impermeable => ocean is isolated from atmosphere
185      IF( .NOT. ln_limdH )  hfx_in(:,:) = ( 1._wp - at_i_b(:,:) ) * ( qns_oce(:,:) + qsr_oce(:,:) ) + qemp_oce(:,:)
186      IF( .NOT. ln_limdH )  fhtur (:,:) = 0._wp  ;  fhld  (:,:) = 0._wp
187
188      ! ---------------------------------------------------------------------
189      ! Net heat flux on top of the ocean after ice thermo (1st step) [W.m-2]
190      ! ---------------------------------------------------------------------
191      !     First  step here              :  non solar + precip - qlead - qturb
192      !     Second step in icethd_dh      :  heat remaining if total melt (zq_rema)
193      !     Third  step in iceupdate.F90  :  heat from ice-ocean mass exchange (zf_mass) + solar
194      DO jj = 1, jpj
195         DO ji = 1, jpi
196            hfx_out(ji,jj) = ( 1._wp - at_i_b(ji,jj) ) * qns_oce(ji,jj) + qemp_oce(ji,jj)  &  ! Non solar heat flux received by the ocean               
197               &             - qlead(ji,jj) * r1_rdtice                                    &  ! heat flux taken from the ocean where there is open water ice formation
198               &             - at_i(ji,jj) * fhtur(ji,jj)                                  &  ! heat flux taken by turbulence
199               &             - at_i(ji,jj) *  fhld(ji,jj)                                     ! heat flux taken during bottom growth/melt
200                                                                                              !    (fhld should be 0 while bott growth)
201         END DO
202      END DO
203
204      !-------------------------------------------------------------------------------------------!
205      ! Thermodynamic computation (only on grid points covered by ice) => loop over ice categories
206      !-------------------------------------------------------------------------------------------!
207      DO jl = 1, jpl
208
209         ! select ice covered grid points
210         nidx = 0 ; idxice(:) = 0
211         DO jj = 1, jpj
212            DO ji = 1, jpi
213               IF ( a_i(ji,jj,jl) > epsi10 ) THEN     
214                  nidx         = nidx  + 1
215                  idxice(nidx) = (jj - 1) * jpi + ji
216               ENDIF
217            END DO
218         END DO
219
220         IF( lk_mpp )         CALL mpp_ini_ice( nidx , numout )
221
222         IF( nidx > 0 ) THEN  ! If there is no ice, do nothing.
223            !                                                               
224                              CALL ice_thd_1d2d( jl, 1 )            ! --- Move to 1D arrays --- !
225            !                                                       ! --- & Change units of e_i, e_s from J/m2 to J/m3 --- !
226            !
227            s_i_new   (1:nidx) = 0._wp ; dh_s_tot (1:nidx) = 0._wp  ! --- some init --- !  (important to have them here)
228            dh_i_surf (1:nidx) = 0._wp ; dh_i_bott(1:nidx) = 0._wp
229            dh_snowice(1:nidx) = 0._wp ; dh_i_sub (1:nidx) = 0._wp
230            !
231            IF( ln_limdH )    CALL ice_thd_dif                      ! --- Ice/Snow Temperature profile --- !
232            !
233            IF( ln_limdH )    CALL ice_thd_dh                       ! --- Ice/Snow thickness --- !   
234            !
235            IF( ln_limdH )    CALL ice_thd_ent( e_i_1d(1:nidx,:) )  ! --- Ice enthalpy remapping --- !
236            !
237                              CALL ice_thd_sal                      ! --- Ice salinity --- !   
238            !
239                              CALL ice_thd_temp                     ! --- temperature update --- !
240            !
241            IF( ln_limdH ) THEN
242               IF ( ( nn_monocat == 1 .OR. nn_monocat == 4 ) .AND. jpl == 1 ) THEN
243                              CALL ice_thd_lam                      ! --- extra lateral melting if monocat --- !
244               END IF
245            END IF
246            !
247            IF( ln_limdA )    CALL ice_thd_da                       ! --- lateral melting --- !
248            !
249                              CALL ice_thd_1d2d( jl, 2 )            ! --- Change units of e_i, e_s from J/m3 to J/m2 --- !
250            !                                                       ! --- & Move to 2D arrays --- !
251            !
252            IF( lk_mpp )      CALL mpp_comm_free( ncomm_ice ) !RB necessary ??
253         ENDIF
254         !
255      END DO
256      ! update ice age (in case a_i changed, i.e. becomes 0 or lateral melting)
257      oa_i(:,:,:) = o_i(:,:,:) * a_i(:,:,:)
258
259      IF( ln_limdiachk ) CALL ice_cons_hsm(1, 'icethd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
260      !
261                         CALL ice_var_zapsmall           ! --- remove very small ice concentration (<1e-10) --- !
262      !                                                  !     & make sure at_i=SUM(a_i) & ato_i=1 where at_i=0
263      !                   
264      IF( jpl > 1 )      CALL ice_itd_rem( kt )          ! --- Transport ice between thickness categories --- !
265      !
266      IF( ln_limdO )     CALL ice_thd_lac                ! --- frazil ice growing in leads --- !
267      !
268      IF( ln_limctl )    CALL ice_prt( kt, iiceprt, jiceprt, 1, ' - ice thermodyn. - ' )   ! control print
269      IF( ln_ctl )       CALL ice_prt3D( 'icethd' )      ! Control print
270      !
271      IF( nn_timing == 1 )  CALL timing_stop('icethd')
272
273   END SUBROUTINE ice_thd 
274
275 
276   SUBROUTINE ice_thd_temp
277      !!-----------------------------------------------------------------------
278      !!                   ***  ROUTINE ice_thd_temp ***
279      !!                 
280      !! ** Purpose :   Computes sea ice temperature (Kelvin) from enthalpy
281      !!
282      !! ** Method  :   Formula (Bitz and Lipscomb, 1999)
283      !!-------------------------------------------------------------------
284      INTEGER  ::   ji, jk   ! dummy loop indices
285      REAL(wp) ::   ztmelts, zaaa, zbbb, zccc, zdiscrim  ! local scalar
286      !!-------------------------------------------------------------------
287      ! Recover ice temperature
288      DO jk = 1, nlay_i
289         DO ji = 1, nidx
290            ztmelts       =  -tmut * s_i_1d(ji,jk) + rt0
291            ! Conversion q(S,T) -> T (second order equation)
292            zaaa          =  cpic
293            zbbb          =  ( rcp - cpic ) * ( ztmelts - rt0 ) + e_i_1d(ji,jk) * r1_rhoic - lfus
294            zccc          =  lfus * ( ztmelts - rt0 )
295            zdiscrim      =  SQRT( MAX( zbbb * zbbb - 4._wp * zaaa * zccc, 0._wp ) )
296            t_i_1d(ji,jk) =  rt0 - ( zbbb + zdiscrim ) / ( 2._wp * zaaa )
297           
298            ! mask temperature
299            rswitch       =  1._wp - MAX( 0._wp , SIGN( 1._wp , - ht_i_1d(ji) ) ) 
300            t_i_1d(ji,jk) =  rswitch * t_i_1d(ji,jk) + ( 1._wp - rswitch ) * rt0
301         END DO
302      END DO 
303      !
304   END SUBROUTINE ice_thd_temp
305
306
307   SUBROUTINE ice_thd_lam
308      !!-----------------------------------------------------------------------
309      !!                   ***  ROUTINE ice_thd_lam ***
310      !!                 
311      !! ** Purpose :   Lateral melting in case monocategory
312      !!                          ( dA = A/2h dh )
313      !!-----------------------------------------------------------------------
314      INTEGER  ::   ji                 ! dummy loop indices
315      REAL(wp) ::   zhi_bef            ! ice thickness before thermo
316      REAL(wp) ::   zdh_mel, zda_mel   ! net melting
317      REAL(wp) ::   zvi, zvs           ! ice/snow volumes
318      !!-----------------------------------------------------------------------
319      !
320      DO ji = 1, nidx
321         zdh_mel = MIN( 0._wp, dh_i_surf(ji) + dh_i_bott(ji) + dh_snowice(ji) + dh_i_sub(ji) )
322         IF( zdh_mel < 0._wp .AND. a_i_1d(ji) > 0._wp )  THEN
323            zvi          = a_i_1d(ji) * ht_i_1d(ji)
324            zvs          = a_i_1d(ji) * ht_s_1d(ji)
325            ! lateral melting = concentration change
326            zhi_bef     = ht_i_1d(ji) - zdh_mel
327            rswitch     = MAX( 0._wp , SIGN( 1._wp , zhi_bef - epsi20 ) )
328            zda_mel     = rswitch * a_i_1d(ji) * zdh_mel / ( 2._wp * MAX( zhi_bef, epsi20 ) )
329            a_i_1d(ji)  = MAX( epsi20, a_i_1d(ji) + zda_mel ) 
330            ! adjust thickness
331            ht_i_1d(ji) = zvi / a_i_1d(ji)           
332            ht_s_1d(ji) = zvs / a_i_1d(ji)           
333            ! retrieve total concentration
334            at_i_1d(ji) = a_i_1d(ji)
335         END IF
336      END DO
337      !
338   END SUBROUTINE ice_thd_lam
339
340
341   SUBROUTINE ice_thd_1d2d( jl, kn )
342      !!-----------------------------------------------------------------------
343      !!                   ***  ROUTINE ice_thd_1d2d ***
344      !!                 
345      !! ** Purpose :   move arrays from 1d to 2d and the reverse
346      !!-----------------------------------------------------------------------
347      INTEGER, INTENT(in) ::   jl       ! ice cat
348      INTEGER, INTENT(in) ::   kn       ! 1= from 2D to 1D   ;   2= from 1D to 2D
349      !
350      INTEGER             ::   jk       ! dummy loop indices
351      !!-----------------------------------------------------------------------
352      !
353      SELECT CASE( kn )
354      !
355      CASE( 1 )            ! from 2D to 1D
356         !
357         CALL tab_2d_1d( nidx, idxice(1:nidx), at_i_1d(1:nidx), at_i             )
358         CALL tab_2d_1d( nidx, idxice(1:nidx), a_i_1d (1:nidx), a_i(:,:,jl)      )
359         CALL tab_2d_1d( nidx, idxice(1:nidx), ht_i_1d(1:nidx), ht_i(:,:,jl)     )
360         CALL tab_2d_1d( nidx, idxice(1:nidx), ht_s_1d(1:nidx), ht_s(:,:,jl)     )
361         CALL tab_2d_1d( nidx, idxice(1:nidx), t_su_1d(1:nidx), t_su(:,:,jl)     )
362         CALL tab_2d_1d( nidx, idxice(1:nidx), sm_i_1d(1:nidx), sm_i(:,:,jl)     )
363         DO jk = 1, nlay_s
364            CALL tab_2d_1d( nidx, idxice(1:nidx), t_s_1d(1:nidx,jk), t_s(:,:,jk,jl)   )
365            CALL tab_2d_1d( nidx, idxice(1:nidx), e_s_1d(1:nidx,jk), e_s(:,:,jk,jl)   )
366         END DO
367         DO jk = 1, nlay_i
368            CALL tab_2d_1d( nidx, idxice(1:nidx), t_i_1d(1:nidx,jk), t_i(:,:,jk,jl)   )
369            CALL tab_2d_1d( nidx, idxice(1:nidx), e_i_1d(1:nidx,jk), e_i(:,:,jk,jl)   )
370            CALL tab_2d_1d( nidx, idxice(1:nidx), s_i_1d(1:nidx,jk), s_i(:,:,jk,jl)   )
371         END DO
372         !
373         CALL tab_2d_1d( nidx, idxice(1:nidx), qprec_ice_1d(1:nidx), qprec_ice        )
374         CALL tab_2d_1d( nidx, idxice(1:nidx), qsr_ice_1d  (1:nidx), qsr_ice(:,:,jl)  )
375         CALL tab_2d_1d( nidx, idxice(1:nidx), fr1_i0_1d   (1:nidx), fr1_i0           )
376         CALL tab_2d_1d( nidx, idxice(1:nidx), fr2_i0_1d   (1:nidx), fr2_i0           )
377         CALL tab_2d_1d( nidx, idxice(1:nidx), qns_ice_1d  (1:nidx), qns_ice(:,:,jl)  )
378         CALL tab_2d_1d( nidx, idxice(1:nidx), ftr_ice_1d  (1:nidx), ftr_ice(:,:,jl)  )
379         CALL tab_2d_1d( nidx, idxice(1:nidx), evap_ice_1d (1:nidx), evap_ice(:,:,jl) )
380         CALL tab_2d_1d( nidx, idxice(1:nidx), dqns_ice_1d (1:nidx), dqns_ice(:,:,jl) )
381         CALL tab_2d_1d( nidx, idxice(1:nidx), t_bo_1d     (1:nidx), t_bo             )
382         CALL tab_2d_1d( nidx, idxice(1:nidx), sprecip_1d  (1:nidx), sprecip          ) 
383         CALL tab_2d_1d( nidx, idxice(1:nidx), fhtur_1d    (1:nidx), fhtur            )
384         CALL tab_2d_1d( nidx, idxice(1:nidx), fhld_1d     (1:nidx), fhld             )
385         !
386         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_snw_sni_1d(1:nidx), wfx_snw_sni   )
387         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_snw_sum_1d(1:nidx), wfx_snw_sum   )
388         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_sub_1d    (1:nidx), wfx_sub       )
389         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_snw_sub_1d(1:nidx), wfx_snw_sub   )
390         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_ice_sub_1d(1:nidx), wfx_ice_sub   )
391         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_err_sub_1d(1:nidx), wfx_err_sub   )
392         !
393         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_bog_1d (1:nidx), wfx_bog          )
394         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_bom_1d (1:nidx), wfx_bom          )
395         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_sum_1d (1:nidx), wfx_sum          )
396         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_sni_1d (1:nidx), wfx_sni          )
397         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_res_1d (1:nidx), wfx_res          )
398         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_spr_1d (1:nidx), wfx_spr          )
399         CALL tab_2d_1d( nidx, idxice(1:nidx), wfx_lam_1d (1:nidx), wfx_lam          )
400         !
401         CALL tab_2d_1d( nidx, idxice(1:nidx), sfx_bog_1d (1:nidx), sfx_bog          )
402         CALL tab_2d_1d( nidx, idxice(1:nidx), sfx_bom_1d (1:nidx), sfx_bom          )
403         CALL tab_2d_1d( nidx, idxice(1:nidx), sfx_sum_1d (1:nidx), sfx_sum          )
404         CALL tab_2d_1d( nidx, idxice(1:nidx), sfx_sni_1d (1:nidx), sfx_sni          )
405         CALL tab_2d_1d( nidx, idxice(1:nidx), sfx_bri_1d (1:nidx), sfx_bri          )
406         CALL tab_2d_1d( nidx, idxice(1:nidx), sfx_res_1d (1:nidx), sfx_res          )
407         CALL tab_2d_1d( nidx, idxice(1:nidx), sfx_sub_1d (1:nidx), sfx_sub          )
408         CALL tab_2d_1d( nidx, idxice(1:nidx), sfx_lam_1d (1:nidx), sfx_lam          )
409         !
410         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_thd_1d (1:nidx), hfx_thd          )
411         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_spr_1d (1:nidx), hfx_spr          )
412         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_sum_1d (1:nidx), hfx_sum          )
413         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_bom_1d (1:nidx), hfx_bom          )
414         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_bog_1d (1:nidx), hfx_bog          )
415         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_dif_1d (1:nidx), hfx_dif          )
416         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_opw_1d (1:nidx), hfx_opw          )
417         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_snw_1d (1:nidx), hfx_snw          )
418         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_sub_1d (1:nidx), hfx_sub          )
419         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_err_1d (1:nidx), hfx_err          )
420         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_res_1d (1:nidx), hfx_res          )
421         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_err_dif_1d(1:nidx), hfx_err_dif   )
422         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_err_rem_1d(1:nidx), hfx_err_rem   )
423         CALL tab_2d_1d( nidx, idxice(1:nidx), hfx_out_1d (1:nidx), hfx_out          )
424         !
425         ! SIMIP diagnostics
426         CALL tab_2d_1d( nidx, idxice(1:nidx), diag_fc_bo_1d(1:nidx), diag_fc_bo   )
427         CALL tab_2d_1d( nidx, idxice(1:nidx), diag_fc_su_1d(1:nidx), diag_fc_su   )
428         ! ocean surface fields
429         CALL tab_2d_1d( nidx, idxice(1:nidx), sst_1d(1:nidx), sst_m )
430         CALL tab_2d_1d( nidx, idxice(1:nidx), sss_1d(1:nidx), sss_m )
431
432         ! --- Change units of e_i, e_s from J/m2 to J/m3 --- !
433         DO jk = 1, nlay_i
434            WHERE( ht_i_1d(1:nidx)>0._wp ) e_i_1d(1:nidx,jk) = e_i_1d(1:nidx,jk) / (ht_i_1d(1:nidx) * a_i_1d(1:nidx)) * nlay_i
435         ENDDO
436         DO jk = 1, nlay_s
437            WHERE( ht_s_1d(1:nidx)>0._wp ) e_s_1d(1:nidx,jk) = e_s_1d(1:nidx,jk) / (ht_s_1d(1:nidx) * a_i_1d(1:nidx)) * nlay_s
438         ENDDO
439         !
440      CASE( 2 )            ! from 1D to 2D
441         !
442         ! --- Change units of e_i, e_s from J/m3 to J/m2 --- !
443         DO jk = 1, nlay_i
444            e_i_1d(1:nidx,jk) = e_i_1d(1:nidx,jk) * ht_i_1d(1:nidx) * a_i_1d(1:nidx) * r1_nlay_i
445         ENDDO
446         DO jk = 1, nlay_s
447            e_s_1d(1:nidx,jk) = e_s_1d(1:nidx,jk) * ht_s_1d(1:nidx) * a_i_1d(1:nidx) * r1_nlay_s
448         ENDDO
449         !
450         ! Change thickness to volume
451         v_i_1d(1:nidx)   = ht_i_1d(1:nidx) * a_i_1d(1:nidx)
452         v_s_1d(1:nidx)   = ht_s_1d(1:nidx) * a_i_1d(1:nidx)
453         smv_i_1d(1:nidx) = sm_i_1d(1:nidx) * v_i_1d(1:nidx)
454         
455         CALL tab_1d_2d( nidx, idxice(1:nidx), at_i_1d(1:nidx), at_i             )
456         CALL tab_1d_2d( nidx, idxice(1:nidx), a_i_1d (1:nidx), a_i(:,:,jl)      )
457         CALL tab_1d_2d( nidx, idxice(1:nidx), ht_i_1d(1:nidx), ht_i(:,:,jl)     )
458         CALL tab_1d_2d( nidx, idxice(1:nidx), ht_s_1d(1:nidx), ht_s(:,:,jl)     )
459         CALL tab_1d_2d( nidx, idxice(1:nidx), t_su_1d(1:nidx), t_su(:,:,jl)     )
460         CALL tab_1d_2d( nidx, idxice(1:nidx), sm_i_1d(1:nidx), sm_i(:,:,jl)     )
461         DO jk = 1, nlay_s
462            CALL tab_1d_2d( nidx, idxice(1:nidx), t_s_1d(1:nidx,jk), t_s(:,:,jk,jl)   )
463            CALL tab_1d_2d( nidx, idxice(1:nidx), e_s_1d(1:nidx,jk), e_s(:,:,jk,jl)   )
464         END DO
465         DO jk = 1, nlay_i
466            CALL tab_1d_2d( nidx, idxice(1:nidx), t_i_1d(1:nidx,jk), t_i(:,:,jk,jl)   )
467            CALL tab_1d_2d( nidx, idxice(1:nidx), e_i_1d(1:nidx,jk), e_i(:,:,jk,jl)   )
468            CALL tab_1d_2d( nidx, idxice(1:nidx), s_i_1d(1:nidx,jk), s_i(:,:,jk,jl)   )
469         END DO
470         !
471         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_snw_sni_1d(1:nidx), wfx_snw_sni   )
472         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_snw_sum_1d(1:nidx), wfx_snw_sum   )
473         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_sub_1d    (1:nidx), wfx_sub       )
474         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_snw_sub_1d(1:nidx), wfx_snw_sub   )
475         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_ice_sub_1d(1:nidx), wfx_ice_sub   )
476         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_err_sub_1d(1:nidx), wfx_err_sub   )
477         !
478         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_bog_1d (1:nidx), wfx_bog          )
479         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_bom_1d (1:nidx), wfx_bom          )
480         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_sum_1d (1:nidx), wfx_sum          )
481         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_sni_1d (1:nidx), wfx_sni          )
482         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_res_1d (1:nidx), wfx_res          )
483         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_spr_1d (1:nidx), wfx_spr          )
484         CALL tab_1d_2d( nidx, idxice(1:nidx), wfx_lam_1d (1:nidx), wfx_lam          )
485         !
486         CALL tab_1d_2d( nidx, idxice(1:nidx), sfx_bog_1d (1:nidx), sfx_bog          )
487         CALL tab_1d_2d( nidx, idxice(1:nidx), sfx_bom_1d (1:nidx), sfx_bom          )
488         CALL tab_1d_2d( nidx, idxice(1:nidx), sfx_sum_1d (1:nidx), sfx_sum          )
489         CALL tab_1d_2d( nidx, idxice(1:nidx), sfx_sni_1d (1:nidx), sfx_sni          )
490         CALL tab_1d_2d( nidx, idxice(1:nidx), sfx_bri_1d (1:nidx), sfx_bri          )
491         CALL tab_1d_2d( nidx, idxice(1:nidx), sfx_res_1d (1:nidx), sfx_res          )
492         CALL tab_1d_2d( nidx, idxice(1:nidx), sfx_sub_1d (1:nidx), sfx_sub          )
493         CALL tab_1d_2d( nidx, idxice(1:nidx), sfx_lam_1d (1:nidx), sfx_lam          )
494         !
495         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_thd_1d (1:nidx), hfx_thd          )
496         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_spr_1d (1:nidx), hfx_spr          )
497         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_sum_1d (1:nidx), hfx_sum          )
498         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_bom_1d (1:nidx), hfx_bom          )
499         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_bog_1d (1:nidx), hfx_bog          )
500         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_dif_1d (1:nidx), hfx_dif          )
501         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_opw_1d (1:nidx), hfx_opw          )
502         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_snw_1d (1:nidx), hfx_snw          )
503         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_sub_1d (1:nidx), hfx_sub          )
504         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_err_1d (1:nidx), hfx_err          )
505         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_res_1d (1:nidx), hfx_res          )
506         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_err_dif_1d(1:nidx), hfx_err_dif   )
507         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_err_rem_1d(1:nidx), hfx_err_rem   )
508         CALL tab_1d_2d( nidx, idxice(1:nidx), hfx_out_1d (1:nidx), hfx_out          )
509         !
510         CALL tab_1d_2d( nidx, idxice(1:nidx), qns_ice_1d  (1:nidx), qns_ice(:,:,jl)  )
511         CALL tab_1d_2d( nidx, idxice(1:nidx), ftr_ice_1d  (1:nidx), ftr_ice(:,:,jl)  )
512         !
513         ! SIMIP diagnostics         
514         CALL tab_1d_2d( nidx, idxice(1:nidx), t_si_1d      (1:nidx), t_si(:,:,jl)      )
515         CALL tab_1d_2d( nidx, idxice(1:nidx), diag_fc_bo_1d(1:nidx), diag_fc_bo        )
516         CALL tab_1d_2d( nidx, idxice(1:nidx), diag_fc_su_1d(1:nidx), diag_fc_su        )
517         ! extensive variables
518         CALL tab_1d_2d( nidx, idxice(1:nidx), v_i_1d  (1:nidx), v_i  (:,:,jl) )
519         CALL tab_1d_2d( nidx, idxice(1:nidx), v_s_1d  (1:nidx), v_s  (:,:,jl) )
520         CALL tab_1d_2d( nidx, idxice(1:nidx), smv_i_1d(1:nidx), smv_i(:,:,jl) )
521      END SELECT
522      !
523   END SUBROUTINE ice_thd_1d2d
524
525
526   SUBROUTINE ice_thd_init
527      !!-----------------------------------------------------------------------
528      !!                   ***  ROUTINE ice_thd_init ***
529      !!                 
530      !! ** Purpose :   Physical constants and parameters linked to the ice
531      !!              thermodynamics
532      !!
533      !! ** Method  :   Read the namicethd namelist and check the ice-thermo
534      !!              parameter values called at the first timestep (nit000)
535      !!
536      !! ** input   :   Namelist namicether
537      !!-------------------------------------------------------------------
538      INTEGER  ::   ios                 ! Local integer output status for namelist read
539      NAMELIST/namicethd/ rn_kappa_i, nn_ice_thcon, ln_dqnsice, rn_cdsn,                                  &
540         &                ln_limdH, rn_betas,                                                             &
541         &                ln_limdA, rn_beta, rn_dmin,                                                     &
542         &                ln_limdO, rn_hnewice, ln_frazil, rn_maxfrazb, rn_vfrazb, rn_Cfrazb, rn_himin,   &
543         &                nn_limflx
544      !!-------------------------------------------------------------------
545      !
546      REWIND( numnam_ice_ref )              ! Namelist namicethd in reference namelist : Ice thermodynamics
547      READ  ( numnam_ice_ref, namicethd, IOSTAT = ios, ERR = 901)
548901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in reference namelist', lwp )
549
550      REWIND( numnam_ice_cfg )              ! Namelist namicethd in configuration namelist : Ice thermodynamics
551      READ  ( numnam_ice_cfg, namicethd, IOSTAT = ios, ERR = 902 )
552902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in configuration namelist', lwp )
553      IF(lwm) WRITE ( numoni, namicethd )
554      !
555      !
556      IF(lwp) THEN                          ! control print
557         WRITE(numout,*) 'ice_thd_init : Ice Thermodynamics'
558         WRITE(numout,*) '~~~~~~~~~~~~~'
559         WRITE(numout,*)'   -- icethd_dif --'
560         WRITE(numout,*)'      extinction radiation parameter in sea ice               rn_kappa_i   = ', rn_kappa_i
561         WRITE(numout,*)'      switch for comp. of thermal conductivity in the ice     nn_ice_thcon = ', nn_ice_thcon
562         WRITE(numout,*)'      change the surface non-solar flux with Tsu or not       ln_dqnsice   = ', ln_dqnsice
563         WRITE(numout,*)'      thermal conductivity of the snow                        rn_cdsn      = ', rn_cdsn
564         WRITE(numout,*)'   -- icethd_dh --'
565         WRITE(numout,*)'      activate ice thick change from top/bot (T) or not (F)   ln_limdH     = ', ln_limdH
566         WRITE(numout,*)'      coefficient for ice-lead partition of snowfall          rn_betas     = ', rn_betas
567         WRITE(numout,*)'   -- icethd_da --'
568         WRITE(numout,*)'      activate lateral melting (T) or not (F)                 ln_limdA     = ', ln_limdA
569         WRITE(numout,*)'      Coef. beta for lateral melting param.                   rn_beta      = ', rn_beta
570         WRITE(numout,*)'      Minimum floe diameter for lateral melting param.        rn_dmin      = ', rn_dmin
571         WRITE(numout,*)'   -- icethd_lac --'
572         WRITE(numout,*)'      activate ice growth in open-water (T) or not (F)        ln_limdO     = ', ln_limdO
573         WRITE(numout,*)'      ice thick. for lateral accretion                        rn_hnewice   = ', rn_hnewice
574         WRITE(numout,*)'      Frazil ice thickness as a function of wind or not       ln_frazil    = ', ln_frazil
575         WRITE(numout,*)'      Maximum proportion of frazil ice collecting at bottom   rn_maxfrazb  = ', rn_maxfrazb
576         WRITE(numout,*)'      Thresold relative drift speed for collection of frazil  rn_vfrazb    = ', rn_vfrazb
577         WRITE(numout,*)'      Squeezing coefficient for collection of frazil          rn_Cfrazb    = ', rn_Cfrazb
578         WRITE(numout,*)'   -- iceitd --'
579         WRITE(numout,*)'      minimum ice thickness                                   rn_himin     = ', rn_himin 
580         WRITE(numout,*)'   -- icestp --'
581         WRITE(numout,*)'      Multicategory heat flux formulation                     nn_limflx    = ', nn_limflx
582      ENDIF
583      !
584      IF ( rn_hnewice < rn_himin )   CALL ctl_stop( 'STOP', 'ice_thd_init : rn_hnewice should be >= rn_himin' )
585      !
586      IF(lwp) WRITE(numout,*)
587      SELECT CASE( nn_limflx )         ! LIM3 Multi-category heat flux formulation
588      CASE ( -1 )
589         IF(lwp) WRITE(numout,*) '   LIM3: use per-category fluxes (nn_limflx = -1) '
590         IF( ln_cpl )   CALL ctl_stop( 'sbc_init : the chosen nn_limflx for LIM3 in coupled mode must be 0 or 2' )
591      CASE ( 0  )
592         IF(lwp) WRITE(numout,*) '   LIM3: use average per-category fluxes (nn_limflx = 0) '
593      CASE ( 1  )
594         IF(lwp) WRITE(numout,*) '   LIM3: use average then redistribute per-category fluxes (nn_limflx = 1) '
595         IF( ln_cpl )   CALL ctl_stop( 'sbc_init : the chosen nn_limflx for LIM3 in coupled mode must be 0 or 2' )
596      CASE ( 2  )
597         IF(lwp) WRITE(numout,*) '   LIM3: Redistribute a single flux over categories (nn_limflx = 2) '
598         IF( .NOT. ln_cpl )   CALL ctl_stop( 'sbc_init : the chosen nn_limflx for LIM3 in forced mode cannot be 2' )
599      CASE DEFAULT
600         CALL ctl_stop( 'sbcmod: LIM3 option, nn_limflx, should be between -1 and 2' )
601      END SELECT
602      !
603   END SUBROUTINE ice_thd_init
604
605#else
606   !!----------------------------------------------------------------------
607   !!   Default option         Dummy module          NO  LIM3 sea-ice model
608   !!----------------------------------------------------------------------
609#endif
610
611   !!======================================================================
612END MODULE icethd
Note: See TracBrowser for help on using the repository browser.