New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zmicro.F90 in branches/CNRS/dev_r6270_PISCES_QUOTA/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/CNRS/dev_r6270_PISCES_QUOTA/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zmicro.F90 @ 6453

Last change on this file since 6453 was 6453, checked in by aumont, 9 years ago

New developments of PISCES (QUOTA, ligands, lability, ...)
File size: 14.8 KB
Line 
1MODULE p4zmicro
2   !!======================================================================
3   !!                         ***  MODULE p4zmicro  ***
4   !! TOP :   PISCES Compute the sources/sinks for microzooplankton
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!----------------------------------------------------------------------
10#if defined key_pisces
11   !!----------------------------------------------------------------------
12   !!   'key_pisces'                                       PISCES bio-model
13   !!----------------------------------------------------------------------
14   !!   p4z_micro       :   Compute the sources/sinks for microzooplankton
15   !!   p4z_micro_init  :   Initialize and read the appropriate namelist
16   !!----------------------------------------------------------------------
17   USE oce_trc         !  shared variables between ocean and passive tracers
18   USE trc             !  passive tracers common variables
19   USE sms_pisces      !  PISCES Source Minus Sink variables
20   USE p4zlim          !  Co-limitations
21   USE p4zsink         !  vertical flux of particulate matter due to sinking
22   USE p4zprod         !  production
23   USE iom             !  I/O manager
24   USE prtctl_trc      !  print control for debugging
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   p4z_micro         ! called in p4zbio.F90
30   PUBLIC   p4z_micro_init    ! called in trcsms_pisces.F90
31
32   !! * Shared module variables
33   REAL(wp), PUBLIC ::  part        !: part of calcite not dissolved in microzoo guts
34   REAL(wp), PUBLIC ::  xpref2c     !: microzoo preference for POC
35   REAL(wp), PUBLIC ::  xpref2p     !: microzoo preference for nanophyto
36   REAL(wp), PUBLIC ::  xpref2d     !: microzoo preference for diatoms
37   REAL(wp), PUBLIC ::  xthreshdia  !: diatoms feeding threshold for microzooplankton
38   REAL(wp), PUBLIC ::  xthreshphy  !: nanophyto threshold for microzooplankton
39   REAL(wp), PUBLIC ::  xthreshpoc  !: poc threshold for microzooplankton
40   REAL(wp), PUBLIC ::  xthresh     !: feeding threshold for microzooplankton
41   REAL(wp), PUBLIC ::  resrat      !: exsudation rate of microzooplankton
42   REAL(wp), PUBLIC ::  mzrat       !: microzooplankton mortality rate
43   REAL(wp), PUBLIC ::  grazrat     !: maximal microzoo grazing rate
44   REAL(wp), PUBLIC ::  xkgraz      !: non assimilated fraction of P by microzoo
45   REAL(wp), PUBLIC ::  unass       !: Efficicency of microzoo growth
46   REAL(wp), PUBLIC ::  sigma1      !: Fraction of microzoo excretion as DOM
47   REAL(wp), PUBLIC ::  epsher      !: half sturation constant for grazing 1
48
49
50   !!* Substitution
51#  include "top_substitute.h90"
52   !!----------------------------------------------------------------------
53   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
54   !! $Id: p4zmicro.F90 3160 2011-11-20 14:27:18Z cetlod $
55   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
56   !!----------------------------------------------------------------------
57
58CONTAINS
59
60   SUBROUTINE p4z_micro( kt, knt )
61      !!---------------------------------------------------------------------
62      !!                     ***  ROUTINE p4z_micro  ***
63      !!
64      !! ** Purpose :   Compute the sources/sinks for microzooplankton
65      !!
66      !! ** Method  : - ???
67      !!---------------------------------------------------------------------
68      INTEGER, INTENT(in) ::  kt  ! ocean time step
69      INTEGER, INTENT(in) ::  knt 
70      !
71      INTEGER  :: ji, jj, jk
72      REAL(wp) :: zcompadi, zcompaz , zcompaph, zcompapoc
73      REAL(wp) :: zgraze  , zdenom, zdenom2
74      REAL(wp) :: zfact   , zstep, zfood, zfoodlim
75      REAL(wp) :: zepshert, zepsherv, zgrarsig, zgraztot, zgraztotn, zgraztotf
76      REAL(wp) :: zgrarem, zgrafer, zgrapoc, zprcaca, zmortz
77      REAL(wp) :: zrespz, ztortz, zgrasrat, zgrasratn
78      REAL(wp) :: zgrazp, zgrazm, zgrazsd
79      REAL(wp) :: zgrazmf, zgrazsf, zgrazpf
80      REAL(wp), POINTER, DIMENSION(:,:,:) :: zgrazing, zw3d
81      CHARACTER (len=25) :: charout
82      !!---------------------------------------------------------------------
83      !
84      IF( nn_timing == 1 )  CALL timing_start('p4z_micro')
85      !
86      IF( lk_iomput )  CALL wrk_alloc( jpi, jpj, jpk, zgrazing )
87      !
88      DO jk = 1, jpkm1
89         DO jj = 1, jpj
90            DO ji = 1, jpi
91               zcompaz = MAX( ( trb(ji,jj,jk,jpzoo) - 1.e-9 ), 0.e0 )
92               zstep   = xstep
93# if defined key_degrad
94               zstep = zstep * facvol(ji,jj,jk)
95# endif
96               zfact   = zstep * tgfunc2(ji,jj,jk) * zcompaz
97
98               !  Respiration rates of both zooplankton
99               !  -------------------------------------
100               zrespz = resrat * zfact * trb(ji,jj,jk,jpzoo) / ( xkmort + trb(ji,jj,jk,jpzoo) )  &
101                  &   + resrat * zfact * 3. * nitrfac(ji,jj,jk)
102
103               !  Zooplankton mortality. A square function has been selected with
104               !  no real reason except that it seems to be more stable and may mimic predation.
105               !  ---------------------------------------------------------------
106               ztortz = mzrat * 1.e6 * zfact * trb(ji,jj,jk,jpzoo)
107
108               zcompadi  = MIN( MAX( ( trb(ji,jj,jk,jpdia) - xthreshdia ), 0.e0 ), xsizedia )
109               zcompaph  = MAX( ( trb(ji,jj,jk,jpphy) - xthreshphy ), 0.e0 )
110               zcompapoc = MAX( ( trb(ji,jj,jk,jppoc) - xthreshpoc ), 0.e0 )
111               
112               !     Microzooplankton grazing
113               !     ------------------------
114               zfood     = xpref2p * zcompaph + xpref2c * zcompapoc + xpref2d * zcompadi
115               zfoodlim  = MAX( 0. , zfood - min(xthresh,0.5*zfood) )
116               zdenom    = zfoodlim / ( xkgraz + zfoodlim )
117               zdenom2   = zdenom / ( zfood + rtrn )
118               zgraze    = grazrat * zstep * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jpzoo) 
119
120               zgrazp    = zgraze  * xpref2p * zcompaph  * zdenom2 
121               zgrazm    = zgraze  * xpref2c * zcompapoc * zdenom2 
122               zgrazsd   = zgraze  * xpref2d * zcompadi  * zdenom2 
123
124               zgrazpf   = zgrazp  * trb(ji,jj,jk,jpnfe) / (trb(ji,jj,jk,jpphy) + rtrn)
125               zgrazmf   = zgrazm  * trb(ji,jj,jk,jpsfe) / (trb(ji,jj,jk,jppoc) + rtrn)
126               zgrazsf   = zgrazsd * trb(ji,jj,jk,jpdfe) / (trb(ji,jj,jk,jpdia) + rtrn)
127               !
128               zgraztot  = zgrazp  + zgrazm  + zgrazsd 
129               zgraztotf = zgrazpf + zgrazsf + zgrazmf 
130               zgraztotn = zgrazp * quotan(ji,jj,jk) + zgrazm + zgrazsd * quotad(ji,jj,jk)
131
132               ! Grazing by microzooplankton
133               IF( ln_diatrc .AND. lk_iomput )  zgrazing(ji,jj,jk) = zgraztot
134
135               !    Various remineralization and excretion terms
136               !    --------------------------------------------
137               zgrasrat  = ( zgraztotf + rtrn ) / ( zgraztot + rtrn )
138               zgrasratn = ( zgraztotn + rtrn ) / ( zgraztot + rtrn )
139               zepshert  =  MIN( 1., zgrasratn, zgrasrat / ferat3)
140               zepsherv  = zepshert * MIN( epsher, (1. - unass) * zgrasrat / ferat3, (1. - unass) * zgrasratn )
141               zgrafer   = zgraztot * MAX( 0. , ( 1. - unass ) * zgrasrat - ferat3 * zepsherv ) 
142               zgrarem   = zgraztot * ( 1. - zepsherv - unass )
143               zgrapoc   = zgraztot * unass
144
145               !  Update of the TRA arrays
146               !  ------------------------
147               zgrarsig  = zgrarem * sigma1
148               tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zgrarsig
149               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zgrarsig
150               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zgrarem - zgrarsig
151#if defined key_ligand
152               tra(ji,jj,jk,jplgw) = tra(ji,jj,jk,jplgw) + (zgrarem - zgrarsig) * ldocz
153#endif
154               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2ut * zgrarsig
155               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zgrafer
156               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zgrapoc
157               prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + zgrapoc
158               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zgraztotf * unass
159               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zgrarsig
160               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * zgrarsig
161#if defined key_kriest
162               tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) + zgrapoc * xkr_dmicro
163#endif
164               !   Update the arrays TRA which contain the biological sources and sinks
165               !   --------------------------------------------------------------------
166               zmortz = ztortz + zrespz
167               tra(ji,jj,jk,jpzoo) = tra(ji,jj,jk,jpzoo) - zmortz + zepsherv * zgraztot 
168               tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) - zgrazp
169               tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) - zgrazsd
170               tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) - zgrazp  * trb(ji,jj,jk,jpnch)/(trb(ji,jj,jk,jpphy)+rtrn)
171               tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) - zgrazsd * trb(ji,jj,jk,jpdch)/(trb(ji,jj,jk,jpdia)+rtrn)
172               tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) - zgrazsd * trb(ji,jj,jk,jpdsi)/(trb(ji,jj,jk,jpdia)+rtrn)
173               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) + zgrazsd * trb(ji,jj,jk,jpdsi)/(trb(ji,jj,jk,jpdia)+rtrn)
174               tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) - zgrazpf
175               tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) - zgrazsf
176               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zmortz - zgrazm
177               prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + zmortz
178               conspoc(ji,jj,jk) = conspoc(ji,jj,jk) - zgrazm
179               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + ferat3 * zmortz - zgrazmf
180               !
181               ! calcite production
182               zprcaca = xfracal(ji,jj,jk) * zgrazp
183               prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca  ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
184               !
185               zprcaca = part * zprcaca
186               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprcaca
187               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2. * zprcaca
188               tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) + zprcaca
189#if defined key_kriest
190               tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) + zmortz * xkr_dmicro &
191                                                         - zgrazm * trb(ji,jj,jk,jpnum) / ( trb(ji,jj,jk,jppoc) + rtrn )
192#endif
193            END DO
194         END DO
195      END DO
196      !
197      IF( lk_iomput .AND. knt == nrdttrc ) THEN
198         CALL wrk_alloc( jpi, jpj, jpk, zw3d )
199         IF( iom_use( "GRAZ1" ) ) THEN
200            zw3d(:,:,:) = zgrazing(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:)  !  Total grazing of phyto by zooplankton
201            CALL iom_put( "GRAZ1", zw3d )
202         ENDIF
203         CALL wrk_dealloc( jpi, jpj, jpk, zw3d )
204      ENDIF
205      !
206      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
207         WRITE(charout, FMT="('micro')")
208         CALL prt_ctl_trc_info(charout)
209         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
210      ENDIF
211      !
212      IF( lk_iomput )  CALL wrk_dealloc( jpi, jpj, jpk, zgrazing )
213      !
214      IF( nn_timing == 1 )  CALL timing_stop('p4z_micro')
215      !
216   END SUBROUTINE p4z_micro
217
218
219   SUBROUTINE p4z_micro_init
220
221      !!----------------------------------------------------------------------
222      !!                  ***  ROUTINE p4z_micro_init  ***
223      !!
224      !! ** Purpose :   Initialization of microzooplankton parameters
225      !!
226      !! ** Method  :   Read the nampiszoo namelist and check the parameters
227      !!                called at the first timestep (nittrc000)
228      !!
229      !! ** input   :   Namelist nampiszoo
230      !!
231      !!----------------------------------------------------------------------
232
233      NAMELIST/nampiszoo/ part, grazrat, resrat, mzrat, xpref2c, xpref2p, &
234         &                xpref2d,  xthreshdia,  xthreshphy,  xthreshpoc, &
235         &                xthresh, xkgraz, epsher, sigma1, unass
236      INTEGER :: ios                 ! Local integer output status for namelist read
237
238      REWIND( numnatp_ref )              ! Namelist nampiszoo in reference namelist : Pisces microzooplankton
239      READ  ( numnatp_ref, nampiszoo, IOSTAT = ios, ERR = 901)
240901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampiszoo in reference namelist', lwp )
241
242      REWIND( numnatp_cfg )              ! Namelist nampiszoo in configuration namelist : Pisces microzooplankton
243      READ  ( numnatp_cfg, nampiszoo, IOSTAT = ios, ERR = 902 )
244902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampiszoo in configuration namelist', lwp )
245      IF(lwm) WRITE ( numonp, nampiszoo )
246
247      IF(lwp) THEN                         ! control print
248         WRITE(numout,*) ' '
249         WRITE(numout,*) ' Namelist parameters for microzooplankton, nampiszoo'
250         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
251         WRITE(numout,*) '    part of calcite not dissolved in microzoo guts  part        =', part
252         WRITE(numout,*) '    microzoo preference for POC                     xpref2c     =', xpref2c
253         WRITE(numout,*) '    microzoo preference for nano                    xpref2p     =', xpref2p
254         WRITE(numout,*) '    microzoo preference for diatoms                 xpref2d     =', xpref2d
255         WRITE(numout,*) '    diatoms feeding threshold  for microzoo         xthreshdia  =', xthreshdia
256         WRITE(numout,*) '    nanophyto feeding threshold for microzoo        xthreshphy  =', xthreshphy
257         WRITE(numout,*) '    poc feeding threshold for microzoo              xthreshpoc  =', xthreshpoc
258         WRITE(numout,*) '    feeding threshold for microzooplankton          xthresh     =', xthresh
259         WRITE(numout,*) '    exsudation rate of microzooplankton             resrat      =', resrat
260         WRITE(numout,*) '    microzooplankton mortality rate                 mzrat       =', mzrat
261         WRITE(numout,*) '    maximal microzoo grazing rate                   grazrat     =', grazrat
262         WRITE(numout,*) '    non assimilated fraction of P by microzoo       unass       =', unass
263         WRITE(numout,*) '    Efficicency of microzoo growth                  epsher      =', epsher
264         WRITE(numout,*) '    Fraction of microzoo excretion as DOM           sigma1      =', sigma1
265         WRITE(numout,*) '    half sturation constant for grazing 1           xkgraz      =', xkgraz
266      ENDIF
267
268   END SUBROUTINE p4z_micro_init
269
270#else
271   !!======================================================================
272   !!  Dummy module :                                   No PISCES bio-model
273   !!======================================================================
274CONTAINS
275   SUBROUTINE p4z_micro                    ! Empty routine
276   END SUBROUTINE p4z_micro
277#endif 
278
279   !!======================================================================
280END MODULE p4zmicro
Note: See TracBrowser for help on using the repository browser.