source: branches/UKMO/dev_r5518_cleanup_1d_cpl/NEMOGCM/NEMO/OPA_SRC/SBC/cpl_oasis3.F90 @ 10041

Last change on this file since 10041 was 10041, checked in by dancopsey, 2 years ago

Added coupling of 1D river outflow.

File size: 33.8 KB
Line 
1MODULE cpl_oasis3
2   !!======================================================================
3   !!                    ***  MODULE cpl_oasis  ***
4   !! Coupled O/A : coupled ocean-atmosphere case using OASIS3-MCT
5   !!=====================================================================
6   !! History :   
7   !!   9.0  !  04-06  (R. Redler, NEC Laboratories Europe, Germany) Original code
8   !!   " "  !  04-11  (R. Redler, NEC Laboratories Europe; N. Keenlyside, W. Park, IFM-GEOMAR, Germany) revision
9   !!   " "  !  04-11  (V. Gayler, MPI M&D) Grid writing
10   !!   " "  !  05-08  (R. Redler, W. Park) frld initialization, paral(2) revision
11   !!   " "  !  05-09  (R. Redler) extended to allow for communication over root only
12   !!   " "  !  06-01  (W. Park) modification of physical part
13   !!   " "  !  06-02  (R. Redler, W. Park) buffer array fix for root exchange
14   !!   3.4  !  11-11  (C. Harris) Changes to allow mutiple category fields
15   !!----------------------------------------------------------------------
16   !!----------------------------------------------------------------------
17   !!   'key_oasis3'                    coupled Ocean/Atmosphere via OASIS3-MCT
18   !!   'key_oa3mct_v3'                 to be added for OASIS3-MCT version 3
19   !!----------------------------------------------------------------------
20   !!   cpl_init     : initialization of coupled mode communication
21   !!   cpl_define   : definition of grid and fields
22   !!   cpl_snd     : snd out fields in coupled mode
23   !!   cpl_rcv     : receive fields in coupled mode
24   !!   cpl_finalize : finalize the coupled mode communication
25   !!----------------------------------------------------------------------
26#if defined key_oasis3
27   USE mod_oasis                    ! OASIS3-MCT module
28#endif
29   USE par_oce                      ! ocean parameters
30   USE cpl_rnf_1d, ONLY: nn_cpl_river   ! Variables used in 1D river outflow
31   USE dom_oce                      ! ocean space and time domain
32   USE in_out_manager               ! I/O manager
33   USE lbclnk                       ! ocean lateral boundary conditions (or mpp link)
34   
35   IMPLICIT NONE
36   PRIVATE
37
38   PUBLIC   cpl_init
39   PUBLIC   cpl_define
40   PUBLIC   cpl_snd
41   PUBLIC   cpl_rcv
42   PUBLIC   cpl_rcv_1d
43   PUBLIC   cpl_freq
44   PUBLIC   cpl_finalize
45#if defined key_mpp_mpi
46   INCLUDE 'mpif.h'
47#endif
48   
49   INTEGER, PARAMETER         :: localRoot  = 0
50   LOGICAL                    :: commRank            ! true for ranks doing OASIS communication
51#if defined key_cpl_rootexchg
52   LOGICAL                    :: rootexchg =.true.   ! logical switch
53#else
54   LOGICAL                    :: rootexchg =.false.  ! logical switch
55#endif
56
57   INTEGER, PUBLIC            ::   OASIS_Rcv  = 1    !: return code if received field
58   INTEGER, PUBLIC            ::   OASIS_idle = 0    !: return code if nothing done by oasis
59   INTEGER                    ::   ncomp_id          ! id returned by oasis_init_comp
60   INTEGER                    ::   nerror            ! return error code
61#if ! defined key_oasis3
62   ! OASIS Variables not used. defined only for compilation purpose
63   INTEGER                    ::   OASIS_Out         = -1
64   INTEGER                    ::   OASIS_REAL        = -1
65   INTEGER                    ::   OASIS_Ok          = -1
66   INTEGER                    ::   OASIS_In          = -1
67   INTEGER                    ::   OASIS_Sent        = -1
68   INTEGER                    ::   OASIS_SentOut     = -1
69   INTEGER                    ::   OASIS_ToRest      = -1
70   INTEGER                    ::   OASIS_ToRestOut   = -1
71   INTEGER                    ::   OASIS_Recvd       = -1
72   INTEGER                    ::   OASIS_RecvOut     = -1
73   INTEGER                    ::   OASIS_FromRest    = -1
74   INTEGER                    ::   OASIS_FromRestOut = -1
75#endif
76
77   INTEGER                    ::   nrcv         ! total number of fields received
78   INTEGER                    ::   nsnd         ! total number of fields sent
79   INTEGER                    ::   ncplmodel    ! Maximum number of models to/from which NEMO is potentialy sending/receiving data
80   INTEGER, PUBLIC, PARAMETER ::   nmaxfld=50   ! Maximum number of coupling fields
81   INTEGER, PUBLIC, PARAMETER ::   nmaxcat=5    ! Maximum number of coupling fields
82   INTEGER, PUBLIC, PARAMETER ::   nmaxcpl=5    ! Maximum number of coupling fields
83   
84   TYPE, PUBLIC ::   FLD_CPL               !: Type for coupling field information
85      LOGICAL               ::   laction   ! To be coupled or not
86      CHARACTER(len = 8)    ::   clname    ! Name of the coupling field   
87      CHARACTER(len = 1)    ::   clgrid    ! Grid type 
88      REAL(wp)              ::   nsgn      ! Control of the sign change
89      INTEGER, DIMENSION(nmaxcat,nmaxcpl) ::   nid   ! Id of the field (no more than 9 categories and 9 extrena models)
90      INTEGER               ::   nct       ! Number of categories in field
91      INTEGER               ::   ncplmodel ! Maximum number of models to/from which this variable may be sent/received
92      INTEGER               ::   dimensions ! Number of dimensions of coupling field
93   END TYPE FLD_CPL
94
95   TYPE(FLD_CPL), DIMENSION(nmaxfld), PUBLIC ::   srcv, ssnd   !: Coupling fields
96
97   REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   exfld   ! Temporary buffer for receiving
98   INTEGER, PUBLIC :: localComm 
99     
100   !!----------------------------------------------------------------------
101   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
102   !! $Id$
103   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
104   !!----------------------------------------------------------------------
105CONTAINS
106
107   SUBROUTINE cpl_init( cd_modname, kl_comm )
108      !!-------------------------------------------------------------------
109      !!             ***  ROUTINE cpl_init  ***
110      !!
111      !! ** Purpose :   Initialize coupled mode communication for ocean
112      !!    exchange between AGCM, OGCM and COUPLER. (OASIS3 software)
113      !!
114      !! ** Method  :   OASIS3 MPI communication
115      !!--------------------------------------------------------------------
116      CHARACTER(len = *), INTENT(in) ::   cd_modname   ! model name as set in namcouple file
117      INTEGER          , INTENT(out) ::   kl_comm      ! local communicator of the model
118      !!--------------------------------------------------------------------
119
120      ! WARNING: No write in numout in this routine
121      !============================================
122
123      !------------------------------------------------------------------
124      ! 1st Initialize the OASIS system for the application
125      !------------------------------------------------------------------
126      CALL oasis_init_comp ( ncomp_id, TRIM(cd_modname), nerror )
127      IF ( nerror /= OASIS_Ok ) &
128         CALL oasis_abort (ncomp_id, 'cpl_init', 'Failure in oasis_init_comp')
129
130      !------------------------------------------------------------------
131      ! 3rd Get an MPI communicator for OPA local communication
132      !------------------------------------------------------------------
133
134      CALL oasis_get_localcomm ( kl_comm, nerror )
135      IF ( nerror /= OASIS_Ok ) &
136         CALL oasis_abort (ncomp_id, 'cpl_init','Failure in oasis_get_localcomm' )
137      localComm = kl_comm 
138      !
139   END SUBROUTINE cpl_init
140
141
142   SUBROUTINE cpl_define( krcv, ksnd, kcplmodel )
143      !!-------------------------------------------------------------------
144      !!             ***  ROUTINE cpl_define  ***
145      !!
146      !! ** Purpose :   Define grid and field information for ocean
147      !!    exchange between AGCM, OGCM and COUPLER. (OASIS3 software)
148      !!
149      !! ** Method  :   OASIS3 MPI communication
150      !!--------------------------------------------------------------------
151      INTEGER, INTENT(in) ::   krcv, ksnd     ! Number of received and sent coupling fields
152      INTEGER, INTENT(in) ::   kcplmodel      ! Maximum number of models to/from which NEMO is potentialy sending/receiving data
153      !
154      INTEGER :: id_part
155      INTEGER :: id_part_0d     ! Partition for 0d fields
156      INTEGER :: id_part_rnf_1d ! Partition for 1d river outflow fields
157      INTEGER :: id_part_temp   ! Temperary partition used to choose either 0d or 1d partitions
158      INTEGER :: vector_length  ! Length of 0d or 1d variables (0d variables will have vector_length=1)
159      INTEGER :: paral(5)       ! OASIS3 box partition
160      INTEGER :: ishape(2,2)    ! shape of arrays passed to PSMILe
161      INTEGER :: ji,jc,jm       ! local loop indicees
162      CHARACTER(LEN=64) :: zclname
163      CHARACTER(LEN=2) :: cli2
164      !!--------------------------------------------------------------------
165
166      IF(lwp) WRITE(numout,*)
167      IF(lwp) WRITE(numout,*) 'cpl_define : initialization in coupled ocean/atmosphere case'
168      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~~~~'
169      IF(lwp) WRITE(numout,*)
170
171      ncplmodel = kcplmodel
172      IF( kcplmodel > nmaxcpl ) THEN
173         CALL oasis_abort ( ncomp_id, 'cpl_define', 'ncplmodel is larger than nmaxcpl, increase nmaxcpl')   ;   RETURN
174      ENDIF
175
176      nrcv = krcv
177      IF( nrcv > nmaxfld ) THEN
178         CALL oasis_abort ( ncomp_id, 'cpl_define', 'nrcv is larger than nmaxfld, increase nmaxfld')   ;   RETURN
179      ENDIF
180
181      nsnd = ksnd
182      IF( nsnd > nmaxfld ) THEN
183         CALL oasis_abort ( ncomp_id, 'cpl_define', 'nsnd is larger than nmaxfld, increase nmaxfld')   ;   RETURN
184      ENDIF
185
186      !
187      ! ... Define the shape for the area that excludes the halo
188      !     For serial configuration (key_mpp_mpi not being active)
189      !     nl* is set to the global values 1 and jp*glo.
190      !
191      ishape(:,1) = (/ 1, nlei-nldi+1 /)
192      ishape(:,2) = (/ 1, nlej-nldj+1 /)
193      !
194      ! ... Allocate memory for data exchange
195      !
196      ALLOCATE(exfld(nlei-nldi+1, nlej-nldj+1), stat = nerror)
197      IF( nerror > 0 ) THEN
198         CALL oasis_abort ( ncomp_id, 'cpl_define', 'Failure in allocating exfld')   ;   RETURN
199      ENDIF     
200      !
201      ! -----------------------------------------------------------------
202      ! ... Define the partition
203      ! -----------------------------------------------------------------
204           
205      paral(1) = 2                                              ! box partitioning
206      paral(2) = jpiglo * (nldj-1+njmpp-1) + (nldi-1+nimpp-1)   ! NEMO lower left corner global offset   
207      paral(3) = nlei-nldi+1                                    ! local extent in i
208      paral(4) = nlej-nldj+1                                    ! local extent in j
209      paral(5) = jpiglo                                         ! global extent in x
210     
211      IF( ln_ctl ) THEN
212         WRITE(numout,*) ' multiexchg: paral (1:5)', paral
213         WRITE(numout,*) ' multiexchg: jpi, jpj =', jpi, jpj
214         WRITE(numout,*) ' multiexchg: nldi, nlei, nimpp =', nldi, nlei, nimpp
215         WRITE(numout,*) ' multiexchg: nldj, nlej, njmpp =', nldj, nlej, njmpp
216      ENDIF
217     
218      CALL oasis_def_partition ( id_part, paral, nerror, jpiglo*jpjglo)
219
220      ! A special partition is needed for 0D fields
221     
222      paral(1) = 0                                       ! serial partitioning
223      paral(2) = 0   
224      IF ( nproc == 0) THEN
225         paral(3) = 1                   ! Size of array to couple (scalar)
226      ELSE
227         paral(3) = 0                   ! Dummy size for PE's not involved
228      END IF
229      paral(4) = 0
230      paral(5) = 0
231       
232      CALL oasis_def_partition ( id_part_0d, paral, nerror, 1 )
233
234      ! Another partition is needed for 1D river routing fields
235     
236      paral(1) = 0                                       ! serial partitioning
237      paral(2) = 0   
238      IF ( nproc == 0) THEN
239         paral(3) = nn_cpl_river                   ! Size of array to couple (vector)
240      ELSE
241         paral(3) = 0                   ! Dummy size for PE's not involved
242      END IF
243      paral(4) = 0
244      paral(5) = 0
245
246
247      CALL oasis_def_partition ( id_part_rnf_1d, paral, nerror, nn_cpl_river )
248 
249      !
250      ! ... Announce send variables.
251      !
252      ssnd(:)%ncplmodel = kcplmodel
253      !
254      DO ji = 1, ksnd
255         IF ( ssnd(ji)%laction ) THEN
256
257            IF( ssnd(ji)%nct > nmaxcat ) THEN
258               CALL oasis_abort ( ncomp_id, 'cpl_define', 'Number of categories of '//   &
259                  &              TRIM(ssnd(ji)%clname)//' is larger than nmaxcat, increase nmaxcat' )
260               RETURN
261            ENDIF
262           
263            DO jc = 1, ssnd(ji)%nct
264               DO jm = 1, kcplmodel
265
266                  IF ( ssnd(ji)%nct .GT. 1 ) THEN
267                     WRITE(cli2,'(i2.2)') jc
268                     zclname = TRIM(ssnd(ji)%clname)//'_cat'//cli2
269                  ELSE
270                     zclname = ssnd(ji)%clname
271                  ENDIF
272                  IF ( kcplmodel  > 1 ) THEN
273                     WRITE(cli2,'(i2.2)') jm
274                     zclname = 'model'//cli2//'_'//TRIM(zclname)
275                  ENDIF
276#if defined key_agrif
277                  IF( agrif_fixed() /= 0 ) THEN
278                     zclname=TRIM(Agrif_CFixed())//'_'//TRIM(zclname)
279                  END IF
280#endif
281                  IF( ln_ctl ) WRITE(numout,*) "Define", ji, jc, jm, " "//TRIM(zclname), " for ", OASIS_Out
282                  CALL oasis_def_var (ssnd(ji)%nid(jc,jm), zclname, id_part   , (/ 2, 0 /),   &
283                     &                OASIS_Out          , ishape , OASIS_REAL, nerror )
284                  IF ( nerror /= OASIS_Ok ) THEN
285                     WRITE(numout,*) 'Failed to define transient ', ji, jc, jm, " "//TRIM(zclname)
286                     CALL oasis_abort ( ssnd(ji)%nid(jc,jm), 'cpl_define', 'Failure in oasis_def_var' )
287                  ENDIF
288                  IF( ln_ctl .AND. ssnd(ji)%nid(jc,jm) /= -1 ) WRITE(numout,*) "variable defined in the namcouple"
289                  IF( ln_ctl .AND. ssnd(ji)%nid(jc,jm) == -1 ) WRITE(numout,*) "variable NOT defined in the namcouple"
290               END DO
291            END DO
292         ENDIF
293      END DO     
294      !
295      ! ... Announce received variables.
296      !
297      srcv(:)%ncplmodel = kcplmodel
298      !
299      DO ji = 1, krcv
300         IF ( srcv(ji)%laction ) THEN
301           
302            IF( srcv(ji)%nct > nmaxcat ) THEN
303               CALL oasis_abort ( ncomp_id, 'cpl_define', 'Number of categories of '//   &
304                  &              TRIM(srcv(ji)%clname)//' is larger than nmaxcat, increase nmaxcat' )
305               RETURN
306            ENDIF
307           
308            DO jc = 1, srcv(ji)%nct
309               DO jm = 1, kcplmodel
310                 
311                  IF ( srcv(ji)%nct .GT. 1 ) THEN
312                     WRITE(cli2,'(i2.2)') jc
313                     zclname = TRIM(srcv(ji)%clname)//'_cat'//cli2
314                  ELSE
315                     zclname = srcv(ji)%clname
316                  ENDIF
317                  IF ( kcplmodel  > 1 ) THEN
318                     WRITE(cli2,'(i2.2)') jm
319                     zclname = 'model'//cli2//'_'//TRIM(zclname)
320                  ENDIF
321#if defined key_agrif
322                  IF( agrif_fixed() /= 0 ) THEN
323                     zclname=TRIM(Agrif_CFixed())//'_'//TRIM(zclname)
324                  END IF
325#endif
326                  IF( ln_ctl ) WRITE(numout,*) "Define", ji, jc, jm, " "//TRIM(zclname), " for ", OASIS_In
327flush(numout)
328
329                  ! Define 0D (Greenland or Antarctic ice mass) or 1D (river outflow) coupling fields
330                  IF (srcv(ji)%dimensions <= 1) THEN
331WRITE(numout,*) "RSRH 0d or 1d define field ",zclname; flush(numout)
332                    IF (nproc == 0) THEN                   
333                       
334                       IF (srcv(ji)%dimensions == 0) THEN
335                       
336                          ! If 0D then set temporary variables to 0D components
337                          id_part_temp = id_part_0d
338                          vector_length = 1
339                       ELSE
340                       
341                          ! If 1D then set temporary variables to river outflow components
342                          id_part_temp = id_part_rnf_1d
343                          vector_length = nn_cpl_river
344                         
345                       END IF
346                       
347                       CALL oasis_def_var (srcv(ji)%nid(jc,jm), zclname, id_part_temp   , (/ 1, 0 /),   &
348                                   OASIS_In           , (/ 1, vector_length /) , OASIS_REAL, nerror )
349                    ELSE
350                       ! Dummy call to keep OASIS3-MCT happy.
351                       CALL oasis_def_var (srcv(ji)%nid(jc,jm), zclname, id_part_0d   , (/ 1, 0 /),   &
352                                   OASIS_In           , (/ 0, 0 /) , OASIS_REAL, nerror )
353                    END IF
354WRITE(numout,*) "RSRH 0d field done ",zclname,nerror; flush(numout)
355                  ELSE
356WRITE(numout,*) "RSRH 2d define field ",zclname; flush(numout)
357                    ! It's a "normal" 2D (or pseudo 3D) coupling field. 
358                    CALL oasis_def_var (srcv(ji)%nid(jc,jm), zclname, id_part   , (/ 2, 0 /),   &
359                                         OASIS_In           , ishape , OASIS_REAL, nerror )
360WRITE(numout,*) "RSRH 2d field done ",zclname,nerror; flush(numout)
361                  ENDIF
362
363                  IF ( nerror /= OASIS_Ok ) THEN
364                     WRITE(numout,*) 'Failed to define transient ', ji, jc, jm, " "//TRIM(zclname)
365                     CALL oasis_abort ( srcv(ji)%nid(jc,jm), 'cpl_define', 'Failure in oasis_def_var' )
366                  ENDIF
367                  IF( ln_ctl .AND. srcv(ji)%nid(jc,jm) /= -1 ) WRITE(numout,*) "variable defined in the namcouple"
368                  IF( ln_ctl .AND. srcv(ji)%nid(jc,jm) == -1 ) WRITE(numout,*) "variable NOT defined in the namcouple"
369
370               END DO
371            END DO
372         ENDIF
373      END DO
374     
375      !------------------------------------------------------------------
376      ! End of definition phase
377      !------------------------------------------------------------------
378 WRITE(numout,*) "RSRH NEMO calling enddef";flush(numout)     
379      CALL oasis_enddef(nerror)
380WRITE(numout,*) "RSRH NEMO finished enddef", nerror;flush(numout)     
381      IF( nerror /= OASIS_Ok )   CALL oasis_abort ( ncomp_id, 'cpl_define', 'Failure in oasis_enddef')
382      !
383   END SUBROUTINE cpl_define
384   
385   
386   SUBROUTINE cpl_snd( kid, kstep, pdata, kinfo )
387      !!---------------------------------------------------------------------
388      !!              ***  ROUTINE cpl_snd  ***
389      !!
390      !! ** Purpose : - At each coupling time-step,this routine sends fields
391      !!      like sst or ice cover to the coupler or remote application.
392      !!----------------------------------------------------------------------
393      INTEGER                   , INTENT(in   ) ::   kid       ! variable index in the array
394      INTEGER                   , INTENT(  out) ::   kinfo     ! OASIS3 info argument
395      INTEGER                   , INTENT(in   ) ::   kstep     ! ocean time-step in seconds
396      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   pdata
397      !!
398      INTEGER                                   ::   jc,jm     ! local loop index
399      !!--------------------------------------------------------------------
400      !
401      ! snd data to OASIS3
402      !
403      DO jc = 1, ssnd(kid)%nct
404         DO jm = 1, ssnd(kid)%ncplmodel
405       
406            IF( ssnd(kid)%nid(jc,jm) /= -1 ) THEN
407               CALL oasis_put ( ssnd(kid)%nid(jc,jm), kstep, pdata(nldi:nlei, nldj:nlej,jc), kinfo )
408               
409               IF ( ln_ctl ) THEN       
410                  IF ( kinfo == OASIS_Sent     .OR. kinfo == OASIS_ToRest .OR.   &
411                     & kinfo == OASIS_SentOut  .OR. kinfo == OASIS_ToRestOut ) THEN
412                     WRITE(numout,*) '****************'
413                     WRITE(numout,*) 'oasis_put: Outgoing ', ssnd(kid)%clname
414                     WRITE(numout,*) 'oasis_put: ivarid ', ssnd(kid)%nid(jc,jm)
415                     WRITE(numout,*) 'oasis_put:  kstep ', kstep
416                     WRITE(numout,*) 'oasis_put:   info ', kinfo
417                     WRITE(numout,*) '     - Minimum value is ', MINVAL(pdata(:,:,jc))
418                     WRITE(numout,*) '     - Maximum value is ', MAXVAL(pdata(:,:,jc))
419                     WRITE(numout,*) '     -     Sum value is ', SUM(pdata(:,:,jc))
420                     WRITE(numout,*) '****************'
421                  ENDIF
422               ENDIF
423               
424            ENDIF
425           
426         ENDDO
427      ENDDO
428      !
429    END SUBROUTINE cpl_snd
430
431
432   SUBROUTINE cpl_rcv( kid, kstep, pdata, pmask, kinfo )
433      !!---------------------------------------------------------------------
434      !!              ***  ROUTINE cpl_rcv  ***
435      !!
436      !! ** Purpose : - At each coupling time-step,this routine receives fields
437      !!      like stresses and fluxes from the coupler or remote application.
438      !!----------------------------------------------------------------------
439      INTEGER                   , INTENT(in   ) ::   kid       ! variable index in the array
440      INTEGER                   , INTENT(in   ) ::   kstep     ! ocean time-step in seconds
441      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pdata     ! IN to keep the value if nothing is done
442      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   pmask     ! coupling mask
443      INTEGER                   , INTENT(  out) ::   kinfo     ! OASIS3 info argument
444      !!
445      INTEGER                                   ::   jc,jm     ! local loop index
446      LOGICAL                                   ::   llaction, llfisrt
447      !!--------------------------------------------------------------------
448      !
449      ! receive local data from OASIS3 on every process
450      !
451      kinfo = OASIS_idle
452      !
453      DO jc = 1, srcv(kid)%nct
454         llfisrt = .TRUE.
455
456         DO jm = 1, srcv(kid)%ncplmodel
457
458            IF( srcv(kid)%nid(jc,jm) /= -1 ) THEN
459
460               CALL oasis_get ( srcv(kid)%nid(jc,jm), kstep, exfld, kinfo )   
461               
462               llaction =  kinfo == OASIS_Recvd   .OR. kinfo == OASIS_FromRest .OR.   &
463                &        kinfo == OASIS_RecvOut .OR. kinfo == OASIS_FromRestOut
464               
465               IF ( ln_ctl )   WRITE(numout,*) "llaction, kinfo, kstep, ivarid: " , llaction, kinfo, kstep, srcv(kid)%nid(jc,jm)
466               
467               IF ( llaction ) THEN
468                 
469                  kinfo = OASIS_Rcv
470                  IF( llfisrt ) THEN
471                     pdata(nldi:nlei,nldj:nlej,jc) =                                 exfld(:,:) * pmask(nldi:nlei,nldj:nlej,jm) 
472                     llfisrt = .FALSE.
473                  ELSE
474                     pdata(nldi:nlei,nldj:nlej,jc) = pdata(nldi:nlei,nldj:nlej,jc) + exfld(:,:) * pmask(nldi:nlei,nldj:nlej,jm)
475                  ENDIF
476                 
477                  IF ( ln_ctl ) THEN       
478                     WRITE(numout,*) '****************'
479                     WRITE(numout,*) 'oasis_get: Incoming ', srcv(kid)%clname
480                     WRITE(numout,*) 'oasis_get: ivarid '  , srcv(kid)%nid(jc,jm)
481                     WRITE(numout,*) 'oasis_get:   kstep', kstep
482                     WRITE(numout,*) 'oasis_get:   info ', kinfo
483                     WRITE(numout,*) '     - Minimum value is ', MINVAL(pdata(:,:,jc))
484                     WRITE(numout,*) '     - Maximum value is ', MAXVAL(pdata(:,:,jc))
485                     WRITE(numout,*) '     -     Sum value is ', SUM(pdata(:,:,jc))
486                     WRITE(numout,*) '****************'
487                  ENDIF
488
489               ENDIF
490
491            ENDIF
492           
493         ENDDO
494
495         !--- Fill the overlap areas and extra hallows (mpp)
496         !--- check periodicity conditions (all cases)
497         IF( .not. llfisrt )   CALL lbc_lnk( pdata(:,:,jc), srcv(kid)%clgrid, srcv(kid)%nsgn )   
498 
499      ENDDO
500      !
501   END SUBROUTINE cpl_rcv
502
503   SUBROUTINE cpl_rcv_1d( kid, kstep, pdata, nitems, kinfo )
504      !!---------------------------------------------------------------------
505      !!              ***  ROUTINE cpl_rcv_1d  ***
506      !!
507      !! ** Purpose : - A special version of cpl_rcv to deal exclusively with
508      !! receipt of 0D or 1D fields.
509      !! The fields are recieved into a 1D array buffer which is simply a
510      !! dynamically sized sized array (which may be of size 1)
511      !! of 0 dimensional fields. This allows us to pass miltiple 0D
512      !! fields via a single put/get operation. 
513      !!----------------------------------------------------------------------
514      INTEGER , INTENT(in   ) ::   nitems      ! Number of 0D items to recieve
515                                               ! during this get operation. i.e.
516                                               ! The size of the 1D array in which
517                                               ! 0D items are passed.   
518      INTEGER , INTENT(in   ) ::   kid         ! ID index of the incoming
519                                               ! data. 
520      INTEGER , INTENT(in   ) ::   kstep       ! ocean time-step in seconds
521      REAL(wp), INTENT(inout) ::   pdata(1:nitems) ! The original value(s), 
522                                                   ! unchanged if nothing is
523                                                   ! received
524      INTEGER , INTENT(  out) ::   kinfo       ! OASIS3 info argument
525      !!
526      REAL(wp) ::   recvfld(1:nitems)          ! Local receive field buffer
527      INTEGER  ::   jc,jm     ! local loop index
528      INTEGER  ::   ierr
529      LOGICAL  ::   llaction
530      INTEGER  ::   MPI_WORKING_PRECISION
531      INTEGER  ::   number_to_print 
532      !!--------------------------------------------------------------------
533      !
534      ! receive local data from OASIS3 on every process
535      !
536      kinfo = OASIS_idle
537      !
538      ! 0D and 1D fields won't have categories or any other form of "pseudo level"
539      ! so we only cater for a single set of values and thus don't bother
540      ! with a loop over the jc index
541      jc = 1
542
543      DO jm = 1, srcv(kid)%ncplmodel
544
545         IF( srcv(kid)%nid(jc,jm) /= -1 ) THEN
546
547            IF ( ( srcv(kid)%dimensions <= 1) .AND. (nproc == 0) ) THEN
548               ! Since there is no concept of data decomposition for zero
549               ! dimension fields, they must only be exchanged through the master PE,
550               ! unlike "normal" 2D field cases where every PE is involved.
551
552               CALL oasis_get ( srcv(kid)%nid(jc,jm), kstep, recvfld, kinfo )   
553               
554               llaction =  kinfo == OASIS_Recvd   .OR. kinfo == OASIS_FromRest .OR.   &
555                           kinfo == OASIS_RecvOut .OR. kinfo == OASIS_FromRestOut
556               
557               IF ( ln_ctl ) WRITE(numout,*) "llaction, kinfo, kstep, ivarid: " , &
558                                     llaction, kinfo, kstep, srcv(kid)%nid(jc,jm)
559               
560               IF ( llaction ) THEN
561                 
562                  kinfo = OASIS_Rcv
563                  pdata(1:nitems) = recvfld(1:nitems) 
564                 
565                  IF ( ln_ctl ) THEN       
566                     number_to_print = 10
567                     IF ( nitems < number_to_print ) number_to_print = nitems
568                     WRITE(numout,*) '****************'
569                     WRITE(numout,*) 'oasis_get: Incoming ', srcv(kid)%clname
570                     WRITE(numout,*) 'oasis_get: ivarid '  , srcv(kid)%nid(jc,jm)
571                     WRITE(numout,*) 'oasis_get:   kstep', kstep
572                     WRITE(numout,*) 'oasis_get:   info ', kinfo
573                     WRITE(numout,*) '     - Minimum Value is ', MINVAL(pdata(:))
574                     WRITE(numout,*) '     - Maximum value is ', MAXVAL(pdata(:))
575                     WRITE(numout,*) '     - Start of data is ', pdata(1:number_to_print)
576                     WRITE(numout,*) '****************'
577                  ENDIF
578                 
579               ENDIF
580            ENDIF   
581          ENDIF
582           
583       ENDDO
584       
585       ! Set the precision that we want to broadcast using MPI_BCAST
586       SELECT CASE( wp )
587       CASE( sp ) 
588         MPI_WORKING_PRECISION = MPI_REAL                ! Single precision
589       CASE( dp )
590         MPI_WORKING_PRECISION = MPI_DOUBLE_PRECISION    ! Double precision
591       CASE default
592         CALL oasis_abort( ncomp_id, "cpl_rcv_1d", "Could not find precision for coupling 0d or 1d field" )
593       END SELECT
594
595       ! We have to broadcast (potentially) received values from PE 0 to all
596       ! the others. If no new data has been received we're just
597       ! broadcasting the existing values but there's no more efficient way
598       ! to deal with that w/o NEMO adopting a UM-style test mechanism
599       ! to determine active put/get timesteps.
600       CALL mpi_bcast( pdata, nitems, MPI_WORKING_PRECISION, localRoot, mpi_comm_opa, ierr )
601
602      !
603   END SUBROUTINE cpl_rcv_1d
604
605
606   INTEGER FUNCTION cpl_freq( cdfieldname ) 
607      !!---------------------------------------------------------------------
608      !!              ***  ROUTINE cpl_freq  ***
609      !!
610      !! ** Purpose : - send back the coupling frequency for a particular field
611      !!----------------------------------------------------------------------
612      CHARACTER(len = *), INTENT(in) ::   cdfieldname    ! field name as set in namcouple file
613      !!
614      INTEGER               :: id
615      INTEGER               :: info
616      INTEGER, DIMENSION(1) :: itmp
617      INTEGER               :: ji,jm     ! local loop index
618      INTEGER               :: mop
619      !!----------------------------------------------------------------------
620      cpl_freq = 0   ! defaut definition
621      id = -1        ! defaut definition
622      !
623      DO ji = 1, nsnd
624         IF (ssnd(ji)%laction ) THEN
625            DO jm = 1, ncplmodel
626               IF( ssnd(ji)%nid(1,jm) /= -1 ) THEN
627                  IF( TRIM(cdfieldname) == TRIM(ssnd(ji)%clname) ) THEN
628                     id = ssnd(ji)%nid(1,jm)
629                     mop = OASIS_Out
630                  ENDIF
631               ENDIF
632            ENDDO
633         ENDIF
634      ENDDO
635      DO ji = 1, nrcv
636         IF (srcv(ji)%laction ) THEN
637            DO jm = 1, ncplmodel
638               IF( srcv(ji)%nid(1,jm) /= -1 ) THEN
639                  IF( TRIM(cdfieldname) == TRIM(srcv(ji)%clname) ) THEN
640                     id = srcv(ji)%nid(1,jm)
641                     mop = OASIS_In
642                  ENDIF
643               ENDIF
644            ENDDO
645         ENDIF
646      ENDDO
647      !
648      IF( id /= -1 ) THEN
649#if defined key_oa3mct_v3
650         CALL oasis_get_freqs(id, mop, 1, itmp, info)
651#else
652#if defined key_oasis3 
653         itmp(1) = namflddti( id )
654#else
655         CALL oasis_get_freqs(id,      1, itmp, info)
656#endif
657#endif
658         cpl_freq = itmp(1)
659      ENDIF
660      !
661   END FUNCTION cpl_freq
662
663
664   SUBROUTINE cpl_finalize
665      !!---------------------------------------------------------------------
666      !!              ***  ROUTINE cpl_finalize  ***
667      !!
668      !! ** Purpose : - Finalizes the coupling. If MPI_init has not been
669      !!      called explicitly before cpl_init it will also close
670      !!      MPI communication.
671      !!----------------------------------------------------------------------
672      !
673      DEALLOCATE( exfld )
674      IF (nstop == 0) THEN
675         CALL oasis_terminate( nerror )         
676      ELSE
677         CALL oasis_abort( ncomp_id, "cpl_finalize", "NEMO ABORT STOP" )
678      ENDIF       
679      !
680   END SUBROUTINE cpl_finalize
681
682#if ! defined key_oasis3
683
684   !!----------------------------------------------------------------------
685   !!   No OASIS Library          OASIS3 Dummy module...
686   !!----------------------------------------------------------------------
687
688   SUBROUTINE oasis_init_comp(k1,cd1,k2)
689      CHARACTER(*), INTENT(in   ) ::  cd1
690      INTEGER     , INTENT(  out) ::  k1,k2
691      k1 = -1 ; k2 = -1
692      WRITE(numout,*) 'oasis_init_comp: Error you sould not be there...', cd1
693   END SUBROUTINE oasis_init_comp
694
695   SUBROUTINE oasis_abort(k1,cd1,cd2)
696      INTEGER     , INTENT(in   ) ::  k1
697      CHARACTER(*), INTENT(in   ) ::  cd1,cd2
698      WRITE(numout,*) 'oasis_abort: Error you sould not be there...', cd1, cd2
699   END SUBROUTINE oasis_abort
700
701   SUBROUTINE oasis_get_localcomm(k1,k2)
702      INTEGER     , INTENT(  out) ::  k1,k2
703      k1 = -1 ; k2 = -1
704      WRITE(numout,*) 'oasis_get_localcomm: Error you sould not be there...'
705   END SUBROUTINE oasis_get_localcomm
706
707   SUBROUTINE oasis_def_partition(k1,k2,k3,K4)
708      INTEGER     , INTENT(  out) ::  k1,k3
709      INTEGER     , INTENT(in   ) ::  k2(5)
710      INTEGER     , OPTIONAL, INTENT(in   ) ::  k4
711      k1 = k2(1) ; k3 = k2(5)
712      WRITE(numout,*) 'oasis_def_partition: Error you sould not be there...'
713   END SUBROUTINE oasis_def_partition
714
715   SUBROUTINE oasis_def_var(k1,cd1,k2,k3,k4,k5,k6,k7)
716      CHARACTER(*), INTENT(in   ) ::  cd1
717      INTEGER     , INTENT(in   ) ::  k2,k3(2),k4,k5(2,2),k6
718      INTEGER     , INTENT(  out) ::  k1,k7
719      k1 = -1 ; k7 = -1
720      WRITE(numout,*) 'oasis_def_var: Error you sould not be there...', cd1
721   END SUBROUTINE oasis_def_var
722
723   SUBROUTINE oasis_enddef(k1)
724      INTEGER     , INTENT(  out) ::  k1
725      k1 = -1
726      WRITE(numout,*) 'oasis_enddef: Error you sould not be there...'
727   END SUBROUTINE oasis_enddef
728 
729   SUBROUTINE oasis_put(k1,k2,p1,k3)
730      REAL(wp), DIMENSION(:,:), INTENT(in   ) ::  p1
731      INTEGER                 , INTENT(in   ) ::  k1,k2
732      INTEGER                 , INTENT(  out) ::  k3
733      k3 = -1
734      WRITE(numout,*) 'oasis_put: Error you sould not be there...'
735   END SUBROUTINE oasis_put
736
737   SUBROUTINE oasis_get(k1,k2,p1,k3)
738      REAL(wp), DIMENSION(:,:), INTENT(  out) ::  p1
739      INTEGER                 , INTENT(in   ) ::  k1,k2
740      INTEGER                 , INTENT(  out) ::  k3
741      p1(1,1) = -1. ; k3 = -1
742      WRITE(numout,*) 'oasis_get: Error you sould not be there...'
743   END SUBROUTINE oasis_get
744
745   SUBROUTINE oasis_get_freqs(k1,k2,k3,k4)
746      INTEGER              , INTENT(in   ) ::  k1,k2
747      INTEGER, DIMENSION(1), INTENT(  out) ::  k3
748      INTEGER              , INTENT(  out) ::  k4
749      k3(1) = k1 ; k4 = k2
750      WRITE(numout,*) 'oasis_get_freqs: Error you sould not be there...'
751   END SUBROUTINE oasis_get_freqs
752
753   SUBROUTINE oasis_terminate(k1)
754      INTEGER     , INTENT(  out) ::  k1
755      k1 = -1
756      WRITE(numout,*) 'oasis_terminate: Error you sould not be there...'
757   END SUBROUTINE oasis_terminate
758   
759#endif
760
761   !!=====================================================================
762END MODULE cpl_oasis3
Note: See TracBrowser for help on using the repository browser.