source: branches/UKMO/dev_r5518_STOPACK/NEMOGCM/NEMO/OPA_SRC/TRA/traqsr.F90 @ 11384

Last change on this file since 11384 was 11384, checked in by mattmartin, 2 years ago

Included Andrea Storto's STOPACK code into NEMO3.6 branch.

  • Property svn:keywords set to Id
File size: 30.3 KB
Line 
1MODULE traqsr
2   !!======================================================================
3   !!                       ***  MODULE  traqsr  ***
4   !! Ocean physics: solar radiation penetration in the top ocean levels
5   !!======================================================================
6   !! History :  OPA  !  1990-10  (B. Blanke)  Original code
7   !!            7.0  !  1991-11  (G. Madec)
8   !!                 !  1996-01  (G. Madec)  s-coordinates
9   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
10   !!             -   !  2005-11  (G. Madec) zco, zps, sco coordinate
11   !!            3.2  !  2009-04  (G. Madec & NEMO team)
12   !!            4.0  !  2012-05  (C. Rousset) store attenuation coef for use in ice model
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   tra_qsr      : trend due to the solar radiation penetration
17   !!   tra_qsr_init : solar radiation penetration initialization
18   !!----------------------------------------------------------------------
19   USE oce             ! ocean dynamics and active tracers
20   USE dom_oce         ! ocean space and time domain
21   USE sbc_oce         ! surface boundary condition: ocean
22   USE trc_oce         ! share SMS/Ocean variables
23   USE trd_oce        ! trends: ocean variables
24   USE trdtra         ! trends manager: tracers
25   USE in_out_manager  ! I/O manager
26   USE phycst          ! physical constants
27   USE prtctl          ! Print control
28   USE iom             ! I/O manager
29   USE fldread         ! read input fields
30   USE restart         ! ocean restart
31   USE lib_mpp         ! MPP library
32   USE wrk_nemo       ! Memory Allocation
33   USE timing         ! Timing
34   USE stopack
35
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   tra_qsr       ! routine called by step.F90 (ln_traqsr=T)
40   PUBLIC   tra_qsr_init  ! routine called by nemogcm.F90
41
42   !                                 !!* Namelist namtra_qsr: penetrative solar radiation
43   LOGICAL , PUBLIC ::   ln_traqsr    !: light absorption (qsr) flag
44   LOGICAL , PUBLIC ::   ln_qsr_rgb   !: Red-Green-Blue light absorption flag 
45   LOGICAL , PUBLIC ::   ln_qsr_2bd   !: 2 band         light absorption flag
46   LOGICAL , PUBLIC ::   ln_qsr_bio   !: bio-model      light absorption flag
47   LOGICAL , PUBLIC ::   ln_qsr_ice   !: light penetration for ice-model LIM3 (clem)
48   INTEGER , PUBLIC ::   nn_chldta    !: use Chlorophyll data (=1) or not (=0)
49   REAL(wp), PUBLIC ::   rn_abs       !: fraction absorbed in the very near surface (RGB & 2 bands)
50   REAL(wp), PUBLIC ::   rn_si0       !: very near surface depth of extinction      (RGB & 2 bands)
51   REAL(wp), PUBLIC ::   rn_si1       !: deepest depth of extinction (water type I)       (2 bands)
52 
53   ! Module variables
54   REAL(wp), ALLOCATABLE ::   xsi0r(:,:)         !: inverse of rn_si0
55   REAL(wp) ::   xsi1r                           !: inverse of rn_si1
56   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_chl   ! structure of input Chl (file informations, fields read)
57   INTEGER, PUBLIC ::   nksr              ! levels below which the light cannot penetrate ( depth larger than 391 m)
58   REAL(wp), DIMENSION(3,61) ::   rkrgb   !: tabulated attenuation coefficients for RGB absorption
59
60   !! * Substitutions
61#  include "domzgr_substitute.h90"
62#  include "vectopt_loop_substitute.h90"
63   !!----------------------------------------------------------------------
64   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
65   !! $Id$
66   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
67   !!----------------------------------------------------------------------
68CONTAINS
69
70   SUBROUTINE tra_qsr( kt )
71      !!----------------------------------------------------------------------
72      !!                  ***  ROUTINE tra_qsr  ***
73      !!
74      !! ** Purpose :   Compute the temperature trend due to the solar radiation
75      !!      penetration and add it to the general temperature trend.
76      !!
77      !! ** Method  : The profile of the solar radiation within the ocean is defined
78      !!      through 2 wavebands (rn_si0,rn_si1) or 3 wavebands (RGB) and a ratio rn_abs
79      !!      Considering the 2 wavebands case:
80      !!         I(k) = Qsr*( rn_abs*EXP(z(k)/rn_si0) + (1.-rn_abs)*EXP(z(k)/rn_si1) )
81      !!         The temperature trend associated with the solar radiation penetration
82      !!         is given by : zta = 1/e3t dk[ I ] / (rau0*Cp)
83      !!         At the bottom, boudary condition for the radiation is no flux :
84      !!      all heat which has not been absorbed in the above levels is put
85      !!      in the last ocean level.
86      !!         In z-coordinate case, the computation is only done down to the
87      !!      level where I(k) < 1.e-15 W/m2. In addition, the coefficients
88      !!      used for the computation are calculated one for once as they
89      !!      depends on k only.
90      !!
91      !! ** Action  : - update ta with the penetrative solar radiation trend
92      !!              - save the trend in ttrd ('key_trdtra')
93      !!
94      !! Reference  : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp.
95      !!              Lengaigne et al. 2007, Clim. Dyn., V28, 5, 503-516.
96      !!----------------------------------------------------------------------
97      !
98      INTEGER, INTENT(in) ::   kt     ! ocean time-step
99      !
100      INTEGER  ::   ji, jj, jk           ! dummy loop indices
101      INTEGER  ::   irgb                 ! local integers
102      REAL(wp) ::   zchl, zcoef, zfact   ! local scalars
103      REAL(wp) ::   zc0, zc1, zc2, zc3   !    -         -
104      REAL(wp) ::   zzc0, zzc1, zzc2, zzc3   !    -         -
105      REAL(wp) ::   zz0, zz1, z1_e3t     !    -         -
106      REAL(wp), POINTER, DIMENSION(:,:  ) :: zekb, zekg, zekr
107      REAL(wp), POINTER, DIMENSION(:,:,:) :: ze0, ze1, ze2, ze3, zea, ztrdt
108      !!----------------------------------------------------------------------
109      !
110      IF( nn_timing == 1 )  CALL timing_start('tra_qsr')
111      !
112      CALL wrk_alloc( jpi, jpj,      zekb, zekg, zekr        ) 
113      CALL wrk_alloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
114      !
115      IF( kt == nit000 ) THEN
116         IF(lwp) WRITE(numout,*)
117         IF(lwp) WRITE(numout,*) 'tra_qsr : penetration of the surface solar radiation'
118         IF(lwp) WRITE(numout,*) '~~~~~~~'
119         IF( .NOT.ln_traqsr )   RETURN
120      ENDIF
121
122      IF( l_trdtra ) THEN      ! Save ta and sa trends
123         CALL wrk_alloc( jpi, jpj, jpk, ztrdt ) 
124         ztrdt(:,:,:) = tsa(:,:,:,jp_tem)
125      ENDIF
126
127      !                                        Set before qsr tracer content field
128      !                                        ***********************************
129      IF( kt == nit000 ) THEN                     ! Set the forcing field at nit000 - 1
130         !                                        ! -----------------------------------
131         qsr_hc(:,:,:) = 0.e0
132         !
133         IF( ln_rstart .AND.    &                    ! Restart: read in restart file
134              & iom_varid( numror, 'qsr_hc_b', ldstop = .FALSE. ) > 0 ) THEN
135            IF(lwp) WRITE(numout,*) '          nit000-1 qsr tracer content forcing field red in the restart file'
136            zfact = 0.5e0
137            CALL iom_get( numror, jpdom_autoglo, 'qsr_hc_b', qsr_hc_b )   ! before heat content trend due to Qsr flux
138         ELSE                                           ! No restart or restart not found: Euler forward time stepping
139            zfact = 1.e0
140            qsr_hc_b(:,:,:) = 0.e0
141         ENDIF
142      ELSE                                        ! Swap of forcing field
143         !                                        ! ---------------------
144         zfact = 0.5e0
145         qsr_hc_b(:,:,:) = qsr_hc(:,:,:)
146      ENDIF
147      !                                        Compute now qsr tracer content field
148      !                                        ************************************
149     
150      !                                           ! ============================================== !
151      IF( lk_qsr_bio .AND. ln_qsr_bio ) THEN      !  bio-model fluxes  : all vertical coordinates  !
152         !                                        ! ============================================== !
153         DO jk = 1, jpkm1
154            qsr_hc(:,:,jk) = r1_rau0_rcp * ( etot3(:,:,jk) - etot3(:,:,jk+1) )
155         END DO
156         !                                        Add to the general trend
157         DO jk = 1, jpkm1
158            DO jj = 2, jpjm1 
159               DO ji = fs_2, fs_jpim1   ! vector opt.
160                  z1_e3t = zfact / fse3t(ji,jj,jk)
161                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t
162               END DO
163            END DO
164         END DO
165         CALL iom_put( 'qsr3d', etot3 )   ! Shortwave Radiation 3D distribution
166         ! clem: store attenuation coefficient of the first ocean level
167         IF ( ln_qsr_ice ) THEN
168            DO jj = 1, jpj
169               DO ji = 1, jpi
170                  IF ( qsr(ji,jj) /= 0._wp ) THEN
171                     fraqsr_1lev(ji,jj) = ( qsr_hc(ji,jj,1) / ( r1_rau0_rcp * qsr(ji,jj) ) )
172                  ELSE
173                     fraqsr_1lev(ji,jj) = 1.
174                  ENDIF
175               END DO
176            END DO
177         ENDIF
178         !                                        ! ============================================== !
179      ELSE                                        !  Ocean alone :
180         !                                        ! ============================================== !
181         !
182         !
183         IF( nn_spp_qsi0 > 0 ) THEN
184             xsi0r = rn_si0
185             CALL spp_gen(kt, xsi0r, nn_spp_qsi0, rn_qsi0_sd, jk_spp_qsi0 )
186             xsi0r = 1.e0 / xsi0r
187         ENDIF
188         !                                               ! ------------------------- !
189         IF( ln_qsr_rgb) THEN                             !  R-G-B  light penetration !
190            !                                             ! ------------------------- !
191            ! Set chlorophyl concentration
192            IF( nn_chldta == 1 .OR. lk_vvl ) THEN            !*  Variable Chlorophyll or ocean volume
193               !
194               IF( nn_chldta == 1 ) THEN                             !*  Variable Chlorophyll
195                  !
196                  CALL fld_read( kt, 1, sf_chl )                         ! Read Chl data and provides it at the current time step
197                  !         
198!CDIR COLLAPSE
199!CDIR NOVERRCHK
200                  DO jj = 1, jpj                                         ! Separation in R-G-B depending of the surface Chl
201!CDIR NOVERRCHK
202                     DO ji = 1, jpi
203                        zchl = MIN( 10. , MAX( 0.03, sf_chl(1)%fnow(ji,jj,1) ) )
204                        irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 )
205                        zekb(ji,jj) = rkrgb(1,irgb)
206                        zekg(ji,jj) = rkrgb(2,irgb)
207                        zekr(ji,jj) = rkrgb(3,irgb)
208                     END DO
209                  END DO
210               ELSE                                            ! Variable ocean volume but constant chrlorophyll
211                  zchl = 0.05                                     ! constant chlorophyll
212                  irgb = NINT( 41 + 20.*LOG10( zchl ) + 1.e-15 )
213                  zekb(:,:) = rkrgb(1,irgb)                       ! Separation in R-G-B depending of the chlorophyll
214                  zekg(:,:) = rkrgb(2,irgb)
215                  zekr(:,:) = rkrgb(3,irgb)
216               ENDIF
217               !
218               zcoef  = ( 1. - rn_abs ) / 3.e0                        ! equi-partition in R-G-B
219               ze0(:,:,1) = rn_abs  * qsr(:,:)
220               ze1(:,:,1) = zcoef * qsr(:,:)
221               ze2(:,:,1) = zcoef * qsr(:,:)
222               ze3(:,:,1) = zcoef * qsr(:,:)
223               zea(:,:,1) =         qsr(:,:)
224               !
225               DO jk = 2, nksr+1
226!CDIR NOVERRCHK
227                  DO jj = 1, jpj
228!CDIR NOVERRCHK   
229                     DO ji = 1, jpi
230                        zc0 = ze0(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * xsi0r(ji,jj) )
231                        zc1 = ze1(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekb(ji,jj) )
232                        zc2 = ze2(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekg(ji,jj) )
233                        zc3 = ze3(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekr(ji,jj) )
234                        ze0(ji,jj,jk) = zc0
235                        ze1(ji,jj,jk) = zc1
236                        ze2(ji,jj,jk) = zc2
237                        ze3(ji,jj,jk) = zc3
238                        zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk)
239                     END DO
240                  END DO
241               END DO
242               ! clem: store attenuation coefficient of the first ocean level
243               IF ( ln_qsr_ice ) THEN
244                  DO jj = 1, jpj
245                     DO ji = 1, jpi
246                        zzc0 = rn_abs * EXP( - fse3t(ji,jj,1) * xsi0r(ji,jj) )
247                        zzc1 = zcoef  * EXP( - fse3t(ji,jj,1) * zekb(ji,jj) )
248                        zzc2 = zcoef  * EXP( - fse3t(ji,jj,1) * zekg(ji,jj) )
249                        zzc3 = zcoef  * EXP( - fse3t(ji,jj,1) * zekr(ji,jj) )
250                        fraqsr_1lev(ji,jj) = 1.0 - ( zzc0 + zzc1 + zzc2  + zzc3  ) * tmask(ji,jj,2) 
251                     END DO
252                  END DO
253               ENDIF
254               !
255               DO jk = 1, nksr                                        ! compute and add qsr trend to ta
256                  qsr_hc(:,:,jk) = r1_rau0_rcp * ( zea(:,:,jk) - zea(:,:,jk+1) )
257               END DO
258               zea(:,:,nksr+1:jpk) = 0.e0     ! below 400m set to zero
259               CALL iom_put( 'qsr3d', zea )   ! Shortwave Radiation 3D distribution
260               !
261            ELSE                                                 !*  Constant Chlorophyll
262               DO jk = 1, nksr
263                  qsr_hc(:,:,jk) =  etot3(:,:,jk) * qsr(:,:)
264               END DO
265               ! clem: store attenuation coefficient of the first ocean level
266               IF ( ln_qsr_ice ) THEN
267                  fraqsr_1lev(:,:) = etot3(:,:,1) / r1_rau0_rcp
268               ENDIF
269           ENDIF
270
271         ENDIF
272         !                                                ! ------------------------- !
273         IF( ln_qsr_2bd ) THEN                            !  2 band light penetration !
274            !                                             ! ------------------------- !
275            !
276            IF( lk_vvl .OR. nn_spp_qsi0 > 0 ) THEN        !* variable volume
277
278               zz0   =        rn_abs   * r1_rau0_rcp
279               zz1   = ( 1. - rn_abs ) * r1_rau0_rcp
280               DO jk = 1, nksr                    ! solar heat absorbed at T-point in the top 400m
281                  DO jj = 1, jpj
282                     DO ji = 1, jpi
283                        zc0 = zz0 * EXP( -fsdepw(ji,jj,jk  )*xsi0r(ji,jj) ) + zz1 * EXP( -fsdepw(ji,jj,jk  )*xsi1r )
284                        zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r(ji,jj) ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r )
285                        qsr_hc(ji,jj,jk) = qsr(ji,jj) * ( zc0*tmask(ji,jj,jk) - zc1*tmask(ji,jj,jk+1) ) 
286                     END DO
287                  END DO
288               END DO
289               ! clem: store attenuation coefficient of the first ocean level
290               IF ( ln_qsr_ice ) THEN
291                  DO jj = 1, jpj
292                     DO ji = 1, jpi
293                        zc0 = zz0 * EXP( -fsdepw(ji,jj,1)*xsi0r(ji,jj) ) + zz1 * EXP( -fsdepw(ji,jj,1)*xsi1r )
294                        zc1 = zz0 * EXP( -fsdepw(ji,jj,2)*xsi0r(ji,jj) ) + zz1 * EXP( -fsdepw(ji,jj,2)*xsi1r )
295                        fraqsr_1lev(ji,jj) = ( zc0*tmask(ji,jj,1) - zc1*tmask(ji,jj,2) ) / r1_rau0_rcp
296                     END DO
297                  END DO
298               ENDIF
299            ELSE                                               !* constant volume: coef. computed one for all
300               DO jk = 1, nksr
301                  DO jj = 2, jpjm1
302                     DO ji = fs_2, fs_jpim1   ! vector opt.
303                        ! (ISF) no light penetration below the ice shelves         
304                        qsr_hc(ji,jj,jk) =  etot3(ji,jj,jk) * qsr(ji,jj) * tmask(ji,jj,1)
305                     END DO
306                  END DO
307               END DO
308               ! clem: store attenuation coefficient of the first ocean level
309               IF ( ln_qsr_ice ) THEN
310                  fraqsr_1lev(:,:) = etot3(:,:,1) / r1_rau0_rcp
311               ENDIF
312               !
313            ENDIF
314            !
315         ENDIF
316         !
317         !                                        Add to the general trend
318         DO jk = 1, nksr
319            DO jj = 2, jpjm1 
320               DO ji = fs_2, fs_jpim1   ! vector opt.
321                  z1_e3t = zfact / fse3t(ji,jj,jk)
322                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t
323               END DO
324            END DO
325         END DO
326         !
327      ENDIF
328      !
329      IF( lrst_oce ) THEN   !                  Write in the ocean restart file
330         !                                     *******************************
331         IF(lwp) WRITE(numout,*)
332         IF(lwp) WRITE(numout,*) 'qsr tracer content forcing field written in ocean restart file ',   &
333            &                    'at it= ', kt,' date= ', ndastp
334         IF(lwp) WRITE(numout,*) '~~~~'
335         CALL iom_rstput( kt, nitrst, numrow, 'qsr_hc_b'   , qsr_hc      )
336         CALL iom_rstput( kt, nitrst, numrow, 'fraqsr_1lev', fraqsr_1lev )   ! default definition in sbcssm
337         !
338      ENDIF
339
340      IF( l_trdtra ) THEN     ! qsr tracers trends saved for diagnostics
341         ztrdt(:,:,:) = tsa(:,:,:,jp_tem) - ztrdt(:,:,:)
342         CALL trd_tra( kt, 'TRA', jp_tem, jptra_qsr, ztrdt )
343         CALL wrk_dealloc( jpi, jpj, jpk, ztrdt ) 
344      ENDIF
345      !                       ! print mean trends (used for debugging)
346      IF(ln_ctl)   CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' qsr  - Ta: ', mask1=tmask, clinfo3='tra-ta' )
347      !
348      CALL wrk_dealloc( jpi, jpj,      zekb, zekg, zekr        ) 
349      CALL wrk_dealloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
350      !
351      IF( nn_timing == 1 )  CALL timing_stop('tra_qsr')
352      !
353   END SUBROUTINE tra_qsr
354
355
356   SUBROUTINE tra_qsr_init
357      !!----------------------------------------------------------------------
358      !!                  ***  ROUTINE tra_qsr_init  ***
359      !!
360      !! ** Purpose :   Initialization for the penetrative solar radiation
361      !!
362      !! ** Method  :   The profile of solar radiation within the ocean is set
363      !!      from two length scale of penetration (rn_si0,rn_si1) and a ratio
364      !!      (rn_abs). These parameters are read in the namtra_qsr namelist. The
365      !!      default values correspond to clear water (type I in Jerlov'
366      !!      (1968) classification.
367      !!         called by tra_qsr at the first timestep (nit000)
368      !!
369      !! ** Action  : - initialize rn_si0, rn_si1 and rn_abs
370      !!
371      !! Reference : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp.
372      !!----------------------------------------------------------------------
373      !
374      INTEGER  ::   ji, jj, jk                   ! dummy loop indices
375      INTEGER  ::   irgb, ierror, ioptio, nqsr   ! local integer
376      INTEGER  ::   ios                          ! Local integer output status for namelist read
377      REAL(wp) ::   zz0, zc0  , zc1, zcoef       ! local scalars
378      REAL(wp) ::   zz1, zc2  , zc3, zchl        !   -      -
379      REAL(wp), POINTER, DIMENSION(:,:  ) :: zekb, zekg, zekr
380      REAL(wp), POINTER, DIMENSION(:,:,:) :: ze0, ze1, ze2, ze3, zea
381      !
382      CHARACTER(len=100) ::   cn_dir   ! Root directory for location of ssr files
383      TYPE(FLD_N)        ::   sn_chl   ! informations about the chlorofyl field to be read
384      !!
385      NAMELIST/namtra_qsr/  sn_chl, cn_dir, ln_traqsr, ln_qsr_rgb, ln_qsr_2bd, ln_qsr_bio, ln_qsr_ice,  &
386         &                  nn_chldta, rn_abs, rn_si0, rn_si1
387      !!----------------------------------------------------------------------
388
389      !
390      IF( nn_timing == 1 )  CALL timing_start('tra_qsr_init')
391      !
392      CALL wrk_alloc( jpi, jpj,      zekb, zekg, zekr        ) 
393      CALL wrk_alloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
394      !
395
396      REWIND( numnam_ref )              ! Namelist namtra_qsr in reference namelist : Ratio and length of penetration
397      READ  ( numnam_ref, namtra_qsr, IOSTAT = ios, ERR = 901)
398901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_qsr in reference namelist', lwp )
399
400      REWIND( numnam_cfg )              !  Namelist namtra_qsr in configuration namelist : Ratio and length of penetration
401      READ  ( numnam_cfg, namtra_qsr, IOSTAT = ios, ERR = 902 )
402902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_qsr in configuration namelist', lwp )
403      IF(lwm) WRITE ( numond, namtra_qsr )
404      !
405      IF(lwp) THEN                ! control print
406         WRITE(numout,*)
407         WRITE(numout,*) 'tra_qsr_init : penetration of the surface solar radiation'
408         WRITE(numout,*) '~~~~~~~~~~~~'
409         WRITE(numout,*) '   Namelist namtra_qsr : set the parameter of penetration'
410         WRITE(numout,*) '      Light penetration (T) or not (F)         ln_traqsr  = ', ln_traqsr
411         WRITE(numout,*) '      RGB (Red-Green-Blue) light penetration   ln_qsr_rgb = ', ln_qsr_rgb
412         WRITE(numout,*) '      2 band               light penetration   ln_qsr_2bd = ', ln_qsr_2bd
413         WRITE(numout,*) '      bio-model            light penetration   ln_qsr_bio = ', ln_qsr_bio
414         WRITE(numout,*) '      light penetration for ice-model LIM3     ln_qsr_ice = ', ln_qsr_ice
415         WRITE(numout,*) '      RGB : Chl data (=1) or cst value (=0)    nn_chldta  = ', nn_chldta
416         WRITE(numout,*) '      RGB & 2 bands: fraction of light (rn_si1)    rn_abs = ', rn_abs
417         WRITE(numout,*) '      RGB & 2 bands: shortess depth of extinction  rn_si0 = ', rn_si0
418         WRITE(numout,*) '      2 bands: longest depth of extinction         rn_si1 = ', rn_si1
419      ENDIF
420
421      IF( ln_traqsr ) THEN     ! control consistency
422         !                     
423         IF( .NOT.lk_qsr_bio .AND. ln_qsr_bio )   THEN
424            CALL ctl_warn( 'No bio model : force ln_qsr_bio = FALSE ' )
425            ln_qsr_bio = .FALSE.
426         ENDIF
427         !
428         ioptio = 0                      ! Parameter control
429         IF( ln_qsr_rgb  )   ioptio = ioptio + 1
430         IF( ln_qsr_2bd  )   ioptio = ioptio + 1
431         IF( ln_qsr_bio  )   ioptio = ioptio + 1
432         !
433         IF( ioptio /= 1 ) &
434            CALL ctl_stop( '          Choose ONE type of light penetration in namelist namtra_qsr',  &
435            &              ' 2 bands, 3 RGB bands or bio-model light penetration' )
436         !
437         IF( ln_qsr_rgb .AND. nn_chldta == 0 )   nqsr =  1 
438         IF( ln_qsr_rgb .AND. nn_chldta == 1 )   nqsr =  2
439         IF( ln_qsr_2bd                      )   nqsr =  3
440         IF( ln_qsr_bio                      )   nqsr =  4
441         !
442         IF(lwp) THEN                   ! Print the choice
443            WRITE(numout,*)
444            IF( nqsr ==  1 )   WRITE(numout,*) '         R-G-B   light penetration - Constant Chlorophyll'
445            IF( nqsr ==  2 )   WRITE(numout,*) '         R-G-B   light penetration - Chl data '
446            IF( nqsr ==  3 )   WRITE(numout,*) '         2 bands light penetration'
447            IF( nqsr ==  4 )   WRITE(numout,*) '         bio-model light penetration'
448         ENDIF
449         !
450      ENDIF
451      !                          ! ===================================== !
452      IF( ln_traqsr  ) THEN      !  Initialisation of Light Penetration  ! 
453         !                       ! ===================================== !
454         !
455         ALLOCATE( xsi0r(jpi,jpj) )
456         xsi0r = 1.e0 / rn_si0
457         xsi1r = 1.e0 / rn_si1
458         !                                ! ---------------------------------- !
459         IF( ln_qsr_rgb ) THEN            !  Red-Green-Blue light penetration  !
460            !                             ! ---------------------------------- !
461            !
462            CALL trc_oce_rgb( rkrgb )           !* tabulated attenuation coef.
463            !
464            !                                   !* level of light extinction
465            IF(  ln_sco ) THEN   ;   nksr = jpkm1
466            ELSE                 ;   nksr = trc_oce_ext_lev( r_si2, 0.33e2 )
467            ENDIF
468
469            IF(lwp) WRITE(numout,*) '        level of light extinction = ', nksr, ' ref depth = ', gdepw_1d(nksr+1), ' m'
470            !
471            IF( nn_chldta == 1 ) THEN           !* Chl data : set sf_chl structure
472               IF(lwp) WRITE(numout,*)
473               IF(lwp) WRITE(numout,*) '        Chlorophyll read in a file'
474               ALLOCATE( sf_chl(1), STAT=ierror )
475               IF( ierror > 0 ) THEN
476                  CALL ctl_stop( 'tra_qsr_init: unable to allocate sf_chl structure' )   ;   RETURN
477               ENDIF
478               ALLOCATE( sf_chl(1)%fnow(jpi,jpj,1)   )
479               IF( sn_chl%ln_tint )ALLOCATE( sf_chl(1)%fdta(jpi,jpj,1,2) )
480               !                                        ! fill sf_chl with sn_chl and control print
481               CALL fld_fill( sf_chl, (/ sn_chl /), cn_dir, 'tra_qsr_init',   &
482                  &                                         'Solar penetration function of read chlorophyll', 'namtra_qsr' )
483               !
484            ELSE                                !* constant Chl : compute once for all the distribution of light (etot3)
485               IF(lwp) WRITE(numout,*)
486               IF(lwp) WRITE(numout,*) '        Constant Chlorophyll concentration = 0.05'
487               IF( lk_vvl ) THEN                   ! variable volume
488                  IF(lwp) WRITE(numout,*) '        key_vvl: light distribution will be computed at each time step'
489               ELSE                                ! constant volume: computes one for all
490                  IF(lwp) WRITE(numout,*) '        fixed volume: light distribution computed one for all'
491                  !
492                  zchl = 0.05                                 ! constant chlorophyll
493                  irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 )
494                  zekb(:,:) = rkrgb(1,irgb)                   ! Separation in R-G-B depending of the chlorophyll
495                  zekg(:,:) = rkrgb(2,irgb)
496                  zekr(:,:) = rkrgb(3,irgb)
497                  !
498                  zcoef = ( 1. - rn_abs ) / 3.e0              ! equi-partition in R-G-B
499                  ze0(:,:,1) = rn_abs
500                  ze1(:,:,1) = zcoef
501                  ze2(:,:,1) = zcoef 
502                  ze3(:,:,1) = zcoef
503                  zea(:,:,1) = tmask(:,:,1)                   ! = ( ze0+ze1+z2+ze3 ) * tmask
504               
505                  DO jk = 2, nksr+1
506!CDIR NOVERRCHK
507                     DO jj = 1, jpj
508!CDIR NOVERRCHK   
509                        DO ji = 1, jpi
510                           zc0 = ze0(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * xsi0r(ji,jj) )
511                           zc1 = ze1(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * zekb(ji,jj) )
512                           zc2 = ze2(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * zekg(ji,jj) )
513                           zc3 = ze3(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * zekr(ji,jj) )
514                           ze0(ji,jj,jk) = zc0
515                           ze1(ji,jj,jk) = zc1
516                           ze2(ji,jj,jk) = zc2
517                           ze3(ji,jj,jk) = zc3
518                           zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk)
519                        END DO
520                     END DO
521                  END DO 
522                  !
523                  DO jk = 1, nksr
524                     ! (ISF) no light penetration below the ice shelves
525                     etot3(:,:,jk) = r1_rau0_rcp * ( zea(:,:,jk) - zea(:,:,jk+1) ) * tmask(:,:,1)
526                  END DO
527                  etot3(:,:,nksr+1:jpk) = 0.e0                ! below 400m set to zero
528               ENDIF
529            ENDIF
530            !
531         ENDIF
532            !                             ! ---------------------------------- !
533         IF( ln_qsr_2bd ) THEN            !    2 bands    light penetration    !
534            !                             ! ---------------------------------- !
535            !
536            !                                ! level of light extinction
537            nksr = trc_oce_ext_lev( rn_si1, 1.e2 )
538            IF(lwp) THEN
539               WRITE(numout,*)
540            IF(lwp) WRITE(numout,*) '        level of light extinction = ', nksr, ' ref depth = ', gdepw_1d(nksr+1), ' m'
541            ENDIF
542            !
543            IF( lk_vvl ) THEN                   ! variable volume
544               IF(lwp) WRITE(numout,*) '        key_vvl: light distribution will be computed at each time step'
545            ELSE                                ! constant volume: computes one for all
546               zz0 =        rn_abs   * r1_rau0_rcp
547               zz1 = ( 1. - rn_abs ) * r1_rau0_rcp
548               DO jk = 1, nksr                    !*  solar heat absorbed at T-point computed once for all
549                  DO jj = 1, jpj                              ! top 400 meters
550                     DO ji = 1, jpi
551                        zc0 = zz0 * EXP( -fsdepw(ji,jj,jk  )*xsi0r(ji,jj) ) + zz1 * EXP( -fsdepw(ji,jj,jk  )*xsi1r )
552                        zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r(ji,jj) ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r )
553                        etot3(ji,jj,jk) = (  zc0 * tmask(ji,jj,jk) - zc1 * tmask(ji,jj,jk+1)  ) * tmask(ji,jj,1) 
554                     END DO
555                  END DO
556               END DO
557               etot3(:,:,nksr+1:jpk) = 0.e0                   ! below 400m set to zero
558               !
559            ENDIF
560         ENDIF
561         !                       ! ===================================== !
562      ELSE                       !        No light penetration           !                   
563         !                       ! ===================================== !
564         IF(lwp) THEN
565            WRITE(numout,*)
566            WRITE(numout,*) 'tra_qsr_init : NO solar flux penetration'
567            WRITE(numout,*) '~~~~~~~~~~~~'
568         ENDIF
569      ENDIF
570      !
571      ! initialisation of fraqsr_1lev used in sbcssm
572      IF( iom_varid( numror, 'fraqsr_1lev', ldstop = .FALSE. ) > 0 ) THEN
573         CALL iom_get( numror, jpdom_autoglo, 'fraqsr_1lev'  , fraqsr_1lev  )
574      ELSE
575         fraqsr_1lev(:,:) = 1._wp   ! default definition
576      ENDIF
577      !
578      CALL wrk_dealloc( jpi, jpj,      zekb, zekg, zekr        ) 
579      CALL wrk_dealloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
580      !
581      IF( nn_timing == 1 )  CALL timing_stop('tra_qsr_init')
582      !
583   END SUBROUTINE tra_qsr_init
584
585   !!======================================================================
586END MODULE traqsr
Note: See TracBrowser for help on using the repository browser.