New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limthd.F90 in branches/2017/dev_r8183_ICEMODEL/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/2017/dev_r8183_ICEMODEL/NEMOGCM/NEMO/LIM_SRC_3/limthd.F90 @ 8341

Last change on this file since 8341 was 8341, checked in by clem, 6 years ago

correct the heat conservation (all fine except limthd_da for a reason I do not understand)

  • Property svn:keywords set to Id
File size: 37.5 KB
Line 
1MODULE limthd
2   !!======================================================================
3   !!                  ***  MODULE limthd   ***
4   !!  LIM-3 :   ice thermodynamic
5   !!======================================================================
6   !! History :  LIM  ! 2000-01 (M.A. Morales Maqueda, H. Goosse, T. Fichefet) LIM-1
7   !!            2.0  ! 2002-07 (C. Ethe, G. Madec)  LIM-2 (F90 rewriting)
8   !!            3.0  ! 2005-11 (M. Vancoppenolle)  LIM-3 : Multi-layer thermodynamics + salinity variations
9   !!             -   ! 2007-04 (M. Vancoppenolle) add lim_thd_glohec, lim_thd_con_dh and lim_thd_con_dif
10   !!            3.2  ! 2009-07 (M. Vancoppenolle, Y. Aksenov, G. Madec) bug correction in wfx_snw
11   !!            3.3  ! 2010-11 (G. Madec) corrected snow melting heat (due to factor betas)
12   !!            4.0  ! 2011-02 (G. Madec) dynamical allocation
13   !!             -   ! 2012-05 (C. Rousset) add penetration solar flux
14   !!----------------------------------------------------------------------
15#if defined key_lim3
16   !!----------------------------------------------------------------------
17   !!   'key_lim3'                                      LIM3 sea-ice model
18   !!----------------------------------------------------------------------
19   !!   lim_thd       : thermodynamic of sea ice
20   !!   lim_thd_init  : initialisation of sea-ice thermodynamic
21   !!----------------------------------------------------------------------
22   USE phycst         ! physical constants
23   USE dom_oce        ! ocean space and time domain variables
24   USE ice            ! sea-ice variables
25   USE sbc_oce , ONLY : sss_m, sst_m, e3t_m, utau, vtau, ssu_m, ssv_m, frq_m, qns_tot, qsr_tot, sprecip, ln_cpl
26   USE sbc_ice , ONLY : qsr_oce, qns_oce, qemp_oce, qsr_ice, qns_ice, dqns_ice, evap_ice, qprec_ice, qevap_ice, &
27      &                 fr1_i0, fr2_i0, nn_limflx
28   USE thd_ice        ! thermodynamic sea-ice variables
29   USE limthd_dif     ! vertical diffusion
30   USE limthd_dh      ! ice-snow growth and melt
31   USE limthd_da      ! lateral melting
32   USE limthd_sal     ! ice salinity
33   USE limthd_ent     ! ice enthalpy redistribution
34   USE limthd_lac     ! lateral accretion
35   USE limitd_th      ! remapping thickness distribution
36   USE limtab         ! 1D <==> 2D transformation
37   USE limvar         !
38   USE limcons        ! conservation tests
39   USE limctl         ! control print
40   !
41   USE in_out_manager ! I/O manager
42   USE lbclnk         ! lateral boundary condition - MPP links
43   USE lib_mpp        ! MPP library
44   USE wrk_nemo       ! work arrays
45   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
46   USE timing         ! Timing
47
48   IMPLICIT NONE
49   PRIVATE
50
51   PUBLIC   lim_thd         ! called by limstp module
52   PUBLIC   lim_thd_init    ! called by ice_init
53
54   !! * Substitutions
55#  include "vectopt_loop_substitute.h90"
56   !!----------------------------------------------------------------------
57   !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2010)
58   !! $Id$
59   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
60   !!----------------------------------------------------------------------
61CONTAINS
62
63   SUBROUTINE lim_thd( kt )
64      !!-------------------------------------------------------------------
65      !!                ***  ROUTINE lim_thd  ***       
66      !! 
67      !! ** Purpose : This routine manages ice thermodynamics
68      !!         
69      !! ** Action : - Initialisation of some variables
70      !!             - Some preliminary computation (oceanic heat flux
71      !!               at the ice base, snow acc.,heat budget of the leads)
72      !!             - selection of the icy points and put them in an array
73      !!             - call lim_thd_dif  for vertical heat diffusion
74      !!             - call lim_thd_dh   for vertical ice growth and melt
75      !!             - call lim_thd_ent  for enthalpy remapping
76      !!             - call lim_thd_sal  for ice desalination
77      !!             - call lim_thd_temp to  retrieve temperature from ice enthalpy
78      !!             - back to the geographic grid
79      !!     
80      !! ** References :
81      !!---------------------------------------------------------------------
82      INTEGER, INTENT(in) :: kt    ! number of iteration
83      !
84      INTEGER  :: ji, jj, jk, jl   ! dummy loop indices
85      INTEGER  :: nidx             ! nb of icy pts for vertical thermo calculations
86      REAL(wp) :: zfric_u, zqld, zqfr, zqfr_neg
87      REAL(wp) :: zvi_b, zsmv_b, zei_b, zfs_b, zfw_b, zft_b 
88      REAL(wp), PARAMETER :: zfric_umin = 0._wp           ! lower bound for the friction velocity (cice value=5.e-04)
89      REAL(wp), PARAMETER :: zch        = 0.0057_wp       ! heat transfer coefficient
90      REAL(wp), POINTER, DIMENSION(:,:) ::   zu_io, zv_io, zfric   ! ice-ocean velocity (m/s) and frictional velocity (m2/s2)
91      !
92      !!-------------------------------------------------------------------
93
94      IF( nn_timing == 1 )   CALL timing_start('limthd')
95
96      CALL wrk_alloc( jpi,jpj, zu_io, zv_io, zfric )
97
98      IF( kt == nit000 .AND. lwp ) THEN
99         WRITE(numout,*)'' 
100         WRITE(numout,*)' lim_thd '
101         WRITE(numout,*)' ~~~~~~~~'
102      ENDIF
103     
104      ! conservation test
105      IF( ln_limdiachk ) CALL lim_cons_hsm(0, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
106
107      CALL lim_var_glo2eqv
108
109      !---------------------------------------------!
110      ! computation of friction velocity at T points
111      !---------------------------------------------!
112      IF( ln_limdyn ) THEN
113         zu_io(:,:) = u_ice(:,:) - ssu_m(:,:)
114         zv_io(:,:) = v_ice(:,:) - ssv_m(:,:)
115         DO jj = 2, jpjm1 
116            DO ji = fs_2, fs_jpim1
117               zfric(ji,jj) = rn_cio * ( 0.5_wp *  &
118                  &                    (  zu_io(ji,jj) * zu_io(ji,jj) + zu_io(ji-1,jj) * zu_io(ji-1,jj)   &
119                  &                     + zv_io(ji,jj) * zv_io(ji,jj) + zv_io(ji,jj-1) * zv_io(ji,jj-1) ) ) * tmask(ji,jj,1)
120            END DO
121         END DO
122      ELSE      !  if no ice dynamics => transmit directly the atmospheric stress to the ocean
123         DO jj = 2, jpjm1
124            DO ji = fs_2, fs_jpim1
125               zfric(ji,jj) = r1_rau0 * SQRT( 0.5_wp *  &
126                  &                         (  utau(ji,jj) * utau(ji,jj) + utau(ji-1,jj) * utau(ji-1,jj)   &
127                  &                          + vtau(ji,jj) * vtau(ji,jj) + vtau(ji,jj-1) * vtau(ji,jj-1) ) ) * tmask(ji,jj,1)
128            END DO
129         END DO
130      ENDIF
131      CALL lbc_lnk( zfric, 'T',  1. )
132      !
133      ftr_ice(:,:,:) = 0._wp  ! initialization (part of solar radiation transmitted through the ice)
134
135      !--------------------------------------------------------------------!
136      ! Partial computation of forcing for the thermodynamic sea ice model
137      !--------------------------------------------------------------------!
138      DO jj = 1, jpj
139         DO ji = 1, jpi
140            rswitch  = tmask(ji,jj,1) * MAX( 0._wp , SIGN( 1._wp , at_i(ji,jj) - epsi10 ) ) ! 0 if no ice
141            !
142            !           !  solar irradiance transmission at the mixed layer bottom and used in the lead heat budget
143            !           !  practically no "direct lateral ablation"
144            !           
145            !           !  net downward heat flux from the ice to the ocean, expressed as a function of ocean
146            !           !  temperature and turbulent mixing (McPhee, 1992)
147            !
148            ! --- Energy received in the lead, zqld is defined everywhere (J.m-2) --- !
149            zqld =  tmask(ji,jj,1) * rdt_ice *  &
150               &    ( ( 1._wp - at_i_b(ji,jj) ) * qsr_oce(ji,jj) * frq_m(ji,jj) +  &
151               &      ( 1._wp - at_i_b(ji,jj) ) * qns_oce(ji,jj) + qemp_oce(ji,jj) )
152
153            ! --- Energy needed to bring ocean surface layer until its freezing (<0, J.m-2) --- !
154            ! includes supercooling potential energy (>0) or "above-freezing" energy (<0)
155            zqfr = tmask(ji,jj,1) * rau0 * rcp * e3t_m(ji,jj) * ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) )
156
157            ! --- Above-freezing sensible heat content (J/m2 grid)
158            zqfr_neg = tmask(ji,jj,1) * rau0 * rcp * e3t_m(ji,jj) * MIN( ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) ), 0._wp )
159
160            ! --- Sensible ocean-to-ice heat flux (W/m2)
161            zfric_u      = MAX( SQRT( zfric(ji,jj) ), zfric_umin ) 
162            fhtur(ji,jj) = rswitch * rau0 * rcp * zch  * zfric_u * ( ( sst_m(ji,jj) + rt0 ) - t_bo(ji,jj) ) ! W.m-2
163
164            fhtur(ji,jj) = rswitch * MIN( fhtur(ji,jj), - zqfr_neg * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) )
165            ! upper bound for fhtur: the heat retrieved from the ocean must be smaller than the heat necessary to reach
166            !                        the freezing point, so that we do not have SST < T_freeze
167            !                        This implies: - ( fhtur(ji,jj) * at_i(ji,jj) * rtdice ) - zqfr >= 0
168
169            !-- Energy Budget of the leads (J.m-2), source of lateral accretion. Must be < 0 to form ice
170            qlead(ji,jj) = MIN( 0._wp , zqld - ( fhtur(ji,jj) * at_i(ji,jj) * rdt_ice ) - zqfr )
171
172            ! If there is ice and leads are warming, then transfer energy from the lead budget and use it for bottom melting
173            IF( zqld > 0._wp ) THEN
174               fhld (ji,jj) = rswitch * zqld * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) ! divided by at_i since this is (re)multiplied by a_i in limthd_dh.F90
175               qlead(ji,jj) = 0._wp
176            ELSE
177               fhld (ji,jj) = 0._wp
178            ENDIF
179            !
180            ! Net heat flux on top of the ice-ocean [W.m-2]
181            ! ---------------------------------------------
182            hfx_in(ji,jj) = qns_tot(ji,jj) + qsr_tot(ji,jj) 
183         END DO
184      END DO
185     
186      ! In case we bypass open-water ice formation
187      IF( .NOT. ln_limdO )  qlead(:,:) = 0._wp
188      ! In case we bypass growing/melting from top and bottom: we suppose ice is impermeable => ocean is isolated from atmosphere
189      IF( .NOT. ln_limdH )  hfx_in(:,:) = ( 1._wp - at_i_b(:,:) ) * ( qns_oce(:,:) + qsr_oce(:,:) ) + qemp_oce(:,:)
190      IF( .NOT. ln_limdH )  fhtur (:,:) = 0._wp  ;  fhld  (:,:) = 0._wp
191
192      ! ---------------------------------------------------------------------
193      ! Net heat flux on top of the ocean after ice thermo (1st step) [W.m-2]
194      ! ---------------------------------------------------------------------
195      !     First  step here              :  non solar + precip - qlead - qturb
196      !     Second step in limthd_dh      :  heat remaining if total melt (zq_rema)
197      !     Third  step in limsbc         :  heat from ice-ocean mass exchange (zf_mass) + solar
198      DO jj = 1, jpj
199         DO ji = 1, jpi
200            hfx_out(ji,jj) = ( 1._wp - at_i_b(ji,jj) ) * qns_oce(ji,jj) + qemp_oce(ji,jj)  &  ! Non solar heat flux received by the ocean               
201               &             - qlead(ji,jj) * r1_rdtice                                    &  ! heat flux taken from the ocean where there is open water ice formation
202               &             - at_i(ji,jj) * fhtur(ji,jj)                                  &  ! heat flux taken by turbulence
203               &             - at_i(ji,jj) *  fhld(ji,jj)                                     ! heat flux taken during bottom growth/melt
204                                                                                              !    (fhld should be 0 while bott growth)
205         END DO
206      END DO
207
208      !------------------------------------------------------------------------------!
209      ! Thermodynamic computation (only on grid points covered by ice)
210      !------------------------------------------------------------------------------!
211
212      DO jl = 1, jpl      !loop over ice categories
213
214         ! select ice covered grid points
215         nidx = 0 ; idxice(:) = 0
216         DO jj = 1, jpj
217            DO ji = 1, jpi
218               IF ( a_i(ji,jj,jl) > epsi10 ) THEN     
219                  nidx         = nidx  + 1
220                  idxice(nidx) = (jj - 1) * jpi + ji
221               ENDIF
222            END DO
223         END DO
224
225         ! debug point to follow
226         jiindex_1d = 0
227         IF( ln_limctl ) THEN
228            DO ji = mi0(iiceprt), mi1(iiceprt)
229               DO jj = mj0(jiceprt), mj1(jiceprt)
230                  jiindex_1d = (jj - 1) * jpi + ji
231                  WRITE(numout,*) ' lim_thd : Category no : ', jl 
232               END DO
233            END DO
234         ENDIF
235
236         IF( lk_mpp )         CALL mpp_ini_ice( nidx , numout )
237
238         IF( nidx > 0 ) THEN  ! If there is no ice, do nothing.
239            !                                                               
240            s_i_new   (:) = 0._wp ; dh_s_tot (:) = 0._wp                     ! --- some init --- !
241            dh_i_surf (:) = 0._wp ; dh_i_bott(:) = 0._wp
242            dh_snowice(:) = 0._wp ; dh_i_sub (:) = 0._wp
243
244                              CALL lim_thd_1d2d( nidx, jl, 1 )               ! --- Move to 1D arrays --- !
245            !
246            DO jk = 1, nlay_i                                                ! --- Change units from J/m2 to J/m3 --- !
247               WHERE( ht_i_1d(:)>0._wp ) e_i_1d(:,jk) = e_i_1d(:,jk) / (ht_i_1d(:) * a_i_1d(:)) * nlay_i
248            ENDDO
249            DO jk = 1, nlay_s
250               WHERE( ht_s_1d(:)>0._wp ) e_s_1d(:,jk) = e_s_1d(:,jk) / (ht_s_1d(:) * a_i_1d(:)) * nlay_s
251            ENDDO
252            !
253            IF( ln_limdH )    CALL lim_thd_dif( 1, nidx )                    ! --- Ice/Snow Temperature profile --- !
254            !
255            IF( ln_limdH )    CALL lim_thd_dh( 1, nidx )                     ! --- Ice/Snow thickness --- !   
256            !
257            IF( ln_limdH )    CALL lim_thd_ent( 1, nidx, e_i_1d(1:nidx,:) )  ! --- Ice enthalpy remapping --- !
258            !
259                              CALL lim_thd_sal( 1, nidx )                    ! --- Ice salinity --- !   
260            !
261                              CALL lim_thd_temp( 1, nidx )                   ! --- temperature update --- !
262            !
263            IF( ln_limdH ) THEN
264               IF ( ( nn_monocat == 1 .OR. nn_monocat == 4 ) .AND. jpl == 1 ) THEN
265                              CALL lim_thd_lam( 1, nidx )                    ! --- extra lateral melting if monocat --- !
266               END IF
267            END IF
268            !
269            DO jk = 1, nlay_i                                                ! --- Change units from J/m3 to J/m2 --- !
270               e_i_1d(:,jk) = e_i_1d(:,jk) * ht_i_1d(:) * a_i_1d(:) * r1_nlay_i
271            ENDDO
272            DO jk = 1, nlay_s
273               e_s_1d(:,jk) = e_s_1d(:,jk) * ht_s_1d(:) * a_i_1d(:) * r1_nlay_s
274            ENDDO
275            !
276                              CALL lim_thd_1d2d( nidx, jl, 2 )               ! --- Move to 2D arrays --- !
277            !
278            IF( lk_mpp )      CALL mpp_comm_free( ncomm_ice ) !RB necessary ??
279         ENDIF
280         !
281      END DO
282      at_i(:,:) = SUM( a_i(:,:,:), dim=3 )
283
284      ! Change thickness to volume
285      v_i(:,:,:)   = ht_i(:,:,:) * a_i(:,:,:)
286      v_s(:,:,:)   = ht_s(:,:,:) * a_i(:,:,:)
287      smv_i(:,:,:) = sm_i(:,:,:) * v_i(:,:,:)
288      IF( ln_limdiachk ) CALL lim_cons_hsm(1, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
289
290      IF( ln_limdiachk ) CALL lim_cons_hsm(0, 'limitd_thd_da', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
291      IF( ln_limdA)           CALL lim_thd_da                                ! --- lateral melting --- !
292
293      ! Change thickness to volume
294      at_i(:,:)    = SUM( a_i(:,:,:), dim=3 )
295      v_i(:,:,:)   = ht_i(:,:,:) * a_i(:,:,:)
296      v_s(:,:,:)   = ht_s(:,:,:) * a_i(:,:,:)
297      smv_i(:,:,:) = sm_i(:,:,:) * v_i(:,:,:)
298      IF( ln_limdiachk ) CALL lim_cons_hsm(1, 'limitd_thd_da', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
299
300      ! update ice age (in case a_i changed, i.e. becomes 0 or lateral melting in monocat)
301      DO jl  = 1, jpl
302         DO jj = 1, jpj
303            DO ji = 1, jpi
304               rswitch = MAX( 0._wp , SIGN( 1._wp, a_i_b(ji,jj,jl) - epsi10 ) )
305               oa_i(ji,jj,jl) = rswitch * oa_i(ji,jj,jl) * a_i(ji,jj,jl) / MAX( a_i_b(ji,jj,jl), epsi10 )
306            END DO
307         END DO
308      END DO
309
310      CALL lim_var_zapsmall
311
312      ! control checks
313      IF( ln_limctl )    CALL lim_prt( kt, iiceprt, jiceprt, 1, ' - ice thermodyn. - ' )   ! control print
314      !
315
316      !------------------------------------------------!
317      !  Transport ice between thickness categories
318      !------------------------------------------------!
319      ! Given thermodynamic growth rates, transport ice between thickness categories.
320      IF( ln_limdiachk ) CALL lim_cons_hsm(0, 'limitd_th_rem', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
321
322      IF( jpl > 1 )      CALL lim_itd_th_rem( 1, jpl, kt )
323
324      IF( ln_limdiachk ) CALL lim_cons_hsm(1, 'limitd_th_rem', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
325
326      !------------------------------------------------!
327      !  Add frazil ice growing in leads
328      !------------------------------------------------!
329      IF( ln_limdiachk ) CALL lim_cons_hsm(0, 'limthd_lac', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
330
331      IF( ln_limdO )     CALL lim_thd_lac
332     
333      ! conservation test
334      IF( ln_limdiachk ) CALL lim_cons_hsm(1, 'limthd_lac', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
335
336      ! Control print
337      IF( ln_ctl )       CALL lim_prt3D( 'limthd' )
338      !
339      CALL wrk_dealloc( jpi,jpj, zu_io, zv_io, zfric )
340      !
341      IF( nn_timing == 1 )  CALL timing_stop('limthd')
342
343   END SUBROUTINE lim_thd 
344
345 
346   SUBROUTINE lim_thd_temp( kideb, kiut )
347      !!-----------------------------------------------------------------------
348      !!                   ***  ROUTINE lim_thd_temp ***
349      !!                 
350      !! ** Purpose :   Computes sea ice temperature (Kelvin) from enthalpy
351      !!
352      !! ** Method  :   Formula (Bitz and Lipscomb, 1999)
353      !!-------------------------------------------------------------------
354      INTEGER, INTENT(in) ::   kideb, kiut   ! bounds for the spatial loop
355      !
356      INTEGER  ::   ji, jk   ! dummy loop indices
357      REAL(wp) ::   ztmelts, zaaa, zbbb, zccc, zdiscrim  ! local scalar
358      !!-------------------------------------------------------------------
359      ! Recover ice temperature
360      DO jk = 1, nlay_i
361         DO ji = kideb, kiut
362            ztmelts       =  -tmut * s_i_1d(ji,jk) + rt0
363            ! Conversion q(S,T) -> T (second order equation)
364            zaaa          =  cpic
365            zbbb          =  ( rcp - cpic ) * ( ztmelts - rt0 ) + e_i_1d(ji,jk) * r1_rhoic - lfus
366            zccc          =  lfus * ( ztmelts - rt0 )
367            zdiscrim      =  SQRT( MAX( zbbb * zbbb - 4._wp * zaaa * zccc, 0._wp ) )
368            t_i_1d(ji,jk) =  rt0 - ( zbbb + zdiscrim ) / ( 2._wp * zaaa )
369           
370            ! mask temperature
371            rswitch       =  1._wp - MAX( 0._wp , SIGN( 1._wp , - ht_i_1d(ji) ) ) 
372            t_i_1d(ji,jk) =  rswitch * t_i_1d(ji,jk) + ( 1._wp - rswitch ) * rt0
373         END DO
374      END DO 
375      !
376   END SUBROUTINE lim_thd_temp
377
378
379   SUBROUTINE lim_thd_lam( kideb, kiut )
380      !!-----------------------------------------------------------------------
381      !!                   ***  ROUTINE lim_thd_lam ***
382      !!                 
383      !! ** Purpose :   Lateral melting in case monocategory
384      !!                          ( dA = A/2h dh )
385      !!-----------------------------------------------------------------------
386      INTEGER, INTENT(in) ::   kideb, kiut        ! bounds for the spatial loop
387      !
388      INTEGER  ::   ji                 ! dummy loop indices
389      REAL(wp) ::   zhi_bef            ! ice thickness before thermo
390      REAL(wp) ::   zdh_mel, zda_mel   ! net melting
391      REAL(wp) ::   zvi, zvs           ! ice/snow volumes
392      !!-----------------------------------------------------------------------
393      !
394      DO ji = kideb, kiut
395         zdh_mel = MIN( 0._wp, dh_i_surf(ji) + dh_i_bott(ji) + dh_snowice(ji) + dh_i_sub(ji) )
396         IF( zdh_mel < 0._wp .AND. a_i_1d(ji) > 0._wp )  THEN
397            zvi          = a_i_1d(ji) * ht_i_1d(ji)
398            zvs          = a_i_1d(ji) * ht_s_1d(ji)
399            ! lateral melting = concentration change
400            zhi_bef     = ht_i_1d(ji) - zdh_mel
401            rswitch     = MAX( 0._wp , SIGN( 1._wp , zhi_bef - epsi20 ) )
402            zda_mel     = rswitch * a_i_1d(ji) * zdh_mel / ( 2._wp * MAX( zhi_bef, epsi20 ) )
403            a_i_1d(ji)  = MAX( epsi20, a_i_1d(ji) + zda_mel ) 
404            ! adjust thickness
405            ht_i_1d(ji) = zvi / a_i_1d(ji)           
406            ht_s_1d(ji) = zvs / a_i_1d(ji)           
407            ! retrieve total concentration
408            at_i_1d(ji) = a_i_1d(ji)
409         END IF
410      END DO
411      !
412   END SUBROUTINE lim_thd_lam
413
414
415   SUBROUTINE lim_thd_1d2d( nidx, jl, kn )
416      !!-----------------------------------------------------------------------
417      !!                   ***  ROUTINE lim_thd_1d2d ***
418      !!                 
419      !! ** Purpose :   move arrays from 1d to 2d and the reverse
420      !!-----------------------------------------------------------------------
421      INTEGER, INTENT(in) ::   kn       ! 1= from 2D to 1D   ;   2= from 1D to 2D
422      INTEGER, INTENT(in) ::   nidx     ! size of 1D arrays
423      INTEGER, INTENT(in) ::   jl       ! ice cat
424      !
425      INTEGER             ::   jk       ! dummy loop indices
426      !!-----------------------------------------------------------------------
427      !
428      SELECT CASE( kn )
429      !
430      CASE( 1 )            ! from 2D to 1D
431         !
432         CALL tab_2d_1d( nidx, at_i_1d     (1:nidx), at_i            , jpi, jpj, idxice(1:nidx) )
433         CALL tab_2d_1d( nidx, a_i_1d      (1:nidx), a_i(:,:,jl)     , jpi, jpj, idxice(1:nidx) )
434         CALL tab_2d_1d( nidx, ht_i_1d     (1:nidx), ht_i(:,:,jl)    , jpi, jpj, idxice(1:nidx) )
435         CALL tab_2d_1d( nidx, ht_s_1d     (1:nidx), ht_s(:,:,jl)    , jpi, jpj, idxice(1:nidx) )
436         !
437         CALL tab_2d_1d( nidx, t_su_1d     (1:nidx), t_su(:,:,jl)    , jpi, jpj, idxice(1:nidx) )
438         CALL tab_2d_1d( nidx, sm_i_1d     (1:nidx), sm_i(:,:,jl)    , jpi, jpj, idxice(1:nidx) )
439         DO jk = 1, nlay_s
440            CALL tab_2d_1d( nidx, t_s_1d(1:nidx,jk), t_s(:,:,jk,jl)  , jpi, jpj, idxice(1:nidx) )
441            CALL tab_2d_1d( nidx, e_s_1d(1:nidx,jk), e_s(:,:,jk,jl)  , jpi, jpj, idxice(1:nidx) )
442         END DO
443         DO jk = 1, nlay_i
444            CALL tab_2d_1d( nidx, t_i_1d(1:nidx,jk), t_i(:,:,jk,jl)  , jpi, jpj, idxice(1:nidx) )
445            CALL tab_2d_1d( nidx, e_i_1d(1:nidx,jk), e_i(:,:,jk,jl)  , jpi, jpj, idxice(1:nidx) )
446            CALL tab_2d_1d( nidx, s_i_1d(1:nidx,jk), s_i(:,:,jk,jl)  , jpi, jpj, idxice(1:nidx) )
447         END DO
448         !
449         CALL tab_2d_1d( nidx, qprec_ice_1d(1:nidx), qprec_ice(:,:) , jpi, jpj, idxice(1:nidx) )
450         CALL tab_2d_1d( nidx, qevap_ice_1d(1:nidx), qevap_ice(:,:,jl) , jpi, jpj, idxice(1:nidx) )
451         CALL tab_2d_1d( nidx, qsr_ice_1d (1:nidx), qsr_ice(:,:,jl) , jpi, jpj, idxice(1:nidx) )
452         CALL tab_2d_1d( nidx, fr1_i0_1d  (1:nidx), fr1_i0          , jpi, jpj, idxice(1:nidx) )
453         CALL tab_2d_1d( nidx, fr2_i0_1d  (1:nidx), fr2_i0          , jpi, jpj, idxice(1:nidx) )
454         CALL tab_2d_1d( nidx, qns_ice_1d (1:nidx), qns_ice(:,:,jl) , jpi, jpj, idxice(1:nidx) )
455         CALL tab_2d_1d( nidx, ftr_ice_1d (1:nidx), ftr_ice(:,:,jl) , jpi, jpj, idxice(1:nidx) )
456         CALL tab_2d_1d( nidx, evap_ice_1d (1:nidx), evap_ice(:,:,jl), jpi, jpj, idxice(1:nidx) )
457         CALL tab_2d_1d( nidx, dqns_ice_1d(1:nidx), dqns_ice(:,:,jl), jpi, jpj, idxice(1:nidx) )
458         CALL tab_2d_1d( nidx, t_bo_1d     (1:nidx), t_bo            , jpi, jpj, idxice(1:nidx) )
459         CALL tab_2d_1d( nidx, sprecip_1d (1:nidx), sprecip         , jpi, jpj, idxice(1:nidx) ) 
460         CALL tab_2d_1d( nidx, fhtur_1d   (1:nidx), fhtur           , jpi, jpj, idxice(1:nidx) )
461         CALL tab_2d_1d( nidx, fhld_1d    (1:nidx), fhld            , jpi, jpj, idxice(1:nidx) )
462         !
463         CALL tab_2d_1d( nidx, wfx_snw_sni_1d(1:nidx), wfx_snw_sni  , jpi, jpj, idxice(1:nidx) )
464         CALL tab_2d_1d( nidx, wfx_snw_sum_1d(1:nidx), wfx_snw_sum  , jpi, jpj, idxice(1:nidx) )
465         CALL tab_2d_1d( nidx, wfx_sub_1d (1:nidx), wfx_sub         , jpi, jpj, idxice(1:nidx) )
466         CALL tab_2d_1d( nidx, wfx_snw_sub_1d(1:nidx), wfx_snw_sub  , jpi, jpj, idxice(1:nidx) )
467         CALL tab_2d_1d( nidx, wfx_ice_sub_1d(1:nidx), wfx_ice_sub  , jpi, jpj, idxice(1:nidx) )
468         CALL tab_2d_1d( nidx, wfx_err_sub_1d(1:nidx), wfx_err_sub  , jpi, jpj, idxice(1:nidx) )
469         !
470         CALL tab_2d_1d( nidx, wfx_bog_1d (1:nidx), wfx_bog         , jpi, jpj, idxice(1:nidx) )
471         CALL tab_2d_1d( nidx, wfx_bom_1d (1:nidx), wfx_bom         , jpi, jpj, idxice(1:nidx) )
472         CALL tab_2d_1d( nidx, wfx_sum_1d (1:nidx), wfx_sum         , jpi, jpj, idxice(1:nidx) )
473         CALL tab_2d_1d( nidx, wfx_sni_1d (1:nidx), wfx_sni         , jpi, jpj, idxice(1:nidx) )
474         CALL tab_2d_1d( nidx, wfx_res_1d (1:nidx), wfx_res         , jpi, jpj, idxice(1:nidx) )
475         CALL tab_2d_1d( nidx, wfx_spr_1d (1:nidx), wfx_spr         , jpi, jpj, idxice(1:nidx) )
476         !
477         CALL tab_2d_1d( nidx, sfx_bog_1d (1:nidx), sfx_bog         , jpi, jpj, idxice(1:nidx) )
478         CALL tab_2d_1d( nidx, sfx_bom_1d (1:nidx), sfx_bom         , jpi, jpj, idxice(1:nidx) )
479         CALL tab_2d_1d( nidx, sfx_sum_1d (1:nidx), sfx_sum         , jpi, jpj, idxice(1:nidx) )
480         CALL tab_2d_1d( nidx, sfx_sni_1d (1:nidx), sfx_sni         , jpi, jpj, idxice(1:nidx) )
481         CALL tab_2d_1d( nidx, sfx_bri_1d (1:nidx), sfx_bri         , jpi, jpj, idxice(1:nidx) )
482         CALL tab_2d_1d( nidx, sfx_res_1d (1:nidx), sfx_res         , jpi, jpj, idxice(1:nidx) )
483         CALL tab_2d_1d( nidx, sfx_sub_1d (1:nidx), sfx_sub         , jpi, jpj,idxice(1:nidx) )
484         !
485         CALL tab_2d_1d( nidx, hfx_thd_1d (1:nidx), hfx_thd         , jpi, jpj, idxice(1:nidx) )
486         CALL tab_2d_1d( nidx, hfx_spr_1d (1:nidx), hfx_spr         , jpi, jpj, idxice(1:nidx) )
487         CALL tab_2d_1d( nidx, hfx_sum_1d (1:nidx), hfx_sum         , jpi, jpj, idxice(1:nidx) )
488         CALL tab_2d_1d( nidx, hfx_bom_1d (1:nidx), hfx_bom         , jpi, jpj, idxice(1:nidx) )
489         CALL tab_2d_1d( nidx, hfx_bog_1d (1:nidx), hfx_bog         , jpi, jpj, idxice(1:nidx) )
490         CALL tab_2d_1d( nidx, hfx_dif_1d (1:nidx), hfx_dif         , jpi, jpj, idxice(1:nidx) )
491         CALL tab_2d_1d( nidx, hfx_opw_1d (1:nidx), hfx_opw         , jpi, jpj, idxice(1:nidx) )
492         CALL tab_2d_1d( nidx, hfx_snw_1d (1:nidx), hfx_snw         , jpi, jpj, idxice(1:nidx) )
493         CALL tab_2d_1d( nidx, hfx_sub_1d (1:nidx), hfx_sub         , jpi, jpj, idxice(1:nidx) )
494         CALL tab_2d_1d( nidx, hfx_err_1d (1:nidx), hfx_err         , jpi, jpj, idxice(1:nidx) )
495         CALL tab_2d_1d( nidx, hfx_res_1d (1:nidx), hfx_res         , jpi, jpj, idxice(1:nidx) )
496         CALL tab_2d_1d( nidx, hfx_err_dif_1d (1:nidx), hfx_err_dif , jpi, jpj, idxice(1:nidx) )
497         CALL tab_2d_1d( nidx, hfx_err_rem_1d (1:nidx), hfx_err_rem , jpi, jpj, idxice(1:nidx) )
498         CALL tab_2d_1d( nidx, hfx_out_1d (1:nidx), hfx_out         , jpi, jpj, idxice(1:nidx) )
499         !
500         ! SIMIP diagnostics
501         CALL tab_2d_1d( nidx, diag_fc_bo_1d   (1:nidx), diag_fc_bo  , jpi, jpj, idxice(1:nidx) )
502         CALL tab_2d_1d( nidx, diag_fc_su_1d   (1:nidx), diag_fc_su  , jpi, jpj, idxice(1:nidx) )
503         ! ocean surface fields
504         CALL tab_2d_1d( nidx, sst_1d(1:nidx), sst_m, jpi, jpj, idxice(1:nidx) )
505         CALL tab_2d_1d( nidx, sss_1d(1:nidx), sss_m, jpi, jpj, idxice(1:nidx) )
506         !
507      CASE( 2 )            ! from 1D to 2D
508         !
509         CALL tab_1d_2d( nidx, at_i          , idxice, at_i_1d    (1:nidx)   , jpi, jpj )
510         CALL tab_1d_2d( nidx, ht_i(:,:,jl)  , idxice, ht_i_1d    (1:nidx)   , jpi, jpj )
511         CALL tab_1d_2d( nidx, ht_s(:,:,jl)  , idxice, ht_s_1d    (1:nidx)   , jpi, jpj )
512         CALL tab_1d_2d( nidx, a_i (:,:,jl)  , idxice, a_i_1d     (1:nidx)   , jpi, jpj )
513         CALL tab_1d_2d( nidx, t_su(:,:,jl)  , idxice, t_su_1d    (1:nidx)   , jpi, jpj )
514         CALL tab_1d_2d( nidx, sm_i(:,:,jl)  , idxice, sm_i_1d    (1:nidx)   , jpi, jpj )
515         DO jk = 1, nlay_s
516            CALL tab_1d_2d( nidx, t_s(:,:,jk,jl), idxice, t_s_1d     (1:nidx,jk), jpi, jpj)
517            CALL tab_1d_2d( nidx, e_s(:,:,jk,jl), idxice, e_s_1d     (1:nidx,jk), jpi, jpj)
518         END DO
519         DO jk = 1, nlay_i
520            CALL tab_1d_2d( nidx, t_i(:,:,jk,jl), idxice, t_i_1d     (1:nidx,jk), jpi, jpj)
521            CALL tab_1d_2d( nidx, e_i(:,:,jk,jl), idxice, e_i_1d     (1:nidx,jk), jpi, jpj)
522            CALL tab_1d_2d( nidx, s_i(:,:,jk,jl), idxice, s_i_1d     (1:nidx,jk), jpi, jpj)
523         END DO
524         !
525         CALL tab_1d_2d( nidx, wfx_snw_sni   , idxice, wfx_snw_sni_1d(1:nidx), jpi, jpj )
526         CALL tab_1d_2d( nidx, wfx_snw_sum   , idxice, wfx_snw_sum_1d(1:nidx),jpi, jpj )
527         CALL tab_1d_2d( nidx, wfx_sub       , idxice, wfx_sub_1d(1:nidx)   , jpi, jpj )
528         CALL tab_1d_2d( nidx, wfx_snw_sub   , idxice, wfx_snw_sub_1d(1:nidx), jpi, jpj )
529         CALL tab_1d_2d( nidx, wfx_ice_sub   , idxice, wfx_ice_sub_1d(1:nidx), jpi, jpj )
530         CALL tab_1d_2d( nidx, wfx_err_sub   , idxice, wfx_err_sub_1d(1:nidx), jpi, jpj )
531         !
532         CALL tab_1d_2d( nidx, wfx_bog       , idxice, wfx_bog_1d(1:nidx)   , jpi, jpj )
533         CALL tab_1d_2d( nidx, wfx_bom       , idxice, wfx_bom_1d(1:nidx)   , jpi, jpj )
534         CALL tab_1d_2d( nidx, wfx_sum       , idxice, wfx_sum_1d(1:nidx)   , jpi, jpj )
535         CALL tab_1d_2d( nidx, wfx_sni       , idxice, wfx_sni_1d(1:nidx)   , jpi, jpj )
536         CALL tab_1d_2d( nidx, wfx_res       , idxice, wfx_res_1d(1:nidx)   , jpi, jpj )
537         CALL tab_1d_2d( nidx, wfx_spr       , idxice, wfx_spr_1d(1:nidx)   , jpi, jpj )
538         !
539         CALL tab_1d_2d( nidx, sfx_bog       , idxice, sfx_bog_1d(1:nidx)   , jpi, jpj )
540         CALL tab_1d_2d( nidx, sfx_bom       , idxice, sfx_bom_1d(1:nidx)   , jpi, jpj )
541         CALL tab_1d_2d( nidx, sfx_sum       , idxice, sfx_sum_1d(1:nidx)   , jpi, jpj )
542         CALL tab_1d_2d( nidx, sfx_sni       , idxice, sfx_sni_1d(1:nidx)   , jpi, jpj )
543         CALL tab_1d_2d( nidx, sfx_res       , idxice, sfx_res_1d(1:nidx)   , jpi, jpj )
544         CALL tab_1d_2d( nidx, sfx_bri       , idxice, sfx_bri_1d(1:nidx)   , jpi, jpj )
545         CALL tab_1d_2d( nidx, sfx_sub       , idxice, sfx_sub_1d(1:nidx)   , jpi, jpj )       
546         !
547         CALL tab_1d_2d( nidx, hfx_thd       , idxice, hfx_thd_1d(1:nidx)   , jpi, jpj )
548         CALL tab_1d_2d( nidx, hfx_spr       , idxice, hfx_spr_1d(1:nidx)   , jpi, jpj )
549         CALL tab_1d_2d( nidx, hfx_sum       , idxice, hfx_sum_1d(1:nidx)   , jpi, jpj )
550         CALL tab_1d_2d( nidx, hfx_bom       , idxice, hfx_bom_1d(1:nidx)   , jpi, jpj )
551         CALL tab_1d_2d( nidx, hfx_bog       , idxice, hfx_bog_1d(1:nidx)   , jpi, jpj )
552         CALL tab_1d_2d( nidx, hfx_dif       , idxice, hfx_dif_1d(1:nidx)   , jpi, jpj )
553         CALL tab_1d_2d( nidx, hfx_opw       , idxice, hfx_opw_1d(1:nidx)   , jpi, jpj )
554         CALL tab_1d_2d( nidx, hfx_snw       , idxice, hfx_snw_1d(1:nidx)   , jpi, jpj )
555         CALL tab_1d_2d( nidx, hfx_sub       , idxice, hfx_sub_1d(1:nidx)   , jpi, jpj )
556         CALL tab_1d_2d( nidx, hfx_err       , idxice, hfx_err_1d(1:nidx)   , jpi, jpj )
557         CALL tab_1d_2d( nidx, hfx_res       , idxice, hfx_res_1d(1:nidx)   , jpi, jpj )
558         CALL tab_1d_2d( nidx, hfx_err_rem   , idxice, hfx_err_rem_1d(1:nidx), jpi, jpj )
559         CALL tab_1d_2d( nidx, hfx_err_dif   , idxice, hfx_err_dif_1d(1:nidx), jpi, jpj )
560         CALL tab_1d_2d( nidx, hfx_out       , idxice, hfx_out_1d(1:nidx)   , jpi, jpj )
561         !
562         CALL tab_1d_2d( nidx, qns_ice(:,:,jl), idxice, qns_ice_1d(1:nidx) , jpi, jpj)
563         CALL tab_1d_2d( nidx, ftr_ice(:,:,jl), idxice, ftr_ice_1d(1:nidx) , jpi, jpj )
564         !
565         ! SIMIP diagnostics         
566         CALL tab_1d_2d( nidx, t_si(:,:,jl)   , idxice, t_si_1d    (1:nidx)     , jpi, jpj )
567         CALL tab_1d_2d( nidx, diag_fc_bo     , idxice, diag_fc_bo_1d(1:nidx)   , jpi, jpj )
568         CALL tab_1d_2d( nidx, diag_fc_su     , idxice, diag_fc_su_1d(1:nidx)   , jpi, jpj )
569      END SELECT
570      !
571   END SUBROUTINE lim_thd_1d2d
572
573
574   SUBROUTINE lim_thd_init
575      !!-----------------------------------------------------------------------
576      !!                   ***  ROUTINE lim_thd_init ***
577      !!                 
578      !! ** Purpose :   Physical constants and parameters linked to the ice
579      !!              thermodynamics
580      !!
581      !! ** Method  :   Read the namicethd namelist and check the ice-thermo
582      !!              parameter values called at the first timestep (nit000)
583      !!
584      !! ** input   :   Namelist namicether
585      !!-------------------------------------------------------------------
586      INTEGER  ::   ios                 ! Local integer output status for namelist read
587      NAMELIST/namicethd/ rn_kappa_i, nn_ice_thcon, ln_dqnsice, rn_cdsn,                                  &
588         &                ln_limdH, rn_betas,                                                             &
589         &                ln_limdA, rn_beta, rn_dmin,                                                     &
590         &                ln_limdO, rn_hnewice, ln_frazil, rn_maxfrazb, rn_vfrazb, rn_Cfrazb, rn_himin,   &
591         &                nn_limflx
592      !!-------------------------------------------------------------------
593      !
594      REWIND( numnam_ice_ref )              ! Namelist namicethd in reference namelist : Ice thermodynamics
595      READ  ( numnam_ice_ref, namicethd, IOSTAT = ios, ERR = 901)
596901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in reference namelist', lwp )
597
598      REWIND( numnam_ice_cfg )              ! Namelist namicethd in configuration namelist : Ice thermodynamics
599      READ  ( numnam_ice_cfg, namicethd, IOSTAT = ios, ERR = 902 )
600902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in configuration namelist', lwp )
601      IF(lwm) WRITE ( numoni, namicethd )
602      !
603      !
604      IF(lwp) THEN                          ! control print
605         WRITE(numout,*) 'lim_thd_init : Ice Thermodynamics'
606         WRITE(numout,*) '~~~~~~~~~~~~~'
607         WRITE(numout,*)'   -- limthd_dif --'
608         WRITE(numout,*)'      extinction radiation parameter in sea ice               rn_kappa_i   = ', rn_kappa_i
609         WRITE(numout,*)'      switch for comp. of thermal conductivity in the ice     nn_ice_thcon = ', nn_ice_thcon
610         WRITE(numout,*)'      change the surface non-solar flux with Tsu or not       ln_dqnsice   = ', ln_dqnsice
611         WRITE(numout,*)'      thermal conductivity of the snow                        rn_cdsn      = ', rn_cdsn
612         WRITE(numout,*)'   -- limthd_dh --'
613         WRITE(numout,*)'      activate ice thick change from top/bot (T) or not (F)   ln_limdH     = ', ln_limdH
614         WRITE(numout,*)'      coefficient for ice-lead partition of snowfall          rn_betas     = ', rn_betas
615         WRITE(numout,*)'   -- limthd_da --'
616         WRITE(numout,*)'      activate lateral melting (T) or not (F)                 ln_limdA     = ', ln_limdA
617         WRITE(numout,*)'      Coef. beta for lateral melting param.                   rn_beta      = ', rn_beta
618         WRITE(numout,*)'      Minimum floe diameter for lateral melting param.        rn_dmin      = ', rn_dmin
619         WRITE(numout,*)'   -- limthd_lac --'
620         WRITE(numout,*)'      activate ice growth in open-water (T) or not (F)        ln_limdO     = ', ln_limdO
621         WRITE(numout,*)'      ice thick. for lateral accretion                        rn_hnewice   = ', rn_hnewice
622         WRITE(numout,*)'      Frazil ice thickness as a function of wind or not       ln_frazil    = ', ln_frazil
623         WRITE(numout,*)'      Maximum proportion of frazil ice collecting at bottom   rn_maxfrazb  = ', rn_maxfrazb
624         WRITE(numout,*)'      Thresold relative drift speed for collection of frazil  rn_vfrazb    = ', rn_vfrazb
625         WRITE(numout,*)'      Squeezing coefficient for collection of frazil          rn_Cfrazb    = ', rn_Cfrazb
626         WRITE(numout,*)'   -- limitd_th --'
627         WRITE(numout,*)'      minimum ice thickness                                   rn_himin     = ', rn_himin 
628         WRITE(numout,*)'      check heat conservation in the ice/snow                 con_i        = ', con_i
629         WRITE(numout,*)'   -- icestp --'
630         WRITE(numout,*)'      Multicategory heat flux formulation                     nn_limflx    = ', nn_limflx
631      ENDIF
632      !
633      IF ( rn_hnewice < rn_himin )   CALL ctl_stop( 'STOP', 'lim_thd_init : rn_hnewice should be >= rn_himin' )
634      !
635      IF(lwp) WRITE(numout,*)
636      SELECT CASE( nn_limflx )         ! LIM3 Multi-category heat flux formulation
637      CASE ( -1 )
638         IF(lwp) WRITE(numout,*) '   LIM3: use per-category fluxes (nn_limflx = -1) '
639         IF( ln_cpl )   CALL ctl_stop( 'sbc_init : the chosen nn_limflx for LIM3 in coupled mode must be 0 or 2' )
640      CASE ( 0  )
641         IF(lwp) WRITE(numout,*) '   LIM3: use average per-category fluxes (nn_limflx = 0) '
642      CASE ( 1  )
643         IF(lwp) WRITE(numout,*) '   LIM3: use average then redistribute per-category fluxes (nn_limflx = 1) '
644         IF( ln_cpl )   CALL ctl_stop( 'sbc_init : the chosen nn_limflx for LIM3 in coupled mode must be 0 or 2' )
645      CASE ( 2  )
646         IF(lwp) WRITE(numout,*) '   LIM3: Redistribute a single flux over categories (nn_limflx = 2) '
647         IF( .NOT. ln_cpl )   CALL ctl_stop( 'sbc_init : the chosen nn_limflx for LIM3 in forced mode cannot be 2' )
648      CASE DEFAULT
649         CALL ctl_stop( 'sbcmod: LIM3 option, nn_limflx, should be between -1 and 2' )
650      END SELECT
651      !
652   END SUBROUTINE lim_thd_init
653
654#else
655   !!----------------------------------------------------------------------
656   !!   Default option         Dummy module          NO  LIM3 sea-ice model
657   !!----------------------------------------------------------------------
658#endif
659
660   !!======================================================================
661END MODULE limthd
Note: See TracBrowser for help on using the repository browser.