New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zmeso.F90 in branches/CNRS/dev_r6270_PISCES_QUOTA/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/CNRS/dev_r6270_PISCES_QUOTA/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zmeso.F90 @ 7617

Last change on this file since 7617 was 7617, checked in by aumont, 8 years ago

update diagnostics + changes in quota code
File size: 20.4 KB
Line 
1MODULE p4zmeso
2   !!======================================================================
3   !!                         ***  MODULE p4zmeso  ***
4   !! TOP :   PISCES Compute the sources/sinks for mesozooplankton
5   !!======================================================================
6   !! History :   1.0  !  2002     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!----------------------------------------------------------------------
10#if defined key_pisces
11   !!----------------------------------------------------------------------
12   !!   'key_pisces'                                       PISCES bio-model
13   !!----------------------------------------------------------------------
14   !!   p4z_meso       :   Compute the sources/sinks for mesozooplankton
15   !!   p4z_meso_init  :   Initialization of the parameters for mesozooplankton
16   !!----------------------------------------------------------------------
17   USE oce_trc         !  shared variables between ocean and passive tracers
18   USE trc             !  passive tracers common variables
19   USE sms_pisces      !  PISCES Source Minus Sink variables
20   USE p4zsink         !  vertical flux of particulate matter due to sinking
21   USE p4zint          !  interpolation and computation of various fields
22   USE p4zprod         !  production
23   USE prtctl_trc      !  print control for debugging
24   USE iom             !  I/O manager
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   p4z_meso              ! called in p4zbio.F90
30   PUBLIC   p4z_meso_init         ! called in trcsms_pisces.F90
31
32   !! * Shared module variables
33   REAL(wp), PUBLIC ::  part2        !: part of calcite not dissolved in mesozoo guts
34   REAL(wp), PUBLIC ::  xprefc       !: mesozoo preference for POC
35   REAL(wp), PUBLIC ::  xprefp       !: mesozoo preference for nanophyto
36   REAL(wp), PUBLIC ::  xprefz       !: mesozoo preference for diatoms
37   REAL(wp), PUBLIC ::  xprefpoc     !: mesozoo preference for POC
38   REAL(wp), PUBLIC ::  xthresh2zoo  !: zoo feeding threshold for mesozooplankton
39   REAL(wp), PUBLIC ::  xthresh2dia  !: diatoms feeding threshold for mesozooplankton
40   REAL(wp), PUBLIC ::  xthresh2phy  !: nanophyto feeding threshold for mesozooplankton
41   REAL(wp), PUBLIC ::  xthresh2poc  !: poc feeding threshold for mesozooplankton
42   REAL(wp), PUBLIC ::  xthresh2     !: feeding threshold for mesozooplankton
43   REAL(wp), PUBLIC ::  resrat2      !: exsudation rate of mesozooplankton
44   REAL(wp), PUBLIC ::  mzrat2       !: microzooplankton mortality rate
45   REAL(wp), PUBLIC ::  grazrat2     !: maximal mesozoo grazing rate
46   REAL(wp), PUBLIC ::  xkgraz2      !: non assimilated fraction of P by mesozoo
47   REAL(wp), PUBLIC ::  unass2       !: Efficicency of mesozoo growth
48   REAL(wp), PUBLIC ::  sigma2       !: Fraction of mesozoo excretion as DOM
49   REAL(wp), PUBLIC ::  epsher2      !: half sturation constant for grazing 2
50   REAL(wp), PUBLIC ::  grazflux     !: mesozoo flux feeding rate
51
52   !!* Substitution
53#  include "top_substitute.h90"
54   !!----------------------------------------------------------------------
55   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
56   !! $Id: p4zmeso.F90 3160 2011-11-20 14:27:18Z cetlod $
57   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
58   !!----------------------------------------------------------------------
59
60CONTAINS
61
62   SUBROUTINE p4z_meso( kt, knt )
63      !!---------------------------------------------------------------------
64      !!                     ***  ROUTINE p4z_meso  ***
65      !!
66      !! ** Purpose :   Compute the sources/sinks for mesozooplankton
67      !!
68      !! ** Method  : - ???
69      !!---------------------------------------------------------------------
70      INTEGER, INTENT(in) ::   kt, knt ! ocean time step
71      INTEGER  :: ji, jj, jk
72      REAL(wp) :: zcompadi, zcompaph, zcompapoc, zcompaz, zcompam
73      REAL(wp) :: zgraze2 , zdenom, zdenom2
74      REAL(wp) :: zfact   , zstep, zfood, zfoodlim, zproport
75      REAL(wp) :: zmortzgoc, zfrac, zfracfe, zratio, zratio2, zfracal, zgrazcal
76      REAL(wp) :: zepshert, zepsherv, zgrarsig, zgraztot, zgraztotn, zgraztotf
77      REAL(wp) :: zgrarem2, zgrafer2, zgrapoc2, zprcaca, zmortz2, zgrasrat, zgrasratn
78#if defined key_kriest
79      REAL znumpoc
80#endif
81      REAL(wp) :: zrespz2, ztortz2, zgrazd, zgrazz, zgrazpof
82      REAL(wp) :: zgrazn, zgrazpoc, zgraznf, zgrazf
83      REAL(wp) :: zgrazfffp, zgrazfffg, zgrazffep, zgrazffeg
84      CHARACTER (len=25) :: charout
85      REAL(wp), POINTER, DIMENSION(:,:,:) :: zgrazing, zw3d, zfezoo2
86#if defined key_ligand
87      REAL(wp), POINTER, DIMENSION(:,:,:) :: zz2ligprod
88#endif
89
90      !!---------------------------------------------------------------------
91      !
92      IF( nn_timing == 1 )  CALL timing_start('p4z_meso')
93      !
94      CALL wrk_alloc( jpi, jpj, jpk, zgrazing, zfezoo2 )
95#if defined key_ligand
96      CALL wrk_alloc( jpi, jpj, jpk, zz2ligprod )
97      zz2ligprod(:,:,:) = 0._wp
98#endif
99      zgrazing(:,:,:) = 0._wp
100      zfezoo2(:,:,:) = 0._wp
101
102      DO jk = 1, jpkm1
103         DO jj = 1, jpj
104            DO ji = 1, jpi
105               zcompam   = MAX( ( trb(ji,jj,jk,jpmes) - 1.e-9 ), 0.e0 )
106# if defined key_degrad
107               zstep     = xstep * facvol(ji,jj,jk)
108# else
109               zstep     = xstep
110# endif
111               zfact     = zstep * tgfunc2(ji,jj,jk) * zcompam
112
113               !  Respiration rates of both zooplankton
114               !  -------------------------------------
115               zrespz2   = resrat2 * zfact * trb(ji,jj,jk,jpmes) / ( xkmort + trb(ji,jj,jk,jpmes) )  &
116                  &      + resrat2 * zfact * 3. * nitrfac(ji,jj,jk)
117
118               !  Zooplankton mortality. A square function has been selected with
119               !  no real reason except that it seems to be more stable and may mimic predation
120               !  ---------------------------------------------------------------
121               ztortz2   = mzrat2 * 1.e6 * zfact * trb(ji,jj,jk,jpmes)
122               !
123               zcompadi  = MAX( ( trb(ji,jj,jk,jpdia) - xthresh2dia ), 0.e0 )
124               zcompaz   = MAX( ( trb(ji,jj,jk,jpzoo) - xthresh2zoo ), 0.e0 )
125               ! Size effect of nanophytoplankton on grazing : the smaller it is, the less prone
126               ! it is to predation by mesozooplankton
127               ! -------------------------------------------------------------------------------
128               zcompaph  = MAX( ( trb(ji,jj,jk,jpphy) - xthresh2phy ), 0.e0 ) &
129                  &      * MIN(1., MAX( 0., ( quotan(ji,jj,jk) - 0.2) / 0.3 ) )
130               zcompapoc = MAX( ( trb(ji,jj,jk,jppoc) - xthresh2poc ), 0.e0 )
131
132               zfood     = xprefc * zcompadi + xprefz * zcompaz + xprefp * zcompaph + xprefpoc * zcompapoc 
133               zfoodlim  = MAX( 0., zfood - MIN( 0.5 * zfood, xthresh2 ) )
134               zdenom    = zfoodlim / ( xkgraz2 + zfoodlim )
135               zdenom2   = zdenom / ( zfood + rtrn )
136               zgraze2   = grazrat2 * zstep * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jpmes) 
137
138               zgrazd    = zgraze2  * xprefc   * zcompadi  * zdenom2 
139               zgrazz    = zgraze2  * xprefz   * zcompaz   * zdenom2 
140               zgrazn    = zgraze2  * xprefp   * zcompaph  * zdenom2 
141               zgrazpoc  = zgraze2  * xprefpoc * zcompapoc * zdenom2 
142
143               zgraznf   = zgrazn   * trb(ji,jj,jk,jpnfe) / ( trb(ji,jj,jk,jpphy) + rtrn)
144               zgrazf    = zgrazd   * trb(ji,jj,jk,jpdfe) / ( trb(ji,jj,jk,jpdia) + rtrn)
145               zgrazpof  = zgrazpoc * trb(ji,jj,jk,jpsfe) / ( trb(ji,jj,jk,jppoc) + rtrn)
146
147               !  Mesozooplankton flux feeding on GOC
148               !  ----------------------------------
149               !  ----------------------------------
150# if ! defined key_kriest
151               zgrazffeg = grazflux  * zstep * wsbio4(ji,jj,jk)      &
152               &           * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jpgoc) * trb(ji,jj,jk,jpmes)
153               zgrazfffg = zgrazffeg * trb(ji,jj,jk,jpbfe) / (trb(ji,jj,jk,jpgoc) + rtrn)
154# endif
155               zgrazffep = grazflux  * zstep *  wsbio3(ji,jj,jk)     &
156               &           * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jppoc) * trb(ji,jj,jk,jpmes)
157               zgrazfffp = zgrazffep * trb(ji,jj,jk,jpsfe) / (trb(ji,jj,jk,jppoc) + rtrn)
158              !
159# if ! defined key_kriest
160              zgraztot  = zgrazd + zgrazz + zgrazn + zgrazpoc + zgrazffep + zgrazffeg
161              ! Compute the proportion of filter feeders
162              zproport  = (zgrazffep + zgrazffeg)/(rtrn + zgraztot)
163              ! Compute fractionation of aggregates. It is assumed that
164              ! diatoms based aggregates are more prone to fractionation
165              ! since they are more porous (marine snow instead of fecal pellets)
166              zratio    = trb(ji,jj,jk,jpgsi) / ( trb(ji,jj,jk,jpgoc) + rtrn )
167              zratio2   = zratio * zratio
168              zfrac     = zproport * grazflux  * zstep * wsbio4(ji,jj,jk)      &
169               &          * trb(ji,jj,jk,jpgoc) * trb(ji,jj,jk,jpmes)          &
170               &          * ( 0.2 + 3.8 * zratio2 / ( 1.**2 + zratio2 ) )
171              zfracfe   = zfrac * trb(ji,jj,jk,jpbfe) / (trb(ji,jj,jk,jpgoc) + rtrn)
172
173              zgrazffep = zproport * zgrazffep
174              zgrazffeg = zproport * zgrazffeg
175              zgrazfffp = zproport * zgrazfffp
176              zgrazfffg = zproport * zgrazfffg
177              zgraztot  = zgrazd + zgrazz + zgrazn + zgrazpoc + zgrazffep + zgrazffeg
178              zgraztotn = zgrazd * quotad(ji,jj,jk) + zgrazz + zgrazn * quotan(ji,jj,jk)   &
179              &   + zgrazpoc + zgrazffep + zgrazffeg
180              zgraztotf = zgrazf + zgraznf + zgrazz * ferat3 + zgrazpof + zgrazfffp + zgrazfffg
181# else
182              zgraztot  = zgrazd + zgrazz + zgrazn + zgrazpoc + zgrazffep
183              ! Compute the proportion of filter feeders
184              zproport  = zgrazffep / ( zgraztot + rtrn )
185              zgrazffep = zproport * zgrazffep
186              zgrazfffp = zproport * zgrazfffp
187              zgraztot  = zgrazd + zgrazz + zgrazn + zgrazpoc + zgrazffep
188              zgraztotn = zgrazd * quotad(ji,jj,jk) + zgrazz + zgrazn * quotan(ji,jj,jk) + zgrazpoc + zgrazffep
189              zgraztotf = zgrazf + zgraznf + zgrazz * ferat3 + zgrazpof + zgrazfffp
190# endif
191
192              ! Total grazing ( grazing by microzoo is already computed in p4zmicro )
193              IF( lk_iomput )  zgrazing(ji,jj,jk) = zgraztot
194
195              !    Mesozooplankton efficiency
196              !    --------------------------
197               zgrasrat  =  ( zgraztotf +rtrn )/ ( zgraztot + rtrn )
198               zgrasratn =  ( zgraztotn +rtrn )/ ( zgraztot + rtrn )
199               zepshert  = MIN( 1., zgrasratn, zgrasrat / ferat3)
200               zepsherv  = zepshert * MIN( epsher2, (1. - unass2) * zgrasrat / ferat3, (1. - unass2) * zgrasratn )
201               zgrarem2  = zgraztot * ( 1. - zepsherv - unass2 ) &
202                &       + ( 1. - epsher2 - unass2 ) / ( 1. - epsher2 ) * ztortz2
203               zgrafer2  = zgraztot * MAX( 0. , ( 1. - unass2 ) * zgrasrat - ferat3 * zepsherv )    &
204                &       + ferat3 * ( ( 1. - epsher2 - unass2 ) /( 1. - epsher2 ) * ztortz2 )
205               zgrapoc2  = zgraztot * unass2
206
207               !   Update the arrays TRA which contain the biological sources and sinks
208               zgrarsig  = zgrarem2 * sigma2
209               tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zgrarsig
210               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zgrarsig
211               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zgrarem2 - zgrarsig
212#if defined key_ligand
213               tra(ji,jj,jk,jplgw) = tra(ji,jj,jk,jplgw) + (zgrarem2 - zgrarsig) * ldocz
214               zz2ligprod(ji,jj,jk) = (zgrarem2 - zgrarsig) * ldocz
215#endif
216               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2ut * zgrarsig
217               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zgrafer2
218               zfezoo2(ji,jj,jk) = zgrafer2
219               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zgrarsig
220               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * zgrarsig             
221               zmortz2 = ztortz2 + zrespz2
222               zmortzgoc = unass2 / ( 1. - epsher2 ) * ztortz2 + zrespz2
223               tra(ji,jj,jk,jpmes) = tra(ji,jj,jk,jpmes) - zmortz2 + zepsherv * zgraztot 
224               tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) - zgrazd
225               tra(ji,jj,jk,jpzoo) = tra(ji,jj,jk,jpzoo) - zgrazz
226               tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) - zgrazn
227               tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) - zgrazn * trb(ji,jj,jk,jpnch) / ( trb(ji,jj,jk,jpphy) + rtrn )
228               tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) - zgrazd * trb(ji,jj,jk,jpdch) / ( trb(ji,jj,jk,jpdia) + rtrn )
229               tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) - zgrazd * trb(ji,jj,jk,jpdsi) / ( trb(ji,jj,jk,jpdia) + rtrn )
230               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) + zgrazd * trb(ji,jj,jk,jpdsi) / ( trb(ji,jj,jk,jpdia) + rtrn )
231               tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) - zgraznf
232               tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) - zgrazf
233
234#if defined key_kriest
235              znumpoc = trb(ji,jj,jk,jpnum) / ( trb(ji,jj,jk,jppoc) + rtrn )
236              tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zmortzgoc - zgrazpoc - zgrazffep + zgrapoc2
237              tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) - zgrazpoc * znumpoc + zgrapoc2 * xkr_dmeso      &
238                 &   + zmortzgoc * xkr_dmeso - zgrazffep * znumpoc * wsbio4(ji,jj,jk) / ( wsbio3(ji,jj,jk) + rtrn )
239              tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + ferat3 * zmortzgoc - zgrazfffp - zgrazpof    &
240                 &                 + zgraztotf * unass2
241              zfracal = trb(ji,jj,jk,jpcal) / (trb(ji,jj,jk,jppoc) + rtrn )
242              zgrazcal = ( zgrazffep + zgrazpoc ) * (1. - part2) * zfracal
243#else
244              tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) - zgrazpoc - zgrazffep + zfrac
245              prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + zfrac
246              conspoc(ji,jj,jk) = conspoc(ji,jj,jk) - zgrazpoc - zgrazffep
247              tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zmortzgoc - zgrazffeg + zgrapoc2 - zfrac
248              prodgoc(ji,jj,jk) = prodgoc(ji,jj,jk) + zmortzgoc + zgrapoc2
249              consgoc(ji,jj,jk) = consgoc(ji,jj,jk) - zgrazffeg - zfrac
250              tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) - zgrazpof - zgrazfffp + zfracfe
251              tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + ferat3 * zmortzgoc - zgrazfffg     &
252                 &                + zgraztotf * unass2 - zfracfe
253              zfracal = trb(ji,jj,jk,jpcal) / (trb(ji,jj,jk,jpgoc) + rtrn )
254              zgrazcal = zgrazffeg * (1. - part2) * zfracal
255#endif
256
257               ! calcite production
258               zprcaca = xfracal(ji,jj,jk) * zgrazn
259               prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca  ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
260               !
261               zprcaca = part2 * zprcaca
262               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zgrazcal - zprcaca
263               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + 2. * ( zgrazcal - zprcaca )
264               tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) - zgrazcal + zprcaca
265
266            END DO
267         END DO
268      END DO
269      !
270      IF( lk_iomput .AND. knt == nrdttrc ) THEN
271         CALL wrk_alloc( jpi, jpj, jpk, zw3d )
272         IF( iom_use( "GRAZ2" ) ) THEN
273            zw3d(:,:,:) = zgrazing(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:)  !   Total grazing of phyto by zooplankton
274            CALL iom_put( "GRAZ2", zw3d )
275         ENDIF
276         IF( iom_use( "PCAL" ) ) THEN
277            zw3d(:,:,:) = prodcal(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:)   !  Calcite production
278            CALL iom_put( "PCAL", zw3d ) 
279         ENDIF
280         IF( iom_use( "FEZOO2" ) ) THEN
281            zw3d(:,:,:) = zfezoo2(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:)   !
282            CALL iom_put( "FEZOO2", zw3d )
283         ENDIF
284#if defined key_ligand
285         IF( iom_use( "LPRODZ2" ) )  THEN
286            zw3d(:,:,:) = zz2ligprod(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:)
287            CALL iom_put( "LPRODZ2"  , zw3d )
288         ENDIF
289#endif
290         CALL wrk_dealloc( jpi, jpj, jpk, zw3d )
291      ENDIF
292      !
293      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
294        WRITE(charout, FMT="('meso')")
295        CALL prt_ctl_trc_info(charout)
296        CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
297      ENDIF
298      !
299#if defined key_ligand
300      CALL wrk_dealloc( jpi, jpj, jpk, zgrazing, zfezoo2, zz2ligprod )
301#else
302      CALL wrk_dealloc( jpi, jpj, jpk, zgrazing, zfezoo2 )
303#endif
304      !
305      IF( nn_timing == 1 )  CALL timing_stop('p4z_meso')
306      !
307   END SUBROUTINE p4z_meso
308
309   SUBROUTINE p4z_meso_init
310
311      !!----------------------------------------------------------------------
312      !!                  ***  ROUTINE p4z_meso_init  ***
313      !!
314      !! ** Purpose :   Initialization of mesozooplankton parameters
315      !!
316      !! ** Method  :   Read the nampismes namelist and check the parameters
317      !!      called at the first timestep (nittrc000)
318      !!
319      !! ** input   :   Namelist nampismes
320      !!
321      !!----------------------------------------------------------------------
322
323      NAMELIST/nampismes/ part2, grazrat2, resrat2, mzrat2, xprefc, xprefp, xprefz,   &
324         &                xprefpoc, xthresh2dia, xthresh2phy, xthresh2zoo, xthresh2poc, &
325         &                xthresh2, xkgraz2, epsher2, sigma2, unass2, grazflux
326      INTEGER :: ios                 ! Local integer output status for namelist read
327
328      REWIND( numnatp_ref )              ! Namelist nampismes in reference namelist : Pisces mesozooplankton
329      READ  ( numnatp_ref, nampismes, IOSTAT = ios, ERR = 901)
330901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampismes in reference namelist', lwp )
331
332      REWIND( numnatp_cfg )              ! Namelist nampismes in configuration namelist : Pisces mesozooplankton
333      READ  ( numnatp_cfg, nampismes, IOSTAT = ios, ERR = 902 )
334902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampismes in configuration namelist', lwp )
335      IF(lwm) WRITE ( numonp, nampismes )
336
337
338      IF(lwp) THEN                         ! control print
339         WRITE(numout,*) ' ' 
340         WRITE(numout,*) ' Namelist parameters for mesozooplankton, nampismes'
341         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
342         WRITE(numout,*) '    part of calcite not dissolved in mesozoo guts  part2        =', part2
343         WRITE(numout,*) '    mesozoo preference for phyto                   xprefc       =', xprefc
344         WRITE(numout,*) '    mesozoo preference for POC                     xprefp       =', xprefp
345         WRITE(numout,*) '    mesozoo preference for zoo                     xprefz       =', xprefz
346         WRITE(numout,*) '    mesozoo preference for poc                     xprefpoc     =', xprefpoc
347         WRITE(numout,*) '    microzoo feeding threshold  for mesozoo        xthresh2zoo  =', xthresh2zoo
348         WRITE(numout,*) '    diatoms feeding threshold  for mesozoo         xthresh2dia  =', xthresh2dia
349         WRITE(numout,*) '    nanophyto feeding threshold for mesozoo        xthresh2phy  =', xthresh2phy
350         WRITE(numout,*) '    poc feeding threshold for mesozoo              xthresh2poc  =', xthresh2poc
351         WRITE(numout,*) '    feeding threshold for mesozooplankton          xthresh2     =', xthresh2
352         WRITE(numout,*) '    exsudation rate of mesozooplankton             resrat2      =', resrat2
353         WRITE(numout,*) '    mesozooplankton mortality rate                 mzrat2       =', mzrat2
354         WRITE(numout,*) '    maximal mesozoo grazing rate                   grazrat2     =', grazrat2
355         WRITE(numout,*) '    mesozoo flux feeding rate                      grazflux     =', grazflux
356         WRITE(numout,*) '    non assimilated fraction of P by mesozoo       unass2       =', unass2
357         WRITE(numout,*) '    Efficicency of Mesozoo growth                  epsher2      =', epsher2
358         WRITE(numout,*) '    Fraction of mesozoo excretion as DOM           sigma2       =', sigma2
359         WRITE(numout,*) '    half sturation constant for grazing 2          xkgraz2      =', xkgraz2
360      ENDIF
361
362
363   END SUBROUTINE p4z_meso_init
364
365
366#else
367   !!======================================================================
368   !!  Dummy module :                                   No PISCES bio-model
369   !!======================================================================
370CONTAINS
371   SUBROUTINE p4z_meso                    ! Empty routine
372   END SUBROUTINE p4z_meso
373#endif 
374
375   !!======================================================================
376END MODULE p4zmeso
Note: See TracBrowser for help on using the repository browser.