source: branches/UKMO/dev_r5107_eorca025_closea/NEMOGCM/NEMO/OPA_SRC/DOM/closea.F90 @ 5308

Last change on this file since 5308 was 5308, checked in by davestorkey, 6 years ago

UKMO dev_r5107_eorca025_closea branch: apply changes to closea.F90.

File size: 21.2 KB
Line 
1MODULE closea
2   !!======================================================================
3   !!                       ***  MODULE  closea  ***
4   !! Closed Seas  : specific treatments associated with closed seas
5   !!======================================================================
6   !! History :   8.2  !  00-05  (O. Marti)  Original code
7   !!             8.5  !  02-06  (E. Durand, G. Madec)  F90
8   !!             9.0  !  06-07  (G. Madec)  add clo_rnf, clo_ups, clo_bat
9   !!        NEMO 3.4  !  03-12  (P.G. Fogli) sbc_clo bug fix & mpp reproducibility
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!   dom_clo    : modification of the ocean domain for closed seas cases
14   !!   sbc_clo    : Special handling of closed seas
15   !!   clo_rnf    : set close sea outflows as river mouths (see sbcrnf)
16   !!   clo_ups    : set mixed centered/upstream scheme in closed sea (see traadv_cen2)
17   !!   clo_bat    : set to zero a field over closed sea (see domzrg)
18   !!----------------------------------------------------------------------
19   USE oce             ! dynamics and tracers
20   USE dom_oce         ! ocean space and time domain
21   USE phycst          ! physical constants
22   USE in_out_manager  ! I/O manager
23   USE sbc_oce         ! ocean surface boundary conditions
24   USE lib_fortran,    ONLY: glob_sum, DDPDD
25   USE lbclnk          ! lateral boundary condition - MPP exchanges
26   USE lib_mpp         ! MPP library
27   USE timing
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC dom_clo      ! routine called by domain module
33   PUBLIC sbc_clo      ! routine called by step module
34   PUBLIC clo_rnf      ! routine called by sbcrnf module
35   PUBLIC clo_ups      ! routine called in traadv_cen2(_jki) module
36   PUBLIC clo_bat      ! routine called in domzgr module
37
38   INTEGER, PUBLIC, PARAMETER          ::   jpncs   = 4      !: number of closed sea
39   INTEGER, PUBLIC, DIMENSION(jpncs)   ::   ncstt            !: Type of closed sea
40   INTEGER, PUBLIC, DIMENSION(jpncs)   ::   ncsi1, ncsj1     !: south-west closed sea limits (i,j)
41   INTEGER, PUBLIC, DIMENSION(jpncs)   ::   ncsi2, ncsj2     !: north-east closed sea limits (i,j)
42   INTEGER, PUBLIC, DIMENSION(jpncs)   ::   ncsnr            !: number of point where run-off pours
43   INTEGER, PUBLIC, DIMENSION(jpncs,4) ::   ncsir, ncsjr     !: Location of runoff
44
45   REAL(wp), DIMENSION (jpncs+1)       ::   surf             ! closed sea surface
46
47   !! * Substitutions
48#  include "vectopt_loop_substitute.h90"
49   !!----------------------------------------------------------------------
50   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
51   !! $Id: closea.F90 4162 2013-11-07 10:19:49Z cetlod $
52   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
53   !!----------------------------------------------------------------------
54CONTAINS
55
56   SUBROUTINE dom_clo
57      !!---------------------------------------------------------------------
58      !!                  ***  ROUTINE dom_clo  ***
59      !!       
60      !! ** Purpose :   Closed sea domain initialization
61      !!
62      !! ** Method  :   if a closed sea is located only in a model grid point
63      !!                just the thermodynamic processes are applied.
64      !!
65      !! ** Action  :   ncsi1(), ncsj1() : south-west closed sea limits (i,j)
66      !!                ncsi2(), ncsj2() : north-east Closed sea limits (i,j)
67      !!                ncsir(), ncsjr() : Location of runoff
68      !!                ncsnr            : number of point where run-off pours
69      !!                ncstt            : Type of closed sea
70      !!                                   =0 spread over the world ocean
71      !!                                   =2 put at location runoff
72      !!----------------------------------------------------------------------
73      INTEGER ::   jc            ! dummy loop indices
74      !!----------------------------------------------------------------------
75     
76      IF(lwp) WRITE(numout,*)
77      IF(lwp) WRITE(numout,*)'dom_clo : closed seas '
78      IF(lwp) WRITE(numout,*)'~~~~~~~'
79
80      ! initial values
81      ncsnr(:) = 1  ;  ncsi1(:) = 1  ;  ncsi2(:) = 1  ;  ncsir(:,:) = 1
82      ncstt(:) = 0  ;  ncsj1(:) = 1  ;  ncsj2(:) = 1  ;  ncsjr(:,:) = 1
83
84      ! set the closed seas (in data domain indices)
85      ! -------------------
86
87      IF( cp_cfg == "orca" ) THEN
88         !
89         SELECT CASE ( jp_cfg )
90         !                                           ! =======================
91         CASE ( 1 )                                  ! ORCA_R1 configuration
92            !                                        ! =======================
93            ncsnr(1)   = 1    ; ncstt(1)   = 0           ! Caspian Sea
94            ncsi1(1)   = 332  ; ncsj1(1)   = 203
95            ncsi2(1)   = 344  ; ncsj2(1)   = 235
96            ncsir(1,1) = 1    ; ncsjr(1,1) = 1
97            !                                       
98            !                                        ! =======================
99         CASE ( 2 )                                  !  ORCA_R2 configuration
100            !                                        ! =======================
101            !                                            ! Caspian Sea
102            ncsnr(1)   =   1  ;  ncstt(1)   =   0           ! spread over the globe
103            ncsi1(1)   =  11  ;  ncsj1(1)   = 103
104            ncsi2(1)   =  17  ;  ncsj2(1)   = 112
105            ncsir(1,1) =   1  ;  ncsjr(1,1) =   1 
106            !                                            ! Great North American Lakes
107            ncsnr(2)   =   1  ;  ncstt(2)   =   2           ! put at St Laurent mouth
108            ncsi1(2)   =  97  ;  ncsj1(2)   = 107
109            ncsi2(2)   = 103  ;  ncsj2(2)   = 111
110            ncsir(2,1) = 110  ;  ncsjr(2,1) = 111           
111            !                                            ! Black Sea (crossed by the cyclic boundary condition)
112            ncsnr(3:4) =   4  ;  ncstt(3:4) =   2           ! put in Med Sea (north of Aegean Sea)
113            ncsir(3:4,1) = 171;  ncsjr(3:4,1) = 106         !
114            ncsir(3:4,2) = 170;  ncsjr(3:4,2) = 106 
115            ncsir(3:4,3) = 171;  ncsjr(3:4,3) = 105 
116            ncsir(3:4,4) = 170;  ncsjr(3:4,4) = 105 
117            ncsi1(3)   = 174  ;  ncsj1(3)   = 107           ! 1 : west part of the Black Sea     
118            ncsi2(3)   = 181  ;  ncsj2(3)   = 112           !            (ie west of the cyclic b.c.)
119            ncsi1(4)   =   2  ;  ncsj1(4)   = 107           ! 2 : east part of the Black Sea
120            ncsi2(4)   =   6  ;  ncsj2(4)   = 112           !           (ie east of the cyclic b.c.)
121             
122         
123
124            !                                        ! =======================
125         CASE ( 4 )                                  !  ORCA_R4 configuration
126            !                                        ! =======================
127            !                                            ! Caspian Sea
128            ncsnr(1)   =  1  ;  ncstt(1)   =  0 
129            ncsi1(1)   =  4  ;  ncsj1(1)   = 53 
130            ncsi2(1)   =  4  ;  ncsj2(1)   = 56
131            ncsir(1,1) =  1  ;  ncsjr(1,1) =  1
132            !                                            ! Great North American Lakes
133            ncsnr(2)   =  1  ;  ncstt(2)   =  2 
134            ncsi1(2)   = 49  ;  ncsj1(2)   = 55
135            ncsi2(2)   = 51  ;  ncsj2(2)   = 56
136            ncsir(2,1) = 57  ;  ncsjr(2,1) = 55
137            !                                            ! Black Sea
138            ncsnr(3)   =  4  ;  ncstt(3)   =  2 
139            ncsi1(3)   = 88  ;  ncsj1(3)   = 55 
140            ncsi2(3)   = 91  ;  ncsj2(3)   = 56
141            ncsir(3,1) = 86  ;  ncsjr(3,1) = 53
142            ncsir(3,2) = 87  ;  ncsjr(3,2) = 53 
143            ncsir(3,3) = 86  ;  ncsjr(3,3) = 52 
144            ncsir(3,4) = 87  ;  ncsjr(3,4) = 52
145            !                                            ! Baltic Sea
146            ncsnr(4)   =  1  ;  ncstt(4)   =  2
147            ncsi1(4)   = 75  ;  ncsj1(4)   = 59
148            ncsi2(4)   = 76  ;  ncsj2(4)   = 61
149            ncsir(4,1) = 84  ;  ncsjr(4,1) = 59 
150            !                                        ! ================================
151         CASE ( 025 )                                ! ORCA_R025 extended configuration
152            !                                        ! ================================
153            ncsnr(1)   = 1    ; ncstt(1)   = 0               ! Caspian + Aral sea
154            ncsi1(1)   = 1330 ; ncsj1(1)   = 831
155            ncsi2(1)   = 1400 ; ncsj2(1)   = 981
156            ncsir(1,1) = 1    ; ncsjr(1,1) = 1
157            !                                       
158            ncsnr(2)   = 1    ; ncstt(2)   = 0               ! Azov Sea
159            ncsi1(2)   = 1284 ; ncsj1(2)   = 908
160            ncsi2(2)   = 1304 ; ncsj2(2)   = 933
161            ncsir(2,1) = 1    ; ncsjr(2,1) = 1
162            !
163            ncsnr(3)   = 1    ; ncstt(3)   = 0               ! North American Great Lakes 
164            ncsi1(3)   = 781  ; ncsj1(3)   = 870 
165            ncsi2(3)   = 847  ; ncsj2(3)   = 926 
166            ncsir(3,1) = 1    ; ncsjr(3,1) = 1 
167            !
168            ncsnr(4)   = 1    ; ncstt(4)   = 0               ! Lake Victoria 
169            ncsi1(4)   = 1274 ; ncsj1(4)   = 672 
170            ncsi2(4)   = 1289 ; ncsj2(4)   = 687 
171            ncsir(4,1) = 1    ; ncsjr(4,1) = 1 
172            !
173         END SELECT
174         !
175      ENDIF
176
177      ! convert the position in local domain indices
178      ! --------------------------------------------
179      DO jc = 1, jpncs
180         ncsi1(jc)   = mi0( ncsi1(jc) )
181         ncsj1(jc)   = mj0( ncsj1(jc) )
182
183         ncsi2(jc)   = mi1( ncsi2(jc) )   
184         ncsj2(jc)   = mj1( ncsj2(jc) ) 
185      END DO
186      !
187   END SUBROUTINE dom_clo
188
189
190   SUBROUTINE sbc_clo( kt )
191      !!---------------------------------------------------------------------
192      !!                  ***  ROUTINE sbc_clo  ***
193      !!                   
194      !! ** Purpose :   Special handling of closed seas
195      !!
196      !! ** Method  :   Water flux is forced to zero over closed sea
197      !!      Excess is shared between remaining ocean, or
198      !!      put as run-off in open ocean.
199      !!
200      !! ** Action  :   emp updated surface freshwater fluxes and associated heat content at kt
201      !!----------------------------------------------------------------------
202      INTEGER, INTENT(in) ::   kt   ! ocean model time step
203      !
204      INTEGER             ::   ji, jj, jc, jn   ! dummy loop indices
205      REAL(wp), PARAMETER ::   rsmall = 1.e-20_wp    ! Closed sea correction epsilon
206      REAL(wp)            ::   zze2, ztmp, zcorr     !
207      REAL(wp)            ::   zcoef, zcoef1         !
208      COMPLEX(wp)         ::   ctmp 
209      REAL(wp), DIMENSION(jpncs) ::   zfwf   ! 1D workspace
210      !!----------------------------------------------------------------------
211      !
212      IF( nn_timing == 1 )  CALL timing_start('sbc_clo')
213      !                                                   !------------------!
214      IF( kt == nit000 ) THEN                             !  Initialisation  !
215         !                                                !------------------!
216         IF(lwp) WRITE(numout,*)
217         IF(lwp) WRITE(numout,*)'sbc_clo : closed seas '
218         IF(lwp) WRITE(numout,*)'~~~~~~~'
219
220         surf(:) = 0.e0_wp
221         !
222         surf(jpncs+1) = glob_sum( e1e2t(:,:) )   ! surface of the global ocean
223         !
224         !                                        ! surface of closed seas
225         IF( lk_mpp_rep ) THEN                         ! MPP reproductible calculation
226            DO jc = 1, jpncs
227               ctmp = CMPLX( 0.e0, 0.e0, wp )
228               DO jj = ncsj1(jc), ncsj2(jc)
229                  DO ji = ncsi1(jc), ncsi2(jc)
230                     ztmp = e1e2t(ji,jj) * tmask_i(ji,jj)
231                     CALL DDPDD( CMPLX( ztmp, 0.e0, wp ), ctmp )
232                  END DO
233               END DO
234               IF( lk_mpp )   CALL mpp_sum( ctmp )
235               surf(jc) = REAL(ctmp,wp)
236            END DO
237         ELSE                                          ! Standard calculation           
238            DO jc = 1, jpncs
239               DO jj = ncsj1(jc), ncsj2(jc)
240                  DO ji = ncsi1(jc), ncsi2(jc)
241                     surf(jc) = surf(jc) + e1e2t(ji,jj) * tmask_i(ji,jj)      ! surface of closed seas
242                  END DO
243               END DO
244            END DO
245            IF( lk_mpp )   CALL mpp_sum ( surf, jpncs )       ! mpp: sum over all the global domain
246         ENDIF
247
248         IF(lwp) WRITE(numout,*)'     Closed sea surfaces'
249         DO jc = 1, jpncs
250            IF(lwp)WRITE(numout,FMT='(1I3,4I4,5X,F16.2)') jc, ncsi1(jc), ncsi2(jc), ncsj1(jc), ncsj2(jc), surf(jc)
251         END DO
252
253         ! jpncs+1 : surface of sea, closed seas excluded
254         DO jc = 1, jpncs
255            surf(jpncs+1) = surf(jpncs+1) - surf(jc)
256         END DO           
257         !
258      ENDIF
259      !                                                   !--------------------!
260      !                                                   !  update emp        !
261      zfwf = 0.e0_wp                                      !--------------------!
262      IF( lk_mpp_rep ) THEN                         ! MPP reproductible calculation
263         DO jc = 1, jpncs
264            ctmp = CMPLX( 0.e0, 0.e0, wp )
265            DO jj = ncsj1(jc), ncsj2(jc)
266               DO ji = ncsi1(jc), ncsi2(jc)
267                  ztmp = e1e2t(ji,jj) * ( emp(ji,jj)-rnf(ji,jj) ) * tmask_i(ji,jj)
268                  CALL DDPDD( CMPLX( ztmp, 0.e0, wp ), ctmp )
269               END DO 
270            END DO
271            IF( lk_mpp )   CALL mpp_sum( ctmp )
272            zfwf(jc) = REAL(ctmp,wp)
273         END DO
274      ELSE                                          ! Standard calculation           
275         DO jc = 1, jpncs
276            DO jj = ncsj1(jc), ncsj2(jc)
277               DO ji = ncsi1(jc), ncsi2(jc)
278                  zfwf(jc) = zfwf(jc) + e1e2t(ji,jj) * ( emp(ji,jj)-rnf(ji,jj) ) * tmask_i(ji,jj) 
279               END DO 
280            END DO
281         END DO
282         IF( lk_mpp )   CALL mpp_sum ( zfwf(:) , jpncs )       ! mpp: sum over all the global domain
283      ENDIF
284
285      IF( cp_cfg == "orca" .AND. jp_cfg == 2 ) THEN      ! Black Sea case for ORCA_R2 configuration
286         zze2    = ( zfwf(3) + zfwf(4) ) * 0.5_wp
287         zfwf(3) = zze2
288         zfwf(4) = zze2
289      ENDIF
290
291      zcorr = 0._wp
292
293      DO jc = 1, jpncs
294         !
295         ! The following if avoids the redistribution of the round off
296         IF ( ABS(zfwf(jc) / surf(jpncs+1) ) > rsmall) THEN
297            !
298            IF( ncstt(jc) == 0 ) THEN           ! water/evap excess is shared by all open ocean
299               zcoef    = zfwf(jc) / surf(jpncs+1)
300               zcoef1   = rcp * zcoef
301               emp(:,:) = emp(:,:) + zcoef
302               qns(:,:) = qns(:,:) - zcoef1 * sst_m(:,:)
303               ! accumulate closed seas correction
304               zcorr    = zcorr    + zcoef
305               !
306            ELSEIF( ncstt(jc) == 1 ) THEN       ! Excess water in open sea, at outflow location, excess evap shared
307               IF ( zfwf(jc) <= 0.e0_wp ) THEN
308                   DO jn = 1, ncsnr(jc)
309                     ji = mi0(ncsir(jc,jn))
310                     jj = mj0(ncsjr(jc,jn)) ! Location of outflow in open ocean
311                     IF (      ji > 1 .AND. ji < jpi   &
312                         .AND. jj > 1 .AND. jj < jpj ) THEN
313                         zcoef      = zfwf(jc) / ( REAL(ncsnr(jc)) * e1e2t(ji,jj) )
314                         zcoef1     = rcp * zcoef
315                         emp(ji,jj) = emp(ji,jj) + zcoef
316                         qns(ji,jj) = qns(ji,jj) - zcoef1 * sst_m(ji,jj)
317                     ENDIF
318                   END DO
319               ELSE
320                   zcoef    = zfwf(jc) / surf(jpncs+1)
321                   zcoef1   = rcp * zcoef
322                   emp(:,:) = emp(:,:) + zcoef
323                   qns(:,:) = qns(:,:) - zcoef1 * sst_m(:,:)
324                   ! accumulate closed seas correction
325                   zcorr    = zcorr    + zcoef
326               ENDIF
327            ELSEIF( ncstt(jc) == 2 ) THEN       ! Excess e-p-r (either sign) goes to open ocean, at outflow location
328               DO jn = 1, ncsnr(jc)
329                  ji = mi0(ncsir(jc,jn))
330                  jj = mj0(ncsjr(jc,jn)) ! Location of outflow in open ocean
331                  IF(      ji > 1 .AND. ji < jpi    &
332                     .AND. jj > 1 .AND. jj < jpj ) THEN
333                     zcoef      = zfwf(jc) / ( REAL(ncsnr(jc)) *  e1e2t(ji,jj) )
334                     zcoef1     = rcp * zcoef
335                     emp(ji,jj) = emp(ji,jj) + zcoef
336                     qns(ji,jj) = qns(ji,jj) - zcoef1 * sst_m(ji,jj)
337                  ENDIF
338               END DO
339            ENDIF 
340            !
341            DO jj = ncsj1(jc), ncsj2(jc)
342               DO ji = ncsi1(jc), ncsi2(jc)
343                  zcoef      = zfwf(jc) / surf(jc)
344                  zcoef1     = rcp * zcoef
345                  emp(ji,jj) = emp(ji,jj) - zcoef
346                  qns(ji,jj) = qns(ji,jj) + zcoef1 * sst_m(ji,jj)
347               END DO 
348            END DO 
349            !
350         END IF
351      END DO
352
353      IF ( ABS(zcorr) > rsmall ) THEN      ! remove the global correction from the closed seas
354         DO jc = 1, jpncs                  ! only if it is large enough
355            DO jj = ncsj1(jc), ncsj2(jc)
356               DO ji = ncsi1(jc), ncsi2(jc)
357                  emp(ji,jj) = emp(ji,jj) - zcorr
358                  qns(ji,jj) = qns(ji,jj) + rcp * zcorr * sst_m(ji,jj)
359               END DO 
360             END DO
361          END DO
362      ENDIF
363      !
364      emp (:,:) = emp (:,:) * tmask(:,:,1)
365      !
366      CALL lbc_lnk( emp , 'T', 1._wp )
367      !
368      IF( nn_timing == 1 )  CALL timing_stop('sbc_clo')
369      !
370   END SUBROUTINE sbc_clo
371
372
373   SUBROUTINE clo_rnf( p_rnfmsk )
374      !!---------------------------------------------------------------------
375      !!                  ***  ROUTINE sbc_rnf  ***
376      !!                   
377      !! ** Purpose :   allow the treatment of closed sea outflow grid-points
378      !!                to be the same as river mouth grid-points
379      !!
380      !! ** Method  :   set to 1 the runoff mask (mskrnf, see sbcrnf module)
381      !!                at the closed sea outflow grid-point.
382      !!
383      !! ** Action  :   update (p_)mskrnf (set 1 at closed sea outflow)
384      !!----------------------------------------------------------------------
385      REAL(wp), DIMENSION(jpi,jpj), INTENT(inout) ::   p_rnfmsk   ! river runoff mask (rnfmsk array)
386      !
387      INTEGER  ::   jc, jn, ji, jj      ! dummy loop indices
388      !!----------------------------------------------------------------------
389      !
390      DO jc = 1, jpncs
391         IF( ncstt(jc) >= 1 ) THEN            ! runoff mask set to 1 at closed sea outflows
392             DO jn = 1, 4
393                DO jj =    mj0( ncsjr(jc,jn) ), mj1( ncsjr(jc,jn) )
394                   DO ji = mi0( ncsir(jc,jn) ), mi1( ncsir(jc,jn) )
395                      p_rnfmsk(ji,jj) = MAX( p_rnfmsk(ji,jj), 1.0_wp )
396                   END DO
397                END DO
398            END DO
399         ENDIF
400      END DO 
401      !
402   END SUBROUTINE clo_rnf
403
404   
405   SUBROUTINE clo_ups( p_upsmsk )
406      !!---------------------------------------------------------------------
407      !!                  ***  ROUTINE sbc_rnf  ***
408      !!                   
409      !! ** Purpose :   allow the treatment of closed sea outflow grid-points
410      !!                to be the same as river mouth grid-points
411      !!
412      !! ** Method  :   set to 0.5 the upstream mask (upsmsk, see traadv_cen2
413      !!                module) over the closed seas.
414      !!
415      !! ** Action  :   update (p_)upsmsk (set 0.5 over closed seas)
416      !!----------------------------------------------------------------------
417      REAL(wp), DIMENSION(jpi,jpj), INTENT(inout) ::   p_upsmsk   ! upstream mask (upsmsk array)
418      !
419      INTEGER  ::   jc, ji, jj      ! dummy loop indices
420      !!----------------------------------------------------------------------
421      !
422      DO jc = 1, jpncs
423         DO jj = ncsj1(jc), ncsj2(jc)
424            DO ji = ncsi1(jc), ncsi2(jc)
425               p_upsmsk(ji,jj) = 0.5_wp         ! mixed upstream/centered scheme over closed seas
426            END DO
427         END DO
428       END DO 
429       !
430   END SUBROUTINE clo_ups
431   
432     
433   SUBROUTINE clo_bat( pbat, kbat )
434      !!---------------------------------------------------------------------
435      !!                  ***  ROUTINE clo_bat  ***
436      !!                   
437      !! ** Purpose :   suppress closed sea from the domain
438      !!
439      !! ** Method  :   set to 0 the meter and level bathymetry (given in
440      !!                arguments) over the closed seas.
441      !!
442      !! ** Action  :   set pbat=0 and kbat=0 over closed seas
443      !!----------------------------------------------------------------------
444      REAL(wp), DIMENSION(jpi,jpj), INTENT(inout) ::   pbat   ! bathymetry in meters (bathy array)
445      INTEGER , DIMENSION(jpi,jpj), INTENT(inout) ::   kbat   ! bathymetry in levels (mbathy array)
446      !
447      INTEGER  ::   jc, ji, jj      ! dummy loop indices
448      !!----------------------------------------------------------------------
449      !
450      DO jc = 1, jpncs
451         DO jj = ncsj1(jc), ncsj2(jc)
452            DO ji = ncsi1(jc), ncsi2(jc)
453               pbat(ji,jj) = 0._wp   
454               kbat(ji,jj) = 0   
455            END DO
456         END DO
457       END DO 
458       !
459   END SUBROUTINE clo_bat
460
461   !!======================================================================
462END MODULE closea
463
Note: See TracBrowser for help on using the repository browser.