source: branches/UKMO/dev_r5518_GO6_runoff_O4test/NEMOGCM/NEMO/OPA_SRC/SBC/cpl_oasis3.F90 @ 10214

Last change on this file since 10214 was 10214, checked in by frrh, 3 years ago

Working version with OASIS3-MCT vn3.0 and 4.0

File size: 35.3 KB
Line 
1MODULE cpl_oasis3
2   !!======================================================================
3   !!                    ***  MODULE cpl_oasis  ***
4   !! Coupled O/A : coupled ocean-atmosphere case using OASIS3-MCT
5   !!=====================================================================
6   !! History :   
7   !!   9.0  !  04-06  (R. Redler, NEC Laboratories Europe, Germany) Original code
8   !!   " "  !  04-11  (R. Redler, NEC Laboratories Europe; N. Keenlyside, W. Park, IFM-GEOMAR, Germany) revision
9   !!   " "  !  04-11  (V. Gayler, MPI M&D) Grid writing
10   !!   " "  !  05-08  (R. Redler, W. Park) frld initialization, paral(2) revision
11   !!   " "  !  05-09  (R. Redler) extended to allow for communication over root only
12   !!   " "  !  06-01  (W. Park) modification of physical part
13   !!   " "  !  06-02  (R. Redler, W. Park) buffer array fix for root exchange
14   !!   3.4  !  11-11  (C. Harris) Changes to allow mutiple category fields
15   !!----------------------------------------------------------------------
16   !!----------------------------------------------------------------------
17   !!   'key_oasis3'                    coupled Ocean/Atmosphere via OASIS3-MCT
18   !!   'key_oa3mct_v3'                 to be added for OASIS3-MCT version 3
19   !!----------------------------------------------------------------------
20   !!   cpl_init     : initialization of coupled mode communication
21   !!   cpl_define   : definition of grid and fields
22   !!   cpl_snd     : snd out fields in coupled mode
23   !!   cpl_rcv     : receive fields in coupled mode
24   !!   cpl_finalize : finalize the coupled mode communication
25   !!----------------------------------------------------------------------
26#if defined key_oasis3
27   USE mod_oasis                    ! OASIS3-MCT module
28#endif
29   USE par_oce                      ! ocean parameters
30   USE cpl_rnf_1d, ONLY: nn_cpl_river   ! Variables used in 1D river outflow
31   USE dom_oce                      ! ocean space and time domain
32   USE in_out_manager               ! I/O manager
33   USE lbclnk                       ! ocean lateral boundary conditions (or mpp link)
34   
35   IMPLICIT NONE
36   PRIVATE
37   
38#if ! defined key_oasis3
39   ! Dummy interface to oasis_get if not using oasis
40   INTERFACE oasis_get
41      MODULE PROCEDURE oasis_get_1d, oasis_get_2d
42   END INTERFACE
43#endif
44
45   PUBLIC   cpl_init
46   PUBLIC   cpl_define
47   PUBLIC   cpl_snd
48   PUBLIC   cpl_rcv
49   PUBLIC   cpl_rcv_1d
50   PUBLIC   cpl_freq
51   PUBLIC   cpl_finalize
52#if defined key_mpp_mpi
53   INCLUDE 'mpif.h'
54#endif
55   
56   INTEGER, PARAMETER         :: localRoot  = 0
57   LOGICAL                    :: commRank            ! true for ranks doing OASIS communication
58#if defined key_cpl_rootexchg
59   LOGICAL                    :: rootexchg =.true.   ! logical switch
60#else
61   LOGICAL                    :: rootexchg =.false.  ! logical switch
62#endif
63
64   INTEGER, PUBLIC            ::   OASIS_Rcv  = 1    !: return code if received field
65   INTEGER, PUBLIC            ::   OASIS_idle = 0    !: return code if nothing done by oasis
66   INTEGER                    ::   ncomp_id          ! id returned by oasis_init_comp
67   INTEGER                    ::   nerror            ! return error code
68#if ! defined key_oasis3
69   ! OASIS Variables not used. defined only for compilation purpose
70   INTEGER                    ::   OASIS_Out         = -1
71   INTEGER                    ::   OASIS_REAL        = -1
72   INTEGER                    ::   OASIS_Ok          = -1
73   INTEGER                    ::   OASIS_In          = -1
74   INTEGER                    ::   OASIS_Sent        = -1
75   INTEGER                    ::   OASIS_SentOut     = -1
76   INTEGER                    ::   OASIS_ToRest      = -1
77   INTEGER                    ::   OASIS_ToRestOut   = -1
78   INTEGER                    ::   OASIS_Recvd       = -1
79   INTEGER                    ::   OASIS_RecvOut     = -1
80   INTEGER                    ::   OASIS_FromRest    = -1
81   INTEGER                    ::   OASIS_FromRestOut = -1
82#endif
83
84   INTEGER                    ::   nrcv         ! total number of fields received
85   INTEGER                    ::   nsnd         ! total number of fields sent
86   INTEGER                    ::   ncplmodel    ! Maximum number of models to/from which NEMO is potentialy sending/receiving data
87   INTEGER, PUBLIC, PARAMETER ::   nmaxfld=50   ! Maximum number of coupling fields
88   INTEGER, PUBLIC, PARAMETER ::   nmaxcat=5    ! Maximum number of coupling fields
89   INTEGER, PUBLIC, PARAMETER ::   nmaxcpl=5    ! Maximum number of coupling fields
90   
91   TYPE, PUBLIC ::   FLD_CPL               !: Type for coupling field information
92      LOGICAL               ::   laction   ! To be coupled or not
93      CHARACTER(len = 8)    ::   clname    ! Name of the coupling field   
94      CHARACTER(len = 1)    ::   clgrid    ! Grid type 
95      REAL(wp)              ::   nsgn      ! Control of the sign change
96      INTEGER, DIMENSION(nmaxcat,nmaxcpl) ::   nid   ! Id of the field (no more than 9 categories and 9 extrena models)
97      INTEGER               ::   nct       ! Number of categories in field
98      INTEGER               ::   ncplmodel ! Maximum number of models to/from which this variable may be sent/received
99      INTEGER               ::   dimensions ! Number of dimensions of coupling field
100   END TYPE FLD_CPL
101
102   TYPE(FLD_CPL), DIMENSION(nmaxfld), PUBLIC ::   srcv, ssnd   !: Coupling fields
103
104   REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   exfld   ! Temporary buffer for receiving
105   INTEGER, PUBLIC :: localComm 
106     
107   !!----------------------------------------------------------------------
108   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
109   !! $Id$
110   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
111   !!----------------------------------------------------------------------
112CONTAINS
113
114   SUBROUTINE cpl_init( cd_modname, kl_comm )
115      !!-------------------------------------------------------------------
116      !!             ***  ROUTINE cpl_init  ***
117      !!
118      !! ** Purpose :   Initialize coupled mode communication for ocean
119      !!    exchange between AGCM, OGCM and COUPLER. (OASIS3 software)
120      !!
121      !! ** Method  :   OASIS3 MPI communication
122      !!--------------------------------------------------------------------
123      CHARACTER(len = *), INTENT(in) ::   cd_modname   ! model name as set in namcouple file
124      INTEGER          , INTENT(out) ::   kl_comm      ! local communicator of the model
125      !!--------------------------------------------------------------------
126
127      ! WARNING: No write in numout in this routine
128      !============================================
129
130      !------------------------------------------------------------------
131      ! 1st Initialize the OASIS system for the application
132      !------------------------------------------------------------------
133      CALL oasis_init_comp ( ncomp_id, TRIM(cd_modname), nerror )
134      IF ( nerror /= OASIS_Ok ) &
135         CALL oasis_abort (ncomp_id, 'cpl_init', 'Failure in oasis_init_comp')
136
137      !------------------------------------------------------------------
138      ! 3rd Get an MPI communicator for OPA local communication
139      !------------------------------------------------------------------
140
141      CALL oasis_get_localcomm ( kl_comm, nerror )
142      IF ( nerror /= OASIS_Ok ) &
143         CALL oasis_abort (ncomp_id, 'cpl_init','Failure in oasis_get_localcomm' )
144      localComm = kl_comm 
145      !
146   END SUBROUTINE cpl_init
147
148
149   SUBROUTINE cpl_define( krcv, ksnd, kcplmodel )
150      !!-------------------------------------------------------------------
151      !!             ***  ROUTINE cpl_define  ***
152      !!
153      !! ** Purpose :   Define grid and field information for ocean
154      !!    exchange between AGCM, OGCM and COUPLER. (OASIS3 software)
155      !!
156      !! ** Method  :   OASIS3 MPI communication
157      !!--------------------------------------------------------------------
158      INTEGER, INTENT(in) ::   krcv, ksnd     ! Number of received and sent coupling fields
159      INTEGER, INTENT(in) ::   kcplmodel      ! Maximum number of models to/from which NEMO is potentialy sending/receiving data
160      !
161      INTEGER :: id_part
162      INTEGER :: id_part_0d     ! Partition for 0d fields
163      INTEGER :: id_part_rnf_1d ! Partition for 1d river outflow fields
164      INTEGER :: id_part_temp   ! Temperary partition used to choose either 0d or 1d partitions
165      INTEGER :: paral(5)       ! OASIS3 box partition
166      INTEGER :: ishape(4)      ! Shape of 2D arrays passed to PSMILe.
167                                ! Redundant from OASIS3-MCT vn4.0 onwards but required
168                                ! to satisfy interface and for backward compatibility.
169      INTEGER :: ishape0d1d(2)  ! Shape of 0D or 1D arrays passed to PSMILe.
170      INTEGER :: var_nodims(2)  ! Number of coupling field dimensions.
171                                ! var_nodims(1) is redundant from OASIS3-MCT vn4.0 onwards
172                                ! but retained for backward compatibility.
173                                ! var_nodims(2) is the number of fields in a bundle
174                                ! or 1 for unbundled fields (bundles are not yet catered for
175                                ! in NEMO hence we default to 1). 
176      INTEGER :: ji,jc,jm       ! local loop indicees
177      CHARACTER(LEN=64) :: zclname
178      CHARACTER(LEN=2) :: cli2
179      !!--------------------------------------------------------------------
180
181      IF(lwp) WRITE(numout,*)
182      IF(lwp) WRITE(numout,*) 'cpl_define : initialization in coupled ocean/atmosphere case'
183      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~~~~'
184      IF(lwp) WRITE(numout,*)
185
186      ncplmodel = kcplmodel
187      IF( kcplmodel > nmaxcpl ) THEN
188         CALL oasis_abort ( ncomp_id, 'cpl_define', 'ncplmodel is larger than nmaxcpl, increase nmaxcpl')   ;   RETURN
189      ENDIF
190
191      nrcv = krcv
192      IF( nrcv > nmaxfld ) THEN
193         CALL oasis_abort ( ncomp_id, 'cpl_define', 'nrcv is larger than nmaxfld, increase nmaxfld')   ;   RETURN
194      ENDIF
195
196      nsnd = ksnd
197      IF( nsnd > nmaxfld ) THEN
198         CALL oasis_abort ( ncomp_id, 'cpl_define', 'nsnd is larger than nmaxfld, increase nmaxfld')   ;   RETURN
199      ENDIF
200
201      !
202      ! ... Define the shape for the area that excludes the halo
203      !     For serial configuration (key_mpp_mpi not being active)
204      !     nl* is set to the global values 1 and jp*glo.
205      !
206      ishape(1) = 1
207      ishape(2) = nlei-nldi+1
208      ishape(3) = 1
209      ishape(4) = nlej-nldj+1
210
211      ishape0d1d(1) = 0
212      ishape0d1d(2) = 0
213
214      !
215      ! ... Allocate memory for data exchange
216      !
217      ALLOCATE(exfld(nlei-nldi+1, nlej-nldj+1), stat = nerror)
218      IF( nerror > 0 ) THEN
219         CALL oasis_abort ( ncomp_id, 'cpl_define', 'Failure in allocating exfld')   ;   RETURN
220      ENDIF     
221      !
222      ! -----------------------------------------------------------------
223      ! ... Define the partition
224      ! -----------------------------------------------------------------
225           
226      paral(1) = 2                                              ! box partitioning
227      paral(2) = jpiglo * (nldj-1+njmpp-1) + (nldi-1+nimpp-1)   ! NEMO lower left corner global offset   
228      paral(3) = nlei-nldi+1                                    ! local extent in i
229      paral(4) = nlej-nldj+1                                    ! local extent in j
230      paral(5) = jpiglo                                         ! global extent in x
231     
232      IF( ln_ctl ) THEN
233         WRITE(numout,*) ' multiexchg: paral (1:5)', paral
234         WRITE(numout,*) ' multiexchg: jpi, jpj =', jpi, jpj
235         WRITE(numout,*) ' multiexchg: nldi, nlei, nimpp =', nldi, nlei, nimpp
236         WRITE(numout,*) ' multiexchg: nldj, nlej, njmpp =', nldj, nlej, njmpp
237      ENDIF
238     
239      CALL oasis_def_partition ( id_part, paral, nerror, jpiglo*jpjglo)
240
241      ! A special partition is needed for 0D fields
242     
243      paral(1) = 0                                       ! serial partitioning
244      paral(2) = 0   
245      IF ( nproc == 0) THEN
246         paral(3) = 1                   ! Size of array to couple (scalar)
247      ELSE
248         paral(3) = 0                   ! Dummy size for PE's not involved
249      END IF
250      paral(4) = 0
251      paral(5) = 0
252       
253      CALL oasis_def_partition ( id_part_0d, paral, nerror, 1 )
254
255      ! Another partition is needed for 1D river routing fields
256     
257      paral(1) = 0                                       ! serial partitioning
258      paral(2) = 0   
259      IF ( nproc == 0) THEN
260         paral(3) = nn_cpl_river                   ! Size of array to couple (vector)
261      ELSE
262         paral(3) = 0                   ! Dummy size for PE's not involved
263      END IF
264      paral(4) = 0
265      paral(5) = 0
266
267
268      CALL oasis_def_partition ( id_part_rnf_1d, paral, nerror, nn_cpl_river )
269 
270      !
271      ! ... Announce send variables.
272      !
273      ssnd(:)%ncplmodel = kcplmodel
274      !
275      DO ji = 1, ksnd
276         IF ( ssnd(ji)%laction ) THEN
277
278            IF( ssnd(ji)%nct > nmaxcat ) THEN
279               CALL oasis_abort ( ncomp_id, 'cpl_define', 'Number of categories of '//   &
280                  &              TRIM(ssnd(ji)%clname)//' is larger than nmaxcat, increase nmaxcat' )
281               RETURN
282            ENDIF
283           
284            DO jc = 1, ssnd(ji)%nct
285               DO jm = 1, kcplmodel
286
287                  IF ( ssnd(ji)%nct .GT. 1 ) THEN
288                     WRITE(cli2,'(i2.2)') jc
289                     zclname = TRIM(ssnd(ji)%clname)//'_cat'//cli2
290                  ELSE
291                     zclname = ssnd(ji)%clname
292                  ENDIF
293                  IF ( kcplmodel  > 1 ) THEN
294                     WRITE(cli2,'(i2.2)') jm
295                     zclname = 'model'//cli2//'_'//TRIM(zclname)
296                  ENDIF
297#if defined key_agrif
298                  IF( agrif_fixed() /= 0 ) THEN
299                     zclname=TRIM(Agrif_CFixed())//'_'//TRIM(zclname)
300                  END IF
301#endif
302                  IF( ln_ctl ) WRITE(numout,*) "Define", ji, jc, jm, " "//TRIM(zclname), " for ", OASIS_Out
303
304                  !
305                  ! ... Set the field dimension and bundle count
306                  var_nodims(1) = 2
307                  var_nodims(2) = 1 ! Modify this value to cater for bundled fields.   
308
309                  CALL oasis_def_var (ssnd(ji)%nid(jc,jm), zclname, id_part   , var_nodims,   &
310                     &                OASIS_Out          , ishape , OASIS_REAL, nerror )
311                  IF ( nerror /= OASIS_Ok ) THEN
312                     WRITE(numout,*) 'Failed to define transient ', ji, jc, jm, " "//TRIM(zclname)
313                     CALL oasis_abort ( ssnd(ji)%nid(jc,jm), 'cpl_define', 'Failure in oasis_def_var' )
314                  ENDIF
315                  IF( ln_ctl .AND. ssnd(ji)%nid(jc,jm) /= -1 ) WRITE(numout,*) "variable defined in the namcouple"
316                  IF( ln_ctl .AND. ssnd(ji)%nid(jc,jm) == -1 ) WRITE(numout,*) "variable NOT defined in the namcouple"
317               END DO
318            END DO
319         ENDIF
320      END DO     
321      !
322      ! ... Announce received variables.
323      !
324      srcv(:)%ncplmodel = kcplmodel
325      !
326      DO ji = 1, krcv
327         IF ( srcv(ji)%laction ) THEN
328           
329            IF( srcv(ji)%nct > nmaxcat ) THEN
330               CALL oasis_abort ( ncomp_id, 'cpl_define', 'Number of categories of '//   &
331                  &              TRIM(srcv(ji)%clname)//' is larger than nmaxcat, increase nmaxcat' )
332               RETURN
333            ENDIF
334           
335            DO jc = 1, srcv(ji)%nct
336               DO jm = 1, kcplmodel
337                 
338                  IF ( srcv(ji)%nct .GT. 1 ) THEN
339                     WRITE(cli2,'(i2.2)') jc
340                     zclname = TRIM(srcv(ji)%clname)//'_cat'//cli2
341                  ELSE
342                     zclname = srcv(ji)%clname
343                  ENDIF
344                  IF ( kcplmodel  > 1 ) THEN
345                     WRITE(cli2,'(i2.2)') jm
346                     zclname = 'model'//cli2//'_'//TRIM(zclname)
347                  ENDIF
348#if defined key_agrif
349                  IF( agrif_fixed() /= 0 ) THEN
350                     zclname=TRIM(Agrif_CFixed())//'_'//TRIM(zclname)
351                  END IF
352#endif
353                  IF( ln_ctl ) WRITE(numout,*) "Define", ji, jc, jm, " "//TRIM(zclname), " for ", OASIS_In
354                  flush(numout)
355
356                  ! Define 0D (Greenland or Antarctic ice mass) or 1D (river outflow) coupling fields
357                  IF (srcv(ji)%dimensions <= 1) THEN
358                    var_nodims(1) = 1
359                    var_nodims(2) = 1 ! Modify this value to cater for bundled fields. 
360                    IF (nproc == 0) THEN                   
361                       
362                       ishape0d1d(1) = 1
363                       IF (srcv(ji)%dimensions == 0) THEN
364                       
365                          ! If 0D then set temporary variables to 0D components
366                          id_part_temp = id_part_0d
367                          ishape0d1d(2) = 1
368                       ELSE
369                       
370                          ! If 1D then set temporary variables to river outflow components
371                          id_part_temp = id_part_rnf_1d
372                          ishape0d1d(2)= nn_cpl_river
373                         
374                       END IF
375
376                       CALL oasis_def_var (srcv(ji)%nid(jc,jm), zclname, id_part_temp   , var_nodims,   &
377                                   OASIS_In           , ishape0d1d(1:2) , OASIS_REAL, nerror )
378
379                    ELSE                       
380                       ishape0d1d(1) = 0
381                       ishape0d1d(2) = 0
382                       ! Dummy call to keep OASIS3-MCT happy.
383                       CALL oasis_def_var (srcv(ji)%nid(jc,jm), zclname, id_part_0d   , var_nodims,   &
384                                   OASIS_In           , ishape0d1d(1:2) , OASIS_REAL, nerror )
385                   
386                    ENDIF
387                  ELSE 
388                    ! It's a "normal" 2D (or pseudo 3D) coupling field.
389                    ! ... Set the field dimension and bundle count
390                    var_nodims(1) = 2
391                    var_nodims(2) = 1 ! Modify this value to cater for bundled fields.     
392
393                    CALL oasis_def_var (srcv(ji)%nid(jc,jm), zclname, id_part   , var_nodims,   &
394                                         OASIS_In           , ishape , OASIS_REAL, nerror )
395                  ENDIF
396
397                  IF ( nerror /= OASIS_Ok ) THEN
398                     WRITE(numout,*) 'Failed to define transient ', ji, jc, jm, " "//TRIM(zclname)
399                     CALL oasis_abort ( srcv(ji)%nid(jc,jm), 'cpl_define', 'Failure in oasis_def_var' )
400                  ENDIF
401                  IF( ln_ctl .AND. srcv(ji)%nid(jc,jm) /= -1 ) WRITE(numout,*) "variable defined in the namcouple"
402                  IF( ln_ctl .AND. srcv(ji)%nid(jc,jm) == -1 ) WRITE(numout,*) "variable NOT defined in the namcouple"
403
404               END DO
405            END DO
406         ENDIF
407      END DO
408     
409      !------------------------------------------------------------------
410      ! End of definition phase
411      !------------------------------------------------------------------
412     
413      CALL oasis_enddef(nerror)
414      IF( nerror /= OASIS_Ok )   CALL oasis_abort ( ncomp_id, 'cpl_define', 'Failure in oasis_enddef')
415      !
416   END SUBROUTINE cpl_define
417   
418   
419   SUBROUTINE cpl_snd( kid, kstep, pdata, kinfo )
420      !!---------------------------------------------------------------------
421      !!              ***  ROUTINE cpl_snd  ***
422      !!
423      !! ** Purpose : - At each coupling time-step,this routine sends fields
424      !!      like sst or ice cover to the coupler or remote application.
425      !!----------------------------------------------------------------------
426      INTEGER                   , INTENT(in   ) ::   kid       ! variable index in the array
427      INTEGER                   , INTENT(  out) ::   kinfo     ! OASIS3 info argument
428      INTEGER                   , INTENT(in   ) ::   kstep     ! ocean time-step in seconds
429      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   pdata
430      !!
431      INTEGER                                   ::   jc,jm     ! local loop index
432      !!--------------------------------------------------------------------
433      !
434      ! snd data to OASIS3
435      !
436      DO jc = 1, ssnd(kid)%nct
437         DO jm = 1, ssnd(kid)%ncplmodel
438       
439            IF( ssnd(kid)%nid(jc,jm) /= -1 ) THEN
440               CALL oasis_put ( ssnd(kid)%nid(jc,jm), kstep, pdata(nldi:nlei, nldj:nlej,jc), kinfo )
441               
442               IF ( ln_ctl ) THEN       
443                  IF ( kinfo == OASIS_Sent     .OR. kinfo == OASIS_ToRest .OR.   &
444                     & kinfo == OASIS_SentOut  .OR. kinfo == OASIS_ToRestOut ) THEN
445                     WRITE(numout,*) '****************'
446                     WRITE(numout,*) 'oasis_put: Outgoing ', ssnd(kid)%clname
447                     WRITE(numout,*) 'oasis_put: ivarid ', ssnd(kid)%nid(jc,jm)
448                     WRITE(numout,*) 'oasis_put:  kstep ', kstep
449                     WRITE(numout,*) 'oasis_put:   info ', kinfo
450                     WRITE(numout,*) '     - Minimum value is ', MINVAL(pdata(:,:,jc))
451                     WRITE(numout,*) '     - Maximum value is ', MAXVAL(pdata(:,:,jc))
452                     WRITE(numout,*) '     -     Sum value is ', SUM(pdata(:,:,jc))
453                     WRITE(numout,*) '****************'
454                  ENDIF
455               ENDIF
456               
457            ENDIF
458           
459         ENDDO
460      ENDDO
461      !
462    END SUBROUTINE cpl_snd
463
464
465   SUBROUTINE cpl_rcv( kid, kstep, pdata, pmask, kinfo )
466      !!---------------------------------------------------------------------
467      !!              ***  ROUTINE cpl_rcv  ***
468      !!
469      !! ** Purpose : - At each coupling time-step,this routine receives fields
470      !!      like stresses and fluxes from the coupler or remote application.
471      !!----------------------------------------------------------------------
472      INTEGER                   , INTENT(in   ) ::   kid       ! variable index in the array
473      INTEGER                   , INTENT(in   ) ::   kstep     ! ocean time-step in seconds
474      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pdata     ! IN to keep the value if nothing is done
475      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   pmask     ! coupling mask
476      INTEGER                   , INTENT(  out) ::   kinfo     ! OASIS3 info argument
477      !!
478      INTEGER                                   ::   jc,jm     ! local loop index
479      LOGICAL                                   ::   llaction, llfisrt
480      !!--------------------------------------------------------------------
481      !
482      ! receive local data from OASIS3 on every process
483      !
484      kinfo = OASIS_idle
485      !
486      DO jc = 1, srcv(kid)%nct
487         llfisrt = .TRUE.
488
489         DO jm = 1, srcv(kid)%ncplmodel
490
491            IF( srcv(kid)%nid(jc,jm) /= -1 ) THEN
492
493               CALL oasis_get ( srcv(kid)%nid(jc,jm), kstep, exfld, kinfo )   
494               
495               llaction =  kinfo == OASIS_Recvd   .OR. kinfo == OASIS_FromRest .OR.   &
496                &        kinfo == OASIS_RecvOut .OR. kinfo == OASIS_FromRestOut
497               
498               IF ( ln_ctl )   WRITE(numout,*) "llaction, kinfo, kstep, ivarid: " , llaction, kinfo, kstep, srcv(kid)%nid(jc,jm)
499               
500               IF ( llaction ) THEN
501                 
502                  kinfo = OASIS_Rcv
503                  IF( llfisrt ) THEN
504                     pdata(nldi:nlei,nldj:nlej,jc) =                                 exfld(:,:) * pmask(nldi:nlei,nldj:nlej,jm) 
505                     llfisrt = .FALSE.
506                  ELSE
507                     pdata(nldi:nlei,nldj:nlej,jc) = pdata(nldi:nlei,nldj:nlej,jc) + exfld(:,:) * pmask(nldi:nlei,nldj:nlej,jm)
508                  ENDIF
509                 
510                  IF ( ln_ctl ) THEN       
511                     WRITE(numout,*) '****************'
512                     WRITE(numout,*) 'oasis_get: Incoming ', srcv(kid)%clname
513                     WRITE(numout,*) 'oasis_get: ivarid '  , srcv(kid)%nid(jc,jm)
514                     WRITE(numout,*) 'oasis_get:   kstep', kstep
515                     WRITE(numout,*) 'oasis_get:   info ', kinfo
516                     WRITE(numout,*) '     - Minimum value is ', MINVAL(pdata(:,:,jc))
517                     WRITE(numout,*) '     - Maximum value is ', MAXVAL(pdata(:,:,jc))
518                     WRITE(numout,*) '     -     Sum value is ', SUM(pdata(:,:,jc))
519                     WRITE(numout,*) '****************'
520                  ENDIF
521
522               ENDIF
523
524            ENDIF
525           
526         ENDDO
527
528         !--- Fill the overlap areas and extra hallows (mpp)
529         !--- check periodicity conditions (all cases)
530         IF( .not. llfisrt )   CALL lbc_lnk( pdata(:,:,jc), srcv(kid)%clgrid, srcv(kid)%nsgn )   
531 
532      ENDDO
533      !
534   END SUBROUTINE cpl_rcv
535
536   SUBROUTINE cpl_rcv_1d( kid, kstep, pdata, nitems, kinfo )
537      !!---------------------------------------------------------------------
538      !!              ***  ROUTINE cpl_rcv_1d  ***
539      !!
540      !! ** Purpose : - A special version of cpl_rcv to deal exclusively with
541      !! receipt of 0D or 1D fields.
542      !! The fields are recieved into a 1D array buffer which is simply a
543      !! dynamically sized sized array (which may be of size 1)
544      !! of 0 dimensional fields. This allows us to pass miltiple 0D
545      !! fields via a single put/get operation. 
546      !!----------------------------------------------------------------------
547      INTEGER , INTENT(in   ) ::   nitems      ! Number of 0D items to recieve
548                                               ! during this get operation. i.e.
549                                               ! The size of the 1D array in which
550                                               ! 0D items are passed.   
551      INTEGER , INTENT(in   ) ::   kid         ! ID index of the incoming
552                                               ! data. 
553      INTEGER , INTENT(in   ) ::   kstep       ! ocean time-step in seconds
554      REAL(wp), INTENT(inout) ::   pdata(1:nitems) ! The original value(s), 
555                                                   ! unchanged if nothing is
556                                                   ! received
557      INTEGER , INTENT(  out) ::   kinfo       ! OASIS3 info argument
558      !!
559      REAL(wp) ::   recvfld(1:nitems)          ! Local receive field buffer
560      INTEGER  ::   jc,jm     ! local loop index
561      INTEGER  ::   ierr
562      LOGICAL  ::   llaction
563      INTEGER  ::   MPI_WORKING_PRECISION
564      INTEGER  ::   number_to_print 
565      !!--------------------------------------------------------------------
566      !
567      ! receive local data from OASIS3 on every process
568      !
569      kinfo = OASIS_idle
570      !
571      ! 0D and 1D fields won't have categories or any other form of "pseudo level"
572      ! so we only cater for a single set of values and thus don't bother
573      ! with a loop over the jc index
574      jc = 1
575
576      DO jm = 1, srcv(kid)%ncplmodel
577
578         IF( srcv(kid)%nid(jc,jm) /= -1 ) THEN
579
580            IF ( ( srcv(kid)%dimensions <= 1) .AND. (nproc == 0) ) THEN
581               ! Since there is no concept of data decomposition for zero
582               ! dimension fields, they must only be exchanged through the master PE,
583               ! unlike "normal" 2D field cases where every PE is involved.
584
585               CALL oasis_get ( srcv(kid)%nid(jc,jm), kstep, recvfld, kinfo )   
586               
587               llaction =  kinfo == OASIS_Recvd   .OR. kinfo == OASIS_FromRest .OR.   &
588                           kinfo == OASIS_RecvOut .OR. kinfo == OASIS_FromRestOut
589               
590               IF ( ln_ctl ) WRITE(numout,*) "llaction, kinfo, kstep, ivarid: " , &
591                                     llaction, kinfo, kstep, srcv(kid)%nid(jc,jm)
592               
593               IF ( llaction ) THEN
594                 
595                  kinfo = OASIS_Rcv
596                  pdata(1:nitems) = recvfld(1:nitems) 
597                 
598                  IF ( ln_ctl ) THEN       
599                     number_to_print = 10
600                     IF ( nitems < number_to_print ) number_to_print = nitems
601                     WRITE(numout,*) '****************'
602                     WRITE(numout,*) 'oasis_get: Incoming ', srcv(kid)%clname
603                     WRITE(numout,*) 'oasis_get: ivarid '  , srcv(kid)%nid(jc,jm)
604                     WRITE(numout,*) 'oasis_get:   kstep', kstep
605                     WRITE(numout,*) 'oasis_get:   info ', kinfo
606                     WRITE(numout,*) '     - Minimum Value is ', MINVAL(pdata(:))
607                     WRITE(numout,*) '     - Maximum value is ', MAXVAL(pdata(:))
608                     WRITE(numout,*) '     - Start of data is ', pdata(1:number_to_print)
609                     WRITE(numout,*) '****************'
610                  ENDIF
611                 
612               ENDIF
613            ENDIF   
614          ENDIF
615           
616       ENDDO
617       
618       ! Set the precision that we want to broadcast using MPI_BCAST
619       SELECT CASE( wp )
620       CASE( sp ) 
621         MPI_WORKING_PRECISION = MPI_REAL                ! Single precision
622       CASE( dp )
623         MPI_WORKING_PRECISION = MPI_DOUBLE_PRECISION    ! Double precision
624       CASE default
625         CALL oasis_abort( ncomp_id, "cpl_rcv_1d", "Could not find precision for coupling 0d or 1d field" )
626       END SELECT
627
628       ! We have to broadcast (potentially) received values from PE 0 to all
629       ! the others. If no new data has been received we're just
630       ! broadcasting the existing values but there's no more efficient way
631       ! to deal with that w/o NEMO adopting a UM-style test mechanism
632       ! to determine active put/get timesteps.
633       CALL mpi_bcast( pdata, nitems, MPI_WORKING_PRECISION, localRoot, mpi_comm_opa, ierr )
634
635      !
636   END SUBROUTINE cpl_rcv_1d
637
638
639   INTEGER FUNCTION cpl_freq( cdfieldname ) 
640      !!---------------------------------------------------------------------
641      !!              ***  ROUTINE cpl_freq  ***
642      !!
643      !! ** Purpose : - send back the coupling frequency for a particular field
644      !!----------------------------------------------------------------------
645      CHARACTER(len = *), INTENT(in) ::   cdfieldname    ! field name as set in namcouple file
646      !!
647      INTEGER               :: id
648      INTEGER               :: info
649      INTEGER, DIMENSION(1) :: itmp
650      INTEGER               :: ji,jm     ! local loop index
651      INTEGER               :: mop
652      !!----------------------------------------------------------------------
653      cpl_freq = 0   ! defaut definition
654      id = -1        ! defaut definition
655      !
656      DO ji = 1, nsnd
657         IF (ssnd(ji)%laction ) THEN
658            DO jm = 1, ncplmodel
659               IF( ssnd(ji)%nid(1,jm) /= -1 ) THEN
660                  IF( TRIM(cdfieldname) == TRIM(ssnd(ji)%clname) ) THEN
661                     id = ssnd(ji)%nid(1,jm)
662                     mop = OASIS_Out
663                  ENDIF
664               ENDIF
665            ENDDO
666         ENDIF
667      ENDDO
668      DO ji = 1, nrcv
669         IF (srcv(ji)%laction ) THEN
670            DO jm = 1, ncplmodel
671               IF( srcv(ji)%nid(1,jm) /= -1 ) THEN
672                  IF( TRIM(cdfieldname) == TRIM(srcv(ji)%clname) ) THEN
673                     id = srcv(ji)%nid(1,jm)
674                     mop = OASIS_In
675                  ENDIF
676               ENDIF
677            ENDDO
678         ENDIF
679      ENDDO
680      !
681      IF( id /= -1 ) THEN
682#if defined key_oa3mct_v3
683         CALL oasis_get_freqs(id, mop, 1, itmp, info)
684#else
685#if defined key_oasis3 
686         itmp(1) = namflddti( id )
687#else
688         CALL oasis_get_freqs(id,      1, itmp, info)
689#endif
690#endif
691         cpl_freq = itmp(1)
692      ENDIF
693      !
694   END FUNCTION cpl_freq
695
696
697   SUBROUTINE cpl_finalize
698      !!---------------------------------------------------------------------
699      !!              ***  ROUTINE cpl_finalize  ***
700      !!
701      !! ** Purpose : - Finalizes the coupling. If MPI_init has not been
702      !!      called explicitly before cpl_init it will also close
703      !!      MPI communication.
704      !!----------------------------------------------------------------------
705      !
706      DEALLOCATE( exfld )
707      IF (nstop == 0) THEN
708         CALL oasis_terminate( nerror )         
709      ELSE
710         CALL oasis_abort( ncomp_id, "cpl_finalize", "NEMO ABORT STOP" )
711      ENDIF       
712      !
713   END SUBROUTINE cpl_finalize
714
715#if ! defined key_oasis3
716
717   !!----------------------------------------------------------------------
718   !!   No OASIS Library          OASIS3 Dummy module...
719   !!----------------------------------------------------------------------
720
721   SUBROUTINE oasis_init_comp(k1,cd1,k2)
722      CHARACTER(*), INTENT(in   ) ::  cd1
723      INTEGER     , INTENT(  out) ::  k1,k2
724      k1 = -1 ; k2 = -1
725      WRITE(numout,*) 'oasis_init_comp: Error you sould not be there...', cd1
726   END SUBROUTINE oasis_init_comp
727
728   SUBROUTINE oasis_abort(k1,cd1,cd2)
729      INTEGER     , INTENT(in   ) ::  k1
730      CHARACTER(*), INTENT(in   ) ::  cd1,cd2
731      WRITE(numout,*) 'oasis_abort: Error you sould not be there...', cd1, cd2
732   END SUBROUTINE oasis_abort
733
734   SUBROUTINE oasis_get_localcomm(k1,k2)
735      INTEGER     , INTENT(  out) ::  k1,k2
736      k1 = -1 ; k2 = -1
737      WRITE(numout,*) 'oasis_get_localcomm: Error you sould not be there...'
738   END SUBROUTINE oasis_get_localcomm
739
740   SUBROUTINE oasis_def_partition(k1,k2,k3,K4)
741      INTEGER     , INTENT(  out) ::  k1,k3
742      INTEGER     , INTENT(in   ) ::  k2(5)
743      INTEGER     , OPTIONAL, INTENT(in   ) ::  k4
744      k1 = k2(1) ; k3 = k2(5)
745      WRITE(numout,*) 'oasis_def_partition: Error you sould not be there...'
746   END SUBROUTINE oasis_def_partition
747
748   SUBROUTINE oasis_def_var(k1,cd1,k2,k3,k4,k5,k6,k7)
749      CHARACTER(*), INTENT(in   ) ::  cd1
750      INTEGER     , INTENT(in   ) ::  k2,k3(2),k4,k5(2),k6
751      INTEGER     , INTENT(  out) ::  k1,k7
752      k1 = -1 ; k7 = -1
753      WRITE(numout,*) 'oasis_def_var: Error you sould not be there...', cd1
754   END SUBROUTINE oasis_def_var
755
756   SUBROUTINE oasis_enddef(k1)
757      INTEGER     , INTENT(  out) ::  k1
758      k1 = -1
759      WRITE(numout,*) 'oasis_enddef: Error you sould not be there...'
760   END SUBROUTINE oasis_enddef
761 
762   SUBROUTINE oasis_put(k1,k2,p1,k3)
763      REAL(wp), DIMENSION(:,:), INTENT(in   ) ::  p1
764      INTEGER                 , INTENT(in   ) ::  k1,k2
765      INTEGER                 , INTENT(  out) ::  k3
766      k3 = -1
767      WRITE(numout,*) 'oasis_put: Error you sould not be there...'
768   END SUBROUTINE oasis_put
769
770   SUBROUTINE oasis_get_1d(k1,k2,p1,k3)
771      REAL(wp), DIMENSION(:)  , INTENT(  out) ::  p1
772      INTEGER                 , INTENT(in   ) ::  k1,k2
773      INTEGER                 , INTENT(  out) ::  k3
774      p1(1) = -1. ; k3 = -1
775      WRITE(numout,*) 'oasis_get_1d: Error you sould not be there...'
776   END SUBROUTINE oasis_get_1d
777
778   SUBROUTINE oasis_get_2d(k1,k2,p1,k3)
779      REAL(wp), DIMENSION(:,:), INTENT(  out) ::  p1
780      INTEGER                 , INTENT(in   ) ::  k1,k2
781      INTEGER                 , INTENT(  out) ::  k3
782      p1(1,1) = -1. ; k3 = -1
783      WRITE(numout,*) 'oasis_get_2d: Error you sould not be there...'
784   END SUBROUTINE oasis_get_2d
785
786   SUBROUTINE oasis_get_freqs(k1,k2,k3,k4)
787      INTEGER              , INTENT(in   ) ::  k1,k2
788      INTEGER, DIMENSION(1), INTENT(  out) ::  k3
789      INTEGER              , INTENT(  out) ::  k4
790      k3(1) = k1 ; k4 = k2
791      WRITE(numout,*) 'oasis_get_freqs: Error you sould not be there...'
792   END SUBROUTINE oasis_get_freqs
793
794   SUBROUTINE oasis_terminate(k1)
795      INTEGER     , INTENT(  out) ::  k1
796      k1 = -1
797      WRITE(numout,*) 'oasis_terminate: Error you sould not be there...'
798   END SUBROUTINE oasis_terminate
799   
800#endif
801
802   !!=====================================================================
803END MODULE cpl_oasis3
Note: See TracBrowser for help on using the repository browser.