New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zmicro.F90 in branches/CNRS/dev_r6270_PISCES_QUOTA/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/CNRS/dev_r6270_PISCES_QUOTA/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zmicro.F90 @ 7617

Last change on this file since 7617 was 7617, checked in by aumont, 8 years ago

update diagnostics + changes in quota code
File size: 15.6 KB
Line 
1MODULE p4zmicro
2   !!======================================================================
3   !!                         ***  MODULE p4zmicro  ***
4   !! TOP :   PISCES Compute the sources/sinks for microzooplankton
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!----------------------------------------------------------------------
10#if defined key_pisces
11   !!----------------------------------------------------------------------
12   !!   'key_pisces'                                       PISCES bio-model
13   !!----------------------------------------------------------------------
14   !!   p4z_micro       :   Compute the sources/sinks for microzooplankton
15   !!   p4z_micro_init  :   Initialize and read the appropriate namelist
16   !!----------------------------------------------------------------------
17   USE oce_trc         !  shared variables between ocean and passive tracers
18   USE trc             !  passive tracers common variables
19   USE sms_pisces      !  PISCES Source Minus Sink variables
20   USE p4zlim          !  Co-limitations
21   USE p4zsink         !  vertical flux of particulate matter due to sinking
22   USE p4zprod         !  production
23   USE iom             !  I/O manager
24   USE prtctl_trc      !  print control for debugging
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   p4z_micro         ! called in p4zbio.F90
30   PUBLIC   p4z_micro_init    ! called in trcsms_pisces.F90
31
32   !! * Shared module variables
33   REAL(wp), PUBLIC ::  part        !: part of calcite not dissolved in microzoo guts
34   REAL(wp), PUBLIC ::  xpref2c     !: microzoo preference for POC
35   REAL(wp), PUBLIC ::  xpref2p     !: microzoo preference for nanophyto
36   REAL(wp), PUBLIC ::  xpref2d     !: microzoo preference for diatoms
37   REAL(wp), PUBLIC ::  xthreshdia  !: diatoms feeding threshold for microzooplankton
38   REAL(wp), PUBLIC ::  xthreshphy  !: nanophyto threshold for microzooplankton
39   REAL(wp), PUBLIC ::  xthreshpoc  !: poc threshold for microzooplankton
40   REAL(wp), PUBLIC ::  xthresh     !: feeding threshold for microzooplankton
41   REAL(wp), PUBLIC ::  resrat      !: exsudation rate of microzooplankton
42   REAL(wp), PUBLIC ::  mzrat       !: microzooplankton mortality rate
43   REAL(wp), PUBLIC ::  grazrat     !: maximal microzoo grazing rate
44   REAL(wp), PUBLIC ::  xkgraz      !: non assimilated fraction of P by microzoo
45   REAL(wp), PUBLIC ::  unass       !: Efficicency of microzoo growth
46   REAL(wp), PUBLIC ::  sigma1      !: Fraction of microzoo excretion as DOM
47   REAL(wp), PUBLIC ::  epsher      !: half sturation constant for grazing 1
48
49
50   !!* Substitution
51#  include "top_substitute.h90"
52   !!----------------------------------------------------------------------
53   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
54   !! $Id: p4zmicro.F90 3160 2011-11-20 14:27:18Z cetlod $
55   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
56   !!----------------------------------------------------------------------
57
58CONTAINS
59
60   SUBROUTINE p4z_micro( kt, knt )
61      !!---------------------------------------------------------------------
62      !!                     ***  ROUTINE p4z_micro  ***
63      !!
64      !! ** Purpose :   Compute the sources/sinks for microzooplankton
65      !!
66      !! ** Method  : - ???
67      !!---------------------------------------------------------------------
68      INTEGER, INTENT(in) ::  kt  ! ocean time step
69      INTEGER, INTENT(in) ::  knt 
70      !
71      INTEGER  :: ji, jj, jk
72      REAL(wp) :: zcompadi, zcompaz , zcompaph, zcompapoc
73      REAL(wp) :: zgraze  , zdenom, zdenom2
74      REAL(wp) :: zfact   , zstep, zfood, zfoodlim
75      REAL(wp) :: zepshert, zepsherv, zgrarsig, zgraztot, zgraztotn, zgraztotf
76      REAL(wp) :: zgrarem, zgrafer, zgrapoc, zprcaca, zmortz
77      REAL(wp) :: zrespz, ztortz, zgrasrat, zgrasratn
78      REAL(wp) :: zgrazp, zgrazm, zgrazsd
79      REAL(wp) :: zgrazmf, zgrazsf, zgrazpf
80      REAL(wp), POINTER, DIMENSION(:,:,:) :: zgrazing, zw3d, zfezoo
81#if defined key_ligand
82      REAL(wp), POINTER, DIMENSION(:,:,:) :: zzligprod
83#endif
84      CHARACTER (len=25) :: charout
85      !!---------------------------------------------------------------------
86      !
87      IF( nn_timing == 1 )  CALL timing_start('p4z_micro')
88      !
89      CALL wrk_alloc( jpi, jpj, jpk, zgrazing, zfezoo )
90      zfezoo(:,:,:) = 0._wp
91#if defined key_ligand
92      CALL wrk_alloc( jpi, jpj, jpk, zzligprod )
93      zzligprod(:,:,:) = 0._wp
94#endif
95      !
96      DO jk = 1, jpkm1
97         DO jj = 1, jpj
98            DO ji = 1, jpi
99               zcompaz = MAX( ( trb(ji,jj,jk,jpzoo) - 1.e-9 ), 0.e0 )
100               zstep   = xstep
101# if defined key_degrad
102               zstep = zstep * facvol(ji,jj,jk)
103# endif
104               zfact   = zstep * tgfunc2(ji,jj,jk) * zcompaz
105
106               !  Respiration rates of both zooplankton
107               !  -------------------------------------
108               zrespz = resrat * zfact * trb(ji,jj,jk,jpzoo) / ( xkmort + trb(ji,jj,jk,jpzoo) )  &
109                  &   + resrat * zfact * 3. * nitrfac(ji,jj,jk)
110
111               !  Zooplankton mortality. A square function has been selected with
112               !  no real reason except that it seems to be more stable and may mimic predation.
113               !  ---------------------------------------------------------------
114               ztortz = mzrat * 1.e6 * zfact * trb(ji,jj,jk,jpzoo)
115
116               zcompadi  = MIN( MAX( ( trb(ji,jj,jk,jpdia) - xthreshdia ), 0.e0 ), xsizedia )
117               zcompaph  = MAX( ( trb(ji,jj,jk,jpphy) - xthreshphy ), 0.e0 )
118               zcompapoc = MAX( ( trb(ji,jj,jk,jppoc) - xthreshpoc ), 0.e0 )
119               
120               !     Microzooplankton grazing
121               !     ------------------------
122               zfood     = xpref2p * zcompaph + xpref2c * zcompapoc + xpref2d * zcompadi
123               zfoodlim  = MAX( 0. , zfood - min(xthresh,0.5*zfood) )
124               zdenom    = zfoodlim / ( xkgraz + zfoodlim )
125               zdenom2   = zdenom / ( zfood + rtrn )
126               zgraze    = grazrat * zstep * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jpzoo) 
127
128               zgrazp    = zgraze  * xpref2p * zcompaph  * zdenom2 
129               zgrazm    = zgraze  * xpref2c * zcompapoc * zdenom2 
130               zgrazsd   = zgraze  * xpref2d * zcompadi  * zdenom2 
131
132               zgrazpf   = zgrazp  * trb(ji,jj,jk,jpnfe) / (trb(ji,jj,jk,jpphy) + rtrn)
133               zgrazmf   = zgrazm  * trb(ji,jj,jk,jpsfe) / (trb(ji,jj,jk,jppoc) + rtrn)
134               zgrazsf   = zgrazsd * trb(ji,jj,jk,jpdfe) / (trb(ji,jj,jk,jpdia) + rtrn)
135               !
136               zgraztot  = zgrazp  + zgrazm  + zgrazsd 
137               zgraztotf = zgrazpf + zgrazsf + zgrazmf 
138               zgraztotn = zgrazp * quotan(ji,jj,jk) + zgrazm + zgrazsd * quotad(ji,jj,jk)
139
140               ! Grazing by microzooplankton
141               IF( ln_diatrc .AND. lk_iomput )  zgrazing(ji,jj,jk) = zgraztot
142
143               !    Various remineralization and excretion terms
144               !    --------------------------------------------
145               zgrasrat  = ( zgraztotf + rtrn ) / ( zgraztot + rtrn )
146               zgrasratn = ( zgraztotn + rtrn ) / ( zgraztot + rtrn )
147               zepshert  =  MIN( 1., zgrasratn, zgrasrat / ferat3)
148               zepsherv  = zepshert * MIN( epsher, (1. - unass) * zgrasrat / ferat3, (1. - unass) * zgrasratn )
149               zgrafer   = zgraztot * MAX( 0. , ( 1. - unass ) * zgrasrat - ferat3 * zepsherv ) 
150               zgrarem   = zgraztot * ( 1. - zepsherv - unass )
151               zgrapoc   = zgraztot * unass
152
153               !  Update of the TRA arrays
154               !  ------------------------
155               zgrarsig  = zgrarem * sigma1
156               tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zgrarsig
157               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zgrarsig
158               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zgrarem - zgrarsig
159#if defined key_ligand
160               tra(ji,jj,jk,jplgw) = tra(ji,jj,jk,jplgw) + (zgrarem - zgrarsig) * ldocz
161               zzligprod(ji,jj,jk) = (zgrarem - zgrarsig) * ldocz
162#endif
163               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2ut * zgrarsig
164               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zgrafer
165               zfezoo(ji,jj,jk) = zgrafer
166               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zgrapoc
167               prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + zgrapoc
168               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zgraztotf * unass
169               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zgrarsig
170               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * zgrarsig
171#if defined key_kriest
172               tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) + zgrapoc * xkr_dmicro
173#endif
174               !   Update the arrays TRA which contain the biological sources and sinks
175               !   --------------------------------------------------------------------
176               zmortz = ztortz + zrespz
177               tra(ji,jj,jk,jpzoo) = tra(ji,jj,jk,jpzoo) - zmortz + zepsherv * zgraztot 
178               tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) - zgrazp
179               tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) - zgrazsd
180               tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) - zgrazp  * trb(ji,jj,jk,jpnch)/(trb(ji,jj,jk,jpphy)+rtrn)
181               tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) - zgrazsd * trb(ji,jj,jk,jpdch)/(trb(ji,jj,jk,jpdia)+rtrn)
182               tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) - zgrazsd * trb(ji,jj,jk,jpdsi)/(trb(ji,jj,jk,jpdia)+rtrn)
183               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) + zgrazsd * trb(ji,jj,jk,jpdsi)/(trb(ji,jj,jk,jpdia)+rtrn)
184               tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) - zgrazpf
185               tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) - zgrazsf
186               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zmortz - zgrazm
187               prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + zmortz
188               conspoc(ji,jj,jk) = conspoc(ji,jj,jk) - zgrazm
189               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + ferat3 * zmortz - zgrazmf
190               !
191               ! calcite production
192               zprcaca = xfracal(ji,jj,jk) * zgrazp
193               prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca  ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
194               !
195               zprcaca = part * zprcaca
196               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprcaca
197               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2. * zprcaca
198               tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) + zprcaca
199#if defined key_kriest
200               tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) + zmortz * xkr_dmicro &
201                                                         - zgrazm * trb(ji,jj,jk,jpnum) / ( trb(ji,jj,jk,jppoc) + rtrn )
202#endif
203            END DO
204         END DO
205      END DO
206      !
207      IF( lk_iomput .AND. knt == nrdttrc ) THEN
208         CALL wrk_alloc( jpi, jpj, jpk, zw3d )
209         IF( iom_use( "GRAZ1" ) ) THEN
210            zw3d(:,:,:) = zgrazing(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:)  !  Total grazing of phyto by zooplankton
211            CALL iom_put( "GRAZ1", zw3d )
212         ENDIF
213         IF( iom_use( "FEZOO" ) ) THEN
214            zw3d(:,:,:) = zfezoo(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:)   !
215            CALL iom_put( "FEZOO", zw3d )
216         ENDIF
217#if defined key_ligand
218         IF( iom_use( "LPRODZ" ) )  THEN
219            zw3d(:,:,:) = zzligprod(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:)
220            CALL iom_put( "LPRODZ"  , zw3d )
221         ENDIF
222#endif
223         CALL wrk_dealloc( jpi, jpj, jpk, zw3d )
224      ENDIF
225      !
226      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
227         WRITE(charout, FMT="('micro')")
228         CALL prt_ctl_trc_info(charout)
229         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
230      ENDIF
231      !
232      CALL wrk_dealloc( jpi, jpj, jpk, zgrazing, zfezoo )
233#if defined key_ligand
234      CALL wrk_dealloc( jpi, jpj, jpk, zzligprod )
235#endif
236      !
237      IF( nn_timing == 1 )  CALL timing_stop('p4z_micro')
238      !
239   END SUBROUTINE p4z_micro
240
241
242   SUBROUTINE p4z_micro_init
243
244      !!----------------------------------------------------------------------
245      !!                  ***  ROUTINE p4z_micro_init  ***
246      !!
247      !! ** Purpose :   Initialization of microzooplankton parameters
248      !!
249      !! ** Method  :   Read the nampiszoo namelist and check the parameters
250      !!                called at the first timestep (nittrc000)
251      !!
252      !! ** input   :   Namelist nampiszoo
253      !!
254      !!----------------------------------------------------------------------
255
256      NAMELIST/nampiszoo/ part, grazrat, resrat, mzrat, xpref2c, xpref2p, &
257         &                xpref2d,  xthreshdia,  xthreshphy,  xthreshpoc, &
258         &                xthresh, xkgraz, epsher, sigma1, unass
259      INTEGER :: ios                 ! Local integer output status for namelist read
260
261      REWIND( numnatp_ref )              ! Namelist nampiszoo in reference namelist : Pisces microzooplankton
262      READ  ( numnatp_ref, nampiszoo, IOSTAT = ios, ERR = 901)
263901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampiszoo in reference namelist', lwp )
264
265      REWIND( numnatp_cfg )              ! Namelist nampiszoo in configuration namelist : Pisces microzooplankton
266      READ  ( numnatp_cfg, nampiszoo, IOSTAT = ios, ERR = 902 )
267902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampiszoo in configuration namelist', lwp )
268      IF(lwm) WRITE ( numonp, nampiszoo )
269
270      IF(lwp) THEN                         ! control print
271         WRITE(numout,*) ' '
272         WRITE(numout,*) ' Namelist parameters for microzooplankton, nampiszoo'
273         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
274         WRITE(numout,*) '    part of calcite not dissolved in microzoo guts  part        =', part
275         WRITE(numout,*) '    microzoo preference for POC                     xpref2c     =', xpref2c
276         WRITE(numout,*) '    microzoo preference for nano                    xpref2p     =', xpref2p
277         WRITE(numout,*) '    microzoo preference for diatoms                 xpref2d     =', xpref2d
278         WRITE(numout,*) '    diatoms feeding threshold  for microzoo         xthreshdia  =', xthreshdia
279         WRITE(numout,*) '    nanophyto feeding threshold for microzoo        xthreshphy  =', xthreshphy
280         WRITE(numout,*) '    poc feeding threshold for microzoo              xthreshpoc  =', xthreshpoc
281         WRITE(numout,*) '    feeding threshold for microzooplankton          xthresh     =', xthresh
282         WRITE(numout,*) '    exsudation rate of microzooplankton             resrat      =', resrat
283         WRITE(numout,*) '    microzooplankton mortality rate                 mzrat       =', mzrat
284         WRITE(numout,*) '    maximal microzoo grazing rate                   grazrat     =', grazrat
285         WRITE(numout,*) '    non assimilated fraction of P by microzoo       unass       =', unass
286         WRITE(numout,*) '    Efficicency of microzoo growth                  epsher      =', epsher
287         WRITE(numout,*) '    Fraction of microzoo excretion as DOM           sigma1      =', sigma1
288         WRITE(numout,*) '    half sturation constant for grazing 1           xkgraz      =', xkgraz
289      ENDIF
290
291   END SUBROUTINE p4z_micro_init
292
293#else
294   !!======================================================================
295   !!  Dummy module :                                   No PISCES bio-model
296   !!======================================================================
297CONTAINS
298   SUBROUTINE p4z_micro                    ! Empty routine
299   END SUBROUTINE p4z_micro
300#endif 
301
302   !!======================================================================
303END MODULE p4zmicro
Note: See TracBrowser for help on using the repository browser.