source: branches/UKMO/dev_5518_tide_analysis_restart/NEMOGCM/NEMO/OPA_SRC/BDY/bdytides.F90 @ 6370

Last change on this file since 6370 was 6370, checked in by deazer, 6 years ago

Added restart switch for harmonic analysis reading

File size: 30.4 KB
Line 
1MODULE bdytides
2   !!======================================================================
3   !!                       ***  MODULE  bdytides  ***
4   !! Ocean dynamics:   Tidal forcing at open boundaries
5   !!======================================================================
6   !! History :  2.0  !  2007-01  (D.Storkey)  Original code
7   !!            2.3  !  2008-01  (J.Holt)  Add date correction. Origins POLCOMS v6.3 2007
8   !!            3.0  !  2008-04  (NEMO team)  add in the reference version
9   !!            3.3  !  2010-09  (D.Storkey and E.O'Dea)  bug fixes
10   !!            3.4  !  2012-09  (G. Reffray and J. Chanut) New inputs + mods
11   !!            3.5  !  2013-07  (J. Chanut) Compliant with time splitting changes
12   !!----------------------------------------------------------------------
13#if defined key_bdy
14   !!----------------------------------------------------------------------
15   !!   'key_bdy'     Open Boundary Condition
16   !!----------------------------------------------------------------------
17   !!   PUBLIC
18   !!      bdytide_init     : read of namelist and initialisation of tidal harmonics data
19   !!      tide_update   : calculation of tidal forcing at each timestep
20   !!----------------------------------------------------------------------
21   USE timing          ! Timing
22   USE oce             ! ocean dynamics and tracers
23   USE dom_oce         ! ocean space and time domain
24   USE iom
25   USE in_out_manager  ! I/O units
26   USE phycst          ! physical constants
27   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
28   USE bdy_par         ! Unstructured boundary parameters
29   USE bdy_oce         ! ocean open boundary conditions
30   USE daymod          ! calendar
31   USE wrk_nemo        ! Memory allocation
32   USE tideini
33!   USE tide_mod       ! Useless ??
34   USE fldread
35   USE dynspg_oce, ONLY: lk_dynspg_ts
36
37   IMPLICIT NONE
38   PRIVATE
39
40   PUBLIC   bdytide_init     ! routine called in bdy_init
41   PUBLIC   bdytide_update   ! routine called in bdy_dta
42   PUBLIC   bdy_dta_tides    ! routine called in dyn_spg_ts
43
44   TYPE, PUBLIC ::   TIDES_DATA     !: Storage for external tidal harmonics data
45      REAL(wp), POINTER, DIMENSION(:,:,:)    ::   ssh0       !: Tidal constituents : SSH0 (read in file)
46      REAL(wp), POINTER, DIMENSION(:,:,:)    ::   u0         !: Tidal constituents : U0   (read in file)
47      REAL(wp), POINTER, DIMENSION(:,:,:)    ::   v0         !: Tidal constituents : V0   (read in file)
48      REAL(wp), POINTER, DIMENSION(:,:,:)    ::   ssh        !: Tidal constituents : SSH  (after nodal cor.)
49      REAL(wp), POINTER, DIMENSION(:,:,:)    ::   u          !: Tidal constituents : U    (after nodal cor.)
50      REAL(wp), POINTER, DIMENSION(:,:,:)    ::   v          !: Tidal constituents : V    (after nodal cor.)
51   END TYPE TIDES_DATA
52   INTEGER, PUBLIC, PARAMETER                  ::   jptides_max = 15      !: Max number of tidal contituents
53      LOGICAL, PUBLIC                           ::   ln_harm_ana             !: =T  Compute harmonic Analysis
54      LOGICAL, PUBLIC                           ::   ln_harmana_read         !: =T  Decide to do the analysis
55                                                                             !from scratch or continue previous run
56
57!$AGRIF_DO_NOT_TREAT
58   TYPE(TIDES_DATA), PUBLIC, DIMENSION(jp_bdy), TARGET :: tides  !: External tidal harmonics data
59!$AGRIF_END_DO_NOT_TREAT
60   TYPE(OBC_DATA)  , PRIVATE, DIMENSION(jp_bdy) :: dta_bdy_s  !: bdy external data (slow component)
61
62   !!----------------------------------------------------------------------
63   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
64   !! $Id$
65   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
66   !!----------------------------------------------------------------------
67CONTAINS
68
69   SUBROUTINE bdytide_init
70      !!----------------------------------------------------------------------
71      !!                    ***  SUBROUTINE bdytide_init  ***
72      !!                     
73      !! ** Purpose : - Read in namelist for tides and initialise external
74      !!                tidal harmonics data
75      !!
76      !!----------------------------------------------------------------------
77      !! namelist variables
78      !!-------------------
79      CHARACTER(len=80)                         ::   filtide             !: Filename root for tidal input files
80      LOGICAL                                   ::   ln_bdytide_2ddta    !: If true, read 2d harmonic data
81      LOGICAL                                   ::   ln_bdytide_conj     !: If true, assume complex conjugate tidal data
82      !!
83      INTEGER                                   ::   ib_bdy, itide, ib   !: dummy loop indices
84      INTEGER                                   ::   ii, ij              !: dummy loop indices
85      INTEGER                                   ::   inum, igrd
86      INTEGER, DIMENSION(3)                     ::   ilen0       !: length of boundary data (from OBC arrays)
87      INTEGER, POINTER, DIMENSION(:)            ::   nblen, nblenrim     ! short cuts
88      INTEGER                                   ::   ios                 ! Local integer output status for namelist read
89      CHARACTER(len=80)                         ::   clfile              !: full file name for tidal input file
90      REAL(wp),ALLOCATABLE, DIMENSION(:,:,:)    ::   dta_read            !: work space to read in tidal harmonics data
91      REAL(wp), POINTER, DIMENSION(:,:)         ::   ztr, zti            !:  "     "    "   "   "   "        "      "
92      !!
93      TYPE(TIDES_DATA),  POINTER                ::   td                  !: local short cut   
94      TYPE(MAP_POINTER), DIMENSION(jpbgrd)      ::   ibmap_ptr           !: array of pointers to nbmap
95      !!
96      NAMELIST/nambdy_tide/filtide, ln_bdytide_2ddta, ln_bdytide_conj, ln_harm_ana, ln_harmana_read
97      !!----------------------------------------------------------------------
98
99      IF( nn_timing == 1 ) CALL timing_start('bdytide_init')
100
101      IF (nb_bdy>0) THEN
102         IF(lwp) WRITE(numout,*)
103         IF(lwp) WRITE(numout,*) 'bdytide_init : initialization of tidal harmonic forcing at open boundaries'
104         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~'
105      ENDIF
106
107      REWIND(numnam_cfg)
108
109      DO ib_bdy = 1, nb_bdy
110         IF( nn_dyn2d_dta(ib_bdy) .ge. 2 ) THEN
111
112            td => tides(ib_bdy)
113            nblen => idx_bdy(ib_bdy)%nblen
114            nblenrim => idx_bdy(ib_bdy)%nblenrim
115
116            ! Namelist nambdy_tide : tidal harmonic forcing at open boundaries
117            filtide(:) = ''
118
119            ! Don't REWIND here - may need to read more than one of these namelists.
120            READ  ( numnam_ref, nambdy_tide, IOSTAT = ios, ERR = 901)
121901         IF( ios /= 0 ) CALL ctl_nam ( ios , 'nambdy_tide in reference namelist', lwp )
122            READ  ( numnam_cfg, nambdy_tide, IOSTAT = ios, ERR = 902 )
123902         IF( ios /= 0 ) CALL ctl_nam ( ios , 'nambdy_tide in configuration namelist', lwp )
124            IF(lwm) WRITE ( numond, nambdy_tide )
125            !                                               ! Parameter control and print
126            IF(lwp) WRITE(numout,*) '  '
127            IF(lwp) WRITE(numout,*) '          Namelist nambdy_tide : tidal harmonic forcing at open boundaries'
128            IF(lwp) WRITE(numout,*) '             read tidal data in 2d files: ', ln_bdytide_2ddta
129            IF(lwp) WRITE(numout,*) '             assume complex conjugate   : ', ln_bdytide_conj
130            IF(lwp) WRITE(numout,*) '             Number of tidal components to read: ', nb_harmo
131            IF(lwp) WRITE(numout,*) '             Use PCOMS harmonic ananalysis or not: ', ln_harm_ana
132            IF(lwp) WRITE(numout,*) '             Read in previous days harmonic data or start afresh: ', ln_harmana_read
133            IF(lwp) THEN
134                    WRITE(numout,*) '             Tidal components: ' 
135               DO itide = 1, nb_harmo
136                  WRITE(numout,*)  '                 ', Wave(ntide(itide))%cname_tide 
137               END DO
138            ENDIF
139            IF(lwp) WRITE(numout,*) ' '
140
141            ! Allocate space for tidal harmonics data - get size from OBC data arrays
142            ! -----------------------------------------------------------------------
143
144            ! JC: If FRS scheme is used, we assume that tidal is needed over the whole
145            ! relaxation area     
146            IF( cn_dyn2d(ib_bdy) == 'frs' ) THEN
147               ilen0(:)=nblen(:)
148            ELSE
149               ilen0(:)=nblenrim(:)
150            ENDIF
151
152            ALLOCATE( td%ssh0( ilen0(1), nb_harmo, 2 ) )
153            ALLOCATE( td%ssh ( ilen0(1), nb_harmo, 2 ) )
154
155            ALLOCATE( td%u0( ilen0(2), nb_harmo, 2 ) )
156            ALLOCATE( td%u ( ilen0(2), nb_harmo, 2 ) )
157
158            ALLOCATE( td%v0( ilen0(3), nb_harmo, 2 ) )
159            ALLOCATE( td%v ( ilen0(3), nb_harmo, 2 ) )
160
161            td%ssh0(:,:,:) = 0._wp
162            td%ssh (:,:,:) = 0._wp
163            td%u0  (:,:,:) = 0._wp
164            td%u   (:,:,:) = 0._wp
165            td%v0  (:,:,:) = 0._wp
166            td%v   (:,:,:) = 0._wp
167
168            IF (ln_bdytide_2ddta) THEN
169               ! It is assumed that each data file contains all complex harmonic amplitudes
170               ! given on the data domain (ie global, jpidta x jpjdta)
171               !
172               CALL wrk_alloc( jpi, jpj, zti, ztr )
173               !
174               ! SSH fields
175               clfile = TRIM(filtide)//'_grid_T.nc'
176               CALL iom_open (clfile , inum ) 
177               igrd = 1                       ! Everything is at T-points here
178               DO itide = 1, nb_harmo
179                  CALL iom_get  ( inum, jpdom_data, TRIM(Wave(ntide(itide))%cname_tide)//'_z1', ztr(:,:) )
180                  CALL iom_get  ( inum, jpdom_data, TRIM(Wave(ntide(itide))%cname_tide)//'_z2', zti(:,:) ) 
181                  DO ib = 1, ilen0(igrd)
182                     ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
183                     ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
184                     td%ssh0(ib,itide,1) = ztr(ii,ij)
185                     td%ssh0(ib,itide,2) = zti(ii,ij)
186                  END DO
187               END DO
188               CALL iom_close( inum )
189               !
190               ! U fields
191               clfile = TRIM(filtide)//'_grid_U.nc'
192               CALL iom_open (clfile , inum ) 
193               igrd = 2                       ! Everything is at U-points here
194               DO itide = 1, nb_harmo
195                  CALL iom_get  ( inum, jpdom_data, TRIM(Wave(ntide(itide))%cname_tide)//'_u1', ztr(:,:) )
196                  CALL iom_get  ( inum, jpdom_data, TRIM(Wave(ntide(itide))%cname_tide)//'_u2', zti(:,:) )
197                  DO ib = 1, ilen0(igrd)
198                     ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
199                     ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
200                     td%u0(ib,itide,1) = ztr(ii,ij)
201                     td%u0(ib,itide,2) = zti(ii,ij)
202                  END DO
203               END DO
204               CALL iom_close( inum )
205               !
206               ! V fields
207               clfile = TRIM(filtide)//'_grid_V.nc'
208               CALL iom_open (clfile , inum ) 
209               igrd = 3                       ! Everything is at V-points here
210               DO itide = 1, nb_harmo
211                  CALL iom_get  ( inum, jpdom_data, TRIM(Wave(ntide(itide))%cname_tide)//'_v1', ztr(:,:) )
212                  CALL iom_get  ( inum, jpdom_data, TRIM(Wave(ntide(itide))%cname_tide)//'_v2', zti(:,:) )
213                  DO ib = 1, ilen0(igrd)
214                     ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
215                     ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
216                     td%v0(ib,itide,1) = ztr(ii,ij)
217                     td%v0(ib,itide,2) = zti(ii,ij)
218                  END DO
219               END DO 
220               CALL iom_close( inum )
221               !
222               CALL wrk_dealloc( jpi, jpj, ztr, zti ) 
223               !
224            ELSE           
225               !
226               ! Read tidal data only on bdy segments
227               !
228               ALLOCATE( dta_read( MAXVAL(ilen0(1:3)), 1, 1 ) )
229               !
230               ! Set map structure
231               ibmap_ptr(1)%ptr => idx_bdy(ib_bdy)%nbmap(:,1)
232               ibmap_ptr(1)%ll_unstruc = ln_coords_file(ib_bdy)
233               ibmap_ptr(2)%ptr => idx_bdy(ib_bdy)%nbmap(:,2)
234               ibmap_ptr(2)%ll_unstruc = ln_coords_file(ib_bdy)
235               ibmap_ptr(3)%ptr => idx_bdy(ib_bdy)%nbmap(:,3)
236               ibmap_ptr(3)%ll_unstruc = ln_coords_file(ib_bdy)
237
238               ! Open files and read in tidal forcing data
239               ! -----------------------------------------
240
241               DO itide = 1, nb_harmo
242                  !                                                              ! SSH fields
243                  clfile = TRIM(filtide)//TRIM(Wave(ntide(itide))%cname_tide)//'_grid_T.nc'
244                  CALL iom_open( clfile, inum )
245                  CALL fld_map( inum, 'z1' , dta_read(1:ilen0(1),1:1,1:1) , 1,  ibmap_ptr(1) )
246                  td%ssh0(:,itide,1) = dta_read(1:ilen0(1),1,1)
247                  CALL fld_map( inum, 'z2' , dta_read(1:ilen0(1),1:1,1:1) , 1,  ibmap_ptr(1) )
248                  td%ssh0(:,itide,2) = dta_read(1:ilen0(1),1,1)
249                  CALL iom_close( inum )
250                  !                                                              ! U fields
251                  clfile = TRIM(filtide)//TRIM(Wave(ntide(itide))%cname_tide)//'_grid_U.nc'
252                  CALL iom_open( clfile, inum )
253                  CALL fld_map( inum, 'u1' , dta_read(1:ilen0(2),1:1,1:1) , 1, ibmap_ptr(2) )
254                  td%u0(:,itide,1) = dta_read(1:ilen0(2),1,1)
255                  CALL fld_map( inum, 'u2' , dta_read(1:ilen0(2),1:1,1:1) , 1, ibmap_ptr(2) )
256                  td%u0(:,itide,2) = dta_read(1:ilen0(2),1,1)
257                  CALL iom_close( inum )
258                  !                                                              ! V fields
259                  clfile = TRIM(filtide)//TRIM(Wave(ntide(itide))%cname_tide)//'_grid_V.nc'
260                  CALL iom_open( clfile, inum )
261                  CALL fld_map( inum, 'v1' , dta_read(1:ilen0(3),1:1,1:1) , 1, ibmap_ptr(3) )
262                  td%v0(:,itide,1) = dta_read(1:ilen0(3),1,1)
263                  CALL fld_map( inum, 'v2' , dta_read(1:ilen0(3),1:1,1:1) , 1, ibmap_ptr(3) )
264                  td%v0(:,itide,2) = dta_read(1:ilen0(3),1,1)
265                  CALL iom_close( inum )
266                  !
267               END DO ! end loop on tidal components
268               !
269               DEALLOCATE( dta_read )
270            ENDIF ! ln_bdytide_2ddta=.true.
271            !
272            IF ( ln_bdytide_conj ) THEN ! assume complex conjugate in data files
273               td%ssh0(:,:,2) = - td%ssh0(:,:,2)
274               td%u0  (:,:,2) = - td%u0  (:,:,2)
275               td%v0  (:,:,2) = - td%v0  (:,:,2)
276            ENDIF
277            !
278            IF ( lk_dynspg_ts ) THEN ! Allocate arrays to save slowly varying boundary data during
279                                     ! time splitting integration
280               ALLOCATE( dta_bdy_s(ib_bdy)%ssh ( ilen0(1) ) )
281               ALLOCATE( dta_bdy_s(ib_bdy)%u2d ( ilen0(2) ) )
282               ALLOCATE( dta_bdy_s(ib_bdy)%v2d ( ilen0(3) ) )
283               dta_bdy_s(ib_bdy)%ssh(:) = 0.e0
284               dta_bdy_s(ib_bdy)%u2d(:) = 0.e0
285               dta_bdy_s(ib_bdy)%v2d(:) = 0.e0
286            ENDIF
287            !
288         ENDIF ! nn_dyn2d_dta(ib_bdy) .ge. 2
289         !
290      END DO ! loop on ib_bdy
291
292      IF( nn_timing == 1 ) CALL timing_stop('bdytide_init')
293
294   END SUBROUTINE bdytide_init
295
296   SUBROUTINE bdytide_update ( kt, idx, dta, td, jit, time_offset )
297      !!----------------------------------------------------------------------
298      !!                 ***  SUBROUTINE bdytide_update  ***
299      !!               
300      !! ** Purpose : - Add tidal forcing to ssh, u2d and v2d OBC data arrays.
301      !!               
302      !!----------------------------------------------------------------------
303      INTEGER, INTENT( in )            ::   kt          ! Main timestep counter
304      TYPE(OBC_INDEX), INTENT( in )    ::   idx         ! OBC indices
305      TYPE(OBC_DATA),  INTENT(inout)   ::   dta         ! OBC external data
306      TYPE(TIDES_DATA),INTENT( inout ) ::   td          ! tidal harmonics data
307      INTEGER,INTENT(in),OPTIONAL      ::   jit         ! Barotropic timestep counter (for timesplitting option)
308      INTEGER,INTENT( in ), OPTIONAL   ::   time_offset ! time offset in units of timesteps. NB. if jit
309                                                        ! is present then units = subcycle timesteps.
310                                                        ! time_offset = 0  => get data at "now"    time level
311                                                        ! time_offset = -1 => get data at "before" time level
312                                                        ! time_offset = +1 => get data at "after"  time level
313                                                        ! etc.
314      !!
315      INTEGER, DIMENSION(3)            ::   ilen0       !: length of boundary data (from OBC arrays)
316      INTEGER                          :: itide, igrd, ib   ! dummy loop indices
317      INTEGER                          :: time_add          ! time offset in units of timesteps
318      REAL(wp)                         :: z_arg, z_sarg, zflag, zramp     
319      REAL(wp), DIMENSION(jpmax_harmo) :: z_sist, z_cost
320      !!----------------------------------------------------------------------
321
322      IF( nn_timing == 1 ) CALL timing_start('bdytide_update')
323
324      ilen0(1) =  SIZE(td%ssh(:,1,1))
325      ilen0(2) =  SIZE(td%u(:,1,1))
326      ilen0(3) =  SIZE(td%v(:,1,1))
327
328      zflag=1
329      IF ( PRESENT(jit) ) THEN
330        IF ( jit /= 1 ) zflag=0
331      ENDIF
332
333      IF ( nsec_day == NINT(0.5_wp * rdttra(1)) .AND. zflag==1 ) THEN
334        !
335        kt_tide = kt
336        !
337        IF(lwp) THEN
338           WRITE(numout,*)
339           WRITE(numout,*) 'bdytide_update : (re)Initialization of the tidal bdy forcing at kt=',kt
340           WRITE(numout,*) '~~~~~~~~~~~~~~ '
341        ENDIF
342        !
343        CALL tide_init_elevation ( idx, td )
344        CALL tide_init_velocities( idx, td )
345        !
346      ENDIF
347
348      time_add = 0
349      IF( PRESENT(time_offset) ) THEN
350         time_add = time_offset
351      ENDIF
352         
353      IF( PRESENT(jit) ) THEN 
354         z_arg = ((kt-kt_tide) * rdt + (jit+0.5_wp*(time_add-1)) * rdt / REAL(nn_baro,wp) )
355      ELSE                             
356         z_arg = ((kt-kt_tide)+time_add) * rdt
357      ENDIF
358
359      ! Linear ramp on tidal component at open boundaries
360      zramp = 1._wp
361      IF (ln_tide_ramp) zramp = MIN(MAX( (z_arg + (kt_tide-nit000)*rdt)/(rdttideramp*rday),0._wp),1._wp)
362
363      DO itide = 1, nb_harmo
364         z_sarg = z_arg * omega_tide(itide)
365         z_cost(itide) = COS( z_sarg )
366         z_sist(itide) = SIN( z_sarg )
367      END DO
368
369      DO itide = 1, nb_harmo
370         igrd=1                              ! SSH on tracer grid
371         DO ib = 1, ilen0(igrd)
372            dta%ssh(ib) = dta%ssh(ib) + zramp*(td%ssh(ib,itide,1)*z_cost(itide) + td%ssh(ib,itide,2)*z_sist(itide))
373         END DO
374         igrd=2                              ! U grid
375         DO ib = 1, ilen0(igrd)
376            dta%u2d(ib) = dta%u2d(ib) + zramp*(td%u  (ib,itide,1)*z_cost(itide) + td%u  (ib,itide,2)*z_sist(itide))
377         END DO
378         igrd=3                              ! V grid
379         DO ib = 1, ilen0(igrd) 
380            dta%v2d(ib) = dta%v2d(ib) + zramp*(td%v  (ib,itide,1)*z_cost(itide) + td%v  (ib,itide,2)*z_sist(itide))
381         END DO
382      END DO
383      !
384      IF( nn_timing == 1 ) CALL timing_stop('bdytide_update')
385      !
386   END SUBROUTINE bdytide_update
387
388   SUBROUTINE bdy_dta_tides( kt, kit, time_offset )
389      !!----------------------------------------------------------------------
390      !!                 ***  SUBROUTINE bdy_dta_tides  ***
391      !!               
392      !! ** Purpose : - Add tidal forcing to ssh, u2d and v2d OBC data arrays.
393      !!               
394      !!----------------------------------------------------------------------
395      INTEGER, INTENT( in )            ::   kt          ! Main timestep counter
396      INTEGER, INTENT( in ),OPTIONAL   ::   kit         ! Barotropic timestep counter (for timesplitting option)
397      INTEGER, INTENT( in ),OPTIONAL   ::   time_offset ! time offset in units of timesteps. NB. if kit
398                                                        ! is present then units = subcycle timesteps.
399                                                        ! time_offset = 0  => get data at "now"    time level
400                                                        ! time_offset = -1 => get data at "before" time level
401                                                        ! time_offset = +1 => get data at "after"  time level
402                                                        ! etc.
403      !!
404      LOGICAL  :: lk_first_btstp  ! =.TRUE. if time splitting and first barotropic step
405      INTEGER,          DIMENSION(jpbgrd) :: ilen0 
406      INTEGER, DIMENSION(1:jpbgrd) :: nblen, nblenrim  ! short cuts
407      INTEGER  :: itide, ib_bdy, ib, igrd                     ! loop indices
408      INTEGER  :: time_add                                    ! time offset in units of timesteps
409      REAL(wp) :: z_arg, z_sarg, zramp, zoff, z_cost, z_sist     
410      !!----------------------------------------------------------------------
411
412      IF( nn_timing == 1 ) CALL timing_start('bdy_dta_tides')
413
414      lk_first_btstp=.TRUE.
415      IF ( PRESENT(kit).AND.( kit /= 1 ) ) THEN ; lk_first_btstp=.FALSE. ; ENDIF
416
417      time_add = 0
418      IF( PRESENT(time_offset) ) THEN
419         time_add = time_offset
420      ENDIF
421     
422      ! Absolute time from model initialization:   
423      IF( PRESENT(kit) ) THEN 
424         z_arg = ( kt + (kit+0.5_wp*(time_add-1)) / REAL(nn_baro,wp) ) * rdt
425      ELSE                             
426         z_arg = ( kt + time_add ) * rdt
427      ENDIF
428
429      ! Linear ramp on tidal component at open boundaries
430      zramp = 1.
431      IF (ln_tide_ramp) zramp = MIN(MAX( (z_arg - nit000*rdt)/(rdttideramp*rday),0.),1.)
432
433      DO ib_bdy = 1,nb_bdy
434
435         IF ( nn_dyn2d_dta(ib_bdy) .ge. 2 ) THEN
436
437            nblen(1:jpbgrd) = idx_bdy(ib_bdy)%nblen(1:jpbgrd)
438            nblenrim(1:jpbgrd) = idx_bdy(ib_bdy)%nblenrim(1:jpbgrd)
439
440            IF( cn_dyn2d(ib_bdy) == 'frs' ) THEN
441               ilen0(:)=nblen(:)
442            ELSE
443               ilen0(:)=nblenrim(:)
444            ENDIF     
445
446            ! We refresh nodal factors every day below
447            ! This should be done somewhere else
448            IF ( nsec_day == NINT(0.5_wp * rdttra(1)) .AND. lk_first_btstp ) THEN
449               !
450               kt_tide = kt               
451               !
452               IF(lwp) THEN
453               WRITE(numout,*)
454               WRITE(numout,*) 'bdy_tide_dta : Refresh nodal factors for tidal open bdy data at kt=',kt
455               WRITE(numout,*) '~~~~~~~~~~~~~~ '
456               ENDIF
457               !
458               CALL tide_init_elevation ( idx=idx_bdy(ib_bdy), td=tides(ib_bdy) )
459               CALL tide_init_velocities( idx=idx_bdy(ib_bdy), td=tides(ib_bdy) )
460               !
461            ENDIF
462            zoff = -kt_tide * rdt ! time offset relative to nodal factor computation time
463            !
464            ! If time splitting, save data at first barotropic iteration
465            IF ( PRESENT(kit) ) THEN
466               IF ( lk_first_btstp ) THEN ! Save slow varying open boundary data:
467                  IF ( dta_bdy(ib_bdy)%ll_ssh ) dta_bdy_s(ib_bdy)%ssh(1:ilen0(1)) = dta_bdy(ib_bdy)%ssh(1:ilen0(1))
468                  IF ( dta_bdy(ib_bdy)%ll_u2d ) dta_bdy_s(ib_bdy)%u2d(1:ilen0(2)) = dta_bdy(ib_bdy)%u2d(1:ilen0(2))
469                  IF ( dta_bdy(ib_bdy)%ll_v2d ) dta_bdy_s(ib_bdy)%v2d(1:ilen0(3)) = dta_bdy(ib_bdy)%v2d(1:ilen0(3))
470
471               ELSE ! Initialize arrays from slow varying open boundary data:           
472                  IF ( dta_bdy(ib_bdy)%ll_ssh ) dta_bdy(ib_bdy)%ssh(1:ilen0(1)) = dta_bdy_s(ib_bdy)%ssh(1:ilen0(1))
473                  IF ( dta_bdy(ib_bdy)%ll_u2d ) dta_bdy(ib_bdy)%u2d(1:ilen0(2)) = dta_bdy_s(ib_bdy)%u2d(1:ilen0(2))
474                  IF ( dta_bdy(ib_bdy)%ll_v2d ) dta_bdy(ib_bdy)%v2d(1:ilen0(3)) = dta_bdy_s(ib_bdy)%v2d(1:ilen0(3))
475               ENDIF
476            ENDIF
477            !
478            ! Update open boundary data arrays:
479            DO itide = 1, nb_harmo
480               !
481               z_sarg = (z_arg + zoff) * omega_tide(itide)
482               z_cost = zramp * COS( z_sarg )
483               z_sist = zramp * SIN( z_sarg )
484               !
485               IF ( dta_bdy(ib_bdy)%ll_ssh ) THEN
486                  igrd=1                              ! SSH on tracer grid
487                  DO ib = 1, ilen0(igrd)
488                     dta_bdy(ib_bdy)%ssh(ib) = dta_bdy(ib_bdy)%ssh(ib) + &
489                        &                      ( tides(ib_bdy)%ssh(ib,itide,1)*z_cost + &
490                        &                        tides(ib_bdy)%ssh(ib,itide,2)*z_sist )
491                  END DO
492               ENDIF
493               !
494               IF ( dta_bdy(ib_bdy)%ll_u2d ) THEN
495                  igrd=2                              ! U grid
496                  DO ib = 1, ilen0(igrd)
497                     dta_bdy(ib_bdy)%u2d(ib) = dta_bdy(ib_bdy)%u2d(ib) + &
498                        &                      ( tides(ib_bdy)%u(ib,itide,1)*z_cost + &
499                        &                        tides(ib_bdy)%u(ib,itide,2)*z_sist )
500                  END DO
501               ENDIF
502               !
503               IF ( dta_bdy(ib_bdy)%ll_v2d ) THEN
504                  igrd=3                              ! V grid
505                  DO ib = 1, ilen0(igrd) 
506                     dta_bdy(ib_bdy)%v2d(ib) = dta_bdy(ib_bdy)%v2d(ib) + &
507                        &                      ( tides(ib_bdy)%v(ib,itide,1)*z_cost + &
508                        &                        tides(ib_bdy)%v(ib,itide,2)*z_sist )
509                  END DO
510               ENDIF
511            END DO             
512         END IF
513      END DO
514      !
515      IF( nn_timing == 1 ) CALL timing_stop('bdy_dta_tides')
516      !
517   END SUBROUTINE bdy_dta_tides
518
519   SUBROUTINE tide_init_elevation( idx, td )
520      !!----------------------------------------------------------------------
521      !!                 ***  ROUTINE tide_init_elevation  ***
522      !!----------------------------------------------------------------------
523      TYPE(OBC_INDEX), INTENT( in )      ::   idx     ! OBC indices
524      TYPE(TIDES_DATA),INTENT( inout )   ::   td      ! tidal harmonics data
525      !! * Local declarations
526      INTEGER, DIMENSION(1)            ::   ilen0       !: length of boundary data (from OBC arrays)
527      REAL(wp),ALLOCATABLE, DIMENSION(:) ::   mod_tide, phi_tide
528      INTEGER                            ::   itide, igrd, ib      ! dummy loop indices
529
530      igrd=1   
531                              ! SSH on tracer grid.
532   
533      ilen0(1) =  SIZE(td%ssh0(:,1,1))
534
535      ALLOCATE(mod_tide(ilen0(igrd)),phi_tide(ilen0(igrd)))
536
537      DO itide = 1, nb_harmo
538         DO ib = 1, ilen0(igrd)
539            mod_tide(ib)=SQRT(td%ssh0(ib,itide,1)**2.+td%ssh0(ib,itide,2)**2.)
540            phi_tide(ib)=ATAN2(-td%ssh0(ib,itide,2),td%ssh0(ib,itide,1))
541         END DO
542         DO ib = 1 , ilen0(igrd)
543            mod_tide(ib)=mod_tide(ib)*ftide(itide)
544            phi_tide(ib)=phi_tide(ib)+v0tide(itide)+utide(itide)
545         ENDDO
546         DO ib = 1 , ilen0(igrd)
547            td%ssh(ib,itide,1)= mod_tide(ib)*COS(phi_tide(ib))
548            td%ssh(ib,itide,2)=-mod_tide(ib)*SIN(phi_tide(ib))
549         ENDDO
550      END DO
551
552      DEALLOCATE(mod_tide,phi_tide)
553
554   END SUBROUTINE tide_init_elevation
555
556   SUBROUTINE tide_init_velocities( idx, td )
557      !!----------------------------------------------------------------------
558      !!                 ***  ROUTINE tide_init_elevation  ***
559      !!----------------------------------------------------------------------
560      TYPE(OBC_INDEX), INTENT( in )      ::   idx     ! OBC indices
561      TYPE(TIDES_DATA),INTENT( inout )      ::   td      ! tidal harmonics data
562      !! * Local declarations
563      INTEGER, DIMENSION(3)            ::   ilen0       !: length of boundary data (from OBC arrays)
564      REAL(wp),ALLOCATABLE, DIMENSION(:) ::   mod_tide, phi_tide
565      INTEGER                            ::   itide, igrd, ib      ! dummy loop indices
566
567      ilen0(2) =  SIZE(td%u0(:,1,1))
568      ilen0(3) =  SIZE(td%v0(:,1,1))
569
570      igrd=2                                 ! U grid.
571
572      ALLOCATE(mod_tide(ilen0(igrd)),phi_tide(ilen0(igrd)))
573
574      DO itide = 1, nb_harmo
575         DO ib = 1, ilen0(igrd)
576            mod_tide(ib)=SQRT(td%u0(ib,itide,1)**2.+td%u0(ib,itide,2)**2.)
577            phi_tide(ib)=ATAN2(-td%u0(ib,itide,2),td%u0(ib,itide,1))
578         END DO
579         DO ib = 1, ilen0(igrd)
580            mod_tide(ib)=mod_tide(ib)*ftide(itide)
581            phi_tide(ib)=phi_tide(ib)+v0tide(itide)+utide(itide)
582         ENDDO
583         DO ib = 1, ilen0(igrd)
584            td%u(ib,itide,1)= mod_tide(ib)*COS(phi_tide(ib))
585            td%u(ib,itide,2)=-mod_tide(ib)*SIN(phi_tide(ib))
586         ENDDO
587      END DO
588
589      DEALLOCATE(mod_tide,phi_tide)
590
591      igrd=3                                 ! V grid.
592
593      ALLOCATE(mod_tide(ilen0(igrd)),phi_tide(ilen0(igrd)))
594
595      DO itide = 1, nb_harmo
596         DO ib = 1, ilen0(igrd)
597            mod_tide(ib)=SQRT(td%v0(ib,itide,1)**2.+td%v0(ib,itide,2)**2.)
598            phi_tide(ib)=ATAN2(-td%v0(ib,itide,2),td%v0(ib,itide,1))
599         END DO
600         DO ib = 1, ilen0(igrd)
601            mod_tide(ib)=mod_tide(ib)*ftide(itide)
602            phi_tide(ib)=phi_tide(ib)+v0tide(itide)+utide(itide)
603         ENDDO
604         DO ib = 1, ilen0(igrd)
605            td%v(ib,itide,1)= mod_tide(ib)*COS(phi_tide(ib))
606            td%v(ib,itide,2)=-mod_tide(ib)*SIN(phi_tide(ib))
607         ENDDO
608      END DO
609
610      DEALLOCATE(mod_tide,phi_tide)
611
612  END SUBROUTINE tide_init_velocities
613#else
614   !!----------------------------------------------------------------------
615   !!   Dummy module         NO Unstruct Open Boundary Conditions for tides
616   !!----------------------------------------------------------------------
617CONTAINS
618   SUBROUTINE bdytide_init             ! Empty routine
619      WRITE(*,*) 'bdytide_init: You should not have seen this print! error?'
620   END SUBROUTINE bdytide_init
621   SUBROUTINE bdytide_update( kt, jit )   ! Empty routine
622      WRITE(*,*) 'bdytide_update: You should not have seen this print! error?', kt, jit
623   END SUBROUTINE bdytide_update
624   SUBROUTINE bdy_dta_tides( kt, kit, time_offset )     ! Empty routine
625      INTEGER, INTENT( in )            ::   kt          ! Dummy argument empty routine     
626      INTEGER, INTENT( in ),OPTIONAL   ::   kit         ! Dummy argument empty routine
627      INTEGER, INTENT( in ),OPTIONAL   ::   time_offset ! Dummy argument empty routine
628      WRITE(*,*) 'bdy_dta_tides: You should not have seen this print! error?', kt, jit
629   END SUBROUTINE bdy_dta_tides
630#endif
631
632   !!======================================================================
633END MODULE bdytides
634
Note: See TracBrowser for help on using the repository browser.