source: branches/UKMO/AMM15_v3_6_STABLE_package_collate_utils366_fabmv1/NEMOGCM/NEMO/OPA_SRC/TRA/traqsr.F90 @ 13241

Last change on this file since 13241 was 13241, checked in by dford, 3 months ago

Update NEMO-FABM coupler for compatability with FABM v1.0.

File size: 35.3 KB
Line 
1MODULE traqsr
2   !!======================================================================
3   !!                       ***  MODULE  traqsr  ***
4   !! Ocean physics: solar radiation penetration in the top ocean levels
5   !!======================================================================
6   !! History :  OPA  !  1990-10  (B. Blanke)  Original code
7   !!            7.0  !  1991-11  (G. Madec)
8   !!                 !  1996-01  (G. Madec)  s-coordinates
9   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
10   !!             -   !  2005-11  (G. Madec) zco, zps, sco coordinate
11   !!            3.2  !  2009-04  (G. Madec & NEMO team)
12   !!            4.0  !  2012-05  (C. Rousset) store attenuation coef for use in ice model
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   tra_qsr      : trend due to the solar radiation penetration
17   !!   tra_qsr_init : solar radiation penetration initialization
18   !!----------------------------------------------------------------------
19   USE oce             ! ocean dynamics and active tracers
20   USE dom_oce         ! ocean space and time domain
21   USE sbc_oce         ! surface boundary condition: ocean
22   USE trc_oce         ! share SMS/Ocean variables
23   USE trd_oce        ! trends: ocean variables
24   USE trdtra         ! trends manager: tracers
25   USE in_out_manager  ! I/O manager
26   USE phycst          ! physical constants
27   USE prtctl          ! Print control
28   USE iom             ! I/O manager
29   USE fldread         ! read input fields
30   USE restart         ! ocean restart
31   USE lib_mpp         ! MPP library
32   USE wrk_nemo       ! Memory Allocation
33   USE timing         ! Timing
34
35   IMPLICIT NONE
36   PRIVATE
37
38   PUBLIC   tra_qsr       ! routine called by step.F90 (ln_traqsr=T)
39   PUBLIC   tra_qsr_init  ! routine called by nemogcm.F90
40
41   !                                 !!* Namelist namtra_qsr: penetrative solar radiation
42   LOGICAL , PUBLIC ::   ln_traqsr    !: light absorption (qsr) flag
43   LOGICAL , PUBLIC ::   ln_qsr_rgb   !: Red-Green-Blue light absorption flag 
44   LOGICAL , PUBLIC ::   ln_qsr_2bd   !: 2 band         light absorption flag
45   LOGICAL , PUBLIC ::   ln_qsr_bio   !: bio-model      light absorption flag
46   LOGICAL , PUBLIC ::   ln_qsr_ice   !: light penetration for ice-model LIM3 (clem)
47   LOGICAL , PUBLIC ::   ln_qsr_spec  !: spectral model heating from ERSEM
48   INTEGER , PUBLIC ::   nn_chldta    !: use Chlorophyll data (=1) or not (=0)
49   INTEGER , PUBLIC ::   nn_kd490dta  !: use kd490dta data (=1) or not (=0)
50   REAL(wp), PUBLIC ::   rn_abs       !: fraction absorbed in the very near surface (RGB & 2 bands)
51   REAL(wp), PUBLIC ::   rn_si0       !: very near surface depth of extinction      (RGB & 2 bands)
52   REAL(wp), PUBLIC ::   rn_si1       !: deepest depth of extinction (water type I)       (2 bands)
53 
54   ! Module variables
55   REAL(wp) ::   xsi0r                           !: inverse of rn_si0
56   REAL(wp) ::   xsi1r                           !: inverse of rn_si1
57   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_chl   ! structure of input Chl (file informations, fields read)
58   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_kd490 ! structure of input kd490 (file informations, fields read)
59   INTEGER, PUBLIC ::   nksr              ! levels below which the light cannot penetrate ( depth larger than 391 m)
60   REAL(wp), DIMENSION(3,61) ::   rkrgb   !: tabulated attenuation coefficients for RGB absorption
61
62   !! * Substitutions
63#  include "domzgr_substitute.h90"
64#  include "vectopt_loop_substitute.h90"
65   !!----------------------------------------------------------------------
66   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
67   !! $Id$
68   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
69   !!----------------------------------------------------------------------
70CONTAINS
71
72   SUBROUTINE tra_qsr( kt )
73      !!----------------------------------------------------------------------
74      !!                  ***  ROUTINE tra_qsr  ***
75      !!
76      !! ** Purpose :   Compute the temperature trend due to the solar radiation
77      !!      penetration and add it to the general temperature trend.
78      !!
79      !! ** Method  : The profile of the solar radiation within the ocean is defined
80      !!      through 2 wavebands (rn_si0,rn_si1) or 3 wavebands (RGB) and a ratio rn_abs
81      !!      Considering the 2 wavebands case:
82      !!         I(k) = Qsr*( rn_abs*EXP(z(k)/rn_si0) + (1.-rn_abs)*EXP(z(k)/rn_si1) )
83      !!         The temperature trend associated with the solar radiation penetration
84      !!         is given by : zta = 1/e3t dk[ I ] / (rau0*Cp)
85      !!         At the bottom, boudary condition for the radiation is no flux :
86      !!      all heat which has not been absorbed in the above levels is put
87      !!      in the last ocean level.
88      !!         In z-coordinate case, the computation is only done down to the
89      !!      level where I(k) < 1.e-15 W/m2. In addition, the coefficients
90      !!      used for the computation are calculated one for once as they
91      !!      depends on k only.
92      !!
93      !! ** Action  : - update ta with the penetrative solar radiation trend
94      !!              - save the trend in ttrd ('key_trdtra')
95      !!
96      !! Reference  : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp.
97      !!              Lengaigne et al. 2007, Clim. Dyn., V28, 5, 503-516.
98      !!----------------------------------------------------------------------
99      !
100      INTEGER, INTENT(in) ::   kt     ! ocean time-step
101      !
102      INTEGER  ::   ji, jj, jk           ! dummy loop indices
103      INTEGER  ::   irgb                 ! local integers
104      REAL(wp) ::   zchl, zcoef, zfact   ! local scalars
105      REAL(wp) ::   zc0, zc1, zc2, zc3   !    -         -
106      REAL(wp) ::   zzc0, zzc1, zzc2, zzc3   !    -         -
107      REAL(wp) ::   zz0, zz1, z1_e3t     !    -         -
108      REAL(wp), POINTER, DIMENSION(:,:  ) :: zekb, zekg, zekr
109      REAL(wp), POINTER, DIMENSION(:,:,:) :: ze0, ze1, ze2, ze3, zea, ztrdt
110      !!----------------------------------------------------------------------
111      !
112      IF( nn_timing == 1 )  CALL timing_start('tra_qsr')
113      !
114      CALL wrk_alloc( jpi, jpj,      zekb, zekg, zekr        ) 
115      CALL wrk_alloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
116      !
117      IF( kt == nit000 ) THEN
118         IF(lwp) WRITE(numout,*)
119         IF(lwp) WRITE(numout,*) 'tra_qsr : penetration of the surface solar radiation'
120         IF(lwp) WRITE(numout,*) '~~~~~~~'
121         IF( .NOT.ln_traqsr )   RETURN
122      ENDIF
123
124      IF( l_trdtra ) THEN      ! Save ta and sa trends
125         CALL wrk_alloc( jpi, jpj, jpk, ztrdt ) 
126         ztrdt(:,:,:) = tsa(:,:,:,jp_tem)
127      ENDIF
128
129      !                                        Set before qsr tracer content field
130      !                                        ***********************************
131      IF( kt == nit000 ) THEN                     ! Set the forcing field at nit000 - 1
132         !                                        ! -----------------------------------
133         qsr_hc(:,:,:) = 0.e0
134         !
135         IF( ln_rstart .AND.    &                    ! Restart: read in restart file
136              & iom_varid( numror, 'qsr_hc_b', ldstop = .FALSE. ) > 0 ) THEN
137            IF(lwp) WRITE(numout,*) '          nit000-1 qsr tracer content forcing field red in the restart file'
138            zfact = 0.5e0
139            CALL iom_get( numror, jpdom_autoglo, 'qsr_hc_b', qsr_hc_b )   ! before heat content trend due to Qsr flux
140         ELSE                                           ! No restart or restart not found: Euler forward time stepping
141            zfact = 1.e0
142            qsr_hc_b(:,:,:) = 0.e0
143         ENDIF
144      ELSE                                        ! Swap of forcing field
145         !                                        ! ---------------------
146         zfact = 0.5e0
147         qsr_hc_b(:,:,:) = qsr_hc(:,:,:)
148      ENDIF
149      !                                        Compute now qsr tracer content field
150      !                                        ************************************
151     
152      !                                           ! ============================================== !
153      IF( ln_qsr_spec ) THEN                      !  ERSEM spectral heating                        !
154         !                                        ! ============================================== !
155         DO jk = 1, jpkm1
156           qsr_hc(:,:,jk) = r1_rau0_rcp * ( etot3(:,:,jk) )
157         END DO
158         !                                        Add to the general trend
159         DO jk = 1, jpkm1
160            DO jj = 2, jpjm1
161               DO ji = fs_2, fs_jpim1   ! vector opt.
162                  z1_e3t = zfact / fse3t(ji,jj,jk)
163                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t
164               END DO
165            END DO
166         END DO
167         CALL iom_put( 'qsr3d', etot3 )   ! Shortwave Radiation 3D distribution
168         IF ( ln_qsr_ice ) THEN
169            DO jj = 1, jpj
170               DO ji = 1, jpi
171                  IF ( qsr(ji,jj) /= 0._wp ) THEN
172                     fraqsr_1lev(ji,jj) = ( qsr_hc(ji,jj,1) / ( r1_rau0_rcp * qsr(ji,jj) ) )
173                  ELSE
174                     fraqsr_1lev(ji,jj) = 1.
175                  ENDIF
176               END DO
177            END DO
178         ENDIF
179         !
180
181         !                                        ! ============================================== !
182      ELSEIF( lk_qsr_bio .AND. ln_qsr_bio ) THEN      !  bio-model fluxes  : all vertical coordinates  !
183         !                                        ! ============================================== !
184         DO jk = 1, jpkm1
185            qsr_hc(:,:,jk) = r1_rau0_rcp * ( etot3(:,:,jk) - etot3(:,:,jk+1) )
186         END DO
187         !                                        Add to the general trend
188         DO jk = 1, jpkm1
189            DO jj = 2, jpjm1 
190               DO ji = fs_2, fs_jpim1   ! vector opt.
191                  z1_e3t = zfact / fse3t(ji,jj,jk)
192                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t
193               END DO
194            END DO
195         END DO
196         CALL iom_put( 'qsr3d', etot3 )   ! Shortwave Radiation 3D distribution
197         ! clem: store attenuation coefficient of the first ocean level
198         IF ( ln_qsr_ice ) THEN
199            DO jj = 1, jpj
200               DO ji = 1, jpi
201                  IF ( qsr(ji,jj) /= 0._wp ) THEN
202                     fraqsr_1lev(ji,jj) = ( qsr_hc(ji,jj,1) / ( r1_rau0_rcp * qsr(ji,jj) ) )
203                  ELSE
204                     fraqsr_1lev(ji,jj) = 1.
205                  ENDIF
206               END DO
207            END DO
208         ENDIF
209         !                                        ! ============================================== !
210      ELSE                                        !  Ocean alone :
211         !                                        ! ============================================== !
212         !
213         !                                                ! ------------------------- !
214         IF( ln_qsr_rgb) THEN                             !  R-G-B  light penetration !
215            !                                             ! ------------------------- !
216            ! Set chlorophyl concentration
217            IF( nn_chldta == 1 .OR. lk_vvl ) THEN            !*  Variable Chlorophyll or ocean volume
218               !
219               IF( nn_chldta == 1 ) THEN                             !*  Variable Chlorophyll
220                  !
221                  CALL fld_read( kt, 1, sf_chl )                         ! Read Chl data and provides it at the current time step
222                  !         
223!CDIR COLLAPSE
224!CDIR NOVERRCHK
225                  DO jj = 1, jpj                                         ! Separation in R-G-B depending of the surface Chl
226!CDIR NOVERRCHK
227                     DO ji = 1, jpi
228                        zchl = MIN( 10. , MAX( 0.03, sf_chl(1)%fnow(ji,jj,1) ) )
229                        irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 )
230                        zekb(ji,jj) = rkrgb(1,irgb)
231                        zekg(ji,jj) = rkrgb(2,irgb)
232                        zekr(ji,jj) = rkrgb(3,irgb)
233                     END DO
234                  END DO
235               ELSE                                            ! Variable ocean volume but constant chrlorophyll
236                  zchl = 0.05                                     ! constant chlorophyll
237                  irgb = NINT( 41 + 20.*LOG10( zchl ) + 1.e-15 )
238                  zekb(:,:) = rkrgb(1,irgb)                       ! Separation in R-G-B depending of the chlorophyll
239                  zekg(:,:) = rkrgb(2,irgb)
240                  zekr(:,:) = rkrgb(3,irgb)
241               ENDIF
242               !
243               zcoef  = ( 1. - rn_abs ) / 3.e0                        ! equi-partition in R-G-B
244               ze0(:,:,1) = rn_abs  * qsr(:,:)
245               ze1(:,:,1) = zcoef * qsr(:,:)
246               ze2(:,:,1) = zcoef * qsr(:,:)
247               ze3(:,:,1) = zcoef * qsr(:,:)
248               zea(:,:,1) =         qsr(:,:)
249               !
250               DO jk = 2, nksr+1
251!CDIR NOVERRCHK
252                  DO jj = 1, jpj
253!CDIR NOVERRCHK   
254                     DO ji = 1, jpi
255                        zc0 = ze0(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * xsi0r     )
256                        zc1 = ze1(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekb(ji,jj) )
257                        zc2 = ze2(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekg(ji,jj) )
258                        zc3 = ze3(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekr(ji,jj) )
259                        ze0(ji,jj,jk) = zc0
260                        ze1(ji,jj,jk) = zc1
261                        ze2(ji,jj,jk) = zc2
262                        ze3(ji,jj,jk) = zc3
263                        zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk)
264                     END DO
265                  END DO
266               END DO
267               ! clem: store attenuation coefficient of the first ocean level
268               IF ( ln_qsr_ice ) THEN
269                  DO jj = 1, jpj
270                     DO ji = 1, jpi
271                        zzc0 = rn_abs * EXP( - fse3t(ji,jj,1) * xsi0r     )
272                        zzc1 = zcoef  * EXP( - fse3t(ji,jj,1) * zekb(ji,jj) )
273                        zzc2 = zcoef  * EXP( - fse3t(ji,jj,1) * zekg(ji,jj) )
274                        zzc3 = zcoef  * EXP( - fse3t(ji,jj,1) * zekr(ji,jj) )
275                        fraqsr_1lev(ji,jj) = 1.0 - ( zzc0 + zzc1 + zzc2  + zzc3  ) * tmask(ji,jj,2) 
276                     END DO
277                  END DO
278               ENDIF
279               !
280               DO jk = 1, nksr                                        ! compute and add qsr trend to ta
281                  qsr_hc(:,:,jk) = r1_rau0_rcp * ( zea(:,:,jk) - zea(:,:,jk+1) )
282               END DO
283               zea(:,:,nksr+1:jpk) = 0.e0     ! below 400m set to zero
284               CALL iom_put( 'qsr3d', zea )   ! Shortwave Radiation 3D distribution
285               !
286            ELSE                                                 !*  Constant Chlorophyll
287               DO jk = 1, nksr
288                  qsr_hc(:,:,jk) =  etot3(:,:,jk) * qsr(:,:)
289               END DO
290               ! clem: store attenuation coefficient of the first ocean level
291               IF ( ln_qsr_ice ) THEN
292                  fraqsr_1lev(:,:) = etot3(:,:,1) / r1_rau0_rcp
293               ENDIF
294           ENDIF
295
296         ENDIF
297         !                                                ! ------------------------- !
298         IF( ln_qsr_2bd ) THEN                            !  2 band light penetration !
299            !                                             ! ------------------------- !
300            !
301            IF( lk_vvl ) THEN                                  !* variable volume
302               zz0   =        rn_abs   * r1_rau0_rcp
303               zz1   = ( 1. - rn_abs ) * r1_rau0_rcp
304               DO jk = 1, nksr                    ! solar heat absorbed at T-point in the top 400m
305                  DO jj = 1, jpj
306                     DO ji = 1, jpi
307                        zc0 = zz0 * EXP( -fsdepw(ji,jj,jk  )*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk  )*xsi1r )
308                        zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r )
309                        qsr_hc(ji,jj,jk) = qsr(ji,jj) * ( zc0*tmask(ji,jj,jk) - zc1*tmask(ji,jj,jk+1) ) 
310                     END DO
311                  END DO
312               END DO
313               ! clem: store attenuation coefficient of the first ocean level
314               IF ( ln_qsr_ice ) THEN
315                  DO jj = 1, jpj
316                     DO ji = 1, jpi
317                        zc0 = zz0 * EXP( -fsdepw(ji,jj,1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,1)*xsi1r )
318                        zc1 = zz0 * EXP( -fsdepw(ji,jj,2)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,2)*xsi1r )
319                        fraqsr_1lev(ji,jj) = ( zc0*tmask(ji,jj,1) - zc1*tmask(ji,jj,2) ) / r1_rau0_rcp
320                     END DO
321                  END DO
322               ENDIF
323            ELSE                                               !* constant volume: coef. computed one for all
324               DO jk = 1, nksr
325                  DO jj = 2, jpjm1
326                     DO ji = fs_2, fs_jpim1   ! vector opt.
327                        ! (ISF) no light penetration below the ice shelves         
328                        qsr_hc(ji,jj,jk) =  etot3(ji,jj,jk) * qsr(ji,jj) * tmask(ji,jj,1)
329                     END DO
330                  END DO
331               END DO
332               ! clem: store attenuation coefficient of the first ocean level
333               IF ( ln_qsr_ice ) THEN
334                  fraqsr_1lev(:,:) = etot3(:,:,1) / r1_rau0_rcp
335               ENDIF
336               !
337            ENDIF
338            !
339         ENDIF
340! slwa
341         IF( nn_kd490dta == 1 ) THEN                      !  use KD490 data read in   !
342            !                                             ! ------------------------- !
343               nksr = jpk - 1
344               !
345               CALL fld_read( kt, 1, sf_kd490 )     ! Read kd490 data and provide it at the current time step
346               !
347               zcoef  = ( 1. - rn_abs )
348               ze0(:,:,1) = rn_abs  * qsr(:,:)
349               ze1(:,:,1) = zcoef * qsr(:,:)
350               zea(:,:,1) =         qsr(:,:)
351               !
352               DO jk = 2, nksr+1
353!CDIR NOVERRCHK
354                  DO jj = 1, jpj
355!CDIR NOVERRCHK   
356                     DO ji = 1, jpi
357                        zc0 = ze0(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * xsi0r     )
358                        zc1 = ze1(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * sf_kd490(1)%fnow(ji,jj,1) )
359                        ze0(ji,jj,jk) = zc0
360                        ze1(ji,jj,jk) = zc1
361                        zea(ji,jj,jk) = ( zc0 + zc1 ) * tmask(ji,jj,jk)
362                     END DO
363                  END DO
364               END DO
365               ! clem: store attenuation coefficient of the first ocean level
366               IF ( ln_qsr_ice ) THEN
367                  DO jj = 1, jpj
368                     DO ji = 1, jpi
369                        zzc0 = rn_abs * EXP( - fse3t(ji,jj,1) * xsi0r     )
370                        zzc1 = zcoef  * EXP( - fse3t(ji,jj,1) * sf_kd490(1)%fnow(ji,jj,1) )
371                        fraqsr_1lev(ji,jj) = 1.0 - ( zzc0 + zzc1 ) * tmask(ji,jj,2) 
372                     END DO
373                  END DO
374               ENDIF
375               !
376               DO jk = 1, nksr                                        ! compute and add qsr trend to ta
377                  qsr_hc(:,:,jk) = r1_rau0_rcp * ( zea(:,:,jk) - zea(:,:,jk+1) )
378               END DO
379               zea(:,:,nksr+1:jpk) = 0.e0     !
380               CALL iom_put( 'qsr3d', zea )   ! Shortwave Radiation 3D distribution
381               !
382        ENDIF   ! use KD490 data
383!slwa
384         !
385         !                                        Add to the general trend
386         DO jk = 1, nksr
387            DO jj = 2, jpjm1 
388               DO ji = fs_2, fs_jpim1   ! vector opt.
389                  z1_e3t = zfact / fse3t(ji,jj,jk)
390                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t
391               END DO
392            END DO
393         END DO
394         !
395      ENDIF
396      !
397      IF( lrst_oce ) THEN   !                  Write in the ocean restart file
398         !                                     *******************************
399         IF(lwp) WRITE(numout,*)
400         IF(lwp) WRITE(numout,*) 'qsr tracer content forcing field written in ocean restart file ',   &
401            &                    'at it= ', kt,' date= ', ndastp
402         IF(lwp) WRITE(numout,*) '~~~~'
403         CALL iom_rstput( kt, nitrst, numrow, 'qsr_hc_b'   , qsr_hc      )
404         CALL iom_rstput( kt, nitrst, numrow, 'fraqsr_1lev', fraqsr_1lev )   ! default definition in sbcssm
405         !
406      ENDIF
407
408      IF( l_trdtra ) THEN     ! qsr tracers trends saved for diagnostics
409         ztrdt(:,:,:) = tsa(:,:,:,jp_tem) - ztrdt(:,:,:)
410         CALL trd_tra( kt, 'TRA', jp_tem, jptra_qsr, ztrdt )
411         CALL wrk_dealloc( jpi, jpj, jpk, ztrdt ) 
412      ENDIF
413      !                       ! print mean trends (used for debugging)
414      IF(ln_ctl)   CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' qsr  - Ta: ', mask1=tmask, clinfo3='tra-ta' )
415      !
416      CALL wrk_dealloc( jpi, jpj,      zekb, zekg, zekr        ) 
417      CALL wrk_dealloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
418      !
419      IF( nn_timing == 1 )  CALL timing_stop('tra_qsr')
420      !
421   END SUBROUTINE tra_qsr
422
423
424   SUBROUTINE tra_qsr_init
425      !!----------------------------------------------------------------------
426      !!                  ***  ROUTINE tra_qsr_init  ***
427      !!
428      !! ** Purpose :   Initialization for the penetrative solar radiation
429      !!
430      !! ** Method  :   The profile of solar radiation within the ocean is set
431      !!      from two length scale of penetration (rn_si0,rn_si1) and a ratio
432      !!      (rn_abs). These parameters are read in the namtra_qsr namelist. The
433      !!      default values correspond to clear water (type I in Jerlov'
434      !!      (1968) classification.
435      !!         called by tra_qsr at the first timestep (nit000)
436      !!
437      !! ** Action  : - initialize rn_si0, rn_si1 and rn_abs
438      !!
439      !! Reference : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp.
440      !!----------------------------------------------------------------------
441      !
442      INTEGER  ::   ji, jj, jk                   ! dummy loop indices
443      INTEGER  ::   irgb, ierror, ioptio, nqsr   ! local integer
444      INTEGER  ::   ios                          ! Local integer output status for namelist read
445      REAL(wp) ::   zz0, zc0  , zc1, zcoef       ! local scalars
446      REAL(wp) ::   zz1, zc2  , zc3, zchl        !   -      -
447      REAL(wp), POINTER, DIMENSION(:,:  ) :: zekb, zekg, zekr
448      REAL(wp), POINTER, DIMENSION(:,:,:) :: ze0, ze1, ze2, ze3, zea
449      !
450      CHARACTER(len=100) ::   cn_dir   ! Root directory for location of ssr files
451      TYPE(FLD_N)        ::   sn_chl   ! informations about the chlorofyl field to be read
452      TYPE(FLD_N)        ::   sn_kd490 ! informations about the kd490 field to be read
453      !!
454      NAMELIST/namtra_qsr/  sn_chl, sn_kd490, cn_dir, ln_traqsr, ln_qsr_rgb, ln_qsr_2bd, ln_qsr_bio, ln_qsr_ice,  &
455         &                  ln_qsr_spec, nn_chldta, rn_abs, rn_si0, rn_si1, nn_kd490dta
456      !!----------------------------------------------------------------------
457
458      !
459      IF( nn_timing == 1 )  CALL timing_start('tra_qsr_init')
460      !
461      CALL wrk_alloc( jpi, jpj,      zekb, zekg, zekr        ) 
462      CALL wrk_alloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
463      !
464
465      REWIND( numnam_ref )              ! Namelist namtra_qsr in reference namelist : Ratio and length of penetration
466      READ  ( numnam_ref, namtra_qsr, IOSTAT = ios, ERR = 901)
467901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_qsr in reference namelist', lwp )
468
469      REWIND( numnam_cfg )              !  Namelist namtra_qsr in configuration namelist : Ratio and length of penetration
470      READ  ( numnam_cfg, namtra_qsr, IOSTAT = ios, ERR = 902 )
471902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_qsr in configuration namelist', lwp )
472      IF(lwm) WRITE ( numond, namtra_qsr )
473      !
474      IF(lwp) THEN                ! control print
475         WRITE(numout,*)
476         WRITE(numout,*) 'tra_qsr_init : penetration of the surface solar radiation'
477         WRITE(numout,*) '~~~~~~~~~~~~'
478         WRITE(numout,*) '   Namelist namtra_qsr : set the parameter of penetration'
479         WRITE(numout,*) '      Light penetration (T) or not (F)         ln_traqsr  = ', ln_traqsr
480         WRITE(numout,*) '      RGB (Red-Green-Blue) light penetration   ln_qsr_rgb = ', ln_qsr_rgb
481         WRITE(numout,*) '      2 band               light penetration   ln_qsr_2bd = ', ln_qsr_2bd
482         WRITE(numout,*) '      bio-model            light penetration   ln_qsr_bio = ', ln_qsr_bio
483         WRITE(numout,*) '      ERSEM spectral heating model             ln_qsr_spec= ', ln_qsr_spec
484         WRITE(numout,*) '      light penetration for ice-model LIM3     ln_qsr_ice = ', ln_qsr_ice
485         WRITE(numout,*) '      RGB : Chl data (=1) or cst value (=0)    nn_chldta  = ', nn_chldta
486         WRITE(numout,*) '      RGB & 2 bands: fraction of light (rn_si1)    rn_abs = ', rn_abs
487         WRITE(numout,*) '      RGB & 2 bands: shortess depth of extinction  rn_si0 = ', rn_si0
488         WRITE(numout,*) '      2 bands: longest depth of extinction         rn_si1 = ', rn_si1
489         WRITE(numout,*) '      read in KD490 data                       nn_kd490dta  = ', nn_kd490dta
490      ENDIF
491
492      IF( ln_traqsr ) THEN     ! control consistency
493         !                     
494         IF( .NOT.lk_qsr_bio .AND. ln_qsr_bio )   THEN
495            CALL ctl_warn( 'No bio model : force ln_qsr_bio = FALSE ' )
496            ln_qsr_bio = .FALSE.
497         ENDIF
498         !
499         ioptio = 0                      ! Parameter control
500         IF( ln_qsr_rgb  )   ioptio = ioptio + 1
501         IF( ln_qsr_2bd  )   ioptio = ioptio + 1
502         IF( ln_qsr_bio  )   ioptio = ioptio + 1
503         IF( ln_qsr_spec )   ioptio = ioptio + 1
504         IF( nn_kd490dta == 1 )   ioptio = ioptio + 1
505         !
506         IF( ioptio /= 1 ) &
507            CALL ctl_stop( '          Choose ONE type of light penetration in namelist namtra_qsr',  &
508            &              ' 2 bands, 3 RGB bands or bio-model light penetration' )
509         !
510         IF( ln_qsr_rgb .AND. nn_chldta == 0 )   nqsr =  1 
511         IF( ln_qsr_rgb .AND. nn_chldta == 1 )   nqsr =  2
512         IF( ln_qsr_2bd                      )   nqsr =  3
513         IF( ln_qsr_bio                      )   nqsr =  4
514         IF( nn_kd490dta == 1                )   nqsr =  5
515         IF( ln_qsr_spec                     )   nqsr =  6
516         !
517         IF(lwp) THEN                   ! Print the choice
518            WRITE(numout,*)
519            IF( nqsr ==  1 )   WRITE(numout,*) '         R-G-B   light penetration - Constant Chlorophyll'
520            IF( nqsr ==  2 )   WRITE(numout,*) '         R-G-B   light penetration - Chl data '
521            IF( nqsr ==  3 )   WRITE(numout,*) '         2 bands light penetration'
522            IF( nqsr ==  4 )   WRITE(numout,*) '         bio-model light penetration'
523            IF( nqsr ==  5 )   WRITE(numout,*) '         KD490 light penetration'
524            IF( nqsr ==  6 )   WRITE(numout,*) '         ERSEM spectral light penetration'
525         ENDIF
526#if ! defined key_fabm
527         !
528         IF( nqsr ==  6 ) THEN
529            CALL ctl_stop( 'ln_qsr_spec=.true. so trying to use ERSEM spectral light penetration', &
530               &           'but not running with ERSEM' )
531         ENDIF
532#endif
533         !
534      ENDIF
535      !                          ! ===================================== !
536      IF( ln_traqsr  ) THEN      !  Initialisation of Light Penetration  ! 
537         !                       ! ===================================== !
538         !
539         xsi0r = 1.e0 / rn_si0
540         xsi1r = 1.e0 / rn_si1
541         IF( nn_kd490dta == 1 ) THEN           !* KD490 data : set sf_kd490 structure
542            IF(lwp) WRITE(numout,*)
543            IF(lwp) WRITE(numout,*) '        KD490 read in a file'
544            ALLOCATE( sf_kd490(1), STAT=ierror )
545            IF( ierror > 0 ) THEN
546               CALL ctl_stop( 'tra_qsr_init: unable to allocate sf_kd490 structure' )   ;   RETURN
547            ENDIF
548            ALLOCATE( sf_kd490(1)%fnow(jpi,jpj,1)   )
549            IF( sn_kd490%ln_tint )ALLOCATE( sf_kd490(1)%fdta(jpi,jpj,1,2) )
550            !                                        ! fill sf_kd490 with sn_kd490 and control print
551            CALL fld_fill( sf_kd490, (/ sn_kd490 /), cn_dir, 'tra_qsr_init',   &
552               &                                         'Solar penetration function of read KD490', 'namtra_qsr' )
553         !                                ! ---------------------------------- !
554         ELSEIF( ln_qsr_rgb ) THEN            !  Red-Green-Blue light penetration  !
555            !                             ! ---------------------------------- !
556            !
557            CALL trc_oce_rgb( rkrgb )           !* tabulated attenuation coef.
558            !
559            !                                   !* level of light extinction
560            IF(  ln_sco ) THEN   ;   nksr = jpkm1
561            ELSE                 ;   nksr = trc_oce_ext_lev( r_si2, 0.33e2 )
562            ENDIF
563
564            IF(lwp) WRITE(numout,*) '        level of light extinction = ', nksr, ' ref depth = ', gdepw_1d(nksr+1), ' m'
565            !
566            IF( nn_chldta == 1 ) THEN           !* Chl data : set sf_chl structure
567               IF(lwp) WRITE(numout,*)
568               IF(lwp) WRITE(numout,*) '        Chlorophyll read in a file'
569               ALLOCATE( sf_chl(1), STAT=ierror )
570               IF( ierror > 0 ) THEN
571                  CALL ctl_stop( 'tra_qsr_init: unable to allocate sf_chl structure' )   ;   RETURN
572               ENDIF
573               ALLOCATE( sf_chl(1)%fnow(jpi,jpj,1)   )
574               IF( sn_chl%ln_tint )ALLOCATE( sf_chl(1)%fdta(jpi,jpj,1,2) )
575               !                                        ! fill sf_chl with sn_chl and control print
576               CALL fld_fill( sf_chl, (/ sn_chl /), cn_dir, 'tra_qsr_init',   &
577                  &                                         'Solar penetration function of read chlorophyll', 'namtra_qsr' )
578               !
579            ELSE                                !* constant Chl : compute once for all the distribution of light (etot3)
580               IF(lwp) WRITE(numout,*)
581               IF(lwp) WRITE(numout,*) '        Constant Chlorophyll concentration = 0.05'
582               IF( lk_vvl ) THEN                   ! variable volume
583                  IF(lwp) WRITE(numout,*) '        key_vvl: light distribution will be computed at each time step'
584               ELSE                                ! constant volume: computes one for all
585                  IF(lwp) WRITE(numout,*) '        fixed volume: light distribution computed one for all'
586                  !
587                  zchl = 0.05                                 ! constant chlorophyll
588                  irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 )
589                  zekb(:,:) = rkrgb(1,irgb)                   ! Separation in R-G-B depending of the chlorophyll
590                  zekg(:,:) = rkrgb(2,irgb)
591                  zekr(:,:) = rkrgb(3,irgb)
592                  !
593                  zcoef = ( 1. - rn_abs ) / 3.e0              ! equi-partition in R-G-B
594                  ze0(:,:,1) = rn_abs
595                  ze1(:,:,1) = zcoef
596                  ze2(:,:,1) = zcoef 
597                  ze3(:,:,1) = zcoef
598                  zea(:,:,1) = tmask(:,:,1)                   ! = ( ze0+ze1+z2+ze3 ) * tmask
599               
600                  DO jk = 2, nksr+1
601!CDIR NOVERRCHK
602                     DO jj = 1, jpj
603!CDIR NOVERRCHK   
604                        DO ji = 1, jpi
605                           zc0 = ze0(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * xsi0r     )
606                           zc1 = ze1(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * zekb(ji,jj) )
607                           zc2 = ze2(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * zekg(ji,jj) )
608                           zc3 = ze3(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * zekr(ji,jj) )
609                           ze0(ji,jj,jk) = zc0
610                           ze1(ji,jj,jk) = zc1
611                           ze2(ji,jj,jk) = zc2
612                           ze3(ji,jj,jk) = zc3
613                           zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk)
614                        END DO
615                     END DO
616                  END DO 
617                  !
618                  DO jk = 1, nksr
619                     ! (ISF) no light penetration below the ice shelves
620                     etot3(:,:,jk) = r1_rau0_rcp * ( zea(:,:,jk) - zea(:,:,jk+1) ) * tmask(:,:,1)
621                  END DO
622                  etot3(:,:,nksr+1:jpk) = 0.e0                ! below 400m set to zero
623               ENDIF
624            ENDIF
625            !
626         ENDIF
627            !                             ! ---------------------------------- !
628         IF( ln_qsr_2bd ) THEN            !    2 bands    light penetration    !
629            !                             ! ---------------------------------- !
630            !
631            !                                ! level of light extinction
632            nksr = trc_oce_ext_lev( rn_si1, 1.e2 )
633            IF(lwp) THEN
634               WRITE(numout,*)
635            IF(lwp) WRITE(numout,*) '        level of light extinction = ', nksr, ' ref depth = ', gdepw_1d(nksr+1), ' m'
636            ENDIF
637            !
638            IF( lk_vvl ) THEN                   ! variable volume
639               IF(lwp) WRITE(numout,*) '        key_vvl: light distribution will be computed at each time step'
640            ELSE                                ! constant volume: computes one for all
641               zz0 =        rn_abs   * r1_rau0_rcp
642               zz1 = ( 1. - rn_abs ) * r1_rau0_rcp
643               DO jk = 1, nksr                    !*  solar heat absorbed at T-point computed once for all
644                  DO jj = 1, jpj                              ! top 400 meters
645                     DO ji = 1, jpi
646                        zc0 = zz0 * EXP( -fsdepw(ji,jj,jk  )*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk  )*xsi1r )
647                        zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r )
648                        etot3(ji,jj,jk) = (  zc0 * tmask(ji,jj,jk) - zc1 * tmask(ji,jj,jk+1)  ) * tmask(ji,jj,1) 
649                     END DO
650                  END DO
651               END DO
652               etot3(:,:,nksr+1:jpk) = 0.e0                   ! below 400m set to zero
653               !
654            ENDIF
655         ENDIF
656         !                       ! ===================================== !
657      ELSE                       !        No light penetration           !                   
658         !                       ! ===================================== !
659         IF(lwp) THEN
660            WRITE(numout,*)
661            WRITE(numout,*) 'tra_qsr_init : NO solar flux penetration'
662            WRITE(numout,*) '~~~~~~~~~~~~'
663         ENDIF
664      ENDIF
665      !
666      ! initialisation of fraqsr_1lev used in sbcssm
667      IF( iom_varid( numror, 'fraqsr_1lev', ldstop = .FALSE. ) > 0 ) THEN
668         CALL iom_get( numror, jpdom_autoglo, 'fraqsr_1lev'  , fraqsr_1lev  )
669      ELSE
670         fraqsr_1lev(:,:) = 1._wp   ! default definition
671      ENDIF
672      !
673      CALL wrk_dealloc( jpi, jpj,      zekb, zekg, zekr        ) 
674      CALL wrk_dealloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
675      !
676      IF( nn_timing == 1 )  CALL timing_stop('tra_qsr_init')
677      !
678   END SUBROUTINE tra_qsr_init
679
680   !!======================================================================
681END MODULE traqsr
Note: See TracBrowser for help on using the repository browser.