New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p5zrem.F90 in branches/CNRS/dev_r6270_PISCES_QUOTA/NEMOGCM/NEMO/TOP_SRC/PISCES/P5Z – NEMO

source: branches/CNRS/dev_r6270_PISCES_QUOTA/NEMOGCM/NEMO/TOP_SRC/PISCES/P5Z/p5zrem.F90 @ 7190

Last change on this file since 7190 was 7190, checked in by aumont, 8 years ago

various important bug fixes
  • Property svn:executable set to *
File size: 17.4 KB
Line 
1MODULE p5zrem
2   !!======================================================================
3   !!                         ***  MODULE p5zrem  ***
4   !! TOP :   PISCES Compute remineralization/dissolution of organic compounds
5   !!=========================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!             3.6  !  2015-05  (O. Aumont) PISCES quota
10   !!----------------------------------------------------------------------
11#if defined key_pisces_quota
12   !!----------------------------------------------------------------------
13   !!   'key_top'       and                                      TOP models
14   !!   'key_pisces_quota'     PISCES bio-model with variable stoichiometry
15   !!----------------------------------------------------------------------
16   !!   p5z_rem       :  Compute remineralization/dissolution of organic compounds
17   !!   p5z_rem_init  :  Initialisation of parameters for remineralisation
18   !!   p5z_rem_alloc :  Allocate remineralisation variables
19   !!----------------------------------------------------------------------
20   USE oce_trc         !  shared variables between ocean and passive tracers
21   USE trc             !  passive tracers common variables
22   USE sms_pisces      !  PISCES Source Minus Sink variables
23   USE p4zopt          !  optical model
24   USE p4zche          !  chemical model
25   USE p5zlim          ! Phytoplankton limitation factors
26   USE p5zsink         !  Sinking of particles
27   USE p5zprod         !  Production by phytoplankton
28   USE prtctl_trc      !  print control for debugging
29   USE iom             !  I/O manager
30
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   p5z_rem         ! called in p4zbio.F90
36   PUBLIC   p5z_rem_init    ! called in trcsms_pisces.F90
37   PUBLIC   p5z_rem_alloc
38
39   !! * Shared module variables
40   REAL(wp), PUBLIC ::  xremikc    !: remineralisation rate of DOC
41   REAL(wp), PUBLIC ::  xremikn    !: remineralisation rate of DON
42   REAL(wp), PUBLIC ::  xremikp    !: remineralisation rate of DOP
43   REAL(wp), PUBLIC ::  nitrif     !: NH4 nitrification rate
44   REAL(wp), PUBLIC ::  xsirem     !: remineralisation rate of BSi
45   REAL(wp), PUBLIC ::  xsiremlab  !: fast remineralisation rate of BSi
46   REAL(wp), PUBLIC ::  xsilab     !: fraction of labile biogenic silica
47   REAL(wp), PUBLIC ::  oxymin     !: half saturation constant for anoxia
48   REAL(wp), PUBLIC ::  oxymin2    !: Minimum O2 concentration for oxic remin.
49   REAL(wp), PUBLIC ::  feratb     !: Fe/C quota in bacteria
50   REAL(wp), PUBLIC ::  xkferb     !: Half-saturation constant for bacteria Fe/C
51
52
53   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   denitrc     !: denitrification array
54
55   !!* Substitution
56#  include "top_substitute.h90"
57   !!----------------------------------------------------------------------
58   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
59   !! $Id: p4zrem.F90 3160 2011-11-20 14:27:18Z cetlod $
60   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
61   !!----------------------------------------------------------------------
62CONTAINS
63
64   SUBROUTINE p5z_rem( kt, knt )
65      !!---------------------------------------------------------------------
66      !!                     ***  ROUTINE p5z_rem  ***
67      !!
68      !! ** Purpose :   Compute remineralization/scavenging of organic compounds
69      !!
70      !! ** Method  : - ???
71      !!---------------------------------------------------------------------
72      !
73      INTEGER, INTENT(in) ::   kt, knt ! ocean time step
74      !
75      INTEGER  ::   ji, jj, jk
76      REAL(wp) ::   zremik, zremikc, zremikn, zremikp, zsiremin 
77      REAL(wp) ::   zsatur, zsatur2, znusil, znusil2, zdep, zdepmin, zfactdep
78      REAL(wp) ::   zbactfer, zolimit, zonitr, zstep, zrfact2
79      REAL(wp) ::   zosil, ztem, zdenitnh4, zolimic, zolimin, zolimip, zdenitrn, zdenitrp
80      CHARACTER (len=25) :: charout
81      REAL(wp), POINTER, DIMENSION(:,:  ) :: ztempbac 
82      REAL(wp), POINTER, DIMENSION(:,:,:) :: zdepbac, zwork1, zdepprod, zfacsi, zfacsib
83      !!---------------------------------------------------------------------
84      !
85      IF( nn_timing == 1 )  CALL timing_start('p5z_rem')
86      !
87      ! Allocate temporary workspace
88      CALL wrk_alloc( jpi, jpj,      ztempbac                  )
89      CALL wrk_alloc( jpi, jpj, jpk, zdepbac, zdepprod, zwork1, zfacsi, zfacsib )
90
91      ! Initialisation of temprary arrys
92      zdepprod(:,:,:) = 1._wp
93      ztempbac(:,:)   = 0._wp
94      zfacsib(:,:,:)  = xsilab / ( 1.0 - xsilab )
95      zfacsi(:,:,:)   = xsilab
96
97      ! Computation of the mean phytoplankton concentration as
98      ! a crude estimate of the bacterial biomass
99      ! this parameterization has been deduced from a model version
100      ! that was modeling explicitely bacteria
101      ! -------------------------------------------------------
102      DO jk = 1, jpkm1
103         DO jj = 1, jpj
104            DO ji = 1, jpi
105               zdep = MAX( hmld(ji,jj), heup(ji,jj) )
106               IF( fsdept(ji,jj,jk) < zdep ) THEN
107                  zdepbac(ji,jj,jk) = MIN( 0.7 * ( trb(ji,jj,jk,jpzoo) + 2.* trb(ji,jj,jk,jpmes) ), 4.e-6 )
108                  ztempbac(ji,jj)   = zdepbac(ji,jj,jk)
109               ELSE
110                  zdepmin = MIN( 1., zdep / fsdept(ji,jj,jk) )
111                  zdepbac (ji,jj,jk) = zdepmin**0.683 * ztempbac(ji,jj)
112                  zdepprod(ji,jj,jk) = zdepmin**0.273
113               ENDIF
114            END DO
115         END DO
116      END DO
117
118      DO jk = 1, jpkm1
119         DO jj = 1, jpj
120            DO ji = 1, jpi
121               ! denitrification factor computed from O2 levels
122               ! ----------------------------------------------
123               nitrfac(ji,jj,jk) = MAX(  0.e0, 0.4 * ( oxymin2 - trb(ji,jj,jk,jpoxy) )    &
124                  &                                / ( oxymin + trb(ji,jj,jk,jpoxy) )  )
125               nitrfac(ji,jj,jk) = MIN( 1., nitrfac(ji,jj,jk) )
126            END DO
127         END DO
128      END DO
129
130      DO jk = 1, jpkm1
131         DO jj = 1, jpj
132            DO ji = 1, jpi
133               zstep   = xstep
134# if defined key_degrad
135               zstep = zstep * facvol(ji,jj,jk)
136# endif
137               ! DOC ammonification. Depends on depth, phytoplankton biomass
138               ! and a limitation term which is supposed to be a parameterization
139               ! of the bacterial activity.
140               ! -----------------------------------------------------------------
141               zremik = zstep / 1.e-6 * MAX(0.01, xlimbac(ji,jj,jk)) * zdepbac(ji,jj,jk) 
142               zremik = MAX( zremik, 2.74e-4 * xstep / xremikc )
143
144               zremikc = xremikc * zremik
145               zremikn = xremikn / xremikc
146               zremikp = xremikp / xremikc
147
148               ! Ammonification in oxic waters with oxygen consumption
149               ! -----------------------------------------------------
150               zolimit = zremikc * ( 1.- nitrfac(ji,jj,jk) ) * trb(ji,jj,jk,jpdoc) 
151               zolimic = MAX( 0.e0, MIN( ( trb(ji,jj,jk,jpoxy) - rtrn ) / o2ut, zolimit ) ) 
152               zwork1(ji,jj,jk) = zolimic
153               zolimin = zremikn * zolimic * trb(ji,jj,jk,jpdon) / ( trb(ji,jj,jk,jpdoc) + rtrn )
154               zolimip = zremikp * zolimic * trb(ji,jj,jk,jpdop) / ( trb(ji,jj,jk,jpdoc) + rtrn ) 
155
156               ! Ammonification in suboxic waters with denitrification
157               ! -------------------------------------------------------
158               zolimit = zremikc * nitrfac(ji,jj,jk) * trb(ji,jj,jk,jpdoc)
159               denitrc(ji,jj,jk)  = MIN(  ( trb(ji,jj,jk,jpno3) - rtrn ) / rdenit, zolimit )
160               denitrc (ji,jj,jk) = MAX( 0.e0, denitrc (ji,jj,jk) )
161               zdenitrn  = zremikn * denitrc(ji,jj,jk) * trb(ji,jj,jk,jpdon) / ( trb(ji,jj,jk,jpdoc) + rtrn )
162               zdenitrp  = zremikp * denitrc(ji,jj,jk) * trb(ji,jj,jk,jpdop) / ( trb(ji,jj,jk,jpdoc) + rtrn )
163
164               ! Update of trends TRA
165               ! --------------------
166               tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zolimip + zdenitrp
167               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zolimin + zdenitrn
168               tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - denitrc(ji,jj,jk) * rdenit
169               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zolimic - denitrc(ji,jj,jk)
170               tra(ji,jj,jk,jpdon) = tra(ji,jj,jk,jpdon) - zolimin - zdenitrn
171               tra(ji,jj,jk,jpdop) = tra(ji,jj,jk,jpdop) - zolimip - zdenitrp
172               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - zolimic * o2ut
173               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zolimic + denitrc(ji,jj,jk)
174               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zolimin + ( rdenit + 1.) * zdenitrn )
175
176            END DO
177         END DO
178      END DO
179
180
181      DO jk = 1, jpkm1
182         DO jj = 1, jpj
183            DO ji = 1, jpi
184               zstep   = xstep
185# if defined key_degrad
186               zstep = zstep * facvol(ji,jj,jk)
187# endif
188               ! NH4 nitrification to NO3. Ceased for oxygen concentrations
189               ! below 2 umol/L. Inhibited at strong light
190               ! ----------------------------------------------------------
191               zonitr  = nitrif * zstep * trb(ji,jj,jk,jpnh4) * ( 1.- nitrfac(ji,jj,jk) )  &
192               &         * ( 0.2 + 0.8 / ( 1.+ emoy(ji,jj,jk) ) * ( 1. + fr_i(ji,jj) * emoy(ji,jj,jk) ) )
193               zdenitnh4 = nitrif * zstep * trb(ji,jj,jk,jpnh4) * nitrfac(ji,jj,jk) 
194               !
195               ! Update of the tracers trends
196               ! ----------------------------
197               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zonitr - zdenitnh4
198               tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) + zonitr - rdenita * zdenitnh4
199               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2nit * zonitr
200               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2 * rno3 * zonitr + rno3 * ( rdenita - 1. ) * zdenitnh4
201            END DO
202         END DO
203      END DO
204
205      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
206        WRITE(charout, FMT="('rem1')")
207        CALL prt_ctl_trc_info(charout)
208        CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
209      ENDIF
210
211      DO jk = 1, jpkm1
212         DO jj = 1, jpj
213            DO ji = 1, jpi
214
215               ! Bacterial uptake of iron. No iron is available in DOC. So
216               ! Bacteries are obliged to take up iron from the water. Some
217               ! studies (especially at Papa) have shown this uptake to be significant
218               ! ----------------------------------------------------------
219               zbactfer = feratb *  rfact2 * prmaxp(ji,jj,jk) * xlimbacl(ji,jj,jk)             &
220                  &              * biron(ji,jj,jk) / ( xkferb + biron(ji,jj,jk) )    &
221                  &              * zdepprod(ji,jj,jk) * zdepbac(ji,jj,jk)
222#if defined key_kriest
223               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - zbactfer*0.05
224               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zbactfer*0.05
225#else
226               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - zbactfer*0.16
227               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zbactfer*0.12
228               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zbactfer*0.04
229#endif
230            END DO
231         END DO
232      END DO
233
234      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
235        WRITE(charout, FMT="('rem2')")
236        CALL prt_ctl_trc_info(charout)
237        CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
238      ENDIF
239
240      ! Initialization of the array which contains the labile fraction
241      ! of bSi. Set to a constant in the upper ocean
242      ! ---------------------------------------------------------------
243
244      DO jk = 1, jpkm1
245         DO jj = 1, jpj
246            DO ji = 1, jpi
247               zstep   = xstep
248# if defined key_degrad
249               zstep = zstep * facvol(ji,jj,jk)
250# endif
251               zdep     = MAX( hmld(ji,jj), heup_01(ji,jj) )
252               zsatur   = MAX( rtrn, ( sio3eq(ji,jj,jk) - trb(ji,jj,jk,jpsil) ) / ( sio3eq(ji,jj,jk) + rtrn ) )
253               zsatur2  = ( 1. + tsn(ji,jj,jk,jp_tem) / 400.)**37
254               znusil   = 0.225  * ( 1. + tsn(ji,jj,jk,jp_tem) / 15.) * zsatur + 0.775 * zsatur2 * zsatur**9.25
255
256               ! Remineralization rate of BSi depedant on T and saturation
257               ! ---------------------------------------------------------
258               IF ( fsdept(ji,jj,jk) > zdep ) THEN
259                  zfacsib(ji,jj,jk) = zfacsib(ji,jj,jk-1) * EXP( -0.5 * ( xsiremlab - xsirem )  &
260                  &                   * znusil * fse3t(ji,jj,jk) / wsbio4(ji,jj,jk) )
261                  zfacsi(ji,jj,jk)  = zfacsib(ji,jj,jk) / ( 1.0 + zfacsib(ji,jj,jk) )
262                  zfacsib(ji,jj,jk) = zfacsib(ji,jj,jk) * EXP( -0.5 * ( xsiremlab - xsirem )    &
263                  &                   * znusil * fse3t(ji,jj,jk) / wsbio4(ji,jj,jk) )
264               ENDIF
265               zsiremin = ( xsiremlab * zfacsi(ji,jj,jk) + xsirem * ( 1. - zfacsi(ji,jj,jk) ) ) * zstep * znusil
266               zosil    = zsiremin * trb(ji,jj,jk,jpgsi)
267               !
268               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) - zosil
269               tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) + zosil
270            END DO
271         END DO
272      END DO
273
274      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
275         WRITE(charout, FMT="('rem3')")
276         CALL prt_ctl_trc_info(charout)
277         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
278       ENDIF
279
280      IF( ln_diatrc .AND. lk_iomput .AND. knt == nrdttrc ) THEN
281          zrfact2 = 1.e3 * rfact2r
282          CALL iom_put( "REMIN" , zwork1(:,:,:) * tmask(:,:,:) * zrfact2 )  ! Remineralisation rate
283          CALL iom_put( "DENIT" , denitrc(:,:,:) * rdenit * rno3 * tmask(:,:,:) * zrfact2  )  ! Denitrification
284      ENDIF
285      !
286      CALL wrk_dealloc( jpi, jpj,      ztempbac                  )
287      CALL wrk_dealloc( jpi, jpj, jpk, zdepbac, zdepprod, zwork1, zfacsi, zfacsib )
288      !
289      IF( nn_timing == 1 )  CALL timing_stop('p5z_rem')
290      !
291   END SUBROUTINE p5z_rem
292
293
294   SUBROUTINE p5z_rem_init
295      !!----------------------------------------------------------------------
296      !!                  ***  ROUTINE p5z_rem_init  ***
297      !!
298      !! ** Purpose :   Initialization of remineralization parameters
299      !!
300      !! ** Method  :   Read the nampisrem namelist and check the parameters
301      !!      called at the first timestep
302      !!
303      !! ** input   :   Namelist nampisrem
304      !!
305      !!----------------------------------------------------------------------
306      NAMELIST/nampisrem/ xremikc, xremikn, xremikp,   &
307      &                   nitrif, xsirem, xsiremlab, xsilab, oxymin, oxymin2,  &
308      &                   feratb, xkferb 
309      INTEGER :: ios                 ! Local integer output status for namelist read
310
311      REWIND( numnatp_ref )              ! Namelist nampisrem in reference namelist : Pisces remineralization
312      READ  ( numnatp_ref, nampisrem, IOSTAT = ios, ERR = 901)
313901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisrem in reference namelist', lwp )
314
315      REWIND( numnatp_cfg )              ! Namelist nampisrem in configuration namelist : Pisces remineralization
316      READ  ( numnatp_cfg, nampisrem, IOSTAT = ios, ERR = 902 )
317902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisrem in configuration namelist', lwp )
318      IF(lwm) WRITE ( numonp, nampisrem )
319
320      IF(lwp) THEN                         ! control print
321         WRITE(numout,*) ' '
322         WRITE(numout,*) ' Namelist parameters for remineralization, nampisrem'
323         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
324         WRITE(numout,*) '    remineralization rate of DOC              xremikc   =', xremikc
325         WRITE(numout,*) '    remineralization rate of DON              xremikn   =', xremikn
326         WRITE(numout,*) '    remineralization rate of DOP              xremikp   =', xremikp
327         WRITE(numout,*) '    remineralization rate of Si               xsirem    =', xsirem
328         WRITE(numout,*) '    fast remineralization rate of Si          xsiremlab =', xsiremlab
329         WRITE(numout,*) '    fraction of labile biogenic silica        xsilab    =', xsilab
330         WRITE(numout,*) '    NH4 nitrification rate                    nitrif    =', nitrif
331         WRITE(numout,*) '    half saturation constant for anoxia       oxymin    =', oxymin
332         WRITE(numout,*) '    Minimum O2 concentration for oxic remin.  oxymin2   =', oxymin2
333         WRITE(numout,*) '    Bacterial Fe/C ratio                      feratb    =', feratb
334         WRITE(numout,*) '    Half-saturation constant for bact. Fe/C   xkferb    =', xkferb
335      ENDIF
336      !
337      nitrfac (:,:,:) = 0._wp
338      denitrc (:,:,:) = 0._wp
339      !
340   END SUBROUTINE p5z_rem_init
341
342
343   INTEGER FUNCTION p5z_rem_alloc()
344      !!----------------------------------------------------------------------
345      !!                     ***  ROUTINE p5z_rem_alloc  ***
346      !!----------------------------------------------------------------------
347      ALLOCATE( denitrc(jpi,jpj,jpk), STAT=p5z_rem_alloc )
348      !
349      IF( p5z_rem_alloc /= 0 )   CALL ctl_warn('p5z_rem_alloc: failed to allocate arrays')
350      !
351   END FUNCTION p5z_rem_alloc
352
353#else
354   !!======================================================================
355   !!  Dummy module :                                   No PISCES bio-model
356   !!======================================================================
357CONTAINS
358   SUBROUTINE p5z_rem                    ! Empty routine
359   END SUBROUTINE p5z_rem
360#endif 
361
362   !!======================================================================
363END MODULE p5zrem
Note: See TracBrowser for help on using the repository browser.