New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
nemogcm.F90 in branches/UKMO/dev_r5518_GO6_package_port2021/NEMOGCM/NEMO/OFF_SRC – NEMO

source: branches/UKMO/dev_r5518_GO6_package_port2021/NEMOGCM/NEMO/OFF_SRC/nemogcm.F90 @ 15338

Last change on this file since 15338 was 15338, checked in by andmirek, 3 years ago

Ticket GO29: tests 5 and 6

File size: 31.8 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Off-line Ocean   : passive tracer evolution, dynamics read in files
5   !!======================================================================
6   !! History :  3.3  ! 2010-05  (C. Ethe)  Full reorganization of the off-line: phasing with the on-line
7   !!            4.0  ! 2011-01  (C. Ethe, A. R. Porter, STFC Daresbury) dynamical allocation
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   nemo_gcm        : off-line: solve ocean tracer only
12   !!   nemo_init       : initialization of the nemo model
13   !!   nemo_ctl        : initialisation of algorithm flag
14   !!   nemo_closefile  : close remaining files
15   !!----------------------------------------------------------------------
16   USE dom_oce         ! ocean space domain variables
17   USE oce             ! dynamics and tracers variables
18   USE c1d             ! 1D configuration
19   USE domcfg          ! domain configuration               (dom_cfg routine)
20   USE domain          ! domain initialization from coordinate & bathymetry (dom_init routine)
21   USE domrea          ! domain initialization from mesh_mask            (dom_init routine)
22   USE eosbn2          ! equation of state            (eos bn2 routine)
23   !              ! ocean physics
24   USE ldftra          ! lateral diffusivity setting    (ldf_tra_init routine)
25   USE ldfslp          ! slopes of neutral surfaces     (ldf_slp_init routine)
26   USE traqsr          ! solar radiation penetration    (tra_qsr_init routine)
27   USE trabbl          ! bottom boundary layer          (tra_bbl_init routine)
28   USE zdfini          ! vertical physics: initialization
29   USE sbcmod          ! surface boundary condition       (sbc_init     routine)
30   USE phycst          ! physical constant                  (par_cst routine)
31   USE dtadyn          ! Lecture and Interpolation of the dynamical fields
32   USE trcini          ! Initilization of the passive tracers
33   USE daymod          ! calendar                         (day     routine)
34   USE trcstp          ! passive tracer time-stepping      (trc_stp routine)
35   USE dtadyn          ! Lecture and interpolation of the dynamical fields
36   !              ! I/O & MPP
37   USE iom             ! I/O library
38   USE in_out_manager  ! I/O manager
39   USE mppini          ! shared/distributed memory setting (mpp_init routine)
40   USE lib_mpp         ! distributed memory computing
41#if defined key_iomput
42   USE xios
43#endif
44   USE prtctl          ! Print control                    (prt_ctl_init routine)
45   USE timing          ! Timing
46   USE lib_fortran     ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
47   USE lbcnfd, ONLY: isendto, nsndto, nfsloop, nfeloop ! Setup of north fold exchanges
48
49   USE trc
50   USE trcnam
51   USE trcrst
52   USE diaptr         ! Need to initialise this as some variables are used in if statements later
53
54   IMPLICIT NONE
55   PRIVATE
56   
57   PUBLIC   nemo_gcm   ! called by nemo.F90
58
59   CHARACTER (len=64) ::   cform_aaa="( /, 'AAAAAAAA', / ) "   ! flag for output listing
60
61   !!----------------------------------------------------------------------
62   !! NEMO/OFF 3.3 , NEMO Consortium (2010)
63   !! $Id$
64   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
65   !!----------------------------------------------------------------------
66CONTAINS
67
68   SUBROUTINE nemo_gcm
69      !!----------------------------------------------------------------------
70      !!                     ***  ROUTINE nemo_gcm  ***
71      !!
72      !! ** Purpose :   nemo solves the primitive equations on an orthogonal
73      !!      curvilinear mesh on the sphere.
74      !!
75      !! ** Method  : - model general initialization
76      !!              - launch the time-stepping (dta_dyn and trc_stp)
77      !!              - finalize the run by closing files and communications
78      !!
79      !! References : Madec, Delecluse,Imbard, and Levy, 1997:  internal report, IPSL.
80      !!              Madec, 2008, internal report, IPSL.
81      !!----------------------------------------------------------------------
82      INTEGER :: istp, indic       ! time step index
83      !!----------------------------------------------------------------------
84
85      CALL nemo_init  ! Initializations
86
87      ! check that all process are still there... If some process have an error,
88      ! they will never enter in step and other processes will wait until the end of the cpu time!
89      IF( lk_mpp )   CALL mpp_max( nstop )
90
91      !                            !-----------------------!
92      !                            !==   time stepping   ==!
93      !                            !-----------------------!
94      istp = nit000
95      nstop = 0
96      !
97      CALL iom_init( cxios_context )            ! iom_put initialization (must be done after nemo_init for AGRIF+XIOS+OASIS)
98      !
99      DO WHILE ( istp <= nitend .AND. nstop == 0 )    ! time stepping
100         !
101         IF( istp /= nit000 )   CALL day      ( istp )         ! Calendar (day was already called at nit000 in day_init)
102                                CALL iom_setkt( istp - nit000 + 1, "nemo" )   ! say to iom that we are at time step kstp
103                                CALL dta_dyn  ( istp )         ! Interpolation of the dynamical fields
104                                CALL trc_stp  ( istp )         ! time-stepping
105                                CALL stp_ctl  ( istp, indic )  ! Time loop: control and print
106         istp = istp + 1
107         IF( lk_mpp )   CALL mpp_max( nstop )
108      END DO
109#if defined key_iomput
110      CALL iom_context_finalize( cxios_context ) ! needed for XIOS+AGRIF
111#endif
112
113      !                            !------------------------!
114      !                            !==  finalize the run  ==!
115      !                            !------------------------!
116      IF(lwp) WRITE(numout,cform_aaa)                 ! Flag AAAAAAA
117
118      IF( nstop /= 0 .AND. lwp ) THEN                 ! error print
119         WRITE(numout,cform_err)
120         WRITE(numout,*) nstop, ' error have been found'
121      ENDIF
122      !
123      IF( nn_timing == 1 )   CALL timing_finalize
124      !
125      CALL nemo_closefile
126      !
127# if defined key_iomput
128      CALL xios_finalize             ! end mpp communications
129# else
130      IF( lk_mpp )   CALL mppstop       ! end mpp communications
131# endif
132      !
133   END SUBROUTINE nemo_gcm
134
135
136   SUBROUTINE nemo_init
137      !!----------------------------------------------------------------------
138      !!                     ***  ROUTINE nemo_init ***
139      !!
140      !! ** Purpose :   initialization of the nemo model in off-line mode
141      !!----------------------------------------------------------------------
142      INTEGER ::   ji            ! dummy loop indices
143      INTEGER ::   ilocal_comm   ! local integer
144      INTEGER ::   ios
145      LOGICAL ::   llexist
146      CHARACTER(len=80), DIMENSION(16) ::   cltxt
147      !!
148      NAMELIST/namctl/ ln_ctl  , nn_print, nn_ictls, nn_ictle,   &
149         &             nn_isplt, nn_jsplt, nn_jctls, nn_jctle,   &
150         &             nn_bench, nn_timing
151      NAMELIST/namcfg/ cp_cfg, cp_cfz, jp_cfg, jpidta, jpjdta, jpkdta, jpiglo, jpjglo, &
152         &             jpizoom, jpjzoom, jperio, ln_use_jattr
153      !!----------------------------------------------------------------------
154      cltxt = ''
155      cxios_context = 'nemo'
156      !
157      !                             ! Open reference namelist and configuration namelist files
158      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
159      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
160      !
161      REWIND( numnam_ref )              ! Namelist namctl in reference namelist : Control prints & Benchmark
162      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
163901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
164
165      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist : Control prints & Benchmark
166      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
167902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
168
169      !
170      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist : Control prints & Benchmark
171      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
172903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
173
174      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist : Control prints & Benchmark
175      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
176904   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
177
178      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
179      lflush    = ln_flush          ! convert namelist variable to model variable
180      !
181      !                             !--------------------------------------------!
182      !                             !  set communicator & select the local node  !
183      !                             !  NB: mynode also opens output.namelist.dyn !
184      !                             !      on unit number numond on first proc   !
185      !                             !--------------------------------------------!
186#if defined key_iomput
187      CALL  xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm )
188      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )   ! Nodes selection
189#else
190      ilocal_comm = 0
191      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )                ! Nodes selection (control print return in cltxt)
192#endif
193
194      narea = narea + 1                       ! mynode return the rank of proc (0 --> jpnij -1 )
195
196      lwm = (narea == 1)                      ! control of output namelists
197      lwp = (narea == 1) .OR. ln_ctl          ! control of all listing output print
198
199      IF(lwm) THEN
200         ! write merged namelists from earlier to output namelist now that the
201         ! file has been opened in call to mynode. nammpp has already been
202         ! written in mynode (if lk_mpp_mpi)
203         WRITE( numond, namctl )
204         WRITE( numond, namcfg )
205      ENDIF
206
207      ! If dimensions of processor grid weren't specified in the namelist file
208      ! then we calculate them here now that we have our communicator size
209      IF( (jpni < 1) .OR. (jpnj < 1) )THEN
210#if   defined key_mpp_mpi
211         CALL nemo_partition(mppsize)
212#else
213         jpni = 1
214         jpnj = 1
215         jpnij = jpni*jpnj
216#endif
217      END IF
218
219      ! Calculate domain dimensions given calculated jpni and jpnj
220      ! This used to be done in par_oce.F90 when they were parameters rather
221      ! than variables
222      jpi = ( jpiglo-2*jpreci + (jpni-1) ) / jpni + 2*jpreci   ! first  dim.
223      jpj = ( jpjglo-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj   ! second dim.
224      jpk = jpkdta                                             ! third dim
225      jpim1 = jpi-1                                            ! inner domain indices
226      jpjm1 = jpj-1                                            !   "           "
227      jpkm1 = jpk-1                                            !   "           "
228      jpij  = jpi*jpj                                          !  jpi x j
229
230
231      IF(lwp) THEN                            ! open listing units
232         !
233         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
234         !
235         WRITE(numout,*)
236         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
237         WRITE(numout,*) '                       NEMO team'
238         WRITE(numout,*) '            Ocean General Circulation Model'
239         WRITE(numout,*) '                  version 3.6  (2015) '
240         WRITE(numout,*)
241         WRITE(numout,*)
242         DO ji = 1, SIZE(cltxt) 
243            IF( TRIM(cltxt(ji)) /= '' )   WRITE(numout,*) cltxt(ji)      ! control print of mynode
244         END DO
245         WRITE(numout,cform_aaa)                                         ! Flag AAAAAAA
246         !
247      ENDIF
248
249      ! Now we know the dimensions of the grid and numout has been set we can
250      ! allocate arrays
251      CALL nemo_alloc()
252
253      !                             !--------------------------------!
254      !                             !  Model general initialization  !
255      !                             !--------------------------------!
256
257      CALL nemo_ctl                           ! Control prints & Benchmark
258
259      !                                      ! Domain decomposition
260      IF( jpni*jpnj == jpnij ) THEN   ;   CALL mpp_init      ! standard cutting out
261      ELSE                            ;   CALL mpp_init2     ! eliminate land processors
262      ENDIF
263      !
264      IF( nn_timing == 1 )  CALL timing_init
265      !
266
267      !                                      ! General initialization
268      IF( nn_timing == 1 )  CALL timing_start( 'nemo_init')
269      !
270                            CALL     phy_cst    ! Physical constants
271                            CALL     eos_init   ! Equation of state
272      IF( lk_c1d        )   CALL     c1d_init   ! 1D column configuration
273                            CALL     dom_cfg    ! Domain configuration
274      !
275      INQUIRE( FILE='coordinates.nc', EXIST = llexist )   ! Check if coordinate file exist
276      !
277      IF( llexist )  THEN  ;  CALL  dom_init   !  compute the grid from coordinates and bathymetry
278      ELSE                 ;  CALL  dom_rea    !  read grid from the meskmask
279      ENDIF
280                            CALL  istate_init   ! ocean initial state (Dynamics and tracers)
281
282      IF( ln_nnogather )    CALL nemo_northcomms   ! Initialise the northfold neighbour lists (must be done after the masks are defined)
283
284      IF( ln_ctl        )   CALL prt_ctl_init   ! Print control
285
286                            CALL     sbc_init   ! Forcings : surface module
287
288#if ! defined key_degrad
289                            CALL ldf_tra_init   ! Lateral ocean tracer physics
290#endif
291      IF( lk_ldfslp )       CALL ldf_slp_init   ! slope of lateral mixing
292
293                            CALL tra_qsr_init   ! penetrative solar radiation qsr
294      IF( lk_trabbl     )   CALL tra_bbl_init   ! advective (and/or diffusive) bottom boundary layer scheme
295
296                            CALL trc_nam_run    ! Needed to get restart parameters for passive tracers
297                            CALL trc_rst_cal( nit000, 'READ' )   ! calendar
298                            CALL dta_dyn_init   ! Initialization for the dynamics
299
300                            CALL     trc_init   ! Passive tracers initialization
301                            CALL dia_ptr_init   ! Initialise diaptr as some variables are used
302      !                                         ! in various advection and diffusion routines
303      IF(lwp) WRITE(numout,cform_aaa)           ! Flag AAAAAAA
304      !
305      IF( nn_timing == 1 )  CALL timing_stop( 'nemo_init')
306      !
307   END SUBROUTINE nemo_init
308
309
310   SUBROUTINE nemo_ctl
311      !!----------------------------------------------------------------------
312      !!                     ***  ROUTINE nemo_ctl  ***
313      !!
314      !! ** Purpose :   control print setting
315      !!
316      !! ** Method  : - print namctl information and check some consistencies
317      !!----------------------------------------------------------------------
318      !
319      IF(lwp) THEN                  ! Parameter print
320         WRITE(numout,*)
321         WRITE(numout,*) 'nemo_flg: Control prints & Benchmark'
322         WRITE(numout,*) '~~~~~~~ '
323         WRITE(numout,*) '   Namelist namctl'
324         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
325         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
326         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
327         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
328         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
329         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
330         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
331         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
332         WRITE(numout,*) '      benchmark parameter (0/1)       nn_bench   = ', nn_bench
333      ENDIF
334      !
335      nictls    = nn_ictls
336      nictle    = nn_ictle
337      njctls    = nn_jctls
338      njctle    = nn_jctle
339      isplt     = nn_isplt
340      jsplt     = nn_jsplt
341      nbench    = nn_bench
342     IF(lwp) THEN                  ! control print
343         WRITE(numout,*)
344         WRITE(numout,*) 'namcfg  : configuration initialization through namelist read'
345         WRITE(numout,*) '~~~~~~~ '
346         WRITE(numout,*) '   Namelist namcfg'
347         WRITE(numout,*) '      configuration name              cp_cfg      = ', TRIM(cp_cfg)
348         WRITE(numout,*) '      configuration resolution        jp_cfg      = ', jp_cfg
349         WRITE(numout,*) '      1st lateral dimension ( >= jpi ) jpidta     = ', jpidta
350         WRITE(numout,*) '      2nd    "         "    ( >= jpj ) jpjdta     = ', jpjdta
351         WRITE(numout,*) '      3nd    "         "               jpkdta     = ', jpkdta
352         WRITE(numout,*) '      1st dimension of global domain in i jpiglo  = ', jpiglo
353         WRITE(numout,*) '      2nd    -                  -    in j jpjglo  = ', jpjglo
354         WRITE(numout,*) '      left bottom i index of the zoom (in data domain) jpizoom = ', jpizoom
355         WRITE(numout,*) '      left bottom j index of the zoom (in data domain) jpizoom = ', jpjzoom
356         WRITE(numout,*) '      lateral cond. type (between 0 and 6) jperio = ', jperio   
357         WRITE(numout,*) '      use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr
358      ENDIF
359      !                             ! Parameter control
360      !
361      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
362         IF( lk_mpp ) THEN
363            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real splitted domain
364         ELSE
365            IF( isplt == 1 .AND. jsplt == 1  ) THEN
366               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
367                  &           ' - the print control will be done over the whole domain' )
368            ENDIF
369            ijsplt = isplt * jsplt            ! total number of processors ijsplt
370         ENDIF
371         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
372         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
373         !
374         !                              ! indices used for the SUM control
375         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
376            lsp_area = .FALSE.
377         ELSE                                             ! print control done over a specific  area
378            lsp_area = .TRUE.
379            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
380               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
381               nictls = 1
382            ENDIF
383            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
384               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
385               nictle = jpiglo
386            ENDIF
387            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
388               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
389               njctls = 1
390            ENDIF
391            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
392               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
393               njctle = jpjglo
394            ENDIF
395         ENDIF
396      ENDIF
397      !
398      IF( nbench == 1 )   THEN            ! Benchmark
399         SELECT CASE ( cp_cfg )
400         CASE ( 'gyre' )   ;   CALL ctl_warn( ' The Benchmark is activated ' )
401         CASE DEFAULT      ;   CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:',   &
402            &                                 ' cp_cfg="gyre" in namelsit &namcfg or set nbench = 0' )
403         END SELECT
404      ENDIF
405      !
406      IF( lk_c1d .AND. .NOT.lk_iomput )   CALL ctl_stop( 'nemo_ctl: The 1D configuration must be used ',   &
407         &                                               'with the IOM Input/Output manager. '        ,   &
408         &                                               'Compile with key_iomput enabled' )
409      !
410      IF( 1_wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ',  &
411         &                                               'f2003 standard. '                              ,  &
412         &                                               'Compile with key_nosignedzero enabled' )
413      !
414   END SUBROUTINE nemo_ctl
415
416
417   SUBROUTINE nemo_closefile
418      !!----------------------------------------------------------------------
419      !!                     ***  ROUTINE nemo_closefile  ***
420      !!
421      !! ** Purpose :   Close the files
422      !!----------------------------------------------------------------------
423      !
424      IF ( lk_mpp ) CALL mppsync
425      !
426      CALL iom_close                                 ! close all input/output files managed by iom_*
427      !
428      IF( numstp     /= -1 )   CLOSE( numstp     )   ! time-step file
429      IF( numnam_ref /= -1 )   CLOSE( numnam_ref )   ! oce reference namelist
430      IF( numnam_cfg /= -1 )   CLOSE( numnam_cfg )   ! oce configuration namelist
431      IF( numout     /=  6 )   CLOSE( numout     )   ! standard model output file
432      numout = 6                                     ! redefine numout in case it is used after this point...
433      !
434   END SUBROUTINE nemo_closefile
435
436
437   SUBROUTINE nemo_alloc
438      !!----------------------------------------------------------------------
439      !!                     ***  ROUTINE nemo_alloc  ***
440      !!
441      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
442      !!
443      !! ** Method  :
444      !!----------------------------------------------------------------------
445      USE diawri,       ONLY: dia_wri_alloc
446      USE dom_oce,      ONLY: dom_oce_alloc
447      USE zdf_oce,      ONLY: zdf_oce_alloc
448      USE ldftra_oce,   ONLY: ldftra_oce_alloc
449      USE trc_oce,      ONLY: trc_oce_alloc
450      !
451      INTEGER :: ierr
452      !!----------------------------------------------------------------------
453      !
454      ierr =        oce_alloc       ()          ! ocean
455      ierr = ierr + dia_wri_alloc   ()
456      ierr = ierr + dom_oce_alloc   ()          ! ocean domain
457      ierr = ierr + ldftra_oce_alloc()          ! ocean lateral  physics : tracers
458      ierr = ierr + zdf_oce_alloc   ()          ! ocean vertical physics
459      !
460      ierr = ierr + trc_oce_alloc   ()          ! shared TRC / TRA arrays
461      !
462      IF( lk_mpp    )   CALL mpp_sum( ierr )
463      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
464      !
465   END SUBROUTINE nemo_alloc
466
467
468   SUBROUTINE nemo_partition( num_pes )
469      !!----------------------------------------------------------------------
470      !!                 ***  ROUTINE nemo_partition  ***
471      !!
472      !! ** Purpose :   
473      !!
474      !! ** Method  :
475      !!----------------------------------------------------------------------
476      INTEGER, INTENT(in) :: num_pes ! The number of MPI processes we have
477      !
478      INTEGER, PARAMETER :: nfactmax = 20
479      INTEGER :: nfact ! The no. of factors returned
480      INTEGER :: ierr  ! Error flag
481      INTEGER :: ji
482      INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
483      INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
484      !!----------------------------------------------------------------------
485
486      ierr = 0
487
488      CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
489
490      IF( nfact <= 1 ) THEN
491         WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
492         WRITE (numout, *) '       : using grid of ',num_pes,' x 1'
493         jpnj = 1
494         jpni = num_pes
495      ELSE
496         ! Search through factors for the pair that are closest in value
497         mindiff = 1000000
498         imin    = 1
499         DO ji = 1, nfact-1, 2
500            idiff = ABS( ifact(ji) - ifact(ji+1) )
501            IF( idiff < mindiff ) THEN
502               mindiff = idiff
503               imin = ji
504            ENDIF
505         END DO
506         jpnj = ifact(imin)
507         jpni = ifact(imin + 1)
508      ENDIF
509      !
510      jpnij = jpni*jpnj
511      !
512   END SUBROUTINE nemo_partition
513
514
515   SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
516      !!----------------------------------------------------------------------
517      !!                     ***  ROUTINE factorise  ***
518      !!
519      !! ** Purpose :   return the prime factors of n.
520      !!                knfax factors are returned in array kfax which is of
521      !!                maximum dimension kmaxfax.
522      !! ** Method  :
523      !!----------------------------------------------------------------------
524      INTEGER                    , INTENT(in   ) ::   kn, kmaxfax
525      INTEGER                    , INTENT(  out) ::   kerr, knfax
526      INTEGER, DIMENSION(kmaxfax), INTENT(  out) ::   kfax
527      !
528      INTEGER :: ifac, jl, inu
529      INTEGER, PARAMETER :: ntest = 14
530      INTEGER :: ilfax(ntest)
531      !
532      ! lfax contains the set of allowed factors.
533      data (ilfax(jl),jl=1,ntest) / 16384, 8192, 4096, 2048, 1024, 512, 256,  &
534         &                            128,   64,   32,   16,    8,   4,   2  /
535      !!----------------------------------------------------------------------
536
537      ! Clear the error flag and initialise output vars
538      kerr = 0
539      kfax = 1
540      knfax = 0
541
542      ! Find the factors of n.
543      IF( kn == 1 )   GOTO 20
544
545      ! nu holds the unfactorised part of the number.
546      ! knfax holds the number of factors found.
547      ! l points to the allowed factor list.
548      ! ifac holds the current factor.
549
550      inu   = kn
551      knfax = 0
552
553      DO jl = ntest, 1, -1
554         !
555         ifac = ilfax(jl)
556         IF( ifac > inu )   CYCLE
557
558         ! Test whether the factor will divide.
559
560         IF( MOD(inu,ifac) == 0 ) THEN
561            !
562            knfax = knfax + 1            ! Add the factor to the list
563            IF( knfax > kmaxfax ) THEN
564               kerr = 6
565               write (*,*) 'FACTOR: insufficient space in factor array ', knfax
566               return
567            ENDIF
568            kfax(knfax) = ifac
569            ! Store the other factor that goes with this one
570            knfax = knfax + 1
571            kfax(knfax) = inu / ifac
572            !WRITE (*,*) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
573         ENDIF
574         !
575      END DO
576
577   20 CONTINUE      ! Label 20 is the exit point from the factor search loop.
578      !
579   END SUBROUTINE factorise
580
581#if defined key_mpp_mpi
582   SUBROUTINE nemo_northcomms
583      !!======================================================================
584      !!                     ***  ROUTINE  nemo_northcomms  ***
585      !! nemo_northcomms    :  Setup for north fold exchanges with explicit
586      !!                       point-to-point messaging
587      !!=====================================================================
588      !!----------------------------------------------------------------------
589      !!
590      !! ** Purpose :   Initialization of the northern neighbours lists.
591      !!----------------------------------------------------------------------
592      !!    1.0  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE)
593      !!    2.0  ! 2013-06 Setup avoiding MPI communication (I. Epicoco, S.
594      !Mocavero, CMCC)
595      !!----------------------------------------------------------------------
596
597      INTEGER  ::   sxM, dxM, sxT, dxT, jn
598      INTEGER  ::   njmppmax
599
600      njmppmax = MAXVAL( njmppt )
601
602      !initializes the north-fold communication variables
603      isendto(:) = 0
604      nsndto = 0
605
606      !if I am a process in the north
607      IF ( njmpp == njmppmax ) THEN
608          !sxM is the first point (in the global domain) needed to compute the
609          !north-fold for the current process
610          sxM = jpiglo - nimppt(narea) - nlcit(narea) + 1
611          !dxM is the last point (in the global domain) needed to compute the
612          !north-fold for the current process
613          dxM = jpiglo - nimppt(narea) + 2
614
615          !loop over the other north-fold processes to find the processes
616          !managing the points belonging to the sxT-dxT range
617
618          DO jn = 1, jpni
619                !sxT is the first point (in the global domain) of the jn
620                !process
621                sxT = nfiimpp(jn, jpnj)
622                !dxT is the last point (in the global domain) of the jn
623                !process
624                dxT = nfiimpp(jn, jpnj) + nfilcit(jn, jpnj) - 1
625                IF ((sxM .gt. sxT) .AND. (sxM .lt. dxT)) THEN
626                   nsndto = nsndto + 1
627                     isendto(nsndto) = jn
628                ELSEIF ((sxM .le. sxT) .AND. (dxM .ge. dxT)) THEN
629                   nsndto = nsndto + 1
630                     isendto(nsndto) = jn
631                ELSEIF ((dxM .lt. dxT) .AND. (sxT .lt. dxM)) THEN
632                   nsndto = nsndto + 1
633                     isendto(nsndto) = jn
634                END IF
635          END DO
636          nfsloop = 1
637          nfeloop = nlci
638          DO jn = 2,jpni-1
639           IF(nfipproc(jn,jpnj) .eq. (narea - 1)) THEN
640              IF (nfipproc(jn - 1 ,jpnj) .eq. -1) THEN
641                 nfsloop = nldi
642              ENDIF
643              IF (nfipproc(jn + 1,jpnj) .eq. -1) THEN
644                 nfeloop = nlei
645              ENDIF
646           ENDIF
647        END DO
648
649      ENDIF
650      l_north_nogather = .TRUE.
651   END SUBROUTINE nemo_northcomms
652#else
653   SUBROUTINE nemo_northcomms      ! Dummy routine
654      WRITE(*,*) 'nemo_northcomms: You should not have seen this print! error?'
655   END SUBROUTINE nemo_northcomms
656#endif
657
658   SUBROUTINE istate_init
659      !!----------------------------------------------------------------------
660      !!                   ***  ROUTINE istate_init  ***
661      !!
662      !! ** Purpose :   Initialization to zero of the dynamics and tracers.
663      !!----------------------------------------------------------------------
664      !
665      !     now fields         !     after fields      !
666      un   (:,:,:)   = 0._wp   ;   ua(:,:,:) = 0._wp   !
667      vn   (:,:,:)   = 0._wp   ;   va(:,:,:) = 0._wp   !
668      wn   (:,:,:)   = 0._wp   !                       !
669      hdivn(:,:,:)   = 0._wp   !                       !
670      tsn  (:,:,:,:) = 0._wp   !                       !
671      !
672      rhd  (:,:,:) = 0.e0
673      rhop (:,:,:) = 0.e0
674      rn2  (:,:,:) = 0.e0
675      !
676   END SUBROUTINE istate_init
677
678   SUBROUTINE stp_ctl( kt, kindic )
679      !!----------------------------------------------------------------------
680      !!                    ***  ROUTINE stp_ctl  ***
681      !!
682      !! ** Purpose :   Control the run
683      !!
684      !! ** Method  : - Save the time step in numstp
685      !!
686      !! ** Actions :   'time.step' file containing the last ocean time-step
687      !!----------------------------------------------------------------------
688      INTEGER, INTENT(in   ) ::   kt      ! ocean time-step index
689      INTEGER, INTENT(inout) ::   kindic  ! indicator of solver convergence
690      !!----------------------------------------------------------------------
691      !
692      IF( kt == nit000 .AND. lwp ) THEN
693         WRITE(numout,*)
694         WRITE(numout,*) 'stp_ctl : time-stepping control'
695         WRITE(numout,*) '~~~~~~~'
696         ! open time.step file
697         CALL ctl_opn( numstp, 'time.step', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
698      ENDIF
699      !
700      IF(lwp) WRITE ( numstp, '(1x, i8)' )   kt      !* save the current time step in numstp
701      IF(lwp) REWIND( numstp )                       ! --------------------------
702      !
703   END SUBROUTINE stp_ctl
704   !!======================================================================
705END MODULE nemogcm
Note: See TracBrowser for help on using the repository browser.