source: branches/UKMO/2015_V36_STABLE_CO6_CO5_zenv_pomsdwl/NEMOGCM/NEMO/OPA_SRC/SBC/sbcflx.F90 @ 5793

Last change on this file since 5793 was 5793, checked in by deazer, 6 years ago

Bug Fix allocation in sbcflx

File size: 12.6 KB
Line 
1MODULE sbcflx
2   !!======================================================================
3   !!                       ***  MODULE  sbcflx  ***
4   !! Ocean forcing:  momentum, heat and freshwater flux formulation
5   !!=====================================================================
6   !! History :  1.0  !  2006-06  (G. Madec)  Original code
7   !!            3.3  !  2010-10  (S. Masson)  add diurnal cycle
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   namflx   : flux formulation namlist
12   !!   sbc_flx  : flux formulation as ocean surface boundary condition (forced mode, fluxes read in NetCDF files)
13   !!----------------------------------------------------------------------
14   USE oce             ! ocean dynamics and tracers
15   USE dom_oce         ! ocean space and time domain
16   USE sbc_oce         ! surface boundary condition: ocean fields
17   USE sbcdcy          ! surface boundary condition: diurnal cycle on qsr
18   USE phycst          ! physical constants
19   USE fldread         ! read input fields
20   USE iom             ! IOM library
21   USE in_out_manager  ! I/O manager
22   USE lib_mpp         ! distribued memory computing library
23   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC sbc_flx       ! routine called by step.F90
29
30   INTEGER , PARAMETER ::   jpfld   = 6   ! maximum number of files to read
31   INTEGER , PARAMETER ::   jp_utau = 1   ! index of wind stress (i-component) file
32   INTEGER , PARAMETER ::   jp_vtau = 2   ! index of wind stress (j-component) file
33   INTEGER , PARAMETER ::   jp_qtot = 3   ! index of total (non solar+solar) heat file
34   INTEGER , PARAMETER ::   jp_qsr  = 4   ! index of solar heat file
35   INTEGER , PARAMETER ::   jp_emp  = 5   ! index of evaporation-precipation file
36   INTEGER , PARAMETER ::   jp_press = 6  ! index of pressure for UKMO shelf fluxes
37   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf    ! structure of input fields (file informations, fields read)
38   LOGICAL , PUBLIC    ::   ln_shelf_flx = .FALSE. ! UKMO SHELF specific flux flag
39   INTEGER             ::   jpfld_local   ! maximum number of files to read (locally modified depending on ln_shelf_flx)
40
41   !! * Substitutions
42#  include "domzgr_substitute.h90"
43#  include "vectopt_loop_substitute.h90"
44   !!----------------------------------------------------------------------
45   !! NEMO/OPA 3.3 , NEMO-consortium (2010)
46   !! $Id$
47   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51   SUBROUTINE sbc_flx( kt )
52      !!---------------------------------------------------------------------
53      !!                    ***  ROUTINE sbc_flx  ***
54      !!                   
55      !! ** Purpose :   provide at each time step the surface ocean fluxes
56      !!                (momentum, heat, freshwater and runoff)
57      !!
58      !! ** Method  : - READ each fluxes in NetCDF files:
59      !!                   i-component of the stress              utau  (N/m2)
60      !!                   j-component of the stress              vtau  (N/m2)
61      !!                   net downward heat flux                 qtot  (watt/m2)
62      !!                   net downward radiative flux            qsr   (watt/m2)
63      !!                   net upward freshwater (evapo - precip) emp   (kg/m2/s)
64      !!
65      !!      CAUTION :  - never mask the surface stress fields
66      !!                 - the stress is assumed to be in the (i,j) mesh referential
67      !!
68      !! ** Action  :   update at each time-step
69      !!              - utau, vtau  i- and j-component of the wind stress
70      !!              - taum        wind stress module at T-point
71      !!              - wndm        10m wind module at T-point
72      !!              - qns         non solar heat flux including heat flux due to emp
73      !!              - qsr         solar heat flux
74      !!              - emp         upward mass flux (evap. - precip.)
75      !!              - sfx         salt flux; set to zero at nit000 but possibly non-zero
76      !!                            if ice is present (computed in limsbc(_2).F90)
77      !!----------------------------------------------------------------------
78      INTEGER, INTENT(in) ::   kt   ! ocean time step
79      !!
80      INTEGER  ::   ji, jj, jf            ! dummy indices
81      INTEGER  ::   ierror                ! return error code
82      INTEGER  ::   ios                   ! Local integer output status for namelist read
83      REAL(wp) ::   zfact                 ! temporary scalar
84      REAL(wp) ::   zrhoa  = 1.22         ! Air density kg/m3
85      REAL(wp) ::   zcdrag = 1.5e-3       ! drag coefficient
86      REAL(wp) ::   ztx, zty, zmod, zcoef ! temporary variables
87      REAL     ::   cs                    ! UKMO SHELF: Friction co-efficient at surface
88      REAL     ::   totwindspd            ! UKMO SHELF: Magnitude of wind speed vector
89
90      REAL(wp) ::   rhoa  = 1.22         ! Air density kg/m3
91      REAL(wp) ::   cdrag = 1.5e-3       ! drag coefficient
92      !!
93      CHARACTER(len=100) ::  cn_dir                               ! Root directory for location of flx files
94      TYPE(FLD_N), DIMENSION(jpfld) ::   slf_i                    ! array of namelist information structures
95      TYPE(FLD_N) ::   sn_utau, sn_vtau, sn_qtot, sn_qsr, sn_emp, sn_press  !  informations about the fields to be read
96      LOGICAL     ::   ln_foam_flx  = .FALSE.                     ! UKMO FOAM specific flux flag
97      NAMELIST/namsbc_flx/ cn_dir, sn_utau, sn_vtau, sn_qtot, sn_qsr, sn_emp,   &
98      &                    ln_foam_flx, sn_press, ln_shelf_flx
99      !!---------------------------------------------------------------------
100      !
101      IF( kt == nit000 ) THEN                ! First call kt=nit000 
102         ! set file information
103         REWIND( numnam_ref )              ! Namelist namsbc_flx in reference namelist : Files for fluxes
104         READ  ( numnam_ref, namsbc_flx, IOSTAT = ios, ERR = 901)
105901      IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_flx in reference namelist', lwp )
106
107         REWIND( numnam_cfg )              ! Namelist namsbc_flx in configuration namelist : Files for fluxes
108         READ  ( numnam_cfg, namsbc_flx, IOSTAT = ios, ERR = 902 )
109902      IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_flx in configuration namelist', lwp )
110         IF(lwm) WRITE ( numond, namsbc_flx ) 
111         !
112         !                                         ! check: do we plan to use ln_dm2dc with non-daily forcing?
113         IF( ln_dm2dc .AND. sn_qsr%nfreqh /= 24 )   &
114            &   CALL ctl_stop( 'sbc_blk_core: ln_dm2dc can be activated only with daily short-wave forcing' ) 
115         !
116         !                                         ! store namelist information in an array
117         slf_i(jp_utau) = sn_utau   ;   slf_i(jp_vtau) = sn_vtau
118         slf_i(jp_qtot) = sn_qtot   ;   slf_i(jp_qsr ) = sn_qsr 
119         slf_i(jp_emp ) = sn_emp
120         !
121            ALLOCATE( sf(jpfld), STAT=ierror )        ! set sf structure
122            IF( ln_shelf_flx ) slf_i(jp_press) = sn_press
123   
124            ! define local jpfld depending on shelf_flx logical
125            IF( ln_shelf_flx ) THEN
126               jpfld_local = jpfld
127            ELSE
128               jpfld_local = jpfld-1
129            ENDIF
130            !
131         IF( ierror > 0 ) THEN   
132            CALL ctl_stop( 'sbc_flx: unable to allocate sf structure' )   ;   RETURN 
133         ENDIF
134         DO ji= 1, jpfld_local
135            ALLOCATE( sf(ji)%fnow(jpi,jpj,1) )
136            IF( slf_i(ji)%ln_tint ) ALLOCATE( sf(ji)%fdta(jpi,jpj,1,2) )
137         END DO
138         !                                         ! fill sf with slf_i and control print
139         CALL fld_fill( sf, slf_i, cn_dir, 'sbc_flx', 'flux formulation for ocean surface boundary condition', 'namsbc_flx' )
140         !
141         sfx(:,:) = 0.0_wp                         ! salt flux due to freezing/melting (non-zero only if ice is present; set in limsbc(_2).F90)
142         !
143      ENDIF
144
145      CALL fld_read( kt, nn_fsbc, sf )                            ! input fields provided at the current time-step
146     
147      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN                        ! update ocean fluxes at each SBC frequency
148
149         IF( ln_dm2dc ) THEN   ;   qsr(:,:) = sbc_dcy( sf(jp_qsr)%fnow(:,:,1) )   ! modify now Qsr to include the diurnal cycle
150         ELSE                  ;   qsr(:,:) =          sf(jp_qsr)%fnow(:,:,1)
151         ENDIF
152!CDIR COLLAPSE
153            !!UKMO SHELF effect of atmospheric pressure on SSH
154            ! If using ln_apr_dyn, this is done there so don't repeat here.
155            IF( ln_shelf_flx .AND. .NOT. ln_apr_dyn) THEN
156               DO jj = 1, jpjm1
157                  DO ji = 1, jpim1
158                     apgu(ji,jj) = (-1.0/rau0)*(sf(jp_press)%fnow(ji+1,jj,1)-sf(jp_press)%fnow(ji,jj,1))/e1u(ji,jj)
159                     apgv(ji,jj) = (-1.0/rau0)*(sf(jp_press)%fnow(ji,jj+1,1)-sf(jp_press)%fnow(ji,jj,1))/e2v(ji,jj)
160                  END DO
161               END DO
162            ENDIF ! ln_shelf_flx
163     
164         DO jj = 1, jpj                                           ! set the ocean fluxes from read fields
165            DO ji = 1, jpi
166                   IF( ln_shelf_flx ) THEN
167                      !! UKMO SHELF - need atmospheric pressure to calculate Haney forcing
168                      pressnow(ji,jj) = sf(jp_press)%fnow(ji,jj,1)
169                      !! UKMO SHELF flux files contain wind speed not wind stress
170                      totwindspd = sqrt((sf(jp_utau)%fnow(ji,jj,1))**2.0 + (sf(jp_vtau)%fnow(ji,jj,1))**2.0)
171                      cs = 0.63 + (0.066 * totwindspd)
172                      utau(ji,jj) = cs * (rhoa/rau0) * sf(jp_utau)%fnow(ji,jj,1) * totwindspd
173                      vtau(ji,jj) = cs * (rhoa/rau0) * sf(jp_vtau)%fnow(ji,jj,1) * totwindspd
174                   ELSE
175                      utau(ji,jj) = sf(jp_utau)%fnow(ji,jj,1)
176                      vtau(ji,jj) = sf(jp_vtau)%fnow(ji,jj,1)
177                   ENDIF
178                   qsr (ji,jj) = sf(jp_qsr )%fnow(ji,jj,1)
179                   IF( ln_foam_flx .OR. ln_shelf_flx ) THEN
180                      !! UKMO FOAM flux files contain non-solar heat flux (qns) rather than total heat flux (qtot)
181                      qns (ji,jj) = sf(jp_qtot)%fnow(ji,jj,1)
182                      !! UKMO FOAM flux files contain the net DOWNWARD freshwater flux P-E rather then E-P
183                      emp (ji,jj) = -1. * sf(jp_emp )%fnow(ji,jj,1)
184                   ELSE
185                      qns (ji,jj) = sf(jp_qtot)%fnow(ji,jj,1) - sf(jp_qsr)%fnow(ji,jj,1)
186                      emp (ji,jj) = sf(jp_emp )%fnow(ji,jj,1)
187                   ENDIF
188            END DO
189         END DO
190         !                                                        ! add to qns the heat due to e-p
191         qns(:,:) = qns(:,:) - emp(:,:) * sst_m(:,:) * rcp        ! mass flux is at SST
192         !
193   
194            !! UKMO FOAM wind fluxes need lbc_lnk calls owing to a bug in interp.exe
195            IF( ln_foam_flx ) THEN
196               CALL lbc_lnk( utau(:,:), 'U', -1. )
197               CALL lbc_lnk( vtau(:,:), 'V', -1. )
198            ENDIF
199   
200         !                                                        ! module of wind stress and wind speed at T-point
201         zcoef = 1. / ( zrhoa * zcdrag )
202!CDIR NOVERRCHK
203         DO jj = 2, jpjm1
204!CDIR NOVERRCHK
205            DO ji = fs_2, fs_jpim1   ! vect. opt.
206               ztx = utau(ji-1,jj  ) + utau(ji,jj) 
207               zty = vtau(ji  ,jj-1) + vtau(ji,jj) 
208               zmod = 0.5 * SQRT( ztx * ztx + zty * zty )
209               taum(ji,jj) = zmod
210               wndm(ji,jj) = SQRT( zmod * zcoef )
211            END DO
212         END DO
213         taum(:,:) = taum(:,:) * tmask(:,:,1) ; wndm(:,:) = wndm(:,:) * tmask(:,:,1)
214         CALL lbc_lnk( taum(:,:), 'T', 1. )   ;   CALL lbc_lnk( wndm(:,:), 'T', 1. )
215
216         IF( nitend-nit000 <= 100 .AND. lwp ) THEN                ! control print (if less than 100 time-step asked)
217            WRITE(numout,*) 
218            WRITE(numout,*) '        read daily momentum, heat and freshwater fluxes OK'
219            DO jf = 1, jpfld_local
220               IF( jf == jp_utau .OR. jf == jp_vtau )   zfact =     1.
221               IF( jf == jp_qtot .OR. jf == jp_qsr  )   zfact =     0.1
222               IF( jf == jp_emp                     )   zfact = 86400.
223               WRITE(numout,*) 
224               WRITE(numout,*) ' day: ', ndastp , TRIM(sf(jf)%clvar), ' * ', zfact
225               CALL prihre( sf(jf)%fnow, jpi, jpj, 1, jpi, 20, 1, jpj, 10, zfact, numout )
226            END DO
227            CALL FLUSH(numout)
228         ENDIF
229         !
230      ENDIF
231      !
232   END SUBROUTINE sbc_flx
233
234   !!======================================================================
235END MODULE sbcflx
Note: See TracBrowser for help on using the repository browser.