New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traqsr.F90 in branches/UKMO/dev_r5518_GO6_package_FOAMv14/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/UKMO/dev_r5518_GO6_package_FOAMv14/NEMOGCM/NEMO/OPA_SRC/TRA/traqsr.F90 @ 13725

Last change on this file since 13725 was 13725, checked in by dford, 2 years ago

Add two-way NEMO-MEDUSA coupling options, and some extra diagnostics. See Met Office utils ticket 392.

File size: 34.4 KB
Line 
1MODULE traqsr
2   !!======================================================================
3   !!                       ***  MODULE  traqsr  ***
4   !! Ocean physics: solar radiation penetration in the top ocean levels
5   !!======================================================================
6   !! History :  OPA  !  1990-10  (B. Blanke)  Original code
7   !!            7.0  !  1991-11  (G. Madec)
8   !!                 !  1996-01  (G. Madec)  s-coordinates
9   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
10   !!             -   !  2005-11  (G. Madec) zco, zps, sco coordinate
11   !!            3.2  !  2009-04  (G. Madec & NEMO team)
12   !!            3.4  !  2012-05  (C. Rousset) store attenuation coef for use in ice model
13   !!            3.6  !  2015-12  (O. Aumont, J. Jouanno, C. Ethe) use vertical profile of chlorophyll
14   !!----------------------------------------------------------------------
15
16   !!----------------------------------------------------------------------
17   !!   tra_qsr      : trend due to the solar radiation penetration
18   !!   tra_qsr_init : solar radiation penetration initialization
19   !!----------------------------------------------------------------------
20   USE oce             ! ocean dynamics and active tracers
21   USE dom_oce         ! ocean space and time domain
22   USE sbc_oce         ! surface boundary condition: ocean
23   USE trc_oce         ! share SMS/Ocean variables
24   USE trd_oce        ! trends: ocean variables
25   USE trdtra         ! trends manager: tracers
26   USE in_out_manager  ! I/O manager
27   USE phycst          ! physical constants
28   USE prtctl          ! Print control
29   USE iom             ! I/O manager
30   USE fldread         ! read input fields
31   USE restart         ! ocean restart
32   USE lib_mpp         ! MPP library
33   USE wrk_nemo       ! Memory Allocation
34   USE timing         ! Timing
35   USE stopack
36#if defined key_medusa
37   USE trc, ONLY: trn      ! MEDUSA variables
38   USE par_medusa, ONLY: & ! MEDUSA parameters
39      & jpchn, &
40      & jpchd
41#elif defined key_hadocc
42   USE trc, ONLY: &        ! HadOCC chlorophyll
43      & HADOCC_CHL
44#endif
45
46   IMPLICIT NONE
47   PRIVATE
48
49   PUBLIC   tra_qsr       ! routine called by step.F90 (ln_traqsr=T)
50   PUBLIC   tra_qsr_init  ! routine called by nemogcm.F90
51
52   !                                 !!* Namelist namtra_qsr: penetrative solar radiation
53   LOGICAL , PUBLIC ::   ln_traqsr    !: light absorption (qsr) flag
54   LOGICAL , PUBLIC ::   ln_qsr_rgb   !: Red-Green-Blue light absorption flag
55   LOGICAL , PUBLIC ::   ln_qsr_2bd   !: 2 band         light absorption flag
56   LOGICAL , PUBLIC ::   ln_qsr_bio   !: bio-model      light absorption flag
57   LOGICAL , PUBLIC ::   ln_qsr_ice   !: light penetration for ice-model LIM3 (clem)
58   INTEGER , PUBLIC ::   nn_chldta    !: use Chlorophyll data (=1) or not (=0)
59   REAL(wp), PUBLIC ::   rn_abs       !: fraction absorbed in the very near surface (RGB & 2 bands)
60   REAL(wp), PUBLIC ::   rn_si0       !: very near surface depth of extinction      (RGB & 2 bands)
61   REAL(wp), PUBLIC ::   rn_si1       !: deepest depth of extinction (water type I)       (2 bands)
62
63   ! Module variables
64   REAL(wp), ALLOCATABLE ::   xsi0r(:,:)         !: inverse of rn_si0
65   REAL(wp) ::   xsi1r                           !: inverse of rn_si1
66   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_chl   ! structure of input Chl (file informations, fields read)
67   INTEGER, PUBLIC ::   nksr              ! levels below which the light cannot penetrate ( depth larger than 391 m)
68   REAL(wp), DIMENSION(3,61) ::   rkrgb   !: tabulated attenuation coefficients for RGB absorption
69
70   !! * Substitutions
71#  include "domzgr_substitute.h90"
72#  include "vectopt_loop_substitute.h90"
73   !!----------------------------------------------------------------------
74   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
75   !! $Id$
76   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
77   !!----------------------------------------------------------------------
78CONTAINS
79
80   SUBROUTINE tra_qsr( kt )
81      !!----------------------------------------------------------------------
82      !!                  ***  ROUTINE tra_qsr  ***
83      !!
84      !! ** Purpose :   Compute the temperature trend due to the solar radiation
85      !!      penetration and add it to the general temperature trend.
86      !!
87      !! ** Method  : The profile of the solar radiation within the ocean is defined
88      !!      through 2 wavebands (rn_si0,rn_si1) or 3 wavebands (RGB) and a ratio rn_abs
89      !!      Considering the 2 wavebands case:
90      !!         I(k) = Qsr*( rn_abs*EXP(z(k)/rn_si0) + (1.-rn_abs)*EXP(z(k)/rn_si1) )
91      !!         The temperature trend associated with the solar radiation penetration
92      !!         is given by : zta = 1/e3t dk[ I ] / (rau0*Cp)
93      !!         At the bottom, boudary condition for the radiation is no flux :
94      !!      all heat which has not been absorbed in the above levels is put
95      !!      in the last ocean level.
96      !!         In z-coordinate case, the computation is only done down to the
97      !!      level where I(k) < 1.e-15 W/m2. In addition, the coefficients
98      !!      used for the computation are calculated one for once as they
99      !!      depends on k only.
100      !!
101      !! ** Action  : - update ta with the penetrative solar radiation trend
102      !!              - save the trend in ttrd ('key_trdtra')
103      !!
104      !! Reference  : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp.
105      !!              Lengaigne et al. 2007, Clim. Dyn., V28, 5, 503-516.
106      !!              Morel, A. et Berthon, JF, 1989, Limnol Oceanogr 34(8), 1545-1562
107      !!----------------------------------------------------------------------
108      !
109      INTEGER, INTENT(in) ::   kt     ! ocean time-step
110      !
111      INTEGER  ::   ji, jj, jk           ! dummy loop indices
112      INTEGER  ::   irgb                 ! local integers
113      REAL(wp) ::   zchl, zcoef, zfact   ! local scalars
114      REAL(wp) ::   zc0, zc1, zc2, zc3   !    -         -
115      REAL(wp) ::   zz0, zz1, z1_e3t     !    -         -
116      REAL(wp) ::   zCb, zCmax, zze, zpsi, zpsimax, zdelpsi, zCtot, zCze
117      REAL(wp) ::   zlogc, zlogc2, zlogc3
118      REAL(wp), POINTER, DIMENSION(:,:  ) :: zekb, zekg, zekr
119      REAL(wp), POINTER, DIMENSION(:,:,:) :: ze0, ze1, ze2, ze3, zea, ztrdt, zchl3d
120      !!--------------------------------------------------------------------------
121      !
122      IF( nn_timing == 1 )  CALL timing_start('tra_qsr')
123      !
124      CALL wrk_alloc( jpi, jpj,      zekb, zekg, zekr        )
125      CALL wrk_alloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea, zchl3d )
126      !
127      IF( kt == nit000 ) THEN
128         IF(lwp) WRITE(numout,*)
129         IF(lwp) WRITE(numout,*) 'tra_qsr : penetration of the surface solar radiation'
130         IF(lwp) WRITE(numout,*) '~~~~~~~'
131         IF( .NOT.ln_traqsr )   RETURN
132      ENDIF
133
134      IF( l_trdtra ) THEN      ! Save ta and sa trends
135         CALL wrk_alloc( jpi, jpj, jpk, ztrdt )
136         ztrdt(:,:,:) = tsa(:,:,:,jp_tem)
137      ENDIF
138
139      !                                        Set before qsr tracer content field
140      !                                        ***********************************
141      IF( kt == nit000 ) THEN                     ! Set the forcing field at nit000 - 1
142         !                                        ! -----------------------------------
143         qsr_hc(:,:,:) = 0.e0
144         !
145         IF( ln_rstart .AND.    &                    ! Restart: read in restart file
146              & iom_varid( numror, 'qsr_hc_b', ldstop = .FALSE. ) > 0 ) THEN
147            IF(lwp) WRITE(numout,*) '          nit000-1 qsr tracer content forcing field red in the restart file'
148            zfact = 0.5e0
149            CALL iom_get( numror, jpdom_autoglo, 'qsr_hc_b', qsr_hc_b )   ! before heat content trend due to Qsr flux
150         ELSE                                           ! No restart or restart not found: Euler forward time stepping
151            zfact = 1.e0
152            qsr_hc_b(:,:,:) = 0.e0
153         ENDIF
154      ELSE                                        ! Swap of forcing field
155         !                                        ! ---------------------
156         zfact = 0.5e0
157         qsr_hc_b(:,:,:) = qsr_hc(:,:,:)
158      ENDIF
159      !                                        Compute now qsr tracer content field
160      !                                        ************************************
161
162      !                                           ! ============================================== !
163      IF( lk_qsr_bio .AND. ln_qsr_bio ) THEN      !  bio-model fluxes  : all vertical coordinates  !
164         !                                        ! ============================================== !
165         DO jk = 1, jpkm1
166            qsr_hc(:,:,jk) = r1_rau0_rcp * ( etot3(:,:,jk) - etot3(:,:,jk+1) )
167         END DO
168         !                                        Add to the general trend
169         DO jk = 1, jpkm1
170            DO jj = 2, jpjm1
171               DO ji = fs_2, fs_jpim1   ! vector opt.
172                  z1_e3t = zfact / fse3t(ji,jj,jk)
173                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t
174               END DO
175            END DO
176         END DO
177         CALL iom_put( 'qsr3d', etot3 )   ! Shortwave Radiation 3D distribution
178         ! clem: store attenuation coefficient of the first ocean level
179         IF ( ln_qsr_ice ) THEN
180            DO jj = 1, jpj
181               DO ji = 1, jpi
182                  IF ( qsr(ji,jj) /= 0._wp ) THEN
183                     fraqsr_1lev(ji,jj) = ( qsr_hc(ji,jj,1) / ( r1_rau0_rcp * qsr(ji,jj) ) )
184                  ELSE
185                     fraqsr_1lev(ji,jj) = 1.
186                  ENDIF
187               END DO
188            END DO
189         ENDIF
190         !                                        ! ============================================== !
191      ELSE                                        !  Ocean alone :
192         !                                        ! ============================================== !
193         !
194         !
195#if defined key_traldf_c2d || key_traldf_c3d
196         IF( ln_stopack .AND. ( nn_spp_qsi0 > 0 ) ) THEN
197            xsi0r = rn_si0
198            CALL spp_gen(kt, xsi0r, nn_spp_qsi0, rn_qsi0_sd, jk_spp_qsi0 )
199            xsi0r = 1.e0 / xsi0r
200         ENDIF
201#else
202         IF ( ln_stopack .AND. nn_spp_qsi0 > 0 ) &
203            & CALL ctl_stop( 'tra_qsr: parameter perturbation will only work with '// &
204                             'key_traldf_c2d or key_traldf_c3d')
205#endif
206
207         !                                               ! ------------------------- !
208         IF( ln_qsr_rgb) THEN                             !  R-G-B  light penetration !
209            !                                             ! ------------------------- !
210            ! Set chlorophyl concentration
211            IF( nn_chldta == 1 .OR. nn_chldta == 2 .OR. nn_chldta == 3 .OR. lk_vvl ) THEN    !*  Variable Chlorophyll or ocean volume
212               !
213               IF( nn_chldta == 1 ) THEN        !*  2D Variable Chlorophyll
214                  !
215                  CALL fld_read( kt, 1, sf_chl )            ! Read Chl data and provides it at the current time step
216                  DO jk = 1, nksr + 1
217                     zchl3d(:,:,jk) = sf_chl(1)%fnow(:,:,1)
218                  ENDDO
219                  !
220               ELSE IF( nn_chldta == 2 ) THEN    !*   -3-D Variable Chlorophyll
221                  !
222                  CALL fld_read( kt, 1, sf_chl )            ! Read Chl data and provides it at the current time step
223!CDIR NOVERRCHK   !
224                  DO jj = 1, jpj
225!CDIR NOVERRCHK
226                     DO ji = 1, jpi
227                        zchl    = sf_chl(1)%fnow(ji,jj,1)
228                        zCtot   = 40.6  * zchl**0.459
229                        zze     = 568.2 * zCtot**(-0.746)
230                        IF( zze > 102. ) zze = 200.0 * zCtot**(-0.293)
231                        zlogc   = LOG( zchl )
232                        zlogc2  = zlogc * zlogc
233                        zlogc3  = zlogc * zlogc * zlogc
234                        zCb     = 0.768 + 0.087 * zlogc - 0.179 * zlogc2 - 0.025 * zlogc3
235                        zCmax   = 0.299 - 0.289 * zlogc + 0.579 * zlogc2
236                        zpsimax = 0.6   - 0.640 * zlogc + 0.021 * zlogc2 + 0.115 * zlogc3
237                        zdelpsi = 0.710 + 0.159 * zlogc + 0.021 * zlogc2
238                        zCze    = 1.12  * (zchl)**0.803
239                        DO jk = 1, nksr + 1
240                           zpsi = fsdept(ji,jj,jk) / zze
241                           zchl3d(ji,jj,jk) = zCze * ( zCb + zCmax * EXP( -( (zpsi - zpsimax) / zdelpsi )**2 ) )
242                        END DO
243                        !
244                      END DO
245                   END DO
246                     !
247               ELSE IF( nn_chldta == 3 ) THEN
248                  !
249#if defined key_medusa
250                  zchl3d(:,:,:) = trn(:,:,:,jpchn) + trn(:,:,:,jpchd)
251#elif defined key_hadocc
252                  zchl3d(:,:,:) = HADOCC_CHL(:,:,:)
253#else
254                  CALL ctl_stop( 'tra_qsr: Trying to take chlorophyll from MEDUSA or HadOCC', &
255                     &           'but neither MEDUSA nor HadOCC defined' )
256#endif
257                  !
258               ELSE                              !* Variable ocean volume but constant chrlorophyll
259                  DO jk = 1, nksr + 1
260                     zchl3d(:,:,jk) = 0.05
261                  ENDDO
262               ENDIF
263               !
264               zcoef  = ( 1. - rn_abs ) / 3.e0                        !  equi-partition in R-G-B
265               ze0(:,:,1) = rn_abs  * qsr(:,:)
266               ze1(:,:,1) = zcoef * qsr(:,:)
267               ze2(:,:,1) = zcoef * qsr(:,:)
268               ze3(:,:,1) = zcoef * qsr(:,:)
269               zea(:,:,1) =         qsr(:,:)
270               !
271               DO jk = 2, nksr+1
272                  !
273                  DO jj = 1, jpj                                         ! Separation in R-G-B depending of vertical profile of Chl
274!CDIR NOVERRCHK
275                     DO ji = 1, jpi
276                        zchl = MIN( 10. , MAX( 0.03, zchl3d(ji,jj,jk) ) )
277                        irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 )
278                        zekb(ji,jj) = rkrgb(1,irgb)
279                        zekg(ji,jj) = rkrgb(2,irgb)
280                        zekr(ji,jj) = rkrgb(3,irgb)
281                     END DO
282                  END DO
283!CDIR NOVERRCHK
284                  DO jj = 1, jpj
285!CDIR NOVERRCHK
286                     DO ji = 1, jpi
287                        zc0 = ze0(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * xsi0r(ji,jj) )
288                        zc1 = ze1(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekb(ji,jj) )
289                        zc2 = ze2(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekg(ji,jj) )
290                        zc3 = ze3(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekr(ji,jj) )
291                        ze0(ji,jj,jk) = zc0
292                        ze1(ji,jj,jk) = zc1
293                        ze2(ji,jj,jk) = zc2
294                        ze3(ji,jj,jk) = zc3
295                        zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk)
296                     END DO
297                  END DO
298               END DO
299               !
300               DO jk = 1, nksr                                        ! compute and add qsr trend to ta
301                  qsr_hc(:,:,jk) = r1_rau0_rcp * ( zea(:,:,jk) - zea(:,:,jk+1) )
302               END DO
303               zea(:,:,nksr+1:jpk) = 0.e0     ! below 400m set to zero
304               CALL iom_put( 'qsr3d', zea )   ! Shortwave Radiation 3D distribution
305               !
306               IF ( ln_qsr_ice ) THEN    ! store attenuation coefficient of the first ocean level
307!CDIR NOVERRCHK
308                  DO jj = 1, jpj                                         ! Separation in R-G-B depending of the surface Chl
309!CDIR NOVERRCHK
310                     DO ji = 1, jpi
311                        zchl = MIN( 10. , MAX( 0.03, zchl3d(ji,jj,1) ) )
312                        irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 )
313                        zekb(ji,jj) = rkrgb(1,irgb)
314                        zekg(ji,jj) = rkrgb(2,irgb)
315                        zekr(ji,jj) = rkrgb(3,irgb)
316                     END DO
317                  END DO
318                  !
319                  DO jj = 1, jpj
320                     DO ji = 1, jpi
321                        zc0 = rn_abs * EXP( - fse3t(ji,jj,1) * xsi0r(ji,jj) )
322                        zc1 = zcoef  * EXP( - fse3t(ji,jj,1) * zekb(ji,jj) )
323                        zc2 = zcoef  * EXP( - fse3t(ji,jj,1) * zekg(ji,jj) )
324                        zc3 = zcoef  * EXP( - fse3t(ji,jj,1) * zekr(ji,jj) )
325                        fraqsr_1lev(ji,jj) = 1.0 - ( zc0 + zc1 + zc2  + zc3  ) * tmask(ji,jj,2)
326                     END DO
327                  END DO
328                  !
329               ENDIF
330               !
331            ELSE                                                 !*  Constant Chlorophyll
332               DO jk = 1, nksr
333                  qsr_hc(:,:,jk) =  etot3(:,:,jk) * qsr(:,:)
334               END DO
335               !  store attenuation coefficient of the first ocean level
336               IF( ln_qsr_ice ) THEN
337                  fraqsr_1lev(:,:) = etot3(:,:,1) / r1_rau0_rcp
338               ENDIF
339           ENDIF
340
341         ENDIF
342         !                                                ! ------------------------- !
343         IF( ln_qsr_2bd ) THEN                            !  2 band light penetration !
344            !                                             ! ------------------------- !
345            !
346            IF( lk_vvl .OR. ( ln_stopack .AND. ( nn_spp_qsi0 > 0 ) ) ) THEN        !* variable volume
347
348               zz0   =        rn_abs   * r1_rau0_rcp
349               zz1   = ( 1. - rn_abs ) * r1_rau0_rcp
350               DO jk = 1, nksr                    ! solar heat absorbed at T-point in the top 400m
351                  DO jj = 1, jpj
352                     DO ji = 1, jpi
353                        zc0 = zz0 * EXP( -fsdepw(ji,jj,jk  )*xsi0r(ji,jj) ) + zz1 * EXP( -fsdepw(ji,jj,jk  )*xsi1r )
354                        zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r(ji,jj) ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r )
355                        qsr_hc(ji,jj,jk) = qsr(ji,jj) * ( zc0*tmask(ji,jj,jk) - zc1*tmask(ji,jj,jk+1) )
356                     END DO
357                  END DO
358               END DO
359               ! clem: store attenuation coefficient of the first ocean level
360               IF ( ln_qsr_ice ) THEN
361                  DO jj = 1, jpj
362                     DO ji = 1, jpi
363                        zc0 = zz0 * EXP( -fsdepw(ji,jj,1)*xsi0r(ji,jj) ) + zz1 * EXP( -fsdepw(ji,jj,1)*xsi1r )
364                        zc1 = zz0 * EXP( -fsdepw(ji,jj,2)*xsi0r(ji,jj) ) + zz1 * EXP( -fsdepw(ji,jj,2)*xsi1r )
365                        fraqsr_1lev(ji,jj) = ( zc0*tmask(ji,jj,1) - zc1*tmask(ji,jj,2) ) / r1_rau0_rcp
366                     END DO
367                  END DO
368               ENDIF
369            ELSE                                               !* constant volume: coef. computed one for all
370               DO jk = 1, nksr
371                  DO jj = 2, jpjm1
372                     DO ji = fs_2, fs_jpim1   ! vector opt.
373                        ! (ISF) no light penetration below the ice shelves
374                        qsr_hc(ji,jj,jk) =  etot3(ji,jj,jk) * qsr(ji,jj) * tmask(ji,jj,1)
375                     END DO
376                  END DO
377               END DO
378               ! clem: store attenuation coefficient of the first ocean level
379               IF ( ln_qsr_ice ) THEN
380                  fraqsr_1lev(:,:) = etot3(:,:,1) / r1_rau0_rcp
381               ENDIF
382               !
383            ENDIF
384            !
385         ENDIF
386         !
387         !                                        Add to the general trend
388         DO jk = 1, nksr
389            DO jj = 2, jpjm1
390               DO ji = fs_2, fs_jpim1   ! vector opt.
391                  z1_e3t = zfact / fse3t(ji,jj,jk)
392                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t
393               END DO
394            END DO
395         END DO
396         !
397      ENDIF
398      !
399      IF( lrst_oce ) THEN   !                  Write in the ocean restart file
400         !                                     *******************************
401         IF(lwp) WRITE(numout,*)
402         IF(lwp) WRITE(numout,*) 'qsr tracer content forcing field written in ocean restart file ',   &
403            &                    'at it= ', kt,' date= ', ndastp
404         IF(lwp) WRITE(numout,*) '~~~~'
405         IF(nn_timing == 2)  CALL timing_start('iom_rstput')
406         CALL iom_rstput( kt, nitrst, numrow, 'qsr_hc_b'   , qsr_hc      )
407         CALL iom_rstput( kt, nitrst, numrow, 'fraqsr_1lev', fraqsr_1lev )   ! default definition in sbcssm
408         IF(nn_timing == 2)  CALL timing_stop('iom_rstput')
409         !
410      ENDIF
411
412      IF( l_trdtra ) THEN     ! qsr tracers trends saved for diagnostics
413         ztrdt(:,:,:) = tsa(:,:,:,jp_tem) - ztrdt(:,:,:)
414         CALL trd_tra( kt, 'TRA', jp_tem, jptra_qsr, ztrdt )
415         CALL wrk_dealloc( jpi, jpj, jpk, ztrdt )
416      ENDIF
417      !                       ! print mean trends (used for debugging)
418      IF(ln_ctl)   CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' qsr  - Ta: ', mask1=tmask, clinfo3='tra-ta' )
419      !
420      CALL wrk_dealloc( jpi, jpj,      zekb, zekg, zekr        )
421      CALL wrk_dealloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea, zchl3d )
422      !
423      IF( nn_timing == 1 )  CALL timing_stop('tra_qsr')
424      !
425   END SUBROUTINE tra_qsr
426
427
428   SUBROUTINE tra_qsr_init
429      !!----------------------------------------------------------------------
430      !!                  ***  ROUTINE tra_qsr_init  ***
431      !!
432      !! ** Purpose :   Initialization for the penetrative solar radiation
433      !!
434      !! ** Method  :   The profile of solar radiation within the ocean is set
435      !!      from two length scale of penetration (rn_si0,rn_si1) and a ratio
436      !!      (rn_abs). These parameters are read in the namtra_qsr namelist. The
437      !!      default values correspond to clear water (type I in Jerlov'
438      !!      (1968) classification.
439      !!         called by tra_qsr at the first timestep (nit000)
440      !!
441      !! ** Action  : - initialize rn_si0, rn_si1 and rn_abs
442      !!
443      !! Reference : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp.
444      !!----------------------------------------------------------------------
445      !
446      INTEGER  ::   ji, jj, jk                   ! dummy loop indices
447      INTEGER  ::   irgb, ierror, ioptio, nqsr   ! local integer
448      INTEGER  ::   ios                          ! Local integer output status for namelist read
449      REAL(wp) ::   zz0, zc0  , zc1, zcoef       ! local scalars
450      REAL(wp) ::   zz1, zc2  , zc3, zchl        !   -      -
451      REAL(wp), POINTER, DIMENSION(:,:  ) :: zekb, zekg, zekr
452      REAL(wp), POINTER, DIMENSION(:,:,:) :: ze0, ze1, ze2, ze3, zea
453      !
454      CHARACTER(len=100) ::   cn_dir   ! Root directory for location of ssr files
455      TYPE(FLD_N)        ::   sn_chl   ! informations about the chlorofyl field to be read
456      !!
457      NAMELIST/namtra_qsr/  sn_chl, cn_dir, ln_traqsr, ln_qsr_rgb, ln_qsr_2bd, ln_qsr_bio, ln_qsr_ice,  &
458         &                  nn_chldta, rn_abs, rn_si0, rn_si1
459      !!----------------------------------------------------------------------
460
461      !
462      IF( nn_timing == 1 )  CALL timing_start('tra_qsr_init')
463      !
464      CALL wrk_alloc( jpi, jpj,      zekb, zekg, zekr        )
465      CALL wrk_alloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea )
466      !
467
468      REWIND( numnam_ref )              ! Namelist namtra_qsr in reference namelist : Ratio and length of penetration
469      READ  ( numnam_ref, namtra_qsr, IOSTAT = ios, ERR = 901)
470901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_qsr in reference namelist', lwp )
471
472      REWIND( numnam_cfg )              !  Namelist namtra_qsr in configuration namelist : Ratio and length of penetration
473      READ  ( numnam_cfg, namtra_qsr, IOSTAT = ios, ERR = 902 )
474902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_qsr in configuration namelist', lwp )
475      IF(lwm) WRITE ( numond, namtra_qsr )
476      !
477      IF(lwp) THEN                ! control print
478         WRITE(numout,*)
479         WRITE(numout,*) 'tra_qsr_init : penetration of the surface solar radiation'
480         WRITE(numout,*) '~~~~~~~~~~~~'
481         WRITE(numout,*) '   Namelist namtra_qsr : set the parameter of penetration'
482         WRITE(numout,*) '      Light penetration (T) or not (F)         ln_traqsr  = ', ln_traqsr
483         WRITE(numout,*) '      RGB (Red-Green-Blue) light penetration   ln_qsr_rgb = ', ln_qsr_rgb
484         WRITE(numout,*) '      2 band               light penetration   ln_qsr_2bd = ', ln_qsr_2bd
485         WRITE(numout,*) '      bio-model            light penetration   ln_qsr_bio = ', ln_qsr_bio
486         WRITE(numout,*) '      light penetration for ice-model LIM3     ln_qsr_ice = ', ln_qsr_ice
487         WRITE(numout,*) '      RGB: model (3) file (2/1) or cst (0) chl  nn_chldta = ', nn_chldta
488         WRITE(numout,*) '      RGB & 2 bands: fraction of light (rn_si1)    rn_abs = ', rn_abs
489         WRITE(numout,*) '      RGB & 2 bands: shortess depth of extinction  rn_si0 = ', rn_si0
490         WRITE(numout,*) '      2 bands: longest depth of extinction         rn_si1 = ', rn_si1
491      ENDIF
492
493      IF( ln_traqsr ) THEN     ! control consistency
494         !
495         IF( .NOT.lk_qsr_bio .AND. ln_qsr_bio )   THEN
496            CALL ctl_warn( 'No bio model : force ln_qsr_bio = FALSE ' )
497            ln_qsr_bio = .FALSE.
498         ENDIF
499         !
500         ioptio = 0                      ! Parameter control
501         IF( ln_qsr_rgb  )   ioptio = ioptio + 1
502         IF( ln_qsr_2bd  )   ioptio = ioptio + 1
503         IF( ln_qsr_bio  )   ioptio = ioptio + 1
504         !
505         IF( ioptio /= 1 ) &
506            CALL ctl_stop( '          Choose ONE type of light penetration in namelist namtra_qsr',  &
507            &              ' 2 bands, 3 RGB bands or bio-model light penetration' )
508         !
509         IF( ln_qsr_rgb .AND. nn_chldta == 0 )   nqsr =  1
510         IF( ln_qsr_rgb .AND. nn_chldta == 1 )   nqsr =  2
511         IF( ln_qsr_rgb .AND. nn_chldta == 2 )   nqsr =  3
512         IF( ln_qsr_rgb .AND. nn_chldta == 3 )   nqsr =  4
513         IF( ln_qsr_2bd                      )   nqsr =  5
514         IF( ln_qsr_bio                      )   nqsr =  6
515         !
516         IF(lwp) THEN                   ! Print the choice
517            WRITE(numout,*)
518            IF( nqsr ==  1 )   WRITE(numout,*) '         R-G-B   light penetration - Constant Chlorophyll'
519            IF( nqsr ==  2 )   WRITE(numout,*) '         R-G-B   light penetration - 2D Chl data '
520            IF( nqsr ==  3 )   WRITE(numout,*) '         R-G-B   light penetration - 3D Chl data '
521            IF( nqsr ==  4 )   WRITE(numout,*) '         R-G-B   light penetration - 3D Chl from BGC model '
522            IF( nqsr ==  5 )   WRITE(numout,*) '         2 bands light penetration'
523            IF( nqsr ==  6 )   WRITE(numout,*) '         bio-model light penetration'
524         ENDIF
525#if ! (defined key_medusa || defined key_hadocc)
526         !
527         IF( nqsr ==  4 ) THEN
528            CALL ctl_stop( 'nn_chldta=3 so trying to use BGC model chlorophyll for light penetration', &
529               &           'but not running with MEDUSA or HadOCC' )
530         ENDIF
531#endif
532         !
533      ENDIF
534      !                          ! ===================================== !
535      IF( ln_traqsr  ) THEN      !  Initialisation of Light Penetration  !
536         !                       ! ===================================== !
537         !
538         ALLOCATE( xsi0r(jpi,jpj) )
539         xsi0r = 1.e0 / rn_si0
540         xsi1r = 1.e0 / rn_si1
541         !                                ! ---------------------------------- !
542         IF( ln_qsr_rgb ) THEN            !  Red-Green-Blue light penetration  !
543            !                             ! ---------------------------------- !
544            !
545            CALL trc_oce_rgb( rkrgb )           !* tabulated attenuation coef.
546            !
547            !                                   !* level of light extinction
548            IF(  ln_sco ) THEN   ;   nksr = jpkm1
549            ELSE                 ;   nksr = trc_oce_ext_lev( r_si2, 0.33e2 )
550            ENDIF
551
552            IF(lwp) WRITE(numout,*) '        level of light extinction = ', nksr, ' ref depth = ', gdepw_1d(nksr+1), ' m'
553            !
554            IF( nn_chldta == 1  .OR. nn_chldta == 2 ) THEN           !* Chl data : set sf_chl structure
555               IF(lwp) WRITE(numout,*)
556               IF(lwp) WRITE(numout,*) '        Chlorophyll read in a file'
557               ALLOCATE( sf_chl(1), STAT=ierror )
558               IF( ierror > 0 ) THEN
559                  CALL ctl_stop( 'tra_qsr_init: unable to allocate sf_chl structure' )   ;   RETURN
560               ENDIF
561               ALLOCATE( sf_chl(1)%fnow(jpi,jpj,1)   )
562               IF( sn_chl%ln_tint )ALLOCATE( sf_chl(1)%fdta(jpi,jpj,1,2) )
563               !                                        ! fill sf_chl with sn_chl and control print
564               CALL fld_fill( sf_chl, (/ sn_chl /), cn_dir, 'tra_qsr_init',   &
565                  &                                         'Solar penetration function of read chlorophyll', 'namtra_qsr' )
566               !
567            ELSEIF( nn_chldta == 3 ) THEN       !* Chl data will be got from model at each time step
568               IF(lwp) WRITE(numout,*)
569               IF(lwp) WRITE(numout,*) '        Chlorophyll will be taken from model at each time step'
570            ELSE                                !* constant Chl : compute once for all the distribution of light (etot3)
571               IF(lwp) WRITE(numout,*)
572               IF(lwp) WRITE(numout,*) '        Constant Chlorophyll concentration = 0.05'
573               IF( lk_vvl ) THEN                   ! variable volume
574                  IF(lwp) WRITE(numout,*) '        key_vvl: light distribution will be computed at each time step'
575               ELSE                                ! constant volume: computes one for all
576                  IF(lwp) WRITE(numout,*) '        fixed volume: light distribution computed one for all'
577                  !
578                  zchl = 0.05                                 ! constant chlorophyll
579                  irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 )
580                  zekb(:,:) = rkrgb(1,irgb)                   ! Separation in R-G-B depending of the chlorophyll
581                  zekg(:,:) = rkrgb(2,irgb)
582                  zekr(:,:) = rkrgb(3,irgb)
583                  !
584                  zcoef = ( 1. - rn_abs ) / 3.e0              ! equi-partition in R-G-B
585                  ze0(:,:,1) = rn_abs
586                  ze1(:,:,1) = zcoef
587                  ze2(:,:,1) = zcoef
588                  ze3(:,:,1) = zcoef
589                  zea(:,:,1) = tmask(:,:,1)                   ! = ( ze0+ze1+z2+ze3 ) * tmask
590
591                  DO jk = 2, nksr+1
592!CDIR NOVERRCHK
593                     DO jj = 1, jpj
594!CDIR NOVERRCHK
595                        DO ji = 1, jpi
596                           zc0 = ze0(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * xsi0r(ji,jj) )
597                           zc1 = ze1(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * zekb(ji,jj) )
598                           zc2 = ze2(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * zekg(ji,jj) )
599                           zc3 = ze3(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * zekr(ji,jj) )
600                           ze0(ji,jj,jk) = zc0
601                           ze1(ji,jj,jk) = zc1
602                           ze2(ji,jj,jk) = zc2
603                           ze3(ji,jj,jk) = zc3
604                           zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk)
605                        END DO
606                     END DO
607                  END DO
608                  !
609                  DO jk = 1, nksr
610                     ! (ISF) no light penetration below the ice shelves
611                     etot3(:,:,jk) = r1_rau0_rcp * ( zea(:,:,jk) - zea(:,:,jk+1) ) * tmask(:,:,1)
612                  END DO
613                  etot3(:,:,nksr+1:jpk) = 0.e0                ! below 400m set to zero
614               ENDIF
615            ENDIF
616            !
617         ENDIF
618            !                             ! ---------------------------------- !
619         IF( ln_qsr_2bd ) THEN            !    2 bands    light penetration    !
620            !                             ! ---------------------------------- !
621            !
622            !                                ! level of light extinction
623            nksr = trc_oce_ext_lev( rn_si1, 1.e2 )
624            IF(lwp) THEN
625               WRITE(numout,*)
626            IF(lwp) WRITE(numout,*) '        level of light extinction = ', nksr, ' ref depth = ', gdepw_1d(nksr+1), ' m'
627            ENDIF
628            !
629            IF( lk_vvl ) THEN                   ! variable volume
630               IF(lwp) WRITE(numout,*) '        key_vvl: light distribution will be computed at each time step'
631            ELSE                                ! constant volume: computes one for all
632               zz0 =        rn_abs   * r1_rau0_rcp
633               zz1 = ( 1. - rn_abs ) * r1_rau0_rcp
634               DO jk = 1, nksr                    !*  solar heat absorbed at T-point computed once for all
635                  DO jj = 1, jpj                              ! top 400 meters
636                     DO ji = 1, jpi
637                        zc0 = zz0 * EXP( -fsdepw(ji,jj,jk  )*xsi0r(ji,jj) ) + zz1 * EXP( -fsdepw(ji,jj,jk  )*xsi1r )
638                        zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r(ji,jj) ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r )
639                        etot3(ji,jj,jk) = (  zc0 * tmask(ji,jj,jk) - zc1 * tmask(ji,jj,jk+1)  ) * tmask(ji,jj,1)
640                     END DO
641                  END DO
642               END DO
643               etot3(:,:,nksr+1:jpk) = 0.e0                   ! below 400m set to zero
644               !
645            ENDIF
646         ENDIF
647         !                       ! ===================================== !
648      ELSE                       !        No light penetration           !
649         !                       ! ===================================== !
650         IF(lwp) THEN
651            WRITE(numout,*)
652            WRITE(numout,*) 'tra_qsr_init : NO solar flux penetration'
653            WRITE(numout,*) '~~~~~~~~~~~~'
654         ENDIF
655      ENDIF
656      !
657      ! initialisation of fraqsr_1lev used in sbcssm
658      IF( iom_varid( numror, 'fraqsr_1lev', ldstop = .FALSE. ) > 0 ) THEN
659         IF(nn_timing == 2)  CALL timing_start('iom_rstget')
660         CALL iom_get( numror, jpdom_autoglo, 'fraqsr_1lev'  , fraqsr_1lev  )
661         IF(nn_timing == 2)  CALL timing_stop('iom_rstget')
662      ELSE
663         fraqsr_1lev(:,:) = 1._wp   ! default definition
664      ENDIF
665      !
666      CALL wrk_dealloc( jpi, jpj,      zekb, zekg, zekr        )
667      CALL wrk_dealloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea )
668      !
669      IF( nn_timing == 1 )  CALL timing_stop('tra_qsr_init')
670      !
671   END SUBROUTINE tra_qsr_init
672
673   !!======================================================================
674END MODULE traqsr
Note: See TracBrowser for help on using the repository browser.