New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
daymod.F90 in branches/UKMO/dev_r5518_obs_oper_strthr/NEMOGCM/NEMO/OPA_SRC/DOM – NEMO

source: branches/UKMO/dev_r5518_obs_oper_strthr/NEMOGCM/NEMO/OPA_SRC/DOM/daymod.F90 @ 15258

Last change on this file since 15258 was 15258, checked in by jroberts, 17 months ago

Remove nn_timing=2 as cause merge conflict

File size: 20.3 KB
Line 
1MODULE daymod
2   !!======================================================================
3   !!                       ***  MODULE  daymod  ***
4   !! Ocean        :  calendar
5   !!=====================================================================
6   !! History :  OPA  ! 1994-09  (M. Pontaud M. Imbard)  Original code
7   !!                 ! 1997-03  (O. Marti)
8   !!                 ! 1997-05  (G. Madec)
9   !!                 ! 1997-08  (M. Imbard)
10   !!   NEMO     1.0  ! 2003-09  (G. Madec)  F90 + nyear, nmonth, nday
11   !!                 ! 2004-01  (A.M. Treguier) new calculation based on adatrj
12   !!                 ! 2006-08  (G. Madec)  surface module major update
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   day        : calendar
17   !!
18   !!           -------------------------------
19   !!           ----------- WARNING -----------
20   !!
21   !!   we suppose that the time step is deviding the number of second of in a day
22   !!             ---> MOD( rday, rdttra(1) ) == 0
23   !!
24   !!           ----------- WARNING -----------
25   !!           -------------------------------
26   !!
27   !!----------------------------------------------------------------------
28   USE dom_oce         ! ocean space and time domain
29   USE phycst          ! physical constants
30   USE in_out_manager  ! I/O manager
31   USE iom             !
32   USE ioipsl, ONLY :   ymds2ju   ! for calendar
33   USE prtctl          ! Print control
34   USE trc_oce, ONLY : lk_offline ! offline flag
35   USE timing          ! Timing
36   USE restart         ! restart
37
38   IMPLICIT NONE
39   PRIVATE
40
41   PUBLIC   day        ! called by step.F90
42   PUBLIC   day_init   ! called by istate.F90
43   PUBLIC   day_mth    ! Needed by TAM
44
45   INTEGER, PUBLIC ::   nsecd, nsecd05, ndt, ndt05 ! (PUBLIC for TAM)
46
47   !!----------------------------------------------------------------------
48   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
49   !! $Id$
50   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
51   !!----------------------------------------------------------------------
52CONTAINS
53
54   SUBROUTINE day_init
55      !!----------------------------------------------------------------------
56      !!                   ***  ROUTINE day_init  ***
57      !!
58      !! ** Purpose :   Initialization of the calendar values to their values 1 time step before nit000
59      !!                because day will be called at the beginning of step
60      !!
61      !! ** Action  : - nyear        : current year
62      !!              - nmonth       : current month of the year nyear
63      !!              - nday         : current day of the month nmonth
64      !!              - nday_year    : current day of the year nyear
65      !!              - nsec_year    : current time step counted in second since 00h jan 1st of the current year
66      !!              - nsec_month   : current time step counted in second since 00h 1st day of the current month
67      !!              - nsec_day     : current time step counted in second since 00h of the current day
68      !!              - nsec1jan000  : second since Jan. 1st 00h of nit000 year and Jan. 1st 00h of the current year
69      !!              - nmonth_len, nyear_len, nmonth_half, nmonth_end through day_mth
70      !!----------------------------------------------------------------------
71      INTEGER  ::   inbday, idweek
72      REAL(wp) ::   zjul
73      !!----------------------------------------------------------------------
74      !
75      ! max number of seconds between each restart
76      IF( REAL( nitend - nit000 + 1 ) * rdt > REAL( HUGE( nsec1jan000 ) ) ) THEN
77         CALL ctl_stop( 'The number of seconds between each restart exceeds the integer 4 max value: 2^31-1. ',   &
78            &           'You must do a restart at higher frequency (or remove this stop and recompile the code in I8)' )
79      ENDIF
80      ! all calendar staff is based on the fact that MOD( rday, rdttra(1) ) == 0
81      IF( MOD( rday     , rdttra(1) ) /= 0. )   CALL ctl_stop( 'the time step must devide the number of second of in a day' )
82      IF( MOD( rday     , 2.        ) /= 0. )   CALL ctl_stop( 'the number of second of in a day must be an even number'    )
83      IF( MOD( rdttra(1), 2.        ) /= 0. )   CALL ctl_stop( 'the time step (in second) must be an even number'           )
84      nsecd   = NINT(rday           )
85      nsecd05 = NINT(0.5 * rday     )
86      ndt     = NINT(      rdttra(1))
87      ndt05   = NINT(0.5 * rdttra(1))
88
89      IF( .NOT. lk_offline ) CALL day_rst( nit000, 'READ' )
90
91      ! set the calandar from ndastp (read in restart file and namelist)
92
93      nyear   =   ndastp / 10000
94      nmonth  = ( ndastp - (nyear * 10000) ) / 100
95      nday    =   ndastp - (nyear * 10000) - ( nmonth * 100 )
96
97      nhour   =   nn_time0 / 100
98      nminute = ( nn_time0 - nhour * 100 )
99
100      CALL ymds2ju( nyear, nmonth, nday, nhour*3600._wp+nminute*60._wp, fjulday ) 
101      IF( ABS(fjulday - REAL(NINT(fjulday),wp)) < 0.1 / rday )   fjulday = REAL(NINT(fjulday),wp)   ! avoid truncation error
102      IF(nhour*3600 + nminute*60 - ndt05 .lt. 0)   fjulday = fjulday + 1.                    ! move back to the day at nit000 (and not at nit000 - 1)
103
104      nsec1jan000 = 0
105      CALL day_mth
106
107      IF ( nday == 0 ) THEN     !   for ex if ndastp = ndate0 - 1
108         nmonth = nmonth - 1
109         nday = nmonth_len(nmonth)
110      ENDIF
111      IF ( nmonth == 0 ) THEN   ! go at the end of previous year
112         nmonth = 12
113         nyear = nyear - 1
114         nsec1jan000 = nsec1jan000 - nsecd * nyear_len(0)
115         IF( nleapy == 1 )   CALL day_mth
116      ENDIF
117
118      ! day since january 1st
119      nday_year = nday + SUM( nmonth_len(1:nmonth - 1) )
120
121      !compute number of days between last monday and today
122      CALL ymds2ju( 1900, 01, 01, 0.0, zjul )  ! compute julian day value of 01.01.1900 (our reference that was a Monday)
123      inbday = FLOOR(fjulday - zjul)            ! compute nb day between  01.01.1900 and start of current day
124      idweek = MOD(inbday, 7)                  ! compute nb day between last monday and current day
125      IF (idweek .lt. 0) idweek=idweek+7       ! Avoid negative values for dates before 01.01.1900
126
127      ! number of seconds since the beginning of current year/month/week/day at the middle of the time-step
128      IF (nhour*3600+nminute*60-ndt05 .gt. 0) THEN
129         ! 1 timestep before current middle of first time step is still the same day
130         nsec_year  = (nday_year-1) * nsecd + nhour*3600+nminute*60 - ndt05 
131         nsec_month = (nday-1)      * nsecd + nhour*3600+nminute*60 - ndt05   
132      ELSE
133         ! 1 time step before the middle of the first time step is the previous day
134         nsec_year  = nday_year * nsecd + nhour*3600+nminute*60 - ndt05 
135         nsec_month = nday      * nsecd + nhour*3600+nminute*60 - ndt05   
136      ENDIF
137      nsec_week  = idweek    * nsecd + nhour*3600+nminute*60 - ndt05
138      nsec_day   =             nhour*3600+nminute*60 - ndt05 
139      IF( nsec_day .lt. 0 ) nsec_day = nsec_day + nsecd
140      IF( nsec_week .lt. 0 ) nsec_week = nsec_week + nsecd*7
141
142      ! control print
143      IF(lwp) WRITE(numout,'(a,i6,a,i2,a,i2,a,i8,a,i8,a,i8,a,i8)')' =======>> 1/2 time step before the start of the run DATE Y/M/D = ',   &
144           &                   nyear, '/', nmonth, '/', nday, '  nsec_day:', nsec_day, '  nsec_week:', nsec_week, '  &
145           &                   nsec_month:', nsec_month , '  nsec_year:' , nsec_year
146
147      ! Up to now, calendar parameters are related to the end of previous run (nit000-1)
148      ! call day to set the calendar parameters at the begining of the current simulaton. needed by iom_init
149      CALL day( nit000 )
150      !
151   END SUBROUTINE day_init
152
153
154   SUBROUTINE day_mth
155      !!----------------------------------------------------------------------
156      !!                   ***  ROUTINE day_init  ***
157      !!
158      !! ** Purpose :   calendar values related to the months
159      !!
160      !! ** Action  : - nmonth_len    : length in days of the months of the current year
161      !!              - nyear_len     : length in days of the previous/current year
162      !!              - nmonth_half   : second since the beginning of the year and the halft of the months
163      !!              - nmonth_end    : second since the beginning of the year and the end of the months
164      !!----------------------------------------------------------------------
165      INTEGER  ::   jm               ! dummy loop indice
166      !!----------------------------------------------------------------------
167
168      ! length of the month of the current year (from nleapy, read in namelist)
169      IF ( nleapy < 2 ) THEN
170         nmonth_len(:) = (/ 31, 31, 28, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31, 31 /)
171         nyear_len(:) = 365
172         IF ( nleapy == 1 ) THEN   ! we are using calandar with leap years
173            IF ( MOD(nyear-1, 4) == 0 .AND. ( MOD(nyear-1, 400) == 0 .OR. MOD(nyear-1, 100) /= 0 ) ) THEN
174               nyear_len(0)  = 366
175            ENDIF
176            IF ( MOD(nyear  , 4) == 0 .AND. ( MOD(nyear  , 400) == 0 .OR. MOD(nyear  , 100) /= 0 ) ) THEN
177               nmonth_len(2) = 29
178               nyear_len(1)  = 366
179            ENDIF
180            IF ( MOD(nyear+1, 4) == 0 .AND. ( MOD(nyear+1, 400) == 0 .OR. MOD(nyear+1, 100) /= 0 ) ) THEN
181               nyear_len(2)  = 366
182            ENDIF
183         ENDIF
184      ELSE
185         nmonth_len(:) = nleapy   ! all months with nleapy days per year
186         nyear_len(:) = 12 * nleapy
187      ENDIF
188
189      ! half month in second since the begining of the year:
190      ! time since Jan 1st   0     1     2    ...    11    12    13
191      !          ---------*--|--*--|--*--| ... |--*--|--*--|--*--|--------------------------------------
192      !                 <---> <---> <--->  ...  <---> <---> <--->
193      ! month number      0     1     2    ...    11    12    13
194      !
195      ! nmonth_half(jm) = rday * REAL( 0.5 * nmonth_len(jm) + SUM(nmonth_len(1:jm-1)) )
196      nmonth_half(0) = - nsecd05 * nmonth_len(0)
197      DO jm = 1, 13
198         nmonth_half(jm) = nmonth_half(jm-1) + nsecd05 * ( nmonth_len(jm-1) + nmonth_len(jm) )
199      END DO
200
201      nmonth_end(0) = 0
202      DO jm = 1, 13
203         nmonth_end(jm) = nmonth_end(jm-1) + nsecd * nmonth_len(jm)
204      END DO
205      !
206   END SUBROUTINE
207
208
209   SUBROUTINE day( kt )
210      !!----------------------------------------------------------------------
211      !!                      ***  ROUTINE day  ***
212      !!
213      !! ** Purpose :   Compute the date with a day iteration IF necessary.
214      !!
215      !! ** Method  : - ???
216      !!
217      !! ** Action  : - nyear     : current year
218      !!              - nmonth    : current month of the year nyear
219      !!              - nday      : current day of the month nmonth
220      !!              - nday_year : current day of the year nyear
221      !!              - ndastp    : = nyear*10000 + nmonth*100 + nday
222      !!              - adatrj    : date in days since the beginning of the run
223      !!              - nsec_year : current time of the year (in second since 00h, jan 1st)
224      !!----------------------------------------------------------------------
225      INTEGER, INTENT(in) ::   kt        ! ocean time-step indices
226      !
227      CHARACTER (len=25) ::   charout
228      REAL(wp)           ::   zprec      ! fraction of day corresponding to 0.1 second
229      !!----------------------------------------------------------------------
230      !
231      IF( nn_timing == 1 )  CALL timing_start('day')
232      !
233      zprec = 0.1 / rday
234      !                                                 ! New time-step
235      nsec_year  = nsec_year  + ndt
236      nsec_month = nsec_month + ndt
237      nsec_week  = nsec_week  + ndt
238      nsec_day   = nsec_day   + ndt
239      adatrj  = adatrj  + rdttra(1) / rday
240      fjulday = fjulday + rdttra(1) / rday
241      IF( ABS(fjulday - REAL(NINT(fjulday),wp)) < zprec )   fjulday = REAL(NINT(fjulday),wp)   ! avoid truncation error
242      IF( ABS(adatrj  - REAL(NINT(adatrj ),wp)) < zprec )   adatrj  = REAL(NINT(adatrj ),wp)   ! avoid truncation error
243
244      IF( nsec_day > nsecd ) THEN                       ! New day
245         !
246         nday      = nday + 1
247         nday_year = nday_year + 1
248         nsec_day  = ndt05
249         !
250         IF( nday == nmonth_len(nmonth) + 1 ) THEN      ! New month
251            nday   = 1
252            nmonth = nmonth + 1
253            nsec_month = ndt05
254            IF( nmonth == 13 ) THEN                     ! New year
255               nyear     = nyear + 1
256               nmonth    = 1
257               nday_year = 1
258               nsec_year = ndt05
259               nsec1jan000 = nsec1jan000 + nsecd * nyear_len(1)
260               IF( nleapy == 1 )   CALL day_mth
261            ENDIF
262         ENDIF
263         !
264         ndastp = nyear * 10000 + nmonth * 100 + nday   ! New date
265         !
266         !compute first day of the year in julian days
267         CALL ymds2ju( nyear, 01, 01, 0.0, fjulstartyear )
268         !
269         IF(lwp) WRITE(numout,'(a,i8,a,i4.4,a,i2.2,a,i2.2,a,i3.3)') '======>> time-step =', kt,   &
270              &   '      New day, DATE Y/M/D = ', nyear, '/', nmonth, '/', nday, '      nday_year = ', nday_year
271         IF(lwp) WRITE(numout,'(a,i8,a,i7,a,i5)') '         nsec_year = ', nsec_year,   &
272              &   '   nsec_month = ', nsec_month, '   nsec_day = ', nsec_day, '   nsec_week = ', nsec_week
273      ENDIF
274
275      IF( nsec_week > 7*nsecd )   nsec_week = ndt05     ! New week
276
277      IF(ln_ctl) THEN
278         WRITE(charout,FMT="('kt =', I4,'  d/m/y =',I2,I2,I4)") kt, nday, nmonth, nyear
279         CALL prt_ctl_info(charout)
280      ENDIF
281
282      IF( .NOT. lk_offline ) CALL rst_opn( kt )               ! Open the restart file if needed and control lrst_oce
283      IF( lrst_oce         ) CALL day_rst( kt, 'WRITE' )      ! write day restart information
284      !
285      IF( nn_timing == 1 )  CALL timing_stop('day')
286      !
287   END SUBROUTINE day
288
289
290   SUBROUTINE day_rst( kt, cdrw )
291      !!---------------------------------------------------------------------
292      !!                   ***  ROUTINE ts_rst  ***
293      !!
294      !!  ** Purpose : Read or write calendar in restart file:
295      !!
296      !!  WRITE(READ) mode:
297      !!       kt        : number of time step since the begining of the experiment at the
298      !!                   end of the current(previous) run
299      !!       adatrj(0) : number of elapsed days since the begining of the experiment at the
300      !!                   end of the current(previous) run (REAL -> keep fractions of day)
301      !!       ndastp    : date at the end of the current(previous) run (coded as yyyymmdd integer)
302      !!
303      !!   According to namelist parameter nrstdt,
304      !!       nrstdt = 0  no control on the date (nit000 is  arbitrary).
305      !!       nrstdt = 1  we verify that nit000 is equal to the last
306      !!                   time step of previous run + 1.
307      !!       In both those options, the  exact duration of the experiment
308      !!       since the beginning (cumulated duration of all previous restart runs)
309      !!       is not stored in the restart and is assumed to be (nit000-1)*rdt.
310      !!       This is valid is the time step has remained constant.
311      !!
312      !!       nrstdt = 2  the duration of the experiment in days (adatrj)
313      !!                    has been stored in the restart file.
314      !!----------------------------------------------------------------------
315      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
316      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
317      !
318      REAL(wp) ::   zkt, zndastp, zdayfrac, ksecs, ktime
319      INTEGER  ::   ihour, iminute
320      !!----------------------------------------------------------------------
321
322      IF( TRIM(cdrw) == 'READ' ) THEN
323
324         IF( iom_varid( numror, 'kt', ldstop = .FALSE. ) > 0 ) THEN
325            ! Get Calendar informations
326            CALL iom_get( numror, 'kt', zkt )   ! last time-step of previous run
327            IF(lwp) THEN
328               WRITE(numout,*) ' *** Info read in restart : '
329               WRITE(numout,*) '   previous time-step                               : ', NINT( zkt )
330               WRITE(numout,*) ' *** restart option'
331               SELECT CASE ( nrstdt )
332               CASE ( 0 )   ;   WRITE(numout,*) ' nrstdt = 0 : no control of nit000'
333               CASE ( 1 )   ;   WRITE(numout,*) ' nrstdt = 1 : no control the date at nit000 (use ndate0 read in the namelist)'
334               CASE ( 2 )   ;   WRITE(numout,*) ' nrstdt = 2 : calendar parameters read in restart'
335               END SELECT
336               WRITE(numout,*)
337            ENDIF
338            ! Control of date
339            IF( nit000 - NINT( zkt ) /= 1 .AND. nrstdt /= 0 )                                         &
340                 &   CALL ctl_stop( ' ===>>>> : problem with nit000 for the restart',                 &
341                 &                  ' verify the restart file or rerun with nrstdt = 0 (namelist)' )
342            ! define ndastp and adatrj
343            IF ( nrstdt == 2 ) THEN
344               ! read the parameters correspondting to nit000 - 1 (last time step of previous run)
345               CALL iom_get( numror, 'ndastp', zndastp )
346               ndastp = NINT( zndastp )
347               CALL iom_get( numror, 'adatrj', adatrj  )
348          CALL iom_get( numror, 'ntime', ktime )
349          nn_time0=INT(ktime)
350               ! calculate start time in hours and minutes
351          zdayfrac=adatrj-INT(adatrj)
352          ksecs = NINT(zdayfrac*86400)        ! Nearest second to catch rounding errors in adatrj         
353          ihour = INT(ksecs/3600)
354          iminute = ksecs/60-ihour*60
355           
356               ! Add to nn_time0
357               nhour   =   nn_time0 / 100
358               nminute = ( nn_time0 - nhour * 100 )
359          nminute=nminute+iminute
360         
361          IF( nminute >= 60 ) THEN
362             nminute=nminute-60
363        nhour=nhour+1
364          ENDIF
365          nhour=nhour+ihour
366          IF( nhour >= 24 ) THEN
367        nhour=nhour-24
368             adatrj=adatrj+1
369          ENDIF         
370          nn_time0 = nhour * 100 + nminute
371          adatrj = INT(adatrj)                    ! adatrj set to integer as nn_time0 updated         
372            ELSE
373               ! parameters corresponding to nit000 - 1 (as we start the step loop with a call to day)
374               ndastp = ndate0        ! ndate0 read in the namelist in dom_nam
375               nhour   =   nn_time0 / 100
376               nminute = ( nn_time0 - nhour * 100 )
377               IF( nhour*3600+nminute*60-ndt05 .lt. 0 )  ndastp=ndastp-1      ! Start hour is specified in the namelist (default 0)
378               adatrj = ( REAL( nit000-1, wp ) * rdttra(1) ) / rday
379               ! note this is wrong if time step has changed during run
380            ENDIF
381         ELSE
382            ! parameters corresponding to nit000 - 1 (as we start the step loop with a call to day)
383            ndastp = ndate0           ! ndate0 read in the namelist in dom_nam
384            nhour   =   nn_time0 / 100
385            nminute = ( nn_time0 - nhour * 100 )
386            IF( nhour*3600+nminute*60-ndt05 .lt. 0 )  ndastp=ndastp-1      ! Start hour is specified in the namelist (default 0)
387            adatrj = ( REAL( nit000-1, wp ) * rdttra(1) ) / rday
388         ENDIF
389         IF( ABS(adatrj  - REAL(NINT(adatrj),wp)) < 0.1 / rday )   adatrj = REAL(NINT(adatrj),wp)   ! avoid truncation error
390         !
391         IF(lwp) THEN
392            WRITE(numout,*) ' *** Info used values : '
393            WRITE(numout,*) '   date ndastp                                      : ', ndastp
394            WRITE(numout,*) '   number of elapsed days since the begining of run : ', adatrj
395            WRITE(numout,*) '   nn_time0                                         : ',nn_time0
396            WRITE(numout,*)
397         ENDIF
398         !
399      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN
400         !
401         IF( kt == nitrst ) THEN
402            IF(lwp) WRITE(numout,*)
403            IF(lwp) WRITE(numout,*) 'rst_write : write oce restart file  kt =', kt
404            IF(lwp) WRITE(numout,*) '~~~~~~~'
405         ENDIF
406         ! calendar control
407         CALL iom_rstput( kt, nitrst, numrow, 'kt'     , REAL( kt    , wp) )   ! time-step
408         CALL iom_rstput( kt, nitrst, numrow, 'ndastp' , REAL( ndastp, wp) )   ! date
409         CALL iom_rstput( kt, nitrst, numrow, 'adatrj' , adatrj            )   ! number of elapsed days since
410         !                                                                     ! the begining of the run [s]
411         CALL iom_rstput( kt, nitrst, numrow, 'ntime'  , REAL( nn_time0, wp) ) ! time
412      ENDIF
413      !
414   END SUBROUTINE day_rst
415
416   !!======================================================================
417END MODULE daymod
Note: See TracBrowser for help on using the repository browser.