New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
nemogcm.F90 in branches/UKMO/dev_r5518_GO6_package_port2021/NEMOGCM/NEMO/OOO_SRC – NEMO

source: branches/UKMO/dev_r5518_GO6_package_port2021/NEMOGCM/NEMO/OOO_SRC/nemogcm.F90 @ 15338

Last change on this file since 15338 was 15338, checked in by andmirek, 3 years ago

Ticket GO29: tests 5 and 6

File size: 30.9 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  LIM sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!            3.4  ! 2011-11  (C. Harris) decomposition changes for running with CICE
31   !!----------------------------------------------------------------------
32
33   !!----------------------------------------------------------------------
34   !!   nemo_gcm       : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
35   !!   nemo_init      : initialization of the NEMO system
36   !!   nemo_ctl       : initialisation of the contol print
37   !!   nemo_closefile : close remaining open files
38   !!   nemo_alloc     : dynamical allocation
39   !!   nemo_partition : calculate MPP domain decomposition
40   !!   factorise      : calculate the factors of the no. of MPI processes
41   !!----------------------------------------------------------------------
42   USE step_oce        ! module used in the ocean time stepping module
43   USE domcfg          ! domain configuration               (dom_cfg routine)
44   USE mppini          ! shared/distributed memory setting (mpp_init routine)
45   USE domain          ! domain initialization             (dom_init routine)
46#if defined key_nemocice_decomp
47   USE ice_domain_size, only: nx_global, ny_global
48#endif
49   USE istate          ! initial state setting          (istate_init routine)
50   USE phycst          ! physical constant                  (par_cst routine)
51   USE diaobs          ! Observation diagnostics       (dia_obs_init routine)
52   USE lib_fortran     ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
53   USE step            ! NEMO time-stepping                 (stp     routine)
54   USE icbini          ! handle bergs, initialisation
55   USE icbstp          ! handle bergs, calving, themodynamics and transport
56   USE cpl_oasis3      ! OASIS3 coupling
57   USE lib_mpp         ! distributed memory computing
58#if defined key_iomput
59   USE xios
60#endif
61   USE ooo_data        ! Offline obs_oper data
62   USE ooo_read        ! Offline obs_oper read routines
63   USE ooo_intp        ! Offline obs_oper interpolation
64
65   IMPLICIT NONE
66   PRIVATE
67
68   PUBLIC   nemo_gcm    ! called by nemo.f90
69   PUBLIC   nemo_init   ! needed by AGRIF
70   PUBLIC   nemo_alloc  ! needed by TAM
71
72   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
73
74   !!----------------------------------------------------------------------
75   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
76   !! $Id$
77   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
78   !!----------------------------------------------------------------------
79CONTAINS
80
81   SUBROUTINE nemo_gcm
82         !!----------------------------------------------------------------------
83         !!                    ***  SUBROUTINE offline_obs_oper ***
84         !!
85         !! ** Purpose : To use NEMO components to interpolate model fields
86         !!              to observation space.
87         !!
88         !! ** Method : 1. Initialise NEMO
89         !!             2. Initialise offline obs_oper
90         !!             3. Cycle through match ups
91         !!             4. Write results to file
92         !!
93         !!----------------------------------------------------------------------
94         !! Class 4 output stream switch
95         USE obs_fbm, ONLY: ln_cl4
96         !! Initialise NEMO
97         CALL nemo_init
98         !! Initialise Offline obs_oper data
99         CALL ooo_data_init( ln_cl4 )
100         !! Loop over various model counterparts
101         DO jimatch = 1, cl4_match_len
102            IF (jimatch .GT. 1) THEN
103               !! Initialise obs_oper
104               CALL dia_obs_init
105            END IF
106            !! Interpolate to observation space
107            CALL ooo_interp
108            !! Pipe to output files
109            CALL dia_obs_wri
110            !! Reset the obs_oper between
111            CALL dia_obs_dealloc
112         END DO
113         !! Safely stop MPI
114         IF(lk_mpp) CALL mppstop  ! end mpp communications
115   END SUBROUTINE nemo_gcm
116
117   SUBROUTINE nemo_init
118      !!----------------------------------------------------------------------
119      !!                     ***  ROUTINE nemo_init  ***
120      !!
121      !! ** Purpose :   initialization of the NEMO GCM
122      !!----------------------------------------------------------------------
123      INTEGER ::   ji            ! dummy loop indices
124      INTEGER ::   ilocal_comm   ! local integer
125      CHARACTER(len=80), DIMENSION(16) ::   cltxt
126      !!
127      NAMELIST/namctl/ ln_ctl, nn_print, nn_ictls, nn_ictle,   &
128         &             nn_isplt, nn_jsplt, nn_jctls, nn_jctle,   &
129         &             nn_bench, nn_timing
130      NAMELIST/namcfg/ cp_cfg, cp_cfz, jp_cfg, jpidta, jpjdta, jpkdta, jpiglo, jpjglo, &
131         &             jpizoom, jpjzoom, jperio, ln_use_jattr
132      !!----------------------------------------------------------------------
133      !
134      cltxt = ''
135      cxios_context = 'nemo'
136      !
137      !                             ! Open reference namelist and configuration namelist files
138      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
139      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
140      !
141      REWIND( numnam_ref )              ! Namelist namctl in reference namelist : Control prints & Benchmark
142      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
143901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
144
145      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist : Control prints & Benchmark
146      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
147902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
148
149      !
150      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist : Control prints & Benchmark
151      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
152903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
153
154      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist : Control prints & Benchmark
155      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
156904   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
157      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
158      lflush    = ln_flush          ! convert namelist variable to model variable
159      !                             !--------------------------------------------!
160      !                             !  set communicator & select the local node  !
161      !                             !  NB: mynode also opens output.namelist.dyn !
162      !                             !      on unit number numond on first proc   !
163      !                             !--------------------------------------------!
164#if defined key_iomput
165      IF( Agrif_Root() ) THEN
166         IF( lk_oasis ) THEN
167            CALL cpl_init( ilocal_comm )                               ! nemo local communicator given by oasis
168            CALL xios_initialize( "oceanx",local_comm=ilocal_comm )    ! send nemo communicator to xios
169         ELSE
170            CALL  xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm )    ! nemo local communicator given by xios
171         ENDIF
172      ENDIF
173      ENDIF
174      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )   ! Nodes selection
175#else
176      IF( lk_oasis ) THEN
177         IF( Agrif_Root() ) THEN
178            CALL cpl_init( ilocal_comm )                               ! nemo local communicator given by oasis
179         ENDIF
180         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )   ! Nodes selection (control print return in cltxt)
181      ELSE
182         ilocal_comm = 0
183         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )                ! Nodes selection (control print return in cltxt)
184      ENDIF
185#endif
186      narea = narea + 1                                     ! mynode return the rank of proc (0 --> jpnij -1 )
187
188      lwm = (narea == 1)                                    ! control of output namelists
189      lwp = (narea == 1) .OR. ln_ctl                        ! control of all listing output print
190
191      IF(lwm) THEN
192         ! write merged namelists from earlier to output namelist now that the
193         ! file has been opened in call to mynode. nammpp has already been
194         ! written in mynode (if lk_mpp_mpi)
195         WRITE( numond, namctl )
196         WRITE( numond, namcfg )
197      ENDIF
198
199      ! If dimensions of processor grid weren't specified in the namelist file
200      ! then we calculate them here now that we have our communicator size
201      IF( (jpni < 1) .OR. (jpnj < 1) )THEN
202#if   defined key_mpp_mpi
203         IF( Agrif_Root() ) CALL nemo_partition(mppsize)
204#else
205         jpni  = 1
206         jpnj  = 1
207         jpnij = jpni*jpnj
208#endif
209      END IF
210
211      ! Calculate domain dimensions given calculated jpni and jpnj
212      ! This used to be done in par_oce.F90 when they were parameters rather
213      ! than variables
214      IF( Agrif_Root() ) THEN
215#if defined key_nemocice_decomp
216         jpi = ( nx_global+2-2*jpreci + (jpni-1) ) / jpni + 2*jpreci ! first  dim.
217         jpj = ( ny_global+2-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj ! second dim.
218#else
219         jpi = ( jpiglo-2*jpreci + (jpni-1) ) / jpni + 2*jpreci   ! first  dim.
220         jpj = ( jpjglo-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj   ! second dim.
221#endif
222         jpk = jpkdta                                             ! third dim
223         jpim1 = jpi-1                                            ! inner domain indices
224         jpjm1 = jpj-1                                            !   "           "
225         jpkm1 = jpk-1                                            !   "           "
226         jpij  = jpi*jpj                                          !  jpi x j
227      ENDIF
228
229      IF(lwp) THEN                            ! open listing units
230         !
231         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
232         !
233         WRITE(numout,*)
234         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
235         WRITE(numout,*) '                       NEMO team'
236         WRITE(numout,*) '            Ocean General Circulation Model'
237         WRITE(numout,*) '                  version 3.6  (2015) '
238         WRITE(numout,*)
239         WRITE(numout,*)
240         DO ji = 1, SIZE(cltxt)
241            IF( TRIM(cltxt(ji)) /= '' )   WRITE(numout,*) cltxt(ji)      ! control print of mynode
242         END DO
243         WRITE(numout,cform_aaa)                                         ! Flag AAAAAAA
244         !
245      ENDIF
246
247      ! Now we know the dimensions of the grid and numout has been set we can
248      ! allocate arrays
249      CALL nemo_alloc()
250
251      !                             !-------------------------------!
252      !                             !  NEMO general initialization  !
253      !                             !-------------------------------!
254
255      CALL nemo_ctl                          ! Control prints & Benchmark
256
257      !                                      ! Domain decomposition
258      IF( jpni*jpnj == jpnij ) THEN   ;   CALL mpp_init      ! standard cutting out
259      ELSE                            ;   CALL mpp_init2     ! eliminate land processors
260      ENDIF
261      !
262      IF( nn_timing == 1 )  CALL timing_init
263      !
264      !                                      ! General initialization
265                            CALL     phy_cst    ! Physical constants
266                            CALL     eos_init   ! Equation of state
267                            CALL     dom_cfg    ! Domain configuration
268                            CALL     dom_init   ! Domain
269
270      IF( ln_nnogather )    CALL nemo_northcomms   ! Initialise the northfold neighbour lists (must be done after the masks are defined)
271
272      IF( ln_ctl        )   CALL prt_ctl_init   ! Print control
273
274                            CALL  istate_init   ! ocean initial state (Dynamics and tracers)
275
276      IF( lk_diaobs     ) THEN                  ! Observation & model comparison
277                            CALL dia_obs_init            ! Initialize observational data
278                            CALL dia_obs( nit000 - 1 )   ! Observation operator for restart
279      ENDIF
280   END SUBROUTINE nemo_init
281
282
283   SUBROUTINE nemo_ctl
284      !!----------------------------------------------------------------------
285      !!                     ***  ROUTINE nemo_ctl  ***
286      !!
287      !! ** Purpose :   control print setting
288      !!
289      !! ** Method  : - print namctl information and check some consistencies
290      !!----------------------------------------------------------------------
291      !
292      IF(lwp) THEN                  ! control print
293         WRITE(numout,*)
294         WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark'
295         WRITE(numout,*) '~~~~~~~ '
296         WRITE(numout,*) '   Namelist namctl'
297         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
298         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
299         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
300         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
301         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
302         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
303         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
304         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
305         WRITE(numout,*) '      benchmark parameter (0/1)       nn_bench   = ', nn_bench
306         WRITE(numout,*) '      timing activated    (0/1)       nn_timing  = ', nn_timing
307      ENDIF
308      !
309      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
310      nictls    = nn_ictls
311      nictle    = nn_ictle
312      njctls    = nn_jctls
313      njctle    = nn_jctle
314      isplt     = nn_isplt
315      jsplt     = nn_jsplt
316      nbench    = nn_bench
317      !                             ! Parameter control
318      !
319      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
320         IF( lk_mpp .AND. jpnij > 1 ) THEN
321            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
322         ELSE
323            IF( isplt == 1 .AND. jsplt == 1  ) THEN
324               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
325                  &           ' - the print control will be done over the whole domain' )
326            ENDIF
327            ijsplt = isplt * jsplt            ! total number of processors ijsplt
328         ENDIF
329         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
330         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
331         !
332         !                              ! indices used for the SUM control
333         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
334            lsp_area = .FALSE.
335         ELSE                                             ! print control done over a specific  area
336            lsp_area = .TRUE.
337            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
338               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
339               nictls = 1
340            ENDIF
341            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
342               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
343               nictle = jpiglo
344            ENDIF
345            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
346               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
347               njctls = 1
348            ENDIF
349            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
350               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
351               njctle = jpjglo
352            ENDIF
353         ENDIF
354      ENDIF
355      !
356      IF( nbench == 1 ) THEN              ! Benchmark
357         SELECT CASE ( cp_cfg )
358         CASE ( 'gyre' )   ;   CALL ctl_warn( ' The Benchmark is activated ' )
359         CASE DEFAULT      ;   CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:',   &
360            &                                 ' key_gyre must be used or set nbench = 0' )
361         END SELECT
362      ENDIF
363      !
364      IF( lk_c1d .AND. .NOT.lk_iomput )   CALL ctl_stop( 'nemo_ctl: The 1D configuration must be used ',   &
365         &                                               'with the IOM Input/Output manager. '         ,   &
366         &                                               'Compile with key_iomput enabled' )
367      !
368      IF( 1_wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ',  &
369         &                                               'f2003 standard. '                              ,  &
370         &                                               'Compile with key_nosignedzero enabled' )
371      !
372   END SUBROUTINE nemo_ctl
373
374
375   SUBROUTINE nemo_closefile
376      !!----------------------------------------------------------------------
377      !!                     ***  ROUTINE nemo_closefile  ***
378      !!
379      !! ** Purpose :   Close the files
380      !!----------------------------------------------------------------------
381      !
382      IF( lk_mpp )   CALL mppsync
383      !
384      CALL iom_close                                 ! close all input/output files managed by iom_*
385      !
386      IF( numstp      /= -1 )   CLOSE( numstp      )   ! time-step file
387      IF( numsol      /= -1 )   CLOSE( numsol      )   ! solver file
388      IF( numnam      /= -1 )   CLOSE( numnam      )   ! oce namelist
389      IF( numnam_ice  /= -1 )   CLOSE( numnam_ice  )   ! ice namelist
390      IF( numevo_ice  /= -1 )   CLOSE( numevo_ice  )   ! ice variables (temp. evolution)
391      IF( numout      /=  6 )   CLOSE( numout      )   ! standard model output file
392      IF( numdct_vol  /= -1 )   CLOSE( numdct_vol  )   ! volume transports
393      IF( numdct_heat /= -1 )   CLOSE( numdct_heat )   ! heat transports
394      IF( numdct_salt /= -1 )   CLOSE( numdct_salt )   ! salt transports
395
396      !
397      numout = 6                                     ! redefine numout in case it is used after this point...
398      !
399   END SUBROUTINE nemo_closefile
400
401
402   SUBROUTINE nemo_alloc
403      !!----------------------------------------------------------------------
404      !!                     ***  ROUTINE nemo_alloc  ***
405      !!
406      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
407      !!
408      !! ** Method  :
409      !!----------------------------------------------------------------------
410      USE diawri    , ONLY: dia_wri_alloc
411      USE dom_oce   , ONLY: dom_oce_alloc
412      !
413      INTEGER :: ierr
414      !!----------------------------------------------------------------------
415      !
416      ierr =        oce_alloc       ()          ! ocean
417      ierr = ierr + dia_wri_alloc   ()
418      ierr = ierr + dom_oce_alloc   ()          ! ocean domain
419      !
420      ierr = ierr + lib_mpp_alloc   (numout)    ! mpp exchanges
421      !
422      IF( lk_mpp    )   CALL mpp_sum( ierr )
423      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
424      !
425   END SUBROUTINE nemo_alloc
426
427
428   SUBROUTINE nemo_partition( num_pes )
429      !!----------------------------------------------------------------------
430      !!                 ***  ROUTINE nemo_partition  ***
431      !!
432      !! ** Purpose :
433      !!
434      !! ** Method  :
435      !!----------------------------------------------------------------------
436      INTEGER, INTENT(in) :: num_pes ! The number of MPI processes we have
437      !
438      INTEGER, PARAMETER :: nfactmax = 20
439      INTEGER :: nfact ! The no. of factors returned
440      INTEGER :: ierr  ! Error flag
441      INTEGER :: ji
442      INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
443      INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
444      !!----------------------------------------------------------------------
445
446      ierr = 0
447
448      CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
449
450      IF( nfact <= 1 ) THEN
451         WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
452         WRITE (numout, *) '       : using grid of ',num_pes,' x 1'
453         jpnj = 1
454         jpni = num_pes
455      ELSE
456         ! Search through factors for the pair that are closest in value
457         mindiff = 1000000
458         imin    = 1
459         DO ji = 1, nfact-1, 2
460            idiff = ABS( ifact(ji) - ifact(ji+1) )
461            IF( idiff < mindiff ) THEN
462               mindiff = idiff
463               imin = ji
464            ENDIF
465         END DO
466         jpnj = ifact(imin)
467         jpni = ifact(imin + 1)
468      ENDIF
469      !
470      jpnij = jpni*jpnj
471      !
472   END SUBROUTINE nemo_partition
473
474
475   SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
476      !!----------------------------------------------------------------------
477      !!                     ***  ROUTINE factorise  ***
478      !!
479      !! ** Purpose :   return the prime factors of n.
480      !!                knfax factors are returned in array kfax which is of
481      !!                maximum dimension kmaxfax.
482      !! ** Method  :
483      !!----------------------------------------------------------------------
484      INTEGER                    , INTENT(in   ) ::   kn, kmaxfax
485      INTEGER                    , INTENT(  out) ::   kerr, knfax
486      INTEGER, DIMENSION(kmaxfax), INTENT(  out) ::   kfax
487      !
488      INTEGER :: ifac, jl, inu
489      INTEGER, PARAMETER :: ntest = 14
490      INTEGER :: ilfax(ntest)
491
492      ! lfax contains the set of allowed factors.
493      data (ilfax(jl),jl=1,ntest) / 16384, 8192, 4096, 2048, 1024, 512, 256,  &
494         &                            128,   64,   32,   16,    8,   4,   2  /
495      !!----------------------------------------------------------------------
496
497      ! Clear the error flag and initialise output vars
498      kerr = 0
499      kfax = 1
500      knfax = 0
501
502      ! Find the factors of n.
503      IF( kn == 1 )   GOTO 20
504
505      ! nu holds the unfactorised part of the number.
506      ! knfax holds the number of factors found.
507      ! l points to the allowed factor list.
508      ! ifac holds the current factor.
509
510      inu   = kn
511      knfax = 0
512
513      DO jl = ntest, 1, -1
514         !
515         ifac = ilfax(jl)
516         IF( ifac > inu )   CYCLE
517
518         ! Test whether the factor will divide.
519
520         IF( MOD(inu,ifac) == 0 ) THEN
521            !
522            knfax = knfax + 1            ! Add the factor to the list
523            IF( knfax > kmaxfax ) THEN
524               kerr = 6
525               write (*,*) 'FACTOR: insufficient space in factor array ', knfax
526               return
527            ENDIF
528            kfax(knfax) = ifac
529            ! Store the other factor that goes with this one
530            knfax = knfax + 1
531            kfax(knfax) = inu / ifac
532            !WRITE (*,*) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
533         ENDIF
534         !
535      END DO
536
537   20 CONTINUE      ! Label 20 is the exit point from the factor search loop.
538      !
539   END SUBROUTINE factorise
540
541#if defined key_mpp_mpi
542   SUBROUTINE nemo_northcomms
543      !!======================================================================
544      !!                     ***  ROUTINE  nemo_northcomms  ***
545      !! nemo_northcomms    :  Setup for north fold exchanges with explicit peer to peer messaging
546      !!=====================================================================
547      !!----------------------------------------------------------------------
548      !!
549      !! ** Purpose :   Initialization of the northern neighbours lists.
550      !!----------------------------------------------------------------------
551      !!    1.0  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE)
552      !!----------------------------------------------------------------------
553
554      INTEGER ::   ji, jj, jk, ij, jtyp    ! dummy loop indices
555      INTEGER ::   ijpj                    ! number of rows involved in north-fold exchange
556      INTEGER ::   northcomms_alloc        ! allocate return status
557      REAL(wp), ALLOCATABLE, DIMENSION ( :,: ) ::   znnbrs     ! workspace
558      LOGICAL,  ALLOCATABLE, DIMENSION ( : )   ::   lrankset   ! workspace
559
560      IF(lwp) WRITE(numout,*)
561      IF(lwp) WRITE(numout,*) 'nemo_northcomms : Initialization of the northern neighbours lists'
562      IF(lwp) WRITE(numout,*) '~~~~~~~~~~'
563
564      !!----------------------------------------------------------------------
565      ALLOCATE( znnbrs(jpi,jpj), stat = northcomms_alloc )
566      ALLOCATE( lrankset(jpnij), stat = northcomms_alloc )
567      IF( northcomms_alloc /= 0 ) THEN
568         WRITE(numout,cform_war)
569         WRITE(numout,*) 'northcomms_alloc : failed to allocate arrays'
570         CALL ctl_stop( 'STOP', 'nemo_northcomms : unable to allocate temporary arrays' )
571      ENDIF
572      nsndto = 0
573      isendto = -1
574      ijpj   = 4
575      !
576      ! This routine has been called because ln_nnogather has been set true ( nammpp )
577      ! However, these first few exchanges have to use the mpi_allgather method to
578      ! establish the neighbour lists to use in subsequent peer to peer exchanges.
579      ! Consequently, set l_north_nogather to be false here and set it true only after
580      ! the lists have been established.
581      !
582      l_north_nogather = .FALSE.
583      !
584      ! Exchange and store ranks on northern rows
585
586      DO jtyp = 1,4
587
588         lrankset = .FALSE.
589         znnbrs = narea
590         SELECT CASE (jtyp)
591            CASE(1)
592               CALL lbc_lnk( znnbrs, 'T', 1. )      ! Type 1: T,W-points
593            CASE(2)
594               CALL lbc_lnk( znnbrs, 'U', 1. )      ! Type 2: U-point
595            CASE(3)
596               CALL lbc_lnk( znnbrs, 'V', 1. )      ! Type 3: V-point
597            CASE(4)
598               CALL lbc_lnk( znnbrs, 'F', 1. )      ! Type 4: F-point
599         END SELECT
600
601         IF ( njmppt(narea) .EQ. MAXVAL( njmppt ) ) THEN
602            DO jj = nlcj-ijpj+1, nlcj
603               ij = jj - nlcj + ijpj
604               DO ji = 1,jpi
605                  IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) &
606               &     lrankset(INT(znnbrs(ji,jj))) = .true.
607               END DO
608            END DO
609
610            DO jj = 1,jpnij
611               IF ( lrankset(jj) ) THEN
612                  nsndto(jtyp) = nsndto(jtyp) + 1
613                  IF ( nsndto(jtyp) .GT. jpmaxngh ) THEN
614                     CALL ctl_stop( ' Too many neighbours in nemo_northcomms ', &
615                  &                 ' jpmaxngh will need to be increased ')
616                  ENDIF
617                  isendto(nsndto(jtyp),jtyp) = jj-1   ! narea converted to MPI rank
618               ENDIF
619            END DO
620         ENDIF
621
622      END DO
623
624      !
625      ! Type 5: I-point
626      !
627      ! ICE point exchanges may involve some averaging. The neighbours list is
628      ! built up using two exchanges to ensure that the whole stencil is covered.
629      ! lrankset should not be reset between these 'J' and 'K' point exchanges
630
631      jtyp = 5
632      lrankset = .FALSE.
633      znnbrs = narea
634      CALL lbc_lnk( znnbrs, 'J', 1. ) ! first ice U-V point
635
636      IF ( njmppt(narea) .EQ. MAXVAL( njmppt ) ) THEN
637         DO jj = nlcj-ijpj+1, nlcj
638            ij = jj - nlcj + ijpj
639            DO ji = 1,jpi
640               IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) &
641            &     lrankset(INT(znnbrs(ji,jj))) = .true.
642         END DO
643        END DO
644      ENDIF
645
646      znnbrs = narea
647      CALL lbc_lnk( znnbrs, 'K', 1. ) ! second ice U-V point
648
649      IF ( njmppt(narea) .EQ. MAXVAL( njmppt )) THEN
650         DO jj = nlcj-ijpj+1, nlcj
651            ij = jj - nlcj + ijpj
652            DO ji = 1,jpi
653               IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND.  INT(znnbrs(ji,jj)) .NE. narea ) &
654            &       lrankset( INT(znnbrs(ji,jj))) = .true.
655            END DO
656         END DO
657
658         DO jj = 1,jpnij
659            IF ( lrankset(jj) ) THEN
660               nsndto(jtyp) = nsndto(jtyp) + 1
661               IF ( nsndto(jtyp) .GT. jpmaxngh ) THEN
662                  CALL ctl_stop( ' Too many neighbours in nemo_northcomms ', &
663               &                 ' jpmaxngh will need to be increased ')
664               ENDIF
665               isendto(nsndto(jtyp),jtyp) = jj-1   ! narea converted to MPI rank
666            ENDIF
667         END DO
668         !
669         ! For northern row areas, set l_north_nogather so that all subsequent exchanges
670         ! can use peer to peer communications at the north fold
671         !
672         l_north_nogather = .TRUE.
673         !
674      ENDIF
675      DEALLOCATE( znnbrs )
676      DEALLOCATE( lrankset )
677
678   END SUBROUTINE nemo_northcomms
679#else
680   SUBROUTINE nemo_northcomms      ! Dummy routine
681      WRITE(*,*) 'nemo_northcomms: You should not have seen this print! error?'
682   END SUBROUTINE nemo_northcomms
683#endif
684   !!======================================================================
685END MODULE nemogcm
Note: See TracBrowser for help on using the repository browser.