source: branches/UKMO/AMM15_v3_6_STABLE_package_collate_utils366_fabmv1_v2/NEMOGCM/NEMO/OPA_SRC/TRA/traqsr.F90 @ 13499

Last change on this file since 13499 was 13499, checked in by dford, 13 months ago

Update qsr3d diagnostic for spectral case.

File size: 37.7 KB
Line 
1MODULE traqsr
2   !!======================================================================
3   !!                       ***  MODULE  traqsr  ***
4   !! Ocean physics: solar radiation penetration in the top ocean levels
5   !!======================================================================
6   !! History :  OPA  !  1990-10  (B. Blanke)  Original code
7   !!            7.0  !  1991-11  (G. Madec)
8   !!                 !  1996-01  (G. Madec)  s-coordinates
9   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
10   !!             -   !  2005-11  (G. Madec) zco, zps, sco coordinate
11   !!            3.2  !  2009-04  (G. Madec & NEMO team)
12   !!            4.0  !  2012-05  (C. Rousset) store attenuation coef for use in ice model
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   tra_qsr      : trend due to the solar radiation penetration
17   !!   tra_qsr_init : solar radiation penetration initialization
18   !!----------------------------------------------------------------------
19   USE oce             ! ocean dynamics and active tracers
20   USE dom_oce         ! ocean space and time domain
21   USE sbc_oce         ! surface boundary condition: ocean
22   USE trc_oce         ! share SMS/Ocean variables
23   USE trd_oce        ! trends: ocean variables
24   USE trdtra         ! trends manager: tracers
25   USE in_out_manager  ! I/O manager
26   USE phycst          ! physical constants
27   USE prtctl          ! Print control
28   USE iom             ! I/O manager
29   USE fldread         ! read input fields
30   USE restart         ! ocean restart
31   USE lib_mpp         ! MPP library
32   USE wrk_nemo       ! Memory Allocation
33   USE timing         ! Timing
34#if defined key_fabm
35   USE trc, ONLY: trn  ! FABM variables
36   USE par_fabm        ! FABM parameters
37#endif
38
39   IMPLICIT NONE
40   PRIVATE
41
42   PUBLIC   tra_qsr       ! routine called by step.F90 (ln_traqsr=T)
43   PUBLIC   tra_qsr_init  ! routine called by nemogcm.F90
44
45   !                                 !!* Namelist namtra_qsr: penetrative solar radiation
46   LOGICAL , PUBLIC ::   ln_traqsr    !: light absorption (qsr) flag
47   LOGICAL , PUBLIC ::   ln_qsr_rgb   !: Red-Green-Blue light absorption flag 
48   LOGICAL , PUBLIC ::   ln_qsr_2bd   !: 2 band         light absorption flag
49   LOGICAL , PUBLIC ::   ln_qsr_bio   !: bio-model      light absorption flag
50   LOGICAL , PUBLIC ::   ln_qsr_ice   !: light penetration for ice-model LIM3 (clem)
51   LOGICAL , PUBLIC ::   ln_qsr_spec  !: spectral model heating from ERSEM
52   INTEGER , PUBLIC ::   nn_chldta    !: use Chlorophyll data (=1) or not (=0)
53   INTEGER , PUBLIC ::   nn_kd490dta  !: use kd490dta data (=1) or not (=0)
54   REAL(wp), PUBLIC ::   rn_abs       !: fraction absorbed in the very near surface (RGB & 2 bands)
55   REAL(wp), PUBLIC ::   rn_si0       !: very near surface depth of extinction      (RGB & 2 bands)
56   REAL(wp), PUBLIC ::   rn_si1       !: deepest depth of extinction (water type I)       (2 bands)
57 
58   ! Module variables
59   REAL(wp) ::   xsi0r                           !: inverse of rn_si0
60   REAL(wp) ::   xsi1r                           !: inverse of rn_si1
61   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_chl   ! structure of input Chl (file informations, fields read)
62   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_kd490 ! structure of input kd490 (file informations, fields read)
63   INTEGER, PUBLIC ::   nksr              ! levels below which the light cannot penetrate ( depth larger than 391 m)
64   REAL(wp), DIMENSION(3,61) ::   rkrgb   !: tabulated attenuation coefficients for RGB absorption
65
66   !! * Substitutions
67#  include "domzgr_substitute.h90"
68#  include "vectopt_loop_substitute.h90"
69   !!----------------------------------------------------------------------
70   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
71   !! $Id$
72   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
73   !!----------------------------------------------------------------------
74CONTAINS
75
76   SUBROUTINE tra_qsr( kt )
77      !!----------------------------------------------------------------------
78      !!                  ***  ROUTINE tra_qsr  ***
79      !!
80      !! ** Purpose :   Compute the temperature trend due to the solar radiation
81      !!      penetration and add it to the general temperature trend.
82      !!
83      !! ** Method  : The profile of the solar radiation within the ocean is defined
84      !!      through 2 wavebands (rn_si0,rn_si1) or 3 wavebands (RGB) and a ratio rn_abs
85      !!      Considering the 2 wavebands case:
86      !!         I(k) = Qsr*( rn_abs*EXP(z(k)/rn_si0) + (1.-rn_abs)*EXP(z(k)/rn_si1) )
87      !!         The temperature trend associated with the solar radiation penetration
88      !!         is given by : zta = 1/e3t dk[ I ] / (rau0*Cp)
89      !!         At the bottom, boudary condition for the radiation is no flux :
90      !!      all heat which has not been absorbed in the above levels is put
91      !!      in the last ocean level.
92      !!         In z-coordinate case, the computation is only done down to the
93      !!      level where I(k) < 1.e-15 W/m2. In addition, the coefficients
94      !!      used for the computation are calculated one for once as they
95      !!      depends on k only.
96      !!
97      !! ** Action  : - update ta with the penetrative solar radiation trend
98      !!              - save the trend in ttrd ('key_trdtra')
99      !!
100      !! Reference  : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp.
101      !!              Lengaigne et al. 2007, Clim. Dyn., V28, 5, 503-516.
102      !!----------------------------------------------------------------------
103      !
104      INTEGER, INTENT(in) ::   kt     ! ocean time-step
105      !
106      INTEGER  ::   ji, jj, jk           ! dummy loop indices
107      INTEGER  ::   irgb                 ! local integers
108      REAL(wp) ::   zchl, zcoef, zfact   ! local scalars
109      REAL(wp) ::   zc0, zc1, zc2, zc3   !    -         -
110      REAL(wp) ::   zzc0, zzc1, zzc2, zzc3   !    -         -
111      REAL(wp) ::   zz0, zz1, z1_e3t     !    -         -
112      REAL(wp), POINTER, DIMENSION(:,:  ) :: zekb, zekg, zekr
113      REAL(wp), POINTER, DIMENSION(:,:,:) :: zekb_3d, zekg_3d, zekr_3d
114      REAL(wp), POINTER, DIMENSION(:,:,:) :: ze0, ze1, ze2, ze3, zea, ztrdt
115      !!----------------------------------------------------------------------
116      !
117      IF( nn_timing == 1 )  CALL timing_start('tra_qsr')
118      !
119      CALL wrk_alloc( jpi, jpj,      zekb, zekg, zekr        ) 
120      CALL wrk_alloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
121      CALL wrk_alloc( jpi, jpj, jpk, zekb_3d, zekg_3d, zekr_3d ) 
122      !
123      IF( kt == nit000 ) THEN
124         IF(lwp) WRITE(numout,*)
125         IF(lwp) WRITE(numout,*) 'tra_qsr : penetration of the surface solar radiation'
126         IF(lwp) WRITE(numout,*) '~~~~~~~'
127         IF( .NOT.ln_traqsr )   RETURN
128      ENDIF
129
130      IF( l_trdtra ) THEN      ! Save ta and sa trends
131         CALL wrk_alloc( jpi, jpj, jpk, ztrdt ) 
132         ztrdt(:,:,:) = tsa(:,:,:,jp_tem)
133      ENDIF
134
135      !                                        Set before qsr tracer content field
136      !                                        ***********************************
137      IF( kt == nit000 ) THEN                     ! Set the forcing field at nit000 - 1
138         !                                        ! -----------------------------------
139         qsr_hc(:,:,:) = 0.e0
140         !
141         IF( ln_rstart .AND.    &                    ! Restart: read in restart file
142              & iom_varid( numror, 'qsr_hc_b', ldstop = .FALSE. ) > 0 ) THEN
143            IF(lwp) WRITE(numout,*) '          nit000-1 qsr tracer content forcing field red in the restart file'
144            zfact = 0.5e0
145            CALL iom_get( numror, jpdom_autoglo, 'qsr_hc_b', qsr_hc_b )   ! before heat content trend due to Qsr flux
146         ELSE                                           ! No restart or restart not found: Euler forward time stepping
147            zfact = 1.e0
148            qsr_hc_b(:,:,:) = 0.e0
149         ENDIF
150      ELSE                                        ! Swap of forcing field
151         !                                        ! ---------------------
152         zfact = 0.5e0
153         qsr_hc_b(:,:,:) = qsr_hc(:,:,:)
154      ENDIF
155      !                                        Compute now qsr tracer content field
156      !                                        ************************************
157     
158      !                                           ! ============================================== !
159      IF( ln_qsr_spec ) THEN                      !  ERSEM spectral heating                        !
160         !                                        ! ============================================== !
161         DO jk = 1, jpkm1
162           qsr_hc(:,:,jk) = r1_rau0_rcp * ( etot3(:,:,jk) )
163         END DO
164         !                                        Add to the general trend
165         DO jk = 1, jpkm1
166            DO jj = 2, jpjm1
167               DO ji = fs_2, fs_jpim1   ! vector opt.
168                  z1_e3t = zfact / fse3t(ji,jj,jk)
169                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t
170               END DO
171            END DO
172         END DO
173         zea(:,:,:) = etot3(:,:,:) * tmask(:,:,:)
174         DO jk = jpkm1, 1, -1
175            zea(:,:,jk) = zea(:,:,jk) + zea(:,:,jk+1)
176         END DO
177         CALL iom_put( 'qsr3d', zea )   ! Shortwave Radiation 3D distribution
178         IF ( ln_qsr_ice ) THEN
179            DO jj = 1, jpj
180               DO ji = 1, jpi
181                  IF ( qsr(ji,jj) /= 0._wp ) THEN
182                     fraqsr_1lev(ji,jj) = ( qsr_hc(ji,jj,1) / ( r1_rau0_rcp * qsr(ji,jj) ) )
183                  ELSE
184                     fraqsr_1lev(ji,jj) = 1.
185                  ENDIF
186               END DO
187            END DO
188         ENDIF
189         !
190
191         !                                        ! ============================================== !
192      ELSEIF( lk_qsr_bio .AND. ln_qsr_bio ) THEN      !  bio-model fluxes  : all vertical coordinates  !
193         !                                        ! ============================================== !
194         DO jk = 1, jpkm1
195            qsr_hc(:,:,jk) = r1_rau0_rcp * ( etot3(:,:,jk) - etot3(:,:,jk+1) )
196         END DO
197         !                                        Add to the general trend
198         DO jk = 1, jpkm1
199            DO jj = 2, jpjm1 
200               DO ji = fs_2, fs_jpim1   ! vector opt.
201                  z1_e3t = zfact / fse3t(ji,jj,jk)
202                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t
203               END DO
204            END DO
205         END DO
206         CALL iom_put( 'qsr3d', etot3 )   ! Shortwave Radiation 3D distribution
207         ! clem: store attenuation coefficient of the first ocean level
208         IF ( ln_qsr_ice ) THEN
209            DO jj = 1, jpj
210               DO ji = 1, jpi
211                  IF ( qsr(ji,jj) /= 0._wp ) THEN
212                     fraqsr_1lev(ji,jj) = ( qsr_hc(ji,jj,1) / ( r1_rau0_rcp * qsr(ji,jj) ) )
213                  ELSE
214                     fraqsr_1lev(ji,jj) = 1.
215                  ENDIF
216               END DO
217            END DO
218         ENDIF
219         !                                        ! ============================================== !
220      ELSE                                        !  Ocean alone :
221         !                                        ! ============================================== !
222         !
223         !                                                ! ------------------------- !
224         IF( ln_qsr_rgb) THEN                             !  R-G-B  light penetration !
225            !                                             ! ------------------------- !
226            ! Set chlorophyl concentration
227            IF( nn_chldta == 2 .OR. nn_chldta == 1 .OR. lk_vvl ) THEN   !*  Variable Chlorophyll or ocean volume
228               !
229               IF( nn_chldta == 2 ) THEN
230                  DO jk = 1, nksr+1
231                     DO jj = 1, jpj
232                        DO ji = 1, jpi
233#if defined key_fabm
234                           zchl = trn(ji,jj,jk,jp_fabm_m1+jp_fabm_chl1) + trn(ji,jj,jk,jp_fabm_m1+jp_fabm_chl2) + &
235                              &   trn(ji,jj,jk,jp_fabm_m1+jp_fabm_chl3) + trn(ji,jj,jk,jp_fabm_m1+jp_fabm_chl4)
236#endif
237                           zchl = MIN(  10. , MAX( 0.03, zchl )  )
238                           irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 )
239                           !                                                         
240                           zekb_3d(ji,jj,jk) = rkrgb(1,irgb)
241                           zekg_3d(ji,jj,jk) = rkrgb(2,irgb)
242                           zekr_3d(ji,jj,jk) = rkrgb(3,irgb)
243                        END DO
244                     END DO
245                  END DO
246                  !
247               ELSEIF( nn_chldta == 1 ) THEN                             !*  Variable Chlorophyll
248                  !
249                  CALL fld_read( kt, 1, sf_chl )                         ! Read Chl data and provides it at the current time step
250                  !         
251!CDIR COLLAPSE
252!CDIR NOVERRCHK
253                  DO jj = 1, jpj                                         ! Separation in R-G-B depending of the surface Chl
254!CDIR NOVERRCHK
255                     DO ji = 1, jpi
256                        zchl = MIN( 10. , MAX( 0.03, sf_chl(1)%fnow(ji,jj,1) ) )
257                        irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 )
258                        zekb(ji,jj) = rkrgb(1,irgb)
259                        zekg(ji,jj) = rkrgb(2,irgb)
260                        zekr(ji,jj) = rkrgb(3,irgb)
261                     END DO
262                  END DO
263               ELSE                                            ! Variable ocean volume but constant chrlorophyll
264                  zchl = 0.05                                     ! constant chlorophyll
265                  irgb = NINT( 41 + 20.*LOG10( zchl ) + 1.e-15 )
266                  zekb(:,:) = rkrgb(1,irgb)                       ! Separation in R-G-B depending of the chlorophyll
267                  zekg(:,:) = rkrgb(2,irgb)
268                  zekr(:,:) = rkrgb(3,irgb)
269               ENDIF
270               !
271               zcoef  = ( 1. - rn_abs ) / 3.e0                        ! equi-partition in R-G-B
272               ze0(:,:,1) = rn_abs  * qsr(:,:)
273               ze1(:,:,1) = zcoef * qsr(:,:)
274               ze2(:,:,1) = zcoef * qsr(:,:)
275               ze3(:,:,1) = zcoef * qsr(:,:)
276               zea(:,:,1) =         qsr(:,:)
277               !
278               DO jk = 2, nksr+1
279                  IF( nn_chldta == 2 ) THEN
280                     zekb(:,:) = zekb_3d(:,:,jk)
281                     zekg(:,:) = zekg_3d(:,:,jk)
282                     zekr(:,:) = zekr_3d(:,:,jk)
283                  ENDIF
284!CDIR NOVERRCHK
285                  DO jj = 1, jpj
286!CDIR NOVERRCHK   
287                     DO ji = 1, jpi
288                        zc0 = ze0(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * xsi0r     )
289                        zc1 = ze1(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekb(ji,jj) )
290                        zc2 = ze2(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekg(ji,jj) )
291                        zc3 = ze3(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekr(ji,jj) )
292                        ze0(ji,jj,jk) = zc0
293                        ze1(ji,jj,jk) = zc1
294                        ze2(ji,jj,jk) = zc2
295                        ze3(ji,jj,jk) = zc3
296                        zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk)
297                     END DO
298                  END DO
299               END DO
300               ! clem: store attenuation coefficient of the first ocean level
301               IF ( ln_qsr_ice ) THEN
302                  IF( nn_chldta == 2 ) THEN
303                     zekb(:,:) = zekb_3d(:,:,1)
304                     zekg(:,:) = zekg_3d(:,:,1)
305                     zekr(:,:) = zekr_3d(:,:,1)
306                  ENDIF
307                  DO jj = 1, jpj
308                     DO ji = 1, jpi
309                        zzc0 = rn_abs * EXP( - fse3t(ji,jj,1) * xsi0r     )
310                        zzc1 = zcoef  * EXP( - fse3t(ji,jj,1) * zekb(ji,jj) )
311                        zzc2 = zcoef  * EXP( - fse3t(ji,jj,1) * zekg(ji,jj) )
312                        zzc3 = zcoef  * EXP( - fse3t(ji,jj,1) * zekr(ji,jj) )
313                        fraqsr_1lev(ji,jj) = 1.0 - ( zzc0 + zzc1 + zzc2  + zzc3  ) * tmask(ji,jj,2) 
314                     END DO
315                  END DO
316               ENDIF
317               !
318               DO jk = 1, nksr                                        ! compute and add qsr trend to ta
319                  qsr_hc(:,:,jk) = r1_rau0_rcp * ( zea(:,:,jk) - zea(:,:,jk+1) )
320               END DO
321               zea(:,:,nksr+1:jpk) = 0.e0     ! below 400m set to zero
322               CALL iom_put( 'qsr3d', zea )   ! Shortwave Radiation 3D distribution
323               !
324            ELSE                                                 !*  Constant Chlorophyll
325               DO jk = 1, nksr
326                  qsr_hc(:,:,jk) =  etot3(:,:,jk) * qsr(:,:)
327               END DO
328               ! clem: store attenuation coefficient of the first ocean level
329               IF ( ln_qsr_ice ) THEN
330                  fraqsr_1lev(:,:) = etot3(:,:,1) / r1_rau0_rcp
331               ENDIF
332           ENDIF
333
334         ENDIF
335         !                                                ! ------------------------- !
336         IF( ln_qsr_2bd ) THEN                            !  2 band light penetration !
337            !                                             ! ------------------------- !
338            !
339            IF( lk_vvl ) THEN                                  !* variable volume
340               zz0   =        rn_abs   * r1_rau0_rcp
341               zz1   = ( 1. - rn_abs ) * r1_rau0_rcp
342               DO jk = 1, nksr                    ! solar heat absorbed at T-point in the top 400m
343                  DO jj = 1, jpj
344                     DO ji = 1, jpi
345                        zc0 = zz0 * EXP( -fsdepw(ji,jj,jk  )*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk  )*xsi1r )
346                        zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r )
347                        qsr_hc(ji,jj,jk) = qsr(ji,jj) * ( zc0*tmask(ji,jj,jk) - zc1*tmask(ji,jj,jk+1) ) 
348                     END DO
349                  END DO
350               END DO
351               ! clem: store attenuation coefficient of the first ocean level
352               IF ( ln_qsr_ice ) THEN
353                  DO jj = 1, jpj
354                     DO ji = 1, jpi
355                        zc0 = zz0 * EXP( -fsdepw(ji,jj,1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,1)*xsi1r )
356                        zc1 = zz0 * EXP( -fsdepw(ji,jj,2)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,2)*xsi1r )
357                        fraqsr_1lev(ji,jj) = ( zc0*tmask(ji,jj,1) - zc1*tmask(ji,jj,2) ) / r1_rau0_rcp
358                     END DO
359                  END DO
360               ENDIF
361            ELSE                                               !* constant volume: coef. computed one for all
362               DO jk = 1, nksr
363                  DO jj = 2, jpjm1
364                     DO ji = fs_2, fs_jpim1   ! vector opt.
365                        ! (ISF) no light penetration below the ice shelves         
366                        qsr_hc(ji,jj,jk) =  etot3(ji,jj,jk) * qsr(ji,jj) * tmask(ji,jj,1)
367                     END DO
368                  END DO
369               END DO
370               ! clem: store attenuation coefficient of the first ocean level
371               IF ( ln_qsr_ice ) THEN
372                  fraqsr_1lev(:,:) = etot3(:,:,1) / r1_rau0_rcp
373               ENDIF
374               !
375            ENDIF
376            !
377         ENDIF
378! slwa
379         IF( nn_kd490dta == 1 ) THEN                      !  use KD490 data read in   !
380            !                                             ! ------------------------- !
381               nksr = jpk - 1
382               !
383               CALL fld_read( kt, 1, sf_kd490 )     ! Read kd490 data and provide it at the current time step
384               !
385               zcoef  = ( 1. - rn_abs )
386               ze0(:,:,1) = rn_abs  * qsr(:,:)
387               ze1(:,:,1) = zcoef * qsr(:,:)
388               zea(:,:,1) =         qsr(:,:)
389               !
390               DO jk = 2, nksr+1
391!CDIR NOVERRCHK
392                  DO jj = 1, jpj
393!CDIR NOVERRCHK   
394                     DO ji = 1, jpi
395                        zc0 = ze0(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * xsi0r     )
396                        zc1 = ze1(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * sf_kd490(1)%fnow(ji,jj,1) )
397                        ze0(ji,jj,jk) = zc0
398                        ze1(ji,jj,jk) = zc1
399                        zea(ji,jj,jk) = ( zc0 + zc1 ) * tmask(ji,jj,jk)
400                     END DO
401                  END DO
402               END DO
403               ! clem: store attenuation coefficient of the first ocean level
404               IF ( ln_qsr_ice ) THEN
405                  DO jj = 1, jpj
406                     DO ji = 1, jpi
407                        zzc0 = rn_abs * EXP( - fse3t(ji,jj,1) * xsi0r     )
408                        zzc1 = zcoef  * EXP( - fse3t(ji,jj,1) * sf_kd490(1)%fnow(ji,jj,1) )
409                        fraqsr_1lev(ji,jj) = 1.0 - ( zzc0 + zzc1 ) * tmask(ji,jj,2) 
410                     END DO
411                  END DO
412               ENDIF
413               !
414               DO jk = 1, nksr                                        ! compute and add qsr trend to ta
415                  qsr_hc(:,:,jk) = r1_rau0_rcp * ( zea(:,:,jk) - zea(:,:,jk+1) )
416               END DO
417               zea(:,:,nksr+1:jpk) = 0.e0     !
418               CALL iom_put( 'qsr3d', zea )   ! Shortwave Radiation 3D distribution
419               !
420        ENDIF   ! use KD490 data
421!slwa
422         !
423         !                                        Add to the general trend
424         DO jk = 1, nksr
425            DO jj = 2, jpjm1 
426               DO ji = fs_2, fs_jpim1   ! vector opt.
427                  z1_e3t = zfact / fse3t(ji,jj,jk)
428                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t
429               END DO
430            END DO
431         END DO
432         !
433      ENDIF
434      !
435      IF( lrst_oce ) THEN   !                  Write in the ocean restart file
436         !                                     *******************************
437         IF(lwp) WRITE(numout,*)
438         IF(lwp) WRITE(numout,*) 'qsr tracer content forcing field written in ocean restart file ',   &
439            &                    'at it= ', kt,' date= ', ndastp
440         IF(lwp) WRITE(numout,*) '~~~~'
441         CALL iom_rstput( kt, nitrst, numrow, 'qsr_hc_b'   , qsr_hc      )
442         CALL iom_rstput( kt, nitrst, numrow, 'fraqsr_1lev', fraqsr_1lev )   ! default definition in sbcssm
443         !
444      ENDIF
445
446      IF( l_trdtra ) THEN     ! qsr tracers trends saved for diagnostics
447         ztrdt(:,:,:) = tsa(:,:,:,jp_tem) - ztrdt(:,:,:)
448         CALL trd_tra( kt, 'TRA', jp_tem, jptra_qsr, ztrdt )
449         CALL wrk_dealloc( jpi, jpj, jpk, ztrdt ) 
450      ENDIF
451      !                       ! print mean trends (used for debugging)
452      IF(ln_ctl)   CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' qsr  - Ta: ', mask1=tmask, clinfo3='tra-ta' )
453      !
454      CALL wrk_dealloc( jpi, jpj,      zekb, zekg, zekr        ) 
455      CALL wrk_dealloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
456      CALL wrk_dealloc( jpi, jpj, jpk, zekb_3d, zekg_3d, zekr_3d ) 
457      !
458      IF( nn_timing == 1 )  CALL timing_stop('tra_qsr')
459      !
460   END SUBROUTINE tra_qsr
461
462
463   SUBROUTINE tra_qsr_init
464      !!----------------------------------------------------------------------
465      !!                  ***  ROUTINE tra_qsr_init  ***
466      !!
467      !! ** Purpose :   Initialization for the penetrative solar radiation
468      !!
469      !! ** Method  :   The profile of solar radiation within the ocean is set
470      !!      from two length scale of penetration (rn_si0,rn_si1) and a ratio
471      !!      (rn_abs). These parameters are read in the namtra_qsr namelist. The
472      !!      default values correspond to clear water (type I in Jerlov'
473      !!      (1968) classification.
474      !!         called by tra_qsr at the first timestep (nit000)
475      !!
476      !! ** Action  : - initialize rn_si0, rn_si1 and rn_abs
477      !!
478      !! Reference : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp.
479      !!----------------------------------------------------------------------
480      !
481      INTEGER  ::   ji, jj, jk                   ! dummy loop indices
482      INTEGER  ::   irgb, ierror, ioptio, nqsr   ! local integer
483      INTEGER  ::   ios                          ! Local integer output status for namelist read
484      REAL(wp) ::   zz0, zc0  , zc1, zcoef       ! local scalars
485      REAL(wp) ::   zz1, zc2  , zc3, zchl        !   -      -
486      REAL(wp), POINTER, DIMENSION(:,:  ) :: zekb, zekg, zekr
487      REAL(wp), POINTER, DIMENSION(:,:,:) :: ze0, ze1, ze2, ze3, zea
488      !
489      CHARACTER(len=100) ::   cn_dir   ! Root directory for location of ssr files
490      TYPE(FLD_N)        ::   sn_chl   ! informations about the chlorofyl field to be read
491      TYPE(FLD_N)        ::   sn_kd490 ! informations about the kd490 field to be read
492      !!
493      NAMELIST/namtra_qsr/  sn_chl, sn_kd490, cn_dir, ln_traqsr, ln_qsr_rgb, ln_qsr_2bd, ln_qsr_bio, ln_qsr_ice,  &
494         &                  ln_qsr_spec, nn_chldta, rn_abs, rn_si0, rn_si1, nn_kd490dta
495      !!----------------------------------------------------------------------
496
497      !
498      IF( nn_timing == 1 )  CALL timing_start('tra_qsr_init')
499      !
500      CALL wrk_alloc( jpi, jpj,      zekb, zekg, zekr        ) 
501      CALL wrk_alloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
502      !
503
504      REWIND( numnam_ref )              ! Namelist namtra_qsr in reference namelist : Ratio and length of penetration
505      READ  ( numnam_ref, namtra_qsr, IOSTAT = ios, ERR = 901)
506901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_qsr in reference namelist', lwp )
507
508      REWIND( numnam_cfg )              !  Namelist namtra_qsr in configuration namelist : Ratio and length of penetration
509      READ  ( numnam_cfg, namtra_qsr, IOSTAT = ios, ERR = 902 )
510902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_qsr in configuration namelist', lwp )
511      IF(lwm) WRITE ( numond, namtra_qsr )
512      !
513      IF(lwp) THEN                ! control print
514         WRITE(numout,*)
515         WRITE(numout,*) 'tra_qsr_init : penetration of the surface solar radiation'
516         WRITE(numout,*) '~~~~~~~~~~~~'
517         WRITE(numout,*) '   Namelist namtra_qsr : set the parameter of penetration'
518         WRITE(numout,*) '      Light penetration (T) or not (F)         ln_traqsr  = ', ln_traqsr
519         WRITE(numout,*) '      RGB (Red-Green-Blue) light penetration   ln_qsr_rgb = ', ln_qsr_rgb
520         WRITE(numout,*) '      2 band               light penetration   ln_qsr_2bd = ', ln_qsr_2bd
521         WRITE(numout,*) '      bio-model            light penetration   ln_qsr_bio = ', ln_qsr_bio
522         WRITE(numout,*) '      ERSEM spectral heating model             ln_qsr_spec= ', ln_qsr_spec
523         WRITE(numout,*) '      light penetration for ice-model LIM3     ln_qsr_ice = ', ln_qsr_ice
524         WRITE(numout,*) '      RGB: model (2), file (1) or cst (0) chl   nn_chldta = ', nn_chldta
525         WRITE(numout,*) '      RGB & 2 bands: fraction of light (rn_si1)    rn_abs = ', rn_abs
526         WRITE(numout,*) '      RGB & 2 bands: shortess depth of extinction  rn_si0 = ', rn_si0
527         WRITE(numout,*) '      2 bands: longest depth of extinction         rn_si1 = ', rn_si1
528         WRITE(numout,*) '      read in KD490 data                       nn_kd490dta  = ', nn_kd490dta
529      ENDIF
530
531      IF( ln_traqsr ) THEN     ! control consistency
532         !                     
533         IF( .NOT.lk_qsr_bio .AND. ln_qsr_bio )   THEN
534            CALL ctl_warn( 'No bio model : force ln_qsr_bio = FALSE ' )
535            ln_qsr_bio = .FALSE.
536         ENDIF
537         !
538         ioptio = 0                      ! Parameter control
539         IF( ln_qsr_rgb  )   ioptio = ioptio + 1
540         IF( ln_qsr_2bd  )   ioptio = ioptio + 1
541         IF( ln_qsr_bio  )   ioptio = ioptio + 1
542         IF( ln_qsr_spec )   ioptio = ioptio + 1
543         IF( nn_kd490dta == 1 )   ioptio = ioptio + 1
544         !
545         IF( ioptio /= 1 ) &
546            CALL ctl_stop( '          Choose ONE type of light penetration in namelist namtra_qsr',  &
547            &              ' 2 bands, 3 RGB bands or bio-model light penetration' )
548         !
549         IF( ln_qsr_rgb .AND. nn_chldta == 0 )   nqsr =  1 
550         IF( ln_qsr_rgb .AND. nn_chldta == 1 )   nqsr =  2
551         IF( ln_qsr_rgb .AND. nn_chldta == 2 )   nqsr =  3
552         IF( ln_qsr_2bd                      )   nqsr =  4
553         IF( ln_qsr_bio                      )   nqsr =  5
554         IF( nn_kd490dta == 1                )   nqsr =  6
555         IF( ln_qsr_spec                     )   nqsr =  7
556         !
557         IF(lwp) THEN                   ! Print the choice
558            WRITE(numout,*)
559            IF( nqsr ==  1 )   WRITE(numout,*) '         R-G-B   light penetration - Constant Chlorophyll'
560            IF( nqsr ==  2 )   WRITE(numout,*) '         R-G-B   light penetration - Chl data from file'
561            IF( nqsr ==  3 )   WRITE(numout,*) '         R-G-B   light penetration - Chl data from model'
562            IF( nqsr ==  4 )   WRITE(numout,*) '         2 bands light penetration'
563            IF( nqsr ==  5 )   WRITE(numout,*) '         bio-model light penetration'
564            IF( nqsr ==  6 )   WRITE(numout,*) '         KD490 light penetration'
565            IF( nqsr ==  7 )   WRITE(numout,*) '         ERSEM spectral light penetration'
566         ENDIF
567#if ! defined key_fabm
568         !
569         IF( nqsr ==  2 ) THEN
570            CALL ctl_stop( 'nn_chldta=2 so trying to use ERSEM chlorophyll for light penetration', &
571               &           'but not running with ERSEM' )
572         ELSEIF( nqsr ==  7 ) THEN
573            CALL ctl_stop( 'ln_qsr_spec=.true. so trying to use ERSEM spectral light penetration', &
574               &           'but not running with ERSEM' )
575         ENDIF
576#endif
577         !
578      ENDIF
579      !                          ! ===================================== !
580      IF( ln_traqsr  ) THEN      !  Initialisation of Light Penetration  ! 
581         !                       ! ===================================== !
582         !
583         xsi0r = 1.e0 / rn_si0
584         xsi1r = 1.e0 / rn_si1
585         IF( nn_kd490dta == 1 ) THEN           !* KD490 data : set sf_kd490 structure
586            IF(lwp) WRITE(numout,*)
587            IF(lwp) WRITE(numout,*) '        KD490 read in a file'
588            ALLOCATE( sf_kd490(1), STAT=ierror )
589            IF( ierror > 0 ) THEN
590               CALL ctl_stop( 'tra_qsr_init: unable to allocate sf_kd490 structure' )   ;   RETURN
591            ENDIF
592            ALLOCATE( sf_kd490(1)%fnow(jpi,jpj,1)   )
593            IF( sn_kd490%ln_tint )ALLOCATE( sf_kd490(1)%fdta(jpi,jpj,1,2) )
594            !                                        ! fill sf_kd490 with sn_kd490 and control print
595            CALL fld_fill( sf_kd490, (/ sn_kd490 /), cn_dir, 'tra_qsr_init',   &
596               &                                         'Solar penetration function of read KD490', 'namtra_qsr' )
597         !                                ! ---------------------------------- !
598         ELSEIF( ln_qsr_rgb ) THEN            !  Red-Green-Blue light penetration  !
599            !                             ! ---------------------------------- !
600            !
601            CALL trc_oce_rgb( rkrgb )           !* tabulated attenuation coef.
602            !
603            !                                   !* level of light extinction
604            IF(  ln_sco ) THEN   ;   nksr = jpkm1
605            ELSE                 ;   nksr = trc_oce_ext_lev( r_si2, 0.33e2 )
606            ENDIF
607
608            IF(lwp) WRITE(numout,*) '        level of light extinction = ', nksr, ' ref depth = ', gdepw_1d(nksr+1), ' m'
609            !
610            IF( nn_chldta == 1 ) THEN           !* Chl data : set sf_chl structure
611               IF(lwp) WRITE(numout,*)
612               IF(lwp) WRITE(numout,*) '        Chlorophyll read in a file'
613               ALLOCATE( sf_chl(1), STAT=ierror )
614               IF( ierror > 0 ) THEN
615                  CALL ctl_stop( 'tra_qsr_init: unable to allocate sf_chl structure' )   ;   RETURN
616               ENDIF
617               ALLOCATE( sf_chl(1)%fnow(jpi,jpj,1)   )
618               IF( sn_chl%ln_tint )ALLOCATE( sf_chl(1)%fdta(jpi,jpj,1,2) )
619               !                                        ! fill sf_chl with sn_chl and control print
620               CALL fld_fill( sf_chl, (/ sn_chl /), cn_dir, 'tra_qsr_init',   &
621                  &                                         'Solar penetration function of read chlorophyll', 'namtra_qsr' )
622               !
623            ELSEIF( nn_chldta == 2 ) THEN       !* Chl data will be got from model at each time step
624               IF(lwp) WRITE(numout,*)
625               IF(lwp) WRITE(numout,*) '        Chlorophyll will be taken from model at each time step'
626            ELSE                                !* constant Chl : compute once for all the distribution of light (etot3)
627               IF(lwp) WRITE(numout,*)
628               IF(lwp) WRITE(numout,*) '        Constant Chlorophyll concentration = 0.05'
629               IF( lk_vvl ) THEN                   ! variable volume
630                  IF(lwp) WRITE(numout,*) '        key_vvl: light distribution will be computed at each time step'
631               ELSE                                ! constant volume: computes one for all
632                  IF(lwp) WRITE(numout,*) '        fixed volume: light distribution computed one for all'
633                  !
634                  zchl = 0.05                                 ! constant chlorophyll
635                  irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 )
636                  zekb(:,:) = rkrgb(1,irgb)                   ! Separation in R-G-B depending of the chlorophyll
637                  zekg(:,:) = rkrgb(2,irgb)
638                  zekr(:,:) = rkrgb(3,irgb)
639                  !
640                  zcoef = ( 1. - rn_abs ) / 3.e0              ! equi-partition in R-G-B
641                  ze0(:,:,1) = rn_abs
642                  ze1(:,:,1) = zcoef
643                  ze2(:,:,1) = zcoef 
644                  ze3(:,:,1) = zcoef
645                  zea(:,:,1) = tmask(:,:,1)                   ! = ( ze0+ze1+z2+ze3 ) * tmask
646               
647                  DO jk = 2, nksr+1
648!CDIR NOVERRCHK
649                     DO jj = 1, jpj
650!CDIR NOVERRCHK   
651                        DO ji = 1, jpi
652                           zc0 = ze0(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * xsi0r     )
653                           zc1 = ze1(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * zekb(ji,jj) )
654                           zc2 = ze2(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * zekg(ji,jj) )
655                           zc3 = ze3(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * zekr(ji,jj) )
656                           ze0(ji,jj,jk) = zc0
657                           ze1(ji,jj,jk) = zc1
658                           ze2(ji,jj,jk) = zc2
659                           ze3(ji,jj,jk) = zc3
660                           zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk)
661                        END DO
662                     END DO
663                  END DO 
664                  !
665                  DO jk = 1, nksr
666                     ! (ISF) no light penetration below the ice shelves
667                     etot3(:,:,jk) = r1_rau0_rcp * ( zea(:,:,jk) - zea(:,:,jk+1) ) * tmask(:,:,1)
668                  END DO
669                  etot3(:,:,nksr+1:jpk) = 0.e0                ! below 400m set to zero
670               ENDIF
671            ENDIF
672            !
673         ENDIF
674            !                             ! ---------------------------------- !
675         IF( ln_qsr_2bd ) THEN            !    2 bands    light penetration    !
676            !                             ! ---------------------------------- !
677            !
678            !                                ! level of light extinction
679            nksr = trc_oce_ext_lev( rn_si1, 1.e2 )
680            IF(lwp) THEN
681               WRITE(numout,*)
682            IF(lwp) WRITE(numout,*) '        level of light extinction = ', nksr, ' ref depth = ', gdepw_1d(nksr+1), ' m'
683            ENDIF
684            !
685            IF( lk_vvl ) THEN                   ! variable volume
686               IF(lwp) WRITE(numout,*) '        key_vvl: light distribution will be computed at each time step'
687            ELSE                                ! constant volume: computes one for all
688               zz0 =        rn_abs   * r1_rau0_rcp
689               zz1 = ( 1. - rn_abs ) * r1_rau0_rcp
690               DO jk = 1, nksr                    !*  solar heat absorbed at T-point computed once for all
691                  DO jj = 1, jpj                              ! top 400 meters
692                     DO ji = 1, jpi
693                        zc0 = zz0 * EXP( -fsdepw(ji,jj,jk  )*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk  )*xsi1r )
694                        zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r )
695                        etot3(ji,jj,jk) = (  zc0 * tmask(ji,jj,jk) - zc1 * tmask(ji,jj,jk+1)  ) * tmask(ji,jj,1) 
696                     END DO
697                  END DO
698               END DO
699               etot3(:,:,nksr+1:jpk) = 0.e0                   ! below 400m set to zero
700               !
701            ENDIF
702         ENDIF
703         !                       ! ===================================== !
704      ELSE                       !        No light penetration           !                   
705         !                       ! ===================================== !
706         IF(lwp) THEN
707            WRITE(numout,*)
708            WRITE(numout,*) 'tra_qsr_init : NO solar flux penetration'
709            WRITE(numout,*) '~~~~~~~~~~~~'
710         ENDIF
711      ENDIF
712      !
713      ! initialisation of fraqsr_1lev used in sbcssm
714      IF( iom_varid( numror, 'fraqsr_1lev', ldstop = .FALSE. ) > 0 ) THEN
715         CALL iom_get( numror, jpdom_autoglo, 'fraqsr_1lev'  , fraqsr_1lev  )
716      ELSE
717         fraqsr_1lev(:,:) = 1._wp   ! default definition
718      ENDIF
719      !
720      CALL wrk_dealloc( jpi, jpj,      zekb, zekg, zekr        ) 
721      CALL wrk_dealloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
722      !
723      IF( nn_timing == 1 )  CALL timing_stop('tra_qsr_init')
724      !
725   END SUBROUTINE tra_qsr_init
726
727   !!======================================================================
728END MODULE traqsr
Note: See TracBrowser for help on using the repository browser.