source: branches/NERC/dev_r5518_GO6_package_trdtrc/NEMOGCM/NEMO/TOP_SRC/MEDUSA/bio_medusa_update.F90 @ 8453

Last change on this file since 8453 was 8453, checked in by jpalmier, 4 years ago

JPALM —22-08-2017— repair trends for passive tracers

File size: 42.9 KB
Line 
1MODULE bio_medusa_update_mod
2   !!======================================================================
3   !!                         ***  MODULE bio_medusa_update_mod  ***
4   !! Update tracer fields
5   !!======================================================================
6   !! History :
7   !!   -   ! 2017-04 (M. Stringer)        Code taken from trcbio_medusa.F90
8   !!----------------------------------------------------------------------
9#if defined key_medusa
10   !!----------------------------------------------------------------------
11   !!                                                   MEDUSA bio-model
12   !!----------------------------------------------------------------------
13
14   IMPLICIT NONE
15   PRIVATE
16     
17   PUBLIC   bio_medusa_update        ! Called in trcbio_medusa.F90
18
19   !!----------------------------------------------------------------------
20   !! NEMO/TOP 2.0 , LOCEAN-IPSL (2007)
21   !! $Id$
22   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
23   !!----------------------------------------------------------------------
24
25CONTAINS
26
27   SUBROUTINE bio_medusa_update( kt, jk )
28      !!---------------------------------------------------------------------
29      !!                     ***  ROUTINE bio_medusa_update  ***
30      !! This called from TRC_BIO_MEDUSA and updates the tracer fields
31      !!---------------------------------------------------------------------
32      USE bio_medusa_mod,    ONLY: b0, bddtalk3, bddtdic3, bddtdife3,        &
33                                   bddtdin3, bddtdisi3,                      &
34                                   ibenthic, ibio_switch, idf, idfval,       &
35                                   f_benout_c, f_benout_ca, f_benout_n,      &
36                                   f_benout_si,                              &
37                                   f_co2flux, f_o2flux,                      &
38                                   f_riv_loc_alk, f_riv_loc_c,               &
39                                   f_riv_loc_n, f_riv_loc_si,                & 
40                                   f_riv_alk, f_riv_c, f_riv_n, f_riv_si,    &
41                                   fbddtalk, fbddtdic, fbddtdife,            &
42                                   fbddtdin, fbddtdisi,                      & 
43                                   fdd, fdpd, fdpd2, fdpds, fdpds2,          &
44                                   fdpn, fdpn2,                              &
45                                   fdzme, fdzme2, fdzmi, fdzmi2,             &
46                                   ffast2slowc, ffast2slown,                 &
47                                   ffebot, ffetop, ffescav,                  &
48                                   fflx_fe, fflx_n, fflx_si,                 &
49                                   fgmed, fgmepd, fgmedc, fgmepd, fgmepds,   &
50                                   fgmepn, fgmezmi,                          &
51                                   fgmid, fgmidc, fgmipn,                    &
52                                   ficme, ficmi, finme, finmi,               &
53                                   fmeexcr, fmegrow, fmeresp,                &
54                                   fmiexcr, fmigrow, fmiresp,                &
55                                   fnit_cons, fnit_prod,                     &
56                                   fprd, fprds, fprn,                        &
57                                   frd,                                      &
58                                   freminc, freminca, freminn, freminsi,     &
59                                   frn,                                      &
60                                   fsil_cons, fsil_prod, fsdiss,             &
61                                   ftempca, fthetad, fthetan,                &
62# if defined key_roam
63                                   fcar_cons, fcar_prod, fcomm_resp,         &
64                                   fddc, fflx_a, fflx_c, fflx_o2, zoxy,      &
65                                   foxy_anox, foxy_cons, foxy_prod,          &
66# endif
67                                   zpds, zphd, zphn
68      USE dom_oce,           ONLY: e3t_0, e3t_n, gphit, mbathy, tmask
69      USE in_out_manager,    ONLY: lwp, numout
70      USE lib_mpp,           ONLY: ctl_stop
71      USE par_kind,          ONLY: wp
72      USE par_medusa,        ONLY: jp_medusa,                                &
73                                   jpalk, jpchd, jpchn, jpdet, jpdic,        &
74                                   jpdin, jpdtc, jpfer, jpoxy, jppds,        &
75                                   jpphd, jpphn, jpsil, jpzme, jpzmi,        &
76                                   jpalk_lc, jpchd_lc, jpchn_lc, jpdet_lc,   & 
77                                   jpdic_lc, jpdin_lc, jpdtc_lc, jpfer_lc,   & 
78                                   jpoxy_lc, jppds_lc, jpphd_lc, jpphn_lc,   &
79                                   jpsil_lc, jpzme_lc, jpzmi_lc
80      USE par_oce,           ONLY: jpi, jpim1, jpj, jpjm1
81      USE par_trc,           ONLY: jptra
82      USE sms_medusa,        ONLY: friver_dep,                               &
83                                   jinorgben, jorgben,                       &
84                                   jriver_alk, jriver_c,                     &
85                                   jriver_n, jriver_si,                      &
86                                   xbetac, xbetan,                           &
87                                   xfdfrac1, xfdfrac2, xfdfrac3,             &
88                                   xo2min, xphi, xrfn,                       &
89                                   xthetanit, xthetapd, xthetapn,            &
90                                   xthetarem, xthetazme, xthetazmi,          &
91                                   xxi
92      USE trc,               ONLY: med_diag, tra
93      USE trd_oce,           ONLY: jptra_sms 
94      USE trdtrc
95
96   !!* Substitution
97#  include "domzgr_substitute.h90"
98
99      !! time (integer timestep)
100      INTEGER, INTENT( in ) :: kt
101      !! Level
102      INTEGER, INTENT( in ) :: jk
103
104      !! Loop variables
105      INTEGER :: ji, jj, jn
106
107      !! AXY (23/08/13): changed from individual variables for each flux to
108      !!                 an array that holds all fluxes
109      REAL(wp), DIMENSION(jpi,jpj,jp_medusa) :: btra
110
111      !! nitrogen and silicon production and consumption
112      REAL(wp) :: fn_prod, fn_cons, fs_prod, fs_cons
113
114      !! carbon, alkalinity production and consumption
115      REAL(wp) :: fc_prod, fc_cons, fa_prod, fa_cons
116
117      !! oxygen production and consumption (and non-consumption)
118      REAL(wp), DIMENSION(jpi,jpj) :: fo2_prod, fo2_cons
119      REAL(wp), DIMENSION(jpi,jpj) :: fo2_ncons, fo2_ccons
120
121      !! temporary variables
122      REAL(wp) :: fq0
123
124      !! trend temporary array:
125      REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrmed
126
127      !!==========================================================
128      !! LOCAL GRID CELL TRENDS
129      !!==========================================================
130      !!
131      !!----------------------------------------------------------
132      !! Determination of trends
133      !!----------------------------------------------------------
134      DO jj = 2,jpjm1
135         DO ji = 2,jpim1
136            !! OPEN wet point IF..THEN loop
137            if (tmask(ji,jj,jk) == 1) then
138               !!
139               !!----------------------------------------------------------
140               !! chlorophyll
141               btra(ji,jj,jpchn_lc) = b0 * ( ( (frn(ji,jj) * fprn(ji,jj) *      &
142                                             zphn(ji,jj) ) -                 &
143                                           fgmipn(ji,jj) - fgmepn(ji,jj) -   &
144                                           fdpn(ji,jj) - fdpn2(ji,jj) ) *    &
145                                          (fthetan(ji,jj) / xxi) )
146               btra(ji,jj,jpchd_lc) = b0 * ( ( (frd(ji,jj) * fprd(ji,jj) *      &
147                                             zphd(ji,jj) ) -                 &
148                                           fgmepd(ji,jj) - fdpd(ji,jj) -     &
149                                           fdpd2(ji,jj) ) *                  &
150                                          (fthetad(ji,jj) / xxi) )
151            ENDIF
152         ENDDO
153      ENDDO
154
155      DO jj = 2,jpjm1
156         DO ji = 2,jpim1
157            if (tmask(ji,jj,jk) == 1) then
158               !!
159               !!----------------------------------------------------------
160               !! phytoplankton
161               btra(ji,jj,jpphn_lc) = b0 * ( (fprn(ji,jj) * zphn(ji,jj)) -      &
162                                          fgmipn(ji,jj) - fgmepn(ji,jj) -    &
163                                          fdpn(ji,jj) - fdpn2(ji,jj) )
164               btra(ji,jj,jpphd_lc) = b0 * ( (fprd(ji,jj) * zphd(ji,jj)) -      &
165                                          fgmepd(ji,jj) - fdpd(ji,jj) -      &
166                                          fdpd2(ji,jj) )
167               btra(ji,jj,jppds_lc) = b0 * ( (fprds(ji,jj) * zpds(ji,jj)) -     &
168                                          fgmepds(ji,jj) - fdpds(ji,jj) -    &
169                                          fsdiss(ji,jj) - fdpds2(ji,jj) )
170            ENDIF
171         ENDDO
172      ENDDO
173
174      DO jj = 2,jpjm1
175         DO ji = 2,jpim1
176            if (tmask(ji,jj,jk) == 1) then
177               !!
178               !!----------------------------------------------------------
179               !! zooplankton
180               btra(ji,jj,jpzmi_lc) = b0 * (fmigrow(ji,jj) - fgmezmi(ji,jj) -   &
181                                         fdzmi(ji,jj) - fdzmi2(ji,jj))
182               btra(ji,jj,jpzme_lc) = b0 * (fmegrow(ji,jj) - fdzme(ji,jj) -     &
183                                         fdzme2(ji,jj))
184            ENDIF
185         ENDDO
186      ENDDO
187
188      DO jj = 2,jpjm1
189         DO ji = 2,jpim1
190            if (tmask(ji,jj,jk) == 1) then
191               !!
192               !!----------------------------------------------------------
193               !! detritus
194               btra(ji,jj,jpdet_lc) = b0 *                                      &
195                                          ! mort. losses
196                                   (fdpn(ji,jj) + ((1.0 - xfdfrac1) *        &
197                                                   fdpd(ji,jj)) +            &
198                                    fdzmi(ji,jj) +                           &
199                                    ((1.0 - xfdfrac2) * fdzme(ji,jj)) +      &
200                                          ! assim. inefficiency
201                                    ((1.0 - xbetan) * (finmi(ji,jj) +        &
202                                                       finme(ji,jj))) -      &
203                                          ! grazing and remin.
204                                    fgmid(ji,jj) - fgmed(ji,jj) -            &
205                                    fdd(ji,jj) +                             &
206                                          ! seafloor fast->slow
207                                    ffast2slown(ji,jj))
208               !!
209            ENDIF
210         ENDDO
211      ENDDO
212
213      DO jj = 2,jpjm1
214         DO ji = 2,jpim1
215            if (tmask(ji,jj,jk) == 1) then
216               !!----------------------------------------------------------
217               !! dissolved inorganic nitrogen nutrient
218               !! primary production
219               fn_cons = - (fprn(ji,jj) * zphn(ji,jj)) -                     &
220                           (fprd(ji,jj) * zphd(ji,jj))
221               !!
222               fn_prod =                                                     &
223                                         ! messy feeding remin.
224                         (xphi * (fgmipn(ji,jj) + fgmid(ji,jj))) +           &
225                         (xphi * (fgmepn(ji,jj) + fgmepd(ji,jj) +            &
226                                  fgmezmi(ji,jj) + fgmed(ji,jj))) +          &
227                                         ! excretion and remin.
228                         fmiexcr(ji,jj) + fmeexcr(ji,jj) + fdd(ji,jj) +      &
229                         freminn(ji,jj) +                                    &
230                                         ! metab. losses
231                         fdpn2(ji,jj) + fdpd2(ji,jj) + fdzmi2(ji,jj) +       &
232                         fdzme2(ji,jj)
233               !!
234               !! riverine flux
235               if ( jriver_n .gt. 0 ) then
236                  f_riv_loc_n(ji,jj) = f_riv_n(ji,jj) *                      &
237                     friver_dep(jk,mbathy(ji,jj)) / fse3t(ji,jj,jk)
238                  fn_prod = fn_prod + f_riv_loc_n(ji,jj)
239               endif
240               !! 
241               !! benthic remineralisation
242               if (jk.eq.mbathy(ji,jj) .and. jorgben.eq.1 .and.              &
243                   ibenthic.eq.1) then
244                  fn_prod = fn_prod + (f_benout_n(ji,jj) / fse3t(ji,jj,jk))
245               endif
246               !!
247               btra(ji,jj,jpdin_lc) = b0 * ( fn_prod + fn_cons )
248               !!
249               !! consumption of dissolved nitrogen
250               fnit_cons(ji,jj) = fnit_cons(ji,jj) + ( fse3t(ji,jj,jk) *     &
251                                                       fn_cons )
252               !! production of dissolved nitrogen
253               fnit_prod(ji,jj) = fnit_prod(ji,jj) + ( fse3t(ji,jj,jk) *     &
254                                                       fn_prod )
255            ENDIF
256         ENDDO
257      ENDDO
258
259      DO jj = 2,jpjm1
260         DO ji = 2,jpim1
261            if (tmask(ji,jj,jk) == 1) then
262               !!
263               !!----------------------------------------------------------
264               !! dissolved silicic acid nutrient
265               !! opal production
266               fs_cons = - (fprds(ji,jj) * zpds(ji,jj))
267               !!
268               fs_prod =                                                     &
269                             ! opal dissolution
270                         fsdiss(ji,jj) +                                     &
271                             ! mort. loss
272                         ((1.0 - xfdfrac1) * fdpds(ji,jj)) +                 &
273                             &  ! egestion of grazed Si
274                         ((1.0 - xfdfrac3) * fgmepds(ji,jj)) +               &
275                             ! fast diss. and metab. losses
276                         freminsi(ji,jj) + fdpds2(ji,jj)
277               !!
278               !! riverine flux
279               if ( jriver_si .gt. 0 ) then
280                  f_riv_loc_si(ji,jj) = f_riv_si(ji,jj) *                    &
281                                        friver_dep(jk,mbathy(ji,jj)) /       &
282                                        fse3t(ji,jj,jk)
283                  fs_prod = fs_prod + f_riv_loc_si(ji,jj)
284               endif
285               !! 
286               !! benthic remineralisation
287               if (jk.eq.mbathy(ji,jj) .and. jinorgben.eq.1 .and.            &
288                   ibenthic.eq.1) then
289                  fs_prod = fs_prod + (f_benout_si(ji,jj) / fse3t(ji,jj,jk))
290               endif
291               !!
292               btra(ji,jj,jpsil_lc) = b0 * ( &
293                 fs_prod + fs_cons )
294               !! consumption of dissolved silicon
295               fsil_cons(ji,jj) = fsil_cons(ji,jj) + ( fse3t(ji,jj,jk) *     &
296                                                       fs_cons )
297               !! production of dissolved silicon
298               fsil_prod(ji,jj) = fsil_prod(ji,jj) + ( fse3t(ji,jj,jk) *     &
299                                                       fs_prod )
300            ENDIF
301         ENDDO
302      ENDDO
303
304      DO jj = 2,jpjm1
305         DO ji = 2,jpim1
306            if (tmask(ji,jj,jk) == 1) then !!
307               !!----------------------------------------------------------
308               !! dissolved "iron" nutrient
309               btra(ji,jj,jpfer_lc) = b0 * ( (xrfn * btra(ji,jj,jpdin_lc)) +       &
310                                          ffetop(ji,jj) + ffebot(ji,jj) -    &
311                                          ffescav(ji,jj) )
312# if defined key_roam
313               !!
314               !!----------------------------------------------------------
315               !! AXY (26/11/08): implicit detrital carbon change
316               btra(ji,jj,jpdtc_lc) = b0 * (                                    &
317                                            ! mort. losses
318                                         (xthetapn * fdpn(ji,jj)) +          &
319                                         ((1.0 - xfdfrac1) *                 &
320                                          (xthetapd * fdpd(ji,jj))) +        &
321                                         (xthetazmi * fdzmi(ji,jj)) +        &
322                                         ((1.0 - xfdfrac2) *                 &
323                                          (xthetazme * fdzme(ji,jj))) +      &
324                                             ! assim. inefficiency
325                                         ((1.0 - xbetac) *                   &
326                                          (ficmi(ji,jj) + ficme(ji,jj))) -   &
327                                             ! grazing and remin.
328                                         fgmidc(ji,jj) - fgmedc(ji,jj) -     &
329                                         fddc(ji,jj) +                       &
330                                             ! seafloor fast->slow
331                                         ffast2slowc(ji,jj) )
332            ENDIF
333         ENDDO
334      ENDDO
335
336      DO jj = 2,jpjm1
337         DO ji = 2,jpim1
338            if (tmask(ji,jj,jk) == 1) then
339               !!
340               !!----------------------------------------------------------
341               !! dissolved inorganic carbon
342               !! primary production
343               fc_cons = - (xthetapn * fprn(ji,jj) * zphn(ji,jj)) -          &
344                           (xthetapd * fprd(ji,jj) * zphd(ji,jj))
345               !!
346               fc_prod =                                                     &
347                            ! messy feeding remin
348                         (xthetapn * xphi * fgmipn(ji,jj)) +                 &
349                         (xphi * fgmidc(ji,jj)) +                            &
350                         (xthetapn * xphi * fgmepn(ji,jj)) +                 &
351                         (xthetapd * xphi * fgmepd(ji,jj)) +                 &
352                         (xthetazmi * xphi * fgmezmi(ji,jj)) +               &
353                         (xphi * fgmedc(ji,jj)) +                            &
354                            ! resp., remin., losses
355                         fmiresp(ji,jj) + fmeresp(ji,jj) + fddc(ji,jj) +     &
356                         freminc(ji,jj) + (xthetapn * fdpn2(ji,jj)) +        &
357                            ! losses
358                         (xthetapd * fdpd2(ji,jj)) +                         &
359                         (xthetazmi * fdzmi2(ji,jj)) +                       &
360                         (xthetazme * fdzme2(ji,jj))
361               !!
362               !! riverine flux
363               if ( jriver_c .gt. 0 ) then
364                  f_riv_loc_c(ji,jj) = f_riv_c(ji,jj) *                      &
365                                       friver_dep(jk,mbathy(ji,jj)) /        &
366                                       fse3t(ji,jj,jk)
367                  fc_prod = fc_prod + f_riv_loc_c(ji,jj)
368               endif
369               !! 
370               !! benthic remineralisation
371               if (jk.eq.mbathy(ji,jj) .and. jorgben.eq.1 .and.              &
372                   ibenthic.eq.1) then
373                  fc_prod = fc_prod + (f_benout_c(ji,jj) / fse3t(ji,jj,jk))
374               endif
375               if (jk.eq.mbathy(ji,jj) .and. jinorgben.eq.1 .and.            &
376                   ibenthic.eq.1) then
377                  fc_prod = fc_prod + (f_benout_ca(ji,jj) / fse3t(ji,jj,jk))
378               endif
379               !!
380               !! community respiration (does not include CaCO3 terms -
381               !! obviously!)
382               fcomm_resp(ji,jj) = fcomm_resp(ji,jj) + fc_prod
383               !!
384               !! CaCO3
385               fc_prod = fc_prod - ftempca(ji,jj) + freminca(ji,jj)
386               !!
387               !! riverine flux
388               if ( jk .eq. 1 .and. jriver_c .gt. 0 ) then
389                  fc_prod = fc_prod + f_riv_c(ji,jj)
390               endif
391               !!
392               btra(ji,jj,jpdic_lc) = b0 * ( fc_prod + fc_cons )
393               !! consumption of dissolved carbon
394               fcar_cons(ji,jj) = fcar_cons(ji,jj) + ( fse3t(ji,jj,jk) *     &
395                                                       fc_cons )
396               !! production of dissolved carbon
397               fcar_prod(ji,jj) = fcar_prod(ji,jj) + ( fse3t(ji,jj,jk) *     &
398                                                       fc_prod )
399            ENDIF
400         ENDDO
401      ENDDO
402
403      DO jj = 2,jpjm1
404         DO ji = 2,jpim1
405            if (tmask(ji,jj,jk) == 1) then
406               !!
407               !!----------------------------------------------------------
408               !! alkalinity
409               !! CaCO3 dissolution
410               fa_prod = 2.0 * freminca(ji,jj)
411               !! CaCO3 production
412               fa_cons = - 2.0 * ftempca(ji,jj)
413               !!
414               !! riverine flux
415               if ( jriver_alk .gt. 0 ) then
416                  f_riv_loc_alk(ji,jj) = f_riv_alk(ji,jj) *                  &
417                                         friver_dep(jk,mbathy(ji,jj)) /      &
418                                         fse3t(ji,jj,jk)
419                  fa_prod = fa_prod + f_riv_loc_alk(ji,jj)
420               endif
421               !! 
422               !! benthic remineralisation
423               if (jk.eq.mbathy(ji,jj) .and. jinorgben.eq.1 .and.            &
424                   ibenthic.eq.1) then
425                  fa_prod = fa_prod + (2.0 * f_benout_ca(ji,jj) /            &
426                                       fse3t(ji,jj,jk))
427               endif
428               !!
429               btra(ji,jj,jpalk_lc) = b0 * ( fa_prod + fa_cons )
430            ENDIF
431         ENDDO
432      ENDDO
433
434      DO jj = 2,jpjm1
435         DO ji = 2,jpim1
436            if (tmask(ji,jj,jk) == 1) then
437               !!
438               !!----------------------------------------------------------
439               !! oxygen (has protection at low O2 concentrations;
440               !! OCMIP-2 style)
441               fo2_prod(ji,jj) =                                             &
442                                     ! Pn primary production, N
443                                 (xthetanit * fprn(ji,jj) * zphn(ji,jj)) +   &
444                                     ! Pd primary production, N
445                                 (xthetanit * fprd(ji,jj) * zphd(ji,jj)) +   &
446                                     ! Pn primary production, C
447                                 (xthetarem * xthetapn * fprn(ji,jj) *       &
448                                  zphn(ji,jj)) +                             &
449                                     ! Pd primary production, C
450                                  (xthetarem * xthetapd * fprd(ji,jj) *      &
451                                   zphd(ji,jj))
452               fo2_ncons(ji,jj) =                                            &
453                                     ! Pn messy feeding remin., N
454                                   - (xthetanit * xphi * fgmipn(ji,jj))      &
455                                     ! D  messy feeding remin., N
456                                   - (xthetanit * xphi * fgmid(ji,jj))       &
457                                     ! Pn messy feeding remin., N
458                                   - (xthetanit * xphi * fgmepn(ji,jj))      &
459                                     ! Pd messy feeding remin., N
460                                   - (xthetanit * xphi * fgmepd(ji,jj))      &
461                                     ! Zi messy feeding remin., N
462                                   - (xthetanit * xphi * fgmezmi(ji,jj))     &
463                                     ! D  messy feeding remin., N
464                                   - (xthetanit * xphi * fgmed(ji,jj))       &
465                                     ! microzoo excretion, N
466                                   - (xthetanit * fmiexcr(ji,jj))            &
467                                     ! mesozoo  excretion, N
468                                   - (xthetanit * fmeexcr(ji,jj))            &
469                                     ! slow detritus remin., N
470                                   - (xthetanit * fdd(ji,jj))                &
471                                     ! fast detritus remin., N
472                                   - (xthetanit * freminn(ji,jj))            &
473                                     ! Pn  losses, N
474                                   - (xthetanit * fdpn2(ji,jj))              &
475                                     ! Pd  losses, N
476                                   - (xthetanit * fdpd2(ji,jj))              &
477                                     ! Zmi losses, N
478                                   - (xthetanit * fdzmi2(ji,jj))             &
479                                     ! Zme losses, N
480                                   - (xthetanit * fdzme2(ji,jj))
481               !! 
482               !! benthic remineralisation
483               if (jk.eq.mbathy(ji,jj) .and. jorgben.eq.1 .and.              &
484                   ibenthic.eq.1) then
485                  fo2_ncons(ji,jj) = fo2_ncons(ji,jj) -                      &
486                                     (xthetanit * f_benout_n(ji,jj) /        &
487                                      fse3t(ji,jj,jk))
488               endif
489            ENDIF
490         ENDDO
491      ENDDO
492
493      DO jj = 2,jpjm1
494         DO ji = 2,jpim1
495            if (tmask(ji,jj,jk) == 1) then
496               fo2_ccons(ji,jj) =                                            &
497                                     ! Pn messy feeding remin., C
498                                  - (xthetarem * xthetapn * xphi *           &
499                                     fgmipn(ji,jj))                          &
500                                     ! D  messy feeding remin., C
501                                  - (xthetarem * xphi * fgmidc(ji,jj))       &
502                                     ! Pn messy feeding remin., C
503                                  - (xthetarem * xthetapn * xphi *           &
504                                     fgmepn(ji,jj))                          &
505                                     ! Pd messy feeding remin., C
506                                  - (xthetarem * xthetapd * xphi *           &
507                                     fgmepd(ji,jj))                          &
508                                     ! Zi messy feeding remin., C
509                                  - (xthetarem * xthetazmi * xphi *          &
510                                     fgmezmi(ji,jj))                         &
511                                     ! D  messy feeding remin., C
512                                  - (xthetarem * xphi * fgmedc(ji,jj))       &
513                                     ! microzoo respiration, C
514                                  - (xthetarem * fmiresp(ji,jj))             &
515                                     ! mesozoo  respiration, C
516                                  - (xthetarem * fmeresp(ji,jj))             &
517                                     ! slow detritus remin., C
518                                  - (xthetarem * fddc(ji,jj))                &
519                                     ! fast detritus remin., C
520                                  - (xthetarem * freminc(ji,jj))             &
521                                     ! Pn  losses, C
522                                  - (xthetarem * xthetapn * fdpn2(ji,jj))    &
523                                     ! Pd  losses, C
524                                  - (xthetarem * xthetapd * fdpd2(ji,jj))    &
525                                     ! Zmi losses, C
526                                  - (xthetarem * xthetazmi * fdzmi2(ji,jj))  &
527                                     ! Zme losses, C
528                                  - (xthetarem * xthetazme * fdzme2(ji,jj))
529               !! 
530               !! benthic remineralisation
531               if (jk.eq.mbathy(ji,jj) .and. jorgben.eq.1 .and.              &
532                   ibenthic.eq.1) then
533                  fo2_ccons(ji,jj) = fo2_ccons(ji,jj) - (xthetarem *         &
534                                                         f_benout_c(ji,jj) / &
535                                                         fse3t(ji,jj,jk))
536               endif
537               fo2_cons(ji,jj) = fo2_ncons(ji,jj) + fo2_ccons(ji,jj)
538            ENDIF
539         ENDDO
540      ENDDO
541
542      DO jj = 2,jpjm1
543         DO ji = 2,jpim1
544            if (tmask(ji,jj,jk) == 1) then
545               !!
546               !! is this a suboxic zone?
547               !! deficient O2; production fluxes only
548               if (zoxy(ji,jj).lt.xo2min) then
549                  btra(ji,jj,jpoxy_lc) = b0 * fo2_prod(ji,jj)
550                  foxy_prod(ji,jj) = foxy_prod(ji,jj) + ( fse3t(ji,jj,jk) *  &
551                                                          fo2_prod(ji,jj) )
552                  foxy_anox(ji,jj) = foxy_anox(ji,jj) + ( fse3t(ji,jj,jk) *  &
553                                                          fo2_cons(ji,jj) )
554               else
555                  !! sufficient O2; production + consumption fluxes
556                  btra(ji,jj,jpoxy_lc) = b0 * ( fo2_prod(ji,jj) +               &
557                                             fo2_cons(ji,jj) )
558                  foxy_prod(ji,jj) = foxy_prod(ji,jj) +                      &
559                                     ( fse3t(ji,jj,jk) * fo2_prod(ji,jj) )
560                  foxy_cons(ji,jj) = foxy_cons(ji,jj) +                      &
561                                     ( fse3t(ji,jj,jk) * fo2_cons(ji,jj) )
562               endif
563            ENDIF
564         ENDDO
565      ENDDO
566
567      DO jj = 2,jpjm1
568         DO ji = 2,jpim1
569            if (tmask(ji,jj,jk) == 1) then
570               !!
571               !! air-sea fluxes (if this is the surface box)
572               if (jk.eq.1) then
573                  !!
574                  !! CO2 flux
575                  btra(ji,jj,jpdic_lc) = btra(ji,jj,jpdic_lc) + (b0 *              &
576                                                           f_co2flux(ji,jj))
577                  !!
578                  !! O2 flux (mol/m3/s -> mmol/m3/d)
579                  btra(ji,jj,jpoxy_lc) = btra(ji,jj,jpoxy_lc) + (b0 *              &
580                                                           f_o2flux(ji,jj))
581               endif
582# endif
583            ENDIF
584         ENDDO
585      ENDDO
586
587# if defined key_debug_medusa
588! I DON'T THIS IS MUCH USE, NOW IT'S BEEN PULLED OUT OF THE MAIN DO LOOP
589! - marc 5/5/17
590      DO jj = 2,jpjm1
591         DO ji = 2,jpim1
592            if (tmask(ji,jj,jk) == 1) then
593               !! report state variable fluxes (not including
594               !! fast-sinking detritus)
595               if (idf.eq.1.AND.idfval.eq.1) then
596                  IF (lwp) write (numout,*) '------------------------------'
597                  IF (lwp) write (numout,*) 'btra(ji,jj,jpchn_lc)(',jk,')  = ', &
598                                            btra(ji,jj,jpchn_lc)
599                  IF (lwp) write (numout,*) 'btra(ji,jj,jpchd_lc)(',jk,')  = ', &
600                                            btra(ji,jj,jpchd_lc)
601                  IF (lwp) write (numout,*) 'btra(ji,jj,jpphn_lc)(',jk,')  = ', &
602                                            btra(ji,jj,jpphn_lc)
603                  IF (lwp) write (numout,*) 'btra(ji,jj,jpphd_lc)(',jk,')  = ', &
604                                            btra(ji,jj,jpphd_lc)
605                  IF (lwp) write (numout,*) 'btra(ji,jj,jppds_lc)(',jk,')  = ', &
606                                            btra(ji,jj,jppds_lc)
607                  IF (lwp) write (numout,*) 'btra(ji,jj,jpzmi_lc)(',jk,')  = ', &
608                                            btra(ji,jj,jpzmi_lc)
609                  IF (lwp) write (numout,*) 'btra(ji,jj,jpzme_lc)(',jk,')  = ', &
610                                            btra(ji,jj,jpzme_lc)
611                  IF (lwp) write (numout,*) 'btra(ji,jj,jpdet_lc)(',jk,')  = ', &
612                                            btra(ji,jj,jpdet_lc)
613                  IF (lwp) write (numout,*) 'btra(ji,jj,jpdin_lc)(',jk,')  = ', &
614                                            btra(ji,jj,jpdin_lc)
615                  IF (lwp) write (numout,*) 'btra(ji,jj,jpsil_lc)(',jk,')  = ', &
616                                            btra(ji,jj,jpsil_lc)
617                  IF (lwp) write (numout,*) 'btra(ji,jj,jpfer_lc)(',jk,')  = ', &
618                                            btra(ji,jj,jpfer_lc)
619#  if defined key_roam
620                  IF (lwp) write (numout,*) 'btra(ji,jj,jpdtc_lc)(',jk,')  = ', &
621                                            btra(ji,jj,jpdtc_lc)
622                  IF (lwp) write (numout,*) 'btra(ji,jj,jpdic_lc)(',jk,')  = ', &
623                                            btra(ji,jj,jpdic_lc)
624                  IF (lwp) write (numout,*) 'btra(ji,jj,jpalk_lc)(',jk,')  = ', &
625                                            btra(ji,jj,jpalk_lc)
626                  IF (lwp) write (numout,*) 'btra(ji,jj,jpoxy_lc)(',jk,')  = ', &
627                                            btra(ji,jj,jpoxy_lc)
628#  endif
629               endif
630            ENDIF
631         ENDDO
632      ENDDO
633# endif
634
635      !!----------------------------------------------------------
636      !! Integrate calculated fluxes for mass balance
637      !!----------------------------------------------------------
638      DO jj = 2,jpjm1
639         DO ji = 2,jpim1
640            if (tmask(ji,jj,jk) == 1) then
641               !!
642               !! === nitrogen ===
643               fflx_n(ji,jj)  = fflx_n(ji,jj) + fse3t(ji,jj,jk) *            &
644                                ( btra(ji,jj,jpphn_lc) + btra(ji,jj,jpphd_lc) +    &
645                                  btra(ji,jj,jpzmi_lc) + btra(ji,jj,jpzme_lc) +    &
646                                  btra(ji,jj,jpdet_lc) + btra(ji,jj,jpdin_lc) )
647               !! === silicon ===
648               fflx_si(ji,jj) = fflx_si(ji,jj) + fse3t(ji,jj,jk) *           &
649                                ( btra(ji,jj,jppds_lc) + btra(ji,jj,jpsil_lc) )
650               !! === iron ===
651               fflx_fe(ji,jj) = fflx_fe(ji,jj) + fse3t(ji,jj,jk) *           &
652                                ( (xrfn *                                    &
653                                   (btra(ji,jj,jpphn_lc) + btra(ji,jj,jpphd_lc) +  &
654                                    btra(ji,jj,jpzmi_lc) + btra(ji,jj,jpzme_lc) +  &
655                                    btra(ji,jj,jpdet_lc))) + btra(ji,jj,jpfer_lc) )
656# if defined key_roam
657               !! === carbon ===
658               fflx_c(ji,jj)  = fflx_c(ji,jj) + fse3t(ji,jj,jk) *            &
659                                ( (xthetapn * btra(ji,jj,jpphn_lc)) +           &
660                                  (xthetapd * btra(ji,jj,jpphd_lc)) +           &
661                                  (xthetazmi * btra(ji,jj,jpzmi_lc)) +          &
662                                  (xthetazme * btra(ji,jj,jpzme_lc)) +          &
663                                  btra(ji,jj,jpdtc_lc) + btra(ji,jj,jpdic_lc) )
664               !! === alkalinity ===
665               fflx_a(ji,jj)  = fflx_a(ji,jj) + fse3t(ji,jj,jk) *            &
666                                btra(ji,jj,jpalk_lc)
667               !! === oxygen ===
668               fflx_o2(ji,jj) = fflx_o2(ji,jj) + fse3t(ji,jj,jk) *           &
669                                btra(ji,jj,jpoxy_lc)
670# endif
671            ENDIF
672         ENDDO
673      ENDDO
674
675      !!----------------------------------------------------------
676      !! Apply calculated tracer fluxes
677      !!----------------------------------------------------------
678      !!
679      !! units: [unit of tracer] per second (fluxes are calculated
680      !! above per day)
681      !!
682      DO jj = 2,jpjm1
683         DO ji = 2,jpim1
684            if (tmask(ji,jj,jk) == 1) then
685               ibio_switch = 1
686# if defined key_gulf_finland
687               !! AXY (17/05/13): fudge in a Gulf of Finland correction;
688               !!                 uses longitude-latitude range to
689               !!                 establish if this is a Gulf of Finland
690               !!                 grid cell; if so, then BGC fluxes are
691               !!                 ignored (though still calculated); for
692               !!                 reference, this is meant to be a
693               !!                 temporary fix to see if all of my
694               !!                 problems can be done away with if I
695               !!                 switch off BGC fluxes in the Gulf of
696               !!                 Finland, which currently appears the
697               !!                 source of trouble
698               if ( glamt(ji,jj).gt.24.7 .and. glamt(ji,jj).lt.27.8 .and.    &
699                    gphit(ji,jj).gt.59.2 .and. gphit(ji,jj).lt.60.2 ) then
700                  ibio_switch = 0
701               endif
702# endif               
703               if (ibio_switch.eq.1) then
704                  tra(ji,jj,jk,jpchn) = tra(ji,jj,jk,jpchn) +                &
705                                        (btra(ji,jj,jpchn_lc) / 86400.)
706                  tra(ji,jj,jk,jpchd) = tra(ji,jj,jk,jpchd) +                &
707                                        (btra(ji,jj,jpchd_lc) / 86400.)
708                  tra(ji,jj,jk,jpphn) = tra(ji,jj,jk,jpphn) +                &
709                                        (btra(ji,jj,jpphn_lc) / 86400.)
710                  tra(ji,jj,jk,jpphd) = tra(ji,jj,jk,jpphd) +                &
711                                        (btra(ji,jj,jpphd_lc) / 86400.)
712                  tra(ji,jj,jk,jppds) = tra(ji,jj,jk,jppds) +                &
713                                        (btra(ji,jj,jppds_lc) / 86400.)
714                  tra(ji,jj,jk,jpzmi) = tra(ji,jj,jk,jpzmi) +                &
715                                        (btra(ji,jj,jpzmi_lc) / 86400.)
716                  tra(ji,jj,jk,jpzme) = tra(ji,jj,jk,jpzme) +                &
717                                        (btra(ji,jj,jpzme_lc) / 86400.)
718                  tra(ji,jj,jk,jpdet) = tra(ji,jj,jk,jpdet) +                &
719                                        (btra(ji,jj,jpdet_lc) / 86400.)
720                  tra(ji,jj,jk,jpdin) = tra(ji,jj,jk,jpdin) +                &
721                                        (btra(ji,jj,jpdin_lc) / 86400.)
722                  tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) +                &
723                                        (btra(ji,jj,jpsil_lc) / 86400.)
724                  tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) +                &
725                                        (btra(ji,jj,jpfer_lc) / 86400.)
726# if defined key_roam
727                  tra(ji,jj,jk,jpdtc) = tra(ji,jj,jk,jpdtc) +                &
728                                        (btra(ji,jj,jpdtc_lc) / 86400.)
729                  tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) +                &
730                                        (btra(ji,jj,jpdic_lc) / 86400.)
731                  tra(ji,jj,jk,jpalk) = tra(ji,jj,jk,jpalk) +                &
732                                        (btra(ji,jj,jpalk_lc) / 86400.)
733                  tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) +                &
734                                        (btra(ji,jj,jpoxy_lc) / 86400.)
735# endif
736               endif
737            ENDIF
738         ENDDO
739      ENDDO
740
741      !! MEDUSA SMS trends:
742      IF( l_trdtrc ) THEN
743          CALL wrk_alloc( jpi, jpj, jpk, ztrmed )
744          DO jn = jp_msa0, jp_msa1
745            ztrmed(:,:,:) = tra(:,:,:,jn)
746            CALL trd_trc( ztrmed, jn, jptra_sms, kt )   ! save trends
747          END DO
748          CALL wrk_dealloc( jpi, jpj, jpk, ztrmed )
749      END IF
750
751      DO jj = 2,jpjm1
752         DO ji = 2,jpim1
753            if (tmask(ji,jj,jk) == 1) then
754
755               !! AXY (18/11/16): CMIP6 diagnostics
756               IF( med_diag%FBDDTALK%dgsave )  THEN
757                  fbddtalk(ji,jj)  =  fbddtalk(ji,jj)  +                     &
758                                      (btra(ji,jj,jpalk_lc) * fse3t(ji,jj,jk))
759               ENDIF
760               IF( med_diag%FBDDTDIC%dgsave )  THEN
761                  fbddtdic(ji,jj)  =  fbddtdic(ji,jj)  +                     &
762                                      (btra(ji,jj,jpdic_lc) * fse3t(ji,jj,jk))
763               ENDIF
764               IF( med_diag%FBDDTDIFE%dgsave ) THEN
765                  fbddtdife(ji,jj) =  fbddtdife(ji,jj) +                     &
766                                      (btra(ji,jj,jpfer_lc) * fse3t(ji,jj,jk))
767               ENDIF
768               IF( med_diag%FBDDTDIN%dgsave )  THEN
769                  fbddtdin(ji,jj)  =  fbddtdin(ji,jj)  +                     &
770                                      (btra(ji,jj,jpdin_lc) * fse3t(ji,jj,jk))
771               ENDIF
772               IF( med_diag%FBDDTDISI%dgsave ) THEN
773                  fbddtdisi(ji,jj) =  fbddtdisi(ji,jj) +                     &
774                                      (btra(ji,jj,jpsil_lc) * fse3t(ji,jj,jk))
775               ENDIF
776          !!
777               IF( med_diag%BDDTALK3%dgsave )  THEN
778                  bddtalk3(ji,jj,jk)  =  btra(ji,jj,jpalk_lc)
779               ENDIF
780               IF( med_diag%BDDTDIC3%dgsave )  THEN
781                  bddtdic3(ji,jj,jk)  =  btra(ji,jj,jpdic_lc)
782               ENDIF
783               IF( med_diag%BDDTDIFE3%dgsave ) THEN
784                  bddtdife3(ji,jj,jk) =  btra(ji,jj,jpfer_lc)
785               ENDIF
786               IF( med_diag%BDDTDIN3%dgsave )  THEN
787                  bddtdin3(ji,jj,jk)  =  btra(ji,jj,jpdin_lc)
788               ENDIF
789               IF( med_diag%BDDTDISI3%dgsave ) THEN
790                  bddtdisi3(ji,jj,jk) =  btra(ji,jj,jpsil_lc)
791               ENDIF
792            ENDIF
793         ENDDO
794      ENDDO
795
796#   if defined key_debug_medusa
797      IF (lwp) write (numout,*) '------'
798      IF (lwp) write (numout,*) 'bio_medusa_update: end all calculations'
799      IF (lwp) write (numout,*) 'bio_medusa_update: now outputs kt = ', kt
800      CALL flush(numout)
801#   endif
802
803# if defined key_axy_nancheck
804      !!----------------------------------------------------------
805      !! Check calculated tracer fluxes
806      !!----------------------------------------------------------
807      DO jj = 2,jpjm1
808         DO ji = 2,jpim1
809            if (tmask(ji,jj,jk) == 1) then
810               !!
811               DO jn = 1,jp_medusa
812                  fq0 = btra(ji,jj,jn)
813                  !! AXY (30/01/14): "isnan" problem on HECTOR
814                  !! if (fq0 /= fq0 ) then
815                  if ( ieee_is_nan( fq0 ) ) then
816                     !! there's a NaN here
817                     if (lwp) write(numout,*) 'NAN detected in btra(ji,jj,',  &
818                        ji, ',', jj, ',', jk, ',', jn, ') at time', kt
819           CALL ctl_stop( 'trcbio_medusa, NAN in btra field' )
820                  endif
821               ENDDO
822               DO jn = jp_msa0,jp_msa1
823                  fq0 = tra(ji,jj,jk,jn)
824                  !! AXY (30/01/14): "isnan" problem on HECTOR
825                  !! if (fq0 /= fq0 ) then
826                  if ( ieee_is_nan( fq0 ) ) then
827                     !! there's a NaN here
828                     if (lwp) write(numout,*) 'NAN detected in tra(', ji, &
829                        ',', jj, ',', jk, ',', jn, ') at time', kt
830              CALL ctl_stop( 'trcbio_medusa, NAN in tra field' )
831                  endif
832               ENDDO
833               CALL flush(numout)
834            ENDIF
835         ENDDO
836      ENDDO
837# endif
838
839
840   END SUBROUTINE bio_medusa_update
841
842#else
843   !!======================================================================
844   !!  Dummy module :                                   No MEDUSA bio-model
845   !!======================================================================
846CONTAINS
847   SUBROUTINE bio_medusa_update( )                    ! Empty routine
848      WRITE(*,*) 'bio_medusa_update: You should not have seen this print! error?'
849   END SUBROUTINE bio_medusa_update
850#endif 
851
852   !!======================================================================
853END MODULE bio_medusa_update_mod
Note: See TracBrowser for help on using the repository browser.