source: branches/NERC/dev_r5589_marine_glacier_termini/NEMOGCM/NEMO/OPA_SRC/SBC/sbcfwb.F90 @ 5605

Last change on this file since 5605 was 5605, checked in by mathiot, 6 years ago

Marine glacier termini: initial commit

  • Property svn:keywords set to Id
File size: 12.0 KB
Line 
1MODULE sbcfwb
2   !!======================================================================
3   !!                       ***  MODULE  sbcfwb  ***
4   !! Ocean fluxes   : domain averaged freshwater budget
5   !!======================================================================
6   !! History :  OPA  ! 2001-02  (E. Durand)  Original code
7   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
8   !!            3.0  ! 2006-08  (G. Madec)  Surface module
9   !!            3.2  ! 2009-07  (C. Talandier) emp mean s spread over erp area
10   !!            3.6  ! 2014-11  (P. Mathiot  ) add ice shelf melting
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   sbc_fwb      : freshwater budget for global ocean configurations
15   !!                  in free surface and forced mode
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean dynamics and tracers
18   USE dom_oce         ! ocean space and time domain
19   USE sbc_oce         ! surface ocean boundary condition
20   USE phycst          ! physical constants
21   USE sbcrnf          ! ocean runoffs
22   USE sbcisf          ! ice shelf melting contribution
23   USE sbcssr          ! SS damping terms
24   USE in_out_manager  ! I/O manager
25   USE lib_mpp         ! distribued memory computing library
26   USE wrk_nemo        ! work arrays
27   USE timing          ! Timing
28   USE lbclnk          ! ocean lateral boundary conditions
29   USE lib_fortran
30   USE traicw
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   sbc_fwb    ! routine called by step
36
37   REAL(wp) ::   a_fwb_b   ! annual domain averaged freshwater budget
38   REAL(wp) ::   a_fwb     ! for 2 year before (_b) and before year.
39   REAL(wp) ::   fwfold    ! fwfold to be suppressed
40   REAL(wp) ::   area      ! global mean ocean surface (interior domain)
41
42   !! * Substitutions
43#  include "domzgr_substitute.h90"
44#  include "vectopt_loop_substitute.h90"
45   !!----------------------------------------------------------------------
46   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
47   !! $Id$
48   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
49   !!----------------------------------------------------------------------
50CONTAINS
51
52   SUBROUTINE sbc_fwb( kt, kn_fwb, kn_fsbc )
53      !!---------------------------------------------------------------------
54      !!                  ***  ROUTINE sbc_fwb  ***
55      !!
56      !! ** Purpose :   Control the mean sea surface drift
57      !!
58      !! ** Method  :   several ways  depending on kn_fwb
59      !!                =0 no control
60      !!                =1 global mean of emp set to zero at each nn_fsbc time step
61      !!                =2 annual global mean corrected from previous year
62      !!                =3 global mean of emp set to zero at each nn_fsbc time step
63      !!                   & spread out over erp area depending its sign
64      !! Note: if sea ice is embedded it is taken into account when computing the budget
65      !!----------------------------------------------------------------------
66      INTEGER, INTENT( in ) ::   kt       ! ocean time-step index
67      INTEGER, INTENT( in ) ::   kn_fsbc  !
68      INTEGER, INTENT( in ) ::   kn_fwb   ! ocean time-step index
69      !
70      INTEGER  ::   inum, ikty, iyear     ! local integers
71      REAL(wp) ::   z_fwf, z_fwf_nsrf, zsum_fwf, zsum_erp                ! local scalars
72      REAL(wp) ::   zsurf_neg, zsurf_pos, zsurf_tospread, zcoef          !   -      -
73      REAL(wp), POINTER, DIMENSION(:,:) ::   ztmsk_neg, ztmsk_pos, z_wgt ! 2D workspaces
74      REAL(wp), POINTER, DIMENSION(:,:) ::   ztmsk_tospread, zerp_cor    !   -      -
75      !!----------------------------------------------------------------------
76      !
77      IF( nn_timing == 1 )  CALL timing_start('sbc_fwb')
78      !
79      CALL wrk_alloc( jpi,jpj, ztmsk_neg, ztmsk_pos, ztmsk_tospread, z_wgt, zerp_cor )
80      !
81      IF( kt == nit000 ) THEN
82         IF(lwp) THEN
83            WRITE(numout,*)
84            WRITE(numout,*) 'sbc_fwb : FreshWater Budget correction'
85            WRITE(numout,*) '~~~~~~~'
86            IF( kn_fwb == 1 )   WRITE(numout,*) '          instantaneously set to zero'
87            IF( kn_fwb == 2 )   WRITE(numout,*) '          adjusted from previous year budget'
88            IF( kn_fwb == 3 )   WRITE(numout,*) '          fwf set to zero and spread out over erp area'
89         ENDIF
90         !
91         IF( kn_fwb == 3 .AND. nn_sssr /= 2 )   CALL ctl_stop( 'sbc_fwb: nn_fwb = 3 requires nn_sssr = 2, we stop ' )
92         IF( kn_fwb == 3 .AND. ln_isfcav    )   CALL ctl_stop( 'sbc_fwb: nn_fwb = 3 with ln_isfcav = .TRUE. not working, we stop ' )
93         !
94         area = glob_sum( e1e2t(:,:) * tmask(:,:,1))           ! interior global domain surface
95         ! isf cavities are excluded because it can feedback to the melting with generation of inhibition of plumes
96         ! and in case of no melt, it can generate HSSW.
97         !
98#if ! defined key_lim2 &&  ! defined key_lim3 && ! defined key_cice
99         snwice_mass_b(:,:) = 0.e0               ! no sea-ice model is being used : no snow+ice mass
100         snwice_mass  (:,:) = 0.e0
101#endif
102         !
103      ENDIF
104     
105
106      SELECT CASE ( kn_fwb )
107      !
108      CASE ( 1 )                             !==  global mean fwf set to zero  ==!
109         !
110         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
111            z_fwf = glob_sum( e1e2t(:,:) * ( emp(:,:) - rnf(:,:) + rdivisf * fwfisf(:,:) -qtot(:,:) - snwice_fmass(:,:) ) ) / area   ! sum over the global domain
112            zcoef = z_fwf * rcp
113            emp(:,:) = emp(:,:) - z_fwf              * tmask(:,:,1)
114            qns(:,:) = qns(:,:) + zcoef * sst_m(:,:) * tmask(:,:,1) ! account for change to the heat budget due to fw correction
115         ENDIF
116         !
117      CASE ( 2 )                             !==  fwf budget adjusted from the previous year  ==!
118         !
119         IF( kt == nit000 ) THEN                      ! initialisation
120            !                                         ! Read the corrective factor on precipitations (fwfold)
121            CALL ctl_opn( inum, 'EMPave_old.dat', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE. )
122            READ ( inum, "(24X,I8,2ES24.16)" ) iyear, a_fwb_b, a_fwb
123            CLOSE( inum )
124            fwfold = a_fwb                            ! current year freshwater budget correction
125            !                                         ! estimate from the previous year budget
126            IF(lwp)WRITE(numout,*)
127            IF(lwp)WRITE(numout,*)'sbc_fwb : year = ',iyear  , ' freshwater budget correction = ', fwfold
128            IF(lwp)WRITE(numout,*)'          year = ',iyear-1, ' freshwater budget read       = ', a_fwb
129            IF(lwp)WRITE(numout,*)'          year = ',iyear-2, ' freshwater budget read       = ', a_fwb_b
130         ENDIF   
131         !                                         ! Update fwfold if new year start
132         ikty = 365 * 86400 / rdttra(1)    !!bug  use of 365 days leap year or 360d year !!!!!!!
133         IF( MOD( kt, ikty ) == 0 ) THEN
134            a_fwb_b = a_fwb                           ! mean sea level taking into account the ice+snow
135                                                      ! sum over the global domain
136            a_fwb   = glob_sum( e1e2t(:,:) * ( sshn(:,:) + snwice_mass(:,:) * r1_rau0 ) )
137            a_fwb   = a_fwb * 1.e+3 / ( area * rday * 365. )     ! convert in Kg/m3/s = mm/s
138!!gm        !                                                      !!bug 365d year
139            fwfold =  a_fwb                           ! current year freshwater budget correction
140            !                                         ! estimate from the previous year budget
141         ENDIF
142         !
143         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN         ! correct the freshwater fluxes
144            zcoef = fwfold * rcp
145            emp(:,:) = emp(:,:) + fwfold             * tmask(:,:,1)
146            qns(:,:) = qns(:,:) - zcoef * sst_m(:,:) * tmask(:,:,1) ! account for change to the heat budget due to fw correction
147         ENDIF
148         !
149         IF( kt == nitend .AND. lwp ) THEN            ! save fwfold value in a file
150            CALL ctl_opn( inum, 'EMPave.dat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE., narea )
151            WRITE( inum, "(24X,I8,2ES24.16)" ) nyear, a_fwb_b, a_fwb
152            CLOSE( inum )
153         ENDIF
154         !
155      CASE ( 3 )                             !==  global fwf set to zero and spread out over erp area  ==!
156         !
157         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
158            ztmsk_pos(:,:) = tmask_i(:,:)                      ! Select <0 and >0 area of erp
159            WHERE( erp < 0._wp )   ztmsk_pos = 0._wp
160            ztmsk_neg(:,:) = tmask_i(:,:) - ztmsk_pos(:,:)
161            !
162            zsurf_neg = glob_sum( e1e2t(:,:)*ztmsk_neg(:,:) )  ! Area filled by <0 and >0 erp
163            zsurf_pos = glob_sum( e1e2t(:,:)*ztmsk_pos(:,:) )
164            !                                                  ! fwf global mean (excluding ocean to ice/snow exchanges)
165            z_fwf     = glob_sum( e1e2t(:,:) * ( emp(:,:) - rnf(:,:) + rdivisf * fwfisf(:,:) - snwice_fmass(:,:) ) ) / area
166            !           
167            IF( z_fwf < 0._wp ) THEN         ! spread out over >0 erp area to increase evaporation
168                zsurf_tospread      = zsurf_pos
169                ztmsk_tospread(:,:) = ztmsk_pos(:,:)
170            ELSE                             ! spread out over <0 erp area to increase precipitation
171                zsurf_tospread      = zsurf_neg
172                ztmsk_tospread(:,:) = ztmsk_neg(:,:)
173            ENDIF
174            !
175            zsum_fwf   = glob_sum( e1e2t(:,:) * z_fwf )         ! fwf global mean over <0 or >0 erp area
176!!gm :  zsum_fwf   = z_fwf * area   ???  it is right?  I think so....
177            z_fwf_nsrf =  zsum_fwf / ( zsurf_tospread + rsmall )
178            !                                                  ! weight to respect erp field 2D structure
179            zsum_erp   = glob_sum( ztmsk_tospread(:,:) * erp(:,:) * e1e2t(:,:) )
180            z_wgt(:,:) = ztmsk_tospread(:,:) * erp(:,:) / ( zsum_erp + rsmall )
181            !                                                  ! final correction term to apply
182            zerp_cor(:,:) = -1. * z_fwf_nsrf * zsurf_tospread * z_wgt(:,:)
183            !
184!!gm   ===>>>>  lbc_lnk should be useless as all the computation is done over the whole domain !
185            CALL lbc_lnk( zerp_cor, 'T', 1. )
186            !
187            emp(:,:) = emp(:,:) + zerp_cor(:,:)
188            qns(:,:) = qns(:,:) - zerp_cor(:,:) * rcp * sst_m(:,:)  ! account for change to the heat budget due to fw correction
189            erp(:,:) = erp(:,:) + zerp_cor(:,:)
190            !
191            IF( nprint == 1 .AND. lwp ) THEN                   ! control print
192               IF( z_fwf < 0._wp ) THEN
193                  WRITE(numout,*)'   z_fwf < 0'
194                  WRITE(numout,*)'   SUM(erp+)     = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv'
195               ELSE
196                  WRITE(numout,*)'   z_fwf >= 0'
197                  WRITE(numout,*)'   SUM(erp-)     = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv'
198               ENDIF
199               WRITE(numout,*)'   SUM(empG)     = ', SUM( z_fwf*e1e2t(:,:) )*1.e-9,' Sv'
200               WRITE(numout,*)'   z_fwf         = ', z_fwf      ,' Kg/m2/s'
201               WRITE(numout,*)'   z_fwf_nsrf    = ', z_fwf_nsrf ,' Kg/m2/s'
202               WRITE(numout,*)'   MIN(zerp_cor) = ', MINVAL(zerp_cor) 
203               WRITE(numout,*)'   MAX(zerp_cor) = ', MAXVAL(zerp_cor) 
204            ENDIF
205         ENDIF
206         !
207      CASE DEFAULT                           !==  you should never be there  ==!
208         CALL ctl_stop( 'sbc_fwb : wrong nn_fwb value for the FreshWater Budget correction, choose either 1, 2 or 3' )
209         !
210      END SELECT
211      !
212      CALL wrk_dealloc( jpi,jpj, ztmsk_neg, ztmsk_pos, ztmsk_tospread, z_wgt, zerp_cor )
213      !
214      IF( nn_timing == 1 )  CALL timing_stop('sbc_fwb')
215      !
216   END SUBROUTINE sbc_fwb
217
218   !!======================================================================
219END MODULE sbcfwb
Note: See TracBrowser for help on using the repository browser.