New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
cpl_oasis3.F90 in branches/UKMO/r5936_hadgem3_mct/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/UKMO/r5936_hadgem3_mct/NEMOGCM/NEMO/OPA_SRC/SBC/cpl_oasis3.F90 @ 7129

Last change on this file since 7129 was 7129, checked in by jcastill, 7 years ago

As in UKMO/dev_r5107_hadgem3_mct@5631

File size: 28.7 KB
Line 
1MODULE cpl_oasis3
2   !!======================================================================
3   !!                    ***  MODULE cpl_oasis  ***
4   !! Coupled O/A : coupled ocean-atmosphere case using OASIS3-MCT
5   !!=====================================================================
6   !! History :  1.0  !  2004-06  (R. Redler, NEC Laboratories Europe, Germany) Original code
7   !!             -   !  2004-11  (R. Redler, NEC Laboratories Europe; N. Keenlyside, W. Park, IFM-GEOMAR, Germany) revision
8   !!             -   !  2004-11  (V. Gayler, MPI M&D) Grid writing
9   !!            2.0  !  2005-08  (R. Redler, W. Park) frld initialization, paral(2) revision
10   !!             -   !  2005-09  (R. Redler) extended to allow for communication over root only
11   !!             -   !  2006-01  (W. Park) modification of physical part
12   !!             -   !  2006-02  (R. Redler, W. Park) buffer array fix for root exchange
13   !!            3.4  !  2011-11  (C. Harris) Changes to allow mutiple category fields
14   !!            3.6  !  2014-11  (S. Masson) OASIS3-MCT
15   !!----------------------------------------------------------------------
16   
17   !!----------------------------------------------------------------------
18   !!   'key_oasis3'                    coupled Ocean/Atmosphere via OASIS3-MCT
19   !!   'key_oa3mct_v3'                 to be added for OASIS3-MCT version 3
20   !!----------------------------------------------------------------------
21   !!   cpl_init     : initialization of coupled mode communication
22   !!   cpl_define   : definition of grid and fields
23   !!   cpl_snd      : snd out fields in coupled mode
24   !!   cpl_rcv      : receive fields in coupled mode
25   !!   cpl_finalize : finalize the coupled mode communication
26   !!----------------------------------------------------------------------
27#if defined key_oasis3 || defined key_oasis3mct
28   USE mod_oasis                    ! OASIS3-MCT module
29#endif
30   USE par_oce                      ! ocean parameters
31   USE dom_oce                      ! ocean space and time domain
32   USE in_out_manager               ! I/O manager
33   USE lbclnk                       ! ocean lateral boundary conditions (or mpp link)
34
35#if defined key_cpl_rootexchg 
36   USE lib_mpp, only : mppsync 
37   USE lib_mpp, only : mppscatter,mppgather 
38#endif 
39
40   IMPLICIT NONE
41   PRIVATE
42
43   PUBLIC   cpl_init
44   PUBLIC   cpl_define
45   PUBLIC   cpl_snd
46   PUBLIC   cpl_rcv
47   PUBLIC   cpl_freq
48   PUBLIC   cpl_finalize
49#if defined key_mpp_mpi 
50   INCLUDE 'mpif.h' 
51#endif
52   
53   INTEGER, PARAMETER         :: localRoot  = 0 
54   LOGICAL                    :: commRank            ! true for ranks doing OASIS communication
55#if defined key_cpl_rootexchg 
56   LOGICAL                    :: rootexchg =.true.   ! logical switch 
57#else
58   LOGICAL                    :: rootexchg =.false.  ! logical switch 
59#endif 
60
61   INTEGER, PUBLIC            ::   OASIS_Rcv  = 1    !: return code if received field
62   INTEGER, PUBLIC            ::   OASIS_idle = 0    !: return code if nothing done by oasis
63   INTEGER                    ::   ncomp_id          ! id returned by oasis_init_comp
64   INTEGER                    ::   nerror            ! return error code
65#if ! defined key_oasis3 && ! defined key_oasis3mct
66   ! OASIS Variables not used. defined only for compilation purpose
67   INTEGER                    ::   OASIS_Out         = -1
68   INTEGER                    ::   OASIS_REAL        = -1
69   INTEGER                    ::   OASIS_Ok          = -1
70   INTEGER                    ::   OASIS_In          = -1
71   INTEGER                    ::   OASIS_Sent        = -1
72   INTEGER                    ::   OASIS_SentOut     = -1
73   INTEGER                    ::   OASIS_ToRest      = -1
74   INTEGER                    ::   OASIS_ToRestOut   = -1
75   INTEGER                    ::   OASIS_Recvd       = -1
76   INTEGER                    ::   OASIS_RecvOut     = -1
77   INTEGER                    ::   OASIS_FromRest    = -1
78   INTEGER                    ::   OASIS_FromRestOut = -1
79#endif
80
81   INTEGER                    ::   nrcv         ! total number of fields received
82   INTEGER                    ::   nsnd         ! total number of fields sent
83   INTEGER                    ::   ncplmodel    ! Maximum number of models to/from which NEMO is potentialy sending/receiving data
84   INTEGER, PUBLIC, PARAMETER ::   nmaxfld=50   ! Maximum number of coupling fields
85   INTEGER, PUBLIC, PARAMETER ::   nmaxcat=5    ! Maximum number of coupling fields
86   INTEGER, PUBLIC, PARAMETER ::   nmaxcpl=5    ! Maximum number of coupling fields
87   
88   TYPE, PUBLIC ::   FLD_CPL               !: Type for coupling field information
89      LOGICAL               ::   laction   ! To be coupled or not
90      CHARACTER(len = 8)    ::   clname    ! Name of the coupling field   
91      CHARACTER(len = 1)    ::   clgrid    ! Grid type 
92      REAL(wp)              ::   nsgn      ! Control of the sign change
93      INTEGER, DIMENSION(nmaxcat,nmaxcpl) ::   nid   ! Id of the field (no more than 9 categories and 9 extrena models)
94      INTEGER               ::   nct       ! Number of categories in field
95      INTEGER               ::   ncplmodel ! Maximum number of models to/from which this variable may be sent/received
96   END TYPE FLD_CPL
97
98   TYPE(FLD_CPL), DIMENSION(nmaxfld), PUBLIC ::   srcv, ssnd   !: Coupling fields
99
100   REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   exfld   ! Temporary buffer for receiving
101   REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   tbuf  ! Temporary buffer for sending / receiving 
102   INTEGER, PUBLIC :: localComm 
103
104   !!----------------------------------------------------------------------
105   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
106   !! $Id$
107   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
108   !!----------------------------------------------------------------------
109CONTAINS
110
111   SUBROUTINE cpl_init( cd_modname, kl_comm )
112      !!-------------------------------------------------------------------
113      !!             ***  ROUTINE cpl_init  ***
114      !!
115      !! ** Purpose :   Initialize coupled mode communication for ocean
116      !!    exchange between AGCM, OGCM and COUPLER. (OASIS3 software)
117      !!
118      !! ** Method  :   OASIS3 MPI communication
119      !!--------------------------------------------------------------------
120      CHARACTER(len = *), INTENT(in   ) ::   cd_modname   ! model name as set in namcouple file
121      INTEGER           , INTENT(  out) ::   kl_comm      ! local communicator of the model
122      !!--------------------------------------------------------------------
123
124      ! WARNING: No write in numout in this routine
125      !============================================
126
127      !------------------------------------------------------------------
128      ! 1st Initialize the OASIS system for the application
129      !------------------------------------------------------------------
130      CALL oasis_init_comp ( ncomp_id, TRIM(cd_modname), nerror )
131      IF ( nerror /= OASIS_Ok ) &
132         CALL oasis_abort (ncomp_id, 'cpl_init', 'Failure in oasis_init_comp')
133
134      !------------------------------------------------------------------
135      ! 3rd Get an MPI communicator for OPA local communication
136      !------------------------------------------------------------------
137
138      CALL oasis_get_localcomm ( kl_comm, nerror )
139      IF ( nerror /= OASIS_Ok ) &
140         CALL oasis_abort (ncomp_id, 'cpl_init','Failure in oasis_get_localcomm' )
141      localComm = kl_comm
142      !
143   END SUBROUTINE cpl_init
144
145
146   SUBROUTINE cpl_define( krcv, ksnd, kcplmodel )
147      !!-------------------------------------------------------------------
148      !!             ***  ROUTINE cpl_define  ***
149      !!
150      !! ** Purpose :   Define grid and field information for ocean
151      !!    exchange between AGCM, OGCM and COUPLER. (OASIS3 software)
152      !!
153      !! ** Method  :   OASIS3 MPI communication
154      !!--------------------------------------------------------------------
155      INTEGER, INTENT(in) ::   krcv, ksnd     ! Number of received and sent coupling fields
156      INTEGER, INTENT(in) ::   kcplmodel      ! Maximum number of models to/from which NEMO is potentialy sending/receiving data
157      !
158      INTEGER :: id_part
159      INTEGER :: paral(5)       ! OASIS3 box partition
160      INTEGER :: ishape(2,2)    ! shape of arrays passed to PSMILe
161      INTEGER :: ji,jc,jm       ! local loop indicees
162      CHARACTER(LEN=64) :: zclname
163      CHARACTER(LEN=2) :: cli2
164      !!--------------------------------------------------------------------
165
166      IF(lwp) WRITE(numout,*)
167      IF(lwp) WRITE(numout,*) 'cpl_define : initialization in coupled ocean/atmosphere case'
168      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~~~~'
169      IF(lwp) WRITE(numout,*)
170       
171      commRank = .false. 
172      IF ( rootexchg ) THEN
173         IF ( nproc == localRoot ) commRank = .true. 
174      ELSE
175         commRank = .true. 
176      ENDIF
177
178      ncplmodel = kcplmodel
179      IF( kcplmodel > nmaxcpl ) THEN
180         CALL oasis_abort ( ncomp_id, 'cpl_define', 'ncplmodel is larger than nmaxcpl, increase nmaxcpl')   ;   RETURN
181      ENDIF
182
183      nrcv = krcv
184      IF( nrcv > nmaxfld ) THEN
185         CALL oasis_abort ( ncomp_id, 'cpl_define', 'nrcv is larger than nmaxfld, increase nmaxfld')   ;   RETURN
186      ENDIF
187
188      nsnd = ksnd
189      IF( nsnd > nmaxfld ) THEN
190         CALL oasis_abort ( ncomp_id, 'cpl_define', 'nsnd is larger than nmaxfld, increase nmaxfld')   ;   RETURN
191      ENDIF
192      !
193      ! ... Define the shape for the area that excludes the halo
194      !     For serial configuration (key_mpp_mpi not being active)
195      !     nl* is set to the global values 1 and jp*glo.
196      !
197      ishape(:,1) = (/ 1, nlei-nldi+1 /)
198      ishape(:,2) = (/ 1, nlej-nldj+1 /)
199      !
200      !
201      ! -----------------------------------------------------------------
202      ! ... Define the partition
203      ! -----------------------------------------------------------------
204
205      IF ( rootexchg ) THEN
206 
207         paral(1) = 2              ! box partitioning
208         paral(2) = 0              ! NEMO lower left corner global offset     
209         paral(3) = jpiglo         ! local extent in i 
210         paral(4) = jpjglo         ! local extent in j
211         paral(5) = jpiglo         ! global extent in x
212
213      ELSE 
214     
215      paral(1) = 2                                              ! box partitioning
216      paral(2) = jpiglo * (nldj-1+njmpp-1) + (nldi-1+nimpp-1)   ! NEMO lower left corner global offset   
217      paral(3) = nlei-nldi+1                                    ! local extent in i
218      paral(4) = nlej-nldj+1                                    ! local extent in j
219      paral(5) = jpiglo                                         ! global extent in x
220     
221      IF( ln_ctl ) THEN
222         WRITE(numout,*) ' multiexchg: paral (1:5)', paral
223         WRITE(numout,*) ' multiexchg: jpi, jpj =', jpi, jpj
224         WRITE(numout,*) ' multiexchg: nldi, nlei, nimpp =', nldi, nlei, nimpp
225         WRITE(numout,*) ' multiexchg: nldj, nlej, njmpp =', nldj, nlej, njmpp
226      ENDIF
227     
228      ENDIF
229      IF ( commRank )  CALL oasis_def_partition ( id_part, paral, nerror ) 
230   
231      ! ... Allocate memory for data exchange
232      !
233      ALLOCATE(exfld(paral(3), paral(4)), stat = nerror) 
234      IF( nerror > 0 ) THEN
235         CALL oasis_abort ( ncomp_id, 'cpl_define', 'Failure in allocating exfld')   ;   RETURN
236      ENDIF
237      IF ( rootexchg ) THEN 
238         ! Should possibly use one of the work arrays for tbuf really
239         ALLOCATE(tbuf(jpi, jpj, jpnij), stat = nerror) 
240         IF( nerror > 0 ) THEN
241            CALL oasis_abort ( ncomp_id, 'cpl_define', 'Failure in allocating tbuf') ; RETURN
242         ENDIF
243      ENDIF             
244      !
245      IF (commRank ) THEN 
246      !
247      ! ... Announce send variables.
248      !
249      ssnd(:)%ncplmodel = kcplmodel
250      !
251      DO ji = 1, ksnd
252         IF ( ssnd(ji)%laction ) THEN
253
254            IF( ssnd(ji)%nct > nmaxcat ) THEN
255               CALL oasis_abort ( ncomp_id, 'cpl_define', 'Number of categories of '//   &
256                  &              TRIM(ssnd(ji)%clname)//' is larger than nmaxcat, increase nmaxcat' )
257               RETURN
258            ENDIF
259           
260            DO jc = 1, ssnd(ji)%nct
261               DO jm = 1, kcplmodel
262
263                  IF ( ssnd(ji)%nct .GT. 1 ) THEN
264                     WRITE(cli2,'(i2.2)') jc
265                     zclname = TRIM(ssnd(ji)%clname)//'_cat'//cli2
266                  ELSE
267                     zclname = ssnd(ji)%clname
268                  ENDIF
269                  IF ( kcplmodel  > 1 ) THEN
270                     WRITE(cli2,'(i2.2)') jm
271                     zclname = 'model'//cli2//'_'//TRIM(zclname)
272                  ENDIF
273#if defined key_agrif
274                  IF( agrif_fixed() /= 0 ) THEN
275                     zclname=TRIM(Agrif_CFixed())//'_'//TRIM(zclname)
276                  END IF
277#endif
278                  IF( ln_ctl ) WRITE(numout,*) "Define", ji, jc, jm, " "//TRIM(zclname), " for ", OASIS_Out
279                  CALL oasis_def_var (ssnd(ji)%nid(jc,jm), zclname, id_part   , (/ 2, 0 /),   &
280                     &                OASIS_Out          , ishape , OASIS_REAL, nerror )
281                  IF ( nerror /= OASIS_Ok ) THEN
282                     WRITE(numout,*) 'Failed to define transient ', ji, jc, jm, " "//TRIM(zclname)
283                     CALL oasis_abort ( ssnd(ji)%nid(jc,jm), 'cpl_define', 'Failure in oasis_def_var' )
284                  ENDIF
285                  IF( ln_ctl .AND. ssnd(ji)%nid(jc,jm) /= -1 ) WRITE(numout,*) "variable defined in the namcouple"
286                  IF( ln_ctl .AND. ssnd(ji)%nid(jc,jm) == -1 ) WRITE(numout,*) "variable NOT defined in the namcouple"
287               END DO
288            END DO
289         ENDIF
290      END DO
291      !
292      ! ... Announce received variables.
293      !
294      srcv(:)%ncplmodel = kcplmodel
295      !
296      DO ji = 1, krcv
297         IF ( srcv(ji)%laction ) THEN
298           
299            IF( srcv(ji)%nct > nmaxcat ) THEN
300               CALL oasis_abort ( ncomp_id, 'cpl_define', 'Number of categories of '//   &
301                  &              TRIM(srcv(ji)%clname)//' is larger than nmaxcat, increase nmaxcat' )
302               RETURN
303            ENDIF
304           
305            DO jc = 1, srcv(ji)%nct
306               DO jm = 1, kcplmodel
307                 
308                  IF ( srcv(ji)%nct .GT. 1 ) THEN
309                     WRITE(cli2,'(i2.2)') jc
310                     zclname = TRIM(srcv(ji)%clname)//'_cat'//cli2
311                  ELSE
312                     zclname = srcv(ji)%clname
313                  ENDIF
314                  IF ( kcplmodel  > 1 ) THEN
315                     WRITE(cli2,'(i2.2)') jm
316                     zclname = 'model'//cli2//'_'//TRIM(zclname)
317                  ENDIF
318#if defined key_agrif
319                  IF( agrif_fixed() /= 0 ) THEN
320                     zclname=TRIM(Agrif_CFixed())//'_'//TRIM(zclname)
321                  END IF
322#endif
323                  IF( ln_ctl ) WRITE(numout,*) "Define", ji, jc, jm, " "//TRIM(zclname), " for ", OASIS_In
324                  CALL oasis_def_var (srcv(ji)%nid(jc,jm), zclname, id_part   , (/ 2, 0 /),   &
325                     &                OASIS_In           , ishape , OASIS_REAL, nerror )
326                  IF ( nerror /= OASIS_Ok ) THEN
327                     WRITE(numout,*) 'Failed to define transient ', ji, jc, jm, " "//TRIM(zclname)
328                     CALL oasis_abort ( srcv(ji)%nid(jc,jm), 'cpl_define', 'Failure in oasis_def_var' )
329                  ENDIF
330                  IF( ln_ctl .AND. srcv(ji)%nid(jc,jm) /= -1 ) WRITE(numout,*) "variable defined in the namcouple"
331                  IF( ln_ctl .AND. srcv(ji)%nid(jc,jm) == -1 ) WRITE(numout,*) "variable NOT defined in the namcouple"
332
333               END DO
334            END DO
335         ENDIF
336      END DO
337      !
338      ENDIF  ! commRank=true
339     
340      !------------------------------------------------------------------
341      ! End of definition phase
342      !------------------------------------------------------------------
343     
344      IF ( commRank ) THEN     
345         CALL oasis_enddef(nerror) 
346         IF( nerror /= OASIS_Ok )   CALL oasis_abort ( ncomp_id, 'cpl_define', 'Failure in oasis_enddef') 
347      ENDIF 
348      !
349   END SUBROUTINE cpl_define
350   
351   
352   SUBROUTINE cpl_snd( kid, kstep, pdata, kinfo )
353      !!---------------------------------------------------------------------
354      !!              ***  ROUTINE cpl_snd  ***
355      !!
356      !! ** Purpose : - At each coupling time-step,this routine sends fields
357      !!      like sst or ice cover to the coupler or remote application.
358      !!----------------------------------------------------------------------
359      INTEGER                   , INTENT(in   ) ::   kid       ! variable index in the array
360      INTEGER                   , INTENT(  out) ::   kinfo     ! OASIS3 info argument
361      INTEGER                   , INTENT(in   ) ::   kstep     ! ocean time-step in seconds
362      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   pdata
363      !!
364      INTEGER                                   ::   jn,jc,jm     ! local loop index
365      !!--------------------------------------------------------------------
366      !
367      ! snd data to OASIS3
368      !
369      DO jc = 1, ssnd(kid)%nct
370         DO jm = 1, ssnd(kid)%ncplmodel
371       
372            IF( ssnd(kid)%nid(jc,jm) /= -1 ) THEN
373               IF ( rootexchg ) THEN 
374                  !
375                  ! collect data on the local root process
376                  !
377                  CALL mppgather (pdata(:,:,jc),localRoot,tbuf) 
378                  CALL mppsync 
379                       
380                  IF ( nproc == localRoot ) THEN
381                     DO jn = 1, jpnij 
382                        exfld(nimppt(jn)-1+nldit(jn):nimppt(jn)+nleit(jn)-1,njmppt(jn)-1+nldjt(jn):njmppt(jn)+nlejt(jn)-1)= & 
383                          tbuf(nldit(jn):nleit(jn),nldjt(jn):nlejt(jn),jn) 
384                     ENDDO 
385                     ! snd data to OASIS3
386                     CALL oasis_put ( ssnd(kid)%nid(jc,jm), kstep, exfld, kinfo ) 
387                  ENDIF
388               ELSE 
389                  ! snd data to OASIS3
390                  CALL oasis_put ( ssnd(kid)%nid(jc,jm), kstep, pdata(nldi:nlei, nldj:nlej,jc), kinfo ) 
391               ENDIF
392               
393               IF ( ln_ctl ) THEN       
394                  IF ( kinfo == OASIS_Sent     .OR. kinfo == OASIS_ToRest .OR.   &
395                     & kinfo == OASIS_SentOut  .OR. kinfo == OASIS_ToRestOut ) THEN
396                     WRITE(numout,*) '****************'
397                     WRITE(numout,*) 'oasis_put: Outgoing ', ssnd(kid)%clname
398                     WRITE(numout,*) 'oasis_put: ivarid ', ssnd(kid)%nid(jc,jm)
399                     WRITE(numout,*) 'oasis_put:  kstep ', kstep
400                     WRITE(numout,*) 'oasis_put:   info ', kinfo
401                     WRITE(numout,*) '     - Minimum value is ', MINVAL(pdata(:,:,jc))
402                     WRITE(numout,*) '     - Maximum value is ', MAXVAL(pdata(:,:,jc))
403                     WRITE(numout,*) '     -     Sum value is ', SUM(pdata(:,:,jc))
404                     WRITE(numout,*) '****************'
405                  ENDIF
406               ENDIF
407               
408            ENDIF
409           
410         ENDDO
411      ENDDO
412      !
413    END SUBROUTINE cpl_snd
414
415
416   SUBROUTINE cpl_rcv( kid, kstep, pdata, pmask, kinfo )
417      !!---------------------------------------------------------------------
418      !!              ***  ROUTINE cpl_rcv  ***
419      !!
420      !! ** Purpose : - At each coupling time-step,this routine receives fields
421      !!      like stresses and fluxes from the coupler or remote application.
422      !!----------------------------------------------------------------------
423      INTEGER                   , INTENT(in   ) ::   kid       ! variable index in the array
424      INTEGER                   , INTENT(in   ) ::   kstep     ! ocean time-step in seconds
425      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pdata     ! IN to keep the value if nothing is done
426      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   pmask     ! coupling mask
427      INTEGER                   , INTENT(  out) ::   kinfo     ! OASIS3 info argument
428      !!
429      INTEGER                                   ::   jn,jc,jm     ! local loop index
430      LOGICAL                                   ::   llaction, llfisrt
431      !!--------------------------------------------------------------------
432      !
433      ! receive local data from OASIS3 on every process
434      !
435      kinfo = OASIS_idle
436      !
437      DO jc = 1, srcv(kid)%nct
438         llfisrt = .TRUE.
439
440         DO jm = 1, srcv(kid)%ncplmodel
441
442            IF( srcv(kid)%nid(jc,jm) /= -1 ) THEN
443               !
444               ! receive data from OASIS3
445               !
446               IF ( commRank )   CALL oasis_get ( srcv(kid)%nid(jc,jm), kstep, exfld, kinfo ) 
447               IF ( rootexchg )  CALL MPI_BCAST ( kinfo, 1, MPI_INTEGER, localRoot, localComm, nerror )
448               
449               llaction =  kinfo == OASIS_Recvd   .OR. kinfo == OASIS_FromRest .OR.   &
450                  &        kinfo == OASIS_RecvOut .OR. kinfo == OASIS_FromRestOut
451               
452               IF ( ln_ctl )   WRITE(numout,*) "llaction, kinfo, kstep, ivarid: " , llaction, kinfo, kstep, srcv(kid)%nid(jc,jm)
453               
454               IF ( llaction ) THEN
455                 
456                  kinfo = OASIS_Rcv
457                  IF( llfisrt ) THEN
458                     IF ( rootexchg ) THEN 
459                        ! distribute data to processes
460                        !
461                        IF ( nproc == localRoot ) THEN
462                           DO jn = 1, jpnij 
463                              tbuf(nldit(jn):nleit(jn),nldjt(jn):nlejt(jn),jn)=          & 
464                              exfld(nimppt(jn)-1+nldit(jn):nimppt(jn)+nleit(jn)-1,njmppt(jn)-1+nldjt(jn):njmppt(jn)+nlejt(jn)-1) 
465                              ! NOTE: we are missing combining this with pmask (see else below)
466                           ENDDO 
467                        ENDIF
468                        CALL mppscatter(tbuf,localRoot,pdata(:,:,jc)) 
469                        CALL mppsync 
470                     ELSE
471                        pdata(nldi:nlei, nldj:nlej, jc) = exfld(:,:) * pmask(nldi:nlei,nldj:nlej,jm) 
472                     ENDIF
473                     llfisrt = .FALSE.
474                  ELSE
475                     pdata(nldi:nlei,nldj:nlej,jc) = pdata(nldi:nlei,nldj:nlej,jc) + exfld(:,:) * pmask(nldi:nlei,nldj:nlej,jm)
476                  ENDIF
477                 
478                  IF ( ln_ctl ) THEN       
479                     WRITE(numout,*) '****************'
480                     WRITE(numout,*) 'oasis_get: Incoming ', srcv(kid)%clname
481                     WRITE(numout,*) 'oasis_get: ivarid '  , srcv(kid)%nid(jc,jm)
482                     WRITE(numout,*) 'oasis_get:   kstep', kstep
483                     WRITE(numout,*) 'oasis_get:   info ', kinfo
484                     WRITE(numout,*) '     - Minimum value is ', MINVAL(pdata(:,:,jc))
485                     WRITE(numout,*) '     - Maximum value is ', MAXVAL(pdata(:,:,jc))
486                     WRITE(numout,*) '     -     Sum value is ', SUM(pdata(:,:,jc))
487                     WRITE(numout,*) '****************'
488                  ENDIF
489                 
490               ENDIF
491               
492            ENDIF
493           
494         ENDDO
495
496         !--- Fill the overlap areas and extra hallows (mpp)
497         !--- check periodicity conditions (all cases)
498         IF( .not. llfisrt )   CALL lbc_lnk( pdata(:,:,jc), srcv(kid)%clgrid, srcv(kid)%nsgn )   
499 
500      ENDDO
501      !
502   END SUBROUTINE cpl_rcv
503
504
505   INTEGER FUNCTION cpl_freq( cdfieldname ) 
506      !!---------------------------------------------------------------------
507      !!              ***  ROUTINE cpl_freq  ***
508      !!
509      !! ** Purpose : - send back the coupling frequency for a particular field
510      !!----------------------------------------------------------------------
511      CHARACTER(len = *), INTENT(in) ::   cdfieldname    ! field name as set in namcouple file
512      !!
513      INTEGER               :: id
514      INTEGER               :: info
515      INTEGER, DIMENSION(1) :: itmp
516      INTEGER               :: ji,jm     ! local loop index
517      INTEGER               :: mop
518      !!----------------------------------------------------------------------
519      cpl_freq = 0   ! defaut definition
520      id = -1        ! defaut definition
521      !
522      DO ji = 1, nsnd
523         IF (ssnd(ji)%laction ) THEN
524            DO jm = 1, ncplmodel
525               IF( ssnd(ji)%nid(1,jm) /= -1 ) THEN
526                  IF( TRIM(cdfieldname) == TRIM(ssnd(ji)%clname) ) THEN
527                     id = ssnd(ji)%nid(1,jm)
528                     mop = OASIS_Out
529                  ENDIF
530               ENDIF
531            ENDDO
532         ENDIF
533      ENDDO
534      DO ji = 1, nrcv
535         IF (srcv(ji)%laction ) THEN
536            DO jm = 1, ncplmodel
537               IF( srcv(ji)%nid(1,jm) /= -1 ) THEN
538                  IF( TRIM(cdfieldname) == TRIM(srcv(ji)%clname) ) THEN
539                     id = srcv(ji)%nid(1,jm)
540                     mop = OASIS_In
541                  ENDIF
542               ENDIF
543            ENDDO
544         ENDIF
545      ENDDO
546      !
547      IF( id /= -1 ) THEN
548#if defined key_oa3mct_v3
549         CALL oasis_get_freqs(id, mop, 1, itmp, info)
550#endif
551#if defined key_oasis3
552         CALL oasis_get_freqs(id,      1, itmp, info)
553#endif
554         cpl_freq = itmp(1)
555#if defined key_oasis3mct
556         cpl_freq = namflddti( id )
557#endif
558      ENDIF
559      !
560   END FUNCTION cpl_freq
561
562
563   SUBROUTINE cpl_finalize
564      !!---------------------------------------------------------------------
565      !!              ***  ROUTINE cpl_finalize  ***
566      !!
567      !! ** Purpose : - Finalizes the coupling. If MPI_init has not been
568      !!      called explicitly before cpl_init it will also close
569      !!      MPI communication.
570      !!----------------------------------------------------------------------
571      !
572      DEALLOCATE( exfld )
573      IF ( rootexchg ) DEALLOCATE ( tbuf )
574      IF (nstop == 0) THEN
575         CALL oasis_terminate( nerror )         
576      ELSE
577         CALL oasis_abort( ncomp_id, "cpl_finalize", "NEMO ABORT STOP" )
578      ENDIF       
579      !
580   END SUBROUTINE cpl_finalize
581
582#if ! defined key_oasis3 && ! defined key_oasis3mct
583
584   !!----------------------------------------------------------------------
585   !!   No OASIS Library          OASIS3 Dummy module...
586   !!----------------------------------------------------------------------
587
588   SUBROUTINE oasis_init_comp(k1,cd1,k2)
589      CHARACTER(*), INTENT(in   ) ::  cd1
590      INTEGER     , INTENT(  out) ::  k1,k2
591      k1 = -1 ; k2 = -1
592      WRITE(numout,*) 'oasis_init_comp: Error you sould not be there...', cd1
593   END SUBROUTINE oasis_init_comp
594
595   SUBROUTINE oasis_abort(k1,cd1,cd2)
596      INTEGER     , INTENT(in   ) ::  k1
597      CHARACTER(*), INTENT(in   ) ::  cd1,cd2
598      WRITE(numout,*) 'oasis_abort: Error you sould not be there...', cd1, cd2
599   END SUBROUTINE oasis_abort
600
601   SUBROUTINE oasis_get_localcomm(k1,k2)
602      INTEGER     , INTENT(  out) ::  k1,k2
603      k1 = -1 ; k2 = -1
604      WRITE(numout,*) 'oasis_get_localcomm: Error you sould not be there...'
605   END SUBROUTINE oasis_get_localcomm
606
607   SUBROUTINE oasis_def_partition(k1,k2,k3)
608      INTEGER     , INTENT(  out) ::  k1,k3
609      INTEGER     , INTENT(in   ) ::  k2(5)
610      k1 = k2(1) ; k3 = k2(5)
611      WRITE(numout,*) 'oasis_def_partition: Error you sould not be there...'
612   END SUBROUTINE oasis_def_partition
613
614   SUBROUTINE oasis_def_var(k1,cd1,k2,k3,k4,k5,k6,k7)
615      CHARACTER(*), INTENT(in   ) ::  cd1
616      INTEGER     , INTENT(in   ) ::  k2,k3(2),k4,k5(2,2),k6
617      INTEGER     , INTENT(  out) ::  k1,k7
618      k1 = -1 ; k7 = -1
619      WRITE(numout,*) 'oasis_def_var: Error you sould not be there...', cd1
620   END SUBROUTINE oasis_def_var
621
622   SUBROUTINE oasis_enddef(k1)
623      INTEGER     , INTENT(  out) ::  k1
624      k1 = -1
625      WRITE(numout,*) 'oasis_enddef: Error you sould not be there...'
626   END SUBROUTINE oasis_enddef
627 
628   SUBROUTINE oasis_put(k1,k2,p1,k3)
629      REAL(wp), DIMENSION(:,:), INTENT(in   ) ::  p1
630      INTEGER                 , INTENT(in   ) ::  k1,k2
631      INTEGER                 , INTENT(  out) ::  k3
632      k3 = -1
633      WRITE(numout,*) 'oasis_put: Error you sould not be there...'
634   END SUBROUTINE oasis_put
635
636   SUBROUTINE oasis_get(k1,k2,p1,k3)
637      REAL(wp), DIMENSION(:,:), INTENT(  out) ::  p1
638      INTEGER                 , INTENT(in   ) ::  k1,k2
639      INTEGER                 , INTENT(  out) ::  k3
640      p1(1,1) = -1. ; k3 = -1
641      WRITE(numout,*) 'oasis_get: Error you sould not be there...'
642   END SUBROUTINE oasis_get
643
644   SUBROUTINE oasis_get_freqs(k1,k2,k3,k4)
645      INTEGER              , INTENT(in   ) ::  k1,k2
646      INTEGER, DIMENSION(1), INTENT(  out) ::  k3
647      INTEGER              , INTENT(  out) ::  k4
648      k3(1) = k1 ; k4 = k2
649      WRITE(numout,*) 'oasis_get_freqs: Error you sould not be there...'
650   END SUBROUTINE oasis_get_freqs
651
652   SUBROUTINE oasis_terminate(k1)
653      INTEGER     , INTENT(  out) ::  k1
654      k1 = -1
655      WRITE(numout,*) 'oasis_terminate: Error you sould not be there...'
656   END SUBROUTINE oasis_terminate
657   
658#endif
659
660   !!=====================================================================
661END MODULE cpl_oasis3
Note: See TracBrowser for help on using the repository browser.