source: branches/UKMO/GO6_dyn_vrt_diag/NEMOGCM/NEMO/OPA_SRC/DYN/dynbfr.F90 @ 8300

Last change on this file since 8300 was 8300, checked in by glong, 4 years ago

Changed diagnostics to calculate the contributions by taking after-before before going into the specific numerical scheme for the model.

File size: 5.9 KB
Line 
1MODULE dynbfr
2   !!==============================================================================
3   !!                 ***  MODULE  dynbfr  ***
4   !! Ocean dynamics :  bottom friction component of the momentum mixing trend
5   !!==============================================================================
6   !! History :  3.2  ! 2008-11  (A. C. Coward)  Original code
7   !!            3.4  ! 2011-09  (H. Liu) Make it consistent with semi-implicit
8   !!                            Bottom friction (ln_bfrimp = .true.)
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   dyn_bfr       : Update the momentum trend with the bottom friction contribution
13   !!----------------------------------------------------------------------
14   USE oce            ! ocean dynamics and tracers variables
15   USE dom_oce        ! ocean space and time domain variables
16   USE zdf_oce        ! ocean vertical physics variables
17   USE zdfbfr         ! ocean bottom friction variables
18   USE trd_oce        ! trends: ocean variables
19   USE trddyn         ! trend manager: dynamics
20   USE in_out_manager ! I/O manager
21   USE prtctl         ! Print control
22   USE timing         ! Timing
23   USE wrk_nemo       ! Memory Allocation
24   USE divcur         ! for dyn_vrt_dia
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   dyn_bfr   !  routine called by step.F90
30
31   !! * Substitutions
32#  include "domzgr_substitute.h90"
33#  include "zdfddm_substitute.h90"
34#  include "vectopt_loop_substitute.h90"
35   !!----------------------------------------------------------------------
36   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
37   !! $Id$
38   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
39   !!----------------------------------------------------------------------
40CONTAINS
41   
42   SUBROUTINE dyn_bfr( kt )
43      !!----------------------------------------------------------------------
44      !!                  ***  ROUTINE dyn_bfr  ***
45      !!
46      !! ** Purpose :   compute the bottom friction ocean dynamics physics.
47      !!
48      !! ** Action  :   (ua,va)   momentum trend increased by bottom friction trend
49      !!---------------------------------------------------------------------
50      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
51      !!
52      INTEGER  ::   ji, jj       ! dummy loop indexes
53      INTEGER  ::   ikbu, ikbv   ! local integers
54      REAL(wp) ::   zm1_2dt      ! local scalar
55      CHARACTER(len=3) ::  id_dyn_vrt_bfr = "bfr"    ! TODO remove once flags set properly
56      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdu, ztrdv
57      !!---------------------------------------------------------------------
58      !
59      IF( nn_timing == 1 )  CALL timing_start('dyn_bfr')
60      !
61!!gm issue: better to put the logical in step to control the call of zdf_bfr
62!!          ==> change the logical from ln_bfrimp to ln_bfr_exp !!
63      IF( .NOT.ln_bfrimp) THEN     ! only for explicit bottom friction form
64                                    ! implicit bfr is implemented in dynzdf_imp
65
66!!gm bug : time step is only rdt (not 2 rdt if euler start !)
67        zm1_2dt = - 1._wp / ( 2._wp * rdt )
68
69        IF( l_trddyn .OR. ( id_dyn_vrt_bfr == "bfr" ) )   THEN                      ! temporary save of ua and va trends
70           CALL wrk_alloc( jpi,jpj,jpk, ztrdu, ztrdv )
71           ztrdu(:,:,:) = ua(:,:,:)
72           ztrdv(:,:,:) = va(:,:,:)
73        ENDIF
74
75
76        DO jj = 2, jpjm1
77           DO ji = 2, jpim1
78              ikbu = mbku(ji,jj)          ! deepest ocean u- & v-levels
79              ikbv = mbkv(ji,jj)
80              !
81              ! Apply stability criteria on absolute value  : abs(bfr/e3) < 1/(2dt) => bfr/e3 > -1/(2dt)
82              ua(ji,jj,ikbu) = ua(ji,jj,ikbu) + MAX(  bfrua(ji,jj) / fse3u(ji,jj,ikbu) , zm1_2dt  ) * ub(ji,jj,ikbu)
83              va(ji,jj,ikbv) = va(ji,jj,ikbv) + MAX(  bfrva(ji,jj) / fse3v(ji,jj,ikbv) , zm1_2dt  ) * vb(ji,jj,ikbv)
84           END DO
85        END DO
86       
87        IF ( ln_isfcav ) THEN
88           DO jj = 2, jpjm1
89              DO ji = 2, jpim1
90                 ! (ISF) stability criteria for top friction
91                 ikbu = miku(ji,jj)          ! first wet ocean u- & v-levels
92                 ikbv = mikv(ji,jj)
93                 !
94                 ! Apply stability criteria on absolute value  : abs(bfr/e3) < 1/(2dt) => bfr/e3 > -1/(2dt)
95                 ua(ji,jj,ikbu) = ua(ji,jj,ikbu) + MAX(  tfrua(ji,jj) / fse3u(ji,jj,ikbu) , zm1_2dt  ) * ub(ji,jj,ikbu) &
96                    &             * (1.-umask(ji,jj,1))
97                 va(ji,jj,ikbv) = va(ji,jj,ikbv) + MAX(  tfrva(ji,jj) / fse3v(ji,jj,ikbv) , zm1_2dt  ) * vb(ji,jj,ikbv) &
98                    &             * (1.-vmask(ji,jj,1))
99                 ! (ISF)
100              END DO
101           END DO
102        END IF
103
104        !
105        IF( l_trddyn .OR. ( id_dyn_vrt_bfr == "bfr" ) )   THEN                      ! save the vertical diffusive trends for further diagnostics
106           ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
107           ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
108           IF( l_trddyn )  THEN
109              CALL trd_dyn( ztrdu(:,:,:), ztrdv(:,:,:), jpdyn_bfr, kt )
110           ENDIF
111           IF( id_dyn_vrt_bfr == "bfr" )  THEN
112              CALL dyn_vrt_dia_3d( ztrdu, ztrdv, id_dyn_vrt_bfr )
113           ENDIF
114           CALL wrk_dealloc( jpi,jpj,jpk, ztrdu, ztrdv )
115        ENDIF
116        !                                          ! print mean trends (used for debugging)
117        IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' bfr  - Ua: ', mask1=umask,               &
118           &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
119        !
120      ENDIF     ! end explicit bottom friction
121      !
122      IF( nn_timing == 1 )  CALL timing_stop('dyn_bfr')
123      !
124   END SUBROUTINE dyn_bfr
125
126   !!==============================================================================
127END MODULE dynbfr
Note: See TracBrowser for help on using the repository browser.