source: branches/UKMO/dev_r5518_obs_oper_update/NEMOGCM/NEMO/OPA_SRC/OBS/obs_write.F90 @ 9306

Last change on this file since 9306 was 9306, checked in by dford, 4 years ago

Add extra biogeochemical variables to OBS code, and make profile obs operator code more generic. See internal Met Office NEMO ticket 733.

File size: 26.4 KB
Line 
1MODULE obs_write
2   !!======================================================================
3   !!                       ***  MODULE obs_write   ***
4   !! Observation diagnosticss: Write observation related diagnostics
5   !!=====================================================================
6
7   !!----------------------------------------------------------------------
8   !!   obs_wri_prof   : Write profile observations in feedback format
9   !!   obs_wri_surf   : Write surface observations in feedback format
10   !!   obs_wri_stats  : Print basic statistics on the data being written out
11   !!----------------------------------------------------------------------
12
13   !! * Modules used
14   USE par_kind, ONLY : &   ! Precision variables
15      & wp
16   USE in_out_manager       ! I/O manager
17   USE dom_oce              ! Ocean space and time domain variables
18   USE obs_types            ! Observation type integer to character translation
19   USE julian, ONLY : &         ! Julian date routines
20      & greg2jul
21   USE obs_utils, ONLY : &  ! Observation operator utility functions
22      & chkerr
23   USE obs_profiles_def     ! Type definitions for profiles
24   USE obs_surf_def         ! Type defintions for surface observations
25   USE obs_fbm              ! Observation feedback I/O
26   USE obs_grid             ! Grid tools
27   USE obs_conv             ! Conversion between units
28   USE obs_const
29   USE obs_mpp              ! MPP support routines for observation diagnostics
30   USE lib_mpp        ! MPP routines
31
32   IMPLICIT NONE
33
34   !! * Routine accessibility
35   PRIVATE
36   PUBLIC obs_wri_prof, &    ! Write profile observation files
37      &   obs_wri_surf, &    ! Write surface observation files
38      &   obswriinfo
39   
40   TYPE obswriinfo
41      INTEGER :: inum
42      INTEGER, POINTER, DIMENSION(:) :: ipoint
43      CHARACTER(len=ilenname), POINTER, DIMENSION(:) :: cdname
44      CHARACTER(len=ilenlong), POINTER, DIMENSION(:,:) :: cdlong
45      CHARACTER(len=ilenunit), POINTER, DIMENSION(:,:) :: cdunit
46   END TYPE obswriinfo
47
48   !!----------------------------------------------------------------------
49   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
50   !! $Id$
51   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
52   !!----------------------------------------------------------------------
53
54CONTAINS
55
56   SUBROUTINE obs_wri_prof( profdata, padd, pext )
57      !!-----------------------------------------------------------------------
58      !!
59      !!                     *** ROUTINE obs_wri_prof  ***
60      !!
61      !! ** Purpose : Write profile feedback files
62      !!
63      !! ** Method  : NetCDF
64      !!
65      !! ** Action  :
66      !!
67      !! History :
68      !!      ! 06-04  (A. Vidard) Original
69      !!      ! 06-04  (A. Vidard) Reformatted
70      !!      ! 06-10  (A. Weaver) Cleanup
71      !!      ! 07-01  (K. Mogensen) Use profile data types
72      !!      ! 07-03  (K. Mogensen) General handling of profiles
73      !!      ! 09-01  (K. Mogensen) New feedback format
74      !!      ! 15-02  (M. Martin) Combined routine for writing profiles
75      !!-----------------------------------------------------------------------
76
77      !! * Arguments
78      TYPE(obs_prof), INTENT(INOUT) :: profdata      ! Full set of profile data
79      TYPE(obswriinfo), OPTIONAL :: padd             ! Additional info for each variable
80      TYPE(obswriinfo), OPTIONAL :: pext             ! Extra info
81
82      !! * Local declarations
83      TYPE(obfbdata) :: fbdata
84      CHARACTER(LEN=40) :: clfname
85      CHARACTER(LEN=10) :: clfiletype
86      CHARACTER(LEN=ilenlong) :: cllongname  ! Long name of variable
87      CHARACTER(LEN=ilenunit) :: clunits     ! Units of variable
88      CHARACTER(LEN=ilengrid) :: clgrid      ! Grid of variable
89      INTEGER :: ilevel
90      INTEGER :: jvar
91      INTEGER :: jo
92      INTEGER :: jk
93      INTEGER :: ik
94      INTEGER :: ja
95      INTEGER :: je
96      INTEGER :: iadd
97      INTEGER :: iext
98      REAL(wp) :: zpres
99
100      IF ( PRESENT( padd ) ) THEN
101         iadd = padd%inum
102      ELSE
103         iadd = 0
104      ENDIF
105
106      IF ( PRESENT( pext ) ) THEN
107         iext = pext%inum
108      ELSE
109         iext = 0
110      ENDIF
111
112      CALL init_obfbdata( fbdata )
113
114      ! Find maximum level
115      ilevel = 0
116      DO jvar = 1, profdata%nvar
117         ilevel = MAX( ilevel, MAXVAL( profdata%var(jvar)%nvlidx(:) ) )
118      END DO
119
120      SELECT CASE ( TRIM(profdata%cvars(1)) )
121      CASE('POTM')
122
123         clfiletype='profb'
124         CALL alloc_obfbdata( fbdata, 2, profdata%nprof, ilevel, &
125            &                 1 + iadd, 1 + iext, .TRUE. )
126         fbdata%cname(1)      = profdata%cvars(1)
127         fbdata%cname(2)      = profdata%cvars(2)
128         fbdata%coblong(1)    = 'Potential temperature'
129         fbdata%coblong(2)    = 'Practical salinity'
130         fbdata%cobunit(1)    = 'Degrees centigrade'
131         fbdata%cobunit(2)    = 'PSU'
132         fbdata%cextname(1)   = 'TEMP'
133         fbdata%cextlong(1)   = 'Insitu temperature'
134         fbdata%cextunit(1)   = 'Degrees centigrade'
135         fbdata%caddlong(1,1) = 'Model interpolated potential temperature'
136         fbdata%caddlong(1,2) = 'Model interpolated practical salinity'
137         fbdata%caddunit(1,1) = 'Degrees centigrade'
138         fbdata%caddunit(1,2) = 'PSU'
139         fbdata%cgrid(:)      = 'T'
140         DO je = 1, iext
141            fbdata%cextname(1+je) = pext%cdname(je)
142            fbdata%cextlong(1+je) = pext%cdlong(je,1)
143            fbdata%cextunit(1+je) = pext%cdunit(je,1)
144         END DO
145         DO ja = 1, iadd
146            fbdata%caddname(1+ja) = padd%cdname(ja)
147            DO jvar = 1, 2
148               fbdata%caddlong(1+ja,jvar) = padd%cdlong(ja,jvar)
149               fbdata%caddunit(1+ja,jvar) = padd%cdunit(ja,jvar)
150            END DO
151         END DO
152
153      CASE('UVEL')
154
155         clfiletype='velfb'
156         CALL alloc_obfbdata( fbdata, 2, profdata%nprof, ilevel, 1, 0, .TRUE. )
157         fbdata%cname(1)      = profdata%cvars(1)
158         fbdata%cname(2)      = profdata%cvars(2)
159         fbdata%coblong(1)    = 'Zonal velocity'
160         fbdata%coblong(2)    = 'Meridional velocity'
161         fbdata%cobunit(1)    = 'm/s'
162         fbdata%cobunit(2)    = 'm/s'
163         DO je = 1, iext
164            fbdata%cextname(je) = pext%cdname(je)
165            fbdata%cextlong(je) = pext%cdlong(je,1)
166            fbdata%cextunit(je) = pext%cdunit(je,1)
167         END DO
168         fbdata%caddlong(1,1) = 'Model interpolated zonal velocity'
169         fbdata%caddlong(1,2) = 'Model interpolated meridional velocity'
170         fbdata%caddunit(1,1) = 'm/s'
171         fbdata%caddunit(1,2) = 'm/s'
172         fbdata%cgrid(1)      = 'U' 
173         fbdata%cgrid(2)      = 'V'
174         DO ja = 1, iadd
175            fbdata%caddname(1+ja) = padd%cdname(ja)
176            fbdata%caddlong(1+ja,1) = padd%cdlong(ja,1)
177            fbdata%caddunit(1+ja,1) = padd%cdunit(ja,1)
178         END DO
179
180      CASE('PLCHLTOT')
181
182         clfiletype = 'plchltotfb'
183         cllongname = 'log10(chlorophyll concentration)'
184         clunits    = 'log10(mg/m3)'
185         clgrid     = 'T'
186
187      CASE('PCHLTOT')
188
189         clfiletype = 'pchltotfb'
190         cllongname = 'chlorophyll concentration'
191         clunits    = 'mg/m3'
192         clgrid     = 'T'
193
194      CASE('PNO3')
195
196         clfiletype = 'pno3fb'
197         cllongname = 'nitrate'
198         clunits    = 'mmol/m3'
199         clgrid     = 'T'
200
201      CASE('PSI4')
202
203         clfiletype = 'psi4fb'
204         cllongname = 'silicate'
205         clunits    = 'mmol/m3'
206         clgrid     = 'T'
207
208      CASE('PPO4')
209
210         clfiletype = 'ppo4fb'
211         cllongname = 'phosphate'
212         clunits    = 'mmol/m3'
213         clgrid     = 'T'
214
215      CASE('PDIC')
216
217         clfiletype = 'pdicfb'
218         cllongname = 'dissolved inorganic carbon'
219         clunits    = 'mmol/m3'
220         clgrid     = 'T'
221
222      CASE('PALK')
223
224         clfiletype = 'palkfb'
225         cllongname = 'alkalinity'
226         clunits    = 'meq/m3'
227         clgrid     = 'T'
228
229      CASE('PPH')
230
231         clfiletype = 'pphfb'
232         cllongname = 'pH'
233         clunits    = '-'
234         clgrid     = 'T'
235
236      CASE('PO2')
237
238         clfiletype = 'po2fb'
239         cllongname = 'dissolved oxygen'
240         clunits    = 'mmol/m3'
241         clgrid     = 'T'
242
243      END SELECT
244     
245      IF ( ( TRIM(profdata%cvars(1)) /= 'POTM' ) .AND. &
246         & ( TRIM(profdata%cvars(1)) /= 'UVEL' ) ) THEN
247         CALL alloc_obfbdata( fbdata, 1, profdata%nprof, ilevel, &
248            &                 1 + iadd, iext, .TRUE. )
249         fbdata%cname(1)      = profdata%cvars(1)
250         fbdata%coblong(1)    = cllongname
251         fbdata%cobunit(1)    = clunits
252         fbdata%caddlong(1,1) = 'Model interpolated ' // TRIM(cllongname)
253         fbdata%caddunit(1,1) = clunits
254         fbdata%cgrid(:)      = clgrid
255         DO je = 1, iext
256            fbdata%cextname(je) = pext%cdname(je)
257            fbdata%cextlong(je) = pext%cdlong(je,1)
258            fbdata%cextunit(je) = pext%cdunit(je,1)
259         END DO
260         DO ja = 1, iadd
261            fbdata%caddname(1+ja) = padd%cdname(ja)
262            fbdata%caddlong(1+ja,1) = padd%cdlong(ja,1)
263            fbdata%caddunit(1+ja,1) = padd%cdunit(ja,1)
264         END DO
265      ENDIF
266
267      fbdata%caddname(1)   = 'Hx'
268
269      WRITE(clfname, FMT="(A,'_fdbk_',I4.4,'.nc')") TRIM(clfiletype), nproc
270
271      IF(lwp) THEN
272         WRITE(numout,*)
273         WRITE(numout,*)'obs_wri_prof :'
274         WRITE(numout,*)'~~~~~~~~~~~~~'
275         WRITE(numout,*)'Writing '//TRIM(clfiletype)//' feedback file : ',TRIM(clfname)
276      ENDIF
277
278      ! Transform obs_prof data structure into obfb data structure
279      fbdata%cdjuldref = '19500101000000'
280      DO jo = 1, profdata%nprof
281         fbdata%plam(jo)      = profdata%rlam(jo)
282         fbdata%pphi(jo)      = profdata%rphi(jo)
283         WRITE(fbdata%cdtyp(jo),'(I4)') profdata%ntyp(jo)
284         fbdata%ivqc(jo,:)    = profdata%ivqc(jo,:)
285         fbdata%ivqcf(:,jo,:) = profdata%ivqcf(:,jo,:)
286         IF ( profdata%nqc(jo) > 255 ) THEN
287            fbdata%ioqc(jo)    = IBSET(profdata%nqc(jo),2)
288            fbdata%ioqcf(1,jo) = profdata%nqcf(1,jo)
289            fbdata%ioqcf(2,jo) = profdata%nqc(jo)
290         ELSE
291            fbdata%ioqc(jo)    = profdata%nqc(jo)
292            fbdata%ioqcf(:,jo) = profdata%nqcf(:,jo)
293         ENDIF
294         fbdata%ipqc(jo)      = profdata%ipqc(jo)
295         fbdata%ipqcf(:,jo)   = profdata%ipqcf(:,jo)
296         fbdata%itqc(jo)      = profdata%itqc(jo)
297         fbdata%itqcf(:,jo)   = profdata%itqcf(:,jo)
298         fbdata%cdwmo(jo)     = profdata%cwmo(jo)
299         fbdata%kindex(jo)    = profdata%npfil(jo)
300         DO jvar = 1, profdata%nvar
301            IF (ln_grid_global) THEN
302               fbdata%iobsi(jo,jvar) = profdata%mi(jo,jvar)
303               fbdata%iobsj(jo,jvar) = profdata%mj(jo,jvar)
304            ELSE
305               fbdata%iobsi(jo,jvar) = mig(profdata%mi(jo,jvar))
306               fbdata%iobsj(jo,jvar) = mjg(profdata%mj(jo,jvar))
307            ENDIF
308         END DO
309         CALL greg2jul( 0, &
310            &           profdata%nmin(jo), &
311            &           profdata%nhou(jo), &
312            &           profdata%nday(jo), &
313            &           profdata%nmon(jo), &
314            &           profdata%nyea(jo), &
315            &           fbdata%ptim(jo),   &
316            &           krefdate = 19500101 )
317         ! Reform the profiles arrays for output
318         DO jvar = 1, profdata%nvar
319            DO jk = profdata%npvsta(jo,jvar), profdata%npvend(jo,jvar)
320               ik = profdata%var(jvar)%nvlidx(jk)
321               fbdata%padd(ik,jo,1,jvar) = profdata%var(jvar)%vmod(jk)
322               fbdata%pob(ik,jo,jvar)    = profdata%var(jvar)%vobs(jk)
323               fbdata%pdep(ik,jo)        = profdata%var(jvar)%vdep(jk)
324               fbdata%idqc(ik,jo)        = profdata%var(jvar)%idqc(jk)
325               fbdata%idqcf(:,ik,jo)     = profdata%var(jvar)%idqcf(:,jk)
326               IF ( profdata%var(jvar)%nvqc(jk) > 255 ) THEN
327                  fbdata%ivlqc(ik,jo,jvar) = IBSET(profdata%var(jvar)%nvqc(jk),2)
328                  fbdata%ivlqcf(1,ik,jo,jvar) = profdata%var(jvar)%nvqcf(1,jk)
329                  fbdata%ivlqcf(2,ik,jo,jvar) = IAND(profdata%var(jvar)%nvqc(jk),b'0000 0000 1111 1111')
330               ELSE
331                  fbdata%ivlqc(ik,jo,jvar) = profdata%var(jvar)%nvqc(jk)
332                  fbdata%ivlqcf(:,ik,jo,jvar) = profdata%var(jvar)%nvqcf(:,jk)
333               ENDIF
334               fbdata%iobsk(ik,jo,jvar)  = profdata%var(jvar)%mvk(jk)
335               DO ja = 1, iadd
336                  fbdata%padd(ik,jo,1+ja,jvar) = &
337                     & profdata%var(jvar)%vext(jk,padd%ipoint(ja))
338               END DO
339               DO je = 1, iext
340                  fbdata%pext(ik,jo,1+je) = &
341                     & profdata%var(jvar)%vext(jk,pext%ipoint(je))
342               END DO
343               IF ( ( jvar == 1 ) .AND. &
344                  & ( TRIM(profdata%cvars(1)) == 'POTM' ) ) THEN
345                  fbdata%pext(ik,jo,1) = profdata%var(jvar)%vext(jk,1)
346               ENDIF
347            END DO
348         END DO
349      END DO
350
351      IF ( TRIM(profdata%cvars(1)) == 'POTM' ) THEN
352         ! Convert insitu temperature to potential temperature using the model
353         ! salinity if no potential temperature
354         DO jo = 1, fbdata%nobs
355            IF ( fbdata%pphi(jo) < 9999.0 ) THEN
356               DO jk = 1, fbdata%nlev
357                  IF ( ( fbdata%pob(jk,jo,1) >= 9999.0 ) .AND. &
358                     & ( fbdata%pdep(jk,jo) < 9999.0 ) .AND. &
359                     & ( fbdata%padd(jk,jo,1,2) < 9999.0 ) .AND. &
360                     & ( fbdata%pext(jk,jo,1) < 9999.0 ) ) THEN
361                     zpres = dep_to_p( REAL(fbdata%pdep(jk,jo),wp), &
362                        &              REAL(fbdata%pphi(jo),wp) )
363                     fbdata%pob(jk,jo,1) = potemp( &
364                        &                     REAL(fbdata%padd(jk,jo,1,2), wp),  &
365                        &                     REAL(fbdata%pext(jk,jo,1), wp), &
366                        &                     zpres, 0.0_wp )
367                  ENDIF
368               END DO
369            ENDIF
370         END DO
371      ENDIF
372
373      ! Write the obfbdata structure
374      CALL write_obfbdata( clfname, fbdata )
375
376      ! Output some basic statistics
377      CALL obs_wri_stats( fbdata )
378
379      CALL dealloc_obfbdata( fbdata )
380
381   END SUBROUTINE obs_wri_prof
382
383   SUBROUTINE obs_wri_surf( surfdata, padd, pext )
384      !!-----------------------------------------------------------------------
385      !!
386      !!                     *** ROUTINE obs_wri_surf  ***
387      !!
388      !! ** Purpose : Write surface observation files
389      !!
390      !! ** Method  : NetCDF
391      !!
392      !! ** Action  :
393      !!
394      !!      ! 07-03  (K. Mogensen) Original
395      !!      ! 09-01  (K. Mogensen) New feedback format.
396      !!      ! 15-02  (M. Martin) Combined surface writing routine.
397      !!-----------------------------------------------------------------------
398
399      !! * Modules used
400      IMPLICIT NONE
401
402      !! * Arguments
403      TYPE(obs_surf), INTENT(INOUT) :: surfdata         ! Full set of surface data
404      TYPE(obswriinfo), OPTIONAL :: padd               ! Additional info for each variable
405      TYPE(obswriinfo), OPTIONAL :: pext               ! Extra info
406
407      !! * Local declarations
408      TYPE(obfbdata) :: fbdata
409      CHARACTER(LEN=40) :: clfname         ! netCDF filename
410      CHARACTER(LEN=10) :: clfiletype
411      CHARACTER(LEN=12), PARAMETER :: cpname = 'obs_wri_surf'
412      CHARACTER(LEN=ilenlong) :: cllongname  ! Long name of variable
413      CHARACTER(LEN=ilenunit) :: clunits     ! Units of variable
414      CHARACTER(LEN=ilengrid) :: clgrid      ! Grid of variable
415      INTEGER :: jo
416      INTEGER :: ja
417      INTEGER :: je
418      INTEGER :: iadd
419      INTEGER :: iext
420
421      IF ( PRESENT( padd ) ) THEN
422         iadd = padd%inum
423      ELSE
424         iadd = 0
425      ENDIF
426
427      IF ( PRESENT( pext ) ) THEN
428         iext = pext%inum
429      ELSE
430         iext = 0
431      ENDIF
432
433      CALL init_obfbdata( fbdata )
434
435      SELECT CASE ( TRIM(surfdata%cvars(1)) )
436      CASE('SLA')
437
438         ! SLA needs special treatment because of MDT, so is all done here
439         ! Other variables are done more generically
440
441         CALL alloc_obfbdata( fbdata, 1, surfdata%nsurf, 1, &
442            &                 2 + iadd, 1 + iext, .TRUE. )
443
444         clfiletype = 'slafb'
445         fbdata%cname(1)      = surfdata%cvars(1)
446         fbdata%coblong(1)    = 'Sea level anomaly'
447         fbdata%cobunit(1)    = 'Metres'
448         fbdata%cextname(1)   = 'MDT'
449         fbdata%cextlong(1)   = 'Mean dynamic topography'
450         fbdata%cextunit(1)   = 'Metres'
451         DO je = 1, iext
452            fbdata%cextname(je) = pext%cdname(je)
453            fbdata%cextlong(je) = pext%cdlong(je,1)
454            fbdata%cextunit(je) = pext%cdunit(je,1)
455         END DO
456         fbdata%caddlong(1,1) = 'Model interpolated SSH - MDT'
457         fbdata%caddunit(1,1) = 'Metres' 
458         fbdata%caddname(2)   = 'SSH'
459         fbdata%caddlong(2,1) = 'Model Sea surface height'
460         fbdata%caddunit(2,1) = 'Metres'
461         fbdata%cgrid(1)      = 'T'
462         DO ja = 1, iadd
463            fbdata%caddname(2+ja) = padd%cdname(ja)
464            fbdata%caddlong(2+ja,1) = padd%cdlong(ja,1)
465            fbdata%caddunit(2+ja,1) = padd%cdunit(ja,1)
466         END DO
467
468      CASE('SST')
469
470         clfiletype = 'sstfb'
471         cllongname = 'Sea surface temperature'
472         clunits    = 'Degree centigrade'
473         clgrid     = 'T'
474
475      CASE('ICECONC')
476
477         clfiletype = 'sicfb'
478         cllongname = 'Sea ice'
479         clunits    = 'Fraction'
480         clgrid     = 'T'
481
482      CASE('SSS')
483
484         clfiletype = 'sssfb'
485         cllongname = 'Sea surface salinity'
486         clunits    = 'psu'
487         clgrid     = 'T'
488
489      CASE('SLCHLTOT','LOGCHL','LogChl','logchl')
490
491         clfiletype = 'slchltotfb'
492         cllongname = 'Surface total log10(chlorophyll)'
493         clunits    = 'log10(mg/m3)'
494         clgrid     = 'T'
495
496      CASE('SLCHLDIA')
497
498         clfiletype = 'slchldiafb'
499         cllongname = 'Surface diatom log10(chlorophyll)'
500         clunits    = 'log10(mg/m3)'
501         clgrid     = 'T'
502
503      CASE('SLCHLNON')
504
505         clfiletype = 'slchlnonfb'
506         cllongname = 'Surface non-diatom log10(chlorophyll)'
507         clunits    = 'log10(mg/m3)'
508         clgrid     = 'T'
509
510      CASE('SLCHLDIN')
511
512         clfiletype = 'slchldinfb'
513         cllongname = 'Surface dinoflagellate log10(chlorophyll)'
514         clunits    = 'log10(mg/m3)'
515         clgrid     = 'T'
516
517      CASE('SLCHLMIC')
518
519         clfiletype = 'slchlmicfb'
520         cllongname = 'Surface microphytoplankton log10(chlorophyll)'
521         clunits    = 'log10(mg/m3)'
522         clgrid     = 'T'
523
524      CASE('SLCHLNAN')
525
526         clfiletype = 'slchlnanfb'
527         cllongname = 'Surface nanophytoplankton log10(chlorophyll)'
528         clunits    = 'log10(mg/m3)'
529         clgrid     = 'T'
530
531      CASE('SLCHLPIC')
532
533         clfiletype = 'slchlpicfb'
534         cllongname = 'Surface picophytoplankton log10(chlorophyll)'
535         clunits    = 'log10(mg/m3)'
536         clgrid     = 'T'
537
538      CASE('SCHLTOT')
539
540         clfiletype = 'schltotfb'
541         cllongname = 'Surface total chlorophyll'
542         clunits    = 'mg/m3'
543         clgrid     = 'T'
544
545      CASE('SLPHYTOT')
546
547         clfiletype = 'slphytotfb'
548         cllongname = 'Surface total log10(phytoplankton carbon)'
549         clunits    = 'log10(mmolC/m3)'
550         clgrid     = 'T'
551
552      CASE('SLPHYDIA')
553
554         clfiletype = 'slphydiafb'
555         cllongname = 'Surface diatom log10(phytoplankton carbon)'
556         clunits    = 'log10(mmolC/m3)'
557         clgrid     = 'T'
558
559      CASE('SLPHYNON')
560
561         clfiletype = 'slphynonfb'
562         cllongname = 'Surface non-diatom log10(phytoplankton carbon)'
563         clunits    = 'log10(mmolC/m3)'
564         clgrid     = 'T'
565
566      CASE('SSPM')
567
568         clfiletype = 'sspmfb'
569         cllongname = 'Surface suspended particulate matter'
570         clunits    = 'g/m3'
571         clgrid     = 'T'
572
573      CASE('SFCO2','FCO2','fCO2','fco2')
574
575         clfiletype = 'sfco2fb'
576         cllongname = 'Surface fugacity of carbon dioxide'
577         clunits    = 'uatm'
578         clgrid     = 'T'
579
580      CASE('SPCO2')
581
582         clfiletype = 'spco2fb'
583         cllongname = 'Surface partial pressure of carbon dioxide'
584         clunits    = 'uatm'
585         clgrid     = 'T'
586
587      CASE DEFAULT
588
589         CALL ctl_stop( 'Unknown observation type '//TRIM(surfdata%cvars(1))//' in obs_wri_surf' )
590
591      END SELECT
592
593      ! SLA needs special treatment because of MDT, so is done above
594      ! Remaining variables treated more generically
595
596      IF ( TRIM(surfdata%cvars(1)) /= 'SLA' ) THEN
597     
598         CALL alloc_obfbdata( fbdata, 1, surfdata%nsurf, 1, &
599            &                 1 + iadd, iext, .TRUE. )
600
601         fbdata%cname(1)      = surfdata%cvars(1)
602         fbdata%coblong(1)    = cllongname
603         fbdata%cobunit(1)    = clunits
604         DO je = 1, iext
605            fbdata%cextname(je) = pext%cdname(je)
606            fbdata%cextlong(je) = pext%cdlong(je,1)
607            fbdata%cextunit(je) = pext%cdunit(je,1)
608         END DO
609         IF ( TRIM(surfdata%cvars(1)) == 'ICECONC' ) THEN
610            fbdata%caddlong(1,1) = 'Model interpolated ICE'
611         ELSE
612            fbdata%caddlong(1,1) = 'Model interpolated ' // TRIM(surfdata%cvars(1))
613         ENDIF
614         fbdata%caddunit(1,1) = clunits
615         fbdata%cgrid(1)      = clgrid
616         DO ja = 1, iadd
617            fbdata%caddname(1+ja) = padd%cdname(ja)
618            fbdata%caddlong(1+ja,1) = padd%cdlong(ja,1)
619            fbdata%caddunit(1+ja,1) = padd%cdunit(ja,1)
620         END DO
621
622      ENDIF
623     
624      fbdata%caddname(1)   = 'Hx'
625
626      WRITE(clfname, FMT="(A,'_fdbk_',I4.4,'.nc')") TRIM(clfiletype), nproc
627
628      IF(lwp) THEN
629         WRITE(numout,*)
630         WRITE(numout,*)'obs_wri_surf :'
631         WRITE(numout,*)'~~~~~~~~~~~~~'
632         WRITE(numout,*)'Writing '//TRIM(surfdata%cvars(1))//' feedback file : ',TRIM(clfname)
633      ENDIF
634
635      ! Transform surf data structure into obfbdata structure
636      fbdata%cdjuldref = '19500101000000'
637      DO jo = 1, surfdata%nsurf
638         fbdata%plam(jo)      = surfdata%rlam(jo)
639         fbdata%pphi(jo)      = surfdata%rphi(jo)
640         WRITE(fbdata%cdtyp(jo),'(I4)') surfdata%ntyp(jo)
641         fbdata%ivqc(jo,:)    = 0
642         fbdata%ivqcf(:,jo,:) = 0
643         IF ( surfdata%nqc(jo) > 255 ) THEN
644            fbdata%ioqc(jo)    = 4
645            fbdata%ioqcf(1,jo) = 0
646            fbdata%ioqcf(2,jo) = IAND(surfdata%nqc(jo),b'0000 0000 1111 1111')
647         ELSE
648            fbdata%ioqc(jo)    = surfdata%nqc(jo)
649            fbdata%ioqcf(:,jo) = 0
650         ENDIF
651         fbdata%ipqc(jo)      = 0
652         fbdata%ipqcf(:,jo)   = 0
653         fbdata%itqc(jo)      = 0
654         fbdata%itqcf(:,jo)   = 0
655         fbdata%cdwmo(jo)     = surfdata%cwmo(jo)
656         fbdata%kindex(jo)    = surfdata%nsfil(jo)
657         IF (ln_grid_global) THEN
658            fbdata%iobsi(jo,1) = surfdata%mi(jo)
659            fbdata%iobsj(jo,1) = surfdata%mj(jo)
660         ELSE
661            fbdata%iobsi(jo,1) = mig(surfdata%mi(jo))
662            fbdata%iobsj(jo,1) = mjg(surfdata%mj(jo))
663         ENDIF
664         CALL greg2jul( 0, &
665            &           surfdata%nmin(jo), &
666            &           surfdata%nhou(jo), &
667            &           surfdata%nday(jo), &
668            &           surfdata%nmon(jo), &
669            &           surfdata%nyea(jo), &
670            &           fbdata%ptim(jo),   &
671            &           krefdate = 19500101 )
672         fbdata%padd(1,jo,1,1) = surfdata%rmod(jo,1)
673         IF ( TRIM(surfdata%cvars(1)) == 'SLA' ) fbdata%padd(1,jo,2,1) = surfdata%rext(jo,1)
674         fbdata%pob(1,jo,1)    = surfdata%robs(jo,1) 
675         fbdata%pdep(1,jo)     = 0.0
676         fbdata%idqc(1,jo)     = 0
677         fbdata%idqcf(:,1,jo)  = 0
678         IF ( surfdata%nqc(jo) > 255 ) THEN
679            fbdata%ivqc(jo,1)       = 4
680            fbdata%ivlqc(1,jo,1)    = 4
681            fbdata%ivlqcf(1,1,jo,1) = 0
682            fbdata%ivlqcf(2,1,jo,1) = IAND(surfdata%nqc(jo),b'0000 0000 1111 1111')
683         ELSE
684            fbdata%ivqc(jo,1)       = surfdata%nqc(jo)
685            fbdata%ivlqc(1,jo,1)    = surfdata%nqc(jo)
686            fbdata%ivlqcf(:,1,jo,1) = 0
687         ENDIF
688         fbdata%iobsk(1,jo,1)  = 0
689         IF ( TRIM(surfdata%cvars(1)) == 'SLA' ) fbdata%pext(1,jo,1) = surfdata%rext(jo,2)
690         DO ja = 1, iadd
691            fbdata%padd(1,jo,2+ja,1) = &
692               & surfdata%rext(jo,padd%ipoint(ja))
693         END DO
694         DO je = 1, iext
695            fbdata%pext(1,jo,1+je) = &
696               & surfdata%rext(jo,pext%ipoint(je))
697         END DO
698      END DO
699
700      ! Write the obfbdata structure
701      CALL write_obfbdata( clfname, fbdata )
702
703      ! Output some basic statistics
704      CALL obs_wri_stats( fbdata )
705
706      CALL dealloc_obfbdata( fbdata )
707
708   END SUBROUTINE obs_wri_surf
709
710   SUBROUTINE obs_wri_stats( fbdata )
711      !!-----------------------------------------------------------------------
712      !!
713      !!                     *** ROUTINE obs_wri_stats  ***
714      !!
715      !! ** Purpose : Output some basic statistics of the data being written out
716      !!
717      !! ** Method  :
718      !!
719      !! ** Action  :
720      !!
721      !!      ! 2014-08  (D. Lea) Initial version
722      !!-----------------------------------------------------------------------
723
724      !! * Arguments
725      TYPE(obfbdata) :: fbdata
726
727      !! * Local declarations
728      INTEGER :: jvar
729      INTEGER :: jo
730      INTEGER :: jk
731      INTEGER :: inumgoodobs
732      INTEGER :: inumgoodobsmpp
733      REAL(wp) :: zsumx
734      REAL(wp) :: zsumx2
735      REAL(wp) :: zomb
736     
737
738      IF (lwp) THEN
739         WRITE(numout,*) ''
740         WRITE(numout,*) 'obs_wri_stats :'
741         WRITE(numout,*) '~~~~~~~~~~~~~~~'
742      ENDIF
743
744      DO jvar = 1, fbdata%nvar
745         zsumx=0.0_wp
746         zsumx2=0.0_wp
747         inumgoodobs=0
748         DO jo = 1, fbdata%nobs
749            DO jk = 1, fbdata%nlev
750               IF ( ( fbdata%pob(jk,jo,jvar) < 9999.0 ) .AND. &
751                  & ( fbdata%pdep(jk,jo) < 9999.0 ) .AND. &
752                  & ( fbdata%padd(jk,jo,1,jvar) < 9999.0 ) ) THEN
753
754                  zomb=fbdata%pob(jk, jo, jvar)-fbdata%padd(jk, jo, 1, jvar)
755                  zsumx=zsumx+zomb
756                  zsumx2=zsumx2+zomb**2
757                  inumgoodobs=inumgoodobs+1
758               ENDIF
759            ENDDO
760         ENDDO
761
762         CALL obs_mpp_sum_integer( inumgoodobs, inumgoodobsmpp )
763         CALL mpp_sum(zsumx)
764         CALL mpp_sum(zsumx2)
765
766         IF (lwp) THEN
767            WRITE(numout,*) 'Type: ',fbdata%cname(jvar),'  Total number of good observations: ',inumgoodobsmpp 
768            WRITE(numout,*) 'Overall mean obs minus model of the good observations: ',zsumx/inumgoodobsmpp
769            WRITE(numout,*) 'Overall RMS obs minus model of the good observations: ',sqrt( zsumx2/inumgoodobsmpp )
770            WRITE(numout,*) ''
771         ENDIF
772
773      ENDDO
774
775   END SUBROUTINE obs_wri_stats
776
777END MODULE obs_write
Note: See TracBrowser for help on using the repository browser.