New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
cpl_oasis3.F90 in branches/UKMO/dev_r5518_new_runoff_coupling/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/UKMO/dev_r5518_new_runoff_coupling/NEMOGCM/NEMO/OPA_SRC/SBC/cpl_oasis3.F90 @ 8437

Last change on this file since 8437 was 8437, checked in by dancopsey, 7 years ago

Put number of rivers into partition definition. Only output final river outflow on processor 1.

File size: 26.6 KB
Line 
1MODULE cpl_oasis3
2   !!======================================================================
3   !!                    ***  MODULE cpl_oasis  ***
4   !! Coupled O/A : coupled ocean-atmosphere case using OASIS3-MCT
5   !!=====================================================================
6   !! History :   
7   !!   9.0  !  04-06  (R. Redler, NEC Laboratories Europe, Germany) Original code
8   !!   " "  !  04-11  (R. Redler, NEC Laboratories Europe; N. Keenlyside, W. Park, IFM-GEOMAR, Germany) revision
9   !!   " "  !  04-11  (V. Gayler, MPI M&D) Grid writing
10   !!   " "  !  05-08  (R. Redler, W. Park) frld initialization, paral(2) revision
11   !!   " "  !  05-09  (R. Redler) extended to allow for communication over root only
12   !!   " "  !  06-01  (W. Park) modification of physical part
13   !!   " "  !  06-02  (R. Redler, W. Park) buffer array fix for root exchange
14   !!   3.4  !  11-11  (C. Harris) Changes to allow mutiple category fields
15   !!----------------------------------------------------------------------
16   !!----------------------------------------------------------------------
17   !!   'key_oasis3'                    coupled Ocean/Atmosphere via OASIS3-MCT
18   !!   'key_oa3mct_v3'                 to be added for OASIS3-MCT version 3
19   !!----------------------------------------------------------------------
20   !!   cpl_init     : initialization of coupled mode communication
21   !!   cpl_define   : definition of grid and fields
22   !!   cpl_snd     : snd out fields in coupled mode
23   !!   cpl_rcv     : receive fields in coupled mode
24   !!   cpl_finalize : finalize the coupled mode communication
25   !!----------------------------------------------------------------------
26#if defined key_oasis3
27   USE mod_oasis                    ! OASIS3-MCT module
28#endif
29   USE par_oce                      ! ocean parameters
30   USE dom_oce                      ! ocean space and time domain
31   USE in_out_manager               ! I/O manager
32   USE lbclnk                       ! ocean lateral boundary conditions (or mpp link)
33
34   IMPLICIT NONE
35   PRIVATE
36
37   PUBLIC   cpl_init
38   PUBLIC   cpl_define
39   PUBLIC   cpl_snd
40   PUBLIC   runoff_rcv
41   PUBLIC   cpl_rcv
42   PUBLIC   cpl_freq
43   PUBLIC   cpl_finalize
44
45   INTEGER, PUBLIC            ::   OASIS_Rcv  = 1    !: return code if received field
46   INTEGER, PUBLIC            ::   OASIS_idle = 0    !: return code if nothing done by oasis
47   INTEGER                    ::   ncomp_id          ! id returned by oasis_init_comp
48   INTEGER                    ::   nerror            ! return error code
49#if ! defined key_oasis3
50   ! OASIS Variables not used. defined only for compilation purpose
51   INTEGER                    ::   OASIS_Out         = -1
52   INTEGER                    ::   OASIS_REAL        = -1
53   INTEGER                    ::   OASIS_Ok          = -1
54   INTEGER                    ::   OASIS_In          = -1
55   INTEGER                    ::   OASIS_Sent        = -1
56   INTEGER                    ::   OASIS_SentOut     = -1
57   INTEGER                    ::   OASIS_ToRest      = -1
58   INTEGER                    ::   OASIS_ToRestOut   = -1
59   INTEGER                    ::   OASIS_Recvd       = -1
60   INTEGER                    ::   OASIS_RecvOut     = -1
61   INTEGER                    ::   OASIS_FromRest    = -1
62   INTEGER                    ::   OASIS_FromRestOut = -1
63#endif
64
65   INTEGER                    ::   nrcv         ! total number of fields received
66   INTEGER                    ::   nsnd         ! total number of fields sent
67   INTEGER                    ::   ncplmodel    ! Maximum number of models to/from which NEMO is potentialy sending/receiving data
68   INTEGER, PUBLIC, PARAMETER ::   nmaxfld=50   ! Maximum number of coupling fields
69   INTEGER, PUBLIC, PARAMETER ::   nmaxcat=5    ! Maximum number of coupling fields
70   INTEGER, PUBLIC, PARAMETER ::   nmaxcpl=5    ! Maximum number of coupling fields
71   
72   INTEGER :: runoff_id
73   
74   TYPE, PUBLIC ::   FLD_CPL               !: Type for coupling field information
75      LOGICAL               ::   laction   ! To be coupled or not
76      CHARACTER(len = 8)    ::   clname    ! Name of the coupling field   
77      CHARACTER(len = 1)    ::   clgrid    ! Grid type 
78      REAL(wp)              ::   nsgn      ! Control of the sign change
79      INTEGER, DIMENSION(nmaxcat,nmaxcpl) ::   nid   ! Id of the field (no more than 9 categories and 9 extrena models)
80      INTEGER               ::   nct       ! Number of categories in field
81      INTEGER               ::   ncplmodel ! Maximum number of models to/from which this variable may be sent/received
82   END TYPE FLD_CPL
83
84   TYPE(FLD_CPL), DIMENSION(nmaxfld), PUBLIC ::   srcv, ssnd   !: Coupling fields
85
86   REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   exfld   ! Temporary buffer for receiving
87
88   !!----------------------------------------------------------------------
89   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
90   !! $Id$
91   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
92   !!----------------------------------------------------------------------
93CONTAINS
94
95   SUBROUTINE cpl_init( cd_modname, kl_comm )
96      !!-------------------------------------------------------------------
97      !!             ***  ROUTINE cpl_init  ***
98      !!
99      !! ** Purpose :   Initialize coupled mode communication for ocean
100      !!    exchange between AGCM, OGCM and COUPLER. (OASIS3 software)
101      !!
102      !! ** Method  :   OASIS3 MPI communication
103      !!--------------------------------------------------------------------
104      CHARACTER(len = *), INTENT(in) ::   cd_modname   ! model name as set in namcouple file
105      INTEGER          , INTENT(out) ::   kl_comm      ! local communicator of the model
106      !!--------------------------------------------------------------------
107
108      ! WARNING: No write in numout in this routine
109      !============================================
110
111      !------------------------------------------------------------------
112      ! 1st Initialize the OASIS system for the application
113      !------------------------------------------------------------------
114      CALL oasis_init_comp ( ncomp_id, TRIM(cd_modname), nerror )
115      IF ( nerror /= OASIS_Ok ) &
116         CALL oasis_abort (ncomp_id, 'cpl_init', 'Failure in oasis_init_comp')
117
118      !------------------------------------------------------------------
119      ! 3rd Get an MPI communicator for OPA local communication
120      !------------------------------------------------------------------
121
122      CALL oasis_get_localcomm ( kl_comm, nerror )
123      IF ( nerror /= OASIS_Ok ) &
124         CALL oasis_abort (ncomp_id, 'cpl_init','Failure in oasis_get_localcomm' )
125      !
126   END SUBROUTINE cpl_init
127
128
129   SUBROUTINE cpl_define( krcv, ksnd, kcplmodel )
130      !!-------------------------------------------------------------------
131      !!             ***  ROUTINE cpl_define  ***
132      !!
133      !! ** Purpose :   Define grid and field information for ocean
134      !!    exchange between AGCM, OGCM and COUPLER. (OASIS3 software)
135      !!
136      !! ** Method  :   OASIS3 MPI communication
137      !!--------------------------------------------------------------------
138      INTEGER, INTENT(in) ::   krcv, ksnd     ! Number of received and sent coupling fields
139      INTEGER, INTENT(in) ::   kcplmodel      ! Maximum number of models to/from which NEMO is potentialy sending/receiving data
140      !
141      INTEGER :: id_part        ! Partition for all 2D model fields to be coupled
142      INTEGER :: id_part_r      ! Partition for river runoff
143      INTEGER :: paral(5)       ! OASIS3 box partition
144      INTEGER :: ishape(2,2)    ! shape of arrays passed to PSMILe
145      INTEGER :: ji,jc,jm       ! local loop indicees
146      CHARACTER(LEN=64) :: zclname
147      CHARACTER(LEN=2) :: cli2
148      !!--------------------------------------------------------------------
149
150      IF(lwp) WRITE(numout,*)
151      IF(lwp) WRITE(numout,*) 'cpl_define : initialization in coupled ocean/atmosphere case'
152      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~~~~'
153      IF(lwp) WRITE(numout,*)
154
155      ncplmodel = kcplmodel
156      IF( kcplmodel > nmaxcpl ) THEN
157         CALL oasis_abort ( ncomp_id, 'cpl_define', 'ncplmodel is larger than nmaxcpl, increase nmaxcpl')   ;   RETURN
158      ENDIF
159
160      nrcv = krcv
161      IF( nrcv > nmaxfld ) THEN
162         CALL oasis_abort ( ncomp_id, 'cpl_define', 'nrcv is larger than nmaxfld, increase nmaxfld')   ;   RETURN
163      ENDIF
164
165      nsnd = ksnd
166      IF( nsnd > nmaxfld ) THEN
167         CALL oasis_abort ( ncomp_id, 'cpl_define', 'nsnd is larger than nmaxfld, increase nmaxfld')   ;   RETURN
168      ENDIF
169
170      !
171      ! ... Define the shape for the area that excludes the halo
172      !     For serial configuration (key_mpp_mpi not being active)
173      !     nl* is set to the global values 1 and jp*glo.
174      !
175      ishape(:,1) = (/ 1, nlei-nldi+1 /)
176      ishape(:,2) = (/ 1, nlej-nldj+1 /)
177      !
178      ! ... Allocate memory for data exchange
179      !
180      ALLOCATE(exfld(nlei-nldi+1, nlej-nldj+1), stat = nerror)
181      IF( nerror > 0 ) THEN
182         CALL oasis_abort ( ncomp_id, 'cpl_define', 'Failure in allocating exfld')   ;   RETURN
183      ENDIF
184      !
185      ! -----------------------------------------------------------------
186      ! ... Define the partition
187      ! -----------------------------------------------------------------
188     
189      paral(1) = 2                                              ! box partitioning
190      paral(2) = jpiglo * (nldj-1+njmpp-1) + (nldi-1+nimpp-1)   ! NEMO lower left corner global offset   
191      paral(3) = nlei-nldi+1                                    ! local extent in i
192      paral(4) = nlej-nldj+1                                    ! local extent in j
193      paral(5) = jpiglo                                         ! global extent in x
194     
195      IF( ln_ctl ) THEN
196         WRITE(numout,*) ' multiexchg: paral (1:5)', paral
197         WRITE(numout,*) ' multiexchg: jpi, jpj =', jpi, jpj
198         WRITE(numout,*) ' multiexchg: nldi, nlei, nimpp =', nldi, nlei, nimpp
199         WRITE(numout,*) ' multiexchg: nldj, nlej, njmpp =', nldj, nlej, njmpp
200      ENDIF
201     
202      CALL oasis_def_partition ( id_part, paral, nerror )
203      !
204      ! Another partition is needed for river runoff
205     
206      paral(1) = 0                                              ! serial partitioning
207      paral(2) = 0   
208      paral(3) = 10                                             ! size of array to couple
209      paral(4) = 0
210      paral(5) = 0
211     
212      CALL oasis_def_partition ( id_part_r, paral, nerror, 10 )
213     
214      ! ... Announce send variables.
215      !
216      ssnd(:)%ncplmodel = kcplmodel
217      !
218      DO ji = 1, ksnd
219         IF ( ssnd(ji)%laction ) THEN
220
221            IF( ssnd(ji)%nct > nmaxcat ) THEN
222               CALL oasis_abort ( ncomp_id, 'cpl_define', 'Number of categories of '//   &
223                  &              TRIM(ssnd(ji)%clname)//' is larger than nmaxcat, increase nmaxcat' )
224               RETURN
225            ENDIF
226           
227            DO jc = 1, ssnd(ji)%nct
228               DO jm = 1, kcplmodel
229
230                  IF ( ssnd(ji)%nct .GT. 1 ) THEN
231                     WRITE(cli2,'(i2.2)') jc
232                     zclname = TRIM(ssnd(ji)%clname)//'_cat'//cli2
233                  ELSE
234                     zclname = ssnd(ji)%clname
235                  ENDIF
236                  IF ( kcplmodel  > 1 ) THEN
237                     WRITE(cli2,'(i2.2)') jm
238                     zclname = 'model'//cli2//'_'//TRIM(zclname)
239                  ENDIF
240#if defined key_agrif
241                  IF( agrif_fixed() /= 0 ) THEN
242                     zclname=TRIM(Agrif_CFixed())//'_'//TRIM(zclname)
243                  END IF
244#endif
245                  IF( ln_ctl ) WRITE(numout,*) "Define", ji, jc, jm, " "//TRIM(zclname), " for ", OASIS_Out
246                  CALL oasis_def_var (ssnd(ji)%nid(jc,jm), zclname, id_part   , (/ 2, 0 /),   &
247                     &                OASIS_Out          , ishape , OASIS_REAL, nerror )
248                  IF ( nerror /= OASIS_Ok ) THEN
249                     WRITE(numout,*) 'Failed to define transient ', ji, jc, jm, " "//TRIM(zclname)
250                     CALL oasis_abort ( ssnd(ji)%nid(jc,jm), 'cpl_define', 'Failure in oasis_def_var' )
251                  ENDIF
252                  IF( ln_ctl .AND. ssnd(ji)%nid(jc,jm) /= -1 ) WRITE(numout,*) "variable defined in the namcouple"
253                  IF( ln_ctl .AND. ssnd(ji)%nid(jc,jm) == -1 ) WRITE(numout,*) "variable NOT defined in the namcouple"
254               END DO
255            END DO
256         ENDIF
257      END DO
258      !
259      ! ... Announce received variables.
260      !
261      srcv(:)%ncplmodel = kcplmodel
262      !
263      DO ji = 1, krcv
264         IF ( srcv(ji)%laction ) THEN
265           
266            IF( srcv(ji)%nct > nmaxcat ) THEN
267               CALL oasis_abort ( ncomp_id, 'cpl_define', 'Number of categories of '//   &
268                  &              TRIM(srcv(ji)%clname)//' is larger than nmaxcat, increase nmaxcat' )
269               RETURN
270            ENDIF
271           
272            DO jc = 1, srcv(ji)%nct
273               DO jm = 1, kcplmodel
274                 
275                  IF ( srcv(ji)%nct .GT. 1 ) THEN
276                     WRITE(cli2,'(i2.2)') jc
277                     zclname = TRIM(srcv(ji)%clname)//'_cat'//cli2
278                  ELSE
279                     zclname = srcv(ji)%clname
280                  ENDIF
281                  IF ( kcplmodel  > 1 ) THEN
282                     WRITE(cli2,'(i2.2)') jm
283                     zclname = 'model'//cli2//'_'//TRIM(zclname)
284                  ENDIF
285#if defined key_agrif
286                  IF( agrif_fixed() /= 0 ) THEN
287                     zclname=TRIM(Agrif_CFixed())//'_'//TRIM(zclname)
288                  END IF
289#endif
290                  IF( ln_ctl ) WRITE(numout,*) "Define", ji, jc, jm, " "//TRIM(zclname), " for ", OASIS_In
291                  CALL oasis_def_var (srcv(ji)%nid(jc,jm), zclname, id_part   , (/ 2, 0 /),   &
292                     &                OASIS_In           , ishape , OASIS_REAL, nerror )
293                  IF ( nerror /= OASIS_Ok ) THEN
294                     WRITE(numout,*) 'Failed to define transient ', ji, jc, jm, " "//TRIM(zclname)
295                     CALL oasis_abort ( srcv(ji)%nid(jc,jm), 'cpl_define', 'Failure in oasis_def_var' )
296                  ENDIF
297                  IF( ln_ctl .AND. srcv(ji)%nid(jc,jm) /= -1 ) WRITE(numout,*) "variable defined in the namcouple"
298                  IF( ln_ctl .AND. srcv(ji)%nid(jc,jm) == -1 ) WRITE(numout,*) "variable NOT defined in the namcouple"
299
300               END DO
301            END DO
302         ENDIF
303      END DO
304     
305      ! Define river runoff
306      CALL oasis_def_var (runoff_id, 'runoffo', id_part_r   , (/ 1, 0 /),   &
307                     &                OASIS_In           , (/ 1, 10 /) , OASIS_REAL, nerror )
308      IF ( nerror /= OASIS_Ok ) THEN
309          WRITE(numout,*) 'Failed to define transient runoffo'
310          CALL oasis_abort ( runoff_id, 'cpl_define', 'Failure in oasis_def_var' )
311      ENDIF
312     
313      !------------------------------------------------------------------
314      ! End of definition phase
315      !------------------------------------------------------------------
316     
317      CALL oasis_enddef(nerror)
318      IF( nerror /= OASIS_Ok )   CALL oasis_abort ( ncomp_id, 'cpl_define', 'Failure in oasis_enddef')
319      !
320   END SUBROUTINE cpl_define
321   
322   
323   SUBROUTINE cpl_snd( kid, kstep, pdata, kinfo )
324      !!---------------------------------------------------------------------
325      !!              ***  ROUTINE cpl_snd  ***
326      !!
327      !! ** Purpose : - At each coupling time-step,this routine sends fields
328      !!      like sst or ice cover to the coupler or remote application.
329      !!----------------------------------------------------------------------
330      INTEGER                   , INTENT(in   ) ::   kid       ! variable index in the array
331      INTEGER                   , INTENT(  out) ::   kinfo     ! OASIS3 info argument
332      INTEGER                   , INTENT(in   ) ::   kstep     ! ocean time-step in seconds
333      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   pdata
334      !!
335      INTEGER                                   ::   jc,jm     ! local loop index
336      !!--------------------------------------------------------------------
337      !
338      ! snd data to OASIS3
339      !
340      DO jc = 1, ssnd(kid)%nct
341         DO jm = 1, ssnd(kid)%ncplmodel
342       
343            IF( ssnd(kid)%nid(jc,jm) /= -1 ) THEN
344               CALL oasis_put ( ssnd(kid)%nid(jc,jm), kstep, pdata(nldi:nlei, nldj:nlej,jc), kinfo )
345               
346               IF ( ln_ctl ) THEN       
347                  IF ( kinfo == OASIS_Sent     .OR. kinfo == OASIS_ToRest .OR.   &
348                     & kinfo == OASIS_SentOut  .OR. kinfo == OASIS_ToRestOut ) THEN
349                     WRITE(numout,*) '****************'
350                     WRITE(numout,*) 'oasis_put: Outgoing ', ssnd(kid)%clname
351                     WRITE(numout,*) 'oasis_put: ivarid ', ssnd(kid)%nid(jc,jm)
352                     WRITE(numout,*) 'oasis_put:  kstep ', kstep
353                     WRITE(numout,*) 'oasis_put:   info ', kinfo
354                     WRITE(numout,*) '     - Minimum value is ', MINVAL(pdata(:,:,jc))
355                     WRITE(numout,*) '     - Maximum value is ', MAXVAL(pdata(:,:,jc))
356                     WRITE(numout,*) '     -     Sum value is ', SUM(pdata(:,:,jc))
357                     WRITE(numout,*) '****************'
358                  ENDIF
359               ENDIF
360               
361            ENDIF
362           
363         ENDDO
364      ENDDO
365      !
366    END SUBROUTINE cpl_snd
367
368
369   SUBROUTINE cpl_rcv( kid, kstep, pdata, pmask, kinfo )
370      !!---------------------------------------------------------------------
371      !!              ***  ROUTINE cpl_rcv  ***
372      !!
373      !! ** Purpose : - At each coupling time-step,this routine receives fields
374      !!      like stresses and fluxes from the coupler or remote application.
375      !!----------------------------------------------------------------------
376      INTEGER                   , INTENT(in   ) ::   kid       ! variable index in the array
377      INTEGER                   , INTENT(in   ) ::   kstep     ! ocean time-step in seconds
378      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pdata     ! IN to keep the value if nothing is done
379      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   pmask     ! coupling mask
380      INTEGER                   , INTENT(  out) ::   kinfo     ! OASIS3 info argument
381      !!
382      INTEGER                                   ::   jc,jm     ! local loop index
383      LOGICAL                                   ::   llaction, llfisrt
384      !!--------------------------------------------------------------------
385      !
386      ! receive local data from OASIS3 on every process
387      !
388      kinfo = OASIS_idle
389      !
390      DO jc = 1, srcv(kid)%nct
391         llfisrt = .TRUE.
392
393         DO jm = 1, srcv(kid)%ncplmodel
394
395            IF( srcv(kid)%nid(jc,jm) /= -1 ) THEN
396
397               CALL oasis_get ( srcv(kid)%nid(jc,jm), kstep, exfld, kinfo )         
398               
399               llaction =  kinfo == OASIS_Recvd   .OR. kinfo == OASIS_FromRest .OR.   &
400                  &        kinfo == OASIS_RecvOut .OR. kinfo == OASIS_FromRestOut
401               
402               IF ( ln_ctl )   WRITE(numout,*) "llaction, kinfo, kstep, ivarid: " , llaction, kinfo, kstep, srcv(kid)%nid(jc,jm)
403               
404               IF ( llaction ) THEN
405                 
406                  kinfo = OASIS_Rcv
407                  IF( llfisrt ) THEN
408                     pdata(nldi:nlei,nldj:nlej,jc) =                                 exfld(:,:) * pmask(nldi:nlei,nldj:nlej,jm)
409                     llfisrt = .FALSE.
410                  ELSE
411                     pdata(nldi:nlei,nldj:nlej,jc) = pdata(nldi:nlei,nldj:nlej,jc) + exfld(:,:) * pmask(nldi:nlei,nldj:nlej,jm)
412                  ENDIF
413                 
414                  IF ( ln_ctl ) THEN       
415                     WRITE(numout,*) '****************'
416                     WRITE(numout,*) 'oasis_get: Incoming ', srcv(kid)%clname
417                     WRITE(numout,*) 'oasis_get: ivarid '  , srcv(kid)%nid(jc,jm)
418                     WRITE(numout,*) 'oasis_get:   kstep', kstep
419                     WRITE(numout,*) 'oasis_get:   info ', kinfo
420                     WRITE(numout,*) '     - Minimum value is ', MINVAL(pdata(:,:,jc))
421                     WRITE(numout,*) '     - Maximum value is ', MAXVAL(pdata(:,:,jc))
422                     WRITE(numout,*) '     -     Sum value is ', SUM(pdata(:,:,jc))
423                     WRITE(numout,*) '****************'
424                  ENDIF
425                 
426               ENDIF
427               
428            ENDIF
429           
430         ENDDO
431
432         !--- Fill the overlap areas and extra hallows (mpp)
433         !--- check periodicity conditions (all cases)
434         IF( .not. llfisrt )   CALL lbc_lnk( pdata(:,:,jc), srcv(kid)%clgrid, srcv(kid)%nsgn )   
435 
436      ENDDO
437      !
438   END SUBROUTINE cpl_rcv
439   
440   SUBROUTINE runoff_rcv( kstep)
441     
442      INTEGER                   , INTENT(in   ) ::   kstep     ! ocean time-step in seconds
443     
444      INTEGER  ::   kinfo                  ! OASIS3 info argument   
445      REAL(wp) ::   runoff(10)             ! River runoff. One value per river.
446   
447      ! Get the river runoff sent by the atmosphere
448      CALL oasis_get ( runoff_id, kstep, runoff, kinfo )
449      IF ( narea == 1 ) THEN
450         WRITE(numout,*)' kstep = ', kstep
451         WRITE(numout,*)' River runoff = ', runoff
452         WRITE(numout,*)' kinfo = ', kinfo
453         WRITE(numout,*)'-------'
454      ENDIF
455   
456   
457   END SUBROUTINE runoff_rcv
458
459
460   INTEGER FUNCTION cpl_freq( cdfieldname ) 
461      !!---------------------------------------------------------------------
462      !!              ***  ROUTINE cpl_freq  ***
463      !!
464      !! ** Purpose : - send back the coupling frequency for a particular field
465      !!----------------------------------------------------------------------
466      CHARACTER(len = *), INTENT(in) ::   cdfieldname    ! field name as set in namcouple file
467      !!
468      INTEGER               :: id
469      INTEGER               :: info
470      INTEGER, DIMENSION(1) :: itmp
471      INTEGER               :: ji,jm     ! local loop index
472      INTEGER               :: mop
473      !!----------------------------------------------------------------------
474      cpl_freq = 0   ! defaut definition
475      id = -1        ! defaut definition
476      !
477      DO ji = 1, nsnd
478         IF (ssnd(ji)%laction ) THEN
479            DO jm = 1, ncplmodel
480               IF( ssnd(ji)%nid(1,jm) /= -1 ) THEN
481                  IF( TRIM(cdfieldname) == TRIM(ssnd(ji)%clname) ) THEN
482                     id = ssnd(ji)%nid(1,jm)
483                     mop = OASIS_Out
484                  ENDIF
485               ENDIF
486            ENDDO
487         ENDIF
488      ENDDO
489      DO ji = 1, nrcv
490         IF (srcv(ji)%laction ) THEN
491            DO jm = 1, ncplmodel
492               IF( srcv(ji)%nid(1,jm) /= -1 ) THEN
493                  IF( TRIM(cdfieldname) == TRIM(srcv(ji)%clname) ) THEN
494                     id = srcv(ji)%nid(1,jm)
495                     mop = OASIS_In
496                  ENDIF
497               ENDIF
498            ENDDO
499         ENDIF
500      ENDDO
501      !
502      IF( id /= -1 ) THEN
503#if defined key_oa3mct_v3
504         CALL oasis_get_freqs(id, mop, 1, itmp, info)
505#else
506         CALL oasis_get_freqs(id,      1, itmp, info)
507#endif
508         cpl_freq = itmp(1)
509      ENDIF
510      !
511   END FUNCTION cpl_freq
512
513
514   SUBROUTINE cpl_finalize
515      !!---------------------------------------------------------------------
516      !!              ***  ROUTINE cpl_finalize  ***
517      !!
518      !! ** Purpose : - Finalizes the coupling. If MPI_init has not been
519      !!      called explicitly before cpl_init it will also close
520      !!      MPI communication.
521      !!----------------------------------------------------------------------
522      !
523      DEALLOCATE( exfld )
524      IF (nstop == 0) THEN
525         CALL oasis_terminate( nerror )         
526      ELSE
527         CALL oasis_abort( ncomp_id, "cpl_finalize", "NEMO ABORT STOP" )
528      ENDIF       
529      !
530   END SUBROUTINE cpl_finalize
531
532#if ! defined key_oasis3
533
534   !!----------------------------------------------------------------------
535   !!   No OASIS Library          OASIS3 Dummy module...
536   !!----------------------------------------------------------------------
537
538   SUBROUTINE oasis_init_comp(k1,cd1,k2)
539      CHARACTER(*), INTENT(in   ) ::  cd1
540      INTEGER     , INTENT(  out) ::  k1,k2
541      k1 = -1 ; k2 = -1
542      WRITE(numout,*) 'oasis_init_comp: Error you sould not be there...', cd1
543   END SUBROUTINE oasis_init_comp
544
545   SUBROUTINE oasis_abort(k1,cd1,cd2)
546      INTEGER     , INTENT(in   ) ::  k1
547      CHARACTER(*), INTENT(in   ) ::  cd1,cd2
548      WRITE(numout,*) 'oasis_abort: Error you sould not be there...', cd1, cd2
549   END SUBROUTINE oasis_abort
550
551   SUBROUTINE oasis_get_localcomm(k1,k2)
552      INTEGER     , INTENT(  out) ::  k1,k2
553      k1 = -1 ; k2 = -1
554      WRITE(numout,*) 'oasis_get_localcomm: Error you sould not be there...'
555   END SUBROUTINE oasis_get_localcomm
556
557   SUBROUTINE oasis_def_partition(k1,k2,k3)
558      INTEGER     , INTENT(  out) ::  k1,k3
559      INTEGER     , INTENT(in   ) ::  k2(5)
560      k1 = k2(1) ; k3 = k2(5)
561      WRITE(numout,*) 'oasis_def_partition: Error you sould not be there...'
562   END SUBROUTINE oasis_def_partition
563
564   SUBROUTINE oasis_def_var(k1,cd1,k2,k3,k4,k5,k6,k7)
565      CHARACTER(*), INTENT(in   ) ::  cd1
566      INTEGER     , INTENT(in   ) ::  k2,k3(2),k4,k5(2,2),k6
567      INTEGER     , INTENT(  out) ::  k1,k7
568      k1 = -1 ; k7 = -1
569      WRITE(numout,*) 'oasis_def_var: Error you sould not be there...', cd1
570   END SUBROUTINE oasis_def_var
571
572   SUBROUTINE oasis_enddef(k1)
573      INTEGER     , INTENT(  out) ::  k1
574      k1 = -1
575      WRITE(numout,*) 'oasis_enddef: Error you sould not be there...'
576   END SUBROUTINE oasis_enddef
577 
578   SUBROUTINE oasis_put(k1,k2,p1,k3)
579      REAL(wp), DIMENSION(:,:), INTENT(in   ) ::  p1
580      INTEGER                 , INTENT(in   ) ::  k1,k2
581      INTEGER                 , INTENT(  out) ::  k3
582      k3 = -1
583      WRITE(numout,*) 'oasis_put: Error you sould not be there...'
584   END SUBROUTINE oasis_put
585
586   SUBROUTINE oasis_get(k1,k2,p1,k3)
587      REAL(wp), DIMENSION(:,:), INTENT(  out) ::  p1
588      INTEGER                 , INTENT(in   ) ::  k1,k2
589      INTEGER                 , INTENT(  out) ::  k3
590      p1(1,1) = -1. ; k3 = -1
591      WRITE(numout,*) 'oasis_get: Error you sould not be there...'
592   END SUBROUTINE oasis_get
593
594   SUBROUTINE oasis_get_freqs(k1,k2,k3,k4)
595      INTEGER              , INTENT(in   ) ::  k1,k2
596      INTEGER, DIMENSION(1), INTENT(  out) ::  k3
597      INTEGER              , INTENT(  out) ::  k4
598      k3(1) = k1 ; k4 = k2
599      WRITE(numout,*) 'oasis_get_freqs: Error you sould not be there...'
600   END SUBROUTINE oasis_get_freqs
601
602   SUBROUTINE oasis_terminate(k1)
603      INTEGER     , INTENT(  out) ::  k1
604      k1 = -1
605      WRITE(numout,*) 'oasis_terminate: Error you sould not be there...'
606   END SUBROUTINE oasis_terminate
607   
608#endif
609
610   !!=====================================================================
611END MODULE cpl_oasis3
Note: See TracBrowser for help on using the repository browser.