source: branches/CNRS/dev_r6270_PISCES_QUOTA/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zflx.F90 @ 8003

Last change on this file since 8003 was 8003, checked in by aumont, 4 years ago

modification in the code to remove unnecessary parts such as kriest and non iomput options

  • Property svn:keywords set to Id
File size: 19.7 KB
Line 
1MODULE p4zflx
2   !!======================================================================
3   !!                         ***  MODULE p4zflx  ***
4   !! TOP :   PISCES CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE
5   !!======================================================================
6   !! History :    -   !  1988-07  (E. MAIER-REIMER) Original code
7   !!              -   !  1998     (O. Aumont) additions
8   !!              -   !  1999     (C. Le Quere) modifications
9   !!             1.0  !  2004     (O. Aumont) modifications
10   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
11   !!                  !  2011-02  (J. Simeon, J. Orr) Include total atm P correction
12   !!             3.6  !  2015-05  (O. Aumont) PISCES quota
13   !!----------------------------------------------------------------------
14#if defined key_pisces || defined key_pisces_quota
15   !!----------------------------------------------------------------------
16   !!   'key_pisces*'                                      PISCES bio-model
17   !!----------------------------------------------------------------------
18   !!   p4z_flx       :   CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE
19   !!   p4z_flx_init  :   Read the namelist
20   !!   p4z_patm      :   Read sfc atm pressure [atm] for each grid cell
21   !!----------------------------------------------------------------------
22   USE oce_trc                      !  shared variables between ocean and passive tracers
23   USE trc                          !  passive tracers common variables
24   USE sms_pisces                   !  PISCES Source Minus Sink variables
25   USE p4zche                       !  Chemical model
26   USE prtctl_trc                   !  print control for debugging
27   USE iom                          !  I/O manager
28   USE fldread                      !  read input fields
29#if defined key_cpl_carbon_cycle
30   USE sbc_oce, ONLY :  atm_co2     !  atmospheric pCO2               
31#endif
32
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   p4z_flx 
37   PUBLIC   p4z_flx_init 
38   PUBLIC   p4z_flx_alloc 
39
40   !                               !!** Namelist  nampisext  **
41   REAL(wp)          ::  atcco2     !: pre-industrial atmospheric [co2] (ppm)   
42   LOGICAL           ::  ln_co2int  !: flag to read in a file and interpolate atmospheric pco2 or not
43   CHARACTER(len=34) ::  clname     !: filename of pco2 values
44   INTEGER           ::  nn_offset  !: Offset model-data start year (default = 0)
45
46   !!  Variables related to reading atmospheric CO2 time history   
47   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:) :: atcco2h, years
48   INTEGER  :: nmaxrec, numco2
49
50   !                               !!* nampisatm namelist (Atmospheric PRessure) *
51   LOGICAL, PUBLIC ::   ln_presatm  !: ref. pressure: global mean Patm (F) or a constant (F)
52
53   REAL(wp) , ALLOCATABLE, SAVE, DIMENSION(:,:)  ::  patm      ! atmospheric pressure at kt                 [N/m2]
54   TYPE(FLD), ALLOCATABLE,       DIMENSION(:)    ::  sf_patm   ! structure of input fields (file informations, fields read)
55   LOGICAL, PUBLIC ::   ln_presatmco2  !: accounting for spatial atm CO2 in the compuation of carbon flux (T) or not (F)
56   TYPE(FLD), ALLOCATABLE,       DIMENSION(:)    ::  sf_atmco2   ! structure of input fields (file informations, fields read)
57
58   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: oce_co2   !: ocean carbon flux
59   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: satmco2   !: atmospheric pco2
60
61   REAL(wp) ::  xconv  = 0.01_wp / 3600._wp !: coefficients for conversion
62
63   !!* Substitution
64#  include "top_substitute.h90"
65   !!----------------------------------------------------------------------
66   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
67   !! $Id$
68   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
69   !!----------------------------------------------------------------------
70CONTAINS
71
72   SUBROUTINE p4z_flx ( kt, knt )
73      !!---------------------------------------------------------------------
74      !!                     ***  ROUTINE p4z_flx  ***
75      !!
76      !! ** Purpose :   CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE
77      !!
78      !! ** Method  :
79      !!              - Include total atm P correction via Esbensen & Kushnir (1981)
80      !!              - Pressure correction NOT done for key_cpl_carbon_cycle
81      !!              - Remove Wanninkhof chemical enhancement;
82      !!              - Add option for time-interpolation of atcco2.txt 
83      !!---------------------------------------------------------------------
84      !
85      INTEGER, INTENT(in) ::   kt, knt   !
86      !
87      INTEGER  ::   ji, jj, jm, iind, iindm1
88      REAL(wp) ::   ztc, ztc2, ztc3, ztc4, zws, zkgwan
89      REAL(wp) ::   zfld, zflu, zfld16, zflu16, zfact
90      REAL(wp) ::   zvapsw, zsal, zfco2, zxc2, xCO2approx, ztkel, zfugcoeff
91      REAL(wp) ::   zph, zdic, zsch_o2, zsch_co2
92      REAL(wp) ::   zyr_dec, zdco2dt
93      CHARACTER (len=25) :: charout
94      REAL(wp), POINTER, DIMENSION(:,:) :: zkgco2, zkgo2, zh2co3, zoflx, zw2d, zpco2atm
95      !!---------------------------------------------------------------------
96      !
97      IF( nn_timing == 1 )  CALL timing_start('p4z_flx')
98      !
99      CALL wrk_alloc( jpi, jpj, zkgco2, zkgo2, zh2co3, zoflx, zpco2atm )
100      !
101
102      ! SURFACE CHEMISTRY (PCO2 AND [H+] IN
103      !     SURFACE LAYER); THE RESULT OF THIS CALCULATION
104      !     IS USED TO COMPUTE AIR-SEA FLUX OF CO2
105
106      IF( kt /= nit000 .AND. knt == 1 ) CALL p4z_patm( kt )    ! Get sea-level pressure (E&K [1981] climatology) for use in flux calcs
107
108      IF( ln_co2int .AND. .NOT.ln_presatmco2 ) THEN
109         ! Linear temporal interpolation  of atmospheric pco2.  atcco2.txt has annual values.
110         ! Caveats: First column of .txt must be in years, decimal  years preferably.
111         ! For nn_offset, if your model year is iyy, nn_offset=(years(1)-iyy)
112         ! then the first atmospheric CO2 record read is at years(1)
113         zyr_dec = REAL( nyear + nn_offset, wp ) + REAL( nday_year, wp ) / REAL( nyear_len(1), wp )
114         jm = 1
115         DO WHILE( jm <= nmaxrec .AND. years(jm) < zyr_dec ) ;  jm = jm + 1 ;  END DO
116         iind = jm  ;   iindm1 = jm - 1
117         zdco2dt = ( atcco2h(iind) - atcco2h(iindm1) ) / ( years(iind) - years(iindm1) + rtrn )
118         atcco2  = zdco2dt * ( zyr_dec - years(iindm1) ) + atcco2h(iindm1)
119         satmco2(:,:) = atcco2 
120      ENDIF
121
122#if defined key_cpl_carbon_cycle
123      satmco2(:,:) = atm_co2(:,:)
124#endif
125
126      DO jj = 1, jpj
127         DO ji = 1, jpi
128            ! DUMMY VARIABLES FOR DIC, H+, AND BORATE
129            zfact = rhop(ji,jj,1) / 1000. + rtrn
130            zdic  = trb(ji,jj,1,jpdic) 
131            zph   = MAX( hi(ji,jj,1), 1.e-10 ) / zfact
132            ! CALCULATE [H2CO3]
133            zh2co3(ji,jj) = zdic/(1. + ak13(ji,jj,1)/zph + ak13(ji,jj,1)*ak23(ji,jj,1)/zph**2)
134         END DO
135      END DO
136
137      ! --------------
138      ! COMPUTE FLUXES
139      ! --------------
140
141      ! FIRST COMPUTE GAS EXCHANGE COEFFICIENTS
142      ! -------------------------------------------
143
144!CDIR NOVERRCHK
145      DO jj = 1, jpj
146!CDIR NOVERRCHK
147         DO ji = 1, jpi
148            ztc  = MIN( 35., tempis(ji,jj,1) )
149            ztc2 = ztc * ztc
150            ztc3 = ztc * ztc2 
151            ztc4 = ztc2 * ztc2
152            ! Compute the schmidt Number both O2 and CO2
153            zsch_co2 = 2116.8 - 136.25 * ztc + 4.7353 * ztc2 - 0.092307 * ztc3 + 0.0007555 * ztc4
154            zsch_o2  = 1920.4 - 135.6  * ztc + 5.2122 * ztc2 - 0.109390 * ztc3 + 0.0009377 * ztc4
155            !  wind speed
156            zws  = wndm(ji,jj) * wndm(ji,jj)
157            ! Compute the piston velocity for O2 and CO2
158            zkgwan = 0.251 * zws
159            zkgwan = zkgwan * xconv * ( 1.- fr_i(ji,jj) ) * tmask(ji,jj,1)
160            ! compute gas exchange for CO2 and O2
161            zkgco2(ji,jj) = zkgwan * SQRT( 660./ zsch_co2 )
162            zkgo2 (ji,jj) = zkgwan * SQRT( 660./ zsch_o2 )
163         END DO
164      END DO
165
166      DO jj = 1, jpj
167         DO ji = 1, jpi
168            ztkel = tempis(ji,jj,1) + 273.15
169            zsal  = salinprac(ji,jj,1) + ( 1.- tmask(ji,jj,1) ) * 35.
170            zvapsw = exp(24.4543 - 67.4509*(100.0/ztkel) - 4.8489*log(ztkel/100) - 0.000544*zsal)
171            zpco2atm(ji,jj) = satmco2(ji,jj) * ( patm(ji,jj) - zvapsw )
172            zxc2 = (1.0 - zpco2atm(ji,jj) * 1E-6 )**2
173            zfugcoeff = exp(patm(ji,jj) * (chemc(ji,jj,2) + 2.0 * zxc2 * chemc(ji,jj,3) )   &
174            &           / (82.05736 * ztkel))
175            zfco2 = zpco2atm(ji,jj) * zfugcoeff
176            ! Compute CO2 flux for the sea and air
177            zfld = zfco2 * chemc(ji,jj,1) * zkgco2(ji,jj)  ! (mol/L) * (m/s)
178            zflu = zh2co3(ji,jj) * zkgco2(ji,jj)                                   ! (mol/L) (m/s) ?
179            oce_co2(ji,jj) = ( zfld - zflu ) * rfact2 * e1e2t(ji,jj) * tmask(ji,jj,1) * 1000.
180            ! compute the trend
181            tra(ji,jj,1,jpdic) = tra(ji,jj,1,jpdic) + ( zfld - zflu ) * rfact2 / fse3t(ji,jj,1) * tmask(ji,jj,1)
182            ! Compute O2 flux
183            zfld16 = patm(ji,jj) * chemo2(ji,jj,1) * zkgo2(ji,jj)          ! (mol/L) * (m/s)
184            zflu16 = trb(ji,jj,1,jpoxy) * zkgo2(ji,jj)
185            zoflx(ji,jj) = ( zfld16 - zflu16 ) * tmask(ji,jj,1)
186            tra(ji,jj,1,jpoxy) = tra(ji,jj,1,jpoxy) + zoflx(ji,jj) * rfact2 / fse3t(ji,jj,1)
187         END DO
188      END DO
189
190      t_oce_co2_flx     = glob_sum( oce_co2(:,:) )                    !  Total Flux of Carbon
191      t_oce_co2_flx_cum = t_oce_co2_flx_cum + t_oce_co2_flx       !  Cumulative Total Flux of Carbon
192      t_atm_co2_flx = glob_sum( satmco2(:,:) * e1e2t(:,:) )         ! Total atmospheric pCO2
193
194      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
195         WRITE(charout, FMT="('flx ')")
196         CALL prt_ctl_trc_info(charout)
197         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
198      ENDIF
199
200      IF( lk_iomput .AND. knt == nrdttrc ) THEN
201         CALL wrk_alloc( jpi, jpj, zw2d )
202         IF( iom_use( "Cflx"  ) )  THEN
203            zw2d(:,:) = oce_co2(:,:) / e1e2t(:,:) * rfact2r
204            CALL iom_put( "Cflx"     , zw2d )
205         ENDIF
206         IF( iom_use( "Oflx"  ) )  THEN
207            zw2d(:,:) =  zoflx(:,:) * 1000 * tmask(:,:,1)
208            CALL iom_put( "Oflx" , zw2d )
209         ENDIF
210         IF( iom_use( "Kg"    ) )  THEN
211            zw2d(:,:) =  zkgco2(:,:) * tmask(:,:,1)
212            CALL iom_put( "Kg"   , zw2d )
213         ENDIF
214         IF( iom_use( "Dpco2" ) ) THEN
215           zw2d(:,:) = ( zpco2atm(:,:) - zh2co3(:,:) / ( chemc(:,:,1) + rtrn ) ) * tmask(:,:,1)
216           CALL iom_put( "Dpco2" ,  zw2d )
217         ENDIF
218         IF( iom_use( "Dpo2" ) )  THEN
219           zw2d(:,:) = ( patm(:,:) - trb(:,:,1,jpoxy) / ( chemo2(:,:,1) + rtrn ) ) * atcox * tmask(:,:,1)
220           CALL iom_put( "Dpo2"  , zw2d )
221         ENDIF
222         IF( iom_use( "tcflx" ) )  CALL iom_put( "tcflx"    , t_oce_co2_flx * rfact2r )   ! molC/s
223         CALL iom_put( "tcflxcum" , t_oce_co2_flx_cum )      ! molC
224         !
225         CALL wrk_dealloc( jpi, jpj, zw2d )
226      ENDIF
227      !
228      CALL wrk_dealloc( jpi, jpj, zkgco2, zkgo2, zh2co3, zoflx, zpco2atm )
229      !
230      IF( nn_timing == 1 )  CALL timing_stop('p4z_flx')
231      !
232   END SUBROUTINE p4z_flx
233
234
235   SUBROUTINE p4z_flx_init
236      !!----------------------------------------------------------------------
237      !!                  ***  ROUTINE p4z_flx_init  ***
238      !!
239      !! ** Purpose :   Initialization of atmospheric conditions
240      !!
241      !! ** Method  :   Read the nampisext namelist and check the parameters
242      !!      called at the first timestep (nittrc000)
243      !! ** input   :   Namelist nampisext
244      !!----------------------------------------------------------------------
245      NAMELIST/nampisext/ln_co2int, atcco2, clname, nn_offset
246      INTEGER :: jm
247      INTEGER :: ios                 ! Local integer output status for namelist read
248      !!----------------------------------------------------------------------
249      !
250
251      REWIND( numnatp_ref )              ! Namelist nampisext in reference namelist : Pisces atm. conditions
252      READ  ( numnatp_ref, nampisext, IOSTAT = ios, ERR = 901)
253901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisext in reference namelist', lwp )
254
255      REWIND( numnatp_cfg )              ! Namelist nampisext in configuration namelist : Pisces atm. conditions
256      READ  ( numnatp_cfg, nampisext, IOSTAT = ios, ERR = 902 )
257902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisext in configuration namelist', lwp )
258      IF(lwm) WRITE ( numonp, nampisext )
259      !
260      IF(lwp) THEN                         ! control print
261         WRITE(numout,*) ' '
262         WRITE(numout,*) ' Namelist parameters for air-sea exchange, nampisext'
263         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
264         WRITE(numout,*) '    Choice for reading in the atm pCO2 file or constant value, ln_co2int =', ln_co2int
265         WRITE(numout,*) ' '
266      ENDIF
267      IF( .NOT.ln_co2int .AND. .NOT.ln_presatmco2 ) THEN
268         IF(lwp) THEN                         ! control print
269            WRITE(numout,*) '    Constant Atmospheric pCO2 value  atcco2    =', atcco2
270            WRITE(numout,*) ' '
271         ENDIF
272         satmco2(:,:)  = atcco2      ! Initialisation of atmospheric pco2
273      ELSEIF(ln_co2int .AND. .NOT.ln_presatmco2) THEN
274         IF(lwp)  THEN
275            WRITE(numout,*) '    Atmospheric pCO2 value  from file clname      =', TRIM( clname )
276            WRITE(numout,*) '    Offset model-data start year      nn_offset   =', nn_offset
277            WRITE(numout,*) ' '
278         ENDIF
279         CALL ctl_opn( numco2, TRIM( clname) , 'OLD', 'FORMATTED', 'SEQUENTIAL', -1 , numout, lwp )
280         jm = 0                      ! Count the number of record in co2 file
281         DO
282           READ(numco2,*,END=100) 
283           jm = jm + 1
284         END DO
285 100     nmaxrec = jm - 1 
286         ALLOCATE( years  (nmaxrec) )     ;      years  (:) = 0._wp
287         ALLOCATE( atcco2h(nmaxrec) )     ;      atcco2h(:) = 0._wp
288
289         REWIND(numco2)
290         DO jm = 1, nmaxrec          ! get  xCO2 data
291            READ(numco2, *)  years(jm), atcco2h(jm)
292            IF(lwp) WRITE(numout, '(f6.0,f7.2)')  years(jm), atcco2h(jm)
293         END DO
294         CLOSE(numco2)
295      ELSEIF(.NOT.ln_co2int .AND. ln_presatmco2) THEN
296         IF(lwp)  THEN
297            WRITE(numout,*) '    Spatialized Atmospheric pCO2 from an external file'
298            WRITE(numout,*) ' '
299         ENDIF
300      ELSE
301         IF(lwp)  THEN
302            WRITE(numout,*) '    Spatialized Atmospheric pCO2 from an external file'
303            WRITE(numout,*) ' '
304         ENDIF
305      ENDIF
306      !
307      oce_co2(:,:)  = 0._wp                ! Initialization of Flux of Carbon
308      t_atm_co2_flx = 0._wp
309      t_oce_co2_flx = 0._wp
310      !
311      CALL p4z_patm( nit000 )
312      !
313   END SUBROUTINE p4z_flx_init
314
315   SUBROUTINE p4z_patm( kt )
316
317      !!----------------------------------------------------------------------
318      !!                  ***  ROUTINE p4z_atm  ***
319      !!
320      !! ** Purpose :   Read and interpolate the external atmospheric sea-levl pressure
321      !! ** Method  :   Read the files and interpolate the appropriate variables
322      !!
323      !!----------------------------------------------------------------------
324      !! * arguments
325      INTEGER, INTENT( in  ) ::   kt   ! ocean time step
326      !
327      INTEGER            ::  ierr
328      INTEGER            ::  ios      ! Local integer output status for namelist read
329      CHARACTER(len=100) ::  cn_dir   ! Root directory for location of ssr files
330      TYPE(FLD_N)        ::  sn_patm  ! informations about the fields to be read
331      TYPE(FLD_N)        ::  sn_atmco2 ! informations about the fields to be read
332      !!
333      NAMELIST/nampisatm/ ln_presatm, ln_presatmco2, sn_patm, sn_atmco2, cn_dir
334      !                                         ! ----------------------- !
335      IF( kt == nit000 ) THEN                   ! First call kt=nittrc000 !
336
337         REWIND( numnatp_ref )              ! Namelist nampisatm in reference namelist : Pisces atm. sea level pressure file
338         READ  ( numnatp_ref, nampisatm, IOSTAT = ios, ERR = 901)
339901      IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisatm in reference namelist', lwp )
340
341         REWIND( numnatp_cfg )              ! Namelist nampisatm in configuration namelist : Pisces atm. sea level pressure file
342         READ  ( numnatp_cfg, nampisatm, IOSTAT = ios, ERR = 902 )
343902      IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisatm in configuration namelist', lwp )
344         IF(lwm) WRITE ( numonp, nampisatm )
345         !
346         !
347         IF(lwp) THEN                                 !* control print
348            WRITE(numout,*)
349            WRITE(numout,*) '   Namelist nampisatm : Atmospheric Pressure as external forcing'
350            WRITE(numout,*) '      constant atmopsheric pressure (F) or from a file (T)  ln_presatm = ', ln_presatm
351            WRITE(numout,*) '      spatial atmopsheric CO2 for flux calcs  ln_presatmco2 = ', ln_presatmco2
352            WRITE(numout,*)
353         ENDIF
354         !
355         IF( ln_presatm ) THEN
356            ALLOCATE( sf_patm(1), STAT=ierr )           !* allocate and fill sf_patm (forcing structure) with sn_patm
357            IF( ierr > 0 )   CALL ctl_stop( 'STOP', 'p4z_flx: unable to allocate sf_patm structure' )
358            !
359            CALL fld_fill( sf_patm, (/ sn_patm /), cn_dir, 'p4z_flx', 'Atmospheric pressure ', 'nampisatm' )
360                                   ALLOCATE( sf_patm(1)%fnow(jpi,jpj,1)   )
361            IF( sn_patm%ln_tint )  ALLOCATE( sf_patm(1)%fdta(jpi,jpj,1,2) )
362         ENDIF
363         !                                         
364         IF( ln_presatmco2 ) THEN
365            ALLOCATE( sf_atmco2(1), STAT=ierr )           !* allocate and fill sf_atmco2 (forcing structure) with sn_atmco2
366            IF( ierr > 0 )   CALL ctl_stop( 'STOP', 'p4z_flx: unable to allocate sf_atmco2 structure' )
367            !
368            CALL fld_fill( sf_atmco2, (/ sn_atmco2 /), cn_dir, 'p4z_flx', 'Atmospheric co2 partial pressure ', 'nampisatm' )
369                                   ALLOCATE( sf_atmco2(1)%fnow(jpi,jpj,1)   )
370            IF( sn_atmco2%ln_tint )  ALLOCATE( sf_atmco2(1)%fdta(jpi,jpj,1,2) )
371         ENDIF
372         !
373      ENDIF
374      !
375      IF( ln_presatm ) THEN
376         CALL fld_read( kt, 1, sf_patm )               !* input Patm provided at kt + 1/2
377         patm(:,:) = sf_patm(1)%fnow(:,:,1)                        ! atmospheric pressure
378      ELSE
379         patm(:,:) = 1.e0    ! Initialize patm if no reading from a file
380      ENDIF
381      !
382      IF( ln_presatmco2 ) THEN
383         CALL fld_read( kt, 1, sf_atmco2 )               !* input atmco2 provided at kt + 1/2
384         satmco2(:,:) = sf_atmco2(1)%fnow(:,:,1)                        ! atmospheric pressure
385      ELSE
386         satmco2(:,:) = atcco2    ! Initialize atmco2 if no reading from a file
387      ENDIF
388      !
389      IF(lwp) THEN                                 !* control print
390         WRITE(numout,*) ' Min-Max atmospheric CO2 = ', MINVAL(satmco2(:,:)),MAXVAL(satmco2(:,:))
391      ENDIF
392      !
393   END SUBROUTINE p4z_patm
394
395   INTEGER FUNCTION p4z_flx_alloc()
396      !!----------------------------------------------------------------------
397      !!                     ***  ROUTINE p4z_flx_alloc  ***
398      !!----------------------------------------------------------------------
399      ALLOCATE( oce_co2(jpi,jpj), satmco2(jpi,jpj), patm(jpi,jpj), STAT=p4z_flx_alloc )
400      !
401      IF( p4z_flx_alloc /= 0 )   CALL ctl_warn('p4z_flx_alloc : failed to allocate arrays')
402      !
403   END FUNCTION p4z_flx_alloc
404
405#else
406   !!======================================================================
407   !!  Dummy module :                                   No PISCES bio-model
408   !!======================================================================
409CONTAINS
410   SUBROUTINE p4z_flx( kt )                   ! Empty routine
411      INTEGER, INTENT( in ) ::   kt
412      WRITE(*,*) 'p4z_flx: You should not have seen this print! error?', kt
413   END SUBROUTINE p4z_flx
414#endif 
415
416   !!======================================================================
417END MODULE  p4zflx
Note: See TracBrowser for help on using the repository browser.