source: branches/UKMO/dev_r5518_FOAMv14_output_heat_fluxes/NEMOGCM/NEMO/OPA_SRC/SBC/sbcblk_core.F90 @ 10879

Last change on this file since 10879 was 10879, checked in by anaguiar, 2 years ago

Changes to reinstate heat fluxes, see https://code.metoffice.gov.uk/trac/gmed/ticket/454

File size: 50.6 KB
Line 
1MODULE sbcblk_core
2   !!======================================================================
3   !!                       ***  MODULE  sbcblk_core  ***
4   !! Ocean forcing:  momentum, heat and freshwater flux formulation
5   !!=====================================================================
6   !! History :  1.0  !  2004-08  (U. Schweckendiek)  Original code
7   !!            2.0  !  2005-04  (L. Brodeau, A.M. Treguier) additions:
8   !!                           -  new bulk routine for efficiency
9   !!                           -  WINDS ARE NOW ASSUMED TO BE AT T POINTS in input files !!!!
10   !!                           -  file names and file characteristics in namelist
11   !!                           -  Implement reading of 6-hourly fields
12   !!            3.0  !  2006-06  (G. Madec) sbc rewritting
13   !!             -   !  2006-12  (L. Brodeau) Original code for turb_core_2z
14   !!            3.2  !  2009-04  (B. Lemaire)  Introduce iom_put
15   !!            3.3  !  2010-10  (S. Masson)  add diurnal cycle
16   !!            3.4  !  2011-11  (C. Harris) Fill arrays required by CICE
17   !!            3.7  !  2014-06  (L. Brodeau) simplification and optimization of CORE bulk
18   !!----------------------------------------------------------------------
19
20   !!----------------------------------------------------------------------
21   !!   sbc_blk_core    : bulk formulation as ocean surface boundary condition (forced mode, CORE bulk formulea)
22   !!   blk_oce_core    : computes momentum, heat and freshwater fluxes over ocean
23   !!   blk_ice_core    : computes momentum, heat and freshwater fluxes over ice
24   !!   turb_core_2z    : Computes turbulent transfert coefficients
25   !!   cd_neutral_10m  : Estimate of the neutral drag coefficient at 10m
26   !!   psi_m           : universal profile stability function for momentum
27   !!   psi_h           : universal profile stability function for temperature and humidity
28   !!----------------------------------------------------------------------
29   USE oce             ! ocean dynamics and tracers
30   USE dom_oce         ! ocean space and time domain
31   USE phycst          ! physical constants
32   USE fldread         ! read input fields
33   USE sbc_oce         ! Surface boundary condition: ocean fields
34   USE cyclone         ! Cyclone 10m wind form trac of cyclone centres
35   USE sbcdcy          ! surface boundary condition: diurnal cycle
36   USE iom             ! I/O manager library
37   USE in_out_manager  ! I/O manager
38   USE lib_mpp         ! distribued memory computing library
39   USE wrk_nemo        ! work arrays
40   USE timing          ! Timing
41   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
42   USE prtctl          ! Print control
43   USE sbcwave, ONLY   :  cdn_wave ! wave module
44   USE sbc_ice         ! Surface boundary condition: ice fields
45   USE lib_fortran     ! to use key_nosignedzero
46#if defined key_lim3
47   USE ice, ONLY       : u_ice, v_ice, jpl, pfrld, a_i_b
48   USE limthd_dh       ! for CALL lim_thd_snwblow
49#elif defined key_lim2
50   USE ice_2, ONLY     : u_ice, v_ice
51   USE par_ice_2
52#endif
53
54   IMPLICIT NONE
55   PRIVATE
56
57   PUBLIC   sbc_blk_core         ! routine called in sbcmod module
58#if defined key_lim2 || defined key_lim3
59   PUBLIC   blk_ice_core_tau     ! routine called in sbc_ice_lim module
60   PUBLIC   blk_ice_core_flx     ! routine called in sbc_ice_lim module
61#endif
62   PUBLIC   turb_core_2z         ! routine calles in sbcblk_mfs module
63
64   INTEGER , PARAMETER ::   jpfld   = 9           ! maximum number of files to read
65   INTEGER , PARAMETER ::   jp_wndi = 1           ! index of 10m wind velocity (i-component) (m/s)    at T-point
66   INTEGER , PARAMETER ::   jp_wndj = 2           ! index of 10m wind velocity (j-component) (m/s)    at T-point
67   INTEGER , PARAMETER ::   jp_humi = 3           ! index of specific humidity               ( % )
68   INTEGER , PARAMETER ::   jp_qsr  = 4           ! index of solar heat                      (W/m2)
69   INTEGER , PARAMETER ::   jp_qlw  = 5           ! index of Long wave                       (W/m2)
70   INTEGER , PARAMETER ::   jp_tair = 6           ! index of 10m air temperature             (Kelvin)
71   INTEGER , PARAMETER ::   jp_prec = 7           ! index of total precipitation (rain+snow) (Kg/m2/s)
72   INTEGER , PARAMETER ::   jp_snow = 8           ! index of snow (solid prcipitation)       (kg/m2/s)
73   INTEGER , PARAMETER ::   jp_tdif = 9           ! index of tau diff associated to HF tau   (N/m2)   at T-point
74
75   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf   ! structure of input fields (file informations, fields read)
76
77   !                                             !!! CORE bulk parameters
78   REAL(wp), PARAMETER ::   rhoa =    1.22        ! air density
79   REAL(wp), PARAMETER ::   cpa  = 1000.5         ! specific heat of air
80   REAL(wp), PARAMETER ::   Lv   =    2.5e6       ! latent heat of vaporization
81   REAL(wp), PARAMETER ::   Ls   =    2.839e6     ! latent heat of sublimation
82   REAL(wp), PARAMETER ::   Stef =    5.67e-8     ! Stefan Boltzmann constant
83   REAL(wp), PARAMETER ::   Cice =    1.4e-3      ! iovi 1.63e-3     ! transfer coefficient over ice
84   REAL(wp), PARAMETER ::   albo =    0.066       ! ocean albedo assumed to be constant
85
86   !                                  !!* Namelist namsbc_core : CORE bulk parameters
87   LOGICAL  ::   ln_taudif   ! logical flag to use the "mean of stress module - module of mean stress" data
88   REAL(wp) ::   rn_pfac     ! multiplication factor for precipitation
89   REAL(wp) ::   rn_efac     ! multiplication factor for evaporation (clem)
90   REAL(wp) ::   rn_vfac     ! multiplication factor for ice/ocean velocity in the calculation of wind stress (clem)
91   REAL(wp) ::   rn_zqt      ! z(q,t) : height of humidity and temperature measurements
92   REAL(wp) ::   rn_zu       ! z(u)   : height of wind measurements
93   REAL(wp), PUBLIC :: rn_sfac ! multiplication factor for snow precipitation over sea-ice
94
95   !! * Substitutions
96#  include "domzgr_substitute.h90"
97#  include "vectopt_loop_substitute.h90"
98   !!----------------------------------------------------------------------
99   !! NEMO/OPA 3.7 , NEMO-consortium (2014)
100   !! $Id$
101   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
102   !!----------------------------------------------------------------------
103CONTAINS
104
105   SUBROUTINE sbc_blk_core( kt )
106      !!---------------------------------------------------------------------
107      !!                    ***  ROUTINE sbc_blk_core  ***
108      !!
109      !! ** Purpose :   provide at each time step the surface ocean fluxes
110      !!      (momentum, heat, freshwater and runoff)
111      !!
112      !! ** Method  : (1) READ each fluxes in NetCDF files:
113      !!      the 10m wind velocity (i-component) (m/s)    at T-point
114      !!      the 10m wind velocity (j-component) (m/s)    at T-point
115      !!      the 10m or 2m specific humidity     ( % )
116      !!      the solar heat                      (W/m2)
117      !!      the Long wave                       (W/m2)
118      !!      the 10m or 2m air temperature       (Kelvin)
119      !!      the total precipitation (rain+snow) (Kg/m2/s)
120      !!      the snow (solid prcipitation)       (kg/m2/s)
121      !!      the tau diff associated to HF tau   (N/m2)   at T-point   (ln_taudif=T)
122      !!              (2) CALL blk_oce_core
123      !!
124      !!      C A U T I O N : never mask the surface stress fields
125      !!                      the stress is assumed to be in the (i,j) mesh referential
126      !!
127      !! ** Action  :   defined at each time-step at the air-sea interface
128      !!              - utau, vtau  i- and j-component of the wind stress
129      !!              - taum        wind stress module at T-point
130      !!              - wndm        wind speed  module at T-point over free ocean or leads in presence of sea-ice
131      !!              - qns, qsr    non-solar and solar heat fluxes
132      !!              - emp         upward mass flux (evapo. - precip.)
133      !!              - sfx         salt flux due to freezing/melting (non-zero only if ice is present)
134      !!                            (set in limsbc(_2).F90)
135      !!
136      !! ** References :   Large & Yeager, 2004 / Large & Yeager, 2008
137      !!                   Brodeau et al. Ocean Modelling 2010
138      !!----------------------------------------------------------------------
139      INTEGER, INTENT(in) ::   kt   ! ocean time step
140      !
141      INTEGER  ::   ierror   ! return error code
142      INTEGER  ::   ifpr     ! dummy loop indice
143      INTEGER  ::   jfld     ! dummy loop arguments
144      INTEGER  ::   ios      ! Local integer output status for namelist read
145      !
146      CHARACTER(len=100) ::  cn_dir   !   Root directory for location of core files
147      TYPE(FLD_N), DIMENSION(jpfld) ::   slf_i     ! array of namelist informations on the fields to read
148      TYPE(FLD_N) ::   sn_wndi, sn_wndj, sn_humi, sn_qsr       ! informations about the fields to be read
149      TYPE(FLD_N) ::   sn_qlw , sn_tair, sn_prec, sn_snow      !   "                                 "
150      TYPE(FLD_N) ::   sn_tdif                                 !   "                                 "
151      NAMELIST/namsbc_core/ cn_dir , ln_taudif, rn_pfac, rn_efac, rn_vfac,  &
152         &                  sn_wndi, sn_wndj, sn_humi  , sn_qsr ,           &
153         &                  sn_qlw , sn_tair, sn_prec  , sn_snow,           &
154         &                  sn_tdif, rn_zqt,  rn_zu, rn_sfac
155      !!---------------------------------------------------------------------
156      !
157      !                                         ! ====================== !
158      IF( kt == nit000 ) THEN                   !  First call kt=nit000  !
159         !                                      ! ====================== !
160         !
161         rn_sfac = 1._wp       ! Default to one if missing from namelist
162         REWIND( numnam_ref )              ! Namelist namsbc_core in reference namelist : CORE bulk parameters
163         READ  ( numnam_ref, namsbc_core, IOSTAT = ios, ERR = 901)
164901      IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_core in reference namelist', lwp )
165         !
166         REWIND( numnam_cfg )              ! Namelist namsbc_core in configuration namelist : CORE bulk parameters
167         READ  ( numnam_cfg, namsbc_core, IOSTAT = ios, ERR = 902 )
168902      IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_core in configuration namelist', lwp )
169
170         IF(lwm) WRITE( numond, namsbc_core )
171         !                                         ! check: do we plan to use ln_dm2dc with non-daily forcing?
172         IF( ln_dm2dc .AND. sn_qsr%nfreqh /= 24 )   &
173            &   CALL ctl_stop( 'sbc_blk_core: ln_dm2dc can be activated only with daily short-wave forcing' )
174         IF( ln_dm2dc .AND. sn_qsr%ln_tint ) THEN
175            CALL ctl_warn( 'sbc_blk_core: ln_dm2dc is taking care of the temporal interpolation of daily qsr',   &
176               &         '              ==> We force time interpolation = .false. for qsr' )
177            sn_qsr%ln_tint = .false.
178         ENDIF
179         !                                         ! store namelist information in an array
180         slf_i(jp_wndi) = sn_wndi   ;   slf_i(jp_wndj) = sn_wndj
181         slf_i(jp_qsr ) = sn_qsr    ;   slf_i(jp_qlw ) = sn_qlw
182         slf_i(jp_tair) = sn_tair   ;   slf_i(jp_humi) = sn_humi
183         slf_i(jp_prec) = sn_prec   ;   slf_i(jp_snow) = sn_snow
184         slf_i(jp_tdif) = sn_tdif
185         !
186         lhftau = ln_taudif                        ! do we use HF tau information?
187         jfld = jpfld - COUNT( (/.NOT. lhftau/) )
188         !
189         ALLOCATE( sf(jfld), STAT=ierror )         ! set sf structure
190         IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_blk_core: unable to allocate sf structure' )
191         DO ifpr= 1, jfld
192            ALLOCATE( sf(ifpr)%fnow(jpi,jpj,1) )
193            IF( slf_i(ifpr)%ln_tint )   ALLOCATE( sf(ifpr)%fdta(jpi,jpj,1,2) )
194         END DO
195         !                                         ! fill sf with slf_i and control print
196         CALL fld_fill( sf, slf_i, cn_dir, 'sbc_blk_core', 'flux formulation for ocean surface boundary condition', 'namsbc_core' )
197         !
198         sfx(:,:) = 0._wp                          ! salt flux; zero unless ice is present (computed in limsbc(_2).F90)
199         !
200      ENDIF
201
202      CALL fld_read( kt, nn_fsbc, sf )             ! input fields provided at the current time-step
203
204      !                                            ! compute the surface ocean fluxes using CORE bulk formulea
205      IF( MOD( kt - 1, nn_fsbc ) == 0 )   CALL blk_oce_core( kt, sf, sst_m, ssu_m, ssv_m )
206
207#if defined key_cice
208      IF( MOD( kt - 1, nn_fsbc ) == 0 )   THEN
209         qlw_ice(:,:,1)   = sf(jp_qlw)%fnow(:,:,1) 
210         IF( ln_dm2dc ) THEN ; qsr_ice(:,:,1) = sbc_dcy( sf(jp_qsr)%fnow(:,:,1) )
211         ELSE                ; qsr_ice(:,:,1) =          sf(jp_qsr)%fnow(:,:,1)
212         ENDIF
213         tatm_ice(:,:)    = sf(jp_tair)%fnow(:,:,1)         
214         qatm_ice(:,:)    = sf(jp_humi)%fnow(:,:,1)
215         tprecip(:,:)     = sf(jp_prec)%fnow(:,:,1) * rn_pfac
216         sprecip(:,:)     = sf(jp_snow)%fnow(:,:,1) * rn_pfac
217         wndi_ice(:,:)    = sf(jp_wndi)%fnow(:,:,1)
218         wndj_ice(:,:)    = sf(jp_wndj)%fnow(:,:,1)
219      ENDIF
220#endif
221      !
222   END SUBROUTINE sbc_blk_core
223   
224   
225   SUBROUTINE blk_oce_core( kt, sf, pst, pu, pv )
226      !!---------------------------------------------------------------------
227      !!                     ***  ROUTINE blk_core  ***
228      !!
229      !! ** Purpose :   provide the momentum, heat and freshwater fluxes at
230      !!      the ocean surface at each time step
231      !!
232      !! ** Method  :   CORE bulk formulea for the ocean using atmospheric
233      !!      fields read in sbc_read
234      !!
235      !! ** Outputs : - utau    : i-component of the stress at U-point  (N/m2)
236      !!              - vtau    : j-component of the stress at V-point  (N/m2)
237      !!              - taum    : Wind stress module at T-point         (N/m2)
238      !!              - wndm    : Wind speed module at T-point          (m/s)
239      !!              - qsr     : Solar heat flux over the ocean        (W/m2)
240      !!              - qns     : Non Solar heat flux over the ocean    (W/m2)
241      !!              - emp     : evaporation minus precipitation       (kg/m2/s)
242      !!
243      !!  ** Nota  :   sf has to be a dummy argument for AGRIF on NEC
244      !!---------------------------------------------------------------------
245      INTEGER  , INTENT(in   )                 ::   kt    ! time step index
246      TYPE(fld), INTENT(inout), DIMENSION(:)   ::   sf    ! input data
247      REAL(wp) , INTENT(in)   , DIMENSION(:,:) ::   pst   ! surface temperature                      [Celcius]
248      REAL(wp) , INTENT(in)   , DIMENSION(:,:) ::   pu    ! surface current at U-point (i-component) [m/s]
249      REAL(wp) , INTENT(in)   , DIMENSION(:,:) ::   pv    ! surface current at V-point (j-component) [m/s]
250      !
251      INTEGER  ::   ji, jj               ! dummy loop indices
252      REAL(wp) ::   zcoef_qsatw, zztmp   ! local variable
253      REAL(wp), DIMENSION(:,:), POINTER ::   zwnd_i, zwnd_j    ! wind speed components at T-point
254      REAL(wp), DIMENSION(:,:), POINTER ::   zqsatw            ! specific humidity at pst
255      REAL(wp), DIMENSION(:,:), POINTER ::   zevap             ! evaporation
256      REAL(wp), DIMENSION(:,:), POINTER ::   Cd                ! transfer coefficient for momentum      (tau)
257      REAL(wp), DIMENSION(:,:), POINTER ::   Ch                ! transfer coefficient for sensible heat (Q_sens)
258      REAL(wp), DIMENSION(:,:), POINTER ::   Ce                ! tansfert coefficient for evaporation   (Q_lat)
259      REAL(wp), DIMENSION(:,:), POINTER ::   zst               ! surface temperature in Kelvin
260      REAL(wp), DIMENSION(:,:), POINTER ::   zt_zu             ! air temperature at wind speed height
261      REAL(wp), DIMENSION(:,:), POINTER ::   zq_zu             ! air spec. hum.  at wind speed height
262      !!---------------------------------------------------------------------
263      !
264      IF( nn_timing == 1 )  CALL timing_start('blk_oce_core')
265      !
266      CALL wrk_alloc( jpi,jpj, zwnd_i, zwnd_j, zqsatw, zevap )
267      CALL wrk_alloc( jpi,jpj, Cd, Ch, Ce, zst, zt_zu, zq_zu )
268      !
269      ! local scalars ( place there for vector optimisation purposes)
270      zcoef_qsatw = 0.98 * 640380. / rhoa
271     
272      zst(:,:) = pst(:,:) + rt0      ! convert SST from Celcius to Kelvin (and set minimum value far above 0 K)
273
274      ! ----------------------------------------------------------------------------- !
275      !      0   Wind components and module at T-point relative to the moving ocean   !
276      ! ----------------------------------------------------------------------------- !
277
278      ! ... components ( U10m - U_oce ) at T-point (unmasked)
279      zwnd_i(:,:) = 0.e0 
280      zwnd_j(:,:) = 0.e0
281#if defined key_cyclone
282      CALL wnd_cyc( kt, zwnd_i, zwnd_j )    ! add analytical tropical cyclone (Vincent et al. JGR 2012)
283      DO jj = 2, jpjm1
284         DO ji = fs_2, fs_jpim1   ! vect. opt.
285            sf(jp_wndi)%fnow(ji,jj,1) = sf(jp_wndi)%fnow(ji,jj,1) + zwnd_i(ji,jj)
286            sf(jp_wndj)%fnow(ji,jj,1) = sf(jp_wndj)%fnow(ji,jj,1) + zwnd_j(ji,jj)
287         END DO
288      END DO
289#endif
290      DO jj = 2, jpjm1
291         DO ji = fs_2, fs_jpim1   ! vect. opt.
292            zwnd_i(ji,jj) = (  sf(jp_wndi)%fnow(ji,jj,1) - rn_vfac * 0.5 * ( pu(ji-1,jj  ) + pu(ji,jj) )  )
293            zwnd_j(ji,jj) = (  sf(jp_wndj)%fnow(ji,jj,1) - rn_vfac * 0.5 * ( pv(ji  ,jj-1) + pv(ji,jj) )  )
294         END DO
295      END DO
296      CALL lbc_lnk( zwnd_i(:,:) , 'T', -1. )
297      CALL lbc_lnk( zwnd_j(:,:) , 'T', -1. )
298      ! ... scalar wind ( = | U10m - U_oce | ) at T-point (masked)
299      wndm(:,:) = SQRT(  zwnd_i(:,:) * zwnd_i(:,:)   &
300         &             + zwnd_j(:,:) * zwnd_j(:,:)  ) * tmask(:,:,1)
301
302      ! ----------------------------------------------------------------------------- !
303      !      I   Radiative FLUXES                                                     !
304      ! ----------------------------------------------------------------------------- !
305
306      ! ocean albedo assumed to be constant + modify now Qsr to include the diurnal cycle                    ! Short Wave
307      zztmp = 1. - albo
308      IF( ln_dm2dc ) THEN   ;   qsr(:,:) = zztmp * sbc_dcy( sf(jp_qsr)%fnow(:,:,1) ) * tmask(:,:,1)
309      ELSE                  ;   qsr(:,:) = zztmp *          sf(jp_qsr)%fnow(:,:,1)   * tmask(:,:,1)
310      ENDIF
311
312      qlw(:,:) = (  sf(jp_qlw)%fnow(:,:,1) - Stef * zst(:,:)*zst(:,:)*zst(:,:)*zst(:,:)  ) * tmask(:,:,1)   ! Long  Wave
313      ! ----------------------------------------------------------------------------- !
314      !     II    Turbulent FLUXES                                                    !
315      ! ----------------------------------------------------------------------------- !
316
317      ! ... specific humidity at SST and IST
318      zqsatw(:,:) = zcoef_qsatw * EXP( -5107.4 / zst(:,:) )
319
320      ! ... NCAR Bulk formulae, computation of Cd, Ch, Ce at T-point :
321      CALL turb_core_2z( rn_zqt, rn_zu, zst, sf(jp_tair)%fnow, zqsatw, sf(jp_humi)%fnow, wndm,   &
322         &               Cd, Ch, Ce, zt_zu, zq_zu )
323   
324      ! ... tau module, i and j component
325      DO jj = 1, jpj
326         DO ji = 1, jpi
327            zztmp = rhoa * wndm(ji,jj) * Cd(ji,jj)
328            taum  (ji,jj) = zztmp * wndm  (ji,jj)
329            zwnd_i(ji,jj) = zztmp * zwnd_i(ji,jj)
330            zwnd_j(ji,jj) = zztmp * zwnd_j(ji,jj)
331         END DO
332      END DO
333
334      ! ... add the HF tau contribution to the wind stress module?
335      IF( lhftau ) THEN
336         taum(:,:) = taum(:,:) + sf(jp_tdif)%fnow(:,:,1)
337      ENDIF
338      CALL iom_put( "taum_oce", taum )   ! output wind stress module
339
340      ! ... utau, vtau at U- and V_points, resp.
341      !     Note the use of 0.5*(2-umask) in order to unmask the stress along coastlines
342      !     Note the use of MAX(tmask(i,j),tmask(i+1,j) is to mask tau over ice shelves
343      DO jj = 1, jpjm1
344         DO ji = 1, fs_jpim1
345            utau(ji,jj) = 0.5 * ( 2. - umask(ji,jj,1) ) * ( zwnd_i(ji,jj) + zwnd_i(ji+1,jj  ) ) &
346               &          * MAX(tmask(ji,jj,1),tmask(ji+1,jj,1))
347            vtau(ji,jj) = 0.5 * ( 2. - vmask(ji,jj,1) ) * ( zwnd_j(ji,jj) + zwnd_j(ji  ,jj+1) ) &
348               &          * MAX(tmask(ji,jj,1),tmask(ji,jj+1,1))
349         END DO
350      END DO
351      CALL lbc_lnk( utau(:,:), 'U', -1. )
352      CALL lbc_lnk( vtau(:,:), 'V', -1. )
353
354   
355      !  Turbulent fluxes over ocean
356      ! -----------------------------
357      IF( ABS( rn_zu - rn_zqt) < 0.01_wp ) THEN
358         !! q_air and t_air are (or "are almost") given at 10m (wind reference height)
359         zevap(:,:) = rn_efac*MAX( 0._wp,     rhoa*Ce(:,:)*( zqsatw(:,:) - sf(jp_humi)%fnow(:,:,1) )*wndm(:,:) ) ! Evaporation
360         qsb (:,:) =                     cpa*rhoa*Ch(:,:)*( zst   (:,:) - sf(jp_tair)%fnow(:,:,1) )*wndm(:,:)   ! Sensible Heat
361      ELSE
362         !! q_air and t_air are not given at 10m (wind reference height)
363         ! Values of temp. and hum. adjusted to height of wind during bulk algorithm iteration must be used!!!
364         zevap(:,:) = rn_efac*MAX( 0._wp,     rhoa*Ce(:,:)*( zqsatw(:,:) - zq_zu(:,:) )*wndm(:,:) )   ! Evaporation
365         qsb (:,:) =                     cpa*rhoa*Ch(:,:)*( zst   (:,:) - zt_zu(:,:) )*wndm(:,:)     ! Sensible Heat
366      ENDIF
367      qla (:,:) = Lv * zevap(:,:)                                                              ! Latent Heat
368
369      IF(ln_ctl) THEN
370         CALL prt_ctl( tab2d_1=qla  , clinfo1=' blk_oce_core: qla   : ', tab2d_2=Ce , clinfo2=' Ce  : ' )
371         CALL prt_ctl( tab2d_1=qsb  , clinfo1=' blk_oce_core: qsb   : ', tab2d_2=Ch , clinfo2=' Ch  : ' )
372         CALL prt_ctl( tab2d_1=qlw  , clinfo1=' blk_oce_core: qlw   : ', tab2d_2=qsr, clinfo2=' qsr : ' )
373         CALL prt_ctl( tab2d_1=zqsatw, clinfo1=' blk_oce_core: zqsatw : ', tab2d_2=zst, clinfo2=' zst : ' )
374         CALL prt_ctl( tab2d_1=utau  , clinfo1=' blk_oce_core: utau   : ', mask1=umask,   &
375            &          tab2d_2=vtau  , clinfo2=              ' vtau : '  , mask2=vmask )
376         CALL prt_ctl( tab2d_1=wndm  , clinfo1=' blk_oce_core: wndm   : ')
377         CALL prt_ctl( tab2d_1=zst   , clinfo1=' blk_oce_core: zst    : ')
378      ENDIF
379       
380      ! ----------------------------------------------------------------------------- !
381      !     III    Total FLUXES                                                       !
382      ! ----------------------------------------------------------------------------- !
383      !
384      emp (:,:) = (  zevap(:,:)                                          &   ! mass flux (evap. - precip.)
385         &         - sf(jp_prec)%fnow(:,:,1) * rn_pfac  ) * tmask(:,:,1)
386      !
387      qns(:,:) = qlw(:,:) - qsb(:,:) - qla(:,:)                                   &   ! Downward Non Solar
388         &     - sf(jp_snow)%fnow(:,:,1) * rn_pfac * lfus                         &   ! remove latent melting heat for solid precip
389         &     - zevap(:,:) * pst(:,:) * rcp                                      &   ! remove evap heat content at SST
390         &     + ( sf(jp_prec)%fnow(:,:,1) - sf(jp_snow)%fnow(:,:,1) ) * rn_pfac  &   ! add liquid precip heat content at Tair
391         &     * ( sf(jp_tair)%fnow(:,:,1) - rt0 ) * rcp                          &
392         &     + sf(jp_snow)%fnow(:,:,1) * rn_pfac                                &   ! add solid  precip heat content at min(Tair,Tsnow)
393         &     * ( MIN( sf(jp_tair)%fnow(:,:,1), rt0_snow ) - rt0 ) * cpic * tmask(:,:,1)
394      !
395#if defined key_lim3
396      qns_oce(:,:) = qlw(:,:) - qsb(:,:) - qla(:,:)                                ! non solar without emp (only needed by LIM3)
397      qsr_oce(:,:) = qsr(:,:)
398#endif
399      !
400      IF ( nn_ice == 0 ) THEN
401          CALL iom_put( "qlw_oce" ,   qlw )                  ! output downward longwave heat over the ocean
402          CALL iom_put( "qsb_oce" , - qsb )                  ! output downward sensible heat over the ocean
403          CALL iom_put( "qla_oce" , - qla )                  ! output downward latent   heat over the ocean
404          CALL iom_put( "qemp_oce",   qns-qlw+qsb+qla )      ! output downward heat content of E-P over the ocean
405          CALL iom_put( "qns_oce" ,   qns  )                 ! output downward non solar heat over the ocean
406          CALL iom_put( "qsr_oce" ,   qsr  )                 ! output downward solar heat over the ocean
407          CALL iom_put( "qt_oce"  ,   qns+qsr )              ! output total downward heat over the ocean
408          tprecip(:,:) = sf(jp_prec)%fnow(:,:,1) * rn_pfac   ! output total precipitation [kg/m2/s]
409          sprecip(:,:) = sf(jp_snow)%fnow(:,:,1) * rn_pfac   ! output solid precipitation [kg/m2/s]
410          CALL iom_put( 'snowpre', sprecip * 86400. )        ! Snow
411          CALL iom_put( 'precip' , tprecip * 86400. )        ! Total precipitation
412      ENDIF
413      !
414      IF(ln_ctl) THEN
415         CALL prt_ctl(tab2d_1=qsb , clinfo1=' blk_oce_core: qsb   : ', tab2d_2=qlw , clinfo2=' qlw  : ')
416         CALL prt_ctl(tab2d_1=qla , clinfo1=' blk_oce_core: qla   : ', tab2d_2=qsr  , clinfo2=' qsr   : ')
417         CALL prt_ctl(tab2d_1=pst  , clinfo1=' blk_oce_core: pst    : ', tab2d_2=emp  , clinfo2=' emp   : ')
418         CALL prt_ctl(tab2d_1=utau , clinfo1=' blk_oce_core: utau   : ', mask1=umask,   &
419            &         tab2d_2=vtau , clinfo2=              ' vtau  : ' , mask2=vmask )
420      ENDIF
421      !
422      CALL wrk_dealloc( jpi,jpj, zwnd_i, zwnd_j, zqsatw, zevap )
423      CALL wrk_dealloc( jpi,jpj, Cd, Ch, Ce, zst, zt_zu, zq_zu )
424      !
425      IF( nn_timing == 1 )  CALL timing_stop('blk_oce_core')
426      !
427   END SUBROUTINE blk_oce_core
428 
429   
430#if defined key_lim2 || defined key_lim3
431   SUBROUTINE blk_ice_core_tau
432      !!---------------------------------------------------------------------
433      !!                     ***  ROUTINE blk_ice_core_tau  ***
434      !!
435      !! ** Purpose :   provide the surface boundary condition over sea-ice
436      !!
437      !! ** Method  :   compute momentum using CORE bulk
438      !!                formulea, ice variables and read atmospheric fields.
439      !!                NB: ice drag coefficient is assumed to be a constant
440      !!---------------------------------------------------------------------
441      INTEGER  ::   ji, jj    ! dummy loop indices
442      REAL(wp) ::   zcoef_wnorm, zcoef_wnorm2
443      REAL(wp) ::   zwnorm_f, zwndi_f , zwndj_f               ! relative wind module and components at F-point
444      REAL(wp) ::             zwndi_t , zwndj_t               ! relative wind components at T-point
445      !!---------------------------------------------------------------------
446      !
447      IF( nn_timing == 1 )  CALL timing_start('blk_ice_core_tau')
448      !
449      ! local scalars ( place there for vector optimisation purposes)
450      zcoef_wnorm  = rhoa * Cice
451      zcoef_wnorm2 = rhoa * Cice * 0.5
452
453!!gm brutal....
454      utau_ice  (:,:) = 0._wp
455      vtau_ice  (:,:) = 0._wp
456      wndm_ice  (:,:) = 0._wp
457!!gm end
458
459      ! ----------------------------------------------------------------------------- !
460      !    Wind components and module relative to the moving ocean ( U10m - U_ice )   !
461      ! ----------------------------------------------------------------------------- !
462      SELECT CASE( cp_ice_msh )
463      CASE( 'I' )                  ! B-grid ice dynamics :   I-point (i.e. F-point with sea-ice indexation)
464         !                           and scalar wind at T-point ( = | U10m - U_ice | ) (masked)
465         DO jj = 2, jpjm1
466            DO ji = 2, jpim1   ! B grid : NO vector opt
467               ! ... scalar wind at I-point (fld being at T-point)
468               zwndi_f = 0.25 * (  sf(jp_wndi)%fnow(ji-1,jj  ,1) + sf(jp_wndi)%fnow(ji  ,jj  ,1)   &
469                  &              + sf(jp_wndi)%fnow(ji-1,jj-1,1) + sf(jp_wndi)%fnow(ji  ,jj-1,1)  ) - rn_vfac * u_ice(ji,jj)
470               zwndj_f = 0.25 * (  sf(jp_wndj)%fnow(ji-1,jj  ,1) + sf(jp_wndj)%fnow(ji  ,jj  ,1)   &
471                  &              + sf(jp_wndj)%fnow(ji-1,jj-1,1) + sf(jp_wndj)%fnow(ji  ,jj-1,1)  ) - rn_vfac * v_ice(ji,jj)
472               zwnorm_f = zcoef_wnorm * SQRT( zwndi_f * zwndi_f + zwndj_f * zwndj_f )
473               ! ... ice stress at I-point
474               utau_ice(ji,jj) = zwnorm_f * zwndi_f
475               vtau_ice(ji,jj) = zwnorm_f * zwndj_f
476               ! ... scalar wind at T-point (fld being at T-point)
477               zwndi_t = sf(jp_wndi)%fnow(ji,jj,1) - rn_vfac * 0.25 * (  u_ice(ji,jj+1) + u_ice(ji+1,jj+1)   &
478                  &                                                    + u_ice(ji,jj  ) + u_ice(ji+1,jj  )  )
479               zwndj_t = sf(jp_wndj)%fnow(ji,jj,1) - rn_vfac * 0.25 * (  v_ice(ji,jj+1) + v_ice(ji+1,jj+1)   &
480                  &                                                    + v_ice(ji,jj  ) + v_ice(ji+1,jj  )  )
481               wndm_ice(ji,jj)  = SQRT( zwndi_t * zwndi_t + zwndj_t * zwndj_t ) * tmask(ji,jj,1)
482            END DO
483         END DO
484         CALL lbc_lnk( utau_ice, 'I', -1. )
485         CALL lbc_lnk( vtau_ice, 'I', -1. )
486         CALL lbc_lnk( wndm_ice, 'T',  1. )
487         !
488      CASE( 'C' )                  ! C-grid ice dynamics :   U & V-points (same as ocean)
489         DO jj = 2, jpj
490            DO ji = fs_2, jpi   ! vect. opt.
491               zwndi_t = (  sf(jp_wndi)%fnow(ji,jj,1) - rn_vfac * 0.5 * ( u_ice(ji-1,jj  ) + u_ice(ji,jj) )  )
492               zwndj_t = (  sf(jp_wndj)%fnow(ji,jj,1) - rn_vfac * 0.5 * ( v_ice(ji  ,jj-1) + v_ice(ji,jj) )  )
493               wndm_ice(ji,jj) = SQRT( zwndi_t * zwndi_t + zwndj_t * zwndj_t ) * tmask(ji,jj,1)
494            END DO
495         END DO
496         DO jj = 2, jpjm1
497            DO ji = fs_2, fs_jpim1   ! vect. opt.
498               utau_ice(ji,jj) = zcoef_wnorm2 * ( wndm_ice(ji+1,jj  ) + wndm_ice(ji,jj) )                          &
499                  &          * ( 0.5 * (sf(jp_wndi)%fnow(ji+1,jj,1) + sf(jp_wndi)%fnow(ji,jj,1) ) - rn_vfac * u_ice(ji,jj) )
500               vtau_ice(ji,jj) = zcoef_wnorm2 * ( wndm_ice(ji,jj+1  ) + wndm_ice(ji,jj) )                          &
501                  &          * ( 0.5 * (sf(jp_wndj)%fnow(ji,jj+1,1) + sf(jp_wndj)%fnow(ji,jj,1) ) - rn_vfac * v_ice(ji,jj) )
502            END DO
503         END DO
504         CALL lbc_lnk( utau_ice, 'U', -1. )
505         CALL lbc_lnk( vtau_ice, 'V', -1. )
506         CALL lbc_lnk( wndm_ice, 'T',  1. )
507         !
508      END SELECT
509
510      IF(ln_ctl) THEN
511         CALL prt_ctl(tab2d_1=utau_ice  , clinfo1=' blk_ice_core: utau_ice : ', tab2d_2=vtau_ice  , clinfo2=' vtau_ice : ')
512         CALL prt_ctl(tab2d_1=wndm_ice  , clinfo1=' blk_ice_core: wndm_ice : ')
513      ENDIF
514
515      IF( nn_timing == 1 )  CALL timing_stop('blk_ice_core_tau')
516     
517   END SUBROUTINE blk_ice_core_tau
518
519
520   SUBROUTINE blk_ice_core_flx( ptsu, palb )
521      !!---------------------------------------------------------------------
522      !!                     ***  ROUTINE blk_ice_core_flx  ***
523      !!
524      !! ** Purpose :   provide the surface boundary condition over sea-ice
525      !!
526      !! ** Method  :   compute heat and freshwater exchanged
527      !!                between atmosphere and sea-ice using CORE bulk
528      !!                formulea, ice variables and read atmmospheric fields.
529      !!
530      !! caution : the net upward water flux has with mm/day unit
531      !!---------------------------------------------------------------------
532      REAL(wp), DIMENSION(:,:,:), INTENT(in)  ::   ptsu          ! sea ice surface temperature
533      REAL(wp), DIMENSION(:,:,:), INTENT(in)  ::   palb          ! ice albedo (all skies)
534      !!
535      INTEGER  ::   ji, jj, jl    ! dummy loop indices
536      REAL(wp) ::   zst2, zst3
537      REAL(wp) ::   zcoef_dqlw, zcoef_dqla, zcoef_dqsb
538      REAL(wp) ::   zztmp, z1_lsub                               ! temporary variable
539      !!
540      REAL(wp), DIMENSION(:,:,:), POINTER ::   z_qlw             ! long wave heat flux over ice
541      REAL(wp), DIMENSION(:,:,:), POINTER ::   z_qsb             ! sensible  heat flux over ice
542      REAL(wp), DIMENSION(:,:,:), POINTER ::   z_dqlw            ! long wave heat sensitivity over ice
543      REAL(wp), DIMENSION(:,:,:), POINTER ::   z_dqsb            ! sensible  heat sensitivity over ice
544      REAL(wp), DIMENSION(:,:)  , POINTER ::   zevap, zsnw       ! evaporation and snw distribution after wind blowing (LIM3)
545      !!---------------------------------------------------------------------
546      !
547      IF( nn_timing == 1 )  CALL timing_start('blk_ice_core_flx')
548      !
549      CALL wrk_alloc( jpi,jpj,jpl, z_qlw, z_qsb, z_dqlw, z_dqsb ) 
550
551      ! local scalars ( place there for vector optimisation purposes)
552      zcoef_dqlw   = 4.0 * 0.95 * Stef
553      zcoef_dqla   = -Ls * Cice * 11637800. * (-5897.8)
554      zcoef_dqsb   = rhoa * cpa * Cice
555
556      zztmp = 1. / ( 1. - albo )
557      !                                     ! ========================== !
558      DO jl = 1, jpl                        !  Loop over ice categories  !
559         !                                  ! ========================== !
560         DO jj = 1 , jpj
561            DO ji = 1, jpi
562               ! ----------------------------!
563               !      I   Radiative FLUXES   !
564               ! ----------------------------!
565               zst2 = ptsu(ji,jj,jl) * ptsu(ji,jj,jl)
566               zst3 = ptsu(ji,jj,jl) * zst2
567               ! Short Wave (sw)
568               qsr_ice(ji,jj,jl) = zztmp * ( 1. - palb(ji,jj,jl) ) * qsr(ji,jj)
569               ! Long  Wave (lw)
570               z_qlw(ji,jj,jl) = 0.95 * ( sf(jp_qlw)%fnow(ji,jj,1) - Stef * ptsu(ji,jj,jl) * zst3 ) * tmask(ji,jj,1)
571               ! lw sensitivity
572               z_dqlw(ji,jj,jl) = zcoef_dqlw * zst3                                               
573
574               ! ----------------------------!
575               !     II    Turbulent FLUXES  !
576               ! ----------------------------!
577
578               ! ... turbulent heat fluxes
579               ! Sensible Heat
580               z_qsb(ji,jj,jl) = rhoa * cpa * Cice * wndm_ice(ji,jj) * ( ptsu(ji,jj,jl) - sf(jp_tair)%fnow(ji,jj,1) )
581               ! Latent Heat
582               qla_ice(ji,jj,jl) = rn_efac * MAX( 0.e0, rhoa * Ls  * Cice * wndm_ice(ji,jj)   &                           
583                  &                         * (  11637800. * EXP( -5897.8 / ptsu(ji,jj,jl) ) / rhoa - sf(jp_humi)%fnow(ji,jj,1)  ) )
584              ! Latent heat sensitivity for ice (Dqla/Dt)
585               IF( qla_ice(ji,jj,jl) > 0._wp ) THEN
586                  dqla_ice(ji,jj,jl) = rn_efac * zcoef_dqla * wndm_ice(ji,jj) / ( zst2 ) * EXP( -5897.8 / ptsu(ji,jj,jl) )
587               ELSE
588                  dqla_ice(ji,jj,jl) = 0._wp
589               ENDIF
590
591               ! Sensible heat sensitivity (Dqsb_ice/Dtn_ice)
592               z_dqsb(ji,jj,jl) = zcoef_dqsb * wndm_ice(ji,jj)
593
594               ! ----------------------------!
595               !     III    Total FLUXES     !
596               ! ----------------------------!
597               ! Downward Non Solar flux
598               qns_ice (ji,jj,jl) =     z_qlw (ji,jj,jl) - z_qsb (ji,jj,jl) - qla_ice (ji,jj,jl)
599               ! Total non solar heat flux sensitivity for ice
600               dqns_ice(ji,jj,jl) = - ( z_dqlw(ji,jj,jl) + z_dqsb(ji,jj,jl) + dqla_ice(ji,jj,jl) )
601            END DO
602            !
603         END DO
604         !
605      END DO
606      !
607      tprecip(:,:) = sf(jp_prec)%fnow(:,:,1) * rn_pfac      ! total precipitation [kg/m2/s]
608      sprecip(:,:) = sf(jp_snow)%fnow(:,:,1) * rn_pfac      ! solid precipitation [kg/m2/s]
609      CALL iom_put( 'snowpre', sprecip * 86400. )                  ! Snow precipitation
610      CALL iom_put( 'precip' , tprecip * 86400. )                  ! Total precipitation
611
612#if defined  key_lim3
613      CALL wrk_alloc( jpi,jpj, zevap, zsnw ) 
614
615      ! --- evaporation --- !
616      z1_lsub = 1._wp / Lsub
617      evap_ice (:,:,:) = rn_efac * qla_ice (:,:,:) * z1_lsub    ! sublimation
618      devap_ice(:,:,:) = rn_efac * dqla_ice(:,:,:) * z1_lsub    ! d(sublimation)/dT
619      zevap    (:,:)   = rn_efac * ( emp(:,:) + tprecip(:,:) )  ! evaporation over ocean
620
621      ! --- evaporation minus precipitation --- !
622      zsnw(:,:) = 0._wp
623      CALL lim_thd_snwblow( pfrld, zsnw )  ! snow distribution over ice after wind blowing
624      emp_oce(:,:) = pfrld(:,:) * zevap(:,:) - ( tprecip(:,:) - sprecip(:,:) ) - sprecip(:,:) * (1._wp - zsnw )
625      emp_ice(:,:) = SUM( a_i_b(:,:,:) * evap_ice(:,:,:), dim=3 ) - sprecip(:,:) * zsnw
626      emp_tot(:,:) = emp_oce(:,:) + emp_ice(:,:)
627
628      ! --- heat flux associated with emp --- !
629      qemp_oce(:,:) = - pfrld(:,:) * zevap(:,:) * sst_m(:,:) * rcp                               & ! evap at sst
630         &          + ( tprecip(:,:) - sprecip(:,:) ) * ( sf(jp_tair)%fnow(:,:,1) - rt0 ) * rcp  & ! liquid precip at Tair
631         &          +   sprecip(:,:) * ( 1._wp - zsnw ) *                                        & ! solid precip at min(Tair,Tsnow)
632         &              ( ( MIN( sf(jp_tair)%fnow(:,:,1), rt0_snow ) - rt0 ) * cpic * tmask(:,:,1) - lfus )
633      qemp_ice(:,:) =   sprecip(:,:) * zsnw *                                                    & ! solid precip (only)
634         &              ( ( MIN( sf(jp_tair)%fnow(:,:,1), rt0_snow ) - rt0 ) * cpic * tmask(:,:,1) - lfus )
635
636      ! --- total solar and non solar fluxes --- !
637      qns_tot(:,:) = pfrld(:,:) * qns_oce(:,:) + SUM( a_i_b(:,:,:) * qns_ice(:,:,:), dim=3 ) + qemp_ice(:,:) + qemp_oce(:,:)
638      qsr_tot(:,:) = pfrld(:,:) * qsr_oce(:,:) + SUM( a_i_b(:,:,:) * qsr_ice(:,:,:), dim=3 )
639
640      ! --- heat content of precip over ice in J/m3 (to be used in 1D-thermo) --- !
641      qprec_ice(:,:) = rhosn * ( ( MIN( sf(jp_tair)%fnow(:,:,1), rt0_snow ) - rt0 ) * cpic * tmask(:,:,1) - lfus )
642
643      ! --- heat content of evap over ice in W/m2 (to be used in 1D-thermo) --- !
644      DO jl = 1, jpl
645         qevap_ice(:,:,jl) = 0._wp ! should be -evap_ice(:,:,jl)*( ( Tice - rt0 ) * cpic * tmask(:,:,1) )
646                                   ! But we do not have Tice => consider it at 0°C => evap=0
647      END DO
648
649      CALL wrk_dealloc( jpi,jpj, zevap, zsnw ) 
650#endif
651
652      !--------------------------------------------------------------------
653      ! FRACTIONs of net shortwave radiation which is not absorbed in the
654      ! thin surface layer and penetrates inside the ice cover
655      ! ( Maykut and Untersteiner, 1971 ; Ebert and Curry, 1993 )
656      !
657      fr1_i0(:,:) = ( 0.18 * ( 1.0 - cldf_ice ) + 0.35 * cldf_ice )
658      fr2_i0(:,:) = ( 0.82 * ( 1.0 - cldf_ice ) + 0.65 * cldf_ice )
659      !
660      !
661      IF(ln_ctl) THEN
662         CALL prt_ctl(tab3d_1=qla_ice , clinfo1=' blk_ice_core: qla_ice  : ', tab3d_2=z_qsb   , clinfo2=' z_qsb    : ', kdim=jpl)
663         CALL prt_ctl(tab3d_1=z_qlw   , clinfo1=' blk_ice_core: z_qlw    : ', tab3d_2=dqla_ice, clinfo2=' dqla_ice : ', kdim=jpl)
664         CALL prt_ctl(tab3d_1=z_dqsb  , clinfo1=' blk_ice_core: z_dqsb   : ', tab3d_2=z_dqlw  , clinfo2=' z_dqlw   : ', kdim=jpl)
665         CALL prt_ctl(tab3d_1=dqns_ice, clinfo1=' blk_ice_core: dqns_ice : ', tab3d_2=qsr_ice , clinfo2=' qsr_ice  : ', kdim=jpl)
666         CALL prt_ctl(tab3d_1=ptsu    , clinfo1=' blk_ice_core: ptsu     : ', tab3d_2=qns_ice , clinfo2=' qns_ice  : ', kdim=jpl)
667         CALL prt_ctl(tab2d_1=tprecip , clinfo1=' blk_ice_core: tprecip  : ', tab2d_2=sprecip , clinfo2=' sprecip  : ')
668      ENDIF
669
670      CALL wrk_dealloc( jpi,jpj,jpl, z_qlw, z_qsb, z_dqlw, z_dqsb )
671      !
672      IF( nn_timing == 1 )  CALL timing_stop('blk_ice_core_flx')
673     
674   END SUBROUTINE blk_ice_core_flx
675#endif
676
677   SUBROUTINE turb_core_2z( zt, zu, sst, T_zt, q_sat, q_zt, dU,    &
678      &                      Cd, Ch, Ce , T_zu, q_zu )
679      !!----------------------------------------------------------------------
680      !!                      ***  ROUTINE  turb_core  ***
681      !!
682      !! ** Purpose :   Computes turbulent transfert coefficients of surface
683      !!                fluxes according to Large & Yeager (2004) and Large & Yeager (2008)
684      !!                If relevant (zt /= zu), adjust temperature and humidity from height zt to zu
685      !!
686      !! ** Method : Monin Obukhov Similarity Theory
687      !!             + Large & Yeager (2004,2008) closure: CD_n10 = f(U_n10)
688      !!
689      !! ** References :   Large & Yeager, 2004 / Large & Yeager, 2008
690      !!
691      !! ** Last update: Laurent Brodeau, June 2014:
692      !!    - handles both cases zt=zu and zt/=zu
693      !!    - optimized: less 2D arrays allocated and less operations
694      !!    - better first guess of stability by checking air-sea difference of virtual temperature
695      !!       rather than temperature difference only...
696      !!    - added function "cd_neutral_10m" that uses the improved parametrization of
697      !!      Large & Yeager 2008. Drag-coefficient reduction for Cyclone conditions!
698      !!    - using code-wide physical constants defined into "phycst.mod" rather than redifining them
699      !!      => 'vkarmn' and 'grav'
700      !!----------------------------------------------------------------------
701      REAL(wp), INTENT(in   )                     ::   zt       ! height for T_zt and q_zt                   [m]
702      REAL(wp), INTENT(in   )                     ::   zu       ! height for dU                              [m]
703      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj) ::   sst      ! sea surface temperature              [Kelvin]
704      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj) ::   T_zt     ! potential air temperature            [Kelvin]
705      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj) ::   q_sat    ! sea surface specific humidity         [kg/kg]
706      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj) ::   q_zt     ! specific air humidity                 [kg/kg]
707      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj) ::   dU       ! relative wind module at zu            [m/s]
708      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   Cd       ! transfer coefficient for momentum         (tau)
709      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   Ch       ! transfer coefficient for sensible heat (Q_sens)
710      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   Ce       ! transfert coefficient for evaporation   (Q_lat)
711      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   T_zu     ! air temp. shifted at zu                     [K]
712      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   q_zu     ! spec. hum.  shifted at zu               [kg/kg]
713      !
714      INTEGER ::   j_itt
715      INTEGER , PARAMETER ::   nb_itt = 5       ! number of itterations
716      LOGICAL ::   l_zt_equal_zu = .FALSE.      ! if q and t are given at different height than U
717      !
718      REAL(wp), DIMENSION(:,:), POINTER ::   U_zu          ! relative wind at zu                            [m/s]
719      REAL(wp), DIMENSION(:,:), POINTER ::   Ce_n10        ! 10m neutral latent coefficient
720      REAL(wp), DIMENSION(:,:), POINTER ::   Ch_n10        ! 10m neutral sensible coefficient
721      REAL(wp), DIMENSION(:,:), POINTER ::   sqrt_Cd_n10   ! root square of Cd_n10
722      REAL(wp), DIMENSION(:,:), POINTER ::   sqrt_Cd       ! root square of Cd
723      REAL(wp), DIMENSION(:,:), POINTER ::   zeta_u        ! stability parameter at height zu
724      REAL(wp), DIMENSION(:,:), POINTER ::   zeta_t        ! stability parameter at height zt
725      REAL(wp), DIMENSION(:,:), POINTER ::   zpsi_h_u, zpsi_m_u
726      REAL(wp), DIMENSION(:,:), POINTER ::   ztmp0, ztmp1, ztmp2
727      REAL(wp), DIMENSION(:,:), POINTER ::   stab          ! 1st stability test integer
728      !!----------------------------------------------------------------------
729
730      IF( nn_timing == 1 )  CALL timing_start('turb_core_2z')
731   
732      CALL wrk_alloc( jpi,jpj, U_zu, Ce_n10, Ch_n10, sqrt_Cd_n10, sqrt_Cd )
733      CALL wrk_alloc( jpi,jpj, zeta_u, stab )
734      CALL wrk_alloc( jpi,jpj, zpsi_h_u, zpsi_m_u, ztmp0, ztmp1, ztmp2 )
735
736      l_zt_equal_zu = .FALSE.
737      IF( ABS(zu - zt) < 0.01 ) l_zt_equal_zu = .TRUE.    ! testing "zu == zt" is risky with double precision
738
739      IF( .NOT. l_zt_equal_zu )   CALL wrk_alloc( jpi,jpj, zeta_t )
740
741      U_zu = MAX( 0.5 , dU )   !  relative wind speed at zu (normally 10m), we don't want to fall under 0.5 m/s
742
743      !! First guess of stability:
744      ztmp0 = T_zt*(1. + 0.608*q_zt) - sst*(1. + 0.608*q_sat) ! air-sea difference of virtual pot. temp. at zt
745      stab  = 0.5 + sign(0.5,ztmp0)                           ! stab = 1 if dTv > 0  => STABLE, 0 if unstable
746
747      !! Neutral coefficients at 10m:
748      IF( ln_cdgw ) THEN      ! wave drag case
749         cdn_wave(:,:) = cdn_wave(:,:) + rsmall * ( 1._wp - tmask(:,:,1) )
750         ztmp0   (:,:) = cdn_wave(:,:)
751      ELSE
752         ztmp0 = cd_neutral_10m( U_zu )
753      ENDIF
754      sqrt_Cd_n10 = SQRT( ztmp0 )
755      Ce_n10  = 1.e-3*( 34.6 * sqrt_Cd_n10 )
756      Ch_n10  = 1.e-3*sqrt_Cd_n10*(18.*stab + 32.7*(1. - stab))
757   
758      !! Initializing transf. coeff. with their first guess neutral equivalents :
759      Cd = ztmp0   ;   Ce = Ce_n10   ;   Ch = Ch_n10   ;   sqrt_Cd = sqrt_Cd_n10
760
761      !! Initializing values at z_u with z_t values:
762      T_zu = T_zt   ;   q_zu = q_zt
763
764      !!  * Now starting iteration loop
765      DO j_itt=1, nb_itt
766         !
767         ztmp1 = T_zu - sst   ! Updating air/sea differences
768         ztmp2 = q_zu - q_sat 
769
770         ! Updating turbulent scales :   (L&Y 2004 eq. (7))
771         ztmp1  = Ch/sqrt_Cd*ztmp1    ! theta*
772         ztmp2  = Ce/sqrt_Cd*ztmp2    ! q*
773       
774         ztmp0 = T_zu*(1. + 0.608*q_zu) ! virtual potential temperature at zu
775
776         ! Estimate the inverse of Monin-Obukov length (1/L) at height zu:
777         ztmp0 =  (vkarmn*grav/ztmp0*(ztmp1*(1.+0.608*q_zu) + 0.608*T_zu*ztmp2)) / (Cd*U_zu*U_zu) 
778         !                                                                     ( Cd*U_zu*U_zu is U*^2 at zu)
779
780         !! Stability parameters :
781         zeta_u   = zu*ztmp0   ;  zeta_u = sign( min(abs(zeta_u),10.0), zeta_u )
782         zpsi_h_u = psi_h( zeta_u )
783         zpsi_m_u = psi_m( zeta_u )
784       
785         !! Shifting temperature and humidity at zu (L&Y 2004 eq. (9b-9c))
786         IF ( .NOT. l_zt_equal_zu ) THEN
787            zeta_t = zt*ztmp0 ;  zeta_t = sign( min(abs(zeta_t),10.0), zeta_t )
788            stab = LOG(zu/zt) - zpsi_h_u + psi_h(zeta_t)  ! stab just used as temp array!!!
789            T_zu = T_zt + ztmp1/vkarmn*stab    ! ztmp1 is still theta*
790            q_zu = q_zt + ztmp2/vkarmn*stab    ! ztmp2 is still q*
791            q_zu = max(0., q_zu)
792         END IF
793       
794         IF( ln_cdgw ) THEN      ! surface wave case
795            sqrt_Cd = vkarmn / ( vkarmn / sqrt_Cd_n10 - zpsi_m_u ) 
796            Cd      = sqrt_Cd * sqrt_Cd
797         ELSE
798           ! Update neutral wind speed at 10m and neutral Cd at 10m (L&Y 2004 eq. 9a)...
799           !   In very rare low-wind conditions, the old way of estimating the
800           !   neutral wind speed at 10m leads to a negative value that causes the code
801           !   to crash. To prevent this a threshold of 0.25m/s is imposed.
802           ztmp0 = MAX( 0.25 , U_zu/(1. + sqrt_Cd_n10/vkarmn*(LOG(zu/10.) - zpsi_m_u)) ) !  U_n10
803           ztmp0 = cd_neutral_10m(ztmp0)                                                 ! Cd_n10
804           sqrt_Cd_n10 = sqrt(ztmp0)
805       
806           Ce_n10  = 1.e-3 * (34.6 * sqrt_Cd_n10)                     ! L&Y 2004 eq. (6b)
807           stab    = 0.5 + sign(0.5,zeta_u)                           ! update stability
808           Ch_n10  = 1.e-3*sqrt_Cd_n10*(18.*stab + 32.7*(1. - stab))  ! L&Y 2004 eq. (6c-6d)
809
810           !! Update of transfer coefficients:
811           ztmp1 = 1. + sqrt_Cd_n10/vkarmn*(LOG(zu/10.) - zpsi_m_u)   ! L&Y 2004 eq. (10a)
812           Cd      = ztmp0 / ( ztmp1*ztmp1 )   
813           sqrt_Cd = SQRT( Cd )
814         ENDIF
815         !
816         ztmp0 = (LOG(zu/10.) - zpsi_h_u) / vkarmn / sqrt_Cd_n10
817         ztmp2 = sqrt_Cd / sqrt_Cd_n10
818         ztmp1 = 1. + Ch_n10*ztmp0               
819         Ch  = Ch_n10*ztmp2 / ztmp1  ! L&Y 2004 eq. (10b)
820         !
821         ztmp1 = 1. + Ce_n10*ztmp0               
822         Ce  = Ce_n10*ztmp2 / ztmp1  ! L&Y 2004 eq. (10c)
823         !
824      END DO
825
826      CALL wrk_dealloc( jpi,jpj, U_zu, Ce_n10, Ch_n10, sqrt_Cd_n10, sqrt_Cd )
827      CALL wrk_dealloc( jpi,jpj, zeta_u, stab )
828      CALL wrk_dealloc( jpi,jpj, zpsi_h_u, zpsi_m_u, ztmp0, ztmp1, ztmp2 )
829
830      IF( .NOT. l_zt_equal_zu ) CALL wrk_dealloc( jpi,jpj, zeta_t )
831
832      IF( nn_timing == 1 )  CALL timing_stop('turb_core_2z')
833      !
834   END SUBROUTINE turb_core_2z
835
836
837   FUNCTION cd_neutral_10m( zw10 )
838      !!----------------------------------------------------------------------
839      !! Estimate of the neutral drag coefficient at 10m as a function
840      !! of neutral wind  speed at 10m
841      !!
842      !! Origin: Large & Yeager 2008 eq.(11a) and eq.(11b)
843      !!
844      !! Author: L. Brodeau, june 2014
845      !!----------------------------------------------------------------------   
846      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   zw10           ! scalar wind speed at 10m (m/s)
847      REAL(wp), DIMENSION(jpi,jpj)             ::   cd_neutral_10m
848      !
849      REAL(wp), DIMENSION(:,:), POINTER ::   rgt33
850      !!----------------------------------------------------------------------   
851      !
852      CALL wrk_alloc( jpi,jpj, rgt33 )
853      !
854      !! When wind speed > 33 m/s => Cyclone conditions => special treatment
855      rgt33 = 0.5_wp + SIGN( 0.5_wp, (zw10 - 33._wp) )   ! If zw10 < 33. => 0, else => 1 
856      cd_neutral_10m = 1.e-3 * ( &
857         &       (1._wp - rgt33)*( 2.7_wp/zw10 + 0.142_wp + zw10/13.09_wp - 3.14807E-10*zw10**6) & ! zw10< 33.
858         &      + rgt33         *      2.34   )                                                    ! zw10 >= 33.
859      !
860      CALL wrk_dealloc( jpi,jpj, rgt33)
861      !
862   END FUNCTION cd_neutral_10m
863
864
865   FUNCTION psi_m(pta)   !! Psis, L&Y 2004 eq. (8c), (8d), (8e)
866      !-------------------------------------------------------------------------------
867      ! universal profile stability function for momentum
868      !-------------------------------------------------------------------------------
869      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: pta
870      !
871      REAL(wp), DIMENSION(jpi,jpj)             :: psi_m
872      REAL(wp), DIMENSION(:,:), POINTER        :: X2, X, stabit
873      !-------------------------------------------------------------------------------
874      !
875      CALL wrk_alloc( jpi,jpj, X2, X, stabit )
876      !
877      X2 = SQRT( ABS( 1. - 16.*pta ) )  ;  X2 = MAX( X2 , 1. )   ;   X = SQRT( X2 )
878      stabit = 0.5 + SIGN( 0.5 , pta )
879      psi_m = -5.*pta*stabit  &                                                          ! Stable
880         &    + (1. - stabit)*(2.*LOG((1. + X)*0.5) + LOG((1. + X2)*0.5) - 2.*ATAN(X) + rpi*0.5)  ! Unstable
881      !
882      CALL wrk_dealloc( jpi,jpj, X2, X, stabit )
883      !
884   END FUNCTION psi_m
885
886
887   FUNCTION psi_h( pta )    !! Psis, L&Y 2004 eq. (8c), (8d), (8e)
888      !-------------------------------------------------------------------------------
889      ! universal profile stability function for temperature and humidity
890      !-------------------------------------------------------------------------------
891      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   pta
892      !
893      REAL(wp), DIMENSION(jpi,jpj)             ::   psi_h
894      REAL(wp), DIMENSION(:,:), POINTER        ::   X2, X, stabit
895      !-------------------------------------------------------------------------------
896      !
897      CALL wrk_alloc( jpi,jpj, X2, X, stabit )
898      !
899      X2 = SQRT( ABS( 1. - 16.*pta ) )   ;   X2 = MAX( X2 , 1. )   ;   X = SQRT( X2 )
900      stabit = 0.5 + SIGN( 0.5 , pta )
901      psi_h = -5.*pta*stabit   &                                       ! Stable
902         &    + (1. - stabit)*(2.*LOG( (1. + X2)*0.5 ))                ! Unstable
903      !
904      CALL wrk_dealloc( jpi,jpj, X2, X, stabit )
905      !
906   END FUNCTION psi_h
907
908   !!======================================================================
909END MODULE sbcblk_core
Note: See TracBrowser for help on using the repository browser.