source: branches/UKMO/dev_r5518_obs_oper_update_icethick/NEMOGCM/NEMO/OPA_SRC/OBS/obs_read_surf.F90 @ 10276

Last change on this file since 10276 was 10276, checked in by emmafiedler, 3 years ago

Freeboard assimilation updates

File size: 20.1 KB
Line 
1MODULE obs_read_surf
2   !!======================================================================
3   !!                       ***  MODULE obs_read_surf  ***
4   !! Observation diagnostics: Read the surface data from feedback files
5   !!======================================================================
6
7   !!----------------------------------------------------------------------
8   !!   obs_rea_surf : Driver for reading surface data from feedback files
9   !!----------------------------------------------------------------------
10
11   !! * Modules used
12   USE par_kind                 ! Precision variables
13   USE in_out_manager           ! I/O manager
14   USE dom_oce                  ! Ocean space and time domain variables
15   USE obs_mpp                  ! MPP support routines for observation diagnostics
16   USE julian                   ! Julian date routines
17   USE obs_utils                ! Observation operator utility functions
18   USE obs_grid                 ! Grid search
19   USE obs_sort                 ! Sorting observation arrays
20   USE obs_surf_def             ! Surface observation definitions
21   USE obs_types                ! Observation type definitions
22   USE obs_fbm                  ! Feedback routines
23   USE netcdf                   ! NetCDF library
24
25   IMPLICIT NONE
26
27   !! * Routine accessibility
28   PRIVATE
29
30   PUBLIC obs_rea_surf      ! Read the surface observations from the point data
31
32   !!----------------------------------------------------------------------
33   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
34   !! $Id$
35   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
36   !!----------------------------------------------------------------------
37
38CONTAINS
39
40   SUBROUTINE obs_rea_surf( surfdata, knumfiles, cdfilenames, &
41      &                     kvars, kextr, kstp, ddobsini, ddobsend, &
42      &                     ldignmis, ldmod, ldnightav )
43      !!---------------------------------------------------------------------
44      !!
45      !!                   *** ROUTINE obs_rea_surf ***
46      !!
47      !! ** Purpose : Read from file the surface data
48      !!
49      !! ** Method  : Read in the data from feedback format files and
50      !!              put into the NEMO internal surface data structure
51      !!
52      !! ** Action  :
53      !!
54      !!
55      !! History : 
56      !!      ! :  2009-01 (K. Mogensen) Initial version based on old versions
57      !!      ! :  2015-02 (M. Martin)   Unify the different surface data type reading.
58      !!----------------------------------------------------------------------
59      !! * Modules used
60
61      !! * Arguments
62      TYPE(obs_surf), INTENT(INOUT) :: &
63         & surfdata                     ! Surface data to be read
64      INTEGER, INTENT(IN) :: knumfiles  ! Number of corio format files to read
65      CHARACTER(LEN=128), INTENT(IN) :: &
66         & cdfilenames(knumfiles)       ! File names to read in
67      INTEGER, INTENT(IN) :: kvars      ! Number of variables in surfdata
68      INTEGER, INTENT(IN) :: kextr      ! Number of extra fields for each var
69      INTEGER, INTENT(IN) :: kstp       ! Ocean time-step index
70      LOGICAL, INTENT(IN) :: ldignmis   ! Ignore missing files
71      LOGICAL, INTENT(IN) :: ldmod      ! Initialize model from input data
72      LOGICAL, INTENT(IN) :: ldnightav  ! Observations represent a night-time average
73      REAL(dp), INTENT(IN) :: ddobsini   ! Obs. ini time in YYYYMMDD.HHMMSS
74      REAL(dp), INTENT(IN) :: ddobsend   ! Obs. end time in YYYYMMDD.HHMMSS
75
76      !! * Local declarations
77      CHARACTER(LEN=11), PARAMETER :: cpname='obs_rea_surf'
78      CHARACTER(len=8) :: clrefdate
79      CHARACTER(len=8), DIMENSION(:), ALLOCATABLE :: clvars
80      INTEGER :: ji
81      INTEGER :: jj
82      INTEGER :: jk
83      INTEGER :: iflag
84      INTEGER :: inobf
85      INTEGER :: i_file_id
86      INTEGER :: inowin
87      INTEGER :: iyea
88      INTEGER :: imon
89      INTEGER :: iday
90      INTEGER :: ihou
91      INTEGER :: imin
92      INTEGER :: isec
93      INTEGER :: itype
94      INTEGER :: iobsmpp
95      INTEGER :: iobs
96      INTEGER :: iobstot
97      INTEGER :: ios
98      INTEGER :: ioserrcount
99      INTEGER :: iextr
100      INTEGER, PARAMETER :: jpsurfmaxtype = 1024
101      INTEGER, DIMENSION(knumfiles) :: irefdate
102      INTEGER, DIMENSION(jpsurfmaxtype+1) :: &
103         & ityp, &
104         & itypmpp
105      INTEGER, DIMENSION(:), ALLOCATABLE :: &
106         & iobsi,    &
107         & iobsj,    &
108         & iproc,    &
109         & iindx,    &
110         & ifileidx, &
111         & isurfidx, &
112         & iadd_std
113      REAL(wp), DIMENSION(:), ALLOCATABLE :: &
114         & zphi, &
115         & zlam
116      REAL(wp), DIMENSION(:), ALLOCATABLE :: &
117         & zdat
118      REAL(wp), DIMENSION(knumfiles) :: &
119         & djulini, &
120         & djulend
121      LOGICAL :: llvalprof
122      TYPE(obfbdata), POINTER, DIMENSION(:) :: &
123         & inpfiles
124
125      ! Local initialization
126      iobs  = 0
127      iextr = kextr
128      !-----------------------------------------------------------------------
129      ! Count the number of files needed and allocate the obfbdata type
130      !-----------------------------------------------------------------------
131
132      inobf = knumfiles
133
134      ALLOCATE( inpfiles(inobf) )
135      ALLOCATE( iadd_std(inobf) )
136
137      surf_files : DO jj = 1, inobf
138
139         !---------------------------------------------------------------------
140         ! Prints
141         !---------------------------------------------------------------------
142         IF(lwp) THEN
143            WRITE(numout,*)
144            WRITE(numout,*) ' obs_rea_surf : Reading from file = ', &
145               & TRIM( TRIM( cdfilenames(jj) ) )
146            WRITE(numout,*) ' ~~~~~~~~~~~'
147            WRITE(numout,*)
148         ENDIF
149
150         !---------------------------------------------------------------------
151         !  Initialization: Open file and get dimensions only
152         !---------------------------------------------------------------------
153
154         iflag = nf90_open( TRIM( TRIM( cdfilenames(jj) ) ), nf90_nowrite, &
155            &                      i_file_id )
156
157         IF ( iflag /= nf90_noerr ) THEN
158
159            IF ( ldignmis ) THEN
160               inpfiles(jj)%nobs = 0
161               CALL ctl_warn( 'File ' // TRIM( TRIM( cdfilenames(jj) ) ) // &
162                  &           ' not found' )
163            ELSE
164               CALL ctl_stop( 'File ' // TRIM( TRIM( cdfilenames(jj) ) ) // &
165                  &           ' not found' )
166            ENDIF
167
168         ELSE 
169
170            !------------------------------------------------------------------
171            !  Close the file since it is opened in read_obfbdata
172            !------------------------------------------------------------------
173
174            iflag = nf90_close( i_file_id )
175
176            !------------------------------------------------------------------
177            !  Read the surface file into inpfiles
178            !------------------------------------------------------------------
179            CALL init_obfbdata( inpfiles(jj) )
180            CALL read_obfbdata( TRIM( cdfilenames(jj) ), inpfiles(jj), &
181               &                ldgrid = .TRUE. )
182
183            IF ( ldmod .AND. ( inpfiles(jj)%nadd == 0 ) ) THEN
184               CALL ctl_stop( 'Model not in input data' )
185               RETURN
186            ENDIF
187
188            IF ( jj == 1 ) THEN
189               ALLOCATE( clvars( inpfiles(jj)%nvar ) )
190               DO ji = 1, inpfiles(jj)%nvar
191                 clvars(ji) = inpfiles(jj)%cname(ji)
192               END DO
193            ELSE
194               DO ji = 1, inpfiles(jj)%nvar
195                  IF ( inpfiles(jj)%cname(ji) /= clvars(ji) ) THEN
196                     CALL ctl_stop( 'Feedback file variables not consistent', &
197                        &           ' with previous files for this type' )
198                  ENDIF
199               END DO
200            ENDIF
201
202            iadd_std(jj) = -1
203            IF ( inpfiles(jj)%nadd > 0 ) THEN
204               DO ji = 1, inpfiles(jj)%nadd
205                  IF ( TRIM( inpfiles(jj)%caddname(ji) ) == 'STD' ) THEN
206                     iextr = kextr + 1
207                     iadd_std(jj) = ji
208                  ENDIF
209               END DO
210            ENDIF
211
212            IF(lwp) THEN
213               IF ( iadd_std(jj) /= -1 ) THEN
214                  WRITE(numout,*) ' STD variable available in input file so passing it through the obs oper'
215                  WRITE(numout,*)
216               ENDIF
217            ENDIF
218
219            !------------------------------------------------------------------
220            !  Change longitude (-180,180)
221            !------------------------------------------------------------------
222
223            DO ji = 1, inpfiles(jj)%nobs
224
225               IF ( inpfiles(jj)%plam(ji) < -180. ) &
226                  &   inpfiles(jj)%plam(ji) = inpfiles(jj)%plam(ji) + 360.
227
228               IF ( inpfiles(jj)%plam(ji) >  180. ) &
229                  &   inpfiles(jj)%plam(ji) = inpfiles(jj)%plam(ji) - 360.
230
231            END DO
232
233            !------------------------------------------------------------------
234            !  Calculate the date  (change eventually)
235            !------------------------------------------------------------------
236            clrefdate=inpfiles(jj)%cdjuldref(1:8)
237            READ(clrefdate,'(I8)') irefdate(jj)
238
239            CALL ddatetoymdhms( ddobsini, iyea, imon, iday, ihou, imin, isec )
240            CALL greg2jul( isec, imin, ihou, iday, imon, iyea, djulini(jj), &
241               &           krefdate = irefdate(jj) )
242            CALL ddatetoymdhms( ddobsend, iyea, imon, iday, ihou, imin, isec )
243            CALL greg2jul( isec, imin, ihou, iday, imon, iyea, djulend(jj), &
244               &           krefdate = irefdate(jj) )
245
246            IF ( ldnightav ) THEN
247
248               IF ( lwp ) THEN
249                  WRITE(numout,*)'Resetting time of night-time averaged observations', &
250                     &             ' to the end of the day'
251               ENDIF
252
253               DO ji = 1, inpfiles(jj)%nobs
254                  !  for night-time averaged data force the time
255                  !  to be the last time-step of the day, but still within the day.
256                  IF ( inpfiles(jj)%ptim(ji) >= 0. ) THEN
257                     inpfiles(jj)%ptim(ji) = &
258                        & INT(inpfiles(jj)%ptim(ji)) + 0.9999
259                  ELSE
260                     inpfiles(jj)%ptim(ji) = &
261                        & INT(inpfiles(jj)%ptim(ji)) - 0.0001
262                  ENDIF
263               END DO
264            ENDIF
265
266            IF ( inpfiles(jj)%nobs > 0 ) THEN
267               inpfiles(jj)%iproc = -1
268               inpfiles(jj)%iobsi = -1
269               inpfiles(jj)%iobsj = -1
270            ENDIF
271            inowin = 0
272            DO ji = 1, inpfiles(jj)%nobs
273               IF ( ( inpfiles(jj)%ptim(ji) >  djulini(jj) ) .AND. &
274                  & ( inpfiles(jj)%ptim(ji) <= djulend(jj) )       ) THEN
275                  inowin = inowin + 1
276               ENDIF
277            END DO
278            ALLOCATE( zlam(inowin)  )
279            ALLOCATE( zphi(inowin)  )
280            ALLOCATE( iobsi(inowin) )
281            ALLOCATE( iobsj(inowin) )
282            ALLOCATE( iproc(inowin) )
283            inowin = 0
284            DO ji = 1, inpfiles(jj)%nobs
285               IF ( ( inpfiles(jj)%ptim(ji) >  djulini(jj) ) .AND. &
286                  & ( inpfiles(jj)%ptim(ji) <= djulend(jj) )       ) THEN
287                  inowin = inowin + 1
288                  zlam(inowin) = inpfiles(jj)%plam(ji)
289                  zphi(inowin) = inpfiles(jj)%pphi(ji)
290               ENDIF
291            END DO
292
293            CALL obs_grid_search( inowin, zlam, zphi, iobsi, iobsj, iproc, 'T' )
294
295            inowin = 0
296            DO ji = 1, inpfiles(jj)%nobs
297               IF ( ( inpfiles(jj)%ptim(ji) >  djulini(jj) ) .AND. &
298                  & ( inpfiles(jj)%ptim(ji) <= djulend(jj) )       ) THEN
299                  inowin = inowin + 1
300                  inpfiles(jj)%iproc(ji,1) = iproc(inowin)
301                  inpfiles(jj)%iobsi(ji,1) = iobsi(inowin)
302                  inpfiles(jj)%iobsj(ji,1) = iobsj(inowin)
303               ENDIF
304            END DO
305            DEALLOCATE( zlam, zphi, iobsi, iobsj, iproc )
306
307            DO ji = 1, inpfiles(jj)%nobs
308               IF ( ( inpfiles(jj)%ptim(ji) >  djulini(jj) ) .AND. &
309                  & ( inpfiles(jj)%ptim(ji) <= djulend(jj) )       ) THEN
310                  IF ( nproc == 0 ) THEN
311                     IF ( inpfiles(jj)%iproc(ji,1) >  nproc ) CYCLE
312                  ELSE
313                     IF ( inpfiles(jj)%iproc(ji,1) /= nproc ) CYCLE
314                  ENDIF
315                  llvalprof = .FALSE.
316                  IF ( .NOT. BTEST(inpfiles(jj)%ivlqc(1,ji,1),2) ) THEN
317                     iobs = iobs + 1
318                  ENDIF
319               ENDIF
320            END DO
321
322         ENDIF
323
324      END DO surf_files
325
326      !-----------------------------------------------------------------------
327      ! Get the time ordered indices of the input data
328      !-----------------------------------------------------------------------
329
330      !---------------------------------------------------------------------
331      !  Loop over input data files to count total number of profiles
332      !---------------------------------------------------------------------
333      iobstot = 0
334      DO jj = 1, inobf
335         DO ji = 1, inpfiles(jj)%nobs
336            IF ( ( inpfiles(jj)%ptim(ji) >  djulini(jj) ) .AND. &
337               & ( inpfiles(jj)%ptim(ji) <= djulend(jj) )       ) THEN
338               iobstot = iobstot + 1
339            ENDIF
340         END DO
341      END DO
342
343      ALLOCATE( iindx(iobstot), ifileidx(iobstot), &
344         &      isurfidx(iobstot), zdat(iobstot) )
345      jk = 0
346      DO jj = 1, inobf
347         DO ji = 1, inpfiles(jj)%nobs
348            IF ( ( inpfiles(jj)%ptim(ji) >  djulini(jj) ) .AND. &
349               & ( inpfiles(jj)%ptim(ji) <= djulend(jj) )       ) THEN
350               jk = jk + 1
351               ifileidx(jk) = jj
352               isurfidx(jk) = ji
353               zdat(jk)     = inpfiles(jj)%ptim(ji)
354            ENDIF
355         END DO
356      END DO
357      CALL sort_dp_indx( iobstot, &
358         &               zdat,     &
359         &               iindx   )
360
361      CALL obs_surf_alloc( surfdata, iobs, kvars, iextr, kstp, jpi, jpj )
362
363      ! Read obs/positions, QC, all variable and assign to surfdata
364
365      iobs = 0
366      surfdata%cvars(:)  = clvars(:)
367      IF ( ldmod .AND. ( TRIM( surfdata%cvars(1) ) == 'SLA' ) ) THEN
368         surfdata%cext(1) = 'SSH'
369         surfdata%cext(2) = 'MDT'
370      ENDIF
371      IF ( ldmod .AND. ( TRIM( surfdata%cvars(1) ) == 'FBD' ) ) THEN
372         surfdata%cext(1) = 'freeboard'
373         surfdata%cext(2) = 'thick_s'
374      ENDIF
375      IF ( iextr > kextr ) surfdata%cext(iextr) = 'STD'
376
377      ityp   (:) = 0
378      itypmpp(:) = 0
379
380      ioserrcount = 0
381
382      DO jk = 1, iobstot
383
384         jj = ifileidx(iindx(jk))
385         ji = isurfidx(iindx(jk))
386         IF ( ( inpfiles(jj)%ptim(ji) >  djulini(jj) ) .AND.  &
387            & ( inpfiles(jj)%ptim(ji) <= djulend(jj) ) ) THEN
388
389            IF ( nproc == 0 ) THEN
390               IF ( inpfiles(jj)%iproc(ji,1) >  nproc ) CYCLE
391            ELSE
392               IF ( inpfiles(jj)%iproc(ji,1) /= nproc ) CYCLE
393            ENDIF
394
395            ! Set observation information
396
397            IF ( .NOT. BTEST(inpfiles(jj)%ivlqc(1,ji,1),2) ) THEN
398
399               iobs = iobs + 1
400
401               CALL jul2greg( isec,                   &
402                  &           imin,                   &
403                  &           ihou,                   &
404                  &           iday,                   &
405                  &           imon,                   &
406                  &           iyea,                   &
407                  &           inpfiles(jj)%ptim(ji), &
408                  &           irefdate(jj) )
409
410
411               ! Surface time coordinates
412               surfdata%nyea(iobs) = iyea
413               surfdata%nmon(iobs) = imon
414               surfdata%nday(iobs) = iday
415               surfdata%nhou(iobs) = ihou
416               surfdata%nmin(iobs) = imin
417
418               ! Surface space coordinates
419               surfdata%rlam(iobs) = inpfiles(jj)%plam(ji)
420               surfdata%rphi(iobs) = inpfiles(jj)%pphi(ji)
421
422               ! Coordinate search parameters
423               surfdata%mi  (iobs) = inpfiles(jj)%iobsi(ji,1)
424               surfdata%mj  (iobs) = inpfiles(jj)%iobsj(ji,1)
425
426               ! WMO number
427               surfdata%cwmo(iobs) = inpfiles(jj)%cdwmo(ji)
428
429               ! Instrument type
430               READ( inpfiles(jj)%cdtyp(ji), '(I4)', IOSTAT = ios, ERR = 901 ) itype
431901            IF ( ios /= 0 ) THEN
432                  IF (ioserrcount == 0) THEN
433                     CALL ctl_warn ( 'Problem converting an instrument type ', &
434                        &            'to integer. Setting type to zero' )
435                  ENDIF
436                  ioserrcount = ioserrcount + 1
437                  itype = 0
438               ENDIF
439               surfdata%ntyp(iobs) = itype
440               IF ( itype < jpsurfmaxtype + 1 ) THEN
441                  ityp(itype+1) = ityp(itype+1) + 1
442               ELSE
443                  IF(lwp)WRITE(numout,*)'WARNING:Increase jpsurfmaxtype in ',&
444                     &                  cpname
445               ENDIF
446
447               ! Bookkeeping data to match observations
448               surfdata%nsidx(iobs) = iobs
449               surfdata%nsfil(iobs) = iindx(jk)
450
451               ! QC flags
452               surfdata%nqc(iobs) = inpfiles(jj)%ivqc(ji,1)
453
454               ! Observed value
455               surfdata%robs(iobs,1) = inpfiles(jj)%pob(1,ji,1)
456               IF ( TRIM(surfdata%cvars(1)) == 'FBD' ) THEN
457                   surfdata%rext(iobs,1) = inpfiles(jj)%pob(1,ji,1)
458                   surfdata%rext(iobs,2) = fbrmdi
459               ENDIF               
460
461               ! Model and MDT is set to fbrmdi unless read from file
462               IF ( ldmod ) THEN
463                  surfdata%rmod(iobs,1) = inpfiles(jj)%padd(1,ji,1,1)
464                  IF ( TRIM(surfdata%cvars(1)) == 'SLA' ) THEN
465                     surfdata%rext(iobs,1) = inpfiles(jj)%padd(1,ji,2,1)
466                     surfdata%rext(iobs,2) = inpfiles(jj)%pext(1,ji,1)
467                  ENDIF
468                ELSE
469                  surfdata%rmod(iobs,1) = fbrmdi
470                  IF ( TRIM(surfdata%cvars(1)) == 'SLA' ) surfdata%rext(iobs,:) = fbrmdi
471               ENDIF
472
473               ! STD (obs error standard deviation) read from file and passed through obs operator
474               IF ( iadd_std(jj) /= -1 ) THEN
475                  surfdata%rext(iobs,iextr) = inpfiles(jj)%padd(1,ji,iadd_std(jj),1)
476               ENDIF
477            ENDIF
478         ENDIF
479
480      END DO
481
482      !-----------------------------------------------------------------------
483      ! Sum up over processors
484      !-----------------------------------------------------------------------
485
486      CALL obs_mpp_sum_integer( iobs, iobsmpp )
487      CALL obs_mpp_sum_integers( ityp, itypmpp, jpsurfmaxtype + 1 )
488
489      !-----------------------------------------------------------------------
490      ! Output number of observations.
491      !-----------------------------------------------------------------------
492      IF (lwp) THEN
493
494         WRITE(numout,*)
495         WRITE(numout,'(1X,A)')TRIM( surfdata%cvars(1) )//' data'
496         WRITE(numout,'(1X,A)')'--------------'
497         DO jj = 1,8
498            IF ( itypmpp(jj) > 0 ) THEN
499               WRITE(numout,'(1X,A4,I4,A3,I10)')'Type ', jj,' = ',itypmpp(jj)
500            ENDIF
501         END DO
502         WRITE(numout,'(1X,A)') &
503            & '---------------------------------------------------------------'
504         WRITE(numout,'(1X,A,I8)') &
505            & 'Total data for variable '//TRIM( surfdata%cvars(1) )// &
506            & '           = ', iobsmpp
507         WRITE(numout,'(1X,A)') &
508            & '---------------------------------------------------------------'
509         WRITE(numout,*)
510
511      ENDIF
512
513      !-----------------------------------------------------------------------
514      ! Deallocate temporary data
515      !-----------------------------------------------------------------------
516      DEALLOCATE( ifileidx, isurfidx, zdat, clvars )
517
518      !-----------------------------------------------------------------------
519      ! Deallocate input data
520      !-----------------------------------------------------------------------
521      DO jj = 1, inobf
522         IF ( inpfiles(jj)%lalloc ) THEN
523            CALL dealloc_obfbdata( inpfiles(jj) )
524         ENDIF
525      END DO
526      DEALLOCATE( inpfiles )
527      DEALLOCATE( iadd_std )
528
529   END SUBROUTINE obs_rea_surf
530
531END MODULE obs_read_surf
Note: See TracBrowser for help on using the repository browser.