New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

restart.F90 in branches/UKMO/dev_r7573_xios_write/NEMOGCM/NEMO/OPA_SRC/IOM – NEMO

Context Navigation

source: branches/UKMO/dev_r7573_xios_write/NEMOGCM/NEMO/OPA_SRC/IOM/restart.F90 @ 8299

Last change on this file since 8299 was 8299, checked in by andmirek, 6 years ago
#1882 no need to define context in iodef.xml
File size: 18.1 KB

Line
1	MODULE restart
2	!!======================================================================
3	!! * MODULE restart *
4	!! Ocean restart : write the ocean restart file
5	!!======================================================================
6	!! History : OPA ! 1999-11 (M. Imbard) Original code
7	!! NEMO 1.0 ! 2002-08 (G. Madec) F90: Free form
8	!! 2.0 ! 2006-07 (S. Masson) use IOM for restart
9	!! 3.3 ! 2010-04 (M. Leclair, G. Madec) modified LF-RA
10	!! - - ! 2010-10 (C. Ethe, G. Madec) TRC-TRA merge (T-S in 4D)
11	!!----------------------------------------------------------------------
12
13	!!----------------------------------------------------------------------
14	!! rst_opn : open the ocean restart file
15	!! rst_write : write the ocean restart file
16	!! rst_read : read the ocean restart file
17	!!----------------------------------------------------------------------
18	USE oce ! ocean dynamics and tracers
19	USE dom_oce ! ocean space and time domain
20	USE phycst ! physical constants
21	USE in_out_manager ! I/O manager
22	USE iom ! I/O module
23	USE ioipsl, ONLY : ju2ymds ! for calendar
24	USE eosbn2 ! equation of state (eos bn2 routine)
25	USE trdmxl_oce ! ocean active mixed layer tracers trends variables
26	USE divcur ! hor. divergence and curl (div & cur routines)
27	USE sbc_oce ! for icesheet freshwater input variables
28	USE iom_def, ONLY : lwxios
29
30	IMPLICIT NONE
31	PRIVATE
32
33	PUBLIC rst_opn ! routine called by step module
34	PUBLIC rst_write ! routine called by step module
35	PUBLIC rst_read ! routine called by istate module
36	PUBLIC rst_read_open ! routine called in rst_read and (possibly) in dom_vvl_init
37
38	!! * Substitutions
39	# include "domzgr_substitute.h90"
40	# include "vectopt_loop_substitute.h90"
41	!!----------------------------------------------------------------------
42	!! NEMO/OPA 3.3 , NEMO Consortium (2010)
43	!! $Id$
44	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
45	!!----------------------------------------------------------------------
46	CONTAINS
47
48	SUBROUTINE rst_opn( kt )
49	!!---------------------------------------------------------------------
50	!! * ROUTINE rst_opn *
51	!!
52	!! ** Purpose : + initialization (should be read in the namelist) of nitrst
53	!! + open the restart when we are one time step before nitrst
54	!! - restart header is defined when kt = nitrst-1
55	!! - restart data are written when kt = nitrst
56	!! + define lrst_oce to .TRUE. when we need to define or write the restart
57	!!----------------------------------------------------------------------
58	INTEGER, INTENT(in) :: kt ! ocean time-step
59	INTEGER :: iyear, imonth, iday
60	REAL (wp) :: zsec
61	REAL (wp) :: zfjulday
62	!!
63	CHARACTER(LEN=20) :: clkt ! ocean time-step deine as a character
64	CHARACTER(LEN=50) :: clname ! ocean output restart file name
65	CHARACTER(LEN=150) :: clpath ! full path to ocean output restart file
66	!!----------------------------------------------------------------------
67	!
68
69	IF( kt == nit000 ) THEN ! default definitions
70	lrst_oce = .FALSE.
71	IF( ln_rst_list ) THEN
72	nrst_lst = 1
73	nitrst = nstocklist( nrst_lst )
74	ELSE
75	nitrst = nitend
76	ENDIF
77	ENDIF
78
79	! frequency-based restart dumping (nn_stock)
80	IF( .NOT. ln_rst_list .AND. MOD( kt - 1, nstock ) == 0 ) THEN
81	! we use kt - 1 and not kt - nit000 to keep the same periodicity from the beginning of the experiment
82	nitrst = kt + nstock - 1 ! define the next value of nitrst for restart writing
83	IF( nitrst > nitend ) nitrst = nitend ! make sure we write a restart at the end of the run
84	ENDIF
85	! to get better performances with NetCDF format:
86	! we open and define the ocean restart file one time step before writing the data (-> at nitrst - 1)
87	! except if we write ocean restart files every time step or if an ocean restart file was writen at nitend - 1
88	! NO, because the data is written 2 times on nitrst - 1 and nitrst
89	IF( kt == nitrst - 1 .OR. nstock == 1 .OR. ( kt == nitend .AND. .NOT. lrst_oce ) ) THEN
90	IF( nitrst <= nitend .AND. nitrst > 0 ) THEN
91	IF ( ln_rstdate ) THEN
92	zfjulday = fjulday + rdttra(1) / rday
93	IF( ABS(zfjulday - REAL(NINT(zfjulday),wp)) < 0.1 / rday ) zfjulday = REAL(NINT(zfjulday),wp) ! avoid truncation error
94	CALL ju2ymds( zfjulday, iyear, imonth, iday, zsec )
95	WRITE(clkt, '(i4.4,2i2.2)') iyear, imonth, iday
96	ELSE
97	! beware of the format used to write kt (default is i8.8, that should be large enough...)
98	IF( nitrst > 999999999 ) THEN ; WRITE(clkt, * ) nitrst
99	ELSE ; WRITE(clkt, '(i8.8)') nitrst
100	ENDIF
101	ENDIF
102	! create the file
103	clname = TRIM(cexper)//"_"//TRIM(ADJUSTL(clkt))//"_"//TRIM(cn_ocerst_out)
104	clpath = TRIM(cn_ocerst_outdir)
105	IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
106	IF(lwp) THEN
107	WRITE(numout,*)
108	IF(lwxios) THEN
109	WRITE(numout,*) &
110	' XIOS open ocean restart NetCDF file: ',TRIM(clpath)//TRIM(clname)
111	ELSE
112	SELECT CASE ( jprstlib )
113	CASE ( jprstdimg ) ; WRITE(numout,*) &
114	' open ocean restart binary file: ',TRIM(clpath)//TRIM(clname)
115	CASE DEFAULT ; WRITE(numout,*) &
116	' open ocean restart NetCDF file: ',TRIM(clpath)//TRIM(clname)
117	END SELECT
118	IF ( snc4set%luse ) WRITE(numout,*) ' opened for NetCDF4 chunking and compression'
119	IF( kt == nitrst - 1 ) THEN ; WRITE(numout,*) ' kt = nitrst - 1 = ', kt
120	ELSE ; WRITE(numout,*) ' kt = ' , kt
121	ENDIF
122	ENDIF
123	ENDIF
124	!
125	IF(.NOT.lwxios) THEN
126	CALL iom_open( TRIM(clpath)//TRIM(clname), numrow, ldwrt = .TRUE., kiolib = jprstlib )
127	ELSE
128	wxios_context = "rstw_"//TRIM(ADJUSTL(clkt))
129	CALL iom_rstw_init( wxios_context, TRIM(clpath)//TRIM(clname) )
130	CALL xios_update_calendar(nitrst)
131	CALL iom_swap( cxios_context )
132	ENDIF
133	lrst_oce = .TRUE.
134	ENDIF
135	ENDIF
136
137	!
138	END SUBROUTINE rst_opn
139
140
141	SUBROUTINE rst_write( kt )
142	!!---------------------------------------------------------------------
143	!! * ROUTINE rstwrite *
144	!!
145	!! ** Purpose : Write restart fields in the format corresponding to jprstlib
146	!!
147	!! ** Method : Write in numrow when kt == nitrst in NetCDF
148	!! file, save fields which are necessary for restart
149	!!----------------------------------------------------------------------
150	INTEGER, INTENT(in) :: kt ! ocean time-step
151	!!----------------------------------------------------------------------
152	IF(lwxios) CALL iom_swap( wxios_context )
153	CALL iom_rstput( kt, nitrst, numrow, 'rdt' , rdt , lxios = lwxios) ! dynamics time step
154	CALL iom_rstput( kt, nitrst, numrow, 'rdttra1', rdttra(1) , lxios = lwxios) ! surface tracer time step
155
156	CALL iom_rstput( kt, nitrst, numrow, 'ub' , ub , lxios = lwxios) ! before fields
157	CALL iom_rstput( kt, nitrst, numrow, 'vb' , vb , lxios = lwxios)
158	CALL iom_rstput( kt, nitrst, numrow, 'tb' , tsb(:,:,:,jp_tem) , lxios = lwxios)
159	CALL iom_rstput( kt, nitrst, numrow, 'sb' , tsb(:,:,:,jp_sal) , lxios = lwxios)
160	CALL iom_rstput( kt, nitrst, numrow, 'rotb' , rotb , lxios = lwxios)
161	CALL iom_rstput( kt, nitrst, numrow, 'hdivb' , hdivb , lxios = lwxios)
162	CALL iom_rstput( kt, nitrst, numrow, 'sshb' , sshb , lxios = lwxios)
163	!
164	CALL iom_rstput( kt, nitrst, numrow, 'un' , un , lxios = lwxios) ! now fields
165	CALL iom_rstput( kt, nitrst, numrow, 'vn' , vn , lxios = lwxios)
166	CALL iom_rstput( kt, nitrst, numrow, 'tn' , tsn(:,:,:,jp_tem) , lxios = lwxios)
167	CALL iom_rstput( kt, nitrst, numrow, 'sn' , tsn(:,:,:,jp_sal) , lxios = lwxios)
168	CALL iom_rstput( kt, nitrst, numrow, 'rotn' , rotn , lxios = lwxios)
169	CALL iom_rstput( kt, nitrst, numrow, 'hdivn' , hdivn , lxios = lwxios)
170	CALL iom_rstput( kt, nitrst, numrow, 'sshn' , sshn , lxios = lwxios)
171	CALL iom_rstput( kt, nitrst, numrow, 'rhop' , rhop , lxios = lwxios)
172	#if defined key_zdfkpp
173	CALL iom_rstput( kt, nitrst, numrow, 'rhd' , rhd , lxios = lwxios)
174	#endif
175	IF( lk_oasis) THEN
176	! ln_coupled_iceshelf_fluxes uninitialised unless lk_oasis=true
177	IF( ln_coupled_iceshelf_fluxes ) THEN
178	CALL iom_rstput( kt, nitrst, numrow, 'greenland_icesheet_mass', greenland_icesheet_mass ,&
179	& lxios = lwxios)
180	CALL iom_rstput( kt, nitrst, numrow, 'greenland_icesheet_timelapsed', greenland_icesheet_timelapsed ,&
181	& lxios = lwxios)
182	CALL iom_rstput( kt, nitrst, numrow, 'greenland_icesheet_mass_roc', greenland_icesheet_mass_rate_of_change ,&
183	& lxios = lwxios)
184	CALL iom_rstput( kt, nitrst, numrow, 'antarctica_icesheet_mass', antarctica_icesheet_mass , &
185	& lxios = lwxios)
186	CALL iom_rstput( kt, nitrst, numrow, 'antarctica_icesheet_timelapsed', antarctica_icesheet_timelapsed ,&
187	& lxios = lwxios)
188	CALL iom_rstput( kt, nitrst, numrow, 'antarctica_icesheet_mass_roc', &
189	& antarctica_icesheet_mass_rate_of_change , lxios = lwxios)
190	ENDIF
191	ENDIF
192
193	IF( kt == nitrst ) THEN
194	IF(.NOT.lwxios) THEN
195	CALL iom_close( numrow ) ! close the restart file (only at last time step)
196	ELSE
197	CALL iom_context_finalize( wxios_context )
198	CALL iom_swap( cxios_context )
199	ENDIF
200	!!gm IF( .NOT. lk_trdmld ) lrst_oce = .FALSE.
201	!!gm not sure what to do here ===>>> ask to Sebastian
202	lrst_oce = .FALSE.
203	IF( ln_rst_list ) THEN
204	nrst_lst = MIN(nrst_lst + 1, SIZE(nstocklist,1))
205	nitrst = nstocklist( nrst_lst )
206	ENDIF
207	ENDIF
208	!
209	END SUBROUTINE rst_write
210
211
212	SUBROUTINE rst_read_open
213	!!----------------------------------------------------------------------
214	!! * ROUTINE rst_read_open *
215	!!
216	!! ** Purpose : Open read files for restart (format fixed by jprstlib )
217	!!
218	!! ** Method : Use a non-zero, positive value of numror to assess whether or not
219	!! the file has already been opened
220	!!----------------------------------------------------------------------
221	INTEGER :: jlibalt = jprstlib
222	LOGICAL :: llok
223	CHARACTER(lc) :: clpath ! full path to ocean output restart file
224	!!----------------------------------------------------------------------
225	!
226	IF( numror <= 0 ) THEN
227	IF(lwp) THEN ! Contol prints
228	WRITE(numout,*)
229	SELECT CASE ( jprstlib )
230	CASE ( jpnf90 ) ; WRITE(numout,*) 'rst_read : read oce NetCDF restart file'
231	CASE ( jprstdimg ) ; WRITE(numout,*) 'rst_read : read oce binary restart file'
232	END SELECT
233	IF ( snc4set%luse ) WRITE(numout,*) 'rst_read : configured with NetCDF4 support'
234	WRITE(numout,*) '~~~~~~~~'
235	ENDIF
236
237	clpath = TRIM(cn_ocerst_indir)
238	IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
239	IF ( jprstlib == jprstdimg ) THEN
240	! eventually read netcdf file (monobloc) for restarting on different number of processors
241	! if {cn_ocerst_in}.nc exists, then set jlibalt to jpnf90
242	INQUIRE( FILE = TRIM(cn_ocerst_indir)//'/'//TRIM(cn_ocerst_in)//'.nc', EXIST = llok )
243	IF ( llok ) THEN ; jlibalt = jpnf90 ; ELSE ; jlibalt = jprstlib ; ENDIF
244	ENDIF
245	CALL iom_open( TRIM(clpath)//cn_ocerst_in, numror, kiolib = jlibalt )
246	ENDIF
247	END SUBROUTINE rst_read_open
248
249	SUBROUTINE rst_read
250	!!----------------------------------------------------------------------
251	!! * ROUTINE rst_read *
252	!!
253	!! ** Purpose : Read files for restart (format fixed by jprstlib )
254	!!
255	!! ** Method : Read in restart.nc file fields which are necessary for restart
256	!!----------------------------------------------------------------------
257	REAL(wp) :: zrdt, zrdttra1
258	INTEGER :: jk
259	LOGICAL :: llok
260	!!----------------------------------------------------------------------
261
262	CALL rst_read_open ! open restart for reading (if not already opened)
263
264	! Check dynamics and tracer time-step consistency and force Euler restart if changed
265	IF( iom_varid( numror, 'rdt', ldstop = .FALSE. ) > 0 ) THEN
266	CALL iom_get( numror, 'rdt', zrdt )
267	IF( zrdt /= rdt ) neuler = 0
268	ENDIF
269	IF( iom_varid( numror, 'rdttra1', ldstop = .FALSE. ) > 0 ) THEN
270	CALL iom_get( numror, 'rdttra1', zrdttra1 )
271	IF( zrdttra1 /= rdttra(1) ) neuler = 0
272	ENDIF
273	!
274	IF( iom_varid( numror, 'ub', ldstop = .FALSE. ) > 0 ) THEN
275	CALL iom_get( numror, jpdom_autoglo, 'ub' , ub ) ! before fields
276	CALL iom_get( numror, jpdom_autoglo, 'vb' , vb )
277	CALL iom_get( numror, jpdom_autoglo, 'tb' , tsb(:,:,:,jp_tem) )
278	CALL iom_get( numror, jpdom_autoglo, 'sb' , tsb(:,:,:,jp_sal) )
279	CALL iom_get( numror, jpdom_autoglo, 'rotb' , rotb )
280	CALL iom_get( numror, jpdom_autoglo, 'hdivb' , hdivb )
281	CALL iom_get( numror, jpdom_autoglo, 'sshb' , sshb )
282	ELSE
283	neuler = 0
284	ENDIF
285	!
286	CALL iom_get( numror, jpdom_autoglo, 'un' , un ) ! now fields
287	CALL iom_get( numror, jpdom_autoglo, 'vn' , vn )
288	CALL iom_get( numror, jpdom_autoglo, 'tn' , tsn(:,:,:,jp_tem) )
289	CALL iom_get( numror, jpdom_autoglo, 'sn' , tsn(:,:,:,jp_sal) )
290	CALL iom_get( numror, jpdom_autoglo, 'sshn' , sshn )
291	IF( iom_varid( numror, 'rotn', ldstop = .FALSE. ) > 0 ) THEN
292	CALL iom_get( numror, jpdom_autoglo, 'rotn' , rotn )
293	CALL iom_get( numror, jpdom_autoglo, 'hdivn' , hdivn )
294	ELSE
295	CALL div_cur( 0 ) ! Horizontal divergence & Relative vorticity
296	ENDIF
297	IF( iom_varid( numror, 'rhop', ldstop = .FALSE. ) > 0 ) THEN
298	CALL iom_get( numror, jpdom_autoglo, 'rhop' , rhop ) ! now potential density
299	ELSE
300	CALL eos ( tsn, rhd, rhop, fsdept_n(:,:,:) )
301	ENDIF
302	#if defined key_zdfkpp
303	IF( iom_varid( numror, 'rhd', ldstop = .FALSE. ) > 0 ) THEN
304	CALL iom_get( numror, jpdom_autoglo, 'rhd' , rhd ) ! now in situ density anomaly
305	ELSE
306	CALL eos( tsn, rhd, fsdept_n(:,:,:) ) ! compute rhd
307	ENDIF
308	#endif
309	!
310	IF( iom_varid( numror, 'greenland_icesheet_mass', ldstop = .FALSE. ) > 0 ) THEN
311	CALL iom_get( numror, 'greenland_icesheet_mass', greenland_icesheet_mass )
312	CALL iom_get( numror, 'greenland_icesheet_timelapsed', greenland_icesheet_timelapsed )
313	CALL iom_get( numror, 'greenland_icesheet_mass_roc', greenland_icesheet_mass_rate_of_change )
314	ELSE
315	greenland_icesheet_mass = 0.0
316	greenland_icesheet_mass_rate_of_change = 0.0
317	greenland_icesheet_timelapsed = 0.0
318	ENDIF
319	IF( iom_varid( numror, 'antarctica_icesheet_mass', ldstop = .FALSE. ) > 0 ) THEN
320	CALL iom_get( numror, 'antarctica_icesheet_mass', antarctica_icesheet_mass )
321	CALL iom_get( numror, 'antarctica_icesheet_timelapsed', antarctica_icesheet_timelapsed )
322	CALL iom_get( numror, 'antarctica_icesheet_mass_roc', antarctica_icesheet_mass_rate_of_change )
323	ELSE
324	antarctica_icesheet_mass = 0.0
325	antarctica_icesheet_mass_rate_of_change = 0.0
326	antarctica_icesheet_timelapsed = 0.0
327	ENDIF
328
329	IF( neuler == 0 ) THEN ! Euler restart (neuler=0)
330	tsb (:,:,:,:) = tsn (:,:,:,:) ! all before fields set to now values
331	ub (:,:,:) = un (:,:,:)
332	vb (:,:,:) = vn (:,:,:)
333	rotb (:,:,:) = rotn (:,:,:)
334	hdivb(:,:,:) = hdivn(:,:,:)
335	sshb (:,:) = sshn (:,:)
336
337	IF( lk_vvl ) THEN
338	DO jk = 1, jpk
339	fse3t_b(:,:,jk) = fse3t_n(:,:,jk)
340	END DO
341	ENDIF
342
343	ENDIF
344	!
345	END SUBROUTINE rst_read
346	!!=====================================================================
347	END MODULE restart

Note: See TracBrowser for help on using the repository browser.

Download in other formats: