New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynhpg.F90 in branches/UKMO/dev_r5518_GO6_package_FOAMv14_updated_pcbias/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/UKMO/dev_r5518_GO6_package_FOAMv14_updated_pcbias/NEMOGCM/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 11478

Last change on this file since 11478 was 11478, checked in by mattmartin, 3 years ago

Include initial version of updated pressure correction by Mike Bell.

File size: 74.4 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  OPA  !  1987-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  1991-11  (G. Madec)
8   !!            7.0  !  1996-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  1997-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  2002-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  2002-08  (A. Bozec)  hpg_zps: Original code
12   !!   NEMO     1.0  !  2005-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                 !         Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!             -   !  2005-11  (G. Madec) style & small optimisation
15   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
16   !!            3.4  !  2011-11  (H. Liu) hpg_prj: Original code for s-coordinates
17   !!                 !           (A. Coward) suppression of hel, wdj and rot options
18   !!            3.6  !  2014-11  (P. Mathiot) hpg_isf: original code for ice shelf cavity
19   !!            3.6  !  2019-08  (M. Bell) Revisions to bias pressure correction
20   !!----------------------------------------------------------------------
21
22   !!----------------------------------------------------------------------
23   !!   dyn_hpg      : update the momentum trend with the now horizontal
24   !!                  gradient of the hydrostatic pressure
25   !!   dyn_hpg_init : initialisation and control of options
26   !!       hpg_zco  : z-coordinate scheme
27   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
28   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
29   !!       hpg_isf  : s-coordinate (sco formulation) adapted to ice shelf
30   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
31   !!       hpg_prj  : s-coordinate (Pressure Jacobian with Cubic polynomial)
32   !!----------------------------------------------------------------------
33   USE oce             ! ocean dynamics and tracers
34   USE sbc_oce         ! surface variable (only for the flag with ice shelf)
35   USE dom_oce         ! ocean space and time domain
36   USE phycst          ! physical constants
37   USE trd_oce         ! trends: ocean variables
38   USE trddyn          ! trend manager: dynamics
39   !
40   USE in_out_manager  ! I/O manager
41   USE prtctl          ! Print control
42   USE lbclnk          ! lateral boundary condition
43   USE lib_mpp         ! MPP library
44   USE eosbn2          ! compute density
45   USE wrk_nemo        ! Memory Allocation
46   USE timing          ! Timing
47   USE biaspar         ! bias correction variables
48
49   IMPLICIT NONE
50   PRIVATE
51
52   PUBLIC   dyn_hpg        ! routine called by step module
53   PUBLIC   dyn_hpg_init   ! routine called by opa module
54
55   !                                    !!* Namelist namdyn_hpg : hydrostatic pressure gradient
56   LOGICAL , PUBLIC ::   ln_hpg_zco      !: z-coordinate - full steps
57   LOGICAL , PUBLIC ::   ln_hpg_zps      !: z-coordinate - partial steps (interpolation)
58   LOGICAL , PUBLIC ::   ln_hpg_sco      !: s-coordinate (standard jacobian formulation)
59   LOGICAL , PUBLIC ::   ln_hpg_djc      !: s-coordinate (Density Jacobian with Cubic polynomial)
60   LOGICAL , PUBLIC ::   ln_hpg_prj      !: s-coordinate (Pressure Jacobian scheme)
61   LOGICAL , PUBLIC ::   ln_hpg_isf      !: s-coordinate similar to sco modify for isf
62   LOGICAL , PUBLIC ::   ln_dynhpg_imp   !: semi-implicite hpg flag
63
64   INTEGER , PUBLIC ::   nhpg  =  0   ! = 0 to 7, type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
65
66   !! * Substitutions
67#  include "domzgr_substitute.h90"
68#  include "vectopt_loop_substitute.h90"
69   !!----------------------------------------------------------------------
70   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
71   !! $Id$
72   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
73   !!----------------------------------------------------------------------
74CONTAINS
75
76   SUBROUTINE dyn_hpg( kt )
77      !!---------------------------------------------------------------------
78      !!                  ***  ROUTINE dyn_hpg  ***
79      !!
80      !! ** Method  :   Call the hydrostatic pressure gradient routine
81      !!              using the scheme defined in the namelist
82      !!
83      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
84      !!             - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
85      !!----------------------------------------------------------------------
86      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
87      INTEGER                                   ::   ji, jj, jk   ! dummy loop indices
88      INTEGER                                   ::   iku, ikv          ! k indices for bottom level at u and v points
89      REAL(wp), POINTER, DIMENSION(:,:,:)       ::   ztrdu, ztrdv
90      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:)   ::   z_rhd_st   ! tmp density storage for pressure corr
91      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:)   ::   z_ua, z_va ! tmp store for ua and va including hpg but not pressure correction
92      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:)   ::   z_ua_bpc, z_va_bpc ! ua calculated with bias pressure correction 
93
94      REAL(wp), ALLOCATABLE, DIMENSION(:,:)     ::   z_gru_st, z_grv_st         ! tmp ua and va trends storage for pressure corr
95      REAL(wp), ALLOCATABLE, DIMENSION(:,:)     ::   z_ua_bpc_bot, z_va_bpc_bot ! bias pc fields calculated at the ocean bottom
96     
97      !!----------------------------------------------------------------------
98      !
99      IF( nn_timing == 1 )  CALL timing_start('dyn_hpg')
100      !
101      IF( l_trddyn ) THEN                    ! Temporary saving of ua and va trends (l_trddyn)
102         CALL wrk_alloc( jpi,jpj,jpk, ztrdu, ztrdv )
103         ztrdu(:,:,:) = ua(:,:,:)
104         ztrdv(:,:,:) = va(:,:,:)
105      ENDIF
106      !
107
108      IF ( ln_bias .AND. ln_bias_pc_app ) THEN
109
110         !Allocate space for tempory variables
111         ALLOCATE( z_rhd_st(jpi,jpj,jpk), &
112            &      z_gru_st(jpi,jpj),     &
113            &      z_grv_st(jpi,jpj),     &
114       &      z_ua(jpi,jpj,jpk),     z_va(jpi,jpj,jpk),     & 
115       &      z_ua_bpc(jpi,jpj,jpk), z_va_bpc(jpi,jpj,jpk), & 
116            &      z_ua_bpc_bot(jpi,jpj), z_va_bpc_bot(jpi,jpj)  & 
117       &            )
118
119! save the original acceleration trends (z_ua_bpc, z_va_bpc are used as temporary storage)
120         z_ua_bpc(:,:,:)     = ua(:,:,:)
121    z_va_bpc(:,:,:)     = va(:,:,:)
122      END IF
123
124      SELECT CASE ( nhpg )      ! Hydrostatic pressure gradient computation
125      CASE (  0 )   ;   CALL hpg_zco    ( kt )      ! z-coordinate
126      CASE (  1 )   ;   CALL hpg_zps    ( kt )      ! z-coordinate plus partial steps (interpolation)
127      CASE (  2 )   ;   CALL hpg_sco    ( kt )      ! s-coordinate (standard jacobian formulation)
128      CASE (  3 )   ;   CALL hpg_djc    ( kt )      ! s-coordinate (Density Jacobian with Cubic polynomial)
129      CASE (  4 )   ;   CALL hpg_prj    ( kt )      ! s-coordinate (Pressure Jacobian scheme)
130      CASE (  5 )   ;   CALL hpg_isf    ( kt )      ! s-coordinate similar to sco modify for ice shelf
131      END SELECT
132      !
133
134      IF ( ln_bias .AND. ln_bias_pc_app ) THEN
135
136         z_rhd_st(:,:,:) = rhd(:,:,:)     ! store orig density
137         rhd(:,:,:)      = rhd_pc(:,:,:)  ! use pressure corrected density
138         z_gru_st(:,:)   = gru(:,:)
139         gru(:,:)        = gru_pc(:,:)
140         z_grv_st(:,:)   = grv(:,:)
141         grv(:,:)        = grv_pc(:,:)
142
143         ! save the acceleration trends including hpg field but calculated without the bpc fields
144         z_ua(:,:,:)     = ua(:,:,:)
145    z_va(:,:,:)     = va(:,:,:)
146
147         ! reset the acceleration trends to their original values
148         ua(:,:,:)       = z_ua_bpc(:,:,:)   
149    va(:,:,:)       = z_va_bpc(:,:,:) 
150
151         ! re-calculate the horizontal pressure gradients with the bpc fields
152         SELECT CASE ( nhpg )      ! Hydrostatic pressure gradient computation
153         CASE (  0 )   ;   CALL hpg_zco    ( kt )      ! z-coordinate
154         CASE (  1 )   ;   CALL hpg_zps    ( kt )      ! z-coordinate plus partial steps (interpolation)
155         CASE (  2 )   ;   CALL hpg_sco    ( kt )      ! s-coordinate (standard jacobian formulation)
156         CASE (  3 )   ;   CALL hpg_djc    ( kt )      ! s-coordinate (Density Jacobian with Cubic polynomial)
157         CASE (  4 )   ;   CALL hpg_prj    ( kt )      ! s-coordinate (Pressure Jacobian scheme)
158         CASE (  5 )   ;   CALL hpg_isf    ( kt )      ! s-coordinate similar to sco modify for ice shelf
159         END SELECT
160
161         ! calculate the bpc contribution to ua and va
162         z_ua_bpc(:,:,:) = ua(:,:,:) - z_ua(:,:,:)
163         z_va_bpc(:,:,:) = va(:,:,:) - z_va(:,:,:)
164
165         ! calculate the bpc contribution to ua and va at the bottom
166         DO jj = 2, jpjm1
167            DO ji = 2, jpim1
168               iku = mbku(ji,jj)
169               ikv = mbkv(ji,jj) 
170               z_ua_bpc_bot(ji,jj) = z_ua_bpc(ji,jj,iku)
171               z_va_bpc_bot(ji,jj) = z_va_bpc(ji,jj,ikv)
172            END DO  ! ji
173         END DO ! jj
174
175         ! subtract off the bottom values of bpc contribution to ua and va
176    DO jk = 1, jpk - 1
177           z_ua_bpc(:,:,jk) = z_ua_bpc(:,:,jk) - z_ua_bpc_bot(:,:)
178           z_va_bpc(:,:,jk) = z_va_bpc(:,:,jk) - z_va_bpc_bot(:,:)
179    END DO 
180
181         ! calculate ua using the original hpg (z_ua) and the bias hpg with the bottom pressure gradients subtracted off
182         ua(:,:,:) = z_ua(:,:,:) + z_ua_bpc(:,:,:)
183         va(:,:,:) = z_va(:,:,:) + z_va_bpc(:,:,:)
184
185         IF(lwp) THEN
186           WRITE(numout,*) " ! restore original density"
187         ENDIF
188
189         ! restore original density, gru and grv fields
190         rhd(:,:,:) = z_rhd_st(:,:,:)     
191         gru(:,:)   = z_gru_st(:,:)
192         grv(:,:)   = z_grv_st(:,:)
193
194         !Deallocate tempory variables
195         DEALLOCATE( z_rhd_st,   z_gru_st, z_grv_st,   &
196            &        z_ua, z_va, z_ua_bpc, z_va_bpc,   &
197       &        z_ua_bpc_bot, z_va_bpc_bot        &
198            &                                          )
199       
200      ENDIF  ! ln_bias .AND. ln_bias_pc_app
201
202
203      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
204         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
205         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
206         CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt )
207         CALL wrk_dealloc( jpi,jpj,jpk, ztrdu, ztrdv )
208      ENDIF
209      !
210      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg  - Ua: ', mask1=umask,   &
211         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
212      !
213      IF( nn_timing == 1 )  CALL timing_stop('dyn_hpg')
214      !
215   END SUBROUTINE dyn_hpg
216
217
218   SUBROUTINE dyn_hpg_init
219      !!----------------------------------------------------------------------
220      !!                 ***  ROUTINE dyn_hpg_init  ***
221      !!
222      !! ** Purpose :   initializations for the hydrostatic pressure gradient
223      !!              computation and consistency control
224      !!
225      !! ** Action  :   Read the namelist namdyn_hpg and check the consistency
226      !!      with the type of vertical coordinate used (zco, zps, sco)
227      !!----------------------------------------------------------------------
228      INTEGER ::   ioptio = 0      ! temporary integer
229      INTEGER ::   ios             ! Local integer output status for namelist read
230      !!
231      NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco,     &
232         &                 ln_hpg_djc, ln_hpg_prj, ln_hpg_isf, ln_dynhpg_imp
233      !!----------------------------------------------------------------------
234      !
235      REWIND( numnam_ref )              ! Namelist namdyn_hpg in reference namelist : Hydrostatic pressure gradient
236      READ  ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
237901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist', lwp )
238
239      REWIND( numnam_cfg )              ! Namelist namdyn_hpg in configuration namelist : Hydrostatic pressure gradient
240      READ  ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
241902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist', lwp )
242      IF(lwm) WRITE ( numond, namdyn_hpg )
243      !
244      IF(lwp) THEN                   ! Control print
245         WRITE(numout,*)
246         WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
247         WRITE(numout,*) '~~~~~~~~~~~~'
248         WRITE(numout,*) '   Namelist namdyn_hpg : choice of hpg scheme'
249         WRITE(numout,*) '      z-coord. - full steps                             ln_hpg_zco    = ', ln_hpg_zco
250         WRITE(numout,*) '      z-coord. - partial steps (interpolation)          ln_hpg_zps    = ', ln_hpg_zps
251         WRITE(numout,*) '      s-coord. (standard jacobian formulation)          ln_hpg_sco    = ', ln_hpg_sco
252         WRITE(numout,*) '      s-coord. (standard jacobian formulation) for isf  ln_hpg_isf    = ', ln_hpg_isf
253         WRITE(numout,*) '      s-coord. (Density Jacobian: Cubic polynomial)     ln_hpg_djc    = ', ln_hpg_djc
254         WRITE(numout,*) '      s-coord. (Pressure Jacobian: Cubic polynomial)    ln_hpg_prj    = ', ln_hpg_prj
255         WRITE(numout,*) '      time stepping: centered (F) or semi-implicit (T)  ln_dynhpg_imp = ', ln_dynhpg_imp
256      ENDIF
257      !
258      IF( ln_hpg_djc )   &
259         &   CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method &
260                           & currently disabled (bugs under investigation). Please select &
261                           & either  ln_hpg_sco or  ln_hpg_prj instead')
262      !
263      IF( lk_vvl .AND. .NOT. (ln_hpg_sco.OR.ln_hpg_prj.OR.ln_hpg_isf) )   &
264         &   CALL ctl_stop('dyn_hpg_init : variable volume key_vvl requires:&
265                           & the standard jacobian formulation hpg_sco or &
266                           & the pressure jacobian formulation hpg_prj')
267
268      IF(       ln_hpg_isf .AND. .NOT. ln_isfcav )   &
269         &   CALL ctl_stop( ' hpg_isf not available if ln_isfcav = false ' )
270      IF( .NOT. ln_hpg_isf .AND.       ln_isfcav )   &
271         &   CALL ctl_stop( 'Only hpg_isf has been corrected to work with ice shelf cavity.' )
272      !
273      !                               ! Set nhpg from ln_hpg_... flags
274      IF( ln_hpg_zco )   nhpg = 0
275      IF( ln_hpg_zps )   nhpg = 1
276      IF( ln_hpg_sco )   nhpg = 2
277      IF( ln_hpg_djc )   nhpg = 3
278      IF( ln_hpg_prj )   nhpg = 4
279      IF( ln_hpg_isf )   nhpg = 5
280      !
281      !                               ! Consistency check
282      ioptio = 0
283      IF( ln_hpg_zco )   ioptio = ioptio + 1
284      IF( ln_hpg_zps )   ioptio = ioptio + 1
285      IF( ln_hpg_sco )   ioptio = ioptio + 1
286      IF( ln_hpg_djc )   ioptio = ioptio + 1
287      IF( ln_hpg_prj )   ioptio = ioptio + 1
288      IF( ln_hpg_isf )   ioptio = ioptio + 1
289      IF( ioptio /= 1 )   CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
290      !
291      ! initialisation of ice load
292      riceload(:,:)=0.0
293      !
294   END SUBROUTINE dyn_hpg_init
295
296
297   SUBROUTINE hpg_zco( kt )
298      !!---------------------------------------------------------------------
299      !!                  ***  ROUTINE hpg_zco  ***
300      !!
301      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
302      !!      The now hydrostatic pressure gradient at a given level, jk,
303      !!      is computed by taking the vertical integral of the in-situ
304      !!      density gradient along the model level from the suface to that
305      !!      level:    zhpi = grav .....
306      !!                zhpj = grav .....
307      !!      add it to the general momentum trend (ua,va).
308      !!            ua = ua - 1/e1u * zhpi
309      !!            va = va - 1/e2v * zhpj
310      !!
311      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
312      !!----------------------------------------------------------------------
313      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
314      !!
315      INTEGER  ::   ji, jj, jk       ! dummy loop indices
316      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
317      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
318      !!----------------------------------------------------------------------
319      !
320      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
321      !
322      IF( kt == nit000 ) THEN
323         IF(lwp) WRITE(numout,*)
324         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
325         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
326      ENDIF
327
328      zcoef0 = - grav * 0.5_wp      ! Local constant initialization
329
330      ! Surface value
331      DO jj = 2, jpjm1
332         DO ji = fs_2, fs_jpim1   ! vector opt.
333            zcoef1 = zcoef0 * fse3w(ji,jj,1)
334            ! hydrostatic pressure gradient
335            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
336            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
337            ! add to the general momentum trend
338            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
339            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
340         END DO
341      END DO
342
343      !
344      ! interior value (2=<jk=<jpkm1)
345      DO jk = 2, jpkm1
346         DO jj = 2, jpjm1
347            DO ji = fs_2, fs_jpim1   ! vector opt.
348               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
349               ! hydrostatic pressure gradient
350               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
351                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )   &
352                  &                       - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
353
354               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
355                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )   &
356                  &                       - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
357               ! add to the general momentum trend
358               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
359               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
360            END DO
361         END DO
362      END DO
363      !
364      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
365      !
366   END SUBROUTINE hpg_zco
367
368
369   SUBROUTINE hpg_zps( kt )
370      !!---------------------------------------------------------------------
371      !!                 ***  ROUTINE hpg_zps  ***
372      !!
373      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
374      !!
375      !! ** Action  : - Update (ua,va) with the now hydrastatic pressure trend
376      !!----------------------------------------------------------------------
377      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
378      !!
379      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
380      INTEGER  ::   iku, ikv                         ! temporary integers
381      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
382      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
383      !!----------------------------------------------------------------------
384      !
385      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
386      !
387      IF( kt == nit000 ) THEN
388         IF(lwp) WRITE(numout,*)
389         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
390         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
391      ENDIF
392
393
394      ! Local constant initialization
395      zcoef0 = - grav * 0.5_wp
396
397      !  Surface value (also valid in partial step case)
398      DO jj = 2, jpjm1
399         DO ji = fs_2, fs_jpim1   ! vector opt.
400            zcoef1 = zcoef0 * fse3w(ji,jj,1)
401            ! hydrostatic pressure gradient
402            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
403            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
404            ! add to the general momentum trend
405            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
406            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
407         END DO
408      END DO
409
410
411      ! interior value (2=<jk=<jpkm1)
412      DO jk = 2, jpkm1
413         DO jj = 2, jpjm1
414            DO ji = fs_2, fs_jpim1   ! vector opt.
415               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
416               ! hydrostatic pressure gradient
417               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
418                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
419                  &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
420
421               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
422                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
423                  &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
424               ! add to the general momentum trend
425               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
426               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
427            END DO
428         END DO
429      END DO
430
431
432      ! partial steps correction at the last level  (use gru & grv computed in zpshde.F90)
433      DO jj = 2, jpjm1
434         DO ji = 2, jpim1
435            iku = mbku(ji,jj)
436            ikv = mbkv(ji,jj)
437            zcoef2 = zcoef0 * MIN( fse3w(ji,jj,iku), fse3w(ji+1,jj  ,iku) )
438            zcoef3 = zcoef0 * MIN( fse3w(ji,jj,ikv), fse3w(ji  ,jj+1,ikv) )
439            IF( iku > 1 ) THEN            ! on i-direction (level 2 or more)
440               ua  (ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku)         ! subtract old value
441               zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1)                   &   ! compute the new one
442                  &            + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) / e1u(ji,jj)
443               ua  (ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku)         ! add the new one to the general momentum trend
444            ENDIF
445            IF( ikv > 1 ) THEN            ! on j-direction (level 2 or more)
446               va  (ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv)         ! subtract old value
447               zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1)                   &   ! compute the new one
448                  &            + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) / e2v(ji,jj)
449               va  (ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv)         ! add the new one to the general momentum trend
450            ENDIF
451         END DO
452      END DO
453      !
454      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
455      !
456   END SUBROUTINE hpg_zps
457
458   SUBROUTINE hpg_sco( kt )
459      !!---------------------------------------------------------------------
460      !!                  ***  ROUTINE hpg_sco  ***
461      !!
462      !! ** Method  :   s-coordinate case. Jacobian scheme.
463      !!      The now hydrostatic pressure gradient at a given level, jk,
464      !!      is computed by taking the vertical integral of the in-situ
465      !!      density gradient along the model level from the suface to that
466      !!      level. s-coordinates (ln_sco): a corrective term is added
467      !!      to the horizontal pressure gradient :
468      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
469      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
470      !!      add it to the general momentum trend (ua,va).
471      !!         ua = ua - 1/e1u * zhpi
472      !!         va = va - 1/e2v * zhpj
473      !!
474      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
475      !!----------------------------------------------------------------------
476      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
477      !!
478      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
479      REAL(wp) ::   zcoef0, zuap, zvap, znad   ! temporary scalars
480      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
481      !!----------------------------------------------------------------------
482      !
483      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
484      !
485      IF( kt == nit000 ) THEN
486         IF(lwp) WRITE(numout,*)
487         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
488         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
489      ENDIF
490
491      ! Local constant initialization
492      zcoef0 = - grav * 0.5_wp
493      ! To use density and not density anomaly
494      IF ( lk_vvl ) THEN   ;     znad = 1._wp          ! Variable volume
495      ELSE                 ;     znad = 0._wp         ! Fixed volume
496      ENDIF
497
498      ! Surface value
499      DO jj = 2, jpjm1
500         DO ji = fs_2, fs_jpim1   ! vector opt.
501            ! hydrostatic pressure gradient along s-surfaces
502            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3w(ji+1,jj  ,1) * ( znad + rhd(ji+1,jj  ,1) )   &
503               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
504            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3w(ji  ,jj+1,1) * ( znad + rhd(ji  ,jj+1,1) )   &
505               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
506            ! s-coordinate pressure gradient correction
507            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
508               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
509            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
510               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
511            ! add to the general momentum trend
512            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
513            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
514         END DO
515      END DO
516
517      ! interior value (2=<jk=<jpkm1)
518      DO jk = 2, jpkm1
519         DO jj = 2, jpjm1
520            DO ji = fs_2, fs_jpim1   ! vector opt.
521               ! hydrostatic pressure gradient along s-surfaces
522               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   &
523                  &           * (  fse3w(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad )   &
524                  &              - fse3w(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad )  )
525               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
526                  &           * (  fse3w(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad )   &
527                  &              - fse3w(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad )  )
528               ! s-coordinate pressure gradient correction
529               zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
530                  &           * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj)
531               zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
532                  &           * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj)
533               ! add to the general momentum trend
534               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
535               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
536            END DO
537         END DO
538      END DO
539      !
540      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
541      !
542   END SUBROUTINE hpg_sco
543
544   SUBROUTINE hpg_isf( kt )
545      !!---------------------------------------------------------------------
546      !!                  ***  ROUTINE hpg_sco  ***
547      !!
548      !! ** Method  :   s-coordinate case. Jacobian scheme.
549      !!      The now hydrostatic pressure gradient at a given level, jk,
550      !!      is computed by taking the vertical integral of the in-situ
551      !!      density gradient along the model level from the suface to that
552      !!      level. s-coordinates (ln_sco): a corrective term is added
553      !!      to the horizontal pressure gradient :
554      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
555      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
556      !!      add it to the general momentum trend (ua,va).
557      !!         ua = ua - 1/e1u * zhpi
558      !!         va = va - 1/e2v * zhpj
559      !!      iceload is added and partial cell case are added to the top and bottom
560      !!     
561      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
562      !!----------------------------------------------------------------------
563      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
564      !!
565      INTEGER  ::   ji, jj, jk, iku, ikv, ikt, iktp1i, iktp1j                 ! dummy loop indices
566      REAL(wp) ::   zcoef0, zuap, zvap, znad, ze3wu, ze3wv, zuapint, zvapint, zhpjint, zhpiint, zdzwt, zdzwtjp1, zdzwtip1             ! temporary scalars
567      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  zhpi, zhpj, zrhd
568      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  ztstop
569      REAL(wp), POINTER, DIMENSION(:,:)     ::  ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj
570      !!----------------------------------------------------------------------
571      !
572      CALL wrk_alloc( jpi,jpj, 2, ztstop) 
573      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj, zrhd)
574      CALL wrk_alloc( jpi,jpj, ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj) 
575      !
576     IF( kt == nit000 ) THEN
577         IF(lwp) WRITE(numout,*)
578         IF(lwp) WRITE(numout,*) 'dyn:hpg_isf : hydrostatic pressure gradient trend for ice shelf'
579         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
580      ENDIF
581
582      ! Local constant initialization
583      zcoef0 = - grav * 0.5_wp
584      ! To use density and not density anomaly
585!      IF ( lk_vvl ) THEN   ;     znad = 1._wp          ! Variable volume
586!      ELSE                 ;     znad = 0._wp         ! Fixed volume
587!      ENDIF
588      znad=1._wp
589      ! iniitialised to 0. zhpi zhpi
590      zhpi(:,:,:)=0._wp ; zhpj(:,:,:)=0._wp
591
592!==================================================================================     
593!=====Compute iceload and contribution of the half first wet layer =================
594!===================================================================================
595
596      ! assume water displaced by the ice shelf is at T=-1.9 and S=34.4 (rude)
597      ztstop(:,:,1)=-1.9_wp ; ztstop(:,:,2)=34.4_wp
598
599      ! compute density of the water displaced by the ice shelf
600      zrhd = rhd ! save rhd
601      DO jk = 1, jpk
602           zdept(:,:)=gdept_1d(jk)
603           CALL eos(ztstop(:,:,:),zdept(:,:),rhd(:,:,jk))
604      END DO
605      WHERE ( tmask(:,:,:) == 1._wp)
606        rhd(:,:,:) = zrhd(:,:,:) ! replace wet cell by the saved rhd
607      END WHERE
608     
609      ! compute rhd at the ice/oce interface (ice shelf side)
610      CALL eos(ztstop,risfdep,zrhdtop_isf)
611
612      ! compute rhd at the ice/oce interface (ocean side)
613      DO ji=1,jpi
614        DO jj=1,jpj
615          ikt=mikt(ji,jj)
616          ztstop(ji,jj,1)=tsn(ji,jj,ikt,1)
617          ztstop(ji,jj,2)=tsn(ji,jj,ikt,2)
618        END DO
619      END DO
620      CALL eos(ztstop,risfdep,zrhdtop_oce)
621      !
622      ! Surface value + ice shelf gradient
623      ! compute pressure due to ice shelf load (used to compute hpgi/j for all the level from 1 to miku/v)
624      ziceload = 0._wp
625      DO jj = 1, jpj
626         DO ji = 1, jpi   ! vector opt.
627            ikt=mikt(ji,jj)
628            ziceload(ji,jj) = ziceload(ji,jj) + (znad + rhd(ji,jj,1) ) * fse3w(ji,jj,1) * (1._wp - tmask(ji,jj,1))
629            DO jk=2,ikt-1
630               ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + rhd(ji,jj,jk-1) + rhd(ji,jj,jk)) * fse3w(ji,jj,jk) &
631                  &                              * (1._wp - tmask(ji,jj,jk))
632            END DO
633            IF (ikt .GE. 2) ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhdtop_isf(ji,jj) + rhd(ji,jj,ikt-1)) &
634                               &                              * ( risfdep(ji,jj) - gdept_1d(ikt-1) )
635         END DO
636      END DO
637      riceload(:,:) = 0.0_wp ; riceload(:,:)=ziceload(:,:)  ! need to be saved for diaar5
638      ! compute zp from z=0 to first T wet point (correction due to zps not yet applied)
639      DO jj = 2, jpjm1
640         DO ji = fs_2, fs_jpim1   ! vector opt.
641            ikt=mikt(ji,jj) ; iktp1i=mikt(ji+1,jj); iktp1j=mikt(ji,jj+1)
642            ! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
643            ! we assume ISF is in isostatic equilibrium
644            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( 0.5_wp * fse3w(ji+1,jj  ,iktp1i)                                    &
645               &                                  * ( 2._wp * znad + rhd(ji+1,jj  ,iktp1i) + zrhdtop_oce(ji+1,jj  ) )   &
646               &                                  - 0.5_wp * fse3w(ji  ,jj  ,ikt   )                                    &
647               &                                  * ( 2._wp * znad + rhd(ji  ,jj  ,ikt   ) + zrhdtop_oce(ji  ,jj  ) )   &
648               &                                  + ( ziceload(ji+1,jj) - ziceload(ji,jj))                              ) 
649            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( 0.5_wp * fse3w(ji  ,jj+1,iktp1j)                                    &
650               &                                  * ( 2._wp * znad + rhd(ji  ,jj+1,iktp1j) + zrhdtop_oce(ji  ,jj+1) )   &
651               &                                  - 0.5_wp * fse3w(ji  ,jj  ,ikt   )                                    & 
652               &                                  * ( 2._wp * znad + rhd(ji  ,jj  ,ikt   ) + zrhdtop_oce(ji  ,jj  ) )   &
653               &                                  + ( ziceload(ji,jj+1) - ziceload(ji,jj) )                             ) 
654            ! s-coordinate pressure gradient correction (=0 if z coordinate)
655            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
656               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
657            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
658               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
659            ! add to the general momentum trend
660            ua(ji,jj,1) = ua(ji,jj,1) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
661            va(ji,jj,1) = va(ji,jj,1) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
662         END DO
663      END DO
664!==================================================================================     
665!===== Compute partial cell contribution for the top cell =========================
666!==================================================================================
667      DO jj = 2, jpjm1
668         DO ji = fs_2, fs_jpim1   ! vector opt.
669            iku = miku(ji,jj) ; 
670            zpshpi(ji,jj)=0.0_wp ; zpshpj(ji,jj)=0.0_wp
671            ze3wu  = (gdepw_0(ji+1,jj,iku+1) - gdept_0(ji+1,jj,iku)) - (gdepw_0(ji,jj,iku+1) - gdept_0(ji,jj,iku))
672            ! u direction
673            IF ( iku .GT. 1 ) THEN
674               ! case iku
675               zhpi(ji,jj,iku)   =  zcoef0 / e1u(ji,jj) * ze3wu                                            &
676                      &                                 * ( rhd    (ji+1,jj,iku) + rhd   (ji,jj,iku)       &
677                      &                                   + SIGN(1._wp,ze3wu) * grui(ji,jj) + 2._wp * znad )
678               ! corrective term ( = 0 if z coordinate )
679               zuap              = -zcoef0 * ( arui(ji,jj) + 2._wp * znad ) * gzui(ji,jj) / e1u(ji,jj)
680               ! zhpi will be added in interior loop
681               ua(ji,jj,iku)     = ua(ji,jj,iku) + zuap
682               ! in case of 2 cell water column, need to save the pressure gradient to compute the bottom pressure 
683               IF (mbku(ji,jj) == iku + 1) zpshpi(ji,jj)  = zhpi(ji,jj,iku)
684
685               ! case iku + 1 (remove the zphi term added in the interior loop and compute the one corrected for zps)
686               zhpiint        =  zcoef0 / e1u(ji,jj)                                                               &   
687                  &           * (  fse3w(ji+1,jj  ,iku+1) * ( (rhd(ji+1,jj,iku+1) + znad)                          &
688                  &                                         + (rhd(ji+1,jj,iku  ) + znad) ) * tmask(ji+1,jj,iku)   &
689                  &              - fse3w(ji  ,jj  ,iku+1) * ( (rhd(ji  ,jj,iku+1) + znad)                          &
690                  &                                         + (rhd(ji  ,jj,iku  ) + znad) ) * tmask(ji  ,jj,iku)   )
691               zhpi(ji,jj,iku+1) =  zcoef0 / e1u(ji,jj) * ge3rui(ji,jj) - zhpiint 
692            END IF
693               
694            ! v direction
695            ikv = mikv(ji,jj)
696            ze3wv  = (gdepw_0(ji,jj+1,ikv+1) - gdept_0(ji,jj+1,ikv)) - (gdepw_0(ji,jj,ikv+1) - gdept_0(ji,jj,ikv))
697            IF ( ikv .GT. 1 ) THEN
698               ! case ikv
699               zhpj(ji,jj,ikv)   =  zcoef0 / e2v(ji,jj) * ze3wv                                            &
700                     &                                  * ( rhd(ji,jj+1,ikv) + rhd   (ji,jj,ikv)           &
701                     &                                    + SIGN(1._wp,ze3wv) * grvi(ji,jj) + 2._wp * znad )
702               ! corrective term ( = 0 if z coordinate )
703               zvap              = -zcoef0 * ( arvi(ji,jj) + 2._wp * znad ) * gzvi(ji,jj) / e2v(ji,jj)
704               ! zhpi will be added in interior loop
705               va(ji,jj,ikv)      = va(ji,jj,ikv) + zvap
706               ! in case of 2 cell water column, need to save the pressure gradient to compute the bottom pressure 
707               IF (mbkv(ji,jj) == ikv + 1)  zpshpj(ji,jj)  =  zhpj(ji,jj,ikv) 
708               
709               ! case ikv + 1 (remove the zphj term added in the interior loop and compute the one corrected for zps)
710               zhpjint        =  zcoef0 / e2v(ji,jj)                                                              &
711                  &           * (  fse3w(ji  ,jj+1,ikv+1) * ( (rhd(ji,jj+1,ikv+1) + znad)                         &
712                  &                                       + (rhd(ji,jj+1,ikv  ) + znad) ) * tmask(ji,jj+1,ikv)    &
713                  &              - fse3w(ji  ,jj  ,ikv+1) * ( (rhd(ji,jj  ,ikv+1) + znad)                         &
714                  &                                       + (rhd(ji,jj  ,ikv  ) + znad) ) * tmask(ji,jj  ,ikv)  )
715               zhpj(ji,jj,ikv+1) =  zcoef0 / e2v(ji,jj) * ge3rvi(ji,jj) - zhpjint
716            END IF
717         END DO
718      END DO
719
720!==================================================================================     
721!===== Compute interior value =====================================================
722!==================================================================================
723
724      DO jj = 2, jpjm1
725         DO ji = fs_2, fs_jpim1   ! vector opt.
726            iku=miku(ji,jj); ikv=mikv(ji,jj)
727            DO jk = 2, jpkm1
728               ! hydrostatic pressure gradient along s-surfaces
729               ! zhpi is masked for the first wet cell  (contribution already done in the upper bloc)
730               zhpi(ji,jj,jk) = zhpi(ji,jj,jk) + zhpi(ji,jj,jk-1)                                                              &
731                  &                            + zcoef0 / e1u(ji,jj)                                                           &
732                  &                                     * ( fse3w(ji+1,jj  ,jk) * ( (rhd(ji+1,jj,jk  ) + znad)                 &
733                  &                                                     + (rhd(ji+1,jj,jk-1) + znad) ) * tmask(ji+1,jj,jk-1)   &
734                  &                                       - fse3w(ji  ,jj  ,jk) * ( (rhd(ji  ,jj,jk  ) + znad)                 &
735                  &                                                     + (rhd(ji  ,jj,jk-1) + znad) ) * tmask(ji  ,jj,jk-1)   ) 
736               ! s-coordinate pressure gradient correction
737               ! corrective term, we mask this term for the first wet level beneath the ice shelf (contribution done in the upper bloc)
738               zuap = - zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )                    &
739                  &            * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj) * umask(ji,jj,jk-1)
740               ua(ji,jj,jk) = ua(ji,jj,jk) + ( zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
741
742               ! hydrostatic pressure gradient along s-surfaces
743               ! zhpi is masked for the first wet cell  (contribution already done in the upper bloc)
744               zhpj(ji,jj,jk) = zhpj(ji,jj,jk) + zhpj(ji,jj,jk-1)                                                              &
745                  &                            + zcoef0 / e2v(ji,jj)                                                           &
746                  &                                     * ( fse3w(ji  ,jj+1,jk) * ( (rhd(ji,jj+1,jk  ) + znad)                 &
747                  &                                                     + (rhd(ji,jj+1,jk-1) + znad) ) * tmask(ji,jj+1,jk-1)   &
748                  &                                       - fse3w(ji  ,jj  ,jk) * ( (rhd(ji,jj  ,jk  ) + znad)                 &
749                  &                                                     + (rhd(ji,jj  ,jk-1) + znad) ) * tmask(ji,jj  ,jk-1)   )
750               ! s-coordinate pressure gradient correction
751               ! corrective term, we mask this term for the first wet level beneath the ice shelf (contribution done in the upper bloc)
752               zvap = - zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )                     &
753                  &            * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj) * vmask(ji,jj,jk-1)
754               ! add to the general momentum trend
755               va(ji,jj,jk) = va(ji,jj,jk) + ( zhpj(ji,jj,jk) + zvap ) * vmask(ji,jj,jk)
756            END DO
757         END DO
758      END DO
759
760!==================================================================================     
761!===== Compute bottom cell contribution (partial cell) ============================
762!==================================================================================
763
764      DO jj = 2, jpjm1
765         DO ji = 2, jpim1
766            iku = mbku(ji,jj)
767            ikv = mbkv(ji,jj)
768
769            IF (iku .GT. 1) THEN
770               ! remove old value (interior case)
771               zuap            = -zcoef0 * ( rhd   (ji+1,jj  ,iku) + rhd   (ji,jj,iku) + 2._wp * znad )   &
772                     &                   * ( fsde3w(ji+1,jj  ,iku) - fsde3w(ji,jj,iku) ) / e1u(ji,jj)
773               ua(ji,jj,iku)   = ua(ji,jj,iku) - zhpi(ji,jj,iku) - zuap
774               ! put new value
775               ! -zpshpi to avoid double contribution of the partial step in the top layer
776               zuap            = -zcoef0 * ( aru(ji,jj) + 2._wp * znad ) * gzu(ji,jj)  / e1u(ji,jj)
777               zhpi(ji,jj,iku) =  zhpi(ji,jj,iku-1) + zcoef0 / e1u(ji,jj) * ge3ru(ji,jj) - zpshpi(ji,jj) 
778               ua(ji,jj,iku)   =  ua(ji,jj,iku) + zhpi(ji,jj,iku) + zuap
779            END IF
780            ! v direction
781            IF (ikv .GT. 1) THEN
782               ! remove old value (interior case)
783               zvap            = -zcoef0 * ( rhd   (ji  ,jj+1,ikv) + rhd   (ji,jj,ikv) + 2._wp * znad )   &
784                     &                   * ( fsde3w(ji  ,jj+1,ikv) - fsde3w(ji,jj,ikv) )   / e2v(ji,jj)
785               va(ji,jj,ikv)   = va(ji,jj,ikv) - zhpj(ji,jj,ikv) - zvap
786               ! put new value
787               ! -zpshpj to avoid double contribution of the partial step in the top layer
788               zvap            = -zcoef0 * ( arv(ji,jj) + 2._wp * znad ) * gzv(ji,jj)     / e2v(ji,jj)
789               zhpj(ji,jj,ikv) =  zhpj(ji,jj,ikv-1) + zcoef0 / e2v(ji,jj) * ge3rv(ji,jj) - zpshpj(ji,jj)   
790               va(ji,jj,ikv)   =  va(ji,jj,ikv) + zhpj(ji,jj,ikv) + zvap
791            END IF
792         END DO
793      END DO
794     
795      ! set back to original density value into the ice shelf cell (maybe useless because it is masked)
796      rhd = zrhd
797      !
798      CALL wrk_dealloc( jpi,jpj,2, ztstop)
799      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj, zrhd)
800      CALL wrk_dealloc( jpi,jpj, ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj)
801      !
802   END SUBROUTINE hpg_isf
803
804
805   SUBROUTINE hpg_djc( kt )
806      !!---------------------------------------------------------------------
807      !!                  ***  ROUTINE hpg_djc  ***
808      !!
809      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
810      !!
811      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
812      !!----------------------------------------------------------------------
813      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
814      !!
815      INTEGER  ::   ji, jj, jk          ! dummy loop indices
816      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
817      REAL(wp) ::   z1_10, cffu, cffx   !    "         "
818      REAL(wp) ::   z1_12, cffv, cffy   !    "         "
819      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
820      REAL(wp), POINTER, DIMENSION(:,:,:) ::  dzx, dzy, dzz, dzu, dzv, dzw
821      REAL(wp), POINTER, DIMENSION(:,:,:) ::  drhox, drhoy, drhoz, drhou, drhov, drhow
822      REAL(wp), POINTER, DIMENSION(:,:,:) ::  rho_i, rho_j, rho_k
823      !!----------------------------------------------------------------------
824      !
825      CALL wrk_alloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
826      CALL wrk_alloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
827      CALL wrk_alloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
828      !
829
830      IF( kt == nit000 ) THEN
831         IF(lwp) WRITE(numout,*)
832         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
833         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
834      ENDIF
835
836      ! Local constant initialization
837      zcoef0 = - grav * 0.5_wp
838      z1_10  = 1._wp / 10._wp
839      z1_12  = 1._wp / 12._wp
840
841      !----------------------------------------------------------------------------------------
842      !  compute and store in provisional arrays elementary vertical and horizontal differences
843      !----------------------------------------------------------------------------------------
844
845!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
846
847      DO jk = 2, jpkm1
848         DO jj = 2, jpjm1
849            DO ji = fs_2, fs_jpim1   ! vector opt.
850               drhoz(ji,jj,jk) = rhd   (ji  ,jj  ,jk) - rhd   (ji,jj,jk-1)
851               dzz  (ji,jj,jk) = fsde3w(ji  ,jj  ,jk) - fsde3w(ji,jj,jk-1)
852               drhox(ji,jj,jk) = rhd   (ji+1,jj  ,jk) - rhd   (ji,jj,jk  )
853               dzx  (ji,jj,jk) = fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk  )
854               drhoy(ji,jj,jk) = rhd   (ji  ,jj+1,jk) - rhd   (ji,jj,jk  )
855               dzy  (ji,jj,jk) = fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk  )
856            END DO
857         END DO
858      END DO
859
860      !-------------------------------------------------------------------------
861      ! compute harmonic averages using eq. 5.18
862      !-------------------------------------------------------------------------
863      zep = 1.e-15
864
865!!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
866!!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
867
868      DO jk = 2, jpkm1
869         DO jj = 2, jpjm1
870            DO ji = fs_2, fs_jpim1   ! vector opt.
871               cffw = 2._wp * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
872
873               cffu = 2._wp * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
874               cffx = 2._wp * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
875
876               cffv = 2._wp * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
877               cffy = 2._wp * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
878
879               IF( cffw > zep) THEN
880                  drhow(ji,jj,jk) = 2._wp *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
881                     &                    / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
882               ELSE
883                  drhow(ji,jj,jk) = 0._wp
884               ENDIF
885
886               dzw(ji,jj,jk) = 2._wp *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
887                  &                  / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
888
889               IF( cffu > zep ) THEN
890                  drhou(ji,jj,jk) = 2._wp *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
891                     &                    / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
892               ELSE
893                  drhou(ji,jj,jk ) = 0._wp
894               ENDIF
895
896               IF( cffx > zep ) THEN
897                  dzu(ji,jj,jk) = 2._wp *   dzx(ji+1,jj,jk) * dzx(ji,jj,jk)   &
898                     &                  / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
899               ELSE
900                  dzu(ji,jj,jk) = 0._wp
901               ENDIF
902
903               IF( cffv > zep ) THEN
904                  drhov(ji,jj,jk) = 2._wp *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
905                     &                    / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
906               ELSE
907                  drhov(ji,jj,jk) = 0._wp
908               ENDIF
909
910               IF( cffy > zep ) THEN
911                  dzv(ji,jj,jk) = 2._wp *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
912                     &                  / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
913               ELSE
914                  dzv(ji,jj,jk) = 0._wp
915               ENDIF
916
917            END DO
918         END DO
919      END DO
920
921      !----------------------------------------------------------------------------------
922      ! apply boundary conditions at top and bottom using 5.36-5.37
923      !----------------------------------------------------------------------------------
924      drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5_wp * drhow(:,:,  2  )
925      drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5_wp * drhou(:,:,  2  )
926      drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5_wp * drhov(:,:,  2  )
927
928      drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
929      drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
930      drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
931
932
933      !--------------------------------------------------------------
934      ! Upper half of top-most grid box, compute and store
935      !-------------------------------------------------------------
936
937!!bug gm   :  e3w-de3w = 0.5*e3w  ....  and de3w(2)-de3w(1)=e3w(2) ....   to be verified
938!          true if de3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
939
940      DO jj = 2, jpjm1
941         DO ji = fs_2, fs_jpim1   ! vector opt.
942            rho_k(ji,jj,1) = -grav * ( fse3w(ji,jj,1) - fsde3w(ji,jj,1) )               &
943               &                   * (  rhd(ji,jj,1)                                    &
944               &                     + 0.5_wp * ( rhd(ji,jj,2) - rhd(ji,jj,1) )         &
945               &                              * ( fse3w (ji,jj,1) - fsde3w(ji,jj,1) )   &
946               &                              / ( fsde3w(ji,jj,2) - fsde3w(ji,jj,1) )  )
947         END DO
948      END DO
949
950!!bug gm    : here also, simplification is possible
951!!bug gm    : optimisation: 1/10 and 1/12 the division should be done before the loop
952
953      DO jk = 2, jpkm1
954         DO jj = 2, jpjm1
955            DO ji = fs_2, fs_jpim1   ! vector opt.
956
957               rho_k(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj,jk) + rhd   (ji,jj,jk-1) )                                   &
958                  &                     * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) )                                   &
959                  &            - grav * z1_10 * (                                                                     &
960                  &     ( drhow (ji,jj,jk) - drhow (ji,jj,jk-1) )                                                     &
961                  &   * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
962                  &   - ( dzw   (ji,jj,jk) - dzw   (ji,jj,jk-1) )                                                     &
963                  &   * ( rhd   (ji,jj,jk) - rhd   (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
964                  &                             )
965
966               rho_i(ji,jj,jk) = zcoef0 * ( rhd   (ji+1,jj,jk) + rhd   (ji,jj,jk) )                                   &
967                  &                     * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) )                                   &
968                  &            - grav* z1_10 * (                                                                      &
969                  &     ( drhou (ji+1,jj,jk) - drhou (ji,jj,jk) )                                                     &
970                  &   * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
971                  &   - ( dzu   (ji+1,jj,jk) - dzu   (ji,jj,jk) )                                                     &
972                  &   * ( rhd   (ji+1,jj,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
973                  &                            )
974
975               rho_j(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj+1,jk) + rhd   (ji,jj,jk) )                                   &
976                  &                     * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) )                                   &
977                  &            - grav* z1_10 * (                                                                      &
978                  &     ( drhov (ji,jj+1,jk) - drhov (ji,jj,jk) )                                                     &
979                  &   * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
980                  &   - ( dzv   (ji,jj+1,jk) - dzv   (ji,jj,jk) )                                                     &
981                  &   * ( rhd   (ji,jj+1,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
982                  &                            )
983
984            END DO
985         END DO
986      END DO
987      CALL lbc_lnk(rho_k,'W',1.)
988      CALL lbc_lnk(rho_i,'U',1.)
989      CALL lbc_lnk(rho_j,'V',1.)
990
991
992      ! ---------------
993      !  Surface value
994      ! ---------------
995      DO jj = 2, jpjm1
996         DO ji = fs_2, fs_jpim1   ! vector opt.
997            zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) / e1u(ji,jj)
998            zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) / e2v(ji,jj)
999            ! add to the general momentum trend
1000            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
1001            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
1002         END DO
1003      END DO
1004
1005      ! ----------------
1006      !  interior value   (2=<jk=<jpkm1)
1007      ! ----------------
1008      DO jk = 2, jpkm1
1009         DO jj = 2, jpjm1
1010            DO ji = fs_2, fs_jpim1   ! vector opt.
1011               ! hydrostatic pressure gradient along s-surfaces
1012               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
1013                  &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
1014                  &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) / e1u(ji,jj)
1015               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
1016                  &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
1017                  &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) / e2v(ji,jj)
1018               ! add to the general momentum trend
1019               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
1020               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
1021            END DO
1022         END DO
1023      END DO
1024      !
1025      CALL wrk_dealloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
1026      CALL wrk_dealloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
1027      CALL wrk_dealloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
1028      !
1029   END SUBROUTINE hpg_djc
1030
1031
1032   SUBROUTINE hpg_prj( kt )
1033      !!---------------------------------------------------------------------
1034      !!                  ***  ROUTINE hpg_prj  ***
1035      !!
1036      !! ** Method  :   s-coordinate case.
1037      !!      A Pressure-Jacobian horizontal pressure gradient method
1038      !!      based on the constrained cubic-spline interpolation for
1039      !!      all vertical coordinate systems
1040      !!
1041      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
1042      !!----------------------------------------------------------------------
1043      INTEGER, PARAMETER  :: polynomial_type = 1    ! 1: cubic spline, 2: linear
1044      INTEGER, INTENT(in) ::   kt                   ! ocean time-step index
1045      !!
1046      INTEGER  ::   ji, jj, jk, jkk                 ! dummy loop indices
1047      REAL(wp) ::   zcoef0, znad                    ! temporary scalars
1048      !!
1049      !! The local variables for the correction term
1050      INTEGER  :: jk1, jis, jid, jjs, jjd
1051      REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
1052      REAL(wp) :: zrhdt1
1053      REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
1054      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdept, zrhh
1055      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
1056      REAL(wp), POINTER, DIMENSION(:,:)   ::   zsshu_n, zsshv_n
1057      !!----------------------------------------------------------------------
1058      !
1059      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
1060      CALL wrk_alloc( jpi,jpj,jpk, zdept, zrhh )
1061      CALL wrk_alloc( jpi,jpj, zsshu_n, zsshv_n )
1062      !
1063      IF( kt == nit000 ) THEN
1064         IF(lwp) WRITE(numout,*)
1065         IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
1066         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, cubic spline pressure Jacobian'
1067      ENDIF
1068
1069      !!----------------------------------------------------------------------
1070      ! Local constant initialization
1071      zcoef0 = - grav
1072      znad = 0.0_wp
1073      IF( lk_vvl ) znad = 1._wp
1074
1075      ! Clean 3-D work arrays
1076      zhpi(:,:,:) = 0._wp
1077      zrhh(:,:,:) = rhd(:,:,:)
1078
1079      ! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
1080      DO jj = 1, jpj
1081        DO ji = 1, jpi
1082          jk = mbathy(ji,jj)
1083          IF( jk <= 0 ) THEN; zrhh(ji,jj,:) = 0._wp
1084          ELSE IF(jk == 1) THEN; zrhh(ji,jj, jk+1:jpk) = rhd(ji,jj,jk)
1085          ELSE IF(jk < jpkm1) THEN
1086             DO jkk = jk+1, jpk
1087                zrhh(ji,jj,jkk) = interp1(fsde3w(ji,jj,jkk),   fsde3w(ji,jj,jkk-1), &
1088                                         fsde3w(ji,jj,jkk-2), rhd(ji,jj,jkk-1), rhd(ji,jj,jkk-2))
1089             END DO
1090          ENDIF
1091        END DO
1092      END DO
1093
1094      ! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
1095      DO jj = 1, jpj
1096         DO ji = 1, jpi
1097            zdept(ji,jj,1) = 0.5_wp * fse3w(ji,jj,1) - sshn(ji,jj) * znad
1098         END DO
1099      END DO
1100
1101      DO jk = 2, jpk
1102         DO jj = 1, jpj
1103            DO ji = 1, jpi
1104               zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + fse3w(ji,jj,jk)
1105            END DO
1106         END DO
1107      END DO
1108
1109      fsp(:,:,:) = zrhh (:,:,:)
1110      xsp(:,:,:) = zdept(:,:,:)
1111
1112      ! Construct the vertical density profile with the
1113      ! constrained cubic spline interpolation
1114      ! rho(z) = asp + bsp*z + csp*z^2 + dsp*z^3
1115      CALL cspline(fsp,xsp,asp,bsp,csp,dsp,polynomial_type)
1116
1117      ! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
1118      DO jj = 2, jpj
1119        DO ji = 2, jpi
1120          zrhdt1 = zrhh(ji,jj,1) - interp3(zdept(ji,jj,1),asp(ji,jj,1), &
1121                                         bsp(ji,jj,1),   csp(ji,jj,1), &
1122                                         dsp(ji,jj,1) ) * 0.25_wp * fse3w(ji,jj,1)
1123
1124          ! assuming linear profile across the top half surface layer
1125          zhpi(ji,jj,1) =  0.5_wp * fse3w(ji,jj,1) * zrhdt1
1126        END DO
1127      END DO
1128
1129      ! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
1130      DO jk = 2, jpkm1
1131        DO jj = 2, jpj
1132          DO ji = 2, jpi
1133            zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) +                          &
1134                             integ_spline(zdept(ji,jj,jk-1), zdept(ji,jj,jk),&
1135                                    asp(ji,jj,jk-1),    bsp(ji,jj,jk-1), &
1136                                    csp(ji,jj,jk-1),    dsp(ji,jj,jk-1))
1137          END DO
1138        END DO
1139      END DO
1140
1141      ! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
1142
1143      ! Prepare zsshu_n and zsshv_n
1144      DO jj = 2, jpjm1
1145        DO ji = 2, jpim1
1146          zsshu_n(ji,jj) = (e12u(ji,jj) * sshn(ji,jj) + e12u(ji+1, jj) * sshn(ji+1,jj)) * &
1147                         & r1_e12u(ji,jj) * umask(ji,jj,1) * 0.5_wp 
1148          zsshv_n(ji,jj) = (e12v(ji,jj) * sshn(ji,jj) + e12v(ji+1, jj) * sshn(ji,jj+1)) * &
1149                         & r1_e12v(ji,jj) * vmask(ji,jj,1) * 0.5_wp 
1150        END DO
1151      END DO
1152
1153      DO jj = 2, jpjm1
1154        DO ji = 2, jpim1
1155          zu(ji,jj,1) = - ( fse3u(ji,jj,1) - zsshu_n(ji,jj) * znad) 
1156          zv(ji,jj,1) = - ( fse3v(ji,jj,1) - zsshv_n(ji,jj) * znad)
1157        END DO
1158      END DO
1159
1160      DO jk = 2, jpkm1
1161        DO jj = 2, jpjm1
1162          DO ji = 2, jpim1
1163            zu(ji,jj,jk) = zu(ji,jj,jk-1)- fse3u(ji,jj,jk)
1164            zv(ji,jj,jk) = zv(ji,jj,jk-1)- fse3v(ji,jj,jk)
1165          END DO
1166        END DO
1167      END DO
1168
1169      DO jk = 1, jpkm1
1170        DO jj = 2, jpjm1
1171          DO ji = 2, jpim1
1172            zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * fse3u(ji,jj,jk)
1173            zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * fse3v(ji,jj,jk)
1174          END DO
1175        END DO
1176      END DO
1177
1178      DO jk = 1, jpkm1
1179        DO jj = 2, jpjm1
1180          DO ji = 2, jpim1
1181            zu(ji,jj,jk) = min(zu(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
1182            zu(ji,jj,jk) = max(zu(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
1183            zv(ji,jj,jk) = min(zv(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
1184            zv(ji,jj,jk) = max(zv(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
1185          END DO
1186        END DO
1187      END DO
1188
1189
1190      DO jk = 1, jpkm1
1191        DO jj = 2, jpjm1
1192          DO ji = 2, jpim1
1193            zpwes = 0._wp; zpwed = 0._wp
1194            zpnss = 0._wp; zpnsd = 0._wp
1195            zuijk = zu(ji,jj,jk)
1196            zvijk = zv(ji,jj,jk)
1197
1198            !!!!!     for u equation
1199            IF( jk <= mbku(ji,jj) ) THEN
1200               IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1201                 jis = ji + 1; jid = ji
1202               ELSE
1203                 jis = ji;     jid = ji +1
1204               ENDIF
1205
1206               ! integrate the pressure on the shallow side
1207               jk1 = jk
1208               DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1209                 IF( jk1 == mbku(ji,jj) ) THEN
1210                   zuijk = -zdept(jis,jj,jk1)
1211                   EXIT
1212                 ENDIF
1213                 zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1214                 zpwes = zpwes +                                    &
1215                      integ_spline(zdept(jis,jj,jk1), zdeps,            &
1216                             asp(jis,jj,jk1),    bsp(jis,jj,jk1), &
1217                             csp(jis,jj,jk1),    dsp(jis,jj,jk1))
1218                 jk1 = jk1 + 1
1219               END DO
1220
1221               ! integrate the pressure on the deep side
1222               jk1 = jk
1223               DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1224                 IF( jk1 == 1 ) THEN
1225                   zdeps = zdept(jid,jj,1) + MIN(zuijk, sshn(jid,jj)*znad)
1226                   zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1227                                                     bsp(jid,jj,1),   csp(jid,jj,1), &
1228                                                     dsp(jid,jj,1)) * zdeps
1229                   zpwed  = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1230                   EXIT
1231                 ENDIF
1232                 zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1233                 zpwed = zpwed +                                        &
1234                        integ_spline(zdeps,              zdept(jid,jj,jk1), &
1235                               asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1),  &
1236                               csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1237                 jk1 = jk1 - 1
1238               END DO
1239
1240               ! update the momentum trends in u direction
1241
1242               zdpdx1 = zcoef0 / e1u(ji,jj) * (zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk))
1243               IF( lk_vvl ) THEN
1244                 zdpdx2 = zcoef0 / e1u(ji,jj) * &
1245                         ( REAL(jis-jid, wp) * (zpwes + zpwed) + (sshn(ji+1,jj)-sshn(ji,jj)) )
1246                ELSE
1247                 zdpdx2 = zcoef0 / e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1248               ENDIF
1249
1250               ua(ji,jj,jk) = ua(ji,jj,jk) + (zdpdx1 + zdpdx2) * &
1251               &           umask(ji,jj,jk) * tmask(ji,jj,jk) * tmask(ji+1,jj,jk)
1252            ENDIF
1253
1254            !!!!!     for v equation
1255            IF( jk <= mbkv(ji,jj) ) THEN
1256               IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1257                 jjs = jj + 1; jjd = jj
1258               ELSE
1259                 jjs = jj    ; jjd = jj + 1
1260               ENDIF
1261
1262               ! integrate the pressure on the shallow side
1263               jk1 = jk
1264               DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1265                 IF( jk1 == mbkv(ji,jj) ) THEN
1266                   zvijk = -zdept(ji,jjs,jk1)
1267                   EXIT
1268                 ENDIF
1269                 zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1270                 zpnss = zpnss +                                      &
1271                        integ_spline(zdept(ji,jjs,jk1), zdeps,            &
1272                               asp(ji,jjs,jk1),    bsp(ji,jjs,jk1), &
1273                               csp(ji,jjs,jk1),    dsp(ji,jjs,jk1) )
1274                 jk1 = jk1 + 1
1275               END DO
1276
1277               ! integrate the pressure on the deep side
1278               jk1 = jk
1279               DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1280                 IF( jk1 == 1 ) THEN
1281                   zdeps = zdept(ji,jjd,1) + MIN(zvijk, sshn(ji,jjd)*znad)
1282                   zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1283                                                     bsp(ji,jjd,1),   csp(ji,jjd,1), &
1284                                                     dsp(ji,jjd,1) ) * zdeps
1285                   zpnsd  = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1286                   EXIT
1287                 ENDIF
1288                 zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1289                 zpnsd = zpnsd +                                        &
1290                        integ_spline(zdeps,              zdept(ji,jjd,jk1), &
1291                               asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1292                               csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1293                 jk1 = jk1 - 1
1294               END DO
1295
1296
1297               ! update the momentum trends in v direction
1298
1299               zdpdy1 = zcoef0 / e2v(ji,jj) * (zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk))
1300               IF( lk_vvl ) THEN
1301                   zdpdy2 = zcoef0 / e2v(ji,jj) * &
1302                           ( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (sshn(ji,jj+1)-sshn(ji,jj)) )
1303               ELSE
1304                   zdpdy2 = zcoef0 / e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1305               ENDIF
1306
1307               va(ji,jj,jk) = va(ji,jj,jk) + (zdpdy1 + zdpdy2)*&
1308               &              vmask(ji,jj,jk)*tmask(ji,jj,jk)*tmask(ji,jj+1,jk)
1309            ENDIF
1310
1311
1312           END DO
1313        END DO
1314      END DO
1315      !
1316      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
1317      CALL wrk_dealloc( jpi,jpj,jpk, zdept, zrhh )
1318      CALL wrk_dealloc( jpi,jpj, zsshu_n, zsshv_n )
1319      !
1320   END SUBROUTINE hpg_prj
1321
1322
1323   SUBROUTINE cspline(fsp, xsp, asp, bsp, csp, dsp, polynomial_type)
1324      !!----------------------------------------------------------------------
1325      !!                 ***  ROUTINE cspline  ***
1326      !!
1327      !! ** Purpose :   constrained cubic spline interpolation
1328      !!
1329      !! ** Method  :   f(x) = asp + bsp*x + csp*x^2 + dsp*x^3
1330      !!
1331      !! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1332      !!----------------------------------------------------------------------
1333      IMPLICIT NONE
1334      REAL(wp), DIMENSION(:,:,:), INTENT(in)  :: fsp, xsp           ! value and coordinate
1335      REAL(wp), DIMENSION(:,:,:), INTENT(out) :: asp, bsp, csp, dsp ! coefficients of
1336                                                                    ! the interpoated function
1337      INTEGER, INTENT(in) :: polynomial_type                        ! 1: cubic spline
1338                                                                    ! 2: Linear
1339      !
1340      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
1341      INTEGER  ::   jpi, jpj, jpkm1
1342      REAL(wp) ::   zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1343      REAL(wp) ::   zdxtmp1, zdxtmp2, zalpha
1344      REAL(wp) ::   zdf(size(fsp,3))
1345      !!----------------------------------------------------------------------
1346
1347      jpi   = size(fsp,1)
1348      jpj   = size(fsp,2)
1349      jpkm1 = size(fsp,3) - 1
1350
1351
1352      IF (polynomial_type == 1) THEN     ! Constrained Cubic Spline
1353         DO ji = 1, jpi
1354            DO jj = 1, jpj
1355           !!Fritsch&Butland's method, 1984 (preferred, but more computation)
1356           !    DO jk = 2, jpkm1-1
1357           !       zdxtmp1 = xsp(ji,jj,jk)   - xsp(ji,jj,jk-1)
1358           !       zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1359           !       zdf1    = ( fsp(ji,jj,jk)   - fsp(ji,jj,jk-1) ) / zdxtmp1
1360           !       zdf2    = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk)   ) / zdxtmp2
1361           !
1362           !       zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1363           !
1364           !       IF(zdf1 * zdf2 <= 0._wp) THEN
1365           !           zdf(jk) = 0._wp
1366           !       ELSE
1367           !         zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1368           !       ENDIF
1369           !    END DO
1370
1371           !!Simply geometric average
1372               DO jk = 2, jpkm1-1
1373                  zdf1 = (fsp(ji,jj,jk) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk) - xsp(ji,jj,jk-1))
1374                  zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk))
1375
1376                  IF(zdf1 * zdf2 <= 0._wp) THEN
1377                     zdf(jk) = 0._wp
1378                  ELSE
1379                     zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1380                  ENDIF
1381               END DO
1382
1383               zdf(1)     = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1384                          &          ( xsp(ji,jj,2) - xsp(ji,jj,1) ) -  0.5_wp * zdf(2)
1385               zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1386                          &          ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - &
1387                          & 0.5_wp * zdf(jpkm1 - 1)
1388
1389               DO jk = 1, jpkm1 - 1
1390                 zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1391                 ztmp1  = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1392                 ztmp2  =  6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1393                 zddf1  = -2._wp * ztmp1 + ztmp2
1394                 ztmp1  = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1395                 zddf2  =  2._wp * ztmp1 - ztmp2
1396
1397                 dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1398                 csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1399                 bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1400                               & csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1401                               & dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1402                               &                   xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1403                 asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1404                               &                (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1405                               &                 dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1406               END DO
1407            END DO
1408         END DO
1409
1410      ELSE IF (polynomial_type == 2) THEN     ! Linear
1411         DO ji = 1, jpi
1412            DO jj = 1, jpj
1413               DO jk = 1, jpkm1-1
1414                  zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1415                  ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1416
1417                  dsp(ji,jj,jk) = 0._wp
1418                  csp(ji,jj,jk) = 0._wp
1419                  bsp(ji,jj,jk) = ztmp1 / zdxtmp
1420                  asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1421               END DO
1422            END DO
1423         END DO
1424
1425      ELSE
1426           CALL ctl_stop( 'invalid polynomial type in cspline' )
1427      ENDIF
1428
1429   END SUBROUTINE cspline
1430
1431
1432   FUNCTION interp1(x, xl, xr, fl, fr)  RESULT(f)
1433      !!----------------------------------------------------------------------
1434      !!                 ***  ROUTINE interp1  ***
1435      !!
1436      !! ** Purpose :   1-d linear interpolation
1437      !!
1438      !! ** Method  :   interpolation is straight forward
1439      !!                extrapolation is also permitted (no value limit)
1440      !!----------------------------------------------------------------------
1441      IMPLICIT NONE
1442      REAL(wp), INTENT(in) ::  x, xl, xr, fl, fr
1443      REAL(wp)             ::  f ! result of the interpolation (extrapolation)
1444      REAL(wp)             ::  zdeltx
1445      !!----------------------------------------------------------------------
1446
1447      zdeltx = xr - xl
1448      IF(abs(zdeltx) <= 10._wp * EPSILON(x)) THEN
1449        f = 0.5_wp * (fl + fr)
1450      ELSE
1451        f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1452      ENDIF
1453
1454   END FUNCTION interp1
1455
1456
1457   FUNCTION interp2(x, a, b, c, d)  RESULT(f)
1458      !!----------------------------------------------------------------------
1459      !!                 ***  ROUTINE interp1  ***
1460      !!
1461      !! ** Purpose :   1-d constrained cubic spline interpolation
1462      !!
1463      !! ** Method  :  cubic spline interpolation
1464      !!
1465      !!----------------------------------------------------------------------
1466      IMPLICIT NONE
1467      REAL(wp), INTENT(in) ::  x, a, b, c, d
1468      REAL(wp)             ::  f ! value from the interpolation
1469      !!----------------------------------------------------------------------
1470
1471      f = a + x* ( b + x * ( c + d * x ) )
1472
1473   END FUNCTION interp2
1474
1475
1476   FUNCTION interp3(x, a, b, c, d)  RESULT(f)
1477      !!----------------------------------------------------------------------
1478      !!                 ***  ROUTINE interp1  ***
1479      !!
1480      !! ** Purpose :   Calculate the first order of deriavtive of
1481      !!                a cubic spline function y=a+b*x+c*x^2+d*x^3
1482      !!
1483      !! ** Method  :   f=dy/dx=b+2*c*x+3*d*x^2
1484      !!
1485      !!----------------------------------------------------------------------
1486      IMPLICIT NONE
1487      REAL(wp), INTENT(in) ::  x, a, b, c, d
1488      REAL(wp)             ::  f ! value from the interpolation
1489      !!----------------------------------------------------------------------
1490
1491      f = b + x * ( 2._wp * c + 3._wp * d * x)
1492
1493   END FUNCTION interp3
1494
1495
1496   FUNCTION integ_spline(xl, xr, a, b, c, d)  RESULT(f)
1497      !!----------------------------------------------------------------------
1498      !!                 ***  ROUTINE interp1  ***
1499      !!
1500      !! ** Purpose :   1-d constrained cubic spline integration
1501      !!
1502      !! ** Method  :  integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1503      !!
1504      !!----------------------------------------------------------------------
1505      IMPLICIT NONE
1506      REAL(wp), INTENT(in) ::  xl, xr, a, b, c, d
1507      REAL(wp)             ::  za1, za2, za3
1508      REAL(wp)             ::  f                   ! integration result
1509      !!----------------------------------------------------------------------
1510
1511      za1 = 0.5_wp * b
1512      za2 = c / 3.0_wp
1513      za3 = 0.25_wp * d
1514
1515      f  = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1516         & xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1517
1518   END FUNCTION integ_spline
1519
1520   !!======================================================================
1521END MODULE dynhpg
1522
Note: See TracBrowser for help on using the repository browser.