New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
obsinter_z1d.h90 in branches/UKMO/dev_r5518_obs_oper_update_DepthBug/NEMOGCM/NEMO/OPA_SRC/OBS – NEMO

source: branches/UKMO/dev_r5518_obs_oper_update_DepthBug/NEMOGCM/NEMO/OPA_SRC/OBS/obsinter_z1d.h90 @ 15356

Last change on this file since 15356 was 15356, checked in by kingr, 2 years ago

Chnages to fix test in obs_level_search to ensure index of level below obdepth is returned, and to obs_prep to remove code which altered obdepths, and to vertical interpolation routine to deal with obs in top half of top box or bottom half of bottom box.
File size: 8.0 KB
Line 
1   !!----------------------------------------------------------------------
2   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
3   !! $Id$
4   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
5   !!----------------------------------------------------------------------
6
7   SUBROUTINE obs_int_z1d( kpk, kkco, k1dint, kdep, &
8      &                    pobsdep, pobsk, pobs2k,  &
9      &                    pobs, pdep, pobsmask )
10      !!---------------------------------------------------------------------
11      !!
12      !!                   ***  ROUTINE obs_int_z1d ***
13      !!
14      !! ** Purpose : Vertical interpolation to the observation point.
15      !! 
16      !! ** Method  : If k1dint = 0 then use linear interpolation.
17      !!              If k1dint = 1 then use cubic spline interpolation.
18      !!
19      !! ** Action  :
20      !!
21      !! References :
22      !!
23      !! History
24      !!      ! 97-11 (A. Weaver, S. Ricci, N. Daget)
25      !!      ! 06-03 (G. Smith) Conversion to F90 for use with NEMOVAR
26      !!      ! 06-10 (A. Weaver) Cleanup
27      !!      ! 07-01 (K. Mogensen) Use profile rather than single level
28      !!---------------------------------------------------------------------
29
30      !! * Arguments
31      INTEGER, INTENT(IN) :: kpk        ! Number of vertical levels
32      INTEGER, INTENT(IN) :: k1dint     ! 0 = linear; 1 = cubic spline interpolation
33      INTEGER, INTENT(IN) :: kdep       ! Number of levels in profile
34      INTEGER, INTENT(IN), DIMENSION(kdep) :: &
35         & kkco                 ! Array indicies for interpolation
36      REAL(KIND=wp), INTENT(IN), DIMENSION(kdep) :: &
37         & pobsdep              ! Depth of the observation
38      REAL(KIND=wp), INTENT(IN), DIMENSION(kpk) :: &
39         & pobsk,  &            ! Model profile at a given (lon,lat)
40         & pobs2k, &            ! 2nd derivative of the interpolating function
41         & pdep,   &            ! Model depth array
42         & pobsmask             ! Vertical mask
43      REAL(KIND=wp), INTENT(OUT), DIMENSION(kdep) :: &
44         & pobs                 ! Model equivalent at observation point
45 
46      !! * Local declarations
47      REAL(KIND=wp) :: z1dm       ! Distance above and below obs to model grid points
48      REAL(KIND=wp) :: z1dp         
49      REAL(KIND=wp) :: zsum       ! Dummy variables for computation
50      REAL(KIND=wp) :: zsum2
51      INTEGER :: jdep             ! Observation depths loop variable
52   
53      !------------------------------------------------------------------------
54      ! Loop over all observation depths
55      !------------------------------------------------------------------------
56
57      DO jdep = 1, kdep
58
59         !---------------------------------------------------------------------
60         ! Initialization
61         !---------------------------------------------------------------------
62         z1dm = ( pdep(kkco(jdep)) - pobsdep(jdep)      )
63         z1dp = ( pobsdep(jdep)    - pdep(kkco(jdep)-1) )
64         
65         ! Where ob is at or above top model T-point, use model top rather than extrapolate
66         IF ( pobsdep(jdep) <= pdep(kkco(jdep)-1) ) z1dp = 0.0_wp
67         
68         ! Where ob is at or below bottom model T-point, use model bottom rather than extrapolate
69         IF ( pobsdep(jdep) >= pdep(kkco(jdep)) ) z1dm = 0.0_wp
70
71         ! Where deeper level is masked, only use higher level
72         IF ( pobsmask(kkco(jdep)) == 0.0_wp ) z1dp = 0.0_wp
73
74         zsum = z1dm + z1dp
75         
76         IF ( zsum > 0.0_wp ) THEN
77            IF ( k1dint == 0 ) THEN
78
79               !-----------------------------------------------------------------
80               !  Linear interpolation
81               !-----------------------------------------------------------------
82               pobs(jdep) = (   z1dm * pobsk(kkco(jdep)-1) &
83                  &           + z1dp * pobsk(kkco(jdep)  ) ) / zsum
84
85            ELSEIF ( k1dint == 1 ) THEN
86
87               !-----------------------------------------------------------------
88               ! Cubic spline interpolation
89               !-----------------------------------------------------------------
90               zsum2 = zsum * zsum
91               pobs(jdep)  = (  z1dm                             * pobsk (kkco(jdep)-1) &
92                  &           + z1dp                             * pobsk (kkco(jdep)  ) &
93                  &           + ( z1dm * ( z1dm * z1dm - zsum2 ) * pobs2k(kkco(jdep)-1) &
94                  &           +   z1dp * ( z1dp * z1dp - zsum2 ) * pobs2k(kkco(jdep)  ) &
95                  &             ) / 6.0_wp                                              &
96                  &          ) / zsum
97
98            ENDIF
99         ELSE ! take value directly from the higher model level
100            pobs(jdep)  = pobsk(kkco(jdep)-1)
101         ENDIF
102      END DO
103
104   END SUBROUTINE obs_int_z1d
105
106   SUBROUTINE obs_int_z1d_spl( kpk, pobsk, pobs2k, &
107      &                        pdep, pobsmask )
108      !!--------------------------------------------------------------------
109      !!
110      !!                  *** ROUTINE obs_int_z1d_spl ***
111      !!
112      !! ** Purpose : Compute the local vector of vertical second-derivatives
113      !!              of the interpolating function used with a cubic spline.
114      !! 
115      !! ** Method  :
116      !!
117      !!    Top and bottom boundary conditions on the 2nd derivative are
118      !!    set to zero.
119      !!
120      !! ** Action  :
121      !!
122      !! References :
123      !!
124      !! History
125      !!      ! 01-11 (A. Weaver, S. Ricci, N. Daget)
126      !!      ! 06-03 (G. Smith) Conversion to F90 for use with NEMOVAR
127      !!      ! 06-10 (A. Weaver) Cleanup
128      !!----------------------------------------------------------------------
129     
130      !! * Arguments
131      INTEGER, INTENT(IN) :: kpk               ! Number of vertical levels
132      REAL(KIND=wp), INTENT(IN), DIMENSION(kpk) :: &
133         & pobsk, &          ! Model profile at a given (lon,lat)
134         & pdep,  &          ! Model depth array
135         & pobsmask          ! Vertical mask
136      REAL(KIND=wp), INTENT(OUT), DIMENSION(kpk) :: &
137         & pobs2k            ! 2nd derivative of the interpolating function
138 
139      !! * Local declarations
140      INTEGER :: jk
141      REAL(KIND=wp) :: za
142      REAL(KIND=wp) :: zb
143      REAL(KIND=wp) :: zc
144      REAL(KIND=wp) :: zpa
145      REAL(KIND=wp) :: zkm
146      REAL(KIND=wp) :: zkp
147      REAL(KIND=wp) :: zk
148      REAL(KIND=wp), DIMENSION(kpk-1) :: &
149         & zs, &
150         & zp, &
151         & zu, &
152         & zv
153
154      !-----------------------------------------------------------------------
155      ! Matrix initialisation
156      !-----------------------------------------------------------------------
157      zs(1) =  0.0_wp
158      zp(1) =  0.0_wp
159      zv(1) = -0.5_wp
160      DO jk = 2, kpk-1
161         zs(jk) =  ( pdep(jk  ) - pdep(jk-1) ) &
162            &    / ( pdep(jk+1) - pdep(jk-1) )
163         zp(jk) = zs(jk) * zv(jk-1) + 2.0_wp
164         zv(jk) = ( zs(jk) - 1.0_wp ) / zp(jk)
165      END DO
166 
167      !-----------------------------------------------------------------------
168      ! Solution of the tridiagonal system
169      !-----------------------------------------------------------------------
170 
171      ! Top boundary condition
172      zu(1) = 0.0_wp
173 
174      DO jk = 2, kpk-1
175         za = pdep(jk+1) - pdep(jk-1)
176         zb = pdep(jk+1) - pdep(jk  )
177         zc = pdep(jk  ) - pdep(jk-1)
178 
179         zpa = 6.0_wp / ( zp(jk) * za )
180         zkm = zpa / zc
181         zkp = zpa / zb
182         zk  = - ( zkm + zkp )
183 
184         zu(jk) =  pobsk(jk+1) * zkp  &
185            &    + pobsk(jk  ) * zk   &
186            &    + pobsk(jk-1) * zkm  &
187            &    + zu(jk-1) * ( -zs(jk) / zp(jk) )
188      END DO
189 
190      !-----------------------------------------------------------------------
191      ! Second derivative
192      !-----------------------------------------------------------------------
193      pobs2k(kpk) = 0.0_wp
194 
195      ! Bottom boundary condition
196      DO jk = kpk-1, 1, -1
197         pobs2k(jk) = zv(jk) * pobs2k(jk+1) + zu(jk)
198         IF ( pobsmask(jk+1) == 0.0_wp ) pobs2k(jk) = 0.0_wp
199      END DO
200 
201  END SUBROUTINE obs_int_z1d_spl
202
203
Note: See TracBrowser for help on using the repository browser.