source: branches/NERC/dev_r5518_GO6_package_trdtrc/NEMOGCM/NEMO/OPA_SRC/TRD/trdtra.F90 @ 8453

Last change on this file since 8453 was 8453, checked in by jpalmier, 4 years ago

JPALM —22-08-2017— repair trends for passive tracers

File size: 22.0 KB
Line 
1MODULE trdtra
2   !!======================================================================
3   !!                       ***  MODULE  trdtra  ***
4   !! Ocean diagnostics:  ocean tracers trends pre-processing
5   !!=====================================================================
6   !! History :  3.3  !  2010-06  (C. Ethe) creation for the TRA/TRC merge
7   !!            3.5  !  2012-02  (G. Madec) update the comments
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   trd_tra       : pre-process the tracer trends
12   !!   trd_tra_adv   : transform a div(U.T) trend into a U.grad(T) trend
13   !!   trd_tra_mng   : tracer trend manager: dispatch to the diagnostic modules
14   !!   trd_tra_iom   : output 3D tracer trends using IOM
15   !!----------------------------------------------------------------------
16   USE oce            ! ocean dynamics and tracers variables
17   USE dom_oce        ! ocean domain
18   USE sbc_oce        ! surface boundary condition: ocean
19   USE zdf_oce        ! ocean vertical physics
20   USE trd_oce        ! trends: ocean variables
21   USE trdtrc         ! ocean passive mixed layer tracers trends
22   USE trc,           ONLY: tra    ! tracer definitions (trn, trb, tra, etc.)
23   USE trdglo         ! trends: global domain averaged
24   USE trdpen         ! trends: Potential ENergy
25   USE trdmxl         ! ocean active mixed layer tracers trends
26   USE ldftra_oce     ! ocean active tracers lateral physics
27   USE zdfddm         ! vertical physics: double diffusion
28   USE phycst         ! physical constants
29   USE in_out_manager ! I/O manager
30   USE iom            ! I/O manager library
31   USE lib_mpp        ! MPP library
32   USE wrk_nemo       ! Memory allocation
33
34   IMPLICIT NONE
35   PRIVATE
36
37   PUBLIC   trd_tra   ! called by all tra_... modules
38
39   REAL(wp) ::   r2dt   ! time-step, = 2 rdttra except at nit000 (=rdttra) if neuler=0
40
41   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   trdtx, trdty, trdt  ! use to store the temperature trends
42   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   avt_evd  ! store avt_evd to calculate EVD trend
43
44   !! * Substitutions
45#  include "domzgr_substitute.h90"
46#  include "zdfddm_substitute.h90"
47#  include "vectopt_loop_substitute.h90"
48   !!----------------------------------------------------------------------
49   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
50   !! $Id$
51   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
52   !!----------------------------------------------------------------------
53CONTAINS
54
55   INTEGER FUNCTION trd_tra_alloc()
56      !!---------------------------------------------------------------------
57      !!                  ***  FUNCTION trd_tra_alloc  ***
58      !!---------------------------------------------------------------------
59      ALLOCATE( trdtx(jpi,jpj,jpk) , trdty(jpi,jpj,jpk) , trdt(jpi,jpj,jpk) , avt_evd(jpi,jpj,jpk), STAT= trd_tra_alloc )
60      !
61      IF( lk_mpp             )   CALL mpp_sum ( trd_tra_alloc )
62      IF( trd_tra_alloc /= 0 )   CALL ctl_warn('trd_tra_alloc: failed to allocate arrays')
63   END FUNCTION trd_tra_alloc
64
65
66   SUBROUTINE trd_tra( kt, ctype, ktra, ktrd, ptrd, pun, ptra )
67      !!---------------------------------------------------------------------
68      !!                  ***  ROUTINE trd_tra  ***
69      !!
70      !! ** Purpose : pre-process tracer trends
71      !!
72      !! ** Method  : - mask the trend
73      !!              - advection (ptra present) converte the incoming flux (U.T)
74      !!              into trend (U.T => -U.grat(T)=div(U.T)-T.div(U)) through a
75      !!              call to trd_tra_adv
76      !!              - 'TRA' case : regroup T & S trends
77      !!              - send the trends to trd_tra_mng (trdtrc) for further processing
78      !!----------------------------------------------------------------------
79      INTEGER                         , INTENT(in)           ::   kt      ! time step
80      CHARACTER(len=3)                , INTENT(in)           ::   ctype   ! tracers trends type 'TRA'/'TRC'
81      INTEGER                         , INTENT(in)           ::   ktra    ! tracer index
82      INTEGER                         , INTENT(in)           ::   ktrd    ! tracer trend index
83      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in)           ::   ptrd    ! tracer trend  or flux
84      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in), OPTIONAL ::   pun     ! now velocity
85      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in), OPTIONAL ::   ptra    ! now tracer variable
86      !
87      INTEGER  ::   jk   ! loop indices
88      REAL(wp), POINTER, DIMENSION(:,:,:)  ::   zwt, zws, ztrdt, ztrds   ! 3D workspace
89      !!----------------------------------------------------------------------
90      !
91      CALL wrk_alloc( jpi, jpj, jpk, ztrds )
92      !     
93      IF( .NOT. ALLOCATED( trdtx ) ) THEN      ! allocate trdtra arrays
94         IF( trd_tra_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'trd_tra : unable to allocate arrays' )
95      ENDIF
96
97      IF( ctype == 'TRA' .AND. ktra == jp_tem ) THEN   !==  Temperature trend  ==!
98         !
99         SELECT CASE( ktrd )
100         !                            ! advection: transform the advective flux into a trend
101         CASE( jptra_xad )   ;   CALL trd_tra_adv( ptrd, pun, ptra, 'X', trdtx ) 
102         CASE( jptra_yad )   ;   CALL trd_tra_adv( ptrd, pun, ptra, 'Y', trdty ) 
103         CASE( jptra_zad )   ;   CALL trd_tra_adv( ptrd, pun, ptra, 'Z', trdt  ) 
104         CASE( jptra_bbc,    &        ! qsr, bbc: on temperature only, send to trd_tra_mng
105            &  jptra_qsr )   ;   trdt(:,:,:) = ptrd(:,:,:) * tmask(:,:,:)
106                                 ztrds(:,:,:) = 0._wp
107                                 CALL trd_tra_mng( trdt, ztrds, ktrd, kt )
108         CASE( jptra_evd )   ;   avt_evd(:,:,:) = ptrd(:,:,:) * tmask(:,:,:)
109         CASE DEFAULT                 ! other trends: masked trends
110            trdt(:,:,:) = ptrd(:,:,:) * tmask(:,:,:)              ! mask & store
111         END SELECT
112         !
113      ENDIF
114
115      IF( ctype == 'TRA' .AND. ktra == jp_sal ) THEN      !==  Salinity trends  ==!
116         !
117         SELECT CASE( ktrd )
118         !                            ! advection: transform the advective flux into a trend
119         !                            !            and send T & S trends to trd_tra_mng
120         CASE( jptra_xad  )   ;   CALL trd_tra_adv( ptrd , pun  , ptra, 'X'  , ztrds ) 
121                                  CALL trd_tra_mng( trdtx, ztrds, ktrd, kt   )
122         CASE( jptra_yad  )   ;   CALL trd_tra_adv( ptrd , pun  , ptra, 'Y'  , ztrds ) 
123                                  CALL trd_tra_mng( trdty, ztrds, ktrd, kt   )
124         CASE( jptra_zad  )   ;   CALL trd_tra_adv( ptrd , pun  , ptra, 'Z'  , ztrds ) 
125                                  CALL trd_tra_mng( trdt , ztrds, ktrd, kt   )
126         CASE( jptra_zdfp )           ! diagnose the "PURE" Kz trend (here: just before the swap)
127            !                         ! iso-neutral diffusion case otherwise jptra_zdf is "PURE"
128            CALL wrk_alloc( jpi, jpj, jpk, zwt, zws, ztrdt )
129            !
130            zwt(:,:, 1 ) = 0._wp   ;   zws(:,:, 1 ) = 0._wp            ! vertical diffusive fluxes
131            zwt(:,:,jpk) = 0._wp   ;   zws(:,:,jpk) = 0._wp
132            DO jk = 2, jpk
133               zwt(:,:,jk) = avt(:,:,jk) * ( tsa(:,:,jk-1,jp_tem) - tsa(:,:,jk,jp_tem) ) / fse3w(:,:,jk) * tmask(:,:,jk)
134               zws(:,:,jk) = fsavs(:,:,jk) * ( tsa(:,:,jk-1,jp_sal) - tsa(:,:,jk,jp_sal) ) / fse3w(:,:,jk) * tmask(:,:,jk)
135            END DO
136            !
137            ztrdt(:,:,jpk) = 0._wp   ;   ztrds(:,:,jpk) = 0._wp
138            DO jk = 1, jpkm1
139               ztrdt(:,:,jk) = ( zwt(:,:,jk) - zwt(:,:,jk+1) ) / fse3t(:,:,jk)
140               ztrds(:,:,jk) = ( zws(:,:,jk) - zws(:,:,jk+1) ) / fse3t(:,:,jk) 
141            END DO
142            CALL trd_tra_mng( ztrdt, ztrds, jptra_zdfp, kt ) 
143            !
144            !                         ! Also calculate EVD trend at this point.
145            zwt(:,:,:) = 0._wp   ;   zws(:,:,:) = 0._wp            ! vertical diffusive fluxes
146            DO jk = 2, jpk
147               zwt(:,:,jk) = avt_evd(:,:,jk) * ( tsa(:,:,jk-1,jp_tem) - tsa(:,:,jk,jp_tem) ) / fse3w(:,:,jk) * tmask(:,:,jk)
148               zws(:,:,jk) = avt_evd(:,:,jk) * ( tsa(:,:,jk-1,jp_sal) - tsa(:,:,jk,jp_sal) ) / fse3w(:,:,jk) * tmask(:,:,jk)
149            END DO
150            !
151            ztrdt(:,:,jpk) = 0._wp   ;   ztrds(:,:,jpk) = 0._wp
152            DO jk = 1, jpkm1
153               ztrdt(:,:,jk) = ( zwt(:,:,jk) - zwt(:,:,jk+1) ) / fse3t(:,:,jk)
154               ztrds(:,:,jk) = ( zws(:,:,jk) - zws(:,:,jk+1) ) / fse3t(:,:,jk) 
155            END DO
156            CALL trd_tra_mng( ztrdt, ztrds, jptra_evd, kt ) 
157            !
158            CALL wrk_dealloc( jpi, jpj, jpk, zwt, zws, ztrdt )
159            !
160         CASE DEFAULT                 ! other trends: mask and send T & S trends to trd_tra_mng
161            ztrds(:,:,:) = ptrd(:,:,:) * tmask(:,:,:)
162            CALL trd_tra_mng( trdt, ztrds, ktrd, kt ) 
163         END SELECT
164      ENDIF
165
166      IF( ctype == 'TRC' ) THEN                           !==  passive tracer trend  ==!
167         !
168         SELECT CASE( ktrd )
169         !                            ! advection: transform the advective flux into a masked trend
170         CASE( jptra_xad )   ;   CALL trd_tra_adv( ptrd , pun , ptra, 'X', ztrds ) 
171         CASE( jptra_yad )   ;   CALL trd_tra_adv( ptrd , pun , ptra, 'Y', ztrds ) 
172         CASE( jptra_zad )   ;   CALL trd_tra_adv( ptrd , pun , ptra, 'Z', ztrds ) 
173         CASE( jptra_zdfp )           ! diagnose the "PURE" Kz trend (here: just before the swap)
174            !                         ! iso-neutral diffusion case otherwise
175            !                         jptra_zdf is "PURE"
176            CALL wrk_alloc( jpi, jpj, jpk, zws )
177            !
178            zws(:,:, 1 ) = 0._wp                        ! vertical diffusive fluxes
179            zws(:,:,jpk) = 0._wp 
180            DO jk = 2, jpk
181               zws(:,:,jk) = avt(:,:,jk) * (tra(:,:,jk-1,ktra) - tra(:,:,jk,ktra) ) / fse3w(:,:,jk) * tmask(:,:,jk)
182            END DO
183            !
184            ztrds(:,:,jpk) = 0._wp   
185            DO jk = 1, jpkm1
186               ztrds(:,:,jk) = ( zws(:,:,jk) - zws(:,:,jk+1) ) / fse3t(:,:,jk)
187            END DO
188            CALL wrk_dealloc( jpi, jpj, jpk, zws )
189            !
190         CASE DEFAULT                 ! other trends: just masked
191                                 ztrds(:,:,:) = ptrd(:,:,:) * tmask(:,:,:)
192         END SELECT
193         !                            ! send trend to trd_trc
194         CALL trd_trc( ztrds, ktra, ktrd, kt ) 
195         !
196      ENDIF
197      !
198      CALL wrk_dealloc( jpi, jpj, jpk, ztrds )
199      !
200   END SUBROUTINE trd_tra
201
202
203   SUBROUTINE trd_tra_adv( pf, pun, ptn, cdir, ptrd )
204      !!---------------------------------------------------------------------
205      !!                  ***  ROUTINE trd_tra_adv  ***
206      !!
207      !! ** Purpose :   transformed a advective flux into a masked advective trends
208      !!
209      !! ** Method  :   use the following transformation: -div(U.T) = - U grad(T) + T.div(U)
210      !!       i-advective trends = -un. di-1[T] = -( di-1[fi] - tn di-1[un] )
211      !!       j-advective trends = -un. di-1[T] = -( dj-1[fi] - tn dj-1[un] )
212      !!       k-advective trends = -un. di+1[T] = -( dk+1[fi] - tn dk+1[un] )
213      !!                where fi is the incoming advective flux.
214      !!----------------------------------------------------------------------
215      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pf      ! advective flux in one direction
216      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pun     ! now velocity   in one direction
217      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   ptn     ! now or before tracer
218      CHARACTER(len=1)                , INTENT(in   ) ::   cdir    ! X/Y/Z direction
219      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(  out) ::   ptrd    ! advective trend in one direction
220      !
221      INTEGER  ::   ji, jj, jk   ! dummy loop indices
222      INTEGER  ::   ii, ij, ik   ! index shift as function of the direction
223      !!----------------------------------------------------------------------
224      !
225      SELECT CASE( cdir )      ! shift depending on the direction
226      CASE( 'X' )   ;   ii = 1   ;   ij = 0   ;   ik = 0      ! i-trend
227      CASE( 'Y' )   ;   ii = 0   ;   ij = 1   ;   ik = 0      ! j-trend
228      CASE( 'Z' )   ;   ii = 0   ;   ij = 0   ;   ik =-1      ! k-trend
229      END SELECT
230      !
231      !                        ! set to zero uncomputed values
232      ptrd(jpi,:,:) = 0._wp   ;   ptrd(1,:,:) = 0._wp
233      ptrd(:,jpj,:) = 0._wp   ;   ptrd(:,1,:) = 0._wp
234      ptrd(:,:,jpk) = 0._wp
235      !
236      DO jk = 1, jpkm1         ! advective trend
237         DO jj = 2, jpjm1
238            DO ji = fs_2, fs_jpim1   ! vector opt.
239               ptrd(ji,jj,jk) = - (     pf (ji,jj,jk) - pf (ji-ii,jj-ij,jk-ik)                        &
240                 &                  - ( pun(ji,jj,jk) - pun(ji-ii,jj-ij,jk-ik) ) * ptn(ji,jj,jk)  )   &
241                 &              / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )  * tmask(ji,jj,jk)
242            END DO
243         END DO
244      END DO
245      !
246   END SUBROUTINE trd_tra_adv
247
248
249   SUBROUTINE trd_tra_mng( ptrdx, ptrdy, ktrd, kt )
250      !!---------------------------------------------------------------------
251      !!                  ***  ROUTINE trd_tra_mng  ***
252      !!
253      !! ** Purpose :   Dispatch all tracer trends computation, e.g. 3D output,
254      !!                integral constraints, potential energy, and/or
255      !!                mixed layer budget.
256      !!----------------------------------------------------------------------
257      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   ptrdx   ! Temperature or U trend
258      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   ptrdy   ! Salinity    or V trend
259      INTEGER                   , INTENT(in   ) ::   ktrd    ! tracer trend index
260      INTEGER                   , INTENT(in   ) ::   kt      ! time step
261      !!----------------------------------------------------------------------
262
263      IF( neuler == 0 .AND. kt == nit000    ) THEN   ;   r2dt =      rdt      ! = rdtra (restart with Euler time stepping)
264      ELSEIF(               kt <= nit000 + 1) THEN   ;   r2dt = 2. * rdt      ! = 2 rdttra (leapfrog)
265      ENDIF
266
267      !                   ! 3D output of tracers trends using IOM interface
268      IF( ln_tra_trd )   CALL trd_tra_iom ( ptrdx, ptrdy, ktrd, kt )
269
270      !                   ! Integral Constraints Properties for tracers trends                                       !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
271      IF( ln_glo_trd )   CALL trd_glo( ptrdx, ptrdy, ktrd, 'TRA', kt )
272
273      !                   ! Potential ENergy trends
274      IF( ln_PE_trd  )   CALL trd_pen( ptrdx, ptrdy, ktrd, kt, r2dt )
275
276      !                   ! Mixed layer trends for active tracers
277      IF( ln_tra_mxl )   THEN   
278         !-----------------------------------------------------------------------------------------------
279         ! W.A.R.N.I.N.G :
280         ! jptra_ldf : called by traldf.F90
281         !                 at this stage we store:
282         !                  - the lateral geopotential diffusion (here, lateral = horizontal)
283         !                  - and the iso-neutral diffusion if activated
284         ! jptra_zdf : called by trazdf.F90
285         !                 * in case of iso-neutral diffusion we store the vertical diffusion component in the
286         !                   lateral trend including the K_z contrib, which will be removed later (see trd_mxl)
287         !-----------------------------------------------------------------------------------------------
288
289         SELECT CASE ( ktrd )
290         CASE ( jptra_xad )        ;   CALL trd_mxl_zint( ptrdx, ptrdy, jpmxl_xad, '3D' )   ! zonal    advection
291         CASE ( jptra_yad )        ;   CALL trd_mxl_zint( ptrdx, ptrdy, jpmxl_yad, '3D' )   ! merid.   advection
292         CASE ( jptra_zad )        ;   CALL trd_mxl_zint( ptrdx, ptrdy, jpmxl_zad, '3D' )   ! vertical advection
293         CASE ( jptra_ldf )        ;   CALL trd_mxl_zint( ptrdx, ptrdy, jpmxl_ldf, '3D' )   ! lateral  diffusion
294         CASE ( jptra_bbl )        ;   CALL trd_mxl_zint( ptrdx, ptrdy, jpmxl_bbl, '3D' )   ! bottom boundary layer
295         CASE ( jptra_zdf )
296            IF( ln_traldf_iso ) THEN ; CALL trd_mxl_zint( ptrdx, ptrdy, jpmxl_ldf, '3D' )   ! lateral  diffusion (K_z)
297            ELSE                   ;   CALL trd_mxl_zint( ptrdx, ptrdy, jpmxl_zdf, '3D' )   ! vertical diffusion (K_z)
298            ENDIF
299         CASE ( jptra_dmp )        ;   CALL trd_mxl_zint( ptrdx, ptrdy, jpmxl_dmp, '3D' )   ! internal 3D restoring (tradmp)
300         CASE ( jptra_qsr )        ;   CALL trd_mxl_zint( ptrdx, ptrdy, jpmxl_for, '3D' )   ! air-sea : penetrative sol radiat
301         CASE ( jptra_nsr )        ;   ptrdx(:,:,2:jpk) = 0._wp   ;   ptrdy(:,:,2:jpk) = 0._wp
302                                       CALL trd_mxl_zint( ptrdx, ptrdy, jpmxl_for, '2D' )   ! air-sea : non penetr sol radiation
303         CASE ( jptra_bbc )        ;   CALL trd_mxl_zint( ptrdx, ptrdy, jpmxl_bbc, '3D' )   ! bottom bound cond (geoth flux)
304         CASE ( jptra_npc )        ;   CALL trd_mxl_zint( ptrdx, ptrdy, jpmxl_npc, '3D' )   ! non penetr convect adjustment
305         CASE ( jptra_atf )        ;   CALL trd_mxl_zint( ptrdx, ptrdy, jpmxl_atf, '3D' )   ! asselin time filter (last trend)
306                                   !
307                                       CALL trd_mxl( kt, r2dt )                             ! trends: Mixed-layer (output)
308         END SELECT
309         !
310      ENDIF
311      !
312   END SUBROUTINE trd_tra_mng
313
314
315   SUBROUTINE trd_tra_iom( ptrdx, ptrdy, ktrd, kt )
316      !!---------------------------------------------------------------------
317      !!                  ***  ROUTINE trd_tra_iom  ***
318      !!
319      !! ** Purpose :   output 3D tracer trends using IOM
320      !!----------------------------------------------------------------------
321     REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   ptrdx   ! Temperature or U trend
322     REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   ptrdy   ! Salinity    or V trend
323     INTEGER                   , INTENT(in   ) ::   ktrd    ! tracer trend index
324     INTEGER                   , INTENT(in   ) ::   kt      ! time step
325     !!
326     INTEGER ::   ji, jj, jk   ! dummy loop indices
327     INTEGER ::   ikbu, ikbv   ! local integers
328     REAL(wp), POINTER, DIMENSION(:,:)   ::   z2dx, z2dy   ! 2D workspace
329     !!----------------------------------------------------------------------
330     !
331     !!gm Rq: mask the trends already masked in trd_tra, but lbc_lnk should probably be added
332     !
333     ! Trends evaluated every time step that could go to the standard T file and can be output every ts into a 1ts file if 1ts output is selected
334     SELECT CASE( ktrd )
335     ! This total trend is done every time step
336     CASE( jptra_tot  )   ;   CALL iom_put( "ttrd_tot" , ptrdx )           ! model total trend
337        CALL iom_put( "strd_tot" , ptrdy )
338     END SELECT
339
340     ! These trends are done every second time step. When 1ts output is selected must go different (2ts) file from standard T-file
341     IF( MOD( kt, 2 ) == 0 ) THEN
342        SELECT CASE( ktrd )
343        CASE( jptra_xad  )   ;   CALL iom_put( "ttrd_xad" , ptrdx )        ! x- horizontal advection
344           CALL iom_put( "strd_xad" , ptrdy )
345        CASE( jptra_yad  )   ;   CALL iom_put( "ttrd_yad" , ptrdx )        ! y- horizontal advection
346           CALL iom_put( "strd_yad" , ptrdy )
347        CASE( jptra_zad  )   ;   CALL iom_put( "ttrd_zad" , ptrdx )        ! z- vertical   advection
348           CALL iom_put( "strd_zad" , ptrdy )
349           IF( .NOT. lk_vvl ) THEN                   ! cst volume : adv flux through z=0 surface
350              CALL wrk_alloc( jpi, jpj, z2dx, z2dy )
351              z2dx(:,:) = wn(:,:,1) * tsn(:,:,1,jp_tem) / fse3t(:,:,1)
352              z2dy(:,:) = wn(:,:,1) * tsn(:,:,1,jp_sal) / fse3t(:,:,1)
353              CALL iom_put( "ttrd_sad", z2dx )
354              CALL iom_put( "strd_sad", z2dy )
355              CALL wrk_dealloc( jpi, jpj, z2dx, z2dy )
356           ENDIF
357        CASE( jptra_totad  ) ;   CALL iom_put( "ttrd_totad" , ptrdx )      ! total   advection
358           CALL iom_put( "strd_totad" , ptrdy )
359        CASE( jptra_ldf  )   ;   CALL iom_put( "ttrd_ldf" , ptrdx )        ! lateral diffusion
360           CALL iom_put( "strd_ldf" , ptrdy )
361        CASE( jptra_zdf  )   ;   CALL iom_put( "ttrd_zdf" , ptrdx )        ! vertical diffusion (including Kz contribution)
362           CALL iom_put( "strd_zdf" , ptrdy )
363        CASE( jptra_zdfp )   ;   CALL iom_put( "ttrd_zdfp", ptrdx )        ! PURE vertical diffusion (no isoneutral contribution)
364           CALL iom_put( "strd_zdfp", ptrdy )
365        CASE( jptra_evd )    ;   CALL iom_put( "ttrd_evd", ptrdx )         ! EVD trend (convection)
366           CALL iom_put( "strd_evd", ptrdy )
367        CASE( jptra_dmp  )   ;   CALL iom_put( "ttrd_dmp" , ptrdx )        ! internal restoring (damping)
368           CALL iom_put( "strd_dmp" , ptrdy )
369        CASE( jptra_bbl  )   ;   CALL iom_put( "ttrd_bbl" , ptrdx )        ! bottom boundary layer
370           CALL iom_put( "strd_bbl" , ptrdy )
371        CASE( jptra_npc  )   ;   CALL iom_put( "ttrd_npc" , ptrdx )        ! static instability mixing
372           CALL iom_put( "strd_npc" , ptrdy )
373        CASE( jptra_bbc  )   ;   CALL iom_put( "ttrd_bbc" , ptrdx )        ! geothermal heating   (only on temperature)
374        CASE( jptra_nsr  )   ;   CALL iom_put( "ttrd_qns" , ptrdx(:,:,1) ) ! surface forcing + runoff (ln_rnf=T)
375           CALL iom_put( "strd_cdt" , ptrdy(:,:,1) )        ! output as 2D surface fields
376        CASE( jptra_qsr  )   ;   CALL iom_put( "ttrd_qsr" , ptrdx )        ! penetrative solar radiat. (only on temperature)
377        END SELECT
378        ! the Asselin filter trend  is also every other time step but needs to be lagged one time step
379        ! Even when 1ts output is selected can go to the same (2ts) file as the trends plotted every even time step.
380     ELSE IF( MOD( kt, 2 ) == 1 ) THEN
381        SELECT CASE( ktrd )
382        CASE( jptra_atf  )   ;   CALL iom_put( "ttrd_atf" , ptrdx )        ! asselin time Filter
383           CALL iom_put( "strd_atf" , ptrdy )
384        END SELECT
385     END IF
386     !
387   END SUBROUTINE trd_tra_iom
388
389   !!======================================================================
390END MODULE trdtra
Note: See TracBrowser for help on using the repository browser.