source: branches/UKMO/2014_Surge_Modelling/NEMOGCM/NEMO/OPA_SRC/DOM/istate.F90 @ 4708

Last change on this file since 4708 was 4708, checked in by rfurner, 7 years ago

changes to remove tracer modules and produce barotropic model

  • Property svn:keywords set to Id
File size: 26.8 KB
Line 
1MODULE istate
2   !!======================================================================
3   !!                     ***  MODULE  istate  ***
4   !! Ocean state   :  initial state setting
5   !!=====================================================================
6   !! History :  OPA  !  1989-12  (P. Andrich)  Original code
7   !!            5.0  !  1991-11  (G. Madec)  rewritting
8   !!            6.0  !  1996-01  (G. Madec)  terrain following coordinates
9   !!            8.0  !  2001-09  (M. Levy, M. Ben Jelloul)  istate_eel
10   !!            8.0  !  2001-09  (M. Levy, M. Ben Jelloul)  istate_uvg
11   !!   NEMO     1.0  !  2003-08  (G. Madec, C. Talandier)  F90: Free form, modules + EEL R5
12   !!             -   !  2004-05  (A. Koch-Larrouy)  istate_gyre
13   !!            2.0  !  2006-07  (S. Masson)  distributed restart using iom
14   !!            3.3  !  2010-10  (C. Ethe) merge TRC-TRA
15   !!            3.4  !  2011-04  (G. Madec) Merge of dtatem and dtasal & suppression of tb,tn/sb,sn
16   !!----------------------------------------------------------------------
17
18   !!----------------------------------------------------------------------
19   !!   istate_init   : initial state setting
20   !!   istate_tem    : analytical profile for initial Temperature
21   !!   istate_sal    : analytical profile for initial Salinity
22   !!   istate_eel    : initial state setting of EEL R5 configuration
23   !!   istate_gyre   : initial state setting of GYRE configuration
24   !!   istate_uvg    : initial velocity in geostropic balance
25   !!----------------------------------------------------------------------
26   USE oce             ! ocean dynamics and active tracers
27   USE dom_oce         ! ocean space and time domain
28   USE c1d             ! 1D vertical configuration
29   USE daymod          ! calendar
30   USE eosbn2          ! eq. of state, Brunt Vaisala frequency (eos     routine)
31   USE ldftra_oce      ! ocean active tracers: lateral physics
32   USE zdf_oce         ! ocean vertical physics
33   USE phycst          ! physical constants
34   USE dtatsd          ! data temperature and salinity   (dta_tsd routine)
35   USE dtauvd          ! data: U & V current             (dta_uvd routine)
36   USE in_out_manager  ! I/O manager
37   USE iom             ! I/O library
38   USE zpshde          ! partial step: hor. derivative (zps_hde routine)
39   USE eosbn2          ! equation of state            (eos bn2 routine)
40   USE domvvl          ! varying vertical mesh
41   USE dynspg_oce      ! pressure gradient schemes
42   USE dynspg_flt      ! filtered free surface
43   USE sol_oce         ! ocean solver variables
44   USE lib_mpp         ! MPP library
45   USE restart         ! restart
46   USE wrk_nemo        ! Memory allocation
47   USE timing          ! Timing
48
49   IMPLICIT NONE
50   PRIVATE
51
52   PUBLIC   istate_init   ! routine called by step.F90
53
54   !! * Substitutions
55#  include "domzgr_substitute.h90"
56#  include "vectopt_loop_substitute.h90"
57   !!----------------------------------------------------------------------
58   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
59   !! $Id$
60   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
61   !!----------------------------------------------------------------------
62CONTAINS
63
64   SUBROUTINE istate_init
65      !!----------------------------------------------------------------------
66      !!                   ***  ROUTINE istate_init  ***
67      !!
68      !! ** Purpose :   Initialization of the dynamics and tracer fields.
69      !!----------------------------------------------------------------------
70      ! - ML - needed for initialization of e3t_b
71      INTEGER  ::  ji,jj,jk     ! dummy loop indices
72      REAL(wp), POINTER, DIMENSION(:,:,:,:)  ::  zuvd    ! U & V data workspace
73      !!----------------------------------------------------------------------
74      !
75      IF( nn_timing == 1 )  CALL timing_start('istate_init')
76      !
77
78      IF(lwp) WRITE(numout,*)
79      IF(lwp) WRITE(numout,*) 'istate_ini : Initialization of the dynamics and tracers'
80      IF(lwp) WRITE(numout,*) '~~~~~~~~~~'
81
82      CALL dta_tsd_init                       ! Initialisation of T & S input data
83      IF( lk_c1d ) CALL dta_uvd_init          ! Initialization of U & V input data
84
85      rhd  (:,:,:  ) = 0.e0
86      rhop (:,:,:  ) = 0.e0
87      rn2  (:,:,:  ) = 0.e0 
88      tsa  (:,:,:,:) = 0.e0   
89
90      IF( ln_rstart ) THEN                    ! Restart from a file
91         !                                    ! -------------------
92         CALL rst_read                           ! Read the restart file
93         CALL day_init                           ! model calendar (using both namelist and restart infos)
94      ELSE
95         !                                    ! Start from rest
96         !                                    ! ---------------
97         numror = 0                              ! define numror = 0 -> no restart file to read
98         neuler = 0                              ! Set time-step indicator at nit000 (euler forward)
99         CALL day_init                           ! model calendar (using both namelist and restart infos)
100         !                                       ! Initialization of ocean to zero
101         !   before fields      !       now fields     
102         sshb (:,:)   = 0._wp   ;   sshn (:,:)   = 0._wp
103         ub   (:,:,:) = 0._wp   ;   un   (:,:,:) = 0._wp
104         vb   (:,:,:) = 0._wp   ;   vn   (:,:,:) = 0._wp 
105         rotb (:,:,:) = 0._wp   ;   rotn (:,:,:) = 0._wp
106         hdivb(:,:,:) = 0._wp   ;   hdivn(:,:,:) = 0._wp
107         !
108         IF( cp_cfg == 'eel' ) THEN
109            CALL istate_eel                      ! EEL   configuration : start from pre-defined U,V T-S fields
110         ELSEIF( cp_cfg == 'gyre' ) THEN         
111            CALL istate_gyre                     ! GYRE  configuration : start from pre-defined T-S fields
112         ELSE                                    ! Initial T-S, U-V fields read in files
113            IF ( ln_tsd_init ) THEN              ! read 3D T and S data at nit000
114               CALL dta_tsd( nit000, tsb ) 
115               tsn(:,:,:,:) = tsb(:,:,:,:)
116               !
117            ELSE                                 ! Initial T-S fields defined analytically
118               CALL istate_t_s
119            ENDIF
120            IF ( ln_uvd_init .AND. lk_c1d ) THEN ! read 3D U and V data at nit000
121               CALL wrk_alloc( jpi, jpj, jpk, 2, zuvd )
122               CALL dta_uvd( nit000, zuvd )
123               ub(:,:,:) = zuvd(:,:,:,1) ;  un(:,:,:) = ub(:,:,:)
124               vb(:,:,:) = zuvd(:,:,:,2) ;  vn(:,:,:) = vb(:,:,:)
125               CALL wrk_dealloc( jpi, jpj, jpk, 2, zuvd )
126            ENDIF
127         ENDIF
128         !
129         CALL eos( tsb, rhd, rhop, gdept_0(:,:,:) )        ! before potential and in situ densities
130#if ! defined key_c1d
131         IF( ln_zps )   CALL zps_hde( nit000, jpts, tsb, gtsu, gtsv,  & ! zps: before hor. gradient
132            &                                       rhd, gru , grv  )   ! of t,s,rd at ocean bottom
133#endif
134         !   
135         ! - ML - sshn could be modified by istate_eel, so that initialization of fse3t_b is done here
136         IF( lk_vvl ) THEN
137            DO jk = 1, jpk
138               fse3t_b(:,:,jk) = fse3t_n(:,:,jk)
139            ENDDO
140         ENDIF
141         !
142      ENDIF
143      !
144      IF( lk_agrif ) THEN                  ! read free surface arrays in restart file
145         IF( ln_rstart ) THEN
146            IF( lk_dynspg_flt )  THEN      ! read or initialize the following fields
147               !                           ! gcx, gcxb for agrif_opa_init
148               IF( sol_oce_alloc()  > 0 )   CALL ctl_stop('agrif sol_oce_alloc: allocation of arrays failed')
149               CALL flt_rst( nit000, 'READ' )
150            ENDIF
151         ENDIF                             ! explicit case not coded yet with AGRIF
152      ENDIF
153      !
154      !
155      ! Initialize "now" and "before" barotropic velocities:
156      ! Do it whatever the free surface method, these arrays
157      ! being eventually used
158      !
159      !
160      un_b(:,:) = 0._wp ; vn_b(:,:) = 0._wp
161      ub_b(:,:) = 0._wp ; vb_b(:,:) = 0._wp
162      !
163      DO jk = 1, jpkm1
164#if defined key_vectopt_loop
165         DO jj = 1, 1         !Vector opt. => forced unrolling
166            DO ji = 1, jpij
167#else
168         DO jj = 1, jpj
169            DO ji = 1, jpi
170#endif                 
171               un_b(ji,jj) = un_b(ji,jj) + fse3u_n(ji,jj,jk) * un(ji,jj,jk) * umask(ji,jj,jk)
172               vn_b(ji,jj) = vn_b(ji,jj) + fse3v_n(ji,jj,jk) * vn(ji,jj,jk) * vmask(ji,jj,jk)
173               !
174               ub_b(ji,jj) = ub_b(ji,jj) + fse3u_b(ji,jj,jk) * ub(ji,jj,jk) * umask(ji,jj,jk)
175               vb_b(ji,jj) = vb_b(ji,jj) + fse3v_b(ji,jj,jk) * vb(ji,jj,jk) * vmask(ji,jj,jk)
176            END DO
177         END DO
178      END DO
179      !
180      un_b(:,:) = un_b(:,:) * hur  (:,:)
181      vn_b(:,:) = vn_b(:,:) * hvr  (:,:)
182      !
183      ub_b(:,:) = ub_b(:,:) * hur_b(:,:)
184      vb_b(:,:) = vb_b(:,:) * hvr_b(:,:)
185      !
186      !
187      IF( nn_timing == 1 )  CALL timing_stop('istate_init')
188      !
189   END SUBROUTINE istate_init
190
191   SUBROUTINE istate_t_s
192      !!---------------------------------------------------------------------
193      !!                  ***  ROUTINE istate_t_s  ***
194      !!   
195      !! ** Purpose :   Intialization of the temperature field with an
196      !!      analytical profile or a file (i.e. in EEL configuration)
197      !!
198      !! ** Method  : - temperature: use Philander analytic profile
199      !!              - salinity   : use to a constant value 35.5
200      !!
201      !! References :  Philander ???
202      !!----------------------------------------------------------------------
203      INTEGER  :: ji, jj, jk
204      REAL(wp) ::   zsal = 35.50
205#if defined key_surge
206      REAL(wp) ::   ztem = 10.0
207#endif
208      !!----------------------------------------------------------------------
209      !
210      IF(lwp) WRITE(numout,*)
211      IF(lwp) WRITE(numout,*) 'istate_t_s : Philander s initial temperature profile'
212      IF(lwp) WRITE(numout,*) '~~~~~~~~~~   and constant salinity (',zsal,' psu)'
213      !
214#if defined key_surge
215      tsn(:,:,:,jp_tem) = ztem * tmask(:,:,:)
216      tsb(:,:,:,jp_tem) = tsn(:,:,:,jp_tem)
217#else
218      DO jk = 1, jpk
219         tsn(:,:,jk,jp_tem) = (  ( ( 7.5 - 0. * ABS( gphit(:,:) )/30. ) * ( 1.-TANH((fsdept(:,:,jk)-80.)/30.) )   &
220            &                + 10. * ( 5000. - fsdept(:,:,jk) ) /5000.)  ) * tmask(:,:,jk)
221         tsb(:,:,jk,jp_tem) = tsn(:,:,jk,jp_tem)
222      END DO
223#endif
224      tsn(:,:,:,jp_sal) = zsal * tmask(:,:,:)
225      tsb(:,:,:,jp_sal) = tsn(:,:,:,jp_sal)
226      !
227   END SUBROUTINE istate_t_s
228
229   SUBROUTINE istate_eel
230      !!----------------------------------------------------------------------
231      !!                   ***  ROUTINE istate_eel  ***
232      !!
233      !! ** Purpose :   Initialization of the dynamics and tracers for EEL R5
234      !!      configuration (channel with or without a topographic bump)
235      !!
236      !! ** Method  : - set temprature field
237      !!              - set salinity field
238      !!              - set velocity field including horizontal divergence
239      !!                and relative vorticity fields
240      !!----------------------------------------------------------------------
241      USE divcur     ! hor. divergence & rel. vorticity      (div_cur routine)
242      USE iom
243 
244      INTEGER  ::   inum              ! temporary logical unit
245      INTEGER  ::   ji, jj, jk        ! dummy loop indices
246      INTEGER  ::   ijloc
247      REAL(wp) ::   zh1, zh2, zslope, zcst, zfcor   ! temporary scalars
248      REAL(wp) ::   zt1  = 15._wp                   ! surface temperature value (EEL R5)
249      REAL(wp) ::   zt2  =  5._wp                   ! bottom  temperature value (EEL R5)
250      REAL(wp) ::   zsal = 35.0_wp                  ! constant salinity (EEL R2, R5 and R6)
251      REAL(wp) ::   zueel = 0.1_wp                  ! constant uniform zonal velocity (EEL R5)
252      REAL(wp), DIMENSION(jpiglo,jpjglo) ::   zssh  ! initial ssh over the global domain
253      !!----------------------------------------------------------------------
254
255      SELECT CASE ( jp_cfg ) 
256         !                                              ! ====================
257         CASE ( 5 )                                     ! EEL R5 configuration
258            !                                           ! ====================
259            !
260            ! set temperature field with a linear profile
261            ! -------------------------------------------
262            IF(lwp) WRITE(numout,*)
263            IF(lwp) WRITE(numout,*) 'istate_eel : EEL R5: linear temperature profile'
264            IF(lwp) WRITE(numout,*) '~~~~~~~~~~'
265            !
266            zh1 = gdept_1d(  1  )
267            zh2 = gdept_1d(jpkm1)
268            !
269            zslope = ( zt1 - zt2 ) / ( zh1 - zh2 )
270            zcst   = ( zt1 * ( zh1 - zh2) - ( zt1 - zt2 ) * zh1 ) / ( zh1 - zh2 )
271            !
272            DO jk = 1, jpk
273               tsn(:,:,jk,jp_tem) = ( zt2 + zt1 * exp( - fsdept(:,:,jk) / 1000 ) ) * tmask(:,:,jk)
274               tsb(:,:,jk,jp_tem) = tsn(:,:,jk,jp_tem)
275            END DO
276            !
277            IF(lwp) CALL prizre( tsn(:,:,:,jp_tem), jpi   , jpj   , jpk   , jpj/2 ,   &
278               &                             1     , jpi   , 5     , 1     , jpk   ,   &
279               &                             1     , 1.    , numout                  )
280            !
281            ! set salinity field to a constant value
282            ! --------------------------------------
283            IF(lwp) WRITE(numout,*)
284            IF(lwp) WRITE(numout,*) 'istate_eel : EEL R5: constant salinity field, S = ', zsal
285            IF(lwp) WRITE(numout,*) '~~~~~~~~~~'
286            !
287            tsn(:,:,:,jp_sal) = zsal * tmask(:,:,:)
288            tsb(:,:,:,jp_sal) = tsn(:,:,:,jp_sal)
289            !
290            ! set the dynamics: U,V, hdiv, rot (and ssh if necessary)
291            ! ----------------
292            ! Start EEL5 configuration with barotropic geostrophic velocities
293            ! according the sshb and sshn SSH imposed.
294            ! we assume a uniform grid (hence the use of e1t(1,1) for delta_y)
295            ! we use the Coriolis frequency at mid-channel.   
296            ub(:,:,:) = zueel * umask(:,:,:)
297            un(:,:,:) = ub(:,:,:)
298            ijloc = mj0(INT(jpjglo-1)/2)
299            zfcor = ff(1,ijloc)
300            !
301            DO jj = 1, jpjglo
302               zssh(:,jj) = - (FLOAT(jj)- FLOAT(jpjglo-1)/2.)*zueel*e1t(1,1)*zfcor/grav 
303            END DO
304            !
305            IF(lwp) THEN
306               WRITE(numout,*) ' Uniform zonal velocity for EEL R5:',zueel
307               WRITE(numout,*) ' Geostrophic SSH profile as a function of y:'
308               WRITE(numout,'(12(1x,f6.2))') zssh(1,:)
309            ENDIF
310            !
311            DO jj = 1, nlcj
312               DO ji = 1, nlci
313                  sshb(ji,jj) = zssh( mig(ji) , mjg(jj) ) * tmask(ji,jj,1)
314               END DO
315            END DO
316            sshb(nlci+1:jpi,      :   ) = 0.e0      ! set to zero extra mpp columns
317            sshb(      :   ,nlcj+1:jpj) = 0.e0      ! set to zero extra mpp rows
318            !
319            sshn(:,:) = sshb(:,:)                   ! set now ssh to the before value
320            !
321            IF( nn_rstssh /= 0 ) THEN 
322               nn_rstssh = 0                        ! hand-made initilization of ssh
323               CALL ctl_warn( 'istate_eel: force nn_rstssh = 0' )
324            ENDIF
325            !
326            CALL div_cur( nit000 )                  ! horizontal divergence and relative vorticity (curl)
327            ! N.B. the vertical velocity will be computed from the horizontal divergence field
328            ! in istate by a call to wzv routine
329
330
331            !                                     ! ==========================
332         CASE ( 2 , 6 )                           ! EEL R2 or R6 configuration
333            !                                     ! ==========================
334            !
335            ! set temperature field with a NetCDF file
336            ! ----------------------------------------
337            IF(lwp) WRITE(numout,*)
338            IF(lwp) WRITE(numout,*) 'istate_eel : EEL R2 or R6: read initial temperature in a NetCDF file'
339            IF(lwp) WRITE(numout,*) '~~~~~~~~~~'
340            !
341            CALL iom_open ( 'eel.initemp', inum )
342            CALL iom_get ( inum, jpdom_data, 'initemp', tsb(:,:,:,jp_tem) ) ! read before temprature (tb)
343            CALL iom_close( inum )
344            !
345            tsn(:,:,:,jp_tem) = tsb(:,:,:,jp_tem)                            ! set nox temperature to tb
346            !
347            IF(lwp) CALL prizre( tsn(:,:,:,jp_tem), jpi   , jpj   , jpk   , jpj/2 ,   &
348               &                            1     , jpi   , 5     , 1     , jpk   ,   &
349               &                            1     , 1.    , numout                  )
350            !
351            ! set salinity field to a constant value
352            ! --------------------------------------
353            IF(lwp) WRITE(numout,*)
354            IF(lwp) WRITE(numout,*) 'istate_eel : EEL R5: constant salinity field, S = ', zsal
355            IF(lwp) WRITE(numout,*) '~~~~~~~~~~'
356            !
357            tsn(:,:,:,jp_sal) = zsal * tmask(:,:,:)
358            tsb(:,:,:,jp_sal) = tsn(:,:,:,jp_sal)
359            !
360            !                                    ! ===========================
361         CASE DEFAULT                            ! NONE existing configuration
362            !                                    ! ===========================
363            WRITE(ctmp1,*) 'EEL with a ', jp_cfg,' km resolution is not coded'
364            CALL ctl_stop( ctmp1 )
365            !
366      END SELECT
367      !
368   END SUBROUTINE istate_eel
369
370
371   SUBROUTINE istate_gyre
372      !!----------------------------------------------------------------------
373      !!                   ***  ROUTINE istate_gyre  ***
374      !!
375      !! ** Purpose :   Initialization of the dynamics and tracers for GYRE
376      !!      configuration (double gyre with rotated domain)
377      !!
378      !! ** Method  : - set temprature field
379      !!              - set salinity field
380      !!----------------------------------------------------------------------
381      INTEGER :: ji, jj, jk  ! dummy loop indices
382      INTEGER            ::   inum          ! temporary logical unit
383      INTEGER, PARAMETER ::   ntsinit = 0   ! (0/1) (analytical/input data files) T&S initialization
384      !!----------------------------------------------------------------------
385
386      SELECT CASE ( ntsinit)
387
388      CASE ( 0 )                  ! analytical T/S profil deduced from LEVITUS
389         IF(lwp) WRITE(numout,*)
390         IF(lwp) WRITE(numout,*) 'istate_gyre : initial analytical T and S profil deduced from LEVITUS '
391         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
392
393         DO jk = 1, jpk
394            DO jj = 1, jpj
395               DO ji = 1, jpi
396                  tsn(ji,jj,jk,jp_tem) = (  16. - 12. * TANH( (fsdept(ji,jj,jk) - 400) / 700 )         )   &
397                       &           * (-TANH( (500-fsdept(ji,jj,jk)) / 150 ) + 1) / 2               &
398                       &       + (      15. * ( 1. - TANH( (fsdept(ji,jj,jk)-50.) / 1500.) )       &
399                       &                - 1.4 * TANH((fsdept(ji,jj,jk)-100.) / 100.)               &   
400                       &                + 7.  * (1500. - fsdept(ji,jj,jk)) / 1500.             )   & 
401                       &           * (-TANH( (fsdept(ji,jj,jk) - 500) / 150) + 1) / 2
402                  tsn(ji,jj,jk,jp_tem) = tsn(ji,jj,jk,jp_tem) * tmask(ji,jj,jk)
403                  tsb(ji,jj,jk,jp_tem) = tsn(ji,jj,jk,jp_tem)
404
405                  tsn(ji,jj,jk,jp_sal) =  (  36.25 - 1.13 * TANH( (fsdept(ji,jj,jk) - 305) / 460 )  )  &
406                     &              * (-TANH((500 - fsdept(ji,jj,jk)) / 150) + 1) / 2          &
407                     &          + (  35.55 + 1.25 * (5000. - fsdept(ji,jj,jk)) / 5000.         &
408                     &                - 1.62 * TANH( (fsdept(ji,jj,jk) - 60.  ) / 650. )       &
409                     &                + 0.2  * TANH( (fsdept(ji,jj,jk) - 35.  ) / 100. )       &
410                     &                + 0.2  * TANH( (fsdept(ji,jj,jk) - 1000.) / 5000.)    )  &
411                     &              * (-TANH((fsdept(ji,jj,jk) - 500) / 150) + 1) / 2 
412                  tsn(ji,jj,jk,jp_sal) = tsn(ji,jj,jk,jp_sal) * tmask(ji,jj,jk)
413                  tsb(ji,jj,jk,jp_sal) = tsn(ji,jj,jk,jp_sal)
414               END DO
415            END DO
416         END DO
417
418      CASE ( 1 )                  ! T/S data fields read in dta_tem.nc/data_sal.nc files
419         IF(lwp) WRITE(numout,*)
420         IF(lwp) WRITE(numout,*) 'istate_gyre : initial T and S read from dta_tem.nc/data_sal.nc files'
421         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
422         IF(lwp) WRITE(numout,*) '              NetCDF FORMAT'
423
424         ! Read temperature field
425         ! ----------------------
426         CALL iom_open ( 'data_tem', inum )
427         CALL iom_get ( inum, jpdom_data, 'votemper', tsn(:,:,:,jp_tem) ) 
428         CALL iom_close( inum )
429
430         tsn(:,:,:,jp_tem) = tsn(:,:,:,jp_tem) * tmask(:,:,:) 
431         tsb(:,:,:,jp_tem) = tsn(:,:,:,jp_tem)
432
433         ! Read salinity field
434         ! -------------------
435         CALL iom_open ( 'data_sal', inum )
436         CALL iom_get ( inum, jpdom_data, 'vosaline', tsn(:,:,:,jp_sal) ) 
437         CALL iom_close( inum )
438
439         tsn(:,:,:,jp_sal) = tsn(:,:,:,jp_sal) * tmask(:,:,:) 
440         tsb(:,:,:,jp_sal) = tsn(:,:,:,jp_sal)
441
442      END SELECT
443
444      IF(lwp) THEN
445         WRITE(numout,*)
446         WRITE(numout,*) '              Initial temperature and salinity profiles:'
447         WRITE(numout, "(9x,' level   gdept_1d   temperature   salinity   ')" )
448         WRITE(numout, "(10x, i4, 3f10.2)" ) ( jk, gdept_1d(jk), tsn(2,2,jk,jp_tem), tsn(2,2,jk,jp_sal), jk = 1, jpk )
449      ENDIF
450
451   END SUBROUTINE istate_gyre
452
453   SUBROUTINE istate_uvg
454      !!----------------------------------------------------------------------
455      !!                  ***  ROUTINE istate_uvg  ***
456      !!
457      !! ** Purpose :   Compute the geostrophic velocities from (tn,sn) fields
458      !!
459      !! ** Method  :   Using the hydrostatic hypothesis the now hydrostatic
460      !!      pressure is computed by integrating the in-situ density from the
461      !!      surface to the bottom.
462      !!                 p=integral [ rau*g dz ]
463      !!----------------------------------------------------------------------
464      USE dynspg          ! surface pressure gradient             (dyn_spg routine)
465      USE divcur          ! hor. divergence & rel. vorticity      (div_cur routine)
466      USE lbclnk          ! ocean lateral boundary condition (or mpp link)
467
468      INTEGER ::   ji, jj, jk        ! dummy loop indices
469      INTEGER ::   indic             ! ???
470      REAL(wp) ::   zmsv, zphv, zmsu, zphu, zalfg     ! temporary scalars
471      REAL(wp), POINTER, DIMENSION(:,:,:) :: zprn
472      !!----------------------------------------------------------------------
473      !
474      CALL wrk_alloc( jpi, jpj, jpk, zprn)
475      !
476      IF(lwp) WRITE(numout,*) 
477      IF(lwp) WRITE(numout,*) 'istate_uvg : Start from Geostrophy'
478      IF(lwp) WRITE(numout,*) '~~~~~~~~~~'
479
480      ! Compute the now hydrostatic pressure
481      ! ------------------------------------
482
483      zalfg = 0.5 * grav * rau0
484     
485      zprn(:,:,1) = zalfg * fse3w(:,:,1) * ( 1 + rhd(:,:,1) )       ! Surface value
486
487      DO jk = 2, jpkm1                                              ! Vertical integration from the surface
488         zprn(:,:,jk) = zprn(:,:,jk-1)   &
489            &         + zalfg * fse3w(:,:,jk) * ( 2. + rhd(:,:,jk) + rhd(:,:,jk-1) )
490      END DO 
491
492      ! Compute geostrophic balance
493      ! ---------------------------
494      DO jk = 1, jpkm1
495         DO jj = 2, jpjm1
496            DO ji = fs_2, fs_jpim1   ! vertor opt.
497               zmsv = 1. / MAX(  umask(ji-1,jj+1,jk) + umask(ji  ,jj+1,jk)   &
498                               + umask(ji-1,jj  ,jk) + umask(ji  ,jj  ,jk) , 1.  )
499               zphv = ( zprn(ji  ,jj+1,jk) - zprn(ji-1,jj+1,jk) ) * umask(ji-1,jj+1,jk) / e1u(ji-1,jj+1)   &
500                    + ( zprn(ji+1,jj+1,jk) - zprn(ji  ,jj+1,jk) ) * umask(ji  ,jj+1,jk) / e1u(ji  ,jj+1)   &
501                    + ( zprn(ji  ,jj  ,jk) - zprn(ji-1,jj  ,jk) ) * umask(ji-1,jj  ,jk) / e1u(ji-1,jj  )   &
502                    + ( zprn(ji+1,jj  ,jk) - zprn(ji  ,jj  ,jk) ) * umask(ji  ,jj  ,jk) / e1u(ji  ,jj  )
503               zphv = 1. / rau0 * zphv * zmsv * vmask(ji,jj,jk)
504
505               zmsu = 1. / MAX(  vmask(ji+1,jj  ,jk) + vmask(ji  ,jj  ,jk)   &
506                               + vmask(ji+1,jj-1,jk) + vmask(ji  ,jj-1,jk) , 1.  )
507               zphu = ( zprn(ji+1,jj+1,jk) - zprn(ji+1,jj  ,jk) ) * vmask(ji+1,jj  ,jk) / e2v(ji+1,jj  )   &
508                    + ( zprn(ji  ,jj+1,jk) - zprn(ji  ,jj  ,jk) ) * vmask(ji  ,jj  ,jk) / e2v(ji  ,jj  )   &
509                    + ( zprn(ji+1,jj  ,jk) - zprn(ji+1,jj-1,jk) ) * vmask(ji+1,jj-1,jk) / e2v(ji+1,jj-1)   &
510                    + ( zprn(ji  ,jj  ,jk) - zprn(ji  ,jj-1,jk) ) * vmask(ji  ,jj-1,jk) / e2v(ji  ,jj-1)
511               zphu = 1. / rau0 * zphu * zmsu * umask(ji,jj,jk)
512
513               ! Compute the geostrophic velocities
514               un(ji,jj,jk) = -2. * zphu / ( ff(ji,jj) + ff(ji  ,jj-1) )
515               vn(ji,jj,jk) =  2. * zphv / ( ff(ji,jj) + ff(ji-1,jj  ) )
516            END DO
517         END DO
518      END DO
519
520      IF(lwp) WRITE(numout,*) '         we force to zero bottom velocity'
521
522      ! Susbtract the bottom velocity (level jpk-1 for flat bottom case)
523      ! to have a zero bottom velocity
524
525      DO jk = 1, jpkm1
526         un(:,:,jk) = ( un(:,:,jk) - un(:,:,jpkm1) ) * umask(:,:,jk)
527         vn(:,:,jk) = ( vn(:,:,jk) - vn(:,:,jpkm1) ) * vmask(:,:,jk)
528      END DO
529
530      CALL lbc_lnk( un, 'U', -1. )
531      CALL lbc_lnk( vn, 'V', -1. )
532     
533      ub(:,:,:) = un(:,:,:)
534      vb(:,:,:) = vn(:,:,:)
535     
536      ! WARNING !!!!!
537      ! after initializing u and v, we need to calculate the initial streamfunction bsf.
538      ! Otherwise, only the trend will be computed and the model will blow up (inconsistency).
539      ! to do that, we call dyn_spg with a special trick:
540      ! we fill ua and va with the velocities divided by dt, and the streamfunction will be brought to the
541      ! right value assuming the velocities have been set up in one time step.
542      ! we then set bsfd to zero (first guess for next step is d(psi)/dt = 0.)
543      !  sets up s false trend to calculate the barotropic streamfunction.
544
545      ua(:,:,:) = ub(:,:,:) / rdt
546      va(:,:,:) = vb(:,:,:) / rdt
547
548      ! calls dyn_spg. we assume euler time step, starting from rest.
549      indic = 0
550      CALL dyn_spg( nit000, indic )       ! surface pressure gradient
551
552      ! the new velocity is ua*rdt
553
554      CALL lbc_lnk( ua, 'U', -1. )
555      CALL lbc_lnk( va, 'V', -1. )
556
557      ub(:,:,:) = ua(:,:,:) * rdt
558      vb(:,:,:) = va(:,:,:) * rdt
559      ua(:,:,:) = 0.e0
560      va(:,:,:) = 0.e0
561      un(:,:,:) = ub(:,:,:)
562      vn(:,:,:) = vb(:,:,:)
563       
564      ! Compute the divergence and curl
565
566      CALL div_cur( nit000 )            ! now horizontal divergence and curl
567
568      hdivb(:,:,:) = hdivn(:,:,:)       ! set the before to the now value
569      rotb (:,:,:) = rotn (:,:,:)       ! set the before to the now value
570      !
571      CALL wrk_dealloc( jpi, jpj, jpk, zprn)
572      !
573   END SUBROUTINE istate_uvg
574
575   !!=====================================================================
576END MODULE istate
577
Note: See TracBrowser for help on using the repository browser.