source: branches/NERC/dev_r5518_GO6_under_ice_relax/NEMOGCM/NEMO/OPA_SRC/SBC/sbcssr.F90 @ 9488

Last change on this file since 9488 was 9488, checked in by jpalmier, 3 years ago

start with hard coded under-ice relax value

File size: 13.0 KB
Line 
1MODULE sbcssr
2   !!======================================================================
3   !!                       ***  MODULE  sbcssr  ***
4   !! Surface module :  heat and fresh water fluxes a restoring term toward observed SST/SSS
5   !!======================================================================
6   !! History :  3.0  !  2006-06  (G. Madec)  Original code
7   !!            3.2  !  2009-04  (B. Lemaire)  Introduce iom_put
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   sbc_ssr       : add to sbc a restoring term toward SST/SSS climatology
12   !!   sbc_ssr_init  : initialisation of surface restoring
13   !!----------------------------------------------------------------------
14   USE oce            ! ocean dynamics and tracers
15   USE dom_oce        ! ocean space and time domain
16   USE sbc_oce        ! surface boundary condition
17   USE phycst         ! physical constants
18   USE sbcrnf         ! surface boundary condition : runoffs
19   !
20   USE fldread        ! read input fields
21   USE iom            ! I/O manager
22   USE in_out_manager ! I/O manager
23   USE lib_mpp        ! distribued memory computing library
24   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
25   USE timing         ! Timing
26   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   sbc_ssr        ! routine called in sbcmod
32   PUBLIC   sbc_ssr_init   ! routine called in sbcmod
33
34   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   erp   !: evaporation damping   [kg/m2/s]
35   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   qrp   !: heat flux damping        [w/m2]
36
37   !                                   !!* Namelist namsbc_ssr *
38   INTEGER, PUBLIC ::   nn_sstr         ! SST/SSS restoring indicator
39   INTEGER, PUBLIC ::   nn_sssr         ! SST/SSS restoring indicator
40   REAL(wp)        ::   rn_dqdt         ! restoring factor on SST and SSS
41   REAL(wp)        ::   rn_deds         ! restoring factor on SST and SSS
42   LOGICAL         ::   ln_sssr_bnd     ! flag to bound erp term
43   REAL(wp)        ::   rn_sssr_bnd     ! ABS(Max./Min.) value of erp term [mm/day]
44
45   REAL(wp) , ALLOCATABLE, DIMENSION(:) ::   buffer   ! Temporary buffer for exchange
46   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_sst   ! structure of input SST (file informations, fields read)
47   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_sss   ! structure of input SSS (file informations, fields read)
48
49   !! * Substitutions
50#  include "domzgr_substitute.h90"
51   !!----------------------------------------------------------------------
52   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
53   !! $Id$
54   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
55   !!----------------------------------------------------------------------
56CONTAINS
57
58   SUBROUTINE sbc_ssr( kt )
59      !!---------------------------------------------------------------------
60      !!                     ***  ROUTINE sbc_ssr  ***
61      !!
62      !! ** Purpose :   Add to heat and/or freshwater fluxes a damping term
63      !!                toward observed SST and/or SSS.
64      !!
65      !! ** Method  : - Read namelist namsbc_ssr
66      !!              - Read observed SST and/or SSS
67      !!              - at each nscb time step
68      !!                   add a retroaction term on qns    (nn_sstr = 1)
69      !!                   add a damping term on sfx        (nn_sssr = 1)
70      !!                   add a damping term on emp        (nn_sssr = 2)
71      !!---------------------------------------------------------------------
72      INTEGER, INTENT(in   ) ::   kt   ! ocean time step
73      !!
74      INTEGER  ::   ji, jj   ! dummy loop indices
75      REAL(wp) ::   zerp     ! local scalar for evaporation damping
76      REAL(wp) ::   zqrp     ! local scalar for heat flux damping
77      REAL(wp) ::   zsrp     ! local scalar for unit conversion of rn_deds factor
78      REAL(wp) ::   zerp_bnd ! local scalar for unit conversion of rn_epr_max factor
79      !! AXY (16-04-2018) scaling under-sea-ice relaxation
80      REAL(wp) ::   zice     ! local scalar to permit differential under sea-ice relaxation
81      REAL(wp) ::   zsrp_ice     !  local scalar for unit conversion of rn_deds factor - under ice
82      REAL(wp), PARAMETER ::   rn_deds_ice = -333.333     ! under ice relaxation term
83      INTEGER  ::   ierror   ! return error code
84      !!
85      CHARACTER(len=100) ::  cn_dir          ! Root directory for location of ssr files
86      TYPE(FLD_N) ::   sn_sst, sn_sss        ! informations about the fields to be read
87      !!----------------------------------------------------------------------
88      !
89      IF( nn_timing == 1 )  CALL timing_start('sbc_ssr')
90      !
91      IF( nn_sstr + nn_sssr /= 0 ) THEN
92         !
93         IF( nn_sstr == 1)   CALL fld_read( kt, nn_fsbc, sf_sst )   ! Read SST data and provides it at kt
94         IF( nn_sssr >= 1)   CALL fld_read( kt, nn_fsbc, sf_sss )   ! Read SSS data and provides it at kt
95         !
96         !                                         ! ========================= !
97         IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN      !    Add restoring term     !
98            !                                      ! ========================= !
99            !
100            IF( nn_sstr == 1 ) THEN                                   !* Temperature restoring term
101               DO jj = 1, jpj
102                  DO ji = 1, jpi
103                     zqrp = rn_dqdt * ( sst_m(ji,jj) - sf_sst(1)%fnow(ji,jj,1) )
104                     qns(ji,jj) = qns(ji,jj) + zqrp
105                     qrp(ji,jj) = zqrp
106                  END DO
107               END DO
108               CALL iom_put( "qrp", qrp )                             ! heat flux damping
109            ENDIF
110            !
111            IF( nn_sssr == 1 ) THEN                                   !* Salinity damping term (salt flux only (sfx))
112               zsrp = rn_deds / rday                                  ! from [mm/day] to [kg/m2/s]
113               zsrp_ice = rn_deds_ice / rday                                  ! from [mm/day] to [kg/m2/s]
114!CDIR COLLAPSE
115               DO jj = 1, jpj
116                  DO ji = 1, jpi
117                     !! AXY (16-04-2018) Calculate ice-scaled zsrp term - from
118                     !!      rn_deds (ice-free) to rn_deds_ice (100% ice)
119                     zice = ((1. - fr_i(ji,jj)) * zsrp) +        &
120                        &   (fr_i(ji,jj) * zsrp_ice) 
121                     zerp = zice * ( 1. - 2.*rnfmsk(ji,jj) )   &      ! No damping in vicinity of river mouths
122                        &        * ( sss_m(ji,jj) - sf_sss(1)%fnow(ji,jj,1) ) 
123                     sfx(ji,jj) = sfx(ji,jj) + zerp                 ! salt flux
124                     erp(ji,jj) = zerp / MAX( sss_m(ji,jj), 1.e-20 ) ! converted into an equivalent volume flux (diagnostic only)
125                  END DO
126               END DO
127               CALL iom_put( "erp", erp )                             ! freshwater flux damping
128               !
129            ELSEIF( nn_sssr == 2 ) THEN                               !* Salinity damping term (volume flux (emp) and associated heat flux (qns)
130               zsrp = rn_deds / rday                                  ! from [mm/day] to [kg/m2/s]
131               zerp_bnd = rn_sssr_bnd / rday                          !       -              -   
132!CDIR COLLAPSE
133               DO jj = 1, jpj
134                  DO ji = 1, jpi                           
135                     zerp = zsrp * ( 1. - 2.*rnfmsk(ji,jj) )   &      ! No damping in vicinity of river mouths
136                        &        * ( sss_m(ji,jj) - sf_sss(1)%fnow(ji,jj,1) )   &
137                        &        / MAX(  sss_m(ji,jj), 1.e-20   )
138                     IF( ln_sssr_bnd )   zerp = SIGN( 1., zerp ) * MIN( zerp_bnd, ABS(zerp) )
139                     emp(ji,jj) = emp (ji,jj) + zerp
140                     qns(ji,jj) = qns(ji,jj) - zerp * rcp * sst_m(ji,jj)
141                     erp(ji,jj) = zerp
142                  END DO
143               END DO
144               CALL iom_put( "erp", erp )                             ! freshwater flux damping
145            ENDIF
146            !
147         ENDIF
148         !
149      ENDIF
150      !
151      IF( nn_timing == 1 )  CALL timing_stop('sbc_ssr')
152      !
153   END SUBROUTINE sbc_ssr
154
155 
156   SUBROUTINE sbc_ssr_init
157      !!---------------------------------------------------------------------
158      !!                  ***  ROUTINE sbc_ssr_init  ***
159      !!
160      !! ** Purpose :   initialisation of surface damping term
161      !!
162      !! ** Method  : - Read namelist namsbc_ssr
163      !!              - Read observed SST and/or SSS if required
164      !!---------------------------------------------------------------------
165      INTEGER  ::   ji, jj   ! dummy loop indices
166      REAL(wp) ::   zerp     ! local scalar for evaporation damping
167      REAL(wp) ::   zqrp     ! local scalar for heat flux damping
168      REAL(wp) ::   zsrp     ! local scalar for unit conversion of rn_deds factor
169      REAL(wp) ::   zerp_bnd ! local scalar for unit conversion of rn_epr_max factor
170      INTEGER  ::   ierror   ! return error code
171      !!
172      CHARACTER(len=100) ::  cn_dir          ! Root directory for location of ssr files
173      TYPE(FLD_N) ::   sn_sst, sn_sss        ! informations about the fields to be read
174      NAMELIST/namsbc_ssr/ cn_dir, nn_sstr, nn_sssr, rn_dqdt, rn_deds, sn_sst, sn_sss, ln_sssr_bnd, rn_sssr_bnd
175      INTEGER     ::  ios
176      !!----------------------------------------------------------------------
177      !
178 
179      REWIND( numnam_ref )              ! Namelist namsbc_ssr in reference namelist :
180      READ  ( numnam_ref, namsbc_ssr, IOSTAT = ios, ERR = 901)
181901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_ssr in reference namelist', lwp )
182
183      REWIND( numnam_cfg )              ! Namelist namsbc_ssr in configuration namelist :
184      READ  ( numnam_cfg, namsbc_ssr, IOSTAT = ios, ERR = 902 )
185902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_ssr in configuration namelist', lwp )
186      IF(lwm) WRITE ( numond, namsbc_ssr )
187
188      IF(lwp) THEN                 !* control print
189         WRITE(numout,*)
190         WRITE(numout,*) 'sbc_ssr : SST and/or SSS damping term '
191         WRITE(numout,*) '~~~~~~~ '
192         WRITE(numout,*) '   Namelist namsbc_ssr :'
193         WRITE(numout,*) '      SST restoring term (Yes=1)             nn_sstr     = ', nn_sstr
194         WRITE(numout,*) '      SSS damping term (Yes=1, salt flux)    nn_sssr     = ', nn_sssr
195         WRITE(numout,*) '                       (Yes=2, volume flux) '
196         WRITE(numout,*) '      dQ/dT (restoring magnitude on SST)     rn_dqdt     = ', rn_dqdt, ' W/m2/K'
197         WRITE(numout,*) '      dE/dS (restoring magnitude on SST)     rn_deds     = ', rn_deds, ' mm/day'
198         WRITE(numout,*) '      flag to bound erp term                 ln_sssr_bnd = ', ln_sssr_bnd
199         WRITE(numout,*) '      ABS(Max./Min.) erp threshold           rn_sssr_bnd = ', rn_sssr_bnd, ' mm/day'
200      ENDIF
201      !
202      !                            !* Allocate erp and qrp array
203      ALLOCATE( qrp(jpi,jpj), erp(jpi,jpj), STAT=ierror )
204      IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate erp and qrp array' )
205      !
206      IF( nn_sstr == 1 ) THEN      !* set sf_sst structure & allocate arrays
207         !
208         ALLOCATE( sf_sst(1), STAT=ierror )
209         IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate sf_sst structure' )
210         ALLOCATE( sf_sst(1)%fnow(jpi,jpj,1), STAT=ierror )
211         IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate sf_sst now array' )
212         !
213         ! fill sf_sst with sn_sst and control print
214         CALL fld_fill( sf_sst, (/ sn_sst /), cn_dir, 'sbc_ssr', 'SST restoring term toward SST data', 'namsbc_ssr' )
215         IF( sf_sst(1)%ln_tint )   ALLOCATE( sf_sst(1)%fdta(jpi,jpj,1,2), STAT=ierror )
216         IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate sf_sst data array' )
217         !
218      ENDIF
219      !
220      IF( nn_sssr >= 1 ) THEN      !* set sf_sss structure & allocate arrays
221         !
222         ALLOCATE( sf_sss(1), STAT=ierror )
223         IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate sf_sss structure' )
224         ALLOCATE( sf_sss(1)%fnow(jpi,jpj,1), STAT=ierror )
225         IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate sf_sss now array' )
226         !
227         ! fill sf_sss with sn_sss and control print
228         CALL fld_fill( sf_sss, (/ sn_sss /), cn_dir, 'sbc_ssr', 'SSS restoring term toward SSS data', 'namsbc_ssr' )
229         IF( sf_sss(1)%ln_tint )   ALLOCATE( sf_sss(1)%fdta(jpi,jpj,1,2), STAT=ierror )
230         IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate sf_sss data array' )
231         !
232      ENDIF
233      !
234      !                            !* Initialize qrp and erp if no restoring
235      IF( nn_sstr /= 1                   )   qrp(:,:) = 0._wp
236      IF( nn_sssr /= 1 .OR. nn_sssr /= 2 )   erp(:,:) = 0._wp
237      !
238   END SUBROUTINE sbc_ssr_init
239     
240   !!======================================================================
241END MODULE sbcssr
Note: See TracBrowser for help on using the repository browser.