source: branches/UKMO/dev_1d_bugfixes_tocommit/NEMOGCM/NEMO/OPA_SRC/TRA/traqsr.F90 @ 13191

Last change on this file since 13191 was 13191, checked in by jwhile, 11 months ago

Updates for 1d runnig

File size: 33.0 KB
Line 
1MODULE traqsr
2   !!======================================================================
3   !!                       ***  MODULE  traqsr  ***
4   !! Ocean physics: solar radiation penetration in the top ocean levels
5   !!======================================================================
6   !! History :  OPA  !  1990-10  (B. Blanke)  Original code
7   !!            7.0  !  1991-11  (G. Madec)
8   !!                 !  1996-01  (G. Madec)  s-coordinates
9   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
10   !!             -   !  2005-11  (G. Madec) zco, zps, sco coordinate
11   !!            3.2  !  2009-04  (G. Madec & NEMO team)
12   !!            3.4  !  2012-05  (C. Rousset) store attenuation coef for use in ice model
13   !!            3.6  !  2015-12  (O. Aumont, J. Jouanno, C. Ethe) use vertical profile of chlorophyll
14   !!----------------------------------------------------------------------
15
16   !!----------------------------------------------------------------------
17   !!   tra_qsr      : trend due to the solar radiation penetration
18   !!   tra_qsr_init : solar radiation penetration initialization
19   !!----------------------------------------------------------------------
20   USE oce             ! ocean dynamics and active tracers
21   USE dom_oce         ! ocean space and time domain
22   USE sbc_oce         ! surface boundary condition: ocean
23   USE trc_oce         ! share SMS/Ocean variables
24   USE trd_oce        ! trends: ocean variables
25   USE trdtra         ! trends manager: tracers
26   USE in_out_manager  ! I/O manager
27   USE phycst          ! physical constants
28   USE prtctl          ! Print control
29   USE iom             ! I/O manager
30   USE fldread         ! read input fields
31   USE restart         ! ocean restart
32   USE lib_mpp         ! MPP library
33   USE wrk_nemo       ! Memory Allocation
34   USE timing         ! Timing
35   USE stopack
36
37   IMPLICIT NONE
38   PRIVATE
39
40   PUBLIC   tra_qsr       ! routine called by step.F90 (ln_traqsr=T)
41   PUBLIC   tra_qsr_init  ! routine called by nemogcm.F90
42
43   !                                 !!* Namelist namtra_qsr: penetrative solar radiation
44   LOGICAL , PUBLIC ::   ln_traqsr    !: light absorption (qsr) flag
45   LOGICAL , PUBLIC ::   ln_qsr_rgb   !: Red-Green-Blue light absorption flag
46   LOGICAL , PUBLIC ::   ln_qsr_2bd   !: 2 band         light absorption flag
47   LOGICAL , PUBLIC ::   ln_qsr_bio   !: bio-model      light absorption flag
48   LOGICAL , PUBLIC ::   ln_qsr_ice   !: light penetration for ice-model LIM3 (clem)
49   INTEGER , PUBLIC ::   nn_chldta    !: use Chlorophyll data (=1) or not (=0)
50   REAL(wp), PUBLIC ::   rn_abs       !: fraction absorbed in the very near surface (RGB & 2 bands)
51   REAL(wp), PUBLIC ::   rn_si0       !: very near surface depth of extinction      (RGB & 2 bands)
52   REAL(wp), PUBLIC ::   rn_si1       !: deepest depth of extinction (water type I)       (2 bands)
53
54   ! Module variables
55   REAL(wp), ALLOCATABLE ::   xsi0r(:,:)         !: inverse of rn_si0
56   REAL(wp) ::   xsi1r                           !: inverse of rn_si1
57   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_chl   ! structure of input Chl (file informations, fields read)
58   INTEGER, PUBLIC ::   nksr              ! levels below which the light cannot penetrate ( depth larger than 391 m)
59   REAL(wp), DIMENSION(3,61) ::   rkrgb   !: tabulated attenuation coefficients for RGB absorption
60
61   !! * Substitutions
62#  include "domzgr_substitute.h90"
63#  include "vectopt_loop_substitute.h90"
64   !!----------------------------------------------------------------------
65   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
66   !! $Id$
67   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
68   !!----------------------------------------------------------------------
69CONTAINS
70
71   SUBROUTINE tra_qsr( kt )
72      !!----------------------------------------------------------------------
73      !!                  ***  ROUTINE tra_qsr  ***
74      !!
75      !! ** Purpose :   Compute the temperature trend due to the solar radiation
76      !!      penetration and add it to the general temperature trend.
77      !!
78      !! ** Method  : The profile of the solar radiation within the ocean is defined
79      !!      through 2 wavebands (rn_si0,rn_si1) or 3 wavebands (RGB) and a ratio rn_abs
80      !!      Considering the 2 wavebands case:
81      !!         I(k) = Qsr*( rn_abs*EXP(z(k)/rn_si0) + (1.-rn_abs)*EXP(z(k)/rn_si1) )
82      !!         The temperature trend associated with the solar radiation penetration
83      !!         is given by : zta = 1/e3t dk[ I ] / (rau0*Cp)
84      !!         At the bottom, boudary condition for the radiation is no flux :
85      !!      all heat which has not been absorbed in the above levels is put
86      !!      in the last ocean level.
87      !!         In z-coordinate case, the computation is only done down to the
88      !!      level where I(k) < 1.e-15 W/m2. In addition, the coefficients
89      !!      used for the computation are calculated one for once as they
90      !!      depends on k only.
91      !!
92      !! ** Action  : - update ta with the penetrative solar radiation trend
93      !!              - save the trend in ttrd ('key_trdtra')
94      !!
95      !! Reference  : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp.
96      !!              Lengaigne et al. 2007, Clim. Dyn., V28, 5, 503-516.
97      !!              Morel, A. et Berthon, JF, 1989, Limnol Oceanogr 34(8), 1545-1562
98      !!----------------------------------------------------------------------
99      !
100      INTEGER, INTENT(in) ::   kt     ! ocean time-step
101      !
102      INTEGER  ::   ji, jj, jk           ! dummy loop indices
103      INTEGER  ::   irgb                 ! local integers
104      REAL(wp) ::   zchl, zcoef, zfact   ! local scalars
105      REAL(wp) ::   zc0, zc1, zc2, zc3   !    -         -
106      REAL(wp) ::   zz0, zz1, z1_e3t     !    -         -
107      REAL(wp) ::   zCb, zCmax, zze, zpsi, zpsimax, zdelpsi, zCtot, zCze
108      REAL(wp) ::   zlogc, zlogc2, zlogc3
109      REAL(wp), POINTER, DIMENSION(:,:  ) :: zekb, zekg, zekr
110      REAL(wp), POINTER, DIMENSION(:,:,:) :: ze0, ze1, ze2, ze3, zea, ztrdt, zchl3d
111      !!--------------------------------------------------------------------------
112      !
113      IF( nn_timing == 1 )  CALL timing_start('tra_qsr')
114      !
115      CALL wrk_alloc( jpi, jpj,      zekb, zekg, zekr        )
116      CALL wrk_alloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea, zchl3d )
117      !
118      IF( kt == nit000 ) THEN
119         IF(lwp) WRITE(numout,*)
120         IF(lwp) WRITE(numout,*) 'tra_qsr : penetration of the surface solar radiation'
121         IF(lwp) WRITE(numout,*) '~~~~~~~'
122         IF( .NOT.ln_traqsr )   RETURN
123      ENDIF
124
125      IF( l_trdtra ) THEN      ! Save ta and sa trends
126         CALL wrk_alloc( jpi, jpj, jpk, ztrdt )
127         ztrdt(:,:,:) = tsa(:,:,:,jp_tem)
128      ENDIF
129
130      !                                        Set before qsr tracer content field
131      !                                        ***********************************
132      IF( kt == nit000 ) THEN                     ! Set the forcing field at nit000 - 1
133         !                                        ! -----------------------------------
134         qsr_hc(:,:,:) = 0.e0
135         !
136         IF( ln_rstart .AND.    &                    ! Restart: read in restart file
137              & iom_varid( numror, 'qsr_hc_b', ldstop = .FALSE. ) > 0 ) THEN
138            IF(lwp) WRITE(numout,*) '          nit000-1 qsr tracer content forcing field red in the restart file'
139            zfact = 0.5e0
140            CALL iom_get( numror, jpdom_autoglo, 'qsr_hc_b', qsr_hc_b )   ! before heat content trend due to Qsr flux
141         ELSE                                           ! No restart or restart not found: Euler forward time stepping
142            zfact = 1.e0
143            qsr_hc_b(:,:,:) = 0.e0
144         ENDIF
145      ELSE                                        ! Swap of forcing field
146         !                                        ! ---------------------
147         zfact = 0.5e0
148         qsr_hc_b(:,:,:) = qsr_hc(:,:,:)
149      ENDIF
150      !                                        Compute now qsr tracer content field
151      !                                        ************************************
152
153      !                                           ! ============================================== !
154      IF( lk_qsr_bio .AND. ln_qsr_bio ) THEN      !  bio-model fluxes  : all vertical coordinates  !
155         !                                        ! ============================================== !
156         DO jk = 1, jpkm1
157            qsr_hc(:,:,jk) = r1_rau0_rcp * ( etot3(:,:,jk) - etot3(:,:,jk+1) )
158         END DO
159         !                                        Add to the general trend
160         DO jk = 1, jpkm1
161            DO jj = 2, jpjm1
162               DO ji = fs_2, fs_jpim1   ! vector opt.
163                  z1_e3t = zfact / fse3t(ji,jj,jk)
164                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t
165               END DO
166            END DO
167         END DO
168         CALL iom_put( 'qsr3d', etot3 )   ! Shortwave Radiation 3D distribution
169         ! clem: store attenuation coefficient of the first ocean level
170         IF ( ln_qsr_ice ) THEN
171            DO jj = 1, jpj
172               DO ji = 1, jpi
173                  IF ( qsr(ji,jj) /= 0._wp ) THEN
174                     fraqsr_1lev(ji,jj) = ( qsr_hc(ji,jj,1) / ( r1_rau0_rcp * qsr(ji,jj) ) )
175                  ELSE
176                     fraqsr_1lev(ji,jj) = 1.
177                  ENDIF
178               END DO
179            END DO
180         ENDIF
181         !                                        ! ============================================== !
182      ELSE                                        !  Ocean alone :
183         !                                        ! ============================================== !
184         !
185         !
186#if defined key_traldf_c2d || key_traldf_c3d
187         IF( ln_stopack .AND. ( nn_spp_qsi0 > 0 ) ) THEN
188            xsi0r = rn_si0
189            CALL spp_gen(kt, xsi0r, nn_spp_qsi0, rn_qsi0_sd, jk_spp_qsi0 )
190            xsi0r = 1.e0 / xsi0r
191         ENDIF
192#else
193         IF ( ln_stopack .AND. nn_spp_qsi0 > 0 ) &
194            & CALL ctl_stop( 'tra_qsr: parameter perturbation will only work with '// &
195                             'key_traldf_c2d or key_traldf_c3d')
196#endif
197
198         !                                               ! ------------------------- !
199         IF( ln_qsr_rgb) THEN                             !  R-G-B  light penetration !
200            !                                             ! ------------------------- !
201            ! Set chlorophyl concentration
202            IF( nn_chldta == 1 .OR. nn_chldta == 2 .OR. lk_vvl ) THEN    !*  Variable Chlorophyll or ocean volume
203               !
204               IF( nn_chldta == 1 ) THEN        !*  2D Variable Chlorophyll
205                  !
206                  CALL fld_read( kt, 1, sf_chl )            ! Read Chl data and provides it at the current time step
207                  DO jk = 1, nksr + 1
208                     zchl3d(:,:,jk) = sf_chl(1)%fnow(:,:,1)
209                  ENDDO
210                  !
211               ELSE IF( nn_chldta == 2 ) THEN    !*   -3-D Variable Chlorophyll
212                  !
213                  CALL fld_read( kt, 1, sf_chl )            ! Read Chl data and provides it at the current time step
214!CDIR NOVERRCHK   !
215                  DO jj = 1, jpj
216!CDIR NOVERRCHK
217                     DO ji = 1, jpi
218                        zchl    = sf_chl(1)%fnow(ji,jj,1)
219                        zCtot   = 40.6  * zchl**0.459
220                        zze     = 568.2 * zCtot**(-0.746)
221                        IF( zze > 102. ) zze = 200.0 * zCtot**(-0.293)
222                        zlogc   = LOG( zchl )
223                        zlogc2  = zlogc * zlogc
224                        zlogc3  = zlogc * zlogc * zlogc
225                        zCb     = 0.768 + 0.087 * zlogc - 0.179 * zlogc2 - 0.025 * zlogc3
226                        zCmax   = 0.299 - 0.289 * zlogc + 0.579 * zlogc2
227                        zpsimax = 0.6   - 0.640 * zlogc + 0.021 * zlogc2 + 0.115 * zlogc3
228                        zdelpsi = 0.710 + 0.159 * zlogc + 0.021 * zlogc2
229                        zCze    = 1.12  * (zchl)**0.803
230                        DO jk = 1, nksr + 1
231                           zpsi = fsdept(ji,jj,jk) / zze
232                           zchl3d(ji,jj,jk) = zCze * ( zCb + zCmax * EXP( -( (zpsi - zpsimax) / zdelpsi )**2 ) )
233                        END DO
234                        !
235                      END DO
236                   END DO
237                     !
238               ELSE                              !* Variable ocean volume but constant chrlorophyll
239                  DO jk = 1, nksr + 1
240                     zchl3d(:,:,jk) = 0.05
241                  ENDDO
242               ENDIF
243               !
244               zcoef  = ( 1. - rn_abs ) / 3.e0                        !  equi-partition in R-G-B
245               ze0(:,:,1) = rn_abs  * qsr(:,:)
246               ze1(:,:,1) = zcoef * qsr(:,:)
247               ze2(:,:,1) = zcoef * qsr(:,:)
248               ze3(:,:,1) = zcoef * qsr(:,:)
249               zea(:,:,1) =         qsr(:,:)
250               !
251               DO jk = 2, nksr+1
252                  !
253                  DO jj = 1, jpj                                         ! Separation in R-G-B depending of vertical profile of Chl
254!CDIR NOVERRCHK
255                     DO ji = 1, jpi
256                        zchl = MIN( 10. , MAX( 0.03, zchl3d(ji,jj,jk) ) )
257                        irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 )
258                        zekb(ji,jj) = rkrgb(1,irgb)
259                        zekg(ji,jj) = rkrgb(2,irgb)
260                        zekr(ji,jj) = rkrgb(3,irgb)
261                     END DO
262                  END DO
263!CDIR NOVERRCHK
264                  DO jj = 1, jpj
265!CDIR NOVERRCHK
266                     DO ji = 1, jpi
267                        zc0 = ze0(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * xsi0r(ji,jj) )
268                        zc1 = ze1(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekb(ji,jj) )
269                        zc2 = ze2(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekg(ji,jj) )
270                        zc3 = ze3(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekr(ji,jj) )
271                        ze0(ji,jj,jk) = zc0
272                        ze1(ji,jj,jk) = zc1
273                        ze2(ji,jj,jk) = zc2
274                        ze3(ji,jj,jk) = zc3
275                        zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk)
276                     END DO
277                  END DO
278               END DO
279               !
280               DO jk = 1, nksr                                        ! compute and add qsr trend to ta
281                  qsr_hc(:,:,jk) = r1_rau0_rcp * ( zea(:,:,jk) - zea(:,:,jk+1) )
282               END DO
283               zea(:,:,nksr+1:jpk) = 0.e0     ! below 400m set to zero
284               CALL iom_put( 'qsr3d', zea )   ! Shortwave Radiation 3D distribution
285               !
286               IF ( ln_qsr_ice ) THEN    ! store attenuation coefficient of the first ocean level
287!CDIR NOVERRCHK
288                  DO jj = 1, jpj                                         ! Separation in R-G-B depending of the surface Chl
289!CDIR NOVERRCHK
290                     DO ji = 1, jpi
291                        zchl = MIN( 10. , MAX( 0.03, zchl3d(ji,jj,1) ) )
292                        irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 )
293                        zekb(ji,jj) = rkrgb(1,irgb)
294                        zekg(ji,jj) = rkrgb(2,irgb)
295                        zekr(ji,jj) = rkrgb(3,irgb)
296                     END DO
297                  END DO
298                  !
299                  DO jj = 1, jpj
300                     DO ji = 1, jpi
301                        zc0 = rn_abs * EXP( - fse3t(ji,jj,1) * xsi0r(ji,jj) )
302                        zc1 = zcoef  * EXP( - fse3t(ji,jj,1) * zekb(ji,jj) )
303                        zc2 = zcoef  * EXP( - fse3t(ji,jj,1) * zekg(ji,jj) )
304                        zc3 = zcoef  * EXP( - fse3t(ji,jj,1) * zekr(ji,jj) )
305                        fraqsr_1lev(ji,jj) = 1.0 - ( zc0 + zc1 + zc2  + zc3  ) * tmask(ji,jj,2)
306                     END DO
307                  END DO
308                  !
309               ENDIF
310               !
311            ELSE                                                 !*  Constant Chlorophyll
312               DO jk = 1, nksr
313                  qsr_hc(:,:,jk) =  etot3(:,:,jk) * qsr(:,:)
314               END DO
315               !  store attenuation coefficient of the first ocean level
316               IF( ln_qsr_ice ) THEN
317                  fraqsr_1lev(:,:) = etot3(:,:,1) / r1_rau0_rcp
318               ENDIF
319           ENDIF
320
321         ENDIF
322         !                                                ! ------------------------- !
323         IF( ln_qsr_2bd ) THEN                            !  2 band light penetration !
324            !                                             ! ------------------------- !
325            !
326            IF( lk_vvl .OR. ( ln_stopack .AND. ( nn_spp_qsi0 > 0 ) ) ) THEN        !* variable volume
327
328               zz0   =        rn_abs   * r1_rau0_rcp
329               zz1   = ( 1. - rn_abs ) * r1_rau0_rcp
330               DO jk = 1, nksr                    ! solar heat absorbed at T-point in the top 400m
331                  DO jj = 1, jpj
332                     DO ji = 1, jpi
333                        zc0 = zz0 * EXP( -fsdepw(ji,jj,jk  )*xsi0r(ji,jj) ) + zz1 * EXP( -fsdepw(ji,jj,jk  )*xsi1r )
334                        zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r(ji,jj) ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r )
335                        qsr_hc(ji,jj,jk) = qsr(ji,jj) * ( zc0*tmask(ji,jj,jk) - zc1*tmask(ji,jj,jk+1) )
336                     END DO
337                  END DO
338               END DO
339               ! clem: store attenuation coefficient of the first ocean level
340               IF ( ln_qsr_ice ) THEN
341                  DO jj = 1, jpj
342                     DO ji = 1, jpi
343                        zc0 = zz0 * EXP( -fsdepw(ji,jj,1)*xsi0r(ji,jj) ) + zz1 * EXP( -fsdepw(ji,jj,1)*xsi1r )
344                        zc1 = zz0 * EXP( -fsdepw(ji,jj,2)*xsi0r(ji,jj) ) + zz1 * EXP( -fsdepw(ji,jj,2)*xsi1r )
345                        fraqsr_1lev(ji,jj) = ( zc0*tmask(ji,jj,1) - zc1*tmask(ji,jj,2) ) / r1_rau0_rcp
346                     END DO
347                  END DO
348               ENDIF
349            ELSE                                               !* constant volume: coef. computed one for all
350               DO jk = 1, nksr
351                  DO jj = 2, jpjm1
352                     DO ji = fs_2, fs_jpim1   ! vector opt.
353                        ! (ISF) no light penetration below the ice shelves
354                        qsr_hc(ji,jj,jk) =  etot3(ji,jj,jk) * qsr(ji,jj) * tmask(ji,jj,1)
355                     END DO
356                  END DO
357               END DO
358               ! clem: store attenuation coefficient of the first ocean level
359               IF ( ln_qsr_ice ) THEN
360                  fraqsr_1lev(:,:) = etot3(:,:,1) / r1_rau0_rcp
361               ENDIF
362               !
363            ENDIF
364            !
365         ENDIF
366         !
367         !                                        Add to the general trend
368         DO jk = 1, nksr
369            DO jj = 2, jpjm1
370               DO ji = fs_2, fs_jpim1   ! vector opt.
371                  z1_e3t = zfact / fse3t(ji,jj,jk)
372                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t
373               END DO
374            END DO
375         END DO
376         !
377      ENDIF
378      !
379      IF( lrst_oce ) THEN   !                  Write in the ocean restart file
380         !                                     *******************************
381         IF(lwp) WRITE(numout,*)
382         IF(lwp) WRITE(numout,*) 'qsr tracer content forcing field written in ocean restart file ',   &
383            &                    'at it= ', kt,' date= ', ndastp
384         IF(lwp) WRITE(numout,*) '~~~~'
385         IF(nn_timing == 2)  CALL timing_start('iom_rstput')
386         CALL iom_rstput( kt, nitrst, numrow, 'qsr_hc_b'   , qsr_hc      )
387         CALL iom_rstput( kt, nitrst, numrow, 'fraqsr_1lev', fraqsr_1lev )   ! default definition in sbcssm
388         IF(nn_timing == 2)  CALL timing_stop('iom_rstput')
389         !
390      ENDIF
391
392      IF( l_trdtra ) THEN     ! qsr tracers trends saved for diagnostics
393         ztrdt(:,:,:) = tsa(:,:,:,jp_tem) - ztrdt(:,:,:)
394         CALL trd_tra( kt, 'TRA', jp_tem, jptra_qsr, ztrdt )
395         CALL wrk_dealloc( jpi, jpj, jpk, ztrdt )
396      ENDIF
397      !                       ! print mean trends (used for debugging)
398      IF(ln_ctl)   CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' qsr  - Ta: ', mask1=tmask, clinfo3='tra-ta' )
399      !
400      CALL wrk_dealloc( jpi, jpj,      zekb, zekg, zekr        )
401      CALL wrk_dealloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea, zchl3d )
402      !
403      IF( nn_timing == 1 )  CALL timing_stop('tra_qsr')
404      !
405   END SUBROUTINE tra_qsr
406
407
408   SUBROUTINE tra_qsr_init
409      !!----------------------------------------------------------------------
410      !!                  ***  ROUTINE tra_qsr_init  ***
411      !!
412      !! ** Purpose :   Initialization for the penetrative solar radiation
413      !!
414      !! ** Method  :   The profile of solar radiation within the ocean is set
415      !!      from two length scale of penetration (rn_si0,rn_si1) and a ratio
416      !!      (rn_abs). These parameters are read in the namtra_qsr namelist. The
417      !!      default values correspond to clear water (type I in Jerlov'
418      !!      (1968) classification.
419      !!         called by tra_qsr at the first timestep (nit000)
420      !!
421      !! ** Action  : - initialize rn_si0, rn_si1 and rn_abs
422      !!
423      !! Reference : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp.
424      !!----------------------------------------------------------------------
425      !
426      INTEGER  ::   ji, jj, jk                   ! dummy loop indices
427      INTEGER  ::   irgb, ierror, ioptio, nqsr   ! local integer
428      INTEGER  ::   ios                          ! Local integer output status for namelist read
429      REAL(wp) ::   zz0, zc0  , zc1, zcoef       ! local scalars
430      REAL(wp) ::   zz1, zc2  , zc3, zchl        !   -      -
431      REAL(wp), POINTER, DIMENSION(:,:  ) :: zekb, zekg, zekr
432      REAL(wp), POINTER, DIMENSION(:,:,:) :: ze0, ze1, ze2, ze3, zea
433      !
434      CHARACTER(len=100) ::   cn_dir   ! Root directory for location of ssr files
435      TYPE(FLD_N)        ::   sn_chl   ! informations about the chlorofyl field to be read
436      !!
437      NAMELIST/namtra_qsr/  sn_chl, cn_dir, ln_traqsr, ln_qsr_rgb, ln_qsr_2bd, ln_qsr_bio, ln_qsr_ice,  &
438         &                  nn_chldta, rn_abs, rn_si0, rn_si1
439      !!----------------------------------------------------------------------
440
441      !
442      IF( nn_timing == 1 )  CALL timing_start('tra_qsr_init')
443      !
444      CALL wrk_alloc( jpi, jpj,      zekb, zekg, zekr        )
445      CALL wrk_alloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea )
446      !
447
448      REWIND( numnam_ref )              ! Namelist namtra_qsr in reference namelist : Ratio and length of penetration
449      READ  ( numnam_ref, namtra_qsr, IOSTAT = ios, ERR = 901)
450901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_qsr in reference namelist', lwp )
451
452      REWIND( numnam_cfg )              !  Namelist namtra_qsr in configuration namelist : Ratio and length of penetration
453      READ  ( numnam_cfg, namtra_qsr, IOSTAT = ios, ERR = 902 )
454902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_qsr in configuration namelist', lwp )
455      IF(lwm) WRITE ( numond, namtra_qsr )
456      !
457      IF(lwp) THEN                ! control print
458         WRITE(numout,*)
459         WRITE(numout,*) 'tra_qsr_init : penetration of the surface solar radiation'
460         WRITE(numout,*) '~~~~~~~~~~~~'
461         WRITE(numout,*) '   Namelist namtra_qsr : set the parameter of penetration'
462         WRITE(numout,*) '      Light penetration (T) or not (F)         ln_traqsr  = ', ln_traqsr
463         WRITE(numout,*) '      RGB (Red-Green-Blue) light penetration   ln_qsr_rgb = ', ln_qsr_rgb
464         WRITE(numout,*) '      2 band               light penetration   ln_qsr_2bd = ', ln_qsr_2bd
465         WRITE(numout,*) '      bio-model            light penetration   ln_qsr_bio = ', ln_qsr_bio
466         WRITE(numout,*) '      light penetration for ice-model LIM3     ln_qsr_ice = ', ln_qsr_ice
467         WRITE(numout,*) '      RGB : Chl data (=1/2) or cst value (=0)  nn_chldta  = ', nn_chldta
468         WRITE(numout,*) '      RGB & 2 bands: fraction of light (rn_si1)    rn_abs = ', rn_abs
469         WRITE(numout,*) '      RGB & 2 bands: shortess depth of extinction  rn_si0 = ', rn_si0
470         WRITE(numout,*) '      2 bands: longest depth of extinction         rn_si1 = ', rn_si1
471      ENDIF
472
473      IF( ln_traqsr ) THEN     ! control consistency
474         !
475         IF( .NOT.lk_qsr_bio .AND. ln_qsr_bio )   THEN
476            CALL ctl_warn( 'No bio model : force ln_qsr_bio = FALSE ' )
477            ln_qsr_bio = .FALSE.
478         ENDIF
479         !
480         ioptio = 0                      ! Parameter control
481         IF( ln_qsr_rgb  )   ioptio = ioptio + 1
482         IF( ln_qsr_2bd  )   ioptio = ioptio + 1
483         IF( ln_qsr_bio  )   ioptio = ioptio + 1
484         !
485         IF( ioptio /= 1 ) &
486            CALL ctl_stop( '          Choose ONE type of light penetration in namelist namtra_qsr',  &
487            &              ' 2 bands, 3 RGB bands or bio-model light penetration' )
488         !
489         IF( ln_qsr_rgb .AND. nn_chldta == 0 )   nqsr =  1
490         IF( ln_qsr_rgb .AND. nn_chldta == 1 )   nqsr =  2
491         IF( ln_qsr_rgb .AND. nn_chldta == 2 )   nqsr =  3
492         IF( ln_qsr_2bd                      )   nqsr =  4
493         IF( ln_qsr_bio                      )   nqsr =  5
494         !
495         IF(lwp) THEN                   ! Print the choice
496            WRITE(numout,*)
497            IF( nqsr ==  1 )   WRITE(numout,*) '         R-G-B   light penetration - Constant Chlorophyll'
498            IF( nqsr ==  2 )   WRITE(numout,*) '         R-G-B   light penetration - 2D Chl data '
499            IF( nqsr ==  3 )   WRITE(numout,*) '         R-G-B   light penetration - 3D Chl data '
500            IF( nqsr ==  4 )   WRITE(numout,*) '         2 bands light penetration'
501            IF( nqsr ==  5 )   WRITE(numout,*) '         bio-model light penetration'
502         ENDIF
503         !
504      ENDIF
505      !                          ! ===================================== !
506      IF( ln_traqsr  ) THEN      !  Initialisation of Light Penetration  !
507         !                       ! ===================================== !
508         !
509         ALLOCATE( xsi0r(jpi,jpj) )
510         xsi0r = 1.e0 / rn_si0
511         xsi1r = 1.e0 / rn_si1
512         !                                ! ---------------------------------- !
513         IF( ln_qsr_rgb ) THEN            !  Red-Green-Blue light penetration  !
514            !                             ! ---------------------------------- !
515            !
516            CALL trc_oce_rgb( rkrgb )           !* tabulated attenuation coef.
517            !
518            !                                   !* level of light extinction
519            IF(  ln_sco ) THEN   ;   nksr = jpkm1
520            ELSE                 ;   nksr = trc_oce_ext_lev( r_si2, 0.33e2 )
521            ENDIF
522
523            IF(lwp) WRITE(numout,*) '        level of light extinction = ', nksr, ' ref depth = ', gdepw_1d(nksr+1), ' m'
524            !
525            IF( nn_chldta == 1  .OR. nn_chldta == 2 ) THEN           !* Chl data : set sf_chl structure
526               IF(lwp) WRITE(numout,*)
527               IF(lwp) WRITE(numout,*) '        Chlorophyll read in a file'
528               ALLOCATE( sf_chl(1), STAT=ierror )
529               IF( ierror > 0 ) THEN
530                  CALL ctl_stop( 'tra_qsr_init: unable to allocate sf_chl structure' )   ;   RETURN
531               ENDIF
532               ALLOCATE( sf_chl(1)%fnow(jpi,jpj,1)   )
533               IF( sn_chl%ln_tint )ALLOCATE( sf_chl(1)%fdta(jpi,jpj,1,2) )
534               !                                        ! fill sf_chl with sn_chl and control print
535               CALL fld_fill( sf_chl, (/ sn_chl /), cn_dir, 'tra_qsr_init',   &
536                  &                                         'Solar penetration function of read chlorophyll', 'namtra_qsr' )
537               !
538            ELSE                                !* constant Chl : compute once for all the distribution of light (etot3)
539               IF(lwp) WRITE(numout,*)
540               IF(lwp) WRITE(numout,*) '        Constant Chlorophyll concentration = 0.05'
541               IF( lk_vvl ) THEN                   ! variable volume
542                  IF(lwp) WRITE(numout,*) '        key_vvl: light distribution will be computed at each time step'
543               ELSE                                ! constant volume: computes one for all
544                  IF(lwp) WRITE(numout,*) '        fixed volume: light distribution computed one for all'
545                  !
546                  zchl = 0.05                                 ! constant chlorophyll
547                  irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 )
548                  zekb(:,:) = rkrgb(1,irgb)                   ! Separation in R-G-B depending of the chlorophyll
549                  zekg(:,:) = rkrgb(2,irgb)
550                  zekr(:,:) = rkrgb(3,irgb)
551                  !
552                  zcoef = ( 1. - rn_abs ) / 3.e0              ! equi-partition in R-G-B
553                  ze0(:,:,1) = rn_abs
554                  ze1(:,:,1) = zcoef
555                  ze2(:,:,1) = zcoef
556                  ze3(:,:,1) = zcoef
557                  zea(:,:,1) = tmask(:,:,1)                   ! = ( ze0+ze1+z2+ze3 ) * tmask
558
559                  DO jk = 2, nksr+1
560!CDIR NOVERRCHK
561                     DO jj = 1, jpj
562!CDIR NOVERRCHK
563                        DO ji = 1, jpi
564                           zc0 = ze0(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * xsi0r(ji,jj) )
565                           zc1 = ze1(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * zekb(ji,jj) )
566                           zc2 = ze2(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * zekg(ji,jj) )
567                           zc3 = ze3(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * zekr(ji,jj) )
568                           ze0(ji,jj,jk) = zc0
569                           ze1(ji,jj,jk) = zc1
570                           ze2(ji,jj,jk) = zc2
571                           ze3(ji,jj,jk) = zc3
572                           zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk)
573                        END DO
574                     END DO
575                  END DO
576                  !
577                  DO jk = 1, nksr
578                     ! (ISF) no light penetration below the ice shelves
579                     etot3(:,:,jk) = r1_rau0_rcp * ( zea(:,:,jk) - zea(:,:,jk+1) ) * tmask(:,:,1)
580                  END DO
581                  etot3(:,:,nksr+1:jpk) = 0.e0                ! below 400m set to zero
582               ENDIF
583            ENDIF
584            !
585         ENDIF
586            !                             ! ---------------------------------- !
587         IF( ln_qsr_2bd ) THEN            !    2 bands    light penetration    !
588            !                             ! ---------------------------------- !
589            !
590            !                                ! level of light extinction
591            nksr = trc_oce_ext_lev( rn_si1, 1.e2 )
592            IF(lwp) THEN
593               WRITE(numout,*)
594            IF(lwp) WRITE(numout,*) '        level of light extinction = ', nksr, ' ref depth = ', gdepw_1d(nksr+1), ' m'
595            ENDIF
596            !
597            IF( lk_vvl ) THEN                   ! variable volume
598               IF(lwp) WRITE(numout,*) '        key_vvl: light distribution will be computed at each time step'
599            ELSE                                ! constant volume: computes one for all
600               zz0 =        rn_abs   * r1_rau0_rcp
601               zz1 = ( 1. - rn_abs ) * r1_rau0_rcp
602               DO jk = 1, nksr                    !*  solar heat absorbed at T-point computed once for all
603                  DO jj = 1, jpj                              ! top 400 meters
604                     DO ji = 1, jpi
605                        zc0 = zz0 * EXP( -fsdepw(ji,jj,jk  )*xsi0r(ji,jj) ) + zz1 * EXP( -fsdepw(ji,jj,jk  )*xsi1r )
606                        zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r(ji,jj) ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r )
607                        etot3(ji,jj,jk) = (  zc0 * tmask(ji,jj,jk) - zc1 * tmask(ji,jj,jk+1)  ) * tmask(ji,jj,1)
608                     END DO
609                  END DO
610               END DO
611               etot3(:,:,nksr+1:jpk) = 0.e0                   ! below 400m set to zero
612               !
613            ENDIF
614         ENDIF
615         !                       ! ===================================== !
616      ELSE                       !        No light penetration           !
617         !                       ! ===================================== !
618         IF(lwp) THEN
619            WRITE(numout,*)
620            WRITE(numout,*) 'tra_qsr_init : NO solar flux penetration'
621            WRITE(numout,*) '~~~~~~~~~~~~'
622         ENDIF
623      ENDIF
624      !
625      ! initialisation of fraqsr_1lev used in sbcssm
626      IF( iom_varid( numror, 'fraqsr_1lev', ldstop = .FALSE. ) > 0 ) THEN
627         IF(nn_timing == 2)  CALL timing_start('iom_rstget')
628         CALL iom_get( numror, jpdom_autoglo, 'fraqsr_1lev'  , fraqsr_1lev  )
629         IF(nn_timing == 2)  CALL timing_stop('iom_rstget')
630      ELSE
631         fraqsr_1lev(:,:) = 1._wp   ! default definition
632      ENDIF
633      !
634      CALL wrk_dealloc( jpi, jpj,      zekb, zekg, zekr        )
635      CALL wrk_dealloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea )
636      !
637      IF( nn_timing == 1 )  CALL timing_stop('tra_qsr_init')
638      !
639   END SUBROUTINE tra_qsr_init
640
641   !!======================================================================
642END MODULE traqsr
Note: See TracBrowser for help on using the repository browser.