source: branches/UKMO/GO6_dyn_vrt_diag/NEMOGCM/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 8300

Last change on this file since 8300 was 8300, checked in by glong, 4 years ago

Changed diagnostics to calculate the contributions by taking after-before before going into the specific numerical scheme for the model.

File size: 70.3 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  OPA  !  1987-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  1991-11  (G. Madec)
8   !!            7.0  !  1996-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  1997-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  2002-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  2002-08  (A. Bozec)  hpg_zps: Original code
12   !!   NEMO     1.0  !  2005-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                 !         Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!             -   !  2005-11  (G. Madec) style & small optimisation
15   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
16   !!            3.4  !  2011-11  (H. Liu) hpg_prj: Original code for s-coordinates
17   !!                 !           (A. Coward) suppression of hel, wdj and rot options
18   !!            3.6  !  2014-11  (P. Mathiot) hpg_isf: original code for ice shelf cavity
19   !!----------------------------------------------------------------------
20
21   !!----------------------------------------------------------------------
22   !!   dyn_hpg      : update the momentum trend with the now horizontal
23   !!                  gradient of the hydrostatic pressure
24   !!   dyn_hpg_init : initialisation and control of options
25   !!       hpg_zco  : z-coordinate scheme
26   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
27   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
28   !!       hpg_isf  : s-coordinate (sco formulation) adapted to ice shelf
29   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
30   !!       hpg_prj  : s-coordinate (Pressure Jacobian with Cubic polynomial)
31   !!----------------------------------------------------------------------
32   USE oce             ! ocean dynamics and tracers
33   USE sbc_oce         ! surface variable (only for the flag with ice shelf)
34   USE dom_oce         ! ocean space and time domain
35   USE phycst          ! physical constants
36   USE trd_oce         ! trends: ocean variables
37   USE trddyn          ! trend manager: dynamics
38   USE divcur          ! for dyn_vrt_dia_3d
39   !
40   USE in_out_manager  ! I/O manager
41   USE prtctl          ! Print control
42   USE lbclnk          ! lateral boundary condition
43   USE lib_mpp         ! MPP library
44   USE eosbn2          ! compute density
45   USE wrk_nemo        ! Memory Allocation
46   USE timing          ! Timing
47
48   IMPLICIT NONE
49   PRIVATE
50
51   PUBLIC   dyn_hpg        ! routine called by step module
52   PUBLIC   dyn_hpg_init   ! routine called by opa module
53
54   !                                    !!* Namelist namdyn_hpg : hydrostatic pressure gradient
55   LOGICAL , PUBLIC ::   ln_hpg_zco      !: z-coordinate - full steps
56   LOGICAL , PUBLIC ::   ln_hpg_zps      !: z-coordinate - partial steps (interpolation)
57   LOGICAL , PUBLIC ::   ln_hpg_sco      !: s-coordinate (standard jacobian formulation)
58   LOGICAL , PUBLIC ::   ln_hpg_djc      !: s-coordinate (Density Jacobian with Cubic polynomial)
59   LOGICAL , PUBLIC ::   ln_hpg_prj      !: s-coordinate (Pressure Jacobian scheme)
60   LOGICAL , PUBLIC ::   ln_hpg_isf      !: s-coordinate similar to sco modify for isf
61   LOGICAL , PUBLIC ::   ln_dynhpg_imp   !: semi-implicite hpg flag
62
63   INTEGER , PUBLIC ::   nhpg  =  0   ! = 0 to 7, type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
64
65   !! * Substitutions
66#  include "domzgr_substitute.h90"
67#  include "vectopt_loop_substitute.h90"
68   !!----------------------------------------------------------------------
69   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
70   !! $Id$
71   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
72   !!----------------------------------------------------------------------
73CONTAINS
74
75   SUBROUTINE dyn_hpg( kt )
76      !!---------------------------------------------------------------------
77      !!                  ***  ROUTINE dyn_hpg  ***
78      !!
79      !! ** Method  :   Call the hydrostatic pressure gradient routine
80      !!              using the scheme defined in the namelist
81      !!
82      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
83      !!             - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
84      !!----------------------------------------------------------------------
85      INTEGER, INTENT(in) ::   kt                     ! ocean time-step index
86      CHARACTER(len=3)    ::   id_vrt_dia_hpg = "hpg" ! TODO remove once flags set properly
87      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdu, ztrdv
88      !!----------------------------------------------------------------------
89      !
90      IF( nn_timing == 1 )  CALL timing_start('dyn_hpg')
91      !
92      IF( l_trddyn .or. ( id_vrt_dia_hpg == "hpg" ) ) THEN    ! Temporary saving of ua and va trends (l_trddyn)
93         CALL wrk_alloc( jpi,jpj,jpk, ztrdu, ztrdv )
94         ztrdu(:,:,:) = ua(:,:,:)
95         ztrdv(:,:,:) = va(:,:,:)
96      ENDIF
97      !
98      SELECT CASE ( nhpg )      ! Hydrostatic pressure gradient computation
99      CASE (  0 )   ;   CALL hpg_zco    ( kt )      ! z-coordinate
100      CASE (  1 )   ;   CALL hpg_zps    ( kt )      ! z-coordinate plus partial steps (interpolation)
101      CASE (  2 )   ;   CALL hpg_sco    ( kt )      ! s-coordinate (standard jacobian formulation)
102      CASE (  3 )   ;   CALL hpg_djc    ( kt )      ! s-coordinate (Density Jacobian with Cubic polynomial)
103      CASE (  4 )   ;   CALL hpg_prj    ( kt )      ! s-coordinate (Pressure Jacobian scheme)
104      CASE (  5 )   ;   CALL hpg_isf    ( kt )      ! s-coordinate similar to sco modify for ice shelf
105      END SELECT
106      !
107      IF( l_trddyn .or. ( id_vrt_dia_hpg == "hpg" ) ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
108         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
109         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
110         !
111         IF( id_vrt_dia_hpg == "hpg" ) THEN
112             CALL dyn_vrt_dia_3d( ztrdu, ztrdv, id_vrt_dia_hpg )
113         END IF
114         IF( l_trddyn ) THEN
115             CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt )
116         END IF
117         CALL wrk_dealloc( jpi,jpj,jpk, ztrdu, ztrdv )
118      ENDIF
119      !
120      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg  - Ua: ', mask1=umask,   &
121         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
122      !
123      IF( nn_timing == 1 )  CALL timing_stop('dyn_hpg')
124      !
125   END SUBROUTINE dyn_hpg
126
127
128   SUBROUTINE dyn_hpg_init
129      !!----------------------------------------------------------------------
130      !!                 ***  ROUTINE dyn_hpg_init  ***
131      !!
132      !! ** Purpose :   initializations for the hydrostatic pressure gradient
133      !!              computation and consistency control
134      !!
135      !! ** Action  :   Read the namelist namdyn_hpg and check the consistency
136      !!      with the type of vertical coordinate used (zco, zps, sco)
137      !!----------------------------------------------------------------------
138      INTEGER ::   ioptio = 0      ! temporary integer
139      INTEGER ::   ios             ! Local integer output status for namelist read
140      !!
141      NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco,     &
142         &                 ln_hpg_djc, ln_hpg_prj, ln_hpg_isf, ln_dynhpg_imp
143      !!----------------------------------------------------------------------
144      !
145      REWIND( numnam_ref )              ! Namelist namdyn_hpg in reference namelist : Hydrostatic pressure gradient
146      READ  ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
147901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist', lwp )
148
149      REWIND( numnam_cfg )              ! Namelist namdyn_hpg in configuration namelist : Hydrostatic pressure gradient
150      READ  ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
151902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist', lwp )
152      IF(lwm) WRITE ( numond, namdyn_hpg )
153      !
154      IF(lwp) THEN                   ! Control print
155         WRITE(numout,*)
156         WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
157         WRITE(numout,*) '~~~~~~~~~~~~'
158         WRITE(numout,*) '   Namelist namdyn_hpg : choice of hpg scheme'
159         WRITE(numout,*) '      z-coord. - full steps                             ln_hpg_zco    = ', ln_hpg_zco
160         WRITE(numout,*) '      z-coord. - partial steps (interpolation)          ln_hpg_zps    = ', ln_hpg_zps
161         WRITE(numout,*) '      s-coord. (standard jacobian formulation)          ln_hpg_sco    = ', ln_hpg_sco
162         WRITE(numout,*) '      s-coord. (standard jacobian formulation) for isf  ln_hpg_isf    = ', ln_hpg_isf
163         WRITE(numout,*) '      s-coord. (Density Jacobian: Cubic polynomial)     ln_hpg_djc    = ', ln_hpg_djc
164         WRITE(numout,*) '      s-coord. (Pressure Jacobian: Cubic polynomial)    ln_hpg_prj    = ', ln_hpg_prj
165         WRITE(numout,*) '      time stepping: centered (F) or semi-implicit (T)  ln_dynhpg_imp = ', ln_dynhpg_imp
166      ENDIF
167      !
168      IF( ln_hpg_djc )   &
169         &   CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method &
170                           & currently disabled (bugs under investigation). Please select &
171                           & either  ln_hpg_sco or  ln_hpg_prj instead')
172      !
173      IF( lk_vvl .AND. .NOT. (ln_hpg_sco.OR.ln_hpg_prj.OR.ln_hpg_isf) )   &
174         &   CALL ctl_stop('dyn_hpg_init : variable volume key_vvl requires:&
175                           & the standard jacobian formulation hpg_sco or &
176                           & the pressure jacobian formulation hpg_prj')
177
178      IF(       ln_hpg_isf .AND. .NOT. ln_isfcav )   &
179         &   CALL ctl_stop( ' hpg_isf not available if ln_isfcav = false ' )
180      IF( .NOT. ln_hpg_isf .AND.       ln_isfcav )   &
181         &   CALL ctl_stop( 'Only hpg_isf has been corrected to work with ice shelf cavity.' )
182      !
183      !                               ! Set nhpg from ln_hpg_... flags
184      IF( ln_hpg_zco )   nhpg = 0
185      IF( ln_hpg_zps )   nhpg = 1
186      IF( ln_hpg_sco )   nhpg = 2
187      IF( ln_hpg_djc )   nhpg = 3
188      IF( ln_hpg_prj )   nhpg = 4
189      IF( ln_hpg_isf )   nhpg = 5
190      !
191      !                               ! Consistency check
192      ioptio = 0
193      IF( ln_hpg_zco )   ioptio = ioptio + 1
194      IF( ln_hpg_zps )   ioptio = ioptio + 1
195      IF( ln_hpg_sco )   ioptio = ioptio + 1
196      IF( ln_hpg_djc )   ioptio = ioptio + 1
197      IF( ln_hpg_prj )   ioptio = ioptio + 1
198      IF( ln_hpg_isf )   ioptio = ioptio + 1
199      IF( ioptio /= 1 )   CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
200      !
201      ! initialisation of ice load
202      riceload(:,:)=0.0
203      !
204   END SUBROUTINE dyn_hpg_init
205
206
207   SUBROUTINE hpg_zco( kt )
208      !!---------------------------------------------------------------------
209      !!                  ***  ROUTINE hpg_zco  ***
210      !!
211      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
212      !!      The now hydrostatic pressure gradient at a given level, jk,
213      !!      is computed by taking the vertical integral of the in-situ
214      !!      density gradient along the model level from the suface to that
215      !!      level:    zhpi = grav .....
216      !!                zhpj = grav .....
217      !!      add it to the general momentum trend (ua,va).
218      !!            ua = ua - 1/e1u * zhpi
219      !!            va = va - 1/e2v * zhpj
220      !!
221      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
222      !!----------------------------------------------------------------------
223      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
224      !!
225      INTEGER  ::   ji, jj, jk       ! dummy loop indices
226      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
227      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
228      !!----------------------------------------------------------------------
229      !
230      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
231      !
232      IF( kt == nit000 ) THEN
233         IF(lwp) WRITE(numout,*)
234         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
235         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
236      ENDIF
237
238      zcoef0 = - grav * 0.5_wp      ! Local constant initialization
239
240      ! Surface value
241      DO jj = 2, jpjm1
242         DO ji = fs_2, fs_jpim1   ! vector opt.
243            zcoef1 = zcoef0 * fse3w(ji,jj,1)
244            ! hydrostatic pressure gradient
245            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
246            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
247            ! add to the general momentum trend
248            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
249            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
250         END DO
251      END DO
252
253      !
254      ! interior value (2=<jk=<jpkm1)
255      DO jk = 2, jpkm1
256         DO jj = 2, jpjm1
257            DO ji = fs_2, fs_jpim1   ! vector opt.
258               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
259               ! hydrostatic pressure gradient
260               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
261                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )   &
262                  &                       - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
263
264               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
265                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )   &
266                  &                       - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
267               ! add to the general momentum trend
268               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
269               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
270            END DO
271         END DO
272      END DO
273      !
274      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
275      !
276   END SUBROUTINE hpg_zco
277
278
279   SUBROUTINE hpg_zps( kt )
280      !!---------------------------------------------------------------------
281      !!                 ***  ROUTINE hpg_zps  ***
282      !!
283      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
284      !!
285      !! ** Action  : - Update (ua,va) with the now hydrastatic pressure trend
286      !!----------------------------------------------------------------------
287      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
288      !!
289      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
290      INTEGER  ::   iku, ikv                         ! temporary integers
291      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
292      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
293      !!----------------------------------------------------------------------
294      !
295      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
296      !
297      IF( kt == nit000 ) THEN
298         IF(lwp) WRITE(numout,*)
299         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
300         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
301      ENDIF
302
303
304      ! Local constant initialization
305      zcoef0 = - grav * 0.5_wp
306
307      !  Surface value (also valid in partial step case)
308      DO jj = 2, jpjm1
309         DO ji = fs_2, fs_jpim1   ! vector opt.
310            zcoef1 = zcoef0 * fse3w(ji,jj,1)
311            ! hydrostatic pressure gradient
312            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
313            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
314            ! add to the general momentum trend
315            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
316            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
317         END DO
318      END DO
319
320
321      ! interior value (2=<jk=<jpkm1)
322      DO jk = 2, jpkm1
323         DO jj = 2, jpjm1
324            DO ji = fs_2, fs_jpim1   ! vector opt.
325               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
326               ! hydrostatic pressure gradient
327               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
328                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
329                  &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
330
331               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
332                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
333                  &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
334               ! add to the general momentum trend
335               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
336               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
337            END DO
338         END DO
339      END DO
340
341
342      ! partial steps correction at the last level  (use gru & grv computed in zpshde.F90)
343      DO jj = 2, jpjm1
344         DO ji = 2, jpim1
345            iku = mbku(ji,jj)
346            ikv = mbkv(ji,jj)
347            zcoef2 = zcoef0 * MIN( fse3w(ji,jj,iku), fse3w(ji+1,jj  ,iku) )
348            zcoef3 = zcoef0 * MIN( fse3w(ji,jj,ikv), fse3w(ji  ,jj+1,ikv) )
349            IF( iku > 1 ) THEN            ! on i-direction (level 2 or more)
350               ua  (ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku)         ! subtract old value
351               zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1)                   &   ! compute the new one
352                  &            + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) / e1u(ji,jj)
353               ua  (ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku)         ! add the new one to the general momentum trend
354            ENDIF
355            IF( ikv > 1 ) THEN            ! on j-direction (level 2 or more)
356               va  (ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv)         ! subtract old value
357               zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1)                   &   ! compute the new one
358                  &            + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) / e2v(ji,jj)
359               va  (ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv)         ! add the new one to the general momentum trend
360            ENDIF
361         END DO
362      END DO
363      !
364      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
365      !
366   END SUBROUTINE hpg_zps
367
368   SUBROUTINE hpg_sco( kt )
369      !!---------------------------------------------------------------------
370      !!                  ***  ROUTINE hpg_sco  ***
371      !!
372      !! ** Method  :   s-coordinate case. Jacobian scheme.
373      !!      The now hydrostatic pressure gradient at a given level, jk,
374      !!      is computed by taking the vertical integral of the in-situ
375      !!      density gradient along the model level from the suface to that
376      !!      level. s-coordinates (ln_sco): a corrective term is added
377      !!      to the horizontal pressure gradient :
378      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
379      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
380      !!      add it to the general momentum trend (ua,va).
381      !!         ua = ua - 1/e1u * zhpi
382      !!         va = va - 1/e2v * zhpj
383      !!
384      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
385      !!----------------------------------------------------------------------
386      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
387      !!
388      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
389      REAL(wp) ::   zcoef0, zuap, zvap, znad   ! temporary scalars
390      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
391      !!----------------------------------------------------------------------
392      !
393      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
394      !
395      IF( kt == nit000 ) THEN
396         IF(lwp) WRITE(numout,*)
397         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
398         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
399      ENDIF
400
401      ! Local constant initialization
402      zcoef0 = - grav * 0.5_wp
403      ! To use density and not density anomaly
404      IF ( lk_vvl ) THEN   ;     znad = 1._wp          ! Variable volume
405      ELSE                 ;     znad = 0._wp         ! Fixed volume
406      ENDIF
407
408      ! Surface value
409      DO jj = 2, jpjm1
410         DO ji = fs_2, fs_jpim1   ! vector opt.
411            ! hydrostatic pressure gradient along s-surfaces
412            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3w(ji+1,jj  ,1) * ( znad + rhd(ji+1,jj  ,1) )   &
413               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
414            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3w(ji  ,jj+1,1) * ( znad + rhd(ji  ,jj+1,1) )   &
415               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
416            ! s-coordinate pressure gradient correction
417            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
418               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
419            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
420               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
421            ! add to the general momentum trend
422            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
423            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
424         END DO
425      END DO
426
427      ! interior value (2=<jk=<jpkm1)
428      DO jk = 2, jpkm1
429         DO jj = 2, jpjm1
430            DO ji = fs_2, fs_jpim1   ! vector opt.
431               ! hydrostatic pressure gradient along s-surfaces
432               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   &
433                  &           * (  fse3w(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad )   &
434                  &              - fse3w(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad )  )
435               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
436                  &           * (  fse3w(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad )   &
437                  &              - fse3w(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad )  )
438               ! s-coordinate pressure gradient correction
439               zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
440                  &           * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj)
441               zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
442                  &           * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj)
443               ! add to the general momentum trend
444               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
445               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
446            END DO
447         END DO
448      END DO
449      !
450      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
451      !
452   END SUBROUTINE hpg_sco
453
454   SUBROUTINE hpg_isf( kt )
455      !!---------------------------------------------------------------------
456      !!                  ***  ROUTINE hpg_sco  ***
457      !!
458      !! ** Method  :   s-coordinate case. Jacobian scheme.
459      !!      The now hydrostatic pressure gradient at a given level, jk,
460      !!      is computed by taking the vertical integral of the in-situ
461      !!      density gradient along the model level from the suface to that
462      !!      level. s-coordinates (ln_sco): a corrective term is added
463      !!      to the horizontal pressure gradient :
464      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
465      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
466      !!      add it to the general momentum trend (ua,va).
467      !!         ua = ua - 1/e1u * zhpi
468      !!         va = va - 1/e2v * zhpj
469      !!      iceload is added and partial cell case are added to the top and bottom
470      !!     
471      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
472      !!----------------------------------------------------------------------
473      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
474      !!
475      INTEGER  ::   ji, jj, jk, iku, ikv, ikt, iktp1i, iktp1j                 ! dummy loop indices
476      REAL(wp) ::   zcoef0, zuap, zvap, znad, ze3wu, ze3wv, zuapint, zvapint, zhpjint, zhpiint, zdzwt, zdzwtjp1, zdzwtip1             ! temporary scalars
477      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  zhpi, zhpj, zrhd
478      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  ztstop
479      REAL(wp), POINTER, DIMENSION(:,:)     ::  ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj
480      !!----------------------------------------------------------------------
481      !
482      CALL wrk_alloc( jpi,jpj, 2, ztstop) 
483      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj, zrhd)
484      CALL wrk_alloc( jpi,jpj, ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj) 
485      !
486     IF( kt == nit000 ) THEN
487         IF(lwp) WRITE(numout,*)
488         IF(lwp) WRITE(numout,*) 'dyn:hpg_isf : hydrostatic pressure gradient trend for ice shelf'
489         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
490      ENDIF
491
492      ! Local constant initialization
493      zcoef0 = - grav * 0.5_wp
494      ! To use density and not density anomaly
495!      IF ( lk_vvl ) THEN   ;     znad = 1._wp          ! Variable volume
496!      ELSE                 ;     znad = 0._wp         ! Fixed volume
497!      ENDIF
498      znad=1._wp
499      ! iniitialised to 0. zhpi zhpi
500      zhpi(:,:,:)=0._wp ; zhpj(:,:,:)=0._wp
501
502!==================================================================================     
503!=====Compute iceload and contribution of the half first wet layer =================
504!===================================================================================
505
506      ! assume water displaced by the ice shelf is at T=-1.9 and S=34.4 (rude)
507      ztstop(:,:,1)=-1.9_wp ; ztstop(:,:,2)=34.4_wp
508
509      ! compute density of the water displaced by the ice shelf
510      zrhd = rhd ! save rhd
511      DO jk = 1, jpk
512           zdept(:,:)=gdept_1d(jk)
513           CALL eos(ztstop(:,:,:),zdept(:,:),rhd(:,:,jk))
514      END DO
515      WHERE ( tmask(:,:,:) == 1._wp)
516        rhd(:,:,:) = zrhd(:,:,:) ! replace wet cell by the saved rhd
517      END WHERE
518     
519      ! compute rhd at the ice/oce interface (ice shelf side)
520      CALL eos(ztstop,risfdep,zrhdtop_isf)
521
522      ! compute rhd at the ice/oce interface (ocean side)
523      DO ji=1,jpi
524        DO jj=1,jpj
525          ikt=mikt(ji,jj)
526          ztstop(ji,jj,1)=tsn(ji,jj,ikt,1)
527          ztstop(ji,jj,2)=tsn(ji,jj,ikt,2)
528        END DO
529      END DO
530      CALL eos(ztstop,risfdep,zrhdtop_oce)
531      !
532      ! Surface value + ice shelf gradient
533      ! compute pressure due to ice shelf load (used to compute hpgi/j for all the level from 1 to miku/v)
534      ziceload = 0._wp
535      DO jj = 1, jpj
536         DO ji = 1, jpi   ! vector opt.
537            ikt=mikt(ji,jj)
538            ziceload(ji,jj) = ziceload(ji,jj) + (znad + rhd(ji,jj,1) ) * fse3w(ji,jj,1) * (1._wp - tmask(ji,jj,1))
539            DO jk=2,ikt-1
540               ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + rhd(ji,jj,jk-1) + rhd(ji,jj,jk)) * fse3w(ji,jj,jk) &
541                  &                              * (1._wp - tmask(ji,jj,jk))
542            END DO
543            IF (ikt .GE. 2) ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhdtop_isf(ji,jj) + rhd(ji,jj,ikt-1)) &
544                               &                              * ( risfdep(ji,jj) - gdept_1d(ikt-1) )
545         END DO
546      END DO
547      riceload(:,:) = 0.0_wp ; riceload(:,:)=ziceload(:,:)  ! need to be saved for diaar5
548      ! compute zp from z=0 to first T wet point (correction due to zps not yet applied)
549      DO jj = 2, jpjm1
550         DO ji = fs_2, fs_jpim1   ! vector opt.
551            ikt=mikt(ji,jj) ; iktp1i=mikt(ji+1,jj); iktp1j=mikt(ji,jj+1)
552            ! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
553            ! we assume ISF is in isostatic equilibrium
554            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( 0.5_wp * fse3w(ji+1,jj  ,iktp1i)                                    &
555               &                                  * ( 2._wp * znad + rhd(ji+1,jj  ,iktp1i) + zrhdtop_oce(ji+1,jj  ) )   &
556               &                                  - 0.5_wp * fse3w(ji  ,jj  ,ikt   )                                    &
557               &                                  * ( 2._wp * znad + rhd(ji  ,jj  ,ikt   ) + zrhdtop_oce(ji  ,jj  ) )   &
558               &                                  + ( ziceload(ji+1,jj) - ziceload(ji,jj))                              ) 
559            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( 0.5_wp * fse3w(ji  ,jj+1,iktp1j)                                    &
560               &                                  * ( 2._wp * znad + rhd(ji  ,jj+1,iktp1j) + zrhdtop_oce(ji  ,jj+1) )   &
561               &                                  - 0.5_wp * fse3w(ji  ,jj  ,ikt   )                                    & 
562               &                                  * ( 2._wp * znad + rhd(ji  ,jj  ,ikt   ) + zrhdtop_oce(ji  ,jj  ) )   &
563               &                                  + ( ziceload(ji,jj+1) - ziceload(ji,jj) )                             ) 
564            ! s-coordinate pressure gradient correction (=0 if z coordinate)
565            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
566               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
567            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
568               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
569            ! add to the general momentum trend
570            ua(ji,jj,1) = ua(ji,jj,1) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
571            va(ji,jj,1) = va(ji,jj,1) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
572         END DO
573      END DO
574!==================================================================================     
575!===== Compute partial cell contribution for the top cell =========================
576!==================================================================================
577      DO jj = 2, jpjm1
578         DO ji = fs_2, fs_jpim1   ! vector opt.
579            iku = miku(ji,jj) ; 
580            zpshpi(ji,jj)=0.0_wp ; zpshpj(ji,jj)=0.0_wp
581            ze3wu  = (gdepw_0(ji+1,jj,iku+1) - gdept_0(ji+1,jj,iku)) - (gdepw_0(ji,jj,iku+1) - gdept_0(ji,jj,iku))
582            ! u direction
583            IF ( iku .GT. 1 ) THEN
584               ! case iku
585               zhpi(ji,jj,iku)   =  zcoef0 / e1u(ji,jj) * ze3wu                                            &
586                      &                                 * ( rhd    (ji+1,jj,iku) + rhd   (ji,jj,iku)       &
587                      &                                   + SIGN(1._wp,ze3wu) * grui(ji,jj) + 2._wp * znad )
588               ! corrective term ( = 0 if z coordinate )
589               zuap              = -zcoef0 * ( arui(ji,jj) + 2._wp * znad ) * gzui(ji,jj) / e1u(ji,jj)
590               ! zhpi will be added in interior loop
591               ua(ji,jj,iku)     = ua(ji,jj,iku) + zuap
592               ! in case of 2 cell water column, need to save the pressure gradient to compute the bottom pressure 
593               IF (mbku(ji,jj) == iku + 1) zpshpi(ji,jj)  = zhpi(ji,jj,iku)
594
595               ! case iku + 1 (remove the zphi term added in the interior loop and compute the one corrected for zps)
596               zhpiint        =  zcoef0 / e1u(ji,jj)                                                               &   
597                  &           * (  fse3w(ji+1,jj  ,iku+1) * ( (rhd(ji+1,jj,iku+1) + znad)                          &
598                  &                                         + (rhd(ji+1,jj,iku  ) + znad) ) * tmask(ji+1,jj,iku)   &
599                  &              - fse3w(ji  ,jj  ,iku+1) * ( (rhd(ji  ,jj,iku+1) + znad)                          &
600                  &                                         + (rhd(ji  ,jj,iku  ) + znad) ) * tmask(ji  ,jj,iku)   )
601               zhpi(ji,jj,iku+1) =  zcoef0 / e1u(ji,jj) * ge3rui(ji,jj) - zhpiint 
602            END IF
603               
604            ! v direction
605            ikv = mikv(ji,jj)
606            ze3wv  = (gdepw_0(ji,jj+1,ikv+1) - gdept_0(ji,jj+1,ikv)) - (gdepw_0(ji,jj,ikv+1) - gdept_0(ji,jj,ikv))
607            IF ( ikv .GT. 1 ) THEN
608               ! case ikv
609               zhpj(ji,jj,ikv)   =  zcoef0 / e2v(ji,jj) * ze3wv                                            &
610                     &                                  * ( rhd(ji,jj+1,ikv) + rhd   (ji,jj,ikv)           &
611                     &                                    + SIGN(1._wp,ze3wv) * grvi(ji,jj) + 2._wp * znad )
612               ! corrective term ( = 0 if z coordinate )
613               zvap              = -zcoef0 * ( arvi(ji,jj) + 2._wp * znad ) * gzvi(ji,jj) / e2v(ji,jj)
614               ! zhpi will be added in interior loop
615               va(ji,jj,ikv)      = va(ji,jj,ikv) + zvap
616               ! in case of 2 cell water column, need to save the pressure gradient to compute the bottom pressure 
617               IF (mbkv(ji,jj) == ikv + 1)  zpshpj(ji,jj)  =  zhpj(ji,jj,ikv) 
618               
619               ! case ikv + 1 (remove the zphj term added in the interior loop and compute the one corrected for zps)
620               zhpjint        =  zcoef0 / e2v(ji,jj)                                                              &
621                  &           * (  fse3w(ji  ,jj+1,ikv+1) * ( (rhd(ji,jj+1,ikv+1) + znad)                         &
622                  &                                       + (rhd(ji,jj+1,ikv  ) + znad) ) * tmask(ji,jj+1,ikv)    &
623                  &              - fse3w(ji  ,jj  ,ikv+1) * ( (rhd(ji,jj  ,ikv+1) + znad)                         &
624                  &                                       + (rhd(ji,jj  ,ikv  ) + znad) ) * tmask(ji,jj  ,ikv)  )
625               zhpj(ji,jj,ikv+1) =  zcoef0 / e2v(ji,jj) * ge3rvi(ji,jj) - zhpjint
626            END IF
627         END DO
628      END DO
629
630!==================================================================================     
631!===== Compute interior value =====================================================
632!==================================================================================
633
634      DO jj = 2, jpjm1
635         DO ji = fs_2, fs_jpim1   ! vector opt.
636            iku=miku(ji,jj); ikv=mikv(ji,jj)
637            DO jk = 2, jpkm1
638               ! hydrostatic pressure gradient along s-surfaces
639               ! zhpi is masked for the first wet cell  (contribution already done in the upper bloc)
640               zhpi(ji,jj,jk) = zhpi(ji,jj,jk) + zhpi(ji,jj,jk-1)                                                              &
641                  &                            + zcoef0 / e1u(ji,jj)                                                           &
642                  &                                     * ( fse3w(ji+1,jj  ,jk) * ( (rhd(ji+1,jj,jk  ) + znad)                 &
643                  &                                                     + (rhd(ji+1,jj,jk-1) + znad) ) * tmask(ji+1,jj,jk-1)   &
644                  &                                       - fse3w(ji  ,jj  ,jk) * ( (rhd(ji  ,jj,jk  ) + znad)                 &
645                  &                                                     + (rhd(ji  ,jj,jk-1) + znad) ) * tmask(ji  ,jj,jk-1)   ) 
646               ! s-coordinate pressure gradient correction
647               ! corrective term, we mask this term for the first wet level beneath the ice shelf (contribution done in the upper bloc)
648               zuap = - zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )                    &
649                  &            * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj) * umask(ji,jj,jk-1)
650               ua(ji,jj,jk) = ua(ji,jj,jk) + ( zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
651
652               ! hydrostatic pressure gradient along s-surfaces
653               ! zhpi is masked for the first wet cell  (contribution already done in the upper bloc)
654               zhpj(ji,jj,jk) = zhpj(ji,jj,jk) + zhpj(ji,jj,jk-1)                                                              &
655                  &                            + zcoef0 / e2v(ji,jj)                                                           &
656                  &                                     * ( fse3w(ji  ,jj+1,jk) * ( (rhd(ji,jj+1,jk  ) + znad)                 &
657                  &                                                     + (rhd(ji,jj+1,jk-1) + znad) ) * tmask(ji,jj+1,jk-1)   &
658                  &                                       - fse3w(ji  ,jj  ,jk) * ( (rhd(ji,jj  ,jk  ) + znad)                 &
659                  &                                                     + (rhd(ji,jj  ,jk-1) + znad) ) * tmask(ji,jj  ,jk-1)   )
660               ! s-coordinate pressure gradient correction
661               ! corrective term, we mask this term for the first wet level beneath the ice shelf (contribution done in the upper bloc)
662               zvap = - zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )                     &
663                  &            * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj) * vmask(ji,jj,jk-1)
664               ! add to the general momentum trend
665               va(ji,jj,jk) = va(ji,jj,jk) + ( zhpj(ji,jj,jk) + zvap ) * vmask(ji,jj,jk)
666            END DO
667         END DO
668      END DO
669
670!==================================================================================     
671!===== Compute bottom cell contribution (partial cell) ============================
672!==================================================================================
673
674      DO jj = 2, jpjm1
675         DO ji = 2, jpim1
676            iku = mbku(ji,jj)
677            ikv = mbkv(ji,jj)
678
679            IF (iku .GT. 1) THEN
680               ! remove old value (interior case)
681               zuap            = -zcoef0 * ( rhd   (ji+1,jj  ,iku) + rhd   (ji,jj,iku) + 2._wp * znad )   &
682                     &                   * ( fsde3w(ji+1,jj  ,iku) - fsde3w(ji,jj,iku) ) / e1u(ji,jj)
683               ua(ji,jj,iku)   = ua(ji,jj,iku) - zhpi(ji,jj,iku) - zuap
684               ! put new value
685               ! -zpshpi to avoid double contribution of the partial step in the top layer
686               zuap            = -zcoef0 * ( aru(ji,jj) + 2._wp * znad ) * gzu(ji,jj)  / e1u(ji,jj)
687               zhpi(ji,jj,iku) =  zhpi(ji,jj,iku-1) + zcoef0 / e1u(ji,jj) * ge3ru(ji,jj) - zpshpi(ji,jj) 
688               ua(ji,jj,iku)   =  ua(ji,jj,iku) + zhpi(ji,jj,iku) + zuap
689            END IF
690            ! v direction
691            IF (ikv .GT. 1) THEN
692               ! remove old value (interior case)
693               zvap            = -zcoef0 * ( rhd   (ji  ,jj+1,ikv) + rhd   (ji,jj,ikv) + 2._wp * znad )   &
694                     &                   * ( fsde3w(ji  ,jj+1,ikv) - fsde3w(ji,jj,ikv) )   / e2v(ji,jj)
695               va(ji,jj,ikv)   = va(ji,jj,ikv) - zhpj(ji,jj,ikv) - zvap
696               ! put new value
697               ! -zpshpj to avoid double contribution of the partial step in the top layer
698               zvap            = -zcoef0 * ( arv(ji,jj) + 2._wp * znad ) * gzv(ji,jj)     / e2v(ji,jj)
699               zhpj(ji,jj,ikv) =  zhpj(ji,jj,ikv-1) + zcoef0 / e2v(ji,jj) * ge3rv(ji,jj) - zpshpj(ji,jj)   
700               va(ji,jj,ikv)   =  va(ji,jj,ikv) + zhpj(ji,jj,ikv) + zvap
701            END IF
702         END DO
703      END DO
704     
705      ! set back to original density value into the ice shelf cell (maybe useless because it is masked)
706      rhd = zrhd
707      !
708      CALL wrk_dealloc( jpi,jpj,2, ztstop)
709      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj, zrhd)
710      CALL wrk_dealloc( jpi,jpj, ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj)
711      !
712   END SUBROUTINE hpg_isf
713
714
715   SUBROUTINE hpg_djc( kt )
716      !!---------------------------------------------------------------------
717      !!                  ***  ROUTINE hpg_djc  ***
718      !!
719      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
720      !!
721      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
722      !!----------------------------------------------------------------------
723      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
724      !!
725      INTEGER  ::   ji, jj, jk          ! dummy loop indices
726      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
727      REAL(wp) ::   z1_10, cffu, cffx   !    "         "
728      REAL(wp) ::   z1_12, cffv, cffy   !    "         "
729      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
730      REAL(wp), POINTER, DIMENSION(:,:,:) ::  dzx, dzy, dzz, dzu, dzv, dzw
731      REAL(wp), POINTER, DIMENSION(:,:,:) ::  drhox, drhoy, drhoz, drhou, drhov, drhow
732      REAL(wp), POINTER, DIMENSION(:,:,:) ::  rho_i, rho_j, rho_k
733      !!----------------------------------------------------------------------
734      !
735      CALL wrk_alloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
736      CALL wrk_alloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
737      CALL wrk_alloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
738      !
739
740      IF( kt == nit000 ) THEN
741         IF(lwp) WRITE(numout,*)
742         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
743         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
744      ENDIF
745
746      ! Local constant initialization
747      zcoef0 = - grav * 0.5_wp
748      z1_10  = 1._wp / 10._wp
749      z1_12  = 1._wp / 12._wp
750
751      !----------------------------------------------------------------------------------------
752      !  compute and store in provisional arrays elementary vertical and horizontal differences
753      !----------------------------------------------------------------------------------------
754
755!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
756
757      DO jk = 2, jpkm1
758         DO jj = 2, jpjm1
759            DO ji = fs_2, fs_jpim1   ! vector opt.
760               drhoz(ji,jj,jk) = rhd   (ji  ,jj  ,jk) - rhd   (ji,jj,jk-1)
761               dzz  (ji,jj,jk) = fsde3w(ji  ,jj  ,jk) - fsde3w(ji,jj,jk-1)
762               drhox(ji,jj,jk) = rhd   (ji+1,jj  ,jk) - rhd   (ji,jj,jk  )
763               dzx  (ji,jj,jk) = fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk  )
764               drhoy(ji,jj,jk) = rhd   (ji  ,jj+1,jk) - rhd   (ji,jj,jk  )
765               dzy  (ji,jj,jk) = fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk  )
766            END DO
767         END DO
768      END DO
769
770      !-------------------------------------------------------------------------
771      ! compute harmonic averages using eq. 5.18
772      !-------------------------------------------------------------------------
773      zep = 1.e-15
774
775!!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
776!!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
777
778      DO jk = 2, jpkm1
779         DO jj = 2, jpjm1
780            DO ji = fs_2, fs_jpim1   ! vector opt.
781               cffw = 2._wp * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
782
783               cffu = 2._wp * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
784               cffx = 2._wp * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
785
786               cffv = 2._wp * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
787               cffy = 2._wp * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
788
789               IF( cffw > zep) THEN
790                  drhow(ji,jj,jk) = 2._wp *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
791                     &                    / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
792               ELSE
793                  drhow(ji,jj,jk) = 0._wp
794               ENDIF
795
796               dzw(ji,jj,jk) = 2._wp *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
797                  &                  / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
798
799               IF( cffu > zep ) THEN
800                  drhou(ji,jj,jk) = 2._wp *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
801                     &                    / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
802               ELSE
803                  drhou(ji,jj,jk ) = 0._wp
804               ENDIF
805
806               IF( cffx > zep ) THEN
807                  dzu(ji,jj,jk) = 2._wp *   dzx(ji+1,jj,jk) * dzx(ji,jj,jk)   &
808                     &                  / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
809               ELSE
810                  dzu(ji,jj,jk) = 0._wp
811               ENDIF
812
813               IF( cffv > zep ) THEN
814                  drhov(ji,jj,jk) = 2._wp *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
815                     &                    / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
816               ELSE
817                  drhov(ji,jj,jk) = 0._wp
818               ENDIF
819
820               IF( cffy > zep ) THEN
821                  dzv(ji,jj,jk) = 2._wp *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
822                     &                  / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
823               ELSE
824                  dzv(ji,jj,jk) = 0._wp
825               ENDIF
826
827            END DO
828         END DO
829      END DO
830
831      !----------------------------------------------------------------------------------
832      ! apply boundary conditions at top and bottom using 5.36-5.37
833      !----------------------------------------------------------------------------------
834      drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5_wp * drhow(:,:,  2  )
835      drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5_wp * drhou(:,:,  2  )
836      drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5_wp * drhov(:,:,  2  )
837
838      drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
839      drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
840      drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
841
842
843      !--------------------------------------------------------------
844      ! Upper half of top-most grid box, compute and store
845      !-------------------------------------------------------------
846
847!!bug gm   :  e3w-de3w = 0.5*e3w  ....  and de3w(2)-de3w(1)=e3w(2) ....   to be verified
848!          true if de3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
849
850      DO jj = 2, jpjm1
851         DO ji = fs_2, fs_jpim1   ! vector opt.
852            rho_k(ji,jj,1) = -grav * ( fse3w(ji,jj,1) - fsde3w(ji,jj,1) )               &
853               &                   * (  rhd(ji,jj,1)                                    &
854               &                     + 0.5_wp * ( rhd(ji,jj,2) - rhd(ji,jj,1) )         &
855               &                              * ( fse3w (ji,jj,1) - fsde3w(ji,jj,1) )   &
856               &                              / ( fsde3w(ji,jj,2) - fsde3w(ji,jj,1) )  )
857         END DO
858      END DO
859
860!!bug gm    : here also, simplification is possible
861!!bug gm    : optimisation: 1/10 and 1/12 the division should be done before the loop
862
863      DO jk = 2, jpkm1
864         DO jj = 2, jpjm1
865            DO ji = fs_2, fs_jpim1   ! vector opt.
866
867               rho_k(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj,jk) + rhd   (ji,jj,jk-1) )                                   &
868                  &                     * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) )                                   &
869                  &            - grav * z1_10 * (                                                                     &
870                  &     ( drhow (ji,jj,jk) - drhow (ji,jj,jk-1) )                                                     &
871                  &   * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
872                  &   - ( dzw   (ji,jj,jk) - dzw   (ji,jj,jk-1) )                                                     &
873                  &   * ( rhd   (ji,jj,jk) - rhd   (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
874                  &                             )
875
876               rho_i(ji,jj,jk) = zcoef0 * ( rhd   (ji+1,jj,jk) + rhd   (ji,jj,jk) )                                   &
877                  &                     * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) )                                   &
878                  &            - grav* z1_10 * (                                                                      &
879                  &     ( drhou (ji+1,jj,jk) - drhou (ji,jj,jk) )                                                     &
880                  &   * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
881                  &   - ( dzu   (ji+1,jj,jk) - dzu   (ji,jj,jk) )                                                     &
882                  &   * ( rhd   (ji+1,jj,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
883                  &                            )
884
885               rho_j(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj+1,jk) + rhd   (ji,jj,jk) )                                   &
886                  &                     * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) )                                   &
887                  &            - grav* z1_10 * (                                                                      &
888                  &     ( drhov (ji,jj+1,jk) - drhov (ji,jj,jk) )                                                     &
889                  &   * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
890                  &   - ( dzv   (ji,jj+1,jk) - dzv   (ji,jj,jk) )                                                     &
891                  &   * ( rhd   (ji,jj+1,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
892                  &                            )
893
894            END DO
895         END DO
896      END DO
897      CALL lbc_lnk(rho_k,'W',1.)
898      CALL lbc_lnk(rho_i,'U',1.)
899      CALL lbc_lnk(rho_j,'V',1.)
900
901
902      ! ---------------
903      !  Surface value
904      ! ---------------
905      DO jj = 2, jpjm1
906         DO ji = fs_2, fs_jpim1   ! vector opt.
907            zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) / e1u(ji,jj)
908            zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) / e2v(ji,jj)
909            ! add to the general momentum trend
910            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
911            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
912         END DO
913      END DO
914
915      ! ----------------
916      !  interior value   (2=<jk=<jpkm1)
917      ! ----------------
918      DO jk = 2, jpkm1
919         DO jj = 2, jpjm1
920            DO ji = fs_2, fs_jpim1   ! vector opt.
921               ! hydrostatic pressure gradient along s-surfaces
922               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
923                  &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
924                  &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) / e1u(ji,jj)
925               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
926                  &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
927                  &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) / e2v(ji,jj)
928               ! add to the general momentum trend
929               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
930               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
931            END DO
932         END DO
933      END DO
934      !
935      CALL wrk_dealloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
936      CALL wrk_dealloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
937      CALL wrk_dealloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
938      !
939   END SUBROUTINE hpg_djc
940
941
942   SUBROUTINE hpg_prj( kt )
943      !!---------------------------------------------------------------------
944      !!                  ***  ROUTINE hpg_prj  ***
945      !!
946      !! ** Method  :   s-coordinate case.
947      !!      A Pressure-Jacobian horizontal pressure gradient method
948      !!      based on the constrained cubic-spline interpolation for
949      !!      all vertical coordinate systems
950      !!
951      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
952      !!----------------------------------------------------------------------
953      INTEGER, PARAMETER  :: polynomial_type = 1    ! 1: cubic spline, 2: linear
954      INTEGER, INTENT(in) ::   kt                   ! ocean time-step index
955      !!
956      INTEGER  ::   ji, jj, jk, jkk                 ! dummy loop indices
957      REAL(wp) ::   zcoef0, znad                    ! temporary scalars
958      !!
959      !! The local variables for the correction term
960      INTEGER  :: jk1, jis, jid, jjs, jjd
961      REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
962      REAL(wp) :: zrhdt1
963      REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
964      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdept, zrhh
965      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
966      REAL(wp), POINTER, DIMENSION(:,:)   ::   zsshu_n, zsshv_n
967      !!----------------------------------------------------------------------
968      !
969      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
970      CALL wrk_alloc( jpi,jpj,jpk, zdept, zrhh )
971      CALL wrk_alloc( jpi,jpj, zsshu_n, zsshv_n )
972      !
973      IF( kt == nit000 ) THEN
974         IF(lwp) WRITE(numout,*)
975         IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
976         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, cubic spline pressure Jacobian'
977      ENDIF
978
979      !!----------------------------------------------------------------------
980      ! Local constant initialization
981      zcoef0 = - grav
982      znad = 0.0_wp
983      IF( lk_vvl ) znad = 1._wp
984
985      ! Clean 3-D work arrays
986      zhpi(:,:,:) = 0._wp
987      zrhh(:,:,:) = rhd(:,:,:)
988
989      ! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
990      DO jj = 1, jpj
991        DO ji = 1, jpi
992          jk = mbathy(ji,jj)
993          IF( jk <= 0 ) THEN; zrhh(ji,jj,:) = 0._wp
994          ELSE IF(jk == 1) THEN; zrhh(ji,jj, jk+1:jpk) = rhd(ji,jj,jk)
995          ELSE IF(jk < jpkm1) THEN
996             DO jkk = jk+1, jpk
997                zrhh(ji,jj,jkk) = interp1(fsde3w(ji,jj,jkk),   fsde3w(ji,jj,jkk-1), &
998                                         fsde3w(ji,jj,jkk-2), rhd(ji,jj,jkk-1), rhd(ji,jj,jkk-2))
999             END DO
1000          ENDIF
1001        END DO
1002      END DO
1003
1004      ! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
1005      DO jj = 1, jpj
1006         DO ji = 1, jpi
1007            zdept(ji,jj,1) = 0.5_wp * fse3w(ji,jj,1) - sshn(ji,jj) * znad
1008         END DO
1009      END DO
1010
1011      DO jk = 2, jpk
1012         DO jj = 1, jpj
1013            DO ji = 1, jpi
1014               zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + fse3w(ji,jj,jk)
1015            END DO
1016         END DO
1017      END DO
1018
1019      fsp(:,:,:) = zrhh (:,:,:)
1020      xsp(:,:,:) = zdept(:,:,:)
1021
1022      ! Construct the vertical density profile with the
1023      ! constrained cubic spline interpolation
1024      ! rho(z) = asp + bsp*z + csp*z^2 + dsp*z^3
1025      CALL cspline(fsp,xsp,asp,bsp,csp,dsp,polynomial_type)
1026
1027      ! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
1028      DO jj = 2, jpj
1029        DO ji = 2, jpi
1030          zrhdt1 = zrhh(ji,jj,1) - interp3(zdept(ji,jj,1),asp(ji,jj,1), &
1031                                         bsp(ji,jj,1),   csp(ji,jj,1), &
1032                                         dsp(ji,jj,1) ) * 0.25_wp * fse3w(ji,jj,1)
1033
1034          ! assuming linear profile across the top half surface layer
1035          zhpi(ji,jj,1) =  0.5_wp * fse3w(ji,jj,1) * zrhdt1
1036        END DO
1037      END DO
1038
1039      ! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
1040      DO jk = 2, jpkm1
1041        DO jj = 2, jpj
1042          DO ji = 2, jpi
1043            zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) +                          &
1044                             integ_spline(zdept(ji,jj,jk-1), zdept(ji,jj,jk),&
1045                                    asp(ji,jj,jk-1),    bsp(ji,jj,jk-1), &
1046                                    csp(ji,jj,jk-1),    dsp(ji,jj,jk-1))
1047          END DO
1048        END DO
1049      END DO
1050
1051      ! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
1052
1053      ! Prepare zsshu_n and zsshv_n
1054      DO jj = 2, jpjm1
1055        DO ji = 2, jpim1
1056          zsshu_n(ji,jj) = (e12u(ji,jj) * sshn(ji,jj) + e12u(ji+1, jj) * sshn(ji+1,jj)) * &
1057                         & r1_e12u(ji,jj) * umask(ji,jj,1) * 0.5_wp 
1058          zsshv_n(ji,jj) = (e12v(ji,jj) * sshn(ji,jj) + e12v(ji+1, jj) * sshn(ji,jj+1)) * &
1059                         & r1_e12v(ji,jj) * vmask(ji,jj,1) * 0.5_wp 
1060        END DO
1061      END DO
1062
1063      DO jj = 2, jpjm1
1064        DO ji = 2, jpim1
1065          zu(ji,jj,1) = - ( fse3u(ji,jj,1) - zsshu_n(ji,jj) * znad) 
1066          zv(ji,jj,1) = - ( fse3v(ji,jj,1) - zsshv_n(ji,jj) * znad)
1067        END DO
1068      END DO
1069
1070      DO jk = 2, jpkm1
1071        DO jj = 2, jpjm1
1072          DO ji = 2, jpim1
1073            zu(ji,jj,jk) = zu(ji,jj,jk-1)- fse3u(ji,jj,jk)
1074            zv(ji,jj,jk) = zv(ji,jj,jk-1)- fse3v(ji,jj,jk)
1075          END DO
1076        END DO
1077      END DO
1078
1079      DO jk = 1, jpkm1
1080        DO jj = 2, jpjm1
1081          DO ji = 2, jpim1
1082            zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * fse3u(ji,jj,jk)
1083            zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * fse3v(ji,jj,jk)
1084          END DO
1085        END DO
1086      END DO
1087
1088      DO jk = 1, jpkm1
1089        DO jj = 2, jpjm1
1090          DO ji = 2, jpim1
1091            zu(ji,jj,jk) = min(zu(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
1092            zu(ji,jj,jk) = max(zu(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
1093            zv(ji,jj,jk) = min(zv(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
1094            zv(ji,jj,jk) = max(zv(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
1095          END DO
1096        END DO
1097      END DO
1098
1099
1100      DO jk = 1, jpkm1
1101        DO jj = 2, jpjm1
1102          DO ji = 2, jpim1
1103            zpwes = 0._wp; zpwed = 0._wp
1104            zpnss = 0._wp; zpnsd = 0._wp
1105            zuijk = zu(ji,jj,jk)
1106            zvijk = zv(ji,jj,jk)
1107
1108            !!!!!     for u equation
1109            IF( jk <= mbku(ji,jj) ) THEN
1110               IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1111                 jis = ji + 1; jid = ji
1112               ELSE
1113                 jis = ji;     jid = ji +1
1114               ENDIF
1115
1116               ! integrate the pressure on the shallow side
1117               jk1 = jk
1118               DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1119                 IF( jk1 == mbku(ji,jj) ) THEN
1120                   zuijk = -zdept(jis,jj,jk1)
1121                   EXIT
1122                 ENDIF
1123                 zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1124                 zpwes = zpwes +                                    &
1125                      integ_spline(zdept(jis,jj,jk1), zdeps,            &
1126                             asp(jis,jj,jk1),    bsp(jis,jj,jk1), &
1127                             csp(jis,jj,jk1),    dsp(jis,jj,jk1))
1128                 jk1 = jk1 + 1
1129               END DO
1130
1131               ! integrate the pressure on the deep side
1132               jk1 = jk
1133               DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1134                 IF( jk1 == 1 ) THEN
1135                   zdeps = zdept(jid,jj,1) + MIN(zuijk, sshn(jid,jj)*znad)
1136                   zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1137                                                     bsp(jid,jj,1),   csp(jid,jj,1), &
1138                                                     dsp(jid,jj,1)) * zdeps
1139                   zpwed  = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1140                   EXIT
1141                 ENDIF
1142                 zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1143                 zpwed = zpwed +                                        &
1144                        integ_spline(zdeps,              zdept(jid,jj,jk1), &
1145                               asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1),  &
1146                               csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1147                 jk1 = jk1 - 1
1148               END DO
1149
1150               ! update the momentum trends in u direction
1151
1152               zdpdx1 = zcoef0 / e1u(ji,jj) * (zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk))
1153               IF( lk_vvl ) THEN
1154                 zdpdx2 = zcoef0 / e1u(ji,jj) * &
1155                         ( REAL(jis-jid, wp) * (zpwes + zpwed) + (sshn(ji+1,jj)-sshn(ji,jj)) )
1156                ELSE
1157                 zdpdx2 = zcoef0 / e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1158               ENDIF
1159
1160               ua(ji,jj,jk) = ua(ji,jj,jk) + (zdpdx1 + zdpdx2) * &
1161               &           umask(ji,jj,jk) * tmask(ji,jj,jk) * tmask(ji+1,jj,jk)
1162            ENDIF
1163
1164            !!!!!     for v equation
1165            IF( jk <= mbkv(ji,jj) ) THEN
1166               IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1167                 jjs = jj + 1; jjd = jj
1168               ELSE
1169                 jjs = jj    ; jjd = jj + 1
1170               ENDIF
1171
1172               ! integrate the pressure on the shallow side
1173               jk1 = jk
1174               DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1175                 IF( jk1 == mbkv(ji,jj) ) THEN
1176                   zvijk = -zdept(ji,jjs,jk1)
1177                   EXIT
1178                 ENDIF
1179                 zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1180                 zpnss = zpnss +                                      &
1181                        integ_spline(zdept(ji,jjs,jk1), zdeps,            &
1182                               asp(ji,jjs,jk1),    bsp(ji,jjs,jk1), &
1183                               csp(ji,jjs,jk1),    dsp(ji,jjs,jk1) )
1184                 jk1 = jk1 + 1
1185               END DO
1186
1187               ! integrate the pressure on the deep side
1188               jk1 = jk
1189               DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1190                 IF( jk1 == 1 ) THEN
1191                   zdeps = zdept(ji,jjd,1) + MIN(zvijk, sshn(ji,jjd)*znad)
1192                   zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1193                                                     bsp(ji,jjd,1),   csp(ji,jjd,1), &
1194                                                     dsp(ji,jjd,1) ) * zdeps
1195                   zpnsd  = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1196                   EXIT
1197                 ENDIF
1198                 zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1199                 zpnsd = zpnsd +                                        &
1200                        integ_spline(zdeps,              zdept(ji,jjd,jk1), &
1201                               asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1202                               csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1203                 jk1 = jk1 - 1
1204               END DO
1205
1206
1207               ! update the momentum trends in v direction
1208
1209               zdpdy1 = zcoef0 / e2v(ji,jj) * (zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk))
1210               IF( lk_vvl ) THEN
1211                   zdpdy2 = zcoef0 / e2v(ji,jj) * &
1212                           ( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (sshn(ji,jj+1)-sshn(ji,jj)) )
1213               ELSE
1214                   zdpdy2 = zcoef0 / e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1215               ENDIF
1216
1217               va(ji,jj,jk) = va(ji,jj,jk) + (zdpdy1 + zdpdy2)*&
1218               &              vmask(ji,jj,jk)*tmask(ji,jj,jk)*tmask(ji,jj+1,jk)
1219            ENDIF
1220
1221
1222           END DO
1223        END DO
1224      END DO
1225      !
1226      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
1227      CALL wrk_dealloc( jpi,jpj,jpk, zdept, zrhh )
1228      CALL wrk_dealloc( jpi,jpj, zsshu_n, zsshv_n )
1229      !
1230   END SUBROUTINE hpg_prj
1231
1232
1233   SUBROUTINE cspline(fsp, xsp, asp, bsp, csp, dsp, polynomial_type)
1234      !!----------------------------------------------------------------------
1235      !!                 ***  ROUTINE cspline  ***
1236      !!
1237      !! ** Purpose :   constrained cubic spline interpolation
1238      !!
1239      !! ** Method  :   f(x) = asp + bsp*x + csp*x^2 + dsp*x^3
1240      !!
1241      !! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1242      !!----------------------------------------------------------------------
1243      IMPLICIT NONE
1244      REAL(wp), DIMENSION(:,:,:), INTENT(in)  :: fsp, xsp           ! value and coordinate
1245      REAL(wp), DIMENSION(:,:,:), INTENT(out) :: asp, bsp, csp, dsp ! coefficients of
1246                                                                    ! the interpoated function
1247      INTEGER, INTENT(in) :: polynomial_type                        ! 1: cubic spline
1248                                                                    ! 2: Linear
1249      !
1250      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
1251      INTEGER  ::   jpi, jpj, jpkm1
1252      REAL(wp) ::   zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1253      REAL(wp) ::   zdxtmp1, zdxtmp2, zalpha
1254      REAL(wp) ::   zdf(size(fsp,3))
1255      !!----------------------------------------------------------------------
1256
1257      jpi   = size(fsp,1)
1258      jpj   = size(fsp,2)
1259      jpkm1 = size(fsp,3) - 1
1260
1261
1262      IF (polynomial_type == 1) THEN     ! Constrained Cubic Spline
1263         DO ji = 1, jpi
1264            DO jj = 1, jpj
1265           !!Fritsch&Butland's method, 1984 (preferred, but more computation)
1266           !    DO jk = 2, jpkm1-1
1267           !       zdxtmp1 = xsp(ji,jj,jk)   - xsp(ji,jj,jk-1)
1268           !       zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1269           !       zdf1    = ( fsp(ji,jj,jk)   - fsp(ji,jj,jk-1) ) / zdxtmp1
1270           !       zdf2    = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk)   ) / zdxtmp2
1271           !
1272           !       zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1273           !
1274           !       IF(zdf1 * zdf2 <= 0._wp) THEN
1275           !           zdf(jk) = 0._wp
1276           !       ELSE
1277           !         zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1278           !       ENDIF
1279           !    END DO
1280
1281           !!Simply geometric average
1282               DO jk = 2, jpkm1-1
1283                  zdf1 = (fsp(ji,jj,jk) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk) - xsp(ji,jj,jk-1))
1284                  zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk))
1285
1286                  IF(zdf1 * zdf2 <= 0._wp) THEN
1287                     zdf(jk) = 0._wp
1288                  ELSE
1289                     zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1290                  ENDIF
1291               END DO
1292
1293               zdf(1)     = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1294                          &          ( xsp(ji,jj,2) - xsp(ji,jj,1) ) -  0.5_wp * zdf(2)
1295               zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1296                          &          ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - &
1297                          & 0.5_wp * zdf(jpkm1 - 1)
1298
1299               DO jk = 1, jpkm1 - 1
1300                 zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1301                 ztmp1  = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1302                 ztmp2  =  6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1303                 zddf1  = -2._wp * ztmp1 + ztmp2
1304                 ztmp1  = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1305                 zddf2  =  2._wp * ztmp1 - ztmp2
1306
1307                 dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1308                 csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1309                 bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1310                               & csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1311                               & dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1312                               &                   xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1313                 asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1314                               &                (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1315                               &                 dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1316               END DO
1317            END DO
1318         END DO
1319
1320      ELSE IF (polynomial_type == 2) THEN     ! Linear
1321         DO ji = 1, jpi
1322            DO jj = 1, jpj
1323               DO jk = 1, jpkm1-1
1324                  zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1325                  ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1326
1327                  dsp(ji,jj,jk) = 0._wp
1328                  csp(ji,jj,jk) = 0._wp
1329                  bsp(ji,jj,jk) = ztmp1 / zdxtmp
1330                  asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1331               END DO
1332            END DO
1333         END DO
1334
1335      ELSE
1336           CALL ctl_stop( 'invalid polynomial type in cspline' )
1337      ENDIF
1338
1339   END SUBROUTINE cspline
1340
1341
1342   FUNCTION interp1(x, xl, xr, fl, fr)  RESULT(f)
1343      !!----------------------------------------------------------------------
1344      !!                 ***  ROUTINE interp1  ***
1345      !!
1346      !! ** Purpose :   1-d linear interpolation
1347      !!
1348      !! ** Method  :   interpolation is straight forward
1349      !!                extrapolation is also permitted (no value limit)
1350      !!----------------------------------------------------------------------
1351      IMPLICIT NONE
1352      REAL(wp), INTENT(in) ::  x, xl, xr, fl, fr
1353      REAL(wp)             ::  f ! result of the interpolation (extrapolation)
1354      REAL(wp)             ::  zdeltx
1355      !!----------------------------------------------------------------------
1356
1357      zdeltx = xr - xl
1358      IF(abs(zdeltx) <= 10._wp * EPSILON(x)) THEN
1359        f = 0.5_wp * (fl + fr)
1360      ELSE
1361        f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1362      ENDIF
1363
1364   END FUNCTION interp1
1365
1366
1367   FUNCTION interp2(x, a, b, c, d)  RESULT(f)
1368      !!----------------------------------------------------------------------
1369      !!                 ***  ROUTINE interp1  ***
1370      !!
1371      !! ** Purpose :   1-d constrained cubic spline interpolation
1372      !!
1373      !! ** Method  :  cubic spline interpolation
1374      !!
1375      !!----------------------------------------------------------------------
1376      IMPLICIT NONE
1377      REAL(wp), INTENT(in) ::  x, a, b, c, d
1378      REAL(wp)             ::  f ! value from the interpolation
1379      !!----------------------------------------------------------------------
1380
1381      f = a + x* ( b + x * ( c + d * x ) )
1382
1383   END FUNCTION interp2
1384
1385
1386   FUNCTION interp3(x, a, b, c, d)  RESULT(f)
1387      !!----------------------------------------------------------------------
1388      !!                 ***  ROUTINE interp1  ***
1389      !!
1390      !! ** Purpose :   Calculate the first order of deriavtive of
1391      !!                a cubic spline function y=a+b*x+c*x^2+d*x^3
1392      !!
1393      !! ** Method  :   f=dy/dx=b+2*c*x+3*d*x^2
1394      !!
1395      !!----------------------------------------------------------------------
1396      IMPLICIT NONE
1397      REAL(wp), INTENT(in) ::  x, a, b, c, d
1398      REAL(wp)             ::  f ! value from the interpolation
1399      !!----------------------------------------------------------------------
1400
1401      f = b + x * ( 2._wp * c + 3._wp * d * x)
1402
1403   END FUNCTION interp3
1404
1405
1406   FUNCTION integ_spline(xl, xr, a, b, c, d)  RESULT(f)
1407      !!----------------------------------------------------------------------
1408      !!                 ***  ROUTINE interp1  ***
1409      !!
1410      !! ** Purpose :   1-d constrained cubic spline integration
1411      !!
1412      !! ** Method  :  integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1413      !!
1414      !!----------------------------------------------------------------------
1415      IMPLICIT NONE
1416      REAL(wp), INTENT(in) ::  xl, xr, a, b, c, d
1417      REAL(wp)             ::  za1, za2, za3
1418      REAL(wp)             ::  f                   ! integration result
1419      !!----------------------------------------------------------------------
1420
1421      za1 = 0.5_wp * b
1422      za2 = c / 3.0_wp
1423      za3 = 0.25_wp * d
1424
1425      f  = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1426         & xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1427
1428   END FUNCTION integ_spline
1429
1430   !!======================================================================
1431END MODULE dynhpg
1432
Note: See TracBrowser for help on using the repository browser.