New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
iscplhsb.F90 in branches/NERC/dev_r5589_is_oce_cpl/NEMOGCM/NEMO/OPA_SRC/DOM – NEMO

source: branches/NERC/dev_r5589_is_oce_cpl/NEMOGCM/NEMO/OPA_SRC/DOM/iscplhsb.F90 @ 5835

Last change on this file since 5835 was 5835, checked in by mathiot, 8 years ago

ice sheet coupling branche: cosmetic changes
File size: 15.5 KB
Line 
1MODULE iscplhsb
2   !!======================================================================
3   !!                       ***  MODULE  iscplhsb***
4   !! Ocean forcing: ice sheet/ocean coupling (conservation)
5   !!=====================================================================
6   !! History :  NEMO  ! 2015-01 P. Mathiot: original
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!   iscpl_alloc    : variable allocation
11   !!   iscpl_hsb      : compute and store the input of heat/salt/volume
12   !!                    into the system due to the coupling process
13   !!   iscpl_div      : correction of divergence to keep volume conservation
14   !!----------------------------------------------------------------------
15   USE dom_oce         ! ocean space and time domain
16   USE domwri          ! ocean space and time domain
17   USE phycst          ! physical constants
18   USE sbc_oce         ! surface boundary condition variables
19   USE oce             ! global tra/dyn variable
20   USE in_out_manager  ! I/O manager
21   USE lib_mpp         ! MPP library
22   USE lib_fortran     ! MPP library
23   USE wrk_nemo        ! Memory allocation
24   USE lbclnk          !
25   USE domngb          !
26   USE iscplini
27
28   IMPLICIT NONE
29   PRIVATE
30   
31   PUBLIC   iscpl_div   
32   PUBLIC   iscpl_cons       
33   !! * Substitutions 
34#  include "domzgr_substitute.h90" 
35   !!----------------------------------------------------------------------
36   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
37   !! $Id: sbcrnf.F90 4666 2014-06-11 12:52:23Z mathiot $
38   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
39   !!----------------------------------------------------------------------
40CONTAINS
41
42   SUBROUTINE iscpl_cons(ptmask_b, psmask_b, pe3t_b, pts_flx, pvol_flx, prdt_iscpl)
43      !!----------------------------------------------------------------------
44      !!                   ***  ROUTINE iscpl_cons  ***
45      !!
46      !! ** Purpose :   compute input into the system during the coupling step
47      !!                compute the correction term
48      !!                compute where the correction have to be applied
49      !!
50      !! ** Method  :   compute tsn*e3t-tsb*e3tb and e3t-e3t_b
51      !!----------------------------------------------------------------------
52      REAL(wp), DIMENSION(:,:,:  ), INTENT(in ) :: ptmask_b    !! mask before
53      REAL(wp), DIMENSION(:,:,:  ), INTENT(in ) :: pe3t_b      !! scale factor before
54      REAL(wp), DIMENSION(:,:    ), INTENT(in ) :: psmask_b    !! mask before
55      REAL(wp), DIMENSION(:,:,:,:), INTENT(out) :: pts_flx     !! corrective flux to have tracer conservation
56      REAL(wp), DIMENSION(:,:,:  ), INTENT(out) :: pvol_flx    !! corrective flux to have volume conservation
57      REAL(wp),                     INTENT(in ) :: prdt_iscpl  !! coupling period
58      !!
59      INTEGER :: ji, jj, jk      !! loop index
60      INTEGER :: jip1, jim1, jjp1, jjm1
61      !!
62      REAL(wp):: summsk, zsum, zsum1, zarea, zsumn, zsumb
63      REAL(wp):: r1_tiscpl
64      REAL(wp):: zjip1_ratio  , zjim1_ratio  , zjjp1_ratio  , zjjm1_ratio
65      !!
66      REAL(wp), DIMENSION(:,:    ), POINTER :: zde3t, zdtem, zdsal
67      REAL(wp), DIMENSION(:,:    ), POINTER :: zssh0 
68      REAL(wp), DIMENSION(:,:,:  ), POINTER :: ztmp3d
69      !
70      REAL(wp), DIMENSION(:    ), ALLOCATABLE :: zlon, zlat
71      REAL(wp), DIMENSION(:    ), ALLOCATABLE :: zcorr_vol, zcorr_tem, zcorr_sal
72      INTEGER , DIMENSION(:    ), ALLOCATABLE :: ixpts, iypts, izpts, vnpts
73      INTEGER :: jpts, npts
74
75      CALL wrk_alloc(jpi,jpj,jpk,   ztmp3d )
76      CALL wrk_alloc(jpi,jpj,       zde3t , zdtem, zdsal )
77      CALL wrk_alloc(jpi,jpj,       zssh0  )
78
79    ! get unbalance (volume heat and salt)
80    ! initialisation
81      zde3t   (:,:)     = 0.0_wp
82      pvol_flx(:,:,:  ) = 0.0_wp
83      pts_flx (:,:,:,:) = 0.0_wp
84      r1_tiscpl = 1._wp / (prdt_iscpl * rn_rdt) 
85
86      ! mask tsn and tsb
87      tsb(:,:,:,jp_tem)=tsb(:,:,:,jp_tem)*ptmask_b(:,:,:); tsn(:,:,:,jp_tem)=tsn(:,:,:,jp_tem)*tmask(:,:,:);
88      tsb(:,:,:,jp_sal)=tsb(:,:,:,jp_sal)*ptmask_b(:,:,:); tsn(:,:,:,jp_sal)=tsn(:,:,:,jp_sal)*tmask(:,:,:);
89
90      !==============================================================================
91      ! diagnose the heat, salt and volume input and compute the correction variable
92      !==============================================================================
93
94      !
95      zssh0(:,:)        = sshn(:,:) * ssmask(:,:) - sshb(:,:) * psmask_b(:,:)
96      IF ( lk_vvl ) zssh0 = 0.0_wp ! already include in the levels by definition
97     
98      DO jk = 1,jpk-1
99         DO ji = 2,jpi-1
100            DO jj = 2,jpj-1
101               IF (tmask_h(ji,jj) == 1._wp) THEN
102
103                  ! volume differences
104                  zde3t(ji,jj) = fse3t_n(ji,jj,jk) * tmask(ji,jj,jk) - pe3t_b(ji,jj,jk) * ptmask_b(ji,jj,jk)
105
106                  ! heat diff
107                  zdtem(ji,jj) = tsn(ji,jj,jk,jp_tem) * fse3t_n(ji,jj,jk) *  tmask  (ji,jj,jk)   &
108                               - tsb(ji,jj,jk,jp_tem) * pe3t_b (ji,jj,jk) * ptmask_b(ji,jj,jk)
109                  ! salt diff
110                  zdsal(ji,jj) = tsn(ji,jj,jk,jp_sal) * fse3t_n(ji,jj,jk) *  tmask  (ji,jj,jk)   &
111                               - tsb(ji,jj,jk,jp_sal) * pe3t_b (ji,jj,jk) * ptmask_b(ji,jj,jk)
112               
113                  ! shh changes
114                  IF ( ptmask_b(ji,jj,jk) == 1._wp .OR. tmask(ji,jj,jk) == 1._wp ) THEN
115                     zde3t(ji,jj) = zde3t(ji,jj) + zssh0(ji,jj) ! zssh0 = 0 if vvl
116                     zssh0(ji,jj) = 0._wp
117                  END IF
118
119                  ! volume, heat and salt differences in each cell
120                  pvol_flx(ji,jj,jk)       =   pvol_flx(ji,jj,jk)        + zde3t(ji,jj) * r1_tiscpl
121                  pts_flx (ji,jj,jk,jp_sal)=   pts_flx (ji,jj,jk,jp_sal) + zdsal(ji,jj) * r1_tiscpl 
122                  pts_flx (ji,jj,jk,jp_tem)=   pts_flx (ji,jj,jk,jp_tem) + zdtem(ji,jj) * r1_tiscpl
123
124                  ! case where we close a cell: check if the neighbour cells are wet
125                  IF ( tmask(ji,jj,jk) == 0._wp .AND. ptmask_b(ji,jj,jk) == 1._wp ) THEN
126
127                     jip1=ji+1 ; jim1=ji-1 ; jjp1=jj+1 ; jjm1=jj-1 ;
128
129                     zsum =   e12t(ji  ,jjp1) * tmask(ji  ,jjp1,jk) + e12t(ji  ,jjm1) * tmask(ji  ,jjm1,jk) &
130                       &    + e12t(jim1,jj  ) * tmask(jim1,jj  ,jk) + e12t(jip1,jj  ) * tmask(jip1,jj  ,jk)
131
132                     IF ( zsum .NE. 0._wp ) THEN
133                        zjip1_ratio   = e12t(jip1,jj  ) * tmask(jip1,jj  ,jk) / zsum
134                        zjim1_ratio   = e12t(jim1,jj  ) * tmask(jim1,jj  ,jk) / zsum
135                        zjjp1_ratio   = e12t(ji  ,jjp1) * tmask(ji  ,jjp1,jk) / zsum
136                        zjjm1_ratio   = e12t(ji  ,jjm1) * tmask(ji  ,jjm1,jk) / zsum
137
138                        pvol_flx(ji  ,jjp1,jk       ) = pvol_flx(ji  ,jjp1,jk       ) + pvol_flx(ji,jj,jk       ) * zjjp1_ratio
139                        pvol_flx(ji  ,jjm1,jk       ) = pvol_flx(ji  ,jjm1,jk       ) + pvol_flx(ji,jj,jk       ) * zjjm1_ratio
140                        pvol_flx(jip1,jj  ,jk       ) = pvol_flx(jip1,jj  ,jk       ) + pvol_flx(ji,jj,jk       ) * zjip1_ratio
141                        pvol_flx(jim1,jj  ,jk       ) = pvol_flx(jim1,jj  ,jk       ) + pvol_flx(ji,jj,jk       ) * zjim1_ratio
142                        pts_flx (ji  ,jjp1,jk,jp_sal) = pts_flx (ji  ,jjp1,jk,jp_sal) + pts_flx (ji,jj,jk,jp_sal) * zjjp1_ratio
143                        pts_flx (ji  ,jjm1,jk,jp_sal) = pts_flx (ji  ,jjm1,jk,jp_sal) + pts_flx (ji,jj,jk,jp_sal) * zjjm1_ratio
144                        pts_flx (jip1,jj  ,jk,jp_sal) = pts_flx (jip1,jj  ,jk,jp_sal) + pts_flx (ji,jj,jk,jp_sal) * zjip1_ratio
145                        pts_flx (jim1,jj  ,jk,jp_sal) = pts_flx (jim1,jj  ,jk,jp_sal) + pts_flx (ji,jj,jk,jp_sal) * zjim1_ratio
146                        pts_flx (ji  ,jjp1,jk,jp_tem) = pts_flx (ji  ,jjp1,jk,jp_tem) + pts_flx (ji,jj,jk,jp_tem) * zjjp1_ratio
147                        pts_flx (ji  ,jjm1,jk,jp_tem) = pts_flx (ji  ,jjm1,jk,jp_tem) + pts_flx (ji,jj,jk,jp_tem) * zjjm1_ratio
148                        pts_flx (jip1,jj  ,jk,jp_tem) = pts_flx (jip1,jj  ,jk,jp_tem) + pts_flx (ji,jj,jk,jp_tem) * zjip1_ratio
149                        pts_flx (jim1,jj  ,jk,jp_tem) = pts_flx (jim1,jj  ,jk,jp_tem) + pts_flx (ji,jj,jk,jp_tem) * zjim1_ratio
150
151                        ! set to 0 the cell we distributed over neigbourg cells
152                        pvol_flx(ji,jj,jk       ) = 0._wp
153                        pts_flx (ji,jj,jk,jp_sal) = 0._wp
154                        pts_flx (ji,jj,jk,jp_tem) = 0._wp
155
156                     ELSE IF (zsum .EQ. 0._wp ) THEN
157                        ! case where we close a cell and no adjacent cell open
158                        ! check if the cell beneath is wet
159                        IF ( tmask(ji,jj,jk+1) .EQ. 1._wp ) THEN
160                           pvol_flx(ji,jj,jk+1)       =  pvol_flx(ji,jj,jk+1)        + pvol_flx(ji,jj,jk)
161                           pts_flx (ji,jj,jk+1,jp_sal)=  pts_flx (ji,jj,jk+1,jp_sal) + pts_flx (ji,jj,jk,jp_sal)
162                           pts_flx (ji,jj,jk+1,jp_tem)=  pts_flx (ji,jj,jk+1,jp_tem) + pts_flx (ji,jj,jk,jp_tem)
163
164                           ! set to 0 the cell we distributed over neigbourg cells
165                           pvol_flx(ji,jj,jk       ) = 0._wp
166                           pts_flx (ji,jj,jk,jp_sal) = 0._wp
167                           pts_flx (ji,jj,jk,jp_tem) = 0._wp
168                        ELSE
169                        ! case no adjacent cell on the horizontal and on the vertical
170                           WRITE(numout,*) 'W A R N I N G iscpl: no adjacent cell on the vertical and horizontal'
171                           WRITE(numout,*) '                     ',mig(ji),' ',mjg(jj),' ',jk
172                           WRITE(numout,*) '                     ',ji,' ',jj,' ',jk,' ',narea
173                           WRITE(numout,*) ' we are now looking for the closest wet cell on the horizontal '
174                        ! We deal with these points later.
175                        END IF
176                     END IF
177                  END IF
178               END IF
179            END DO
180         END DO
181      END DO
182
183      CALL lbc_sum(pvol_flx(:,:,:       ),'T',1.)
184      CALL lbc_sum(pts_flx (:,:,:,jp_sal),'T',1.)
185      CALL lbc_sum(pts_flx (:,:,:,jp_tem),'T',1.)
186
187      ! if no neighbour wet cell in case of 2close a cell", need to find the nearest wet point
188      ! allocation and initialisation of the list of problematic point
189      ALLOCATE(vnpts(jpnij))
190      vnpts(:)=0
191
192      ! fill narea location with the number of problematic point
193      DO jk = 1,jpk-1
194         DO ji = 2,jpi-1
195            DO jj = 2,jpj-1
196               IF (     ptmask_b(ji,jj,jk) == 1._wp .AND. tmask(ji,jj,jk+1)  == 0._wp .AND. tmask_h(ji,jj) == 1._wp  &
197                  .AND. SUM(tmask(ji-1:ji+1,jj,jk)) + SUM(tmask(ji,jj-1:jj+1,jk)) == 0._wp) THEN
198                  vnpts(narea) = vnpts(narea) + 1 
199               END IF
200            END DO
201         END DO
202      END DO
203
204      ! build array of total problematic point on each cpu (share to each cpu)
205      CALL mpp_max(vnpts,jpnij) 
206
207      ! size of the new variable
208      npts  = SUM(vnpts)   
209     
210      ! allocation of the coordinates, correction, index vector for the problematic points
211      ALLOCATE(ixpts(npts), iypts(npts), izpts(npts), zcorr_vol(npts), zcorr_sal(npts), zcorr_tem(npts), zlon(npts), zlat(npts))
212      ixpts(:) = -9999 ; iypts(:) = -9999 ; izpts(:) = -9999 ; zlon(:) = -1.0e20 ; zlat(:) = -1.0e20
213      zcorr_vol(:) = -1.0e20
214      zcorr_sal(:) = -1.0e20
215      zcorr_tem(:) = -1.0e20
216
217      ! fill new variable
218      jpts = SUM(vnpts(1:narea-1))
219      DO jk = 1,jpk-1
220         DO ji = 2,jpi-1
221            DO jj = 2,jpj-1
222               IF (     ptmask_b(ji,jj,jk) == 1._wp .AND. tmask(ji,jj,jk+1)  == 0._wp .AND. tmask_h(ji,jj) == 1._wp  &
223                  .AND. SUM(tmask(ji-1:ji+1,jj,jk)) + SUM(tmask(ji,jj-1:jj+1,jk)) == 0._wp) THEN
224                  jpts = jpts + 1  ! positioning in the vnpts vector for the area narea
225                  ixpts(jpts) = ji           ; iypts(jpts) = jj ; izpts(jpts) = jk
226                  zlon (jpts) = glamt(ji,jj) ; zlat (jpts) = gphit(ji,jj)
227                  zcorr_vol(jpts) = pvol_flx(ji,jj,jk)
228                  zcorr_sal(jpts) = pts_flx (ji,jj,jk,jp_sal)
229                  zcorr_tem(jpts) = pts_flx (ji,jj,jk,jp_tem)
230
231                  ! set flx to 0 (safer)
232                  pvol_flx(ji,jj,jk       ) = 0.0_wp
233                  pts_flx (ji,jj,jk,jp_sal) = 0.0_wp
234                  pts_flx (ji,jj,jk,jp_tem) = 0.0_wp
235               END IF
236            END DO
237         END DO
238      END DO
239
240      ! build array of total problematic point on each cpu (share to each cpu)
241      ! point coordinates
242      CALL mpp_max(zlat ,npts)
243      CALL mpp_max(zlon ,npts)
244      CALL mpp_max(izpts,npts)
245
246      ! correction values
247      CALL mpp_max(zcorr_vol,npts)
248      CALL mpp_max(zcorr_sal,npts)
249      CALL mpp_max(zcorr_tem,npts)
250
251      ! put correction term in the closest cell         
252      DO jpts = 1,npts
253         CALL dom_ngb(zlon(jpts), zlat(jpts), ixpts(jpts), iypts(jpts),'T', izpts(jpts))
254         DO jj = mj0(iypts(jpts)),mj1(iypts(jpts))
255            DO ji = mi0(ixpts(jpts)),mi1(ixpts(jpts))
256               jk = izpts(jpts)
257
258               IF (tmask_h(ji,jj) == 1._wp) THEN
259                  ! correct the vol_flx in the closest cell
260                  pvol_flx(ji,jj,jk)        =  pvol_flx(ji,jj,jk       ) + zcorr_vol(jpts)
261                  pts_flx (ji,jj,jk,jp_sal) =  pts_flx (ji,jj,jk,jp_sal) + zcorr_sal(jpts)
262                  pts_flx (ji,jj,jk,jp_tem) =  pts_flx (ji,jj,jk,jp_tem) + zcorr_tem(jpts)
263
264                  ! set correction to 0
265                  zcorr_vol(jpts) = 0.0_wp
266                  zcorr_sal(jpts) = 0.0_wp
267                  zcorr_tem(jpts) = 0.0_wp
268               END IF
269            END DO
270         END DO
271      END DO
272
273      ! deallocate variables
274      DEALLOCATE(vnpts)
275      DEALLOCATE(ixpts, iypts, izpts, zcorr_vol, zcorr_sal, zcorr_tem, zlon, zlat)
276   
277      ! add contribution store on the hallo (lbclnk remove one of the contribution)
278      pvol_flx(:,:,:       ) = pvol_flx(:,:,:       ) * tmask(:,:,:)
279      pts_flx (:,:,:,jp_sal) = pts_flx (:,:,:,jp_sal) * tmask(:,:,:)
280      pts_flx (:,:,:,jp_tem) = pts_flx (:,:,:,jp_tem) * tmask(:,:,:)
281
282      ! compute sum over the halo and set it to 0.
283      CALL lbc_sum(pvol_flx(:,:,:       ),'T',1._wp)
284      CALL lbc_sum(pts_flx (:,:,:,jp_sal),'T',1._wp)
285      CALL lbc_sum(pts_flx (:,:,:,jp_tem),'T',1._wp)
286
287      ! deallocate variables
288      CALL wrk_dealloc(jpi,jpj,jpk,   ztmp3d ) 
289      CALL wrk_dealloc(jpi,jpj,       zde3t  ) 
290      CALL wrk_dealloc(jpi,jpj,       zssh0  ) 
291   END SUBROUTINE iscpl_cons
292
293   SUBROUTINE iscpl_div( phdivn )
294      !!----------------------------------------------------------------------
295      !!                  ***  ROUTINE iscpl_div  ***
296      !!
297      !! ** Purpose :   update the horizontal divergenc
298      !!
299      !! ** Method  :
300      !!                CAUTION : iscpl is positive (inflow) and expressed in m/s
301      !!
302      !! ** Action  :   phdivn   increase by the iscpl correction term
303      !!----------------------------------------------------------------------
304      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   phdivn   ! horizontal divergence
305      !!
306      INTEGER  ::   ji, jj, jk   ! dummy loop indices
307      !!----------------------------------------------------------------------
308      !
309      DO jk = 1, jpk
310         DO jj = 1, jpj
311            DO ji = 1, jpi
312               phdivn(ji,jj,jk) = phdivn(ji,jj,jk) + hdiv_iscpl(ji,jj,jk) / fse3t_n(ji,jj,jk)
313            END DO
314         END DO
315      END DO
316      !
317   END SUBROUTINE iscpl_div
318
319END MODULE iscplhsb
Note: See TracBrowser for help on using the repository browser.