source: branches/UKMO/GO6_dyn_vrt_diag/NEMOGCM/NEMO/OPA_SRC/DYN/dynzdf.F90 @ 8300

Last change on this file since 8300 was 8300, checked in by glong, 4 years ago

Changed diagnostics to calculate the contributions by taking after-before before going into the specific numerical scheme for the model.

File size: 7.1 KB
Line 
1MODULE dynzdf
2   !!==============================================================================
3   !!                 ***  MODULE  dynzdf  ***
4   !! Ocean dynamics :  vertical component of the momentum mixing trend
5   !!==============================================================================
6   !! History :  1.0  !  2005-11  (G. Madec)  Original code
7   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   dyn_zdf      : Update the momentum trend with the vertical diffusion
12   !!   dyn_zdf_init : initializations of the vertical diffusion scheme
13   !!----------------------------------------------------------------------
14   USE oce             ! ocean dynamics and tracers variables
15   USE dom_oce         ! ocean space and time domain variables
16   USE zdf_oce         ! ocean vertical physics variables
17
18   USE dynzdf_exp      ! vertical diffusion: explicit (dyn_zdf_exp     routine)
19   USE dynzdf_imp      ! vertical diffusion: implicit (dyn_zdf_imp     routine)
20
21   USE ldfdyn_oce      ! ocean dynamics: lateral physics
22   USE trd_oce         ! trends: ocean variables
23   USE trddyn          ! trend manager: dynamics
24   USE in_out_manager  ! I/O manager
25   USE lib_mpp         ! MPP library
26   USE prtctl          ! Print control
27   USE wrk_nemo        ! Memory Allocation
28   USE timing          ! Timing
29   USE divcur          ! for dyn_vrt_dia
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   dyn_zdf       !  routine called by step.F90
35   PUBLIC   dyn_zdf_init  !  routine called by opa.F90
36
37   INTEGER  ::   nzdf = 0   ! type vertical diffusion algorithm used, defined from ln_zdf... namlist logicals
38   REAL(wp) ::   r2dt       ! time-step, = 2 rdttra except at nit000 (=rdttra) if neuler=0
39
40   !! * Substitutions
41#  include "domzgr_substitute.h90"
42#  include "zdfddm_substitute.h90"
43#  include "vectopt_loop_substitute.h90"
44   !!----------------------------------------------------------------------
45   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
46   !! $Id$
47   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
48   !!----------------------------------------------------------------------
49
50CONTAINS
51   
52   SUBROUTINE dyn_zdf( kt )
53      !!----------------------------------------------------------------------
54      !!                  ***  ROUTINE dyn_zdf  ***
55      !!
56      !! ** Purpose :   compute the vertical ocean dynamics physics.
57      !!---------------------------------------------------------------------
58      !!
59      INTEGER, INTENT( in ) ::   kt      ! ocean time-step index
60      !
61      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdu, ztrdv
62      CHARACTER(len=3) :: id_vrt_dia_zdf = "zdf"   ! TODO remove once flags properly set
63      !!---------------------------------------------------------------------
64      !
65      IF( nn_timing == 1 )  CALL timing_start('dyn_zdf')
66      !
67      !                                          ! set time step
68      IF( neuler == 0 .AND. kt == nit000     ) THEN   ;   r2dt =      rdt   ! = rdtra (restart with Euler time stepping)
69      ELSEIF(               kt <= nit000 + 1 ) THEN   ;   r2dt = 2. * rdt   ! = 2 rdttra (leapfrog)
70      ENDIF
71
72      IF( l_trddyn .or. ( id_vrt_dia_zdf == "zdf" ) )   THEN      ! temporary save of ta and sa trends
73         CALL wrk_alloc( jpi, jpj, jpk, ztrdu, ztrdv ) 
74         ztrdu(:,:,:) = ua(:,:,:)
75         ztrdv(:,:,:) = va(:,:,:)
76      ENDIF
77
78      SELECT CASE ( nzdf )                       ! compute lateral mixing trend and add it to the general trend
79      !
80      CASE ( 0 )   ;   CALL dyn_zdf_exp( kt, r2dt )      ! explicit scheme
81      CASE ( 1 )   ;   CALL dyn_zdf_imp( kt, r2dt )      ! implicit scheme
82      !
83      CASE ( -1 )                                        ! esopa: test all possibility with control print
84                       CALL dyn_zdf_exp( kt, r2dt )
85                       CALL prt_ctl( tab3d_1=ua, clinfo1=' zdf0 - Ua: ', mask1=umask,               &
86                          &          tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
87                       CALL dyn_zdf_imp( kt, r2dt )
88                       CALL prt_ctl( tab3d_1=ua, clinfo1=' zdf1 - Ua: ', mask1=umask,               &
89                          &          tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
90      END SELECT
91
92      IF( l_trddyn .or. ( id_vrt_dia_zdf == "zdf" ) )   THEN      ! save the vertical diffusive trends for further diagnostics
93         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
94         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
95         !
96         IF( id_vrt_dia_zdf == "zdf" ) THEN
97             CALL dyn_vrt_dia_3d( ztrdu, ztrdv, id_vrt_dia_zdf )
98         END IF
99         !
100         IF( l_trddyn ) THEN
101             CALL trd_dyn( ztrdu, ztrdv, jpdyn_zdf, kt )
102         END IF
103         !
104         CALL wrk_dealloc( jpi, jpj, jpk, ztrdu, ztrdv ) 
105      ENDIF
106      !                                          ! print mean trends (used for debugging)
107      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' zdf  - Ua: ', mask1=umask,               &
108            &                    tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
109      !
110      IF( nn_timing == 1 )  CALL timing_stop('dyn_zdf')
111      !
112   END SUBROUTINE dyn_zdf
113
114
115   SUBROUTINE dyn_zdf_init
116      !!----------------------------------------------------------------------
117      !!                 ***  ROUTINE dyn_zdf_init  ***
118      !!
119      !! ** Purpose :   initializations of the vertical diffusion scheme
120      !!
121      !! ** Method  :   implicit (euler backward) scheme (default)
122      !!                explicit (time-splitting) scheme if ln_zdfexp=T
123      !!----------------------------------------------------------------------
124      USE zdftke
125      USE zdfgls
126      USE zdfkpp
127      !!----------------------------------------------------------------------
128      !
129      ! Choice from ln_zdfexp read in namelist in zdfini
130      IF( ln_zdfexp ) THEN   ;   nzdf = 0           ! use explicit scheme
131      ELSE                   ;   nzdf = 1           ! use implicit scheme
132      ENDIF
133      !
134      ! Force implicit schemes
135      IF( lk_zdftke .OR. lk_zdfgls .OR. lk_zdfkpp )   nzdf = 1   ! TKE, GLS or KPP physics
136      IF( ln_dynldf_iso                           )   nzdf = 1   ! iso-neutral lateral physics
137      IF( ln_dynldf_hor .AND. ln_sco              )   nzdf = 1   ! horizontal lateral physics in s-coordinate
138      !
139      IF( lk_esopa )    nzdf = -1                   ! Esopa key: All schemes used
140      !
141      IF(lwp) THEN                                  ! Print the choice
142         WRITE(numout,*)
143         WRITE(numout,*) 'dyn_zdf_init : vertical dynamics physics scheme'
144         WRITE(numout,*) '~~~~~~~~~~~'
145         IF( nzdf == -1 )   WRITE(numout,*) '              ESOPA test All scheme used'
146         IF( nzdf ==  0 )   WRITE(numout,*) '              Explicit time-splitting scheme'
147         IF( nzdf ==  1 )   WRITE(numout,*) '              Implicit (euler backward) scheme'
148      ENDIF
149      !
150   END SUBROUTINE dyn_zdf_init
151
152   !!==============================================================================
153END MODULE dynzdf
Note: See TracBrowser for help on using the repository browser.