source: branches/UKMO/2014_Surge_Modelling/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 4708

Last change on this file since 4708 was 4708, checked in by rfurner, 7 years ago

changes to remove tracer modules and produce barotropic model

  • Property svn:keywords set to Id
File size: 38.9 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  LIM sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!            3.4  ! 2011-11  (C. Harris) decomposition changes for running with CICE
31   !!                 ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32   !!----------------------------------------------------------------------
33
34   !!----------------------------------------------------------------------
35   !!   nemo_gcm       : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
36   !!   nemo_init      : initialization of the NEMO system
37   !!   nemo_ctl       : initialisation of the contol print
38   !!   nemo_closefile : close remaining open files
39   !!   nemo_alloc     : dynamical allocation
40   !!   nemo_partition : calculate MPP domain decomposition
41   !!   factorise      : calculate the factors of the no. of MPI processes
42   !!----------------------------------------------------------------------
43   USE step_oce        ! module used in the ocean time stepping module
44   USE sbc_oce         ! surface boundary condition: ocean
45   USE cla             ! cross land advection               (tra_cla routine)
46   USE domcfg          ! domain configuration               (dom_cfg routine)
47   USE mppini          ! shared/distributed memory setting (mpp_init routine)
48   USE domain          ! domain initialization             (dom_init routine)
49#if defined key_nemocice_decomp
50   USE ice_domain_size, only: nx_global, ny_global
51#endif
52   USE tideini         ! tidal components initialization   (tide_ini routine)
53   USE bdyini          ! open boundary cond. initialization (bdy_init routine)
54   USE bdydta          ! open boundary cond. initialization (bdy_dta_init routine)
55   USE bdytides        ! open boundary cond. initialization (bdytide_init routine)
56   USE istate          ! initial state setting          (istate_init routine)
57   USE ldfdyn          ! lateral viscosity setting      (ldfdyn_init routine)
58   USE ldftra          ! lateral diffusivity setting    (ldftra_init routine)
59   USE zdfini          ! vertical physics setting          (zdf_init routine)
60   USE phycst          ! physical constant                  (par_cst routine)
61   USE trdmod          ! momentum/tracers trends       (trd_mod_init routine)
62   USE asminc          ! assimilation increments     
63   USE asmbkg          ! writing out state trajectory
64   USE diaptr          ! poleward transports           (dia_ptr_init routine)
65   USE diadct          ! sections transports           (dia_dct_init routine)
66   USE diaobs          ! Observation diagnostics       (dia_obs_init routine)
67   USE lib_fortran     ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
68   USE step            ! NEMO time-stepping                 (stp     routine)
69   USE icbini          ! handle bergs, initialisation
70   USE icbstp          ! handle bergs, calving, themodynamics and transport
71#if defined key_oasis3
72   USE cpl_oasis3      ! OASIS3 coupling
73#elif defined key_oasis4
74   USE cpl_oasis4      ! OASIS4 coupling (not working)
75#endif
76   USE c1d             ! 1D configuration
77   USE step_c1d        ! Time stepping loop for the 1D configuration
78   USE dyndmp          ! Momentum damping
79#if defined key_top
80   USE trcini          ! passive tracer initialisation
81#endif
82   USE lib_mpp         ! distributed memory computing
83#if defined key_iomput
84   USE xios
85#endif
86   USE sbctide, ONLY: lk_tide
87   USE crsini          ! initialise grid coarsening utility
88   USE lbcnfd, ONLY: isendto, nsndto ! Setup of north fold exchanges
89
90   IMPLICIT NONE
91   PRIVATE
92
93   PUBLIC   nemo_gcm    ! called by model.F90
94   PUBLIC   nemo_init   ! needed by AGRIF
95   PUBLIC   nemo_alloc  ! needed by TAM
96
97   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
98
99   !!----------------------------------------------------------------------
100   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
101   !! $Id$
102   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
103   !!----------------------------------------------------------------------
104CONTAINS
105
106   SUBROUTINE nemo_gcm
107      !!----------------------------------------------------------------------
108      !!                     ***  ROUTINE nemo_gcm  ***
109      !!
110      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
111      !!              curvilinear mesh on the sphere.
112      !!
113      !! ** Method  : - model general initialization
114      !!              - launch the time-stepping (stp routine)
115      !!              - finalize the run by closing files and communications
116      !!
117      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
118      !!              Madec, 2008, internal report, IPSL.
119      !!----------------------------------------------------------------------
120      INTEGER ::   istp       ! time step index
121      !!----------------------------------------------------------------------
122      !
123
124#if defined key_agrif
125      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
126#endif
127
128      !                            !-----------------------!
129      CALL nemo_init               !==  Initialisations  ==!
130      !                            !-----------------------!
131#if defined key_agrif
132      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
133      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
134# if defined key_top
135      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
136# endif
137# if defined key_lim2
138      CALL Agrif_Declare_Var_lim2  !  "      "   "   "      "  LIM
139# endif
140#endif
141
142      ! check that all process are still there... If some process have an error,
143      ! they will never enter in step and other processes will wait until the end of the cpu time!
144      IF( lk_mpp )   CALL mpp_max( nstop )
145
146      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
147
148      !                            !-----------------------!
149      !                            !==   time stepping   ==!
150      !                            !-----------------------!
151      istp = nit000
152#if defined key_c1d
153         DO WHILE ( istp <= nitend .AND. nstop == 0 )
154            CALL stp_c1d( istp )
155            istp = istp + 1
156         END DO
157#else
158          IF( lk_asminc ) THEN
159             IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 )    ! Output background fields
160             IF( ln_asmdin ) THEN                        ! Direct initialization
161                IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 )    ! Tracers
162                IF( ln_dyninc ) CALL dyn_asm_inc( nit000 - 1 )    ! Dynamics
163                IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 )    ! SSH
164             ENDIF
165          ENDIF
166
167         DO WHILE ( istp <= nitend .AND. nstop == 0 )
168
169#if defined key_agrif
170            CALL Agrif_Step( stp )           ! AGRIF: time stepping
171#else
172            CALL stp( istp )                 ! standard time stepping
173#endif
174
175            istp = istp + 1
176            IF( lk_mpp )   CALL mpp_max( nstop )
177         END DO
178#endif
179
180      IF( lk_diaobs   )   CALL dia_obs_wri
181      !
182      IF( ln_icebergs )   CALL icb_end( nitend )
183
184      !                            !------------------------!
185      !                            !==  finalize the run  ==!
186      !                            !------------------------!
187      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
188      !
189      IF( nstop /= 0 .AND. lwp ) THEN   ! error print
190         WRITE(numout,cform_err)
191         WRITE(numout,*) nstop, ' error have been found'
192      ENDIF
193      !
194#if defined key_agrif
195      CALL Agrif_ParentGrid_To_ChildGrid()
196      IF( lk_diaobs ) CALL dia_obs_wri
197      IF( nn_timing == 1 )   CALL timing_finalize
198      CALL Agrif_ChildGrid_To_ParentGrid()
199#endif
200      IF( nn_timing == 1 )   CALL timing_finalize
201      !
202      CALL nemo_closefile
203#if defined key_iomput
204      CALL xios_finalize                ! end mpp communications with xios
205# if defined key_oasis3 || defined key_oasis4
206      CALL cpl_prism_finalize           ! end coupling and mpp communications with OASIS
207# endif
208#else
209# if defined key_oasis3 || defined key_oasis4
210      CALL cpl_prism_finalize           ! end coupling and mpp communications with OASIS
211# else
212      IF( lk_mpp )   CALL mppstop       ! end mpp communications
213# endif
214#endif
215      !
216   END SUBROUTINE nemo_gcm
217
218
219   SUBROUTINE nemo_init
220      !!----------------------------------------------------------------------
221      !!                     ***  ROUTINE nemo_init  ***
222      !!
223      !! ** Purpose :   initialization of the NEMO GCM
224      !!----------------------------------------------------------------------
225      INTEGER ::   ji            ! dummy loop indices
226      INTEGER ::   ilocal_comm   ! local integer
227      INTEGER ::   ios
228      CHARACTER(len=80), DIMENSION(16) ::   cltxt
229      !!
230      NAMELIST/namctl/ ln_ctl, nn_print, nn_ictls, nn_ictle,   &
231         &             nn_isplt, nn_jsplt, nn_jctls, nn_jctle,   &
232         &             nn_bench, nn_timing
233      NAMELIST/namcfg/ cp_cfg, cp_cfz, jp_cfg, jpidta, jpjdta, jpkdta, jpiglo, jpjglo, &
234         &             jpizoom, jpjzoom, jperio
235      !!----------------------------------------------------------------------
236      !
237      cltxt = ''
238      !
239      !                             ! Open reference namelist and configuration namelist files
240      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
241      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
242      !
243      REWIND( numnam_ref )              ! Namelist namctl in reference namelist : Control prints & Benchmark
244      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
245901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
246
247      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist : Control prints & Benchmark
248      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
249902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
250
251      !
252      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist : Control prints & Benchmark
253      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
254903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
255
256      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist : Control prints & Benchmark
257      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
258904   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
259
260! Force values for AGRIF zoom (cf. agrif_user.F90)
261#if defined key_agrif
262   IF( .NOT. Agrif_Root() ) THEN
263      jpiglo  = nbcellsx + 2 + 2*nbghostcells
264      jpjglo  = nbcellsy + 2 + 2*nbghostcells
265      jpi     = ( jpiglo-2*jpreci + (jpni-1+0) ) / jpni + 2*jpreci
266      jpj     = ( jpjglo-2*jprecj + (jpnj-1+0) ) / jpnj + 2*jprecj
267      jpidta  = jpiglo
268      jpjdta  = jpjglo
269      jpizoom = 1
270      jpjzoom = 1
271      nperio  = 0
272      jperio  = 0
273   ENDIF
274#endif
275      !
276      !                             !--------------------------------------------!
277      !                             !  set communicator & select the local node  !
278      !                             !  NB: mynode also opens output.namelist.dyn !
279      !                             !      on unit number numond on first proc   !
280      !                             !--------------------------------------------!
281#if defined key_iomput
282      IF( Agrif_Root() ) THEN
283# if defined key_oasis3 || defined key_oasis4
284         CALL cpl_prism_init( ilocal_comm )      ! nemo local communicator given by oasis
285         CALL xios_initialize( "oceanx",local_comm=ilocal_comm )
286# else
287         CALL  xios_initialize( "nemo",return_comm=ilocal_comm )
288# endif
289      ENDIF
290      narea = mynode( cltxt, numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )   ! Nodes selection
291#else
292# if defined key_oasis3 || defined key_oasis4
293      IF( Agrif_Root() ) THEN
294         CALL cpl_prism_init( ilocal_comm )                 ! nemo local communicator given by oasis
295      ENDIF
296      narea = mynode( cltxt, numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )   ! Nodes selection (control print return in cltxt)
297# else
298      ilocal_comm = 0
299      narea = mynode( cltxt, numnam_ref, numnam_cfg, numond , nstop )                 ! Nodes selection (control print return in cltxt)
300# endif
301#endif
302      narea = narea + 1                                     ! mynode return the rank of proc (0 --> jpnij -1 )
303
304      lwm = (narea == 1)                                    ! control of output namelists
305      lwp = (narea == 1) .OR. ln_ctl                        ! control of all listing output print
306
307      IF(lwm) THEN
308         ! write merged namelists from earlier to output namelist now that the
309         ! file has been opened in call to mynode. nammpp has already been
310         ! written in mynode (if lk_mpp_mpi)
311         WRITE( numond, namctl )
312         WRITE( numond, namcfg )
313      ENDIF
314
315      ! If dimensions of processor grid weren't specified in the namelist file
316      ! then we calculate them here now that we have our communicator size
317      IF( (jpni < 1) .OR. (jpnj < 1) )THEN
318#if   defined key_mpp_mpi
319         IF( Agrif_Root() ) CALL nemo_partition(mppsize)
320#else
321         jpni  = 1
322         jpnj  = 1
323         jpnij = jpni*jpnj
324#endif
325      END IF
326
327      ! Calculate domain dimensions given calculated jpni and jpnj
328      ! This used to be done in par_oce.F90 when they were parameters rather
329      ! than variables
330      IF( Agrif_Root() ) THEN
331#if defined key_nemocice_decomp
332         jpi = ( nx_global+2-2*jpreci + (jpni-1) ) / jpni + 2*jpreci ! first  dim.
333         jpj = ( ny_global+2-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj ! second dim.
334#else
335         jpi = ( jpiglo-2*jpreci + (jpni-1) ) / jpni + 2*jpreci   ! first  dim.
336         jpj = ( jpjglo-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj   ! second dim.
337#endif
338      ENDIF
339         jpk = jpkdta                                             ! third dim
340         jpim1 = jpi-1                                            ! inner domain indices
341         jpjm1 = jpj-1                                            !   "           "
342         jpkm1 = jpk-1                                            !   "           "
343         jpij  = jpi*jpj                                          !  jpi x j
344
345      IF(lwp) THEN                            ! open listing units
346         !
347         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
348         !
349         WRITE(numout,*)
350         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
351         WRITE(numout,*) '                       NEMO team'
352         WRITE(numout,*) '            Ocean General Circulation Model'
353         WRITE(numout,*) '                  version 3.4  (2011) '
354         WRITE(numout,*)
355         WRITE(numout,*)
356         DO ji = 1, SIZE(cltxt)
357            IF( TRIM(cltxt(ji)) /= '' )   WRITE(numout,*) cltxt(ji)      ! control print of mynode
358         END DO
359         WRITE(numout,cform_aaa)                                         ! Flag AAAAAAA
360         !
361      ENDIF
362
363      ! Now we know the dimensions of the grid and numout has been set we can
364      ! allocate arrays
365      CALL nemo_alloc()
366
367      !                             !-------------------------------!
368      !                             !  NEMO general initialization  !
369      !                             !-------------------------------!
370
371      CALL nemo_ctl                          ! Control prints & Benchmark
372
373      !                                      ! Domain decomposition
374      IF( jpni*jpnj == jpnij ) THEN   ;   CALL mpp_init      ! standard cutting out
375      ELSE                            ;   CALL mpp_init2     ! eliminate land processors
376      ENDIF
377      !
378      IF( nn_timing == 1 )  CALL timing_init
379      !
380      !                                      ! General initialization
381                            CALL     phy_cst    ! Physical constants
382                            CALL     eos_init   ! Equation of state
383      IF( lk_c1d        )   CALL     c1d_init   ! 1D column configuration
384                            CALL     dom_cfg    ! Domain configuration
385                            CALL     dom_init   ! Domain
386
387      IF( ln_nnogather )    CALL nemo_northcomms   ! Initialise the northfold neighbour lists (must be done after the masks are defined)
388
389      IF( ln_ctl        )   CALL prt_ctl_init   ! Print control
390
391                            CALL  istate_init   ! ocean initial state (Dynamics and tracers)
392
393      IF( lk_tide       )   CALL    tide_init( nit000 )    ! Initialisation of the tidal harmonics
394
395      IF( lk_bdy        )   CALL      bdy_init  ! Open boundaries initialisation
396      IF( lk_bdy        )   CALL  bdy_dta_init  ! Open boundaries initialisation of external data arrays
397      IF( lk_bdy .AND. lk_tide )   &
398         &                  CALL  bdytide_init  ! Open boundaries initialisation of tidal harmonic forcing
399
400                            CALL dyn_nept_init  ! simplified form of Neptune effect
401
402      !     
403      IF( ln_crs        )   CALL     crs_init   ! Domain initialization of coarsened grid
404      !
405                                ! Ocean physics
406                            CALL     sbc_init   ! Forcings : surface module
407      !                                         ! Vertical physics
408
409                            CALL     zdf_init      ! namelist read
410
411                            CALL zdf_bfr_init      ! bottom friction
412
413      IF( lk_zdfric     )   CALL zdf_ric_init      ! Richardson number dependent Kz
414      IF( lk_zdftke     )   CALL zdf_tke_init      ! TKE closure scheme
415      IF( lk_zdfgls     )   CALL zdf_gls_init      ! GLS closure scheme
416      IF( lk_zdfkpp     )   CALL zdf_kpp_init      ! KPP closure scheme
417      IF( lk_zdftmx     )   CALL zdf_tmx_init      ! tidal vertical mixing
418      IF( lk_zdfddm .AND. .NOT. lk_zdfkpp )   &
419         &                  CALL zdf_ddm_init      ! double diffusive mixing
420      !                                         ! Lateral physics
421#if ! defined key_surge
422                            CALL ldf_tra_init      ! Lateral ocean tracer physics
423#endif
424                            CALL ldf_dyn_init      ! Lateral ocean momentum physics
425      IF( lk_ldfslp     )   CALL ldf_slp_init      ! slope of lateral mixing
426
427#if ! defined key_surge
428      !                                     ! Active tracers
429                            CALL tra_qsr_init   ! penetrative solar radiation qsr
430                            CALL tra_bbc_init   ! bottom heat flux
431      IF( lk_trabbl     )   CALL tra_bbl_init   ! advective (and/or diffusive) bottom boundary layer scheme
432                            CALL tra_dmp_init   ! internal damping trends- tracers
433                            CALL tra_adv_init   ! horizontal & vertical advection
434                            CALL tra_ldf_init   ! lateral mixing
435                            CALL tra_zdf_init   ! vertical mixing and after tracer fields
436#endif
437
438      !                                     ! Dynamics
439      IF( lk_c1d        )   CALL dyn_dmp_init   ! internal damping trends- momentum
440                            CALL dyn_adv_init   ! advection (vector or flux form)
441                            CALL dyn_vor_init   ! vorticity term including Coriolis
442                            CALL dyn_ldf_init   ! lateral mixing
443                            CALL dyn_hpg_init   ! horizontal gradient of Hydrostatic pressure
444                            CALL dyn_zdf_init   ! vertical diffusion
445                            CALL dyn_spg_init   ! surface pressure gradient
446
447      !                                     ! Misc. options
448      IF( nn_cla == 1 .AND. cp_cfg == 'orca' .AND. jp_cfg == 2 )   CALL cla_init       ! Cross Land Advection
449                            CALL icb_init( rdt, nit000)   ! initialise icebergs instance
450     
451#if defined key_top
452      !                                     ! Passive tracers
453                            CALL     trc_init
454#endif
455      !
456 
457                                            ! Diagnostics
458      IF( lk_floats     )   CALL     flo_init   ! drifting Floats
459      IF( lk_diaar5     )   CALL dia_ar5_init   ! ar5 diag
460                            CALL dia_ptr_init   ! Poleward TRansports initialization
461      IF( lk_diadct     )   CALL dia_dct_init   ! Sections tranports
462                            CALL dia_hsb_init   ! heat content, salt content and volume budgets
463                            CALL trd_mod_init   ! Mixed-layer/Vorticity/Integral constraints trends
464      IF( lk_diaobs     ) THEN                  ! Observation & model comparison
465                            CALL dia_obs_init            ! Initialize observational data
466                            CALL dia_obs( nit000 - 1 )   ! Observation operator for restart
467      ENDIF
468      !                                     ! Assimilation increments
469      IF( lk_asminc     )   CALL asm_inc_init   ! Initialize assimilation increments
470      IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
471      !
472   END SUBROUTINE nemo_init
473
474
475   SUBROUTINE nemo_ctl
476      !!----------------------------------------------------------------------
477      !!                     ***  ROUTINE nemo_ctl  ***
478      !!
479      !! ** Purpose :   control print setting
480      !!
481      !! ** Method  : - print namctl information and check some consistencies
482      !!----------------------------------------------------------------------
483      !
484      IF(lwp) THEN                  ! control print
485         WRITE(numout,*)
486         WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark'
487         WRITE(numout,*) '~~~~~~~ '
488         WRITE(numout,*) '   Namelist namctl'
489         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
490         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
491         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
492         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
493         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
494         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
495         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
496         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
497         WRITE(numout,*) '      benchmark parameter (0/1)       nn_bench   = ', nn_bench
498         WRITE(numout,*) '      timing activated    (0/1)       nn_timing  = ', nn_timing
499      ENDIF
500      !
501      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
502      nictls    = nn_ictls
503      nictle    = nn_ictle
504      njctls    = nn_jctls
505      njctle    = nn_jctle
506      isplt     = nn_isplt
507      jsplt     = nn_jsplt
508      nbench    = nn_bench
509
510      IF(lwp) THEN                  ! control print
511         WRITE(numout,*)
512         WRITE(numout,*) 'namcfg  : configuration initialization through namelist read'
513         WRITE(numout,*) '~~~~~~~ '
514         WRITE(numout,*) '   Namelist namcfg'
515         WRITE(numout,*) '      configuration name              cp_cfg      = ', TRIM(cp_cfg)
516         WRITE(numout,*) '      configuration zoom name         cp_cfz      = ', TRIM(cp_cfz)
517         WRITE(numout,*) '      configuration resolution        jp_cfg      = ', jp_cfg
518         WRITE(numout,*) '      1st lateral dimension ( >= jpi ) jpidta     = ', jpidta
519         WRITE(numout,*) '      2nd    "         "    ( >= jpj ) jpjdta     = ', jpjdta
520         WRITE(numout,*) '      3nd    "         "               jpkdta     = ', jpkdta
521         WRITE(numout,*) '      1st dimension of global domain in i jpiglo  = ', jpiglo
522         WRITE(numout,*) '      2nd    -                  -    in j jpjglo  = ', jpjglo
523         WRITE(numout,*) '      left bottom i index of the zoom (in data domain) jpizoom = ', jpizoom
524         WRITE(numout,*) '      left bottom j index of the zoom (in data domain) jpizoom = ', jpjzoom
525         WRITE(numout,*) '      lateral cond. type (between 0 and 6) jperio = ', jperio   
526      ENDIF
527      !                             ! Parameter control
528      !
529      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
530         IF( lk_mpp .AND. jpnij > 1 ) THEN
531            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
532         ELSE
533            IF( isplt == 1 .AND. jsplt == 1  ) THEN
534               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
535                  &           ' - the print control will be done over the whole domain' )
536            ENDIF
537            ijsplt = isplt * jsplt            ! total number of processors ijsplt
538         ENDIF
539         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
540         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
541         !
542         !                              ! indices used for the SUM control
543         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
544            lsp_area = .FALSE.
545         ELSE                                             ! print control done over a specific  area
546            lsp_area = .TRUE.
547            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
548               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
549               nictls = 1
550            ENDIF
551            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
552               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
553               nictle = jpiglo
554            ENDIF
555            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
556               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
557               njctls = 1
558            ENDIF
559            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
560               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
561               njctle = jpjglo
562            ENDIF
563         ENDIF
564      ENDIF
565      !
566      IF( nbench == 1 ) THEN              ! Benchmark
567         SELECT CASE ( cp_cfg )
568         CASE ( 'gyre' )   ;   CALL ctl_warn( ' The Benchmark is activated ' )
569         CASE DEFAULT      ;   CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:',   &
570            &                                 ' cp_cfg = "gyre" in namelist &namcfg or set nbench = 0' )
571         END SELECT
572      ENDIF
573      !
574      IF( lk_c1d .AND. .NOT.lk_iomput )   CALL ctl_stop( 'nemo_ctl: The 1D configuration must be used ',   &
575         &                                               'with the IOM Input/Output manager. '         ,   &
576         &                                               'Compile with key_iomput enabled' )
577      !
578      IF( 1_wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ',  &
579         &                                               'f2003 standard. '                              ,  &
580         &                                               'Compile with key_nosignedzero enabled' )
581      !
582   END SUBROUTINE nemo_ctl
583
584
585   SUBROUTINE nemo_closefile
586      !!----------------------------------------------------------------------
587      !!                     ***  ROUTINE nemo_closefile  ***
588      !!
589      !! ** Purpose :   Close the files
590      !!----------------------------------------------------------------------
591      !
592      IF( lk_mpp )   CALL mppsync
593      !
594      CALL iom_close                                 ! close all input/output files managed by iom_*
595      !
596      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
597      IF( numsol          /= -1 )   CLOSE( numsol          )   ! solver file
598      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
599      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
600      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
601      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
602      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
603      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
604      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
605      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
606      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
607      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
608      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
609
610      !
611      numout = 6                                     ! redefine numout in case it is used after this point...
612      !
613   END SUBROUTINE nemo_closefile
614
615
616   SUBROUTINE nemo_alloc
617      !!----------------------------------------------------------------------
618      !!                     ***  ROUTINE nemo_alloc  ***
619      !!
620      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
621      !!
622      !! ** Method  :
623      !!----------------------------------------------------------------------
624      USE diawri    , ONLY: dia_wri_alloc
625      USE dom_oce   , ONLY: dom_oce_alloc
626      USE ldfdyn_oce, ONLY: ldfdyn_oce_alloc
627      USE ldftra_oce, ONLY: ldftra_oce_alloc
628      USE trc_oce   , ONLY: trc_oce_alloc
629#if defined key_diadct 
630      USE diadct    , ONLY: diadct_alloc 
631#endif 
632#if defined key_bdy
633      USE bdy_oce   , ONLY: bdy_oce_alloc
634#endif
635      !
636      INTEGER :: ierr
637      !!----------------------------------------------------------------------
638      !
639      ierr =        oce_alloc       ()          ! ocean
640      ierr = ierr + dia_wri_alloc   ()
641      ierr = ierr + dom_oce_alloc   ()          ! ocean domain
642      ierr = ierr + ldfdyn_oce_alloc()          ! ocean lateral  physics : dynamics
643      ierr = ierr + ldftra_oce_alloc()          ! ocean lateral  physics : tracers
644      ierr = ierr + zdf_oce_alloc   ()          ! ocean vertical physics
645      !
646      ierr = ierr + trc_oce_alloc   ()          ! shared TRC / TRA arrays
647      !
648#if defined key_diadct 
649      ierr = ierr + diadct_alloc    ()          !
650#endif 
651#if defined key_bdy
652      ierr = ierr + bdy_oce_alloc   ()          ! bdy masks (incl. initialization)
653#endif
654      !
655      IF( lk_mpp    )   CALL mpp_sum( ierr )
656      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
657      !
658   END SUBROUTINE nemo_alloc
659
660
661   SUBROUTINE nemo_partition( num_pes )
662      !!----------------------------------------------------------------------
663      !!                 ***  ROUTINE nemo_partition  ***
664      !!
665      !! ** Purpose :
666      !!
667      !! ** Method  :
668      !!----------------------------------------------------------------------
669      INTEGER, INTENT(in) :: num_pes ! The number of MPI processes we have
670      !
671      INTEGER, PARAMETER :: nfactmax = 20
672      INTEGER :: nfact ! The no. of factors returned
673      INTEGER :: ierr  ! Error flag
674      INTEGER :: ji
675      INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
676      INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
677      !!----------------------------------------------------------------------
678
679      ierr = 0
680
681      CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
682
683      IF( nfact <= 1 ) THEN
684         WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
685         WRITE (numout, *) '       : using grid of ',num_pes,' x 1'
686         jpnj = 1
687         jpni = num_pes
688      ELSE
689         ! Search through factors for the pair that are closest in value
690         mindiff = 1000000
691         imin    = 1
692         DO ji = 1, nfact-1, 2
693            idiff = ABS( ifact(ji) - ifact(ji+1) )
694            IF( idiff < mindiff ) THEN
695               mindiff = idiff
696               imin = ji
697            ENDIF
698         END DO
699         jpnj = ifact(imin)
700         jpni = ifact(imin + 1)
701      ENDIF
702      !
703      jpnij = jpni*jpnj
704      !
705   END SUBROUTINE nemo_partition
706
707
708   SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
709      !!----------------------------------------------------------------------
710      !!                     ***  ROUTINE factorise  ***
711      !!
712      !! ** Purpose :   return the prime factors of n.
713      !!                knfax factors are returned in array kfax which is of
714      !!                maximum dimension kmaxfax.
715      !! ** Method  :
716      !!----------------------------------------------------------------------
717      INTEGER                    , INTENT(in   ) ::   kn, kmaxfax
718      INTEGER                    , INTENT(  out) ::   kerr, knfax
719      INTEGER, DIMENSION(kmaxfax), INTENT(  out) ::   kfax
720      !
721      INTEGER :: ifac, jl, inu
722      INTEGER, PARAMETER :: ntest = 14
723      INTEGER :: ilfax(ntest)
724
725      ! lfax contains the set of allowed factors.
726      data (ilfax(jl),jl=1,ntest) / 16384, 8192, 4096, 2048, 1024, 512, 256,  &
727         &                            128,   64,   32,   16,    8,   4,   2  /
728      !!----------------------------------------------------------------------
729
730      ! Clear the error flag and initialise output vars
731      kerr = 0
732      kfax = 1
733      knfax = 0
734
735      ! Find the factors of n.
736      IF( kn == 1 )   GOTO 20
737
738      ! nu holds the unfactorised part of the number.
739      ! knfax holds the number of factors found.
740      ! l points to the allowed factor list.
741      ! ifac holds the current factor.
742
743      inu   = kn
744      knfax = 0
745
746      DO jl = ntest, 1, -1
747         !
748         ifac = ilfax(jl)
749         IF( ifac > inu )   CYCLE
750
751         ! Test whether the factor will divide.
752
753         IF( MOD(inu,ifac) == 0 ) THEN
754            !
755            knfax = knfax + 1            ! Add the factor to the list
756            IF( knfax > kmaxfax ) THEN
757               kerr = 6
758               write (*,*) 'FACTOR: insufficient space in factor array ', knfax
759               return
760            ENDIF
761            kfax(knfax) = ifac
762            ! Store the other factor that goes with this one
763            knfax = knfax + 1
764            kfax(knfax) = inu / ifac
765            !WRITE (*,*) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
766         ENDIF
767         !
768      END DO
769
770   20 CONTINUE      ! Label 20 is the exit point from the factor search loop.
771      !
772   END SUBROUTINE factorise
773
774#if defined key_mpp_mpi
775   SUBROUTINE nemo_northcomms
776      !!======================================================================
777      !!                     ***  ROUTINE  nemo_northcomms  ***
778      !! nemo_northcomms    :  Setup for north fold exchanges with explicit
779      !!                       point-to-point messaging
780      !!=====================================================================
781      !!----------------------------------------------------------------------
782      !!
783      !! ** Purpose :   Initialization of the northern neighbours lists.
784      !!----------------------------------------------------------------------
785      !!    1.0  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE)
786      !!    2.0  ! 2013-06 Setup avoiding MPI communication (I. Epicoco, S. Mocavero, CMCC)
787      !!----------------------------------------------------------------------
788
789      INTEGER  ::   sxM, dxM, sxT, dxT, jn
790      INTEGER  ::   njmppmax
791
792      njmppmax = MAXVAL( njmppt )
793   
794      !initializes the north-fold communication variables
795      isendto(:) = 0
796      nsndto = 0
797
798      !if I am a process in the north
799      IF ( njmpp == njmppmax ) THEN
800          !sxM is the first point (in the global domain) needed to compute the
801          !north-fold for the current process
802          sxM = jpiglo - nimppt(narea) - nlcit(narea) + 1
803          !dxM is the last point (in the global domain) needed to compute the
804          !north-fold for the current process
805          dxM = jpiglo - nimppt(narea) + 2
806
807          !loop over the other north-fold processes to find the processes
808          !managing the points belonging to the sxT-dxT range
809          DO jn = jpnij - jpni +1, jpnij
810             IF ( njmppt(jn) == njmppmax ) THEN
811                !sxT is the first point (in the global domain) of the jn
812                !process
813                sxT = nimppt(jn)
814                !dxT is the last point (in the global domain) of the jn
815                !process
816                dxT = nimppt(jn) + nlcit(jn) - 1
817                IF ((sxM .gt. sxT) .AND. (sxM .lt. dxT)) THEN
818                   nsndto = nsndto + 1
819                   isendto(nsndto) = jn
820                ELSEIF ((sxM .le. sxT) .AND. (dxM .ge. dxT)) THEN
821                   nsndto = nsndto + 1
822                   isendto(nsndto) = jn
823                ELSEIF ((dxM .lt. dxT) .AND. (sxT .lt. dxM)) THEN
824                   nsndto = nsndto + 1
825                   isendto(nsndto) = jn
826                END IF
827             END IF
828          END DO
829      ENDIF
830      l_north_nogather = .TRUE.
831   END SUBROUTINE nemo_northcomms
832#else
833   SUBROUTINE nemo_northcomms      ! Dummy routine
834      WRITE(*,*) 'nemo_northcomms: You should not have seen this print! error?'
835   END SUBROUTINE nemo_northcomms
836#endif
837   !!======================================================================
838END MODULE nemogcm
839
840
Note: See TracBrowser for help on using the repository browser.