source: branches/NERC/dev_r5589_marine_glacier_termini/NEMOGCM/NEMO/OPA_SRC/TRA/eosbn2.F90 @ 5605

Last change on this file since 5605 was 5605, checked in by mathiot, 6 years ago

Marine glacier termini: initial commit

  • Property svn:keywords set to Id
File size: 77.3 KB
Line 
1MODULE eosbn2
2   !!==============================================================================
3   !!                       ***  MODULE  eosbn2  ***
4   !! Ocean diagnostic variable : equation of state - in situ and potential density
5   !!                                               - Brunt-Vaisala frequency
6   !!==============================================================================
7   !! History :  OPA  ! 1989-03  (O. Marti)  Original code
8   !!            6.0  ! 1994-07  (G. Madec, M. Imbard)  add bn2
9   !!            6.0  ! 1994-08  (G. Madec)  Add Jackett & McDougall eos
10   !!            7.0  ! 1996-01  (G. Madec)  statement function for e3
11   !!            8.1  ! 1997-07  (G. Madec)  density instead of volumic mass
12   !!             -   ! 1999-02  (G. Madec, N. Grima) semi-implicit pressure gradient
13   !!            8.2  ! 2001-09  (M. Ben Jelloul)  bugfix on linear eos
14   !!   NEMO     1.0  ! 2002-10  (G. Madec)  add eos_init
15   !!             -   ! 2002-11  (G. Madec, A. Bozec)  partial step, eos_insitu_2d
16   !!             -   ! 2003-08  (G. Madec)  F90, free form
17   !!            3.0  ! 2006-08  (G. Madec)  add tfreez function (now eos_fzp function)
18   !!            3.3  ! 2010-05  (C. Ethe, G. Madec)  merge TRC-TRA
19   !!             -   ! 2010-10  (G. Nurser, G. Madec)  add alpha/beta used in ldfslp
20   !!            3.7  ! 2012-03  (F. Roquet, G. Madec)  add primitive of alpha and beta used in PE computation
21   !!             -   ! 2012-05  (F. Roquet)  add Vallis and original JM95 equation of state
22   !!             -   ! 2013-04  (F. Roquet, G. Madec)  add eos_rab, change bn2 computation and reorganize the module
23   !!             -   ! 2014-09  (F. Roquet)  add TEOS-10, S-EOS, and modify EOS-80
24   !!             -   ! 2015-06  (P.A. Bouttier) eos_fzp functions changed to subroutines for AGRIF
25   !!----------------------------------------------------------------------
26
27   !!----------------------------------------------------------------------
28   !!   eos            : generic interface of the equation of state
29   !!   eos_insitu     : Compute the in situ density
30   !!   eos_insitu_pot : Compute the insitu and surface referenced potential volumic mass
31   !!   eos_insitu_2d  : Compute the in situ density for 2d fields
32   !!   bn2            : Compute the Brunt-Vaisala frequency
33   !!   eos_rab        : generic interface of in situ thermal/haline expansion ratio
34   !!   eos_rab_3d     : compute in situ thermal/haline expansion ratio
35   !!   eos_rab_2d     : compute in situ thermal/haline expansion ratio for 2d fields
36   !!   eos_fzp_2d     : freezing temperature for 2d fields
37   !!   eos_fzp_0d     : freezing temperature for scalar
38   !!   eos_init       : set eos parameters (namelist)
39   !!----------------------------------------------------------------------
40   USE dom_oce         ! ocean space and time domain
41   USE phycst          ! physical constants
42   !
43   USE in_out_manager  ! I/O manager
44   USE lib_mpp         ! MPP library
45   USE lib_fortran     ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
46   USE prtctl          ! Print control
47   USE wrk_nemo        ! Memory Allocation
48   USE lbclnk         ! ocean lateral boundary conditions
49   USE timing          ! Timing
50   USE stopar          ! Stochastic T/S fluctuations
51   USE stopts          ! Stochastic T/S fluctuations
52
53   IMPLICIT NONE
54   PRIVATE
55
56   !                   !! * Interface
57   INTERFACE eos
58      MODULE PROCEDURE eos_insitu, eos_insitu_pot, eos_insitu_2d, eos_insitu_0d
59   END INTERFACE
60   !
61   INTERFACE eos_rab
62      MODULE PROCEDURE rab_3d, rab_2d, rab_0d
63   END INTERFACE
64   !
65   INTERFACE eos_fzp 
66      MODULE PROCEDURE eos_fzp_2d, eos_fzp_0d
67   END INTERFACE
68   !
69   PUBLIC   eos            ! called by step, istate, tranpc and zpsgrd modules
70   PUBLIC   bn2            ! called by step module
71   PUBLIC   eos_rab        ! called by ldfslp, zdfddm, trabbl
72   PUBLIC   eos_pt_from_ct ! called by sbcssm
73   PUBLIC   eos_fzp        ! called by traadv_cen2 and sbcice_... modules
74   PUBLIC   eos_pen        ! used for pe diagnostics in trdpen module
75   PUBLIC   eos_init       ! called by istate module
76
77   !                                !!* Namelist (nameos) *
78   INTEGER , PUBLIC ::   nn_eos     ! = 0/1/2 type of eq. of state and Brunt-Vaisala frequ.
79   LOGICAL , PUBLIC ::   ln_useCT   ! determine if eos_pt_from_ct is used to compute sst_m
80
81   !                                   !!!  simplified eos coefficients
82   ! default value: Vallis 2006
83   REAL(wp) ::   rn_a0      = 1.6550e-1_wp     ! thermal expansion coeff.
84   REAL(wp) ::   rn_b0      = 7.6554e-1_wp     ! saline  expansion coeff.
85   REAL(wp) ::   rn_lambda1 = 5.9520e-2_wp     ! cabbeling coeff. in T^2       
86   REAL(wp) ::   rn_lambda2 = 5.4914e-4_wp     ! cabbeling coeff. in S^2       
87   REAL(wp) ::   rn_mu1     = 1.4970e-4_wp     ! thermobaric coeff. in T 
88   REAL(wp) ::   rn_mu2     = 1.1090e-5_wp     ! thermobaric coeff. in S 
89   REAL(wp) ::   rn_nu      = 2.4341e-3_wp     ! cabbeling coeff. in theta*salt 
90   
91   ! TEOS10/EOS80 parameters
92   REAL(wp) ::   r1_S0, r1_T0, r1_Z0, rdeltaS
93   
94   ! EOS parameters
95   REAL(wp) ::   EOS000 , EOS100 , EOS200 , EOS300 , EOS400 , EOS500 , EOS600
96   REAL(wp) ::   EOS010 , EOS110 , EOS210 , EOS310 , EOS410 , EOS510
97   REAL(wp) ::   EOS020 , EOS120 , EOS220 , EOS320 , EOS420
98   REAL(wp) ::   EOS030 , EOS130 , EOS230 , EOS330
99   REAL(wp) ::   EOS040 , EOS140 , EOS240
100   REAL(wp) ::   EOS050 , EOS150
101   REAL(wp) ::   EOS060
102   REAL(wp) ::   EOS001 , EOS101 , EOS201 , EOS301 , EOS401
103   REAL(wp) ::   EOS011 , EOS111 , EOS211 , EOS311
104   REAL(wp) ::   EOS021 , EOS121 , EOS221
105   REAL(wp) ::   EOS031 , EOS131
106   REAL(wp) ::   EOS041
107   REAL(wp) ::   EOS002 , EOS102 , EOS202
108   REAL(wp) ::   EOS012 , EOS112
109   REAL(wp) ::   EOS022
110   REAL(wp) ::   EOS003 , EOS103
111   REAL(wp) ::   EOS013 
112   
113   ! ALPHA parameters
114   REAL(wp) ::   ALP000 , ALP100 , ALP200 , ALP300 , ALP400 , ALP500
115   REAL(wp) ::   ALP010 , ALP110 , ALP210 , ALP310 , ALP410
116   REAL(wp) ::   ALP020 , ALP120 , ALP220 , ALP320
117   REAL(wp) ::   ALP030 , ALP130 , ALP230
118   REAL(wp) ::   ALP040 , ALP140
119   REAL(wp) ::   ALP050
120   REAL(wp) ::   ALP001 , ALP101 , ALP201 , ALP301
121   REAL(wp) ::   ALP011 , ALP111 , ALP211
122   REAL(wp) ::   ALP021 , ALP121
123   REAL(wp) ::   ALP031
124   REAL(wp) ::   ALP002 , ALP102
125   REAL(wp) ::   ALP012
126   REAL(wp) ::   ALP003
127   
128   ! BETA parameters
129   REAL(wp) ::   BET000 , BET100 , BET200 , BET300 , BET400 , BET500
130   REAL(wp) ::   BET010 , BET110 , BET210 , BET310 , BET410
131   REAL(wp) ::   BET020 , BET120 , BET220 , BET320
132   REAL(wp) ::   BET030 , BET130 , BET230
133   REAL(wp) ::   BET040 , BET140
134   REAL(wp) ::   BET050
135   REAL(wp) ::   BET001 , BET101 , BET201 , BET301
136   REAL(wp) ::   BET011 , BET111 , BET211
137   REAL(wp) ::   BET021 , BET121
138   REAL(wp) ::   BET031
139   REAL(wp) ::   BET002 , BET102
140   REAL(wp) ::   BET012
141   REAL(wp) ::   BET003
142
143   ! PEN parameters
144   REAL(wp) ::   PEN000 , PEN100 , PEN200 , PEN300 , PEN400
145   REAL(wp) ::   PEN010 , PEN110 , PEN210 , PEN310
146   REAL(wp) ::   PEN020 , PEN120 , PEN220
147   REAL(wp) ::   PEN030 , PEN130
148   REAL(wp) ::   PEN040
149   REAL(wp) ::   PEN001 , PEN101 , PEN201
150   REAL(wp) ::   PEN011 , PEN111
151   REAL(wp) ::   PEN021
152   REAL(wp) ::   PEN002 , PEN102
153   REAL(wp) ::   PEN012
154   
155   ! ALPHA_PEN parameters
156   REAL(wp) ::   APE000 , APE100 , APE200 , APE300
157   REAL(wp) ::   APE010 , APE110 , APE210
158   REAL(wp) ::   APE020 , APE120
159   REAL(wp) ::   APE030
160   REAL(wp) ::   APE001 , APE101
161   REAL(wp) ::   APE011
162   REAL(wp) ::   APE002
163
164   ! BETA_PEN parameters
165   REAL(wp) ::   BPE000 , BPE100 , BPE200 , BPE300
166   REAL(wp) ::   BPE010 , BPE110 , BPE210
167   REAL(wp) ::   BPE020 , BPE120
168   REAL(wp) ::   BPE030
169   REAL(wp) ::   BPE001 , BPE101
170   REAL(wp) ::   BPE011
171   REAL(wp) ::   BPE002
172
173   !! * Substitutions
174#  include "domzgr_substitute.h90"
175#  include "vectopt_loop_substitute.h90"
176   !!----------------------------------------------------------------------
177   !! NEMO/OPA 3.7 , NEMO Consortium (2014)
178   !! $Id$
179   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
180   !!----------------------------------------------------------------------
181CONTAINS
182
183   SUBROUTINE eos_insitu( pts, prd, pdep )
184      !!----------------------------------------------------------------------
185      !!                   ***  ROUTINE eos_insitu  ***
186      !!
187      !! ** Purpose :   Compute the in situ density (ratio rho/rau0) from
188      !!       potential temperature and salinity using an equation of state
189      !!       defined through the namelist parameter nn_eos.
190      !!
191      !! ** Method  :   prd(t,s,z) = ( rho(t,s,z) - rau0 ) / rau0
192      !!         with   prd    in situ density anomaly      no units
193      !!                t      TEOS10: CT or EOS80: PT      Celsius
194      !!                s      TEOS10: SA or EOS80: SP      TEOS10: g/kg or EOS80: psu
195      !!                z      depth                        meters
196      !!                rho    in situ density              kg/m^3
197      !!                rau0   reference density            kg/m^3
198      !!
199      !!     nn_eos = -1 : polynomial TEOS-10 equation of state is used for rho(t,s,z).
200      !!         Check value: rho = 1028.21993233072 kg/m^3 for z=3000 dbar, ct=3 Celcius, sa=35.5 g/kg
201      !!
202      !!     nn_eos =  0 : polynomial EOS-80 equation of state is used for rho(t,s,z).
203      !!         Check value: rho = 1028.35011066567 kg/m^3 for z=3000 dbar, pt=3 Celcius, sp=35.5 psu
204      !!
205      !!     nn_eos =  1 : simplified equation of state
206      !!              prd(t,s,z) = ( -a0*(1+lambda/2*(T-T0)+mu*z+nu*(S-S0))*(T-T0) + b0*(S-S0) ) / rau0
207      !!              linear case function of T only: rn_alpha<>0, other coefficients = 0
208      !!              linear eos function of T and S: rn_alpha and rn_beta<>0, other coefficients=0
209      !!              Vallis like equation: use default values of coefficients
210      !!
211      !! ** Action  :   compute prd , the in situ density (no units)
212      !!
213      !! References :   Roquet et al, Ocean Modelling, in preparation (2014)
214      !!                Vallis, Atmospheric and Oceanic Fluid Dynamics, 2006
215      !!                TEOS-10 Manual, 2010
216      !!----------------------------------------------------------------------
217      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts), INTENT(in   ) ::   pts   ! 1 : potential temperature  [Celcius]
218      !                                                               ! 2 : salinity               [psu]
219      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(  out) ::   prd   ! in situ density            [-]
220      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pdep  ! depth                      [m]
221      !
222      INTEGER  ::   ji, jj, jk                ! dummy loop indices
223      REAL(wp) ::   zt , zh , zs , ztm        ! local scalars
224      REAL(wp) ::   zn , zn0, zn1, zn2, zn3   !   -      -
225      !!----------------------------------------------------------------------
226      !
227      IF( nn_timing == 1 )   CALL timing_start('eos-insitu')
228      !
229      SELECT CASE( nn_eos )
230      !
231      CASE( -1, 0 )                !==  polynomial TEOS-10 / EOS-80 ==!
232         !
233         DO jk = 1, jpkm1
234            DO jj = 1, jpj
235               DO ji = 1, jpi
236                  !
237                  zh  = pdep(ji,jj,jk) * r1_Z0                                  ! depth
238                  zt  = pts (ji,jj,jk,jp_tem) * r1_T0                           ! temperature
239                  zs  = SQRT( ABS( pts(ji,jj,jk,jp_sal) + rdeltaS ) * r1_S0 )   ! square root salinity
240                  ztm = tmask(ji,jj,jk)                                         ! tmask
241                  !
242                  zn3 = EOS013*zt   &
243                     &   + EOS103*zs+EOS003
244                     !
245                  zn2 = (EOS022*zt   &
246                     &   + EOS112*zs+EOS012)*zt   &
247                     &   + (EOS202*zs+EOS102)*zs+EOS002
248                     !
249                  zn1 = (((EOS041*zt   &
250                     &   + EOS131*zs+EOS031)*zt   &
251                     &   + (EOS221*zs+EOS121)*zs+EOS021)*zt   &
252                     &   + ((EOS311*zs+EOS211)*zs+EOS111)*zs+EOS011)*zt   &
253                     &   + (((EOS401*zs+EOS301)*zs+EOS201)*zs+EOS101)*zs+EOS001
254                     !
255                  zn0 = (((((EOS060*zt   &
256                     &   + EOS150*zs+EOS050)*zt   &
257                     &   + (EOS240*zs+EOS140)*zs+EOS040)*zt   &
258                     &   + ((EOS330*zs+EOS230)*zs+EOS130)*zs+EOS030)*zt   &
259                     &   + (((EOS420*zs+EOS320)*zs+EOS220)*zs+EOS120)*zs+EOS020)*zt   &
260                     &   + ((((EOS510*zs+EOS410)*zs+EOS310)*zs+EOS210)*zs+EOS110)*zs+EOS010)*zt   &
261                     &   + (((((EOS600*zs+EOS500)*zs+EOS400)*zs+EOS300)*zs+EOS200)*zs+EOS100)*zs+EOS000
262                     !
263                  zn  = ( ( zn3 * zh + zn2 ) * zh + zn1 ) * zh + zn0
264                  !
265                  prd(ji,jj,jk) = (  zn * r1_rau0 - 1._wp  ) * ztm  ! density anomaly (masked)
266                  !
267               END DO
268            END DO
269         END DO
270         !
271      CASE( 1 )                !==  simplified EOS  ==!
272         !
273         DO jk = 1, jpkm1
274            DO jj = 1, jpj
275               DO ji = 1, jpi
276                  zt  = pts  (ji,jj,jk,jp_tem) - 10._wp
277                  zs  = pts  (ji,jj,jk,jp_sal) - 35._wp
278                  zh  = pdep (ji,jj,jk)
279                  ztm = tmask(ji,jj,jk)
280                  !
281                  zn =  - rn_a0 * ( 1._wp + 0.5_wp*rn_lambda1*zt + rn_mu1*zh ) * zt   &
282                     &  + rn_b0 * ( 1._wp - 0.5_wp*rn_lambda2*zs - rn_mu2*zh ) * zs   &
283                     &  - rn_nu * zt * zs
284                     !                                 
285                  prd(ji,jj,jk) = zn * r1_rau0 * ztm                ! density anomaly (masked)
286               END DO
287            END DO
288         END DO
289         !
290      END SELECT
291      !
292      IF(ln_ctl)   CALL prt_ctl( tab3d_1=prd, clinfo1=' eos-insitu  : ', ovlap=1, kdim=jpk )
293      !
294      IF( nn_timing == 1 )   CALL timing_stop('eos-insitu')
295      !
296   END SUBROUTINE eos_insitu
297
298
299   SUBROUTINE eos_insitu_pot( pts, prd, prhop, pdep )
300      !!----------------------------------------------------------------------
301      !!                  ***  ROUTINE eos_insitu_pot  ***
302      !!
303      !! ** Purpose :   Compute the in situ density (ratio rho/rau0) and the
304      !!      potential volumic mass (Kg/m3) from potential temperature and
305      !!      salinity fields using an equation of state defined through the
306      !!     namelist parameter nn_eos.
307      !!
308      !! ** Action  : - prd  , the in situ density (no units)
309      !!              - prhop, the potential volumic mass (Kg/m3)
310      !!
311      !!----------------------------------------------------------------------
312      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts), INTENT(in   ) ::   pts    ! 1 : potential temperature  [Celcius]
313      !                                                                ! 2 : salinity               [psu]
314      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(  out) ::   prd    ! in situ density            [-]
315      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(  out) ::   prhop  ! potential density (surface referenced)
316      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pdep   ! depth                      [m]
317      !
318      INTEGER  ::   ji, jj, jk, jsmp             ! dummy loop indices
319      INTEGER  ::   jdof
320      REAL(wp) ::   zt , zh , zstemp, zs , ztm   ! local scalars
321      REAL(wp) ::   zn , zn0, zn1, zn2, zn3      !   -      -
322      REAL(wp), DIMENSION(:), ALLOCATABLE :: zn0_sto, zn_sto, zsign    ! local vectors
323      !!----------------------------------------------------------------------
324      !
325      IF( nn_timing == 1 )   CALL timing_start('eos-pot')
326      !
327      SELECT CASE ( nn_eos )
328      !
329      CASE( -1, 0 )                !==  polynomial TEOS-10 / EOS-80 ==!
330         !
331         ! Stochastic equation of state
332         IF ( ln_sto_eos ) THEN
333            ALLOCATE(zn0_sto(1:2*nn_sto_eos))
334            ALLOCATE(zn_sto(1:2*nn_sto_eos))
335            ALLOCATE(zsign(1:2*nn_sto_eos))
336            DO jsmp = 1, 2*nn_sto_eos, 2
337              zsign(jsmp)   = 1._wp
338              zsign(jsmp+1) = -1._wp
339            END DO
340            !
341            DO jk = 1, jpkm1
342               DO jj = 1, jpj
343                  DO ji = 1, jpi
344                     !
345                     ! compute density (2*nn_sto_eos) times:
346                     ! (1) for t+dt, s+ds (with the random TS fluctutation computed in sto_pts)
347                     ! (2) for t-dt, s-ds (with the opposite fluctuation)
348                     DO jsmp = 1, nn_sto_eos*2
349                        jdof   = (jsmp + 1) / 2
350                        zh     = pdep(ji,jj,jk) * r1_Z0                                  ! depth
351                        zt     = (pts (ji,jj,jk,jp_tem) + pts_ran(ji,jj,jk,jp_tem,jdof) * zsign(jsmp)) * r1_T0    ! temperature
352                        zstemp = pts  (ji,jj,jk,jp_sal) + pts_ran(ji,jj,jk,jp_sal,jdof) * zsign(jsmp)
353                        zs     = SQRT( ABS( zstemp + rdeltaS ) * r1_S0 )   ! square root salinity
354                        ztm    = tmask(ji,jj,jk)                                         ! tmask
355                        !
356                        zn3 = EOS013*zt   &
357                           &   + EOS103*zs+EOS003
358                           !
359                        zn2 = (EOS022*zt   &
360                           &   + EOS112*zs+EOS012)*zt   &
361                           &   + (EOS202*zs+EOS102)*zs+EOS002
362                           !
363                        zn1 = (((EOS041*zt   &
364                           &   + EOS131*zs+EOS031)*zt   &
365                           &   + (EOS221*zs+EOS121)*zs+EOS021)*zt   &
366                           &   + ((EOS311*zs+EOS211)*zs+EOS111)*zs+EOS011)*zt   &
367                           &   + (((EOS401*zs+EOS301)*zs+EOS201)*zs+EOS101)*zs+EOS001
368                           !
369                        zn0_sto(jsmp) = (((((EOS060*zt   &
370                           &   + EOS150*zs+EOS050)*zt   &
371                           &   + (EOS240*zs+EOS140)*zs+EOS040)*zt   &
372                           &   + ((EOS330*zs+EOS230)*zs+EOS130)*zs+EOS030)*zt   &
373                           &   + (((EOS420*zs+EOS320)*zs+EOS220)*zs+EOS120)*zs+EOS020)*zt   &
374                           &   + ((((EOS510*zs+EOS410)*zs+EOS310)*zs+EOS210)*zs+EOS110)*zs+EOS010)*zt   &
375                           &   + (((((EOS600*zs+EOS500)*zs+EOS400)*zs+EOS300)*zs+EOS200)*zs+EOS100)*zs+EOS000
376                           !
377                        zn_sto(jsmp)  = ( ( zn3 * zh + zn2 ) * zh + zn1 ) * zh + zn0_sto(jsmp)
378                     END DO
379                     !
380                     ! compute stochastic density as the mean of the (2*nn_sto_eos) densities
381                     prhop(ji,jj,jk) = 0._wp ; prd(ji,jj,jk) = 0._wp
382                     DO jsmp = 1, nn_sto_eos*2
383                        prhop(ji,jj,jk) = prhop(ji,jj,jk) + zn0_sto(jsmp)                      ! potential density referenced at the surface
384                        !
385                        prd(ji,jj,jk) = prd(ji,jj,jk) + (  zn_sto(jsmp) * r1_rau0 - 1._wp  )   ! density anomaly (masked)
386                     END DO
387                     prhop(ji,jj,jk) = 0.5_wp * prhop(ji,jj,jk) * ztm / nn_sto_eos
388                     prd  (ji,jj,jk) = 0.5_wp * prd  (ji,jj,jk) * ztm / nn_sto_eos
389                  END DO
390               END DO
391            END DO
392            DEALLOCATE(zn0_sto,zn_sto,zsign)
393         ! Non-stochastic equation of state
394         ELSE
395            DO jk = 1, jpkm1
396               DO jj = 1, jpj
397                  DO ji = 1, jpi
398                     !
399                     zh  = pdep(ji,jj,jk) * r1_Z0                                  ! depth
400                     zt  = pts (ji,jj,jk,jp_tem) * r1_T0                           ! temperature
401                     zs  = SQRT( ABS( pts(ji,jj,jk,jp_sal) + rdeltaS ) * r1_S0 )   ! square root salinity
402                     ztm = tmask(ji,jj,jk)                                         ! tmask
403                     !
404                     zn3 = EOS013*zt   &
405                        &   + EOS103*zs+EOS003
406                        !
407                     zn2 = (EOS022*zt   &
408                        &   + EOS112*zs+EOS012)*zt   &
409                        &   + (EOS202*zs+EOS102)*zs+EOS002
410                        !
411                     zn1 = (((EOS041*zt   &
412                        &   + EOS131*zs+EOS031)*zt   &
413                        &   + (EOS221*zs+EOS121)*zs+EOS021)*zt   &
414                        &   + ((EOS311*zs+EOS211)*zs+EOS111)*zs+EOS011)*zt   &
415                        &   + (((EOS401*zs+EOS301)*zs+EOS201)*zs+EOS101)*zs+EOS001
416                        !
417                     zn0 = (((((EOS060*zt   &
418                        &   + EOS150*zs+EOS050)*zt   &
419                        &   + (EOS240*zs+EOS140)*zs+EOS040)*zt   &
420                        &   + ((EOS330*zs+EOS230)*zs+EOS130)*zs+EOS030)*zt   &
421                        &   + (((EOS420*zs+EOS320)*zs+EOS220)*zs+EOS120)*zs+EOS020)*zt   &
422                        &   + ((((EOS510*zs+EOS410)*zs+EOS310)*zs+EOS210)*zs+EOS110)*zs+EOS010)*zt   &
423                        &   + (((((EOS600*zs+EOS500)*zs+EOS400)*zs+EOS300)*zs+EOS200)*zs+EOS100)*zs+EOS000
424                        !
425                     zn  = ( ( zn3 * zh + zn2 ) * zh + zn1 ) * zh + zn0
426                     !
427                     prhop(ji,jj,jk) = zn0 * ztm                           ! potential density referenced at the surface
428                     !
429                     prd(ji,jj,jk) = (  zn * r1_rau0 - 1._wp  ) * ztm      ! density anomaly (masked)
430                  END DO
431               END DO
432            END DO
433         ENDIF
434         
435      CASE( 1 )                !==  simplified EOS  ==!
436         !
437         DO jk = 1, jpkm1
438            DO jj = 1, jpj
439               DO ji = 1, jpi
440                  zt  = pts  (ji,jj,jk,jp_tem) - 10._wp
441                  zs  = pts  (ji,jj,jk,jp_sal) - 35._wp
442                  zh  = pdep (ji,jj,jk)
443                  ztm = tmask(ji,jj,jk)
444                  !                                                     ! potential density referenced at the surface
445                  zn =  - rn_a0 * ( 1._wp + 0.5_wp*rn_lambda1*zt ) * zt   &
446                     &  + rn_b0 * ( 1._wp - 0.5_wp*rn_lambda2*zs ) * zs   &
447                     &  - rn_nu * zt * zs
448                  prhop(ji,jj,jk) = ( rau0 + zn ) * ztm
449                  !                                                     ! density anomaly (masked)
450                  zn = zn - ( rn_a0 * rn_mu1 * zt + rn_b0 * rn_mu2 * zs ) * zh
451                  prd(ji,jj,jk) = zn * r1_rau0 * ztm
452                  !
453               END DO
454            END DO
455         END DO
456         !
457      END SELECT
458      !
459      IF(ln_ctl)   CALL prt_ctl( tab3d_1=prd, clinfo1=' eos-pot: ', tab3d_2=prhop, clinfo2=' pot : ', ovlap=1, kdim=jpk )
460      !
461      IF( nn_timing == 1 )   CALL timing_stop('eos-pot')
462      !
463   END SUBROUTINE eos_insitu_pot
464
465
466   SUBROUTINE eos_insitu_2d( pts, pdep, prd )
467      !!----------------------------------------------------------------------
468      !!                  ***  ROUTINE eos_insitu_2d  ***
469      !!
470      !! ** Purpose :   Compute the in situ density (ratio rho/rau0) from
471      !!      potential temperature and salinity using an equation of state
472      !!      defined through the namelist parameter nn_eos. * 2D field case
473      !!
474      !! ** Action  : - prd , the in situ density (no units) (unmasked)
475      !!
476      !!----------------------------------------------------------------------
477      REAL(wp), DIMENSION(jpi,jpj,jpts), INTENT(in   ) ::   pts   ! 1 : potential temperature  [Celcius]
478      !                                                           ! 2 : salinity               [psu]
479      REAL(wp), DIMENSION(jpi,jpj)     , INTENT(in   ) ::   pdep  ! depth                      [m]
480      REAL(wp), DIMENSION(jpi,jpj)     , INTENT(  out) ::   prd   ! in situ density
481      !
482      INTEGER  ::   ji, jj, jk                ! dummy loop indices
483      REAL(wp) ::   zt , zh , zs              ! local scalars
484      REAL(wp) ::   zn , zn0, zn1, zn2, zn3   !   -      -
485      !!----------------------------------------------------------------------
486      !
487      IF( nn_timing == 1 )   CALL timing_start('eos2d')
488      !
489      prd(:,:) = 0._wp
490      !
491      SELECT CASE( nn_eos )
492      !
493      CASE( -1, 0 )                !==  polynomial TEOS-10 / EOS-80 ==!
494         !
495         DO jj = 1, jpjm1
496            DO ji = 1, fs_jpim1   ! vector opt.
497               !
498               zh  = pdep(ji,jj) * r1_Z0                                  ! depth
499               zt  = pts (ji,jj,jp_tem) * r1_T0                           ! temperature
500               zs  = SQRT( ABS( pts(ji,jj,jp_sal) + rdeltaS ) * r1_S0 )   ! square root salinity
501               !
502               zn3 = EOS013*zt   &
503                  &   + EOS103*zs+EOS003
504                  !
505               zn2 = (EOS022*zt   &
506                  &   + EOS112*zs+EOS012)*zt   &
507                  &   + (EOS202*zs+EOS102)*zs+EOS002
508                  !
509               zn1 = (((EOS041*zt   &
510                  &   + EOS131*zs+EOS031)*zt   &
511                  &   + (EOS221*zs+EOS121)*zs+EOS021)*zt   &
512                  &   + ((EOS311*zs+EOS211)*zs+EOS111)*zs+EOS011)*zt   &
513                  &   + (((EOS401*zs+EOS301)*zs+EOS201)*zs+EOS101)*zs+EOS001
514                  !
515               zn0 = (((((EOS060*zt   &
516                  &   + EOS150*zs+EOS050)*zt   &
517                  &   + (EOS240*zs+EOS140)*zs+EOS040)*zt   &
518                  &   + ((EOS330*zs+EOS230)*zs+EOS130)*zs+EOS030)*zt   &
519                  &   + (((EOS420*zs+EOS320)*zs+EOS220)*zs+EOS120)*zs+EOS020)*zt   &
520                  &   + ((((EOS510*zs+EOS410)*zs+EOS310)*zs+EOS210)*zs+EOS110)*zs+EOS010)*zt   &
521                  &   + (((((EOS600*zs+EOS500)*zs+EOS400)*zs+EOS300)*zs+EOS200)*zs+EOS100)*zs+EOS000
522                  !
523               zn  = ( ( zn3 * zh + zn2 ) * zh + zn1 ) * zh + zn0
524               !
525               prd(ji,jj) = zn * r1_rau0 - 1._wp               ! unmasked in situ density anomaly
526               !
527            END DO
528         END DO
529         !
530         CALL lbc_lnk( prd, 'T', 1. )                    ! Lateral boundary conditions
531         !
532      CASE( 1 )                !==  simplified EOS  ==!
533         !
534         DO jj = 1, jpjm1
535            DO ji = 1, fs_jpim1   ! vector opt.
536               !
537               zt    = pts  (ji,jj,jp_tem)  - 10._wp
538               zs    = pts  (ji,jj,jp_sal)  - 35._wp
539               zh    = pdep (ji,jj)                         ! depth at the partial step level
540               !
541               zn =  - rn_a0 * ( 1._wp + 0.5_wp*rn_lambda1*zt + rn_mu1*zh ) * zt   &
542                  &  + rn_b0 * ( 1._wp - 0.5_wp*rn_lambda2*zs - rn_mu2*zh ) * zs   &
543                  &  - rn_nu * zt * zs
544                  !
545               prd(ji,jj) = zn * r1_rau0               ! unmasked in situ density anomaly
546               !
547            END DO
548         END DO
549         !
550         CALL lbc_lnk( prd, 'T', 1. )                    ! Lateral boundary conditions
551         !
552      END SELECT
553      !
554      IF(ln_ctl)   CALL prt_ctl( tab2d_1=prd, clinfo1=' eos2d: ' )
555      !
556      IF( nn_timing == 1 )   CALL timing_stop('eos2d')
557      !
558   END SUBROUTINE eos_insitu_2d
559
560   SUBROUTINE eos_insitu_0d( pts, pdep, prd )
561      !!----------------------------------------------------------------------
562      !!                  ***  ROUTINE eos_insitu_2d  ***
563      !!
564      !! ** Purpose :   Compute the in situ density (ratio rho/rau0) from
565      !!      potential temperature and salinity using an equation of state
566      !!      defined through the namelist parameter nn_eos. * 2D field case
567      !!
568      !! ** Action  : - prd , the in situ density (no units) (unmasked)
569      !!
570      !!----------------------------------------------------------------------
571      REAL(wp), DIMENSION( 2 ), INTENT(in   ) ::   pts   ! 1 : potential temperature  [Celcius]
572      !                                                           ! 2 : salinity               [psu]
573      REAL(wp), INTENT(in   ) ::   pdep  ! depth                      [m]
574      REAL(wp), INTENT(  out) ::   prd   ! in situ density
575      !
576      INTEGER  ::   ji, jj, jk                ! dummy loop indices
577      REAL(wp) ::   zt , zh , zs              ! local scalars
578      REAL(wp) ::   zn , zn0, zn1, zn2, zn3   !   -      -
579      !!----------------------------------------------------------------------
580      !
581      IF( nn_timing == 1 )   CALL timing_start('eos2d')
582      !
583      prd = 0._wp
584      !
585      SELECT CASE( nn_eos )
586      !
587      CASE( -1, 0 )                !==  polynomial TEOS-10 / EOS-80 ==!
588         !
589               !
590               zh  = pdep * r1_Z0                                  ! depth
591               zt  = pts (jp_tem) * r1_T0                           ! temperature
592               zs  = SQRT( ABS( pts(jp_sal) + rdeltaS ) * r1_S0 )   ! square root salinity
593               !
594               zn3 = EOS013*zt   &
595                  &   + EOS103*zs+EOS003
596                  !
597               zn2 = (EOS022*zt   &
598                  &   + EOS112*zs+EOS012)*zt   &
599                  &   + (EOS202*zs+EOS102)*zs+EOS002
600
601               zn1 = (((EOS041*zt   &
602                  &   + EOS131*zs+EOS031)*zt   &
603                  &   + (EOS221*zs+EOS121)*zs+EOS021)*zt   &
604                  &   + ((EOS311*zs+EOS211)*zs+EOS111)*zs+EOS011)*zt   &
605                  &   + (((EOS401*zs+EOS301)*zs+EOS201)*zs+EOS101)*zs+EOS001
606                  !
607               zn0 = (((((EOS060*zt   &
608                  &   + EOS150*zs+EOS050)*zt   &
609                  &   + (EOS240*zs+EOS140)*zs+EOS040)*zt   &
610                  &   + ((EOS330*zs+EOS230)*zs+EOS130)*zs+EOS030)*zt   &
611                  &   + (((EOS420*zs+EOS320)*zs+EOS220)*zs+EOS120)*zs+EOS020)*zt   &
612                  &   + ((((EOS510*zs+EOS410)*zs+EOS310)*zs+EOS210)*zs+EOS110)*zs+EOS010)*zt   &
613                  &   + (((((EOS600*zs+EOS500)*zs+EOS400)*zs+EOS300)*zs+EOS200)*zs+EOS100)*zs+EOS000
614                  !
615               zn  = ( ( zn3 * zh + zn2 ) * zh + zn1 ) * zh + zn0
616               !
617               prd = zn * r1_rau0 - 1._wp               ! unmasked in situ density anomaly
618               !
619      CASE( 1 )                !==  simplified EOS  ==!
620         !
621               zt    = pts  (jp_tem)  - 10._wp
622               zs    = pts  (jp_sal)  - 35._wp
623               zh    = pdep                          ! depth at the partial step level
624               !
625               zn =  - rn_a0 * ( 1._wp + 0.5_wp*rn_lambda1*zt + rn_mu1*zh ) * zt   &
626                  &  + rn_b0 * ( 1._wp - 0.5_wp*rn_lambda2*zs - rn_mu2*zh ) * zs   &
627                  &  - rn_nu * zt * zs
628                  !
629               prd = zn * r1_rau0               ! unmasked in situ density anomaly
630               !
631      END SELECT
632      !
633      IF( nn_timing == 1 )   CALL timing_stop('eos0d')
634      !
635   END SUBROUTINE eos_insitu_0d
636
637   SUBROUTINE rab_3d( pts, pab )
638      !!----------------------------------------------------------------------
639      !!                 ***  ROUTINE rab_3d  ***
640      !!
641      !! ** Purpose :   Calculates thermal/haline expansion ratio at T-points
642      !!
643      !! ** Method  :   calculates alpha / beta at T-points
644      !!
645      !! ** Action  : - pab     : thermal/haline expansion ratio at T-points
646      !!----------------------------------------------------------------------
647      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts), INTENT(in   ) ::   pts   ! pot. temperature & salinity
648      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts), INTENT(  out) ::   pab   ! thermal/haline expansion ratio
649      !
650      INTEGER  ::   ji, jj, jk                ! dummy loop indices
651      REAL(wp) ::   zt , zh , zs , ztm        ! local scalars
652      REAL(wp) ::   zn , zn0, zn1, zn2, zn3   !   -      -
653      !!----------------------------------------------------------------------
654      !
655      IF( nn_timing == 1 )   CALL timing_start('rab_3d')
656      !
657      SELECT CASE ( nn_eos )
658      !
659      CASE( -1, 0 )                !==  polynomial TEOS-10 / EOS-80 ==!
660         !
661         DO jk = 1, jpkm1
662            DO jj = 1, jpj
663               DO ji = 1, jpi
664                  !
665                  zh  = fsdept(ji,jj,jk) * r1_Z0                                ! depth
666                  zt  = pts (ji,jj,jk,jp_tem) * r1_T0                           ! temperature
667                  zs  = SQRT( ABS( pts(ji,jj,jk,jp_sal) + rdeltaS ) * r1_S0 )   ! square root salinity
668                  ztm = tmask(ji,jj,jk)                                         ! tmask
669                  !
670                  ! alpha
671                  zn3 = ALP003
672                  !
673                  zn2 = ALP012*zt + ALP102*zs+ALP002
674                  !
675                  zn1 = ((ALP031*zt   &
676                     &   + ALP121*zs+ALP021)*zt   &
677                     &   + (ALP211*zs+ALP111)*zs+ALP011)*zt   &
678                     &   + ((ALP301*zs+ALP201)*zs+ALP101)*zs+ALP001
679                     !
680                  zn0 = ((((ALP050*zt   &
681                     &   + ALP140*zs+ALP040)*zt   &
682                     &   + (ALP230*zs+ALP130)*zs+ALP030)*zt   &
683                     &   + ((ALP320*zs+ALP220)*zs+ALP120)*zs+ALP020)*zt   &
684                     &   + (((ALP410*zs+ALP310)*zs+ALP210)*zs+ALP110)*zs+ALP010)*zt   &
685                     &   + ((((ALP500*zs+ALP400)*zs+ALP300)*zs+ALP200)*zs+ALP100)*zs+ALP000
686                     !
687                  zn  = ( ( zn3 * zh + zn2 ) * zh + zn1 ) * zh + zn0
688                  !
689                  pab(ji,jj,jk,jp_tem) = zn * r1_rau0 * ztm
690                  !
691                  ! beta
692                  zn3 = BET003
693                  !
694                  zn2 = BET012*zt + BET102*zs+BET002
695                  !
696                  zn1 = ((BET031*zt   &
697                     &   + BET121*zs+BET021)*zt   &
698                     &   + (BET211*zs+BET111)*zs+BET011)*zt   &
699                     &   + ((BET301*zs+BET201)*zs+BET101)*zs+BET001
700                     !
701                  zn0 = ((((BET050*zt   &
702                     &   + BET140*zs+BET040)*zt   &
703                     &   + (BET230*zs+BET130)*zs+BET030)*zt   &
704                     &   + ((BET320*zs+BET220)*zs+BET120)*zs+BET020)*zt   &
705                     &   + (((BET410*zs+BET310)*zs+BET210)*zs+BET110)*zs+BET010)*zt   &
706                     &   + ((((BET500*zs+BET400)*zs+BET300)*zs+BET200)*zs+BET100)*zs+BET000
707                     !
708                  zn  = ( ( zn3 * zh + zn2 ) * zh + zn1 ) * zh + zn0
709                  !
710                  pab(ji,jj,jk,jp_sal) = zn / zs * r1_rau0 * ztm
711                  !
712               END DO
713            END DO
714         END DO
715         !
716      CASE( 1 )                  !==  simplified EOS  ==!
717         !
718         DO jk = 1, jpkm1
719            DO jj = 1, jpj
720               DO ji = 1, jpi
721                  zt  = pts (ji,jj,jk,jp_tem) - 10._wp   ! pot. temperature anomaly (t-T0)
722                  zs  = pts (ji,jj,jk,jp_sal) - 35._wp   ! abs. salinity anomaly (s-S0)
723                  zh  = fsdept(ji,jj,jk)                 ! depth in meters at t-point
724                  ztm = tmask(ji,jj,jk)                  ! land/sea bottom mask = surf. mask
725                  !
726                  zn  = rn_a0 * ( 1._wp + rn_lambda1*zt + rn_mu1*zh ) + rn_nu*zs
727                  pab(ji,jj,jk,jp_tem) = zn * r1_rau0 * ztm   ! alpha
728                  !
729                  zn  = rn_b0 * ( 1._wp - rn_lambda2*zs - rn_mu2*zh ) - rn_nu*zt
730                  pab(ji,jj,jk,jp_sal) = zn * r1_rau0 * ztm   ! beta
731                  !
732               END DO
733            END DO
734         END DO
735         !
736      CASE DEFAULT
737         IF(lwp) WRITE(numout,cform_err)
738         IF(lwp) WRITE(numout,*) '          bad flag value for nn_eos = ', nn_eos
739         nstop = nstop + 1
740         !
741      END SELECT
742      !
743      IF(ln_ctl)   CALL prt_ctl( tab3d_1=pab(:,:,:,jp_tem), clinfo1=' rab_3d_t: ', &
744         &                       tab3d_2=pab(:,:,:,jp_sal), clinfo2=' rab_3d_s : ', ovlap=1, kdim=jpk )
745      !
746      IF( nn_timing == 1 )   CALL timing_stop('rab_3d')
747      !
748   END SUBROUTINE rab_3d
749
750   SUBROUTINE rab_2d( pts, pdep, pab )
751      !!----------------------------------------------------------------------
752      !!                 ***  ROUTINE rab_2d  ***
753      !!
754      !! ** Purpose :   Calculates thermal/haline expansion ratio for a 2d field (unmasked)
755      !!
756      !! ** Action  : - pab     : thermal/haline expansion ratio at T-points
757      !!----------------------------------------------------------------------
758      REAL(wp), DIMENSION(jpi,jpj,jpts)    , INTENT(in   ) ::   pts    ! pot. temperature & salinity
759      REAL(wp), DIMENSION(jpi,jpj)         , INTENT(in   ) ::   pdep   ! depth                  [m]
760      REAL(wp), DIMENSION(jpi,jpj,jpts)    , INTENT(  out) ::   pab    ! thermal/haline expansion ratio
761      !
762      INTEGER  ::   ji, jj, jk                ! dummy loop indices
763      REAL(wp) ::   zt , zh , zs              ! local scalars
764      REAL(wp) ::   zn , zn0, zn1, zn2, zn3   !   -      -
765      !!----------------------------------------------------------------------
766      !
767      IF( nn_timing == 1 ) CALL timing_start('rab_2d')
768      !
769      pab(:,:,:) = 0._wp
770      !
771      SELECT CASE ( nn_eos )
772      !
773      CASE( -1, 0 )                !==  polynomial TEOS-10 / EOS-80 ==!
774         !
775         DO jj = 1, jpjm1
776            DO ji = 1, fs_jpim1   ! vector opt.
777               !
778               zh  = pdep(ji,jj) * r1_Z0                                  ! depth
779               zt  = pts (ji,jj,jp_tem) * r1_T0                           ! temperature
780               zs  = SQRT( ABS( pts(ji,jj,jp_sal) + rdeltaS ) * r1_S0 )   ! square root salinity
781               !
782               ! alpha
783               zn3 = ALP003
784               !
785               zn2 = ALP012*zt + ALP102*zs+ALP002
786               !
787               zn1 = ((ALP031*zt   &
788                  &   + ALP121*zs+ALP021)*zt   &
789                  &   + (ALP211*zs+ALP111)*zs+ALP011)*zt   &
790                  &   + ((ALP301*zs+ALP201)*zs+ALP101)*zs+ALP001
791                  !
792               zn0 = ((((ALP050*zt   &
793                  &   + ALP140*zs+ALP040)*zt   &
794                  &   + (ALP230*zs+ALP130)*zs+ALP030)*zt   &
795                  &   + ((ALP320*zs+ALP220)*zs+ALP120)*zs+ALP020)*zt   &
796                  &   + (((ALP410*zs+ALP310)*zs+ALP210)*zs+ALP110)*zs+ALP010)*zt   &
797                  &   + ((((ALP500*zs+ALP400)*zs+ALP300)*zs+ALP200)*zs+ALP100)*zs+ALP000
798                  !
799               zn  = ( ( zn3 * zh + zn2 ) * zh + zn1 ) * zh + zn0
800               !
801               pab(ji,jj,jp_tem) = zn * r1_rau0
802               !
803               ! beta
804               zn3 = BET003
805               !
806               zn2 = BET012*zt + BET102*zs+BET002
807               !
808               zn1 = ((BET031*zt   &
809                  &   + BET121*zs+BET021)*zt   &
810                  &   + (BET211*zs+BET111)*zs+BET011)*zt   &
811                  &   + ((BET301*zs+BET201)*zs+BET101)*zs+BET001
812                  !
813               zn0 = ((((BET050*zt   &
814                  &   + BET140*zs+BET040)*zt   &
815                  &   + (BET230*zs+BET130)*zs+BET030)*zt   &
816                  &   + ((BET320*zs+BET220)*zs+BET120)*zs+BET020)*zt   &
817                  &   + (((BET410*zs+BET310)*zs+BET210)*zs+BET110)*zs+BET010)*zt   &
818                  &   + ((((BET500*zs+BET400)*zs+BET300)*zs+BET200)*zs+BET100)*zs+BET000
819                  !
820               zn  = ( ( zn3 * zh + zn2 ) * zh + zn1 ) * zh + zn0
821               !
822               pab(ji,jj,jp_sal) = zn / zs * r1_rau0
823               !
824               !
825            END DO
826         END DO
827         !
828         CALL lbc_lnk( pab(:,:,jp_tem), 'T', 1. )                    ! Lateral boundary conditions
829         CALL lbc_lnk( pab(:,:,jp_sal), 'T', 1. )                   
830         !
831      CASE( 1 )                  !==  simplified EOS  ==!
832         !
833         DO jj = 1, jpjm1
834            DO ji = 1, fs_jpim1   ! vector opt.
835               !
836               zt    = pts  (ji,jj,jp_tem) - 10._wp   ! pot. temperature anomaly (t-T0)
837               zs    = pts  (ji,jj,jp_sal) - 35._wp   ! abs. salinity anomaly (s-S0)
838               zh    = pdep (ji,jj)                   ! depth at the partial step level
839               !
840               zn  = rn_a0 * ( 1._wp + rn_lambda1*zt + rn_mu1*zh ) + rn_nu*zs
841               pab(ji,jj,jp_tem) = zn * r1_rau0   ! alpha
842               !
843               zn  = rn_b0 * ( 1._wp - rn_lambda2*zs - rn_mu2*zh ) - rn_nu*zt
844               pab(ji,jj,jp_sal) = zn * r1_rau0   ! beta
845               !
846            END DO
847         END DO
848         !
849         CALL lbc_lnk( pab(:,:,jp_tem), 'T', 1. )                    ! Lateral boundary conditions
850         CALL lbc_lnk( pab(:,:,jp_sal), 'T', 1. )                   
851         !
852      CASE DEFAULT
853         IF(lwp) WRITE(numout,cform_err)
854         IF(lwp) WRITE(numout,*) '          bad flag value for nn_eos = ', nn_eos
855         nstop = nstop + 1
856         !
857      END SELECT
858      !
859      IF(ln_ctl)   CALL prt_ctl( tab2d_1=pab(:,:,jp_tem), clinfo1=' rab_2d_t: ', &
860         &                       tab2d_2=pab(:,:,jp_sal), clinfo2=' rab_2d_s : ' )
861      !
862      IF( nn_timing == 1 )   CALL timing_stop('rab_2d')
863      !
864   END SUBROUTINE rab_2d
865
866
867   SUBROUTINE rab_0d( pts, pdep, pab )
868      !!----------------------------------------------------------------------
869      !!                 ***  ROUTINE rab_0d  ***
870      !!
871      !! ** Purpose :   Calculates thermal/haline expansion ratio for a 2d field (unmasked)
872      !!
873      !! ** Action  : - pab     : thermal/haline expansion ratio at T-points
874      !!----------------------------------------------------------------------
875      REAL(wp), DIMENSION(jpts)    , INTENT(in   ) ::   pts    ! pot. temperature & salinity
876      REAL(wp),                      INTENT(in   ) ::   pdep   ! depth                  [m]
877      REAL(wp), DIMENSION(jpts)    , INTENT(  out) ::   pab    ! thermal/haline expansion ratio
878      !
879      REAL(wp) ::   zt , zh , zs              ! local scalars
880      REAL(wp) ::   zn , zn0, zn1, zn2, zn3   !   -      -
881      !!----------------------------------------------------------------------
882      !
883      IF( nn_timing == 1 ) CALL timing_start('rab_2d')
884      !
885      pab(:) = 0._wp
886      !
887      SELECT CASE ( nn_eos )
888      !
889      CASE( -1, 0 )                !==  polynomial TEOS-10 / EOS-80 ==!
890         !
891         !
892         zh  = pdep * r1_Z0                                  ! depth
893         zt  = pts (jp_tem) * r1_T0                           ! temperature
894         zs  = SQRT( ABS( pts(jp_sal) + rdeltaS ) * r1_S0 )   ! square root salinity
895         !
896         ! alpha
897         zn3 = ALP003
898         !
899         zn2 = ALP012*zt + ALP102*zs+ALP002
900         !
901         zn1 = ((ALP031*zt   &
902            &   + ALP121*zs+ALP021)*zt   &
903            &   + (ALP211*zs+ALP111)*zs+ALP011)*zt   &
904            &   + ((ALP301*zs+ALP201)*zs+ALP101)*zs+ALP001
905            !
906         zn0 = ((((ALP050*zt   &
907            &   + ALP140*zs+ALP040)*zt   &
908            &   + (ALP230*zs+ALP130)*zs+ALP030)*zt   &
909            &   + ((ALP320*zs+ALP220)*zs+ALP120)*zs+ALP020)*zt   &
910            &   + (((ALP410*zs+ALP310)*zs+ALP210)*zs+ALP110)*zs+ALP010)*zt   &
911            &   + ((((ALP500*zs+ALP400)*zs+ALP300)*zs+ALP200)*zs+ALP100)*zs+ALP000
912            !
913         zn  = ( ( zn3 * zh + zn2 ) * zh + zn1 ) * zh + zn0
914         !
915         pab(jp_tem) = zn * r1_rau0
916         !
917         ! beta
918         zn3 = BET003
919         !
920         zn2 = BET012*zt + BET102*zs+BET002
921         !
922         zn1 = ((BET031*zt   &
923            &   + BET121*zs+BET021)*zt   &
924            &   + (BET211*zs+BET111)*zs+BET011)*zt   &
925            &   + ((BET301*zs+BET201)*zs+BET101)*zs+BET001
926            !
927         zn0 = ((((BET050*zt   &
928            &   + BET140*zs+BET040)*zt   &
929            &   + (BET230*zs+BET130)*zs+BET030)*zt   &
930            &   + ((BET320*zs+BET220)*zs+BET120)*zs+BET020)*zt   &
931            &   + (((BET410*zs+BET310)*zs+BET210)*zs+BET110)*zs+BET010)*zt   &
932            &   + ((((BET500*zs+BET400)*zs+BET300)*zs+BET200)*zs+BET100)*zs+BET000
933            !
934         zn  = ( ( zn3 * zh + zn2 ) * zh + zn1 ) * zh + zn0
935         !
936         pab(jp_sal) = zn / zs * r1_rau0
937         !
938         !
939         !
940      CASE( 1 )                  !==  simplified EOS  ==!
941         !
942         zt    = pts(jp_tem) - 10._wp   ! pot. temperature anomaly (t-T0)
943         zs    = pts(jp_sal) - 35._wp   ! abs. salinity anomaly (s-S0)
944         zh    = pdep                    ! depth at the partial step level
945         !
946         zn  = rn_a0 * ( 1._wp + rn_lambda1*zt + rn_mu1*zh ) + rn_nu*zs
947         pab(jp_tem) = zn * r1_rau0   ! alpha
948         !
949         zn  = rn_b0 * ( 1._wp - rn_lambda2*zs - rn_mu2*zh ) - rn_nu*zt
950         pab(jp_sal) = zn * r1_rau0   ! beta
951         !
952      CASE DEFAULT
953         IF(lwp) WRITE(numout,cform_err)
954         IF(lwp) WRITE(numout,*) '          bad flag value for nn_eos = ', nn_eos
955         nstop = nstop + 1
956         !
957      END SELECT
958      !
959      IF( nn_timing == 1 )   CALL timing_stop('rab_2d')
960      !
961   END SUBROUTINE rab_0d
962
963
964   SUBROUTINE bn2( pts, pab, pn2 )
965      !!----------------------------------------------------------------------
966      !!                  ***  ROUTINE bn2  ***
967      !!
968      !! ** Purpose :   Compute the local Brunt-Vaisala frequency at the
969      !!                time-step of the input arguments
970      !!
971      !! ** Method  :   pn2 = grav * (alpha dk[T] + beta dk[S] ) / e3w
972      !!      where alpha and beta are given in pab, and computed on T-points.
973      !!      N.B. N^2 is set one for all to zero at jk=1 in istate module.
974      !!
975      !! ** Action  :   pn2 : square of the brunt-vaisala frequency at w-point
976      !!
977      !!----------------------------------------------------------------------
978      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts), INTENT(in   ) ::  pts   ! pot. temperature and salinity   [Celcius,psu]
979      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts), INTENT(in   ) ::  pab   ! thermal/haline expansion coef.  [Celcius-1,psu-1]
980      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(  out) ::  pn2   ! Brunt-Vaisala frequency squared [1/s^2]
981      !
982      INTEGER  ::   ji, jj, jk      ! dummy loop indices
983      REAL(wp) ::   zaw, zbw, zrw   ! local scalars
984      !!----------------------------------------------------------------------
985      !
986      IF( nn_timing == 1 ) CALL timing_start('bn2')
987      !
988      DO jk = 2, jpkm1           ! interior points only (2=< jk =< jpkm1 )
989         DO jj = 1, jpj          ! surface and bottom value set to zero one for all in istate.F90
990            DO ji = 1, jpi
991               zrw =   ( fsdepw(ji,jj,jk  ) - fsdept(ji,jj,jk) )   &
992                  &  / ( fsdept(ji,jj,jk-1) - fsdept(ji,jj,jk) ) 
993                  !
994               zaw = pab(ji,jj,jk,jp_tem) * (1. - zrw) + pab(ji,jj,jk-1,jp_tem) * zrw 
995               zbw = pab(ji,jj,jk,jp_sal) * (1. - zrw) + pab(ji,jj,jk-1,jp_sal) * zrw
996               !
997               pn2(ji,jj,jk) = grav * (  zaw * ( pts(ji,jj,jk-1,jp_tem) - pts(ji,jj,jk,jp_tem) )     &
998                  &                    - zbw * ( pts(ji,jj,jk-1,jp_sal) - pts(ji,jj,jk,jp_sal) )  )  &
999                  &            / fse3w(ji,jj,jk) * wmask(ji,jj,jk)
1000            END DO
1001         END DO
1002      END DO
1003      !
1004      IF(ln_ctl)   CALL prt_ctl( tab3d_1=pn2, clinfo1=' bn2  : ', ovlap=1, kdim=jpk )
1005      !
1006      IF( nn_timing == 1 )   CALL timing_stop('bn2')
1007      !
1008   END SUBROUTINE bn2
1009
1010
1011   FUNCTION eos_pt_from_ct( ctmp, psal ) RESULT( ptmp )
1012      !!----------------------------------------------------------------------
1013      !!                 ***  ROUTINE eos_pt_from_ct  ***
1014      !!
1015      !! ** Purpose :   Compute pot.temp. from cons. temp. [Celcius]
1016      !!
1017      !! ** Method  :   rational approximation (5/3th order) of TEOS-10 algorithm
1018      !!       checkvalue: pt=20.02391895 Celsius for sa=35.7g/kg, ct=20degC
1019      !!
1020      !! Reference  :   TEOS-10, UNESCO
1021      !!                Rational approximation to TEOS10 algorithm (rms error on WOA13 values: 4.0e-5 degC)
1022      !!----------------------------------------------------------------------
1023      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   ctmp   ! Cons. Temp [Celcius]
1024      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   psal   ! salinity   [psu]
1025      ! Leave result array automatic rather than making explicitly allocated
1026      REAL(wp), DIMENSION(jpi,jpj) ::   ptmp   ! potential temperature [Celcius]
1027      !
1028      INTEGER  ::   ji, jj               ! dummy loop indices
1029      REAL(wp) ::   zt , zs , ztm        ! local scalars
1030      REAL(wp) ::   zn , zd              ! local scalars
1031      REAL(wp) ::   zdeltaS , z1_S0 , z1_T0
1032      !!----------------------------------------------------------------------
1033      !
1034      IF ( nn_timing == 1 )   CALL timing_start('eos_pt_from_ct')
1035      !
1036      zdeltaS = 5._wp
1037      z1_S0   = 0.875_wp/35.16504_wp
1038      z1_T0   = 1._wp/40._wp
1039      !
1040      DO jj = 1, jpj
1041         DO ji = 1, jpi
1042            !
1043            zt  = ctmp   (ji,jj) * z1_T0
1044            zs  = SQRT( ABS( psal(ji,jj) + zdeltaS ) * r1_S0 )
1045            ztm = tmask(ji,jj,1)
1046            !
1047            zn = ((((-2.1385727895e-01_wp*zt   &
1048               &   - 2.7674419971e-01_wp*zs+1.0728094330_wp)*zt   &
1049               &   + (2.6366564313_wp*zs+3.3546960647_wp)*zs-7.8012209473_wp)*zt   &
1050               &   + ((1.8835586562_wp*zs+7.3949191679_wp)*zs-3.3937395875_wp)*zs-5.6414948432_wp)*zt   &
1051               &   + (((3.5737370589_wp*zs-1.5512427389e+01_wp)*zs+2.4625741105e+01_wp)*zs   &
1052               &      +1.9912291000e+01_wp)*zs-3.2191146312e+01_wp)*zt   &
1053               &   + ((((5.7153204649e-01_wp*zs-3.0943149543_wp)*zs+9.3052495181_wp)*zs   &
1054               &      -9.4528934807_wp)*zs+3.1066408996_wp)*zs-4.3504021262e-01_wp
1055               !
1056            zd = (2.0035003456_wp*zt   &
1057               &   -3.4570358592e-01_wp*zs+5.6471810638_wp)*zt   &
1058               &   + (1.5393993508_wp*zs-6.9394762624_wp)*zs+1.2750522650e+01_wp
1059               !
1060            ptmp(ji,jj) = ( zt / z1_T0 + zn / zd ) * ztm
1061               !
1062         END DO
1063      END DO
1064      !
1065      IF( nn_timing == 1 )   CALL timing_stop('eos_pt_from_ct')
1066      !
1067   END FUNCTION eos_pt_from_ct
1068
1069
1070   SUBROUTINE  eos_fzp_2d( psal, ptf, pdep )
1071      !!----------------------------------------------------------------------
1072      !!                 ***  ROUTINE eos_fzp  ***
1073      !!
1074      !! ** Purpose :   Compute the freezing point temperature [Celcius]
1075      !!
1076      !! ** Method  :   UNESCO freezing point (ptf) in Celcius is given by
1077      !!       ptf(t,z) = (-.0575+1.710523e-3*sqrt(abs(s))-2.154996e-4*s)*s - 7.53e-4*z
1078      !!       checkvalue: tf=-2.588567 Celsius for s=40psu, z=500m
1079      !!
1080      !! Reference  :   UNESCO tech. papers in the marine science no. 28. 1978
1081      !!----------------------------------------------------------------------
1082      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   )           ::   psal   ! salinity   [psu]
1083      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ), OPTIONAL ::   pdep   ! depth      [m]
1084      REAL(wp), DIMENSION(jpi,jpj), INTENT(out  )           ::   ptf    ! freezing temperature [Celcius]
1085      !
1086      INTEGER  ::   ji, jj   ! dummy loop indices
1087      REAL(wp) ::   zt, zs   ! local scalars
1088      !!----------------------------------------------------------------------
1089      !
1090      SELECT CASE ( nn_eos )
1091      !
1092      CASE ( -1, 1 )                !==  CT,SA (TEOS-10 formulation) ==!
1093         !
1094         DO jj = 1, jpj
1095            DO ji = 1, jpi
1096               zs= SQRT( ABS( psal(ji,jj) ) * r1_S0 )           ! square root salinity
1097               ptf(ji,jj) = ((((1.46873e-03_wp*zs-9.64972e-03_wp)*zs+2.28348e-02_wp)*zs &
1098                  &          - 3.12775e-02_wp)*zs+2.07679e-02_wp)*zs-5.87701e-02_wp
1099            END DO
1100         END DO
1101         ptf(:,:) = ptf(:,:) * psal(:,:)
1102         !
1103         IF( PRESENT( pdep ) )   ptf(:,:) = ptf(:,:) - 7.53e-4 * pdep(:,:)
1104         !
1105      CASE ( 0 )                     !==  PT,SP (UNESCO formulation)  ==!
1106         !
1107         ptf(:,:) = ( - 0.0575_wp + 1.710523e-3_wp * SQRT( psal(:,:) )   &
1108            &                     - 2.154996e-4_wp *       psal(:,:)   ) * psal(:,:)
1109            !
1110         IF( PRESENT( pdep ) )   ptf(:,:) = ptf(:,:) - 7.53e-4 * pdep(:,:)
1111         !
1112      CASE DEFAULT
1113         IF(lwp) WRITE(numout,cform_err)
1114         IF(lwp) WRITE(numout,*) '          bad flag value for nn_eos = ', nn_eos
1115         nstop = nstop + 1
1116         !
1117      END SELECT     
1118      !
1119  END SUBROUTINE eos_fzp_2d
1120
1121  SUBROUTINE eos_fzp_0d( psal, ptf, pdep )
1122      !!----------------------------------------------------------------------
1123      !!                 ***  ROUTINE eos_fzp  ***
1124      !!
1125      !! ** Purpose :   Compute the freezing point temperature [Celcius]
1126      !!
1127      !! ** Method  :   UNESCO freezing point (ptf) in Celcius is given by
1128      !!       ptf(t,z) = (-.0575+1.710523e-3*sqrt(abs(s))-2.154996e-4*s)*s - 7.53e-4*z
1129      !!       checkvalue: tf=-2.588567 Celsius for s=40psu, z=500m
1130      !!
1131      !! Reference  :   UNESCO tech. papers in the marine science no. 28. 1978
1132      !!----------------------------------------------------------------------
1133      REAL(wp), INTENT(in )           ::   psal         ! salinity   [psu]
1134      REAL(wp), INTENT(in ), OPTIONAL ::   pdep         ! depth      [m]
1135      REAL(wp), INTENT(out)           ::   ptf          ! freezing temperature [Celcius]
1136      !
1137      REAL(wp) :: zs   ! local scalars
1138      !!----------------------------------------------------------------------
1139      !
1140      SELECT CASE ( nn_eos )
1141      !
1142      CASE ( -1, 1 )                !==  CT,SA (TEOS-10 formulation) ==!
1143         !
1144         zs  = SQRT( ABS( psal ) * r1_S0 )           ! square root salinity
1145         ptf = ((((1.46873e-03_wp*zs-9.64972e-03_wp)*zs+2.28348e-02_wp)*zs &
1146                  &          - 3.12775e-02_wp)*zs+2.07679e-02_wp)*zs-5.87701e-02_wp
1147         ptf = ptf * psal
1148         !
1149         IF( PRESENT( pdep ) )   ptf = ptf - 7.53e-4 * pdep
1150         !
1151      CASE ( 0 )                     !==  PT,SP (UNESCO formulation)  ==!
1152         !
1153         ptf = ( - 0.0575_wp + 1.710523e-3_wp * SQRT( psal )   &
1154            &                - 2.154996e-4_wp *       psal   ) * psal
1155            !
1156         IF( PRESENT( pdep ) )   ptf = ptf - 7.53e-4 * pdep
1157         !
1158      CASE DEFAULT
1159         IF(lwp) WRITE(numout,cform_err)
1160         IF(lwp) WRITE(numout,*) '          bad flag value for nn_eos = ', nn_eos
1161         nstop = nstop + 1
1162         !
1163      END SELECT
1164      !
1165   END SUBROUTINE eos_fzp_0d
1166
1167
1168   SUBROUTINE eos_pen( pts, pab_pe, ppen )
1169      !!----------------------------------------------------------------------
1170      !!                 ***  ROUTINE eos_pen  ***
1171      !!
1172      !! ** Purpose :   Calculates nonlinear anomalies of alpha_PE, beta_PE and PE at T-points
1173      !!
1174      !! ** Method  :   PE is defined analytically as the vertical
1175      !!                   primitive of EOS times -g integrated between 0 and z>0.
1176      !!                pen is the nonlinear bsq-PE anomaly: pen = ( PE - rau0 gz ) / rau0 gz - rd
1177      !!                                                      = 1/z * /int_0^z rd dz - rd
1178      !!                                where rd is the density anomaly (see eos_rhd function)
1179      !!                ab_pe are partial derivatives of PE anomaly with respect to T and S:
1180      !!                    ab_pe(1) = - 1/(rau0 gz) * dPE/dT + drd/dT = - d(pen)/dT
1181      !!                    ab_pe(2) =   1/(rau0 gz) * dPE/dS + drd/dS =   d(pen)/dS
1182      !!
1183      !! ** Action  : - pen         : PE anomaly given at T-points
1184      !!            : - pab_pe  : given at T-points
1185      !!                    pab_pe(:,:,:,jp_tem) is alpha_pe
1186      !!                    pab_pe(:,:,:,jp_sal) is beta_pe
1187      !!----------------------------------------------------------------------
1188      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts), INTENT(in   ) ::   pts     ! pot. temperature & salinity
1189      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts), INTENT(  out) ::   pab_pe  ! alpha_pe and beta_pe
1190      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(  out) ::   ppen     ! potential energy anomaly
1191      !
1192      INTEGER  ::   ji, jj, jk                ! dummy loop indices
1193      REAL(wp) ::   zt , zh , zs , ztm        ! local scalars
1194      REAL(wp) ::   zn , zn0, zn1, zn2        !   -      -
1195      !!----------------------------------------------------------------------
1196      !
1197      IF( nn_timing == 1 )   CALL timing_start('eos_pen')
1198      !
1199      SELECT CASE ( nn_eos )
1200      !
1201      CASE( -1, 0 )                !==  polynomial TEOS-10 / EOS-80 ==!
1202         !
1203         DO jk = 1, jpkm1
1204            DO jj = 1, jpj
1205               DO ji = 1, jpi
1206                  !
1207                  zh  = fsdept(ji,jj,jk) * r1_Z0                                ! depth
1208                  zt  = pts (ji,jj,jk,jp_tem) * r1_T0                           ! temperature
1209                  zs  = SQRT( ABS( pts(ji,jj,jk,jp_sal) + rdeltaS ) * r1_S0 )   ! square root salinity
1210                  ztm = tmask(ji,jj,jk)                                         ! tmask
1211                  !
1212                  ! potential energy non-linear anomaly
1213                  zn2 = (PEN012)*zt   &
1214                     &   + PEN102*zs+PEN002
1215                     !
1216                  zn1 = ((PEN021)*zt   &
1217                     &   + PEN111*zs+PEN011)*zt   &
1218                     &   + (PEN201*zs+PEN101)*zs+PEN001
1219                     !
1220                  zn0 = ((((PEN040)*zt   &
1221                     &   + PEN130*zs+PEN030)*zt   &
1222                     &   + (PEN220*zs+PEN120)*zs+PEN020)*zt   &
1223                     &   + ((PEN310*zs+PEN210)*zs+PEN110)*zs+PEN010)*zt   &
1224                     &   + (((PEN400*zs+PEN300)*zs+PEN200)*zs+PEN100)*zs+PEN000
1225                     !
1226                  zn  = ( zn2 * zh + zn1 ) * zh + zn0
1227                  !
1228                  ppen(ji,jj,jk)  = zn * zh * r1_rau0 * ztm
1229                  !
1230                  ! alphaPE non-linear anomaly
1231                  zn2 = APE002
1232                  !
1233                  zn1 = (APE011)*zt   &
1234                     &   + APE101*zs+APE001
1235                     !
1236                  zn0 = (((APE030)*zt   &
1237                     &   + APE120*zs+APE020)*zt   &
1238                     &   + (APE210*zs+APE110)*zs+APE010)*zt   &
1239                     &   + ((APE300*zs+APE200)*zs+APE100)*zs+APE000
1240                     !
1241                  zn  = ( zn2 * zh + zn1 ) * zh + zn0
1242                  !                             
1243                  pab_pe(ji,jj,jk,jp_tem) = zn * zh * r1_rau0 * ztm
1244                  !
1245                  ! betaPE non-linear anomaly
1246                  zn2 = BPE002
1247                  !
1248                  zn1 = (BPE011)*zt   &
1249                     &   + BPE101*zs+BPE001
1250                     !
1251                  zn0 = (((BPE030)*zt   &
1252                     &   + BPE120*zs+BPE020)*zt   &
1253                     &   + (BPE210*zs+BPE110)*zs+BPE010)*zt   &
1254                     &   + ((BPE300*zs+BPE200)*zs+BPE100)*zs+BPE000
1255                     !
1256                  zn  = ( zn2 * zh + zn1 ) * zh + zn0
1257                  !                             
1258                  pab_pe(ji,jj,jk,jp_sal) = zn / zs * zh * r1_rau0 * ztm
1259                  !
1260               END DO
1261            END DO
1262         END DO
1263         !
1264      CASE( 1 )                !==  Vallis (2006) simplified EOS  ==!
1265         !
1266         DO jk = 1, jpkm1
1267            DO jj = 1, jpj
1268               DO ji = 1, jpi
1269                  zt  = pts(ji,jj,jk,jp_tem) - 10._wp  ! temperature anomaly (t-T0)
1270                  zs = pts (ji,jj,jk,jp_sal) - 35._wp  ! abs. salinity anomaly (s-S0)
1271                  zh  = fsdept(ji,jj,jk)               ! depth in meters  at t-point
1272                  ztm = tmask(ji,jj,jk)                ! tmask
1273                  zn  = 0.5_wp * zh * r1_rau0 * ztm
1274                  !                                    ! Potential Energy
1275                  ppen(ji,jj,jk) = ( rn_a0 * rn_mu1 * zt + rn_b0 * rn_mu2 * zs ) * zn
1276                  !                                    ! alphaPE
1277                  pab_pe(ji,jj,jk,jp_tem) = - rn_a0 * rn_mu1 * zn
1278                  pab_pe(ji,jj,jk,jp_sal) =   rn_b0 * rn_mu2 * zn
1279                  !
1280               END DO
1281            END DO
1282         END DO
1283         !
1284      CASE DEFAULT
1285         IF(lwp) WRITE(numout,cform_err)
1286         IF(lwp) WRITE(numout,*) '          bad flag value for nn_eos = ', nn_eos
1287         nstop = nstop + 1
1288         !
1289      END SELECT
1290      !
1291      IF( nn_timing == 1 )   CALL timing_stop('eos_pen')
1292      !
1293   END SUBROUTINE eos_pen
1294
1295
1296   SUBROUTINE eos_init
1297      !!----------------------------------------------------------------------
1298      !!                 ***  ROUTINE eos_init  ***
1299      !!
1300      !! ** Purpose :   initializations for the equation of state
1301      !!
1302      !! ** Method  :   Read the namelist nameos and control the parameters
1303      !!----------------------------------------------------------------------
1304      INTEGER  ::   ios   ! local integer
1305      !!
1306      NAMELIST/nameos/ nn_eos, ln_useCT, rn_a0, rn_b0, rn_lambda1, rn_mu1,   &
1307         &                                             rn_lambda2, rn_mu2, rn_nu
1308      !!----------------------------------------------------------------------
1309      !
1310      REWIND( numnam_ref )              ! Namelist nameos in reference namelist : equation of state
1311      READ  ( numnam_ref, nameos, IOSTAT = ios, ERR = 901 )
1312901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nameos in reference namelist', lwp )
1313      !
1314      REWIND( numnam_cfg )              ! Namelist nameos in configuration namelist : equation of state
1315      READ  ( numnam_cfg, nameos, IOSTAT = ios, ERR = 902 )
1316902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nameos in configuration namelist', lwp )
1317      IF(lwm) WRITE( numond, nameos )
1318      !
1319      rau0        = 1026._wp                 !: volumic mass of reference     [kg/m3]
1320      rcp         = 3991.86795711963_wp      !: heat capacity     [J/K]
1321      !
1322      IF(lwp) THEN                ! Control print
1323         WRITE(numout,*)
1324         WRITE(numout,*) 'eos_init : equation of state'
1325         WRITE(numout,*) '~~~~~~~~'
1326         WRITE(numout,*) '          Namelist nameos : set eos parameters'
1327         WRITE(numout,*) '             flag for eq. of state and N^2  nn_eos   = ', nn_eos
1328         IF( ln_useCT )   THEN
1329            WRITE(numout,*) '             model uses Conservative Temperature'
1330            WRITE(numout,*) '             Important: model must be initialized with CT and SA fields'
1331         ELSE
1332            WRITE(numout,*) '             model does not use Conservative Temperature'
1333         ENDIF
1334      ENDIF
1335      !
1336      SELECT CASE( nn_eos )         ! check option
1337      !
1338      CASE( -1 )                       !==  polynomial TEOS-10  ==!
1339         IF(lwp) WRITE(numout,*)
1340         IF(lwp) WRITE(numout,*) '          use of TEOS-10 equation of state (cons. temp. and abs. salinity)'
1341         !
1342         rdeltaS = 32._wp
1343         r1_S0  = 0.875_wp/35.16504_wp
1344         r1_T0  = 1._wp/40._wp
1345         r1_Z0  = 1.e-4_wp
1346         !
1347         EOS000 = 8.0189615746e+02_wp
1348         EOS100 = 8.6672408165e+02_wp
1349         EOS200 = -1.7864682637e+03_wp
1350         EOS300 = 2.0375295546e+03_wp
1351         EOS400 = -1.2849161071e+03_wp
1352         EOS500 = 4.3227585684e+02_wp
1353         EOS600 = -6.0579916612e+01_wp
1354         EOS010 = 2.6010145068e+01_wp
1355         EOS110 = -6.5281885265e+01_wp
1356         EOS210 = 8.1770425108e+01_wp
1357         EOS310 = -5.6888046321e+01_wp
1358         EOS410 = 1.7681814114e+01_wp
1359         EOS510 = -1.9193502195_wp
1360         EOS020 = -3.7074170417e+01_wp
1361         EOS120 = 6.1548258127e+01_wp
1362         EOS220 = -6.0362551501e+01_wp
1363         EOS320 = 2.9130021253e+01_wp
1364         EOS420 = -5.4723692739_wp
1365         EOS030 = 2.1661789529e+01_wp
1366         EOS130 = -3.3449108469e+01_wp
1367         EOS230 = 1.9717078466e+01_wp
1368         EOS330 = -3.1742946532_wp
1369         EOS040 = -8.3627885467_wp
1370         EOS140 = 1.1311538584e+01_wp
1371         EOS240 = -5.3563304045_wp
1372         EOS050 = 5.4048723791e-01_wp
1373         EOS150 = 4.8169980163e-01_wp
1374         EOS060 = -1.9083568888e-01_wp
1375         EOS001 = 1.9681925209e+01_wp
1376         EOS101 = -4.2549998214e+01_wp
1377         EOS201 = 5.0774768218e+01_wp
1378         EOS301 = -3.0938076334e+01_wp
1379         EOS401 = 6.6051753097_wp
1380         EOS011 = -1.3336301113e+01_wp
1381         EOS111 = -4.4870114575_wp
1382         EOS211 = 5.0042598061_wp
1383         EOS311 = -6.5399043664e-01_wp
1384         EOS021 = 6.7080479603_wp
1385         EOS121 = 3.5063081279_wp
1386         EOS221 = -1.8795372996_wp
1387         EOS031 = -2.4649669534_wp
1388         EOS131 = -5.5077101279e-01_wp
1389         EOS041 = 5.5927935970e-01_wp
1390         EOS002 = 2.0660924175_wp
1391         EOS102 = -4.9527603989_wp
1392         EOS202 = 2.5019633244_wp
1393         EOS012 = 2.0564311499_wp
1394         EOS112 = -2.1311365518e-01_wp
1395         EOS022 = -1.2419983026_wp
1396         EOS003 = -2.3342758797e-02_wp
1397         EOS103 = -1.8507636718e-02_wp
1398         EOS013 = 3.7969820455e-01_wp
1399         !
1400         ALP000 = -6.5025362670e-01_wp
1401         ALP100 = 1.6320471316_wp
1402         ALP200 = -2.0442606277_wp
1403         ALP300 = 1.4222011580_wp
1404         ALP400 = -4.4204535284e-01_wp
1405         ALP500 = 4.7983755487e-02_wp
1406         ALP010 = 1.8537085209_wp
1407         ALP110 = -3.0774129064_wp
1408         ALP210 = 3.0181275751_wp
1409         ALP310 = -1.4565010626_wp
1410         ALP410 = 2.7361846370e-01_wp
1411         ALP020 = -1.6246342147_wp
1412         ALP120 = 2.5086831352_wp
1413         ALP220 = -1.4787808849_wp
1414         ALP320 = 2.3807209899e-01_wp
1415         ALP030 = 8.3627885467e-01_wp
1416         ALP130 = -1.1311538584_wp
1417         ALP230 = 5.3563304045e-01_wp
1418         ALP040 = -6.7560904739e-02_wp
1419         ALP140 = -6.0212475204e-02_wp
1420         ALP050 = 2.8625353333e-02_wp
1421         ALP001 = 3.3340752782e-01_wp
1422         ALP101 = 1.1217528644e-01_wp
1423         ALP201 = -1.2510649515e-01_wp
1424         ALP301 = 1.6349760916e-02_wp
1425         ALP011 = -3.3540239802e-01_wp
1426         ALP111 = -1.7531540640e-01_wp
1427         ALP211 = 9.3976864981e-02_wp
1428         ALP021 = 1.8487252150e-01_wp
1429         ALP121 = 4.1307825959e-02_wp
1430         ALP031 = -5.5927935970e-02_wp
1431         ALP002 = -5.1410778748e-02_wp
1432         ALP102 = 5.3278413794e-03_wp
1433         ALP012 = 6.2099915132e-02_wp
1434         ALP003 = -9.4924551138e-03_wp
1435         !
1436         BET000 = 1.0783203594e+01_wp
1437         BET100 = -4.4452095908e+01_wp
1438         BET200 = 7.6048755820e+01_wp
1439         BET300 = -6.3944280668e+01_wp
1440         BET400 = 2.6890441098e+01_wp
1441         BET500 = -4.5221697773_wp
1442         BET010 = -8.1219372432e-01_wp
1443         BET110 = 2.0346663041_wp
1444         BET210 = -2.1232895170_wp
1445         BET310 = 8.7994140485e-01_wp
1446         BET410 = -1.1939638360e-01_wp
1447         BET020 = 7.6574242289e-01_wp
1448         BET120 = -1.5019813020_wp
1449         BET220 = 1.0872489522_wp
1450         BET320 = -2.7233429080e-01_wp
1451         BET030 = -4.1615152308e-01_wp
1452         BET130 = 4.9061350869e-01_wp
1453         BET230 = -1.1847737788e-01_wp
1454         BET040 = 1.4073062708e-01_wp
1455         BET140 = -1.3327978879e-01_wp
1456         BET050 = 5.9929880134e-03_wp
1457         BET001 = -5.2937873009e-01_wp
1458         BET101 = 1.2634116779_wp
1459         BET201 = -1.1547328025_wp
1460         BET301 = 3.2870876279e-01_wp
1461         BET011 = -5.5824407214e-02_wp
1462         BET111 = 1.2451933313e-01_wp
1463         BET211 = -2.4409539932e-02_wp
1464         BET021 = 4.3623149752e-02_wp
1465         BET121 = -4.6767901790e-02_wp
1466         BET031 = -6.8523260060e-03_wp
1467         BET002 = -6.1618945251e-02_wp
1468         BET102 = 6.2255521644e-02_wp
1469         BET012 = -2.6514181169e-03_wp
1470         BET003 = -2.3025968587e-04_wp
1471         !
1472         PEN000 = -9.8409626043_wp
1473         PEN100 = 2.1274999107e+01_wp
1474         PEN200 = -2.5387384109e+01_wp
1475         PEN300 = 1.5469038167e+01_wp
1476         PEN400 = -3.3025876549_wp
1477         PEN010 = 6.6681505563_wp
1478         PEN110 = 2.2435057288_wp
1479         PEN210 = -2.5021299030_wp
1480         PEN310 = 3.2699521832e-01_wp
1481         PEN020 = -3.3540239802_wp
1482         PEN120 = -1.7531540640_wp
1483         PEN220 = 9.3976864981e-01_wp
1484         PEN030 = 1.2324834767_wp
1485         PEN130 = 2.7538550639e-01_wp
1486         PEN040 = -2.7963967985e-01_wp
1487         PEN001 = -1.3773949450_wp
1488         PEN101 = 3.3018402659_wp
1489         PEN201 = -1.6679755496_wp
1490         PEN011 = -1.3709540999_wp
1491         PEN111 = 1.4207577012e-01_wp
1492         PEN021 = 8.2799886843e-01_wp
1493         PEN002 = 1.7507069098e-02_wp
1494         PEN102 = 1.3880727538e-02_wp
1495         PEN012 = -2.8477365341e-01_wp
1496         !
1497         APE000 = -1.6670376391e-01_wp
1498         APE100 = -5.6087643219e-02_wp
1499         APE200 = 6.2553247576e-02_wp
1500         APE300 = -8.1748804580e-03_wp
1501         APE010 = 1.6770119901e-01_wp
1502         APE110 = 8.7657703198e-02_wp
1503         APE210 = -4.6988432490e-02_wp
1504         APE020 = -9.2436260751e-02_wp
1505         APE120 = -2.0653912979e-02_wp
1506         APE030 = 2.7963967985e-02_wp
1507         APE001 = 3.4273852498e-02_wp
1508         APE101 = -3.5518942529e-03_wp
1509         APE011 = -4.1399943421e-02_wp
1510         APE002 = 7.1193413354e-03_wp
1511         !
1512         BPE000 = 2.6468936504e-01_wp
1513         BPE100 = -6.3170583896e-01_wp
1514         BPE200 = 5.7736640125e-01_wp
1515         BPE300 = -1.6435438140e-01_wp
1516         BPE010 = 2.7912203607e-02_wp
1517         BPE110 = -6.2259666565e-02_wp
1518         BPE210 = 1.2204769966e-02_wp
1519         BPE020 = -2.1811574876e-02_wp
1520         BPE120 = 2.3383950895e-02_wp
1521         BPE030 = 3.4261630030e-03_wp
1522         BPE001 = 4.1079296834e-02_wp
1523         BPE101 = -4.1503681096e-02_wp
1524         BPE011 = 1.7676120780e-03_wp
1525         BPE002 = 1.7269476440e-04_wp
1526         !
1527      CASE( 0 )                        !==  polynomial EOS-80 formulation  ==!
1528         !
1529         IF(lwp) WRITE(numout,*)
1530         IF(lwp) WRITE(numout,*) '          use of EOS-80 equation of state (pot. temp. and pract. salinity)'
1531         !
1532         rdeltaS = 20._wp
1533         r1_S0  = 1._wp/40._wp
1534         r1_T0  = 1._wp/40._wp
1535         r1_Z0  = 1.e-4_wp
1536         !
1537         EOS000 = 9.5356891948e+02_wp
1538         EOS100 = 1.7136499189e+02_wp
1539         EOS200 = -3.7501039454e+02_wp
1540         EOS300 = 5.1856810420e+02_wp
1541         EOS400 = -3.7264470465e+02_wp
1542         EOS500 = 1.4302533998e+02_wp
1543         EOS600 = -2.2856621162e+01_wp
1544         EOS010 = 1.0087518651e+01_wp
1545         EOS110 = -1.3647741861e+01_wp
1546         EOS210 = 8.8478359933_wp
1547         EOS310 = -7.2329388377_wp
1548         EOS410 = 1.4774410611_wp
1549         EOS510 = 2.0036720553e-01_wp
1550         EOS020 = -2.5579830599e+01_wp
1551         EOS120 = 2.4043512327e+01_wp
1552         EOS220 = -1.6807503990e+01_wp
1553         EOS320 = 8.3811577084_wp
1554         EOS420 = -1.9771060192_wp
1555         EOS030 = 1.6846451198e+01_wp
1556         EOS130 = -2.1482926901e+01_wp
1557         EOS230 = 1.0108954054e+01_wp
1558         EOS330 = -6.2675951440e-01_wp
1559         EOS040 = -8.0812310102_wp
1560         EOS140 = 1.0102374985e+01_wp
1561         EOS240 = -4.8340368631_wp
1562         EOS050 = 1.2079167803_wp
1563         EOS150 = 1.1515380987e-01_wp
1564         EOS060 = -2.4520288837e-01_wp
1565         EOS001 = 1.0748601068e+01_wp
1566         EOS101 = -1.7817043500e+01_wp
1567         EOS201 = 2.2181366768e+01_wp
1568         EOS301 = -1.6750916338e+01_wp
1569         EOS401 = 4.1202230403_wp
1570         EOS011 = -1.5852644587e+01_wp
1571         EOS111 = -7.6639383522e-01_wp
1572         EOS211 = 4.1144627302_wp
1573         EOS311 = -6.6955877448e-01_wp
1574         EOS021 = 9.9994861860_wp
1575         EOS121 = -1.9467067787e-01_wp
1576         EOS221 = -1.2177554330_wp
1577         EOS031 = -3.4866102017_wp
1578         EOS131 = 2.2229155620e-01_wp
1579         EOS041 = 5.9503008642e-01_wp
1580         EOS002 = 1.0375676547_wp
1581         EOS102 = -3.4249470629_wp
1582         EOS202 = 2.0542026429_wp
1583         EOS012 = 2.1836324814_wp
1584         EOS112 = -3.4453674320e-01_wp
1585         EOS022 = -1.2548163097_wp
1586         EOS003 = 1.8729078427e-02_wp
1587         EOS103 = -5.7238495240e-02_wp
1588         EOS013 = 3.8306136687e-01_wp
1589         !
1590         ALP000 = -2.5218796628e-01_wp
1591         ALP100 = 3.4119354654e-01_wp
1592         ALP200 = -2.2119589983e-01_wp
1593         ALP300 = 1.8082347094e-01_wp
1594         ALP400 = -3.6936026529e-02_wp
1595         ALP500 = -5.0091801383e-03_wp
1596         ALP010 = 1.2789915300_wp
1597         ALP110 = -1.2021756164_wp
1598         ALP210 = 8.4037519952e-01_wp
1599         ALP310 = -4.1905788542e-01_wp
1600         ALP410 = 9.8855300959e-02_wp
1601         ALP020 = -1.2634838399_wp
1602         ALP120 = 1.6112195176_wp
1603         ALP220 = -7.5817155402e-01_wp
1604         ALP320 = 4.7006963580e-02_wp
1605         ALP030 = 8.0812310102e-01_wp
1606         ALP130 = -1.0102374985_wp
1607         ALP230 = 4.8340368631e-01_wp
1608         ALP040 = -1.5098959754e-01_wp
1609         ALP140 = -1.4394226233e-02_wp
1610         ALP050 = 3.6780433255e-02_wp
1611         ALP001 = 3.9631611467e-01_wp
1612         ALP101 = 1.9159845880e-02_wp
1613         ALP201 = -1.0286156825e-01_wp
1614         ALP301 = 1.6738969362e-02_wp
1615         ALP011 = -4.9997430930e-01_wp
1616         ALP111 = 9.7335338937e-03_wp
1617         ALP211 = 6.0887771651e-02_wp
1618         ALP021 = 2.6149576513e-01_wp
1619         ALP121 = -1.6671866715e-02_wp
1620         ALP031 = -5.9503008642e-02_wp
1621         ALP002 = -5.4590812035e-02_wp
1622         ALP102 = 8.6134185799e-03_wp
1623         ALP012 = 6.2740815484e-02_wp
1624         ALP003 = -9.5765341718e-03_wp
1625         !
1626         BET000 = 2.1420623987_wp
1627         BET100 = -9.3752598635_wp
1628         BET200 = 1.9446303907e+01_wp
1629         BET300 = -1.8632235232e+01_wp
1630         BET400 = 8.9390837485_wp
1631         BET500 = -1.7142465871_wp
1632         BET010 = -1.7059677327e-01_wp
1633         BET110 = 2.2119589983e-01_wp
1634         BET210 = -2.7123520642e-01_wp
1635         BET310 = 7.3872053057e-02_wp
1636         BET410 = 1.2522950346e-02_wp
1637         BET020 = 3.0054390409e-01_wp
1638         BET120 = -4.2018759976e-01_wp
1639         BET220 = 3.1429341406e-01_wp
1640         BET320 = -9.8855300959e-02_wp
1641         BET030 = -2.6853658626e-01_wp
1642         BET130 = 2.5272385134e-01_wp
1643         BET230 = -2.3503481790e-02_wp
1644         BET040 = 1.2627968731e-01_wp
1645         BET140 = -1.2085092158e-01_wp
1646         BET050 = 1.4394226233e-03_wp
1647         BET001 = -2.2271304375e-01_wp
1648         BET101 = 5.5453416919e-01_wp
1649         BET201 = -6.2815936268e-01_wp
1650         BET301 = 2.0601115202e-01_wp
1651         BET011 = -9.5799229402e-03_wp
1652         BET111 = 1.0286156825e-01_wp
1653         BET211 = -2.5108454043e-02_wp
1654         BET021 = -2.4333834734e-03_wp
1655         BET121 = -3.0443885826e-02_wp
1656         BET031 = 2.7786444526e-03_wp
1657         BET002 = -4.2811838287e-02_wp
1658         BET102 = 5.1355066072e-02_wp
1659         BET012 = -4.3067092900e-03_wp
1660         BET003 = -7.1548119050e-04_wp
1661         !
1662         PEN000 = -5.3743005340_wp
1663         PEN100 = 8.9085217499_wp
1664         PEN200 = -1.1090683384e+01_wp
1665         PEN300 = 8.3754581690_wp
1666         PEN400 = -2.0601115202_wp
1667         PEN010 = 7.9263222935_wp
1668         PEN110 = 3.8319691761e-01_wp
1669         PEN210 = -2.0572313651_wp
1670         PEN310 = 3.3477938724e-01_wp
1671         PEN020 = -4.9997430930_wp
1672         PEN120 = 9.7335338937e-02_wp
1673         PEN220 = 6.0887771651e-01_wp
1674         PEN030 = 1.7433051009_wp
1675         PEN130 = -1.1114577810e-01_wp
1676         PEN040 = -2.9751504321e-01_wp
1677         PEN001 = -6.9171176978e-01_wp
1678         PEN101 = 2.2832980419_wp
1679         PEN201 = -1.3694684286_wp
1680         PEN011 = -1.4557549876_wp
1681         PEN111 = 2.2969116213e-01_wp
1682         PEN021 = 8.3654420645e-01_wp
1683         PEN002 = -1.4046808820e-02_wp
1684         PEN102 = 4.2928871430e-02_wp
1685         PEN012 = -2.8729602515e-01_wp
1686         !
1687         APE000 = -1.9815805734e-01_wp
1688         APE100 = -9.5799229402e-03_wp
1689         APE200 = 5.1430784127e-02_wp
1690         APE300 = -8.3694846809e-03_wp
1691         APE010 = 2.4998715465e-01_wp
1692         APE110 = -4.8667669469e-03_wp
1693         APE210 = -3.0443885826e-02_wp
1694         APE020 = -1.3074788257e-01_wp
1695         APE120 = 8.3359333577e-03_wp
1696         APE030 = 2.9751504321e-02_wp
1697         APE001 = 3.6393874690e-02_wp
1698         APE101 = -5.7422790533e-03_wp
1699         APE011 = -4.1827210323e-02_wp
1700         APE002 = 7.1824006288e-03_wp
1701         !
1702         BPE000 = 1.1135652187e-01_wp
1703         BPE100 = -2.7726708459e-01_wp
1704         BPE200 = 3.1407968134e-01_wp
1705         BPE300 = -1.0300557601e-01_wp
1706         BPE010 = 4.7899614701e-03_wp
1707         BPE110 = -5.1430784127e-02_wp
1708         BPE210 = 1.2554227021e-02_wp
1709         BPE020 = 1.2166917367e-03_wp
1710         BPE120 = 1.5221942913e-02_wp
1711         BPE030 = -1.3893222263e-03_wp
1712         BPE001 = 2.8541225524e-02_wp
1713         BPE101 = -3.4236710714e-02_wp
1714         BPE011 = 2.8711395266e-03_wp
1715         BPE002 = 5.3661089288e-04_wp
1716         !
1717      CASE( 1 )                        !==  Simplified EOS     ==!
1718         IF(lwp) THEN
1719            WRITE(numout,*)
1720            WRITE(numout,*) '          use of simplified eos:    rhd(dT=T-10,dS=S-35,Z) = '
1721            WRITE(numout,*) '             [-a0*(1+lambda1/2*dT+mu1*Z)*dT + b0*(1+lambda2/2*dT+mu2*Z)*dS - nu*dT*dS]/rau0'
1722            WRITE(numout,*)
1723            WRITE(numout,*) '             thermal exp. coef.    rn_a0      = ', rn_a0
1724            WRITE(numout,*) '             saline  cont. coef.   rn_b0      = ', rn_b0
1725            WRITE(numout,*) '             cabbeling coef.       rn_lambda1 = ', rn_lambda1
1726            WRITE(numout,*) '             cabbeling coef.       rn_lambda2 = ', rn_lambda2
1727            WRITE(numout,*) '             thermobar. coef.      rn_mu1     = ', rn_mu1
1728            WRITE(numout,*) '             thermobar. coef.      rn_mu2     = ', rn_mu2
1729            WRITE(numout,*) '             2nd cabbel. coef.     rn_nu      = ', rn_nu
1730            WRITE(numout,*) '               Caution: rn_beta0=0 incompatible with ddm parameterization '
1731         ENDIF
1732         !
1733      CASE DEFAULT                     !==  ERROR in nn_eos  ==!
1734         WRITE(ctmp1,*) '          bad flag value for nn_eos = ', nn_eos
1735         CALL ctl_stop( ctmp1 )
1736         !
1737      END SELECT
1738      !
1739      rau0_rcp    = rau0 * rcp 
1740      r1_rau0     = 1._wp / rau0
1741      r1_rcp      = 1._wp / rcp
1742      r1_rau0_rcp = 1._wp / rau0_rcp 
1743      !
1744      IF(lwp) WRITE(numout,*)
1745      IF(lwp) WRITE(numout,*) '          volumic mass of reference           rau0  = ', rau0   , ' kg/m^3'
1746      IF(lwp) WRITE(numout,*) '          1. / rau0                        r1_rau0  = ', r1_rau0, ' m^3/kg'
1747      IF(lwp) WRITE(numout,*) '          ocean specific heat                 rcp   = ', rcp    , ' J/Kelvin'
1748      IF(lwp) WRITE(numout,*) '          rau0 * rcp                       rau0_rcp = ', rau0_rcp
1749      IF(lwp) WRITE(numout,*) '          1. / ( rau0 * rcp )           r1_rau0_rcp = ', r1_rau0_rcp
1750      !
1751   END SUBROUTINE eos_init
1752
1753   !!======================================================================
1754END MODULE eosbn2
Note: See TracBrowser for help on using the repository browser.