New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
nemogcm.F90 in branches/UKMO/dev_1d_bugfixes_tocommit/NEMOGCM/NEMO/OPA_SRC – NEMO

source: branches/UKMO/dev_1d_bugfixes_tocommit/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 15274

Last change on this file since 15274 was 15274, checked in by jwhile, 2 years ago

Update per Rob's review

File size: 41.4 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  LIM sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!            3.4  ! 2011-11  (C. Harris) decomposition changes for running with CICE
31   !!                 ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32   !!----------------------------------------------------------------------
33
34   !!----------------------------------------------------------------------
35   !!   nemo_gcm       : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
36   !!   nemo_init      : initialization of the NEMO system
37   !!   nemo_ctl       : initialisation of the contol print
38   !!   nemo_closefile : close remaining open files
39   !!   nemo_alloc     : dynamical allocation
40   !!   nemo_partition : calculate MPP domain decomposition
41   !!   factorise      : calculate the factors of the no. of MPI processes
42   !!----------------------------------------------------------------------
43   USE step_oce        ! module used in the ocean time stepping module
44   USE cla             ! cross land advection               (tra_cla routine)
45   USE domcfg          ! domain configuration               (dom_cfg routine)
46   USE mppini          ! shared/distributed memory setting (mpp_init routine)
47   USE domain          ! domain initialization             (dom_init routine)
48#if defined key_nemocice_decomp
49   USE ice_domain_size, only: nx_global, ny_global
50#endif
51   USE tideini         ! tidal components initialization   (tide_ini routine)
52   USE bdyini          ! open boundary cond. setting       (bdy_init routine)
53   USE bdydta          ! open boundary cond. setting   (bdy_dta_init routine)
54   USE bdytides        ! open boundary cond. setting   (bdytide_init routine)
55   USE istate          ! initial state setting          (istate_init routine)
56   USE ldfdyn          ! lateral viscosity setting      (ldfdyn_init routine)
57   USE ldftra          ! lateral diffusivity setting    (ldftra_init routine)
58   USE zdfini          ! vertical physics setting          (zdf_init routine)
59   USE phycst          ! physical constant                  (par_cst routine)
60   USE trdini          ! dyn/tra trends initialization     (trd_init routine)
61   USE asminc          ! assimilation increments
62   USE asmbkg          ! writing out state trajectory
63   USE asmbgc          ! biogeochemical assimilation increments
64   USE diaptr          ! poleward transports           (dia_ptr_init routine)
65   USE diadct          ! sections transports           (dia_dct_init routine)
66   USE diaobs          ! Observation diagnostics       (dia_obs_init routine)
67   USE lib_fortran     ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
68   USE step            ! NEMO time-stepping                 (stp     routine)
69   USE icbini          ! handle bergs, initialisation
70   USE icbstp          ! handle bergs, calving, themodynamics and transport
71   USE sbccpl
72   USE cpl_oasis3      ! OASIS3 coupling
73   USE c1d             ! 1D configuration
74   USE step_c1d        ! Time stepping loop for the 1D configuration
75   USE dyndmp          ! Momentum damping
76#if defined key_top
77   USE trcini          ! passive tracer initialisation
78   USE trc, ONLY: numstr  ! tracer stats unit number
79#endif
80   USE lib_mpp         ! distributed memory computing
81#if defined key_iomput
82   USE xios
83#endif
84   USE sbctide, ONLY: lk_tide
85   USE crsini          ! initialise grid coarsening utility
86   USE lbcnfd, ONLY: isendto, nsndto, nfsloop, nfeloop ! Setup of north fold exchanges
87   USE sbc_oce, ONLY: lk_oasis
88   USE stopack
89   USE stopar
90   USE stopts
91
92   IMPLICIT NONE
93   PRIVATE
94
95   PUBLIC   nemo_gcm    ! called by model.F90
96   PUBLIC   nemo_init   ! needed by AGRIF
97   PUBLIC   nemo_alloc  ! needed by TAM
98
99   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
100
101   !!----------------------------------------------------------------------
102   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
103   !! $Id$
104   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
105   !!----------------------------------------------------------------------
106CONTAINS
107
108   SUBROUTINE nemo_gcm
109      !!----------------------------------------------------------------------
110      !!                     ***  ROUTINE nemo_gcm  ***
111      !!
112      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
113      !!              curvilinear mesh on the sphere.
114      !!
115      !! ** Method  : - model general initialization
116      !!              - launch the time-stepping (stp routine)
117      !!              - finalize the run by closing files and communications
118      !!
119      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
120      !!              Madec, 2008, internal report, IPSL.
121      !!----------------------------------------------------------------------
122      INTEGER ::   istp       ! time step index
123      !!----------------------------------------------------------------------
124      !
125#if defined key_agrif
126      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
127#endif
128
129      !                            !-----------------------!
130      CALL nemo_init               !==  Initialisations  ==!
131      !                            !-----------------------!
132#if defined key_agrif
133      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
134      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
135# if defined key_top
136      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
137# endif
138# if defined key_lim2
139      CALL Agrif_Declare_Var_lim2  !  "      "   "   "      "  LIM
140# endif
141#endif
142      ! check that all process are still there... If some process have an error,
143      ! they will never enter in step and other processes will wait until the end of the cpu time!
144      IF( lk_mpp )   CALL mpp_max( nstop )
145
146      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
147
148      !                            !-----------------------!
149      !                            !==   time stepping   ==!
150      !                            !-----------------------!
151      istp = nit000
152
153#if defined key_c1d
154
155      IF( lk_asminc ) THEN
156         IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 )    ! Output background fields
157         IF( ln_asmdin ) THEN                        ! Direct initialization
158            IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 )    ! Tracers
159         ENDIF
160      ENDIF
161
162      DO WHILE ( istp <= nitend .AND. nstop == 0 )
163         CALL stp_c1d( istp )
164         istp = istp + 1
165      END DO
166#else
167
168      IF( lk_asminc ) THEN
169         IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 )    ! Output background fields
170         IF( ln_asmdin ) THEN                        ! Direct initialization
171            IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 )    ! Tracers
172            IF( ln_dyninc ) CALL dyn_asm_inc( nit000 - 1 )    ! Dynamics
173            IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 )    ! SSH
174            IF( lk_bgcinc ) CALL bgc_asm_inc( nit000 - 1 )    ! BGC
175         ENDIF
176      ENDIF
177
178#if defined key_agrif
179      CALL Agrif_Regrid()
180#endif
181
182      DO WHILE ( istp <= nitend .AND. nstop == 0 )
183#if defined key_agrif
184         CALL stp                         ! AGRIF: time stepping
185#else
186         IF (lk_oasis) CALL sbc_cpl_snd( istp )  ! Coupling to atmos
187         CALL stp( istp )
188            ! We don't couple on the final timestep because
189            ! our restart file has already been written
190            ! and contains all the necessary data for a
191            ! restart. sbc_cpl_snd could be called here
192            ! but it would require
193            ! a) A test to ensure it was not performed
194            !    on the very last time-step
195            ! b) the presence of another call to
196            !    sbc_cpl_snd call prior to the main DO loop
197            ! This solution produces identical results
198            ! with fewer lines of code.
199#endif
200         istp = istp + 1
201         IF( lk_mpp )   CALL mpp_max( nstop )
202      END DO
203#endif
204
205      IF( lk_diaobs   )   CALL dia_obs_wri
206      !
207      IF( ( lk_asminc ).AND.( ln_balwri ) ) CALL asm_bgc_bal_wri( nitend )  ! Output balancing increments
208      !
209      IF( ln_icebergs )   CALL icb_end( nitend )
210
211      !                            !------------------------!
212      !                            !==  finalize the run  ==!
213      !                            !------------------------!
214      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
215      !
216      IF( nstop /= 0 .AND. lwp ) THEN   ! error print
217         WRITE(numout,cform_err)
218         WRITE(numout,*) nstop, ' error have been found'
219      ENDIF
220      !
221#if defined key_agrif
222      IF( .NOT. Agrif_Root() ) THEN
223         CALL Agrif_ParentGrid_To_ChildGrid()
224         IF( lk_diaobs ) CALL dia_obs_wri
225         IF( nn_timing > 0 )   CALL timing_finalize
226         CALL Agrif_ChildGrid_To_ParentGrid()
227      ENDIF
228#endif
229      IF( nn_timing > 0 )   CALL timing_finalize
230      !
231      CALL nemo_closefile
232      !
233#if defined key_iomput
234      CALL xios_finalize                ! end mpp communications with xios
235      IF( lk_oasis ) CALL cpl_finalize    ! end coupling and mpp communications with OASIS
236#else
237      IF( lk_oasis ) THEN
238         CALL cpl_finalize              ! end coupling and mpp communications with OASIS
239      ELSE
240         IF( lk_mpp )   CALL mppstop    ! end mpp communications
241      ENDIF
242#endif
243      !
244      ! Met Office addition: if failed, return non-zero exit code
245      IF( nstop /= 0 )  CALL exit( 9 )
246      !
247   END SUBROUTINE nemo_gcm
248
249
250   SUBROUTINE nemo_init
251      !!----------------------------------------------------------------------
252      !!                     ***  ROUTINE nemo_init  ***
253      !!
254      !! ** Purpose :   initialization of the NEMO GCM
255      !!----------------------------------------------------------------------
256      INTEGER ::   ji            ! dummy loop indices
257      INTEGER ::   ilocal_comm   ! local integer
258      INTEGER ::   ios
259      CHARACTER(len=80), DIMENSION(16) ::   cltxt
260      !
261      NAMELIST/namctl/ ln_ctl  , nn_print, nn_ictls, nn_ictle,   &
262         &             nn_isplt, nn_jsplt, nn_jctls, nn_jctle,   &
263         &             nn_bench, nn_timing
264      NAMELIST/namcfg/ cp_cfg, cp_cfz, jp_cfg, jpidta, jpjdta, jpkdta, jpiglo, jpjglo, &
265         &             jpizoom, jpjzoom, jperio, ln_use_jattr
266      !!----------------------------------------------------------------------
267      !
268      cltxt = ''
269      cxios_context = 'nemo'
270      !
271      !                             ! Open reference namelist and configuration namelist files
272      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
273      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
274      !
275      REWIND( numnam_ref )              ! Namelist namctl in reference namelist : Control prints & Benchmark
276      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
277901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
278
279      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist : Control prints & Benchmark
280      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
281902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
282
283      !
284      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist : Control prints & Benchmark
285      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
286903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
287
288      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist : Control prints & Benchmark
289      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
290904   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )
291
292! Force values for AGRIF zoom (cf. agrif_user.F90)
293#if defined key_agrif
294   IF( .NOT. Agrif_Root() ) THEN
295      jpiglo  = nbcellsx + 2 + 2*nbghostcells
296      jpjglo  = nbcellsy + 2 + 2*nbghostcells
297      jpi     = ( jpiglo-2*jpreci + (jpni-1+0) ) / jpni + 2*jpreci
298      jpj     = ( jpjglo-2*jprecj + (jpnj-1+0) ) / jpnj + 2*jprecj
299      jpidta  = jpiglo
300      jpjdta  = jpjglo
301      jpizoom = 1
302      jpjzoom = 1
303      nperio  = 0
304      jperio  = 0
305      ln_use_jattr = .false.
306   ENDIF
307#endif
308      !
309      !                             !--------------------------------------------!
310      !                             !  set communicator & select the local node  !
311      !                             !  NB: mynode also opens output.namelist.dyn !
312      !                             !      on unit number numond on first proc   !
313      !                             !--------------------------------------------!
314#if defined key_iomput
315      IF( Agrif_Root() ) THEN
316         IF( lk_oasis ) THEN
317            CALL cpl_init( "toyoce", ilocal_comm )                     ! nemo local communicator given by oasis
318            CALL xios_initialize( "not used",local_comm=ilocal_comm )    ! send nemo communicator to xios
319         ELSE
320            CALL  xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm )    ! nemo local communicator given by xios
321         ENDIF
322      ENDIF
323      ! Nodes selection (control print return in cltxt)
324      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
325#else
326      IF( lk_oasis ) THEN
327         IF( Agrif_Root() ) THEN
328            CALL cpl_init( "toyoce", ilocal_comm )                      ! nemo local communicator given by oasis
329         ENDIF
330         ! Nodes selection (control print return in cltxt)
331         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
332      ELSE
333         ilocal_comm = 0
334         ! Nodes selection (control print return in cltxt)
335         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )
336      ENDIF
337#endif
338      narea = narea + 1                                     ! mynode return the rank of proc (0 --> jpnij -1 )
339
340      lwm = (narea == 1)                                    ! control of output namelists
341      lwp = (narea == 1) .OR. ln_ctl                        ! control of all listing output print
342
343      IF(lwm) THEN
344         ! write merged namelists from earlier to output namelist now that the
345         ! file has been opened in call to mynode. nammpp has already been
346         ! written in mynode (if lk_mpp_mpi)
347         WRITE( numond, namctl )
348         WRITE( numond, namcfg )
349      ENDIF
350
351      ! If dimensions of processor grid weren't specified in the namelist file
352      ! then we calculate them here now that we have our communicator size
353      IF( (jpni < 1) .OR. (jpnj < 1) )THEN
354#if   defined key_mpp_mpi
355         IF( Agrif_Root() ) CALL nemo_partition(mppsize)
356#else
357         jpni  = 1
358         jpnj  = 1
359         jpnij = jpni*jpnj
360#endif
361      END IF
362
363      ! Calculate domain dimensions given calculated jpni and jpnj
364      ! This used to be done in par_oce.F90 when they were parameters rather
365      ! than variables
366      IF( Agrif_Root() ) THEN
367#if defined key_nemocice_decomp
368         jpi = ( nx_global+2-2*jpreci + (jpni-1) ) / jpni + 2*jpreci ! first  dim.
369         jpj = ( ny_global+2-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj ! second dim.
370#else
371         jpi = ( jpiglo-2*jpreci + (jpni-1) ) / jpni + 2*jpreci   ! first  dim.
372         jpj = ( jpjglo-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj   ! second dim.
373#endif
374      ENDIF
375         jpk = jpkdta                                             ! third dim
376#if defined key_agrif
377         ! simple trick to use same vertical grid as parent
378         ! but different number of levels:
379         ! Save maximum number of levels in jpkdta, then define all vertical grids
380         ! with this number.
381         ! Suppress once vertical online interpolation is ok
382         IF(.NOT.Agrif_Root()) jpkdta = Agrif_Parent(jpkdta)
383#endif
384         jpim1 = jpi-1                                            ! inner domain indices
385         jpjm1 = jpj-1                                            !   "           "
386         jpkm1 = jpk-1                                            !   "           "
387         jpij  = jpi*jpj                                          !  jpi x j
388
389      IF(lwp) THEN                            ! open listing units
390         !
391         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
392         !
393         WRITE(numout,*)
394         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
395         WRITE(numout,*) '                       NEMO team'
396         WRITE(numout,*) '            Ocean General Circulation Model'
397         WRITE(numout,*) '                  version 3.6  (2015) '
398         WRITE(numout,*)
399         WRITE(numout,*)
400         DO ji = 1, SIZE(cltxt)
401            IF( TRIM(cltxt(ji)) /= '' )   WRITE(numout,*) cltxt(ji)      ! control print of mynode
402         END DO
403         WRITE(numout,cform_aaa)                                         ! Flag AAAAAAA
404         !
405      ENDIF
406
407      ! Now we know the dimensions of the grid and numout has been set we can
408      ! allocate arrays
409      CALL nemo_alloc()
410
411      !                             !-------------------------------!
412      !                             !  NEMO general initialization  !
413      !                             !-------------------------------!
414
415      CALL nemo_ctl                          ! Control prints & Benchmark
416
417      !                                      ! Domain decomposition
418      IF( jpni*jpnj == jpnij ) THEN   ;   CALL mpp_init      ! standard cutting out
419      ELSE                            ;   CALL mpp_init2     ! eliminate land processors
420      ENDIF
421      !
422      IF( nn_timing > 0 )  CALL timing_init
423      !
424      !                                      ! General initialization
425                            CALL     phy_cst    ! Physical constants
426                            CALL     eos_init   ! Equation of state
427      IF( lk_c1d        )   CALL     c1d_init   ! 1D column configuration
428                            CALL     dom_cfg    ! Domain configuration
429                            CALL     dom_init   ! Domain
430
431      IF( ln_nnogather )    CALL nemo_northcomms   ! Initialise the northfold neighbour lists (must be done after the masks are defined)
432
433      IF( ln_ctl        )   CALL prt_ctl_init   ! Print control
434
435                            CALL  istate_init   ! ocean initial state (Dynamics and tracers)
436
437      IF( lk_tide       )   CALL    tide_init( nit000 )    ! Initialisation of the tidal harmonics
438
439                            CALL     sbc_init   ! Forcings : surface module (clem: moved here for bdy purpose)
440
441      IF( lk_bdy        )   CALL     bdy_init   ! Open boundaries initialisation
442      IF( lk_bdy        )   CALL bdy_dta_init   ! Open boundaries initialisation of external data arrays
443      IF( lk_bdy .AND. lk_tide )   &
444         &                  CALL bdytide_init   ! Open boundaries initialisation of tidal harmonic forcing
445
446                            CALL dyn_nept_init  ! simplified form of Neptune effect
447      !
448      IF( ln_crs        )   CALL     crs_init   ! Domain initialization of coarsened grid
449      !
450                                ! Ocean physics
451      !                                         ! Vertical physics
452                            CALL     zdf_init      ! namelist read
453                            CALL zdf_bfr_init      ! bottom friction
454      IF( lk_zdfric     )   CALL zdf_ric_init      ! Richardson number dependent Kz
455      IF( lk_zdftke     )   CALL zdf_tke_init      ! TKE closure scheme
456      IF( lk_zdfgls     )   CALL zdf_gls_init      ! GLS closure scheme
457      IF( lk_zdfkpp     )   CALL zdf_kpp_init      ! KPP closure scheme
458      IF( lk_zdftmx     )   CALL zdf_tmx_init      ! tidal vertical mixing
459      IF( lk_zdfddm .AND. .NOT. lk_zdfkpp )   &
460         &                  CALL zdf_ddm_init      ! double diffusive mixing
461      !                                         ! Lateral physics
462                            CALL ldf_tra_init      ! Lateral ocean tracer physics
463                            CALL ldf_dyn_init      ! Lateral ocean momentum physics
464      IF( lk_ldfslp     )   CALL ldf_slp_init      ! slope of lateral mixing
465
466      !                                     ! Active tracers
467                            CALL tra_qsr_init   ! penetrative solar radiation qsr
468                            CALL tra_bbc_init   ! bottom heat flux
469      IF( lk_trabbl     )   CALL tra_bbl_init   ! advective (and/or diffusive) bottom boundary layer scheme
470                            CALL tra_dmp_init   ! internal damping trends- tracers
471                            CALL tra_adv_init   ! horizontal & vertical advection
472                            CALL tra_ldf_init   ! lateral mixing
473                            CALL tra_zdf_init   ! vertical mixing and after tracer fields
474
475      !                                     ! Dynamics
476      IF( lk_c1d        )   CALL dyn_dmp_init   ! internal damping trends- momentum
477                            CALL dyn_adv_init   ! advection (vector or flux form)
478                            CALL dyn_vor_init   ! vorticity term including Coriolis
479                            CALL dyn_ldf_init   ! lateral mixing
480                            CALL dyn_hpg_init   ! horizontal gradient of Hydrostatic pressure
481                            CALL dyn_zdf_init   ! vertical diffusion
482                            CALL dyn_spg_init   ! surface pressure gradient
483
484      !                                     ! Misc. options
485      IF( nn_cla == 1 .AND. cp_cfg == 'orca' .AND. jp_cfg == 2 )   CALL cla_init       ! Cross Land Advection
486                            CALL icb_init( rdt, nit000)   ! initialise icebergs instance
487                            CALL sto_par_init   ! Stochastic parametrization
488      IF( ln_sto_eos     )  CALL sto_pts_init   ! RRandom T/S fluctuations
489
490#if defined key_top
491      !                                     ! Passive tracers
492                            CALL     trc_init
493#endif
494      !                                     ! Diagnostics
495      IF( lk_floats     )   CALL     flo_init   ! drifting Floats
496                            CALL dia_ptr_init   ! Poleward TRansports initialization
497      IF( lk_diadct     )   CALL dia_dct_init   ! Sections tranports
498                            CALL dia_hsb_init   ! heat content, salt content and volume budgets
499                            CALL     trd_init   ! Mixed-layer/Vorticity/Integral constraints trends
500                            CALL stopack_init   ! STOPACK scheme
501      IF( lk_diaobs     ) THEN                  ! Observation & model comparison
502                            CALL dia_obs_init            ! Initialize observational data
503                            CALL dia_obs( nit000 - 1 )   ! Observation operator for restart
504      ENDIF
505
506      !                                     ! Assimilation increments
507      IF( lk_asminc     )   CALL asm_inc_init   ! Initialize assimilation increments
508                            CALL    bias_init   ! Pressure correction bias
509      IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
510
511      IF (nstop > 0) THEN
512        CALL CTL_STOP('STOP','Critical errors in NEMO initialisation')
513      END IF
514
515      !
516   END SUBROUTINE nemo_init
517
518
519   SUBROUTINE nemo_ctl
520      !!----------------------------------------------------------------------
521      !!                     ***  ROUTINE nemo_ctl  ***
522      !!
523      !! ** Purpose :   control print setting
524      !!
525      !! ** Method  : - print namctl information and check some consistencies
526      !!----------------------------------------------------------------------
527      !
528      IF(lwp) THEN                  ! control print
529         WRITE(numout,*)
530         WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark'
531         WRITE(numout,*) '~~~~~~~ '
532         WRITE(numout,*) '   Namelist namctl'
533         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
534         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
535         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
536         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
537         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
538         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
539         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
540         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
541         WRITE(numout,*) '      benchmark parameter (0/1)       nn_bench   = ', nn_bench
542         WRITE(numout,*) '      timing activated    (0/1)       nn_timing  = ', nn_timing
543      ENDIF
544      !
545      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
546      nictls    = nn_ictls
547      nictle    = nn_ictle
548      njctls    = nn_jctls
549      njctle    = nn_jctle
550      isplt     = nn_isplt
551      jsplt     = nn_jsplt
552      nbench    = nn_bench
553
554      IF(lwp) THEN                  ! control print
555         WRITE(numout,*)
556         WRITE(numout,*) 'namcfg  : configuration initialization through namelist read'
557         WRITE(numout,*) '~~~~~~~ '
558         WRITE(numout,*) '   Namelist namcfg'
559         WRITE(numout,*) '      configuration name              cp_cfg      = ', TRIM(cp_cfg)
560         WRITE(numout,*) '      configuration zoom name         cp_cfz      = ', TRIM(cp_cfz)
561         WRITE(numout,*) '      configuration resolution        jp_cfg      = ', jp_cfg
562         WRITE(numout,*) '      1st lateral dimension ( >= jpi ) jpidta     = ', jpidta
563         WRITE(numout,*) '      2nd    "         "    ( >= jpj ) jpjdta     = ', jpjdta
564         WRITE(numout,*) '      3nd    "         "               jpkdta     = ', jpkdta
565         WRITE(numout,*) '      1st dimension of global domain in i jpiglo  = ', jpiglo
566         WRITE(numout,*) '      2nd    -                  -    in j jpjglo  = ', jpjglo
567         WRITE(numout,*) '      left bottom i index of the zoom (in data domain) jpizoom = ', jpizoom
568         WRITE(numout,*) '      left bottom j index of the zoom (in data domain) jpizoom = ', jpjzoom
569         WRITE(numout,*) '      lateral cond. type (between 0 and 6) jperio = ', jperio
570         WRITE(numout,*) '      use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr
571      ENDIF
572      !                             ! Parameter control
573      !
574      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
575         IF( lk_mpp .AND. jpnij > 1 ) THEN
576            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
577         ELSE
578            IF( isplt == 1 .AND. jsplt == 1  ) THEN
579               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
580                  &           ' - the print control will be done over the whole domain' )
581            ENDIF
582            ijsplt = isplt * jsplt            ! total number of processors ijsplt
583         ENDIF
584         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
585         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
586         !
587         !                              ! indices used for the SUM control
588         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
589            lsp_area = .FALSE.
590         ELSE                                             ! print control done over a specific  area
591            lsp_area = .TRUE.
592            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
593               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
594               nictls = 1
595            ENDIF
596            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
597               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
598               nictle = jpiglo
599            ENDIF
600            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
601               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
602               njctls = 1
603            ENDIF
604            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
605               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
606               njctle = jpjglo
607            ENDIF
608         ENDIF
609      ENDIF
610      !
611      IF( nbench == 1 ) THEN              ! Benchmark
612         SELECT CASE ( cp_cfg )
613         CASE ( 'gyre' )   ;   CALL ctl_warn( ' The Benchmark is activated ' )
614         CASE DEFAULT      ;   CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:',   &
615            &                                 ' cp_cfg = "gyre" in namelist &namcfg or set nbench = 0' )
616         END SELECT
617      ENDIF
618      !
619      IF( 1_wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ',  &
620         &                                               'f2003 standard. '                              ,  &
621         &                                               'Compile with key_nosignedzero enabled' )
622      !
623   END SUBROUTINE nemo_ctl
624
625
626   SUBROUTINE nemo_closefile
627      !!----------------------------------------------------------------------
628      !!                     ***  ROUTINE nemo_closefile  ***
629      !!
630      !! ** Purpose :   Close the files
631      !!----------------------------------------------------------------------
632      !
633      IF( lk_mpp )   CALL mppsync
634      !
635      CALL iom_close                                 ! close all input/output files managed by iom_*
636      !
637      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
638      IF( numsol          /= -1 )   CLOSE( numsol          )   ! solver file
639      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
640      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
641      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
642      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
643      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
644      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
645      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
646      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
647      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
648      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
649      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
650#if defined key_top
651      IF( numstr          /= -1 )   CLOSE( numstr          )   ! tracer statistics
652#endif
653      !
654      numout = 6                                     ! redefine numout in case it is used after this point...
655      !
656   END SUBROUTINE nemo_closefile
657
658
659   SUBROUTINE nemo_alloc
660      !!----------------------------------------------------------------------
661      !!                     ***  ROUTINE nemo_alloc  ***
662      !!
663      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
664      !!
665      !! ** Method  :
666      !!----------------------------------------------------------------------
667      USE diawri    , ONLY: dia_wri_alloc
668      USE insitu_tem, ONLY: insitu_tem_alloc
669      USE dom_oce   , ONLY: dom_oce_alloc
670      USE ldfdyn_oce, ONLY: ldfdyn_oce_alloc
671      USE ldftra_oce, ONLY: ldftra_oce_alloc
672      USE trc_oce   , ONLY: trc_oce_alloc
673#if defined key_diadct
674      USE diadct    , ONLY: diadct_alloc
675#endif
676#if defined key_bdy
677      USE bdy_oce   , ONLY: bdy_oce_alloc
678#endif
679      !
680      INTEGER :: ierr
681      !!----------------------------------------------------------------------
682      !
683      ierr =        oce_alloc       ()          ! ocean
684      ierr = ierr + dia_wri_alloc   ()
685      ierr = ierr + insitu_tem_alloc()
686      ierr = ierr + dom_oce_alloc   ()          ! ocean domain
687      ierr = ierr + ldfdyn_oce_alloc()          ! ocean lateral  physics : dynamics
688      ierr = ierr + ldftra_oce_alloc()          ! ocean lateral  physics : tracers
689      ierr = ierr + zdf_oce_alloc   ()          ! ocean vertical physics
690      !
691      ierr = ierr + trc_oce_alloc   ()          ! shared TRC / TRA arrays
692      !
693#if defined key_diadct
694      ierr = ierr + diadct_alloc    ()          !
695#endif
696#if defined key_bdy
697      ierr = ierr + bdy_oce_alloc   ()          ! bdy masks (incl. initialization)
698#endif
699      !
700      IF( lk_mpp    )   CALL mpp_sum( ierr )
701      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
702      !
703   END SUBROUTINE nemo_alloc
704
705
706   SUBROUTINE nemo_partition( num_pes )
707      !!----------------------------------------------------------------------
708      !!                 ***  ROUTINE nemo_partition  ***
709      !!
710      !! ** Purpose :
711      !!
712      !! ** Method  :
713      !!----------------------------------------------------------------------
714      INTEGER, INTENT(in) ::   num_pes   ! The number of MPI processes we have
715      !
716      INTEGER, PARAMETER :: nfactmax = 20
717      INTEGER :: nfact ! The no. of factors returned
718      INTEGER :: ierr  ! Error flag
719      INTEGER :: ji
720      INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
721      INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
722      !!----------------------------------------------------------------------
723      !
724      ierr = 0
725      !
726      CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
727      !
728      IF( nfact <= 1 ) THEN
729         WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
730         WRITE (numout, *) '       : using grid of ',num_pes,' x 1'
731         jpnj = 1
732         jpni = num_pes
733      ELSE
734         ! Search through factors for the pair that are closest in value
735         mindiff = 1000000
736         imin    = 1
737         DO ji = 1, nfact-1, 2
738            idiff = ABS( ifact(ji) - ifact(ji+1) )
739            IF( idiff < mindiff ) THEN
740               mindiff = idiff
741               imin = ji
742            ENDIF
743         END DO
744         jpnj = ifact(imin)
745         jpni = ifact(imin + 1)
746      ENDIF
747      !
748      jpnij = jpni*jpnj
749      !
750   END SUBROUTINE nemo_partition
751
752
753   SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
754      !!----------------------------------------------------------------------
755      !!                     ***  ROUTINE factorise  ***
756      !!
757      !! ** Purpose :   return the prime factors of n.
758      !!                knfax factors are returned in array kfax which is of
759      !!                maximum dimension kmaxfax.
760      !! ** Method  :
761      !!----------------------------------------------------------------------
762      INTEGER                    , INTENT(in   ) ::   kn, kmaxfax
763      INTEGER                    , INTENT(  out) ::   kerr, knfax
764      INTEGER, DIMENSION(kmaxfax), INTENT(  out) ::   kfax
765      !
766      INTEGER :: ifac, jl, inu
767      INTEGER, PARAMETER :: ntest = 14
768      INTEGER, DIMENSION(ntest) :: ilfax
769      !
770      ! ilfax contains the set of allowed factors.
771      ilfax(:) = (/(2**jl,jl=ntest,1,-1)/)
772      !!----------------------------------------------------------------------
773      ! ilfax contains the set of allowed factors.
774      ilfax(:) = (/(2**jl,jl=ntest,1,-1)/)
775
776      ! Clear the error flag and initialise output vars
777      kerr = 0
778      kfax = 1
779      knfax = 0
780
781      ! Find the factors of n.
782      IF( kn == 1 )   GOTO 20
783
784      ! nu holds the unfactorised part of the number.
785      ! knfax holds the number of factors found.
786      ! l points to the allowed factor list.
787      ! ifac holds the current factor.
788
789      inu   = kn
790      knfax = 0
791
792      DO jl = ntest, 1, -1
793         !
794         ifac = ilfax(jl)
795         IF( ifac > inu )   CYCLE
796
797         ! Test whether the factor will divide.
798
799         IF( MOD(inu,ifac) == 0 ) THEN
800            !
801            knfax = knfax + 1            ! Add the factor to the list
802            IF( knfax > kmaxfax ) THEN
803               kerr = 6
804               write (*,*) 'FACTOR: insufficient space in factor array ', knfax
805               return
806            ENDIF
807            kfax(knfax) = ifac
808            ! Store the other factor that goes with this one
809            knfax = knfax + 1
810            kfax(knfax) = inu / ifac
811            !WRITE (*,*) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
812         ENDIF
813         !
814      END DO
815
816   20 CONTINUE      ! Label 20 is the exit point from the factor search loop.
817      !
818   END SUBROUTINE factorise
819
820#if defined key_mpp_mpi
821
822   SUBROUTINE nemo_northcomms
823      !!======================================================================
824      !!                     ***  ROUTINE  nemo_northcomms  ***
825      !! nemo_northcomms    :  Setup for north fold exchanges with explicit
826      !!                       point-to-point messaging
827      !!=====================================================================
828      !!----------------------------------------------------------------------
829      !!
830      !! ** Purpose :   Initialization of the northern neighbours lists.
831      !!----------------------------------------------------------------------
832      !!    1.0  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE)
833      !!    2.0  ! 2013-06 Setup avoiding MPI communication (I. Epicoco, S. Mocavero, CMCC)
834      !!----------------------------------------------------------------------
835
836      INTEGER  ::   sxM, dxM, sxT, dxT, jn
837      INTEGER  ::   njmppmax
838
839      njmppmax = MAXVAL( njmppt )
840
841      !initializes the north-fold communication variables
842      isendto(:) = 0
843      nsndto = 0
844
845      !if I am a process in the north
846      IF ( njmpp == njmppmax ) THEN
847          !sxM is the first point (in the global domain) needed to compute the
848          !north-fold for the current process
849          sxM = jpiglo - nimppt(narea) - nlcit(narea) + 1
850          !dxM is the last point (in the global domain) needed to compute the
851          !north-fold for the current process
852          dxM = jpiglo - nimppt(narea) + 2
853
854          !loop over the other north-fold processes to find the processes
855          !managing the points belonging to the sxT-dxT range
856
857          DO jn = 1, jpni
858                !sxT is the first point (in the global domain) of the jn
859                !process
860                sxT = nfiimpp(jn, jpnj)
861                !dxT is the last point (in the global domain) of the jn
862                !process
863                dxT = nfiimpp(jn, jpnj) + nfilcit(jn, jpnj) - 1
864                IF ((sxM .gt. sxT) .AND. (sxM .lt. dxT)) THEN
865                   nsndto = nsndto + 1
866                     isendto(nsndto) = jn
867                ELSEIF ((sxM .le. sxT) .AND. (dxM .ge. dxT)) THEN
868                   nsndto = nsndto + 1
869                     isendto(nsndto) = jn
870                ELSEIF ((dxM .lt. dxT) .AND. (sxT .lt. dxM)) THEN
871                   nsndto = nsndto + 1
872                     isendto(nsndto) = jn
873                END IF
874          END DO
875          nfsloop = 1
876          nfeloop = nlci
877          DO jn = 2,jpni-1
878           IF(nfipproc(jn,jpnj) .eq. (narea - 1)) THEN
879              IF (nfipproc(jn - 1 ,jpnj) .eq. -1) THEN
880                 nfsloop = nldi
881              ENDIF
882              IF (nfipproc(jn + 1,jpnj) .eq. -1) THEN
883                 nfeloop = nlei
884              ENDIF
885           ENDIF
886        END DO
887
888      ENDIF
889      l_north_nogather = .TRUE.
890   END SUBROUTINE nemo_northcomms
891#else
892   SUBROUTINE nemo_northcomms      ! Dummy routine
893      WRITE(*,*) 'nemo_northcomms: You should not have seen this print! error?'
894   END SUBROUTINE nemo_northcomms
895#endif
896
897   !!======================================================================
898END MODULE nemogcm
Note: See TracBrowser for help on using the repository browser.