New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcwave.F90 in branches/UKMO/r6232_INGV1_WAVE-coupling/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/UKMO/r6232_INGV1_WAVE-coupling/NEMOGCM/NEMO/OPA_SRC/SBC/sbcwave.F90 @ 7717

Last change on this file since 7717 was 7717, checked in by jcastill, 6 years ago

Add surface drag coefficient direct forcing and coupling

File size: 18.5 KB
Line 
1MODULE sbcwave
2   !!======================================================================
3   !!                       ***  MODULE  sbcwave  ***
4   !! Wave module
5   !!======================================================================
6   !! History :  3.3  !   2011-09  (Adani M)  Original code: Drag Coefficient
7   !!         :  3.4  !   2012-10  (Adani M)                 Stokes Drift
8   !!            3.6  !   2014-09  (Clementi E, Oddo P)New Stokes Drift Computation
9   !!             -   !   2016-12  (G. Madec, E. Clementi) update Stoke drift computation
10   !!                                                     + add sbc_wave_ini routine
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   sbc_stokes    : calculate 3D Stokes-drift velocities
15   !!   sbc_wave      : wave data from wave model in netcdf files
16   !!   sbc_wave_init : initialisation fo surface waves
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean variables
19   USE sbc_oce        ! Surface boundary condition: ocean fields
20   USE zdf_oce,  ONLY : ln_zdfqiao
21   USE bdy_oce        ! open boundary condition variables
22   USE domvvl         ! domain: variable volume layers
23   !
24   USE iom            ! I/O manager library
25   USE in_out_manager ! I/O manager
26   USE lib_mpp        ! distribued memory computing library
27   USE fldread        ! read input fields
28   USE wrk_nemo       !
29   USE phycst         ! physical constants
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   sbc_stokes      ! routine called in sbccpl
35   PUBLIC   sbc_wave        ! routine called in sbcmod
36   PUBLIC   sbc_wave_init   ! routine called in sbcmod
37   
38   ! Variables checking if the wave parameters are coupled (if not, they are read from file)
39   LOGICAL, PUBLIC ::   cpl_hsig   = .FALSE.
40   LOGICAL, PUBLIC ::   cpl_phioc  = .FALSE.
41   LOGICAL, PUBLIC ::   cpl_sdrftx = .FALSE.
42   LOGICAL, PUBLIC ::   cpl_sdrfty = .FALSE.
43   LOGICAL, PUBLIC ::   cpl_wper   = .FALSE.
44   LOGICAL, PUBLIC ::   cpl_wnum   = .FALSE.
45   LOGICAL, PUBLIC ::   cpl_wstrf  = .FALSE.
46   LOGICAL, PUBLIC ::   cpl_wdrag  = .FALSE.
47
48   INTEGER ::   jpfld    ! number of files to read for stokes drift
49   INTEGER ::   jp_usd   ! index of stokes drift  (i-component) (m/s)    at T-point
50   INTEGER ::   jp_vsd   ! index of stokes drift  (j-component) (m/s)    at T-point
51   INTEGER ::   jp_hsw   ! index of significant wave hight      (m)      at T-point
52   INTEGER ::   jp_wmp   ! index of mean wave period            (s)      at T-point
53
54   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::  sf_cd    ! structure of input fields (file informations, fields read) Drag Coefficient
55   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::  sf_sd    ! structure of input fields (file informations, fields read) Stokes Drift
56   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::  sf_wn    ! structure of input fields (file informations, fields read) wave number for Qiao
57   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::  sf_tauoc ! structure of input fields (file informations, fields read) normalized wave stress into the ocean
58   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   cdn_wave            !:
59   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   hsw, wmp, wnum      !:
60   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   tauoc_wave          !:
61   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   tsd2d               !:
62   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   div_sd              !: barotropic stokes drift divergence
63   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   ut0sd, vt0sd        !: surface Stokes drift velocities at t-point
64   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:,:) ::   usd  , vsd  , wsd   !: Stokes drift velocities at u-, v- & w-points, resp.
65
66   INTEGER, PUBLIC            ::   nn_drag       ! type of formula to calculate wind stress from wind components
67   INTEGER, PUBLIC, PARAMETER ::   jp_ukmo = 0        ! UKMO SHELF formulation
68   INTEGER, PUBLIC, PARAMETER ::   jp_std  = 1        ! standard formulation:
69
70   !! * Substitutions
71#  include "vectopt_loop_substitute.h90"
72   !!----------------------------------------------------------------------
73   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
74   !! $Id$
75   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
76   !!----------------------------------------------------------------------
77CONTAINS
78
79   SUBROUTINE sbc_stokes( )
80      !!---------------------------------------------------------------------
81      !!                     ***  ROUTINE sbc_stokes  ***
82      !!
83      !! ** Purpose :   compute the 3d Stokes Drift according to Breivik et al.,
84      !!                2014 (DOI: 10.1175/JPO-D-14-0020.1)
85      !!
86      !! ** Method  : - Calculate Stokes transport speed
87      !!              - Calculate horizontal divergence
88      !!              - Integrate the horizontal divergenze from the bottom
89      !! ** action 
90      !!---------------------------------------------------------------------
91      INTEGER  ::   jj, ji, jk   ! dummy loop argument
92      INTEGER  ::   ik           ! local integer
93      REAL(wp) ::  ztransp, zfac, ztemp
94      REAL(wp) ::  zdep_u, zdep_v, zkh_u, zkh_v, zda_u, zda_v
95      REAL(wp), DIMENSION(:,:)  , POINTER ::   zk_t, zk_u, zk_v, zu0_sd, zv0_sd   ! 2D workspace
96      REAL(wp), DIMENSION(:,:,:), POINTER ::   ze3divh                            ! 3D workspace
97
98      !!---------------------------------------------------------------------
99      !
100
101      CALL wrk_alloc( jpi,jpj,jpk,   ze3divh )
102      CALL wrk_alloc( jpi,jpj,       zk_t, zk_u, zk_v, zu0_sd, zv0_sd ) 
103      !
104      zfac = 2.0_wp * rpi / 16.0_wp
105      DO jj = 1, jpj               ! exp. wave number at t-point    (Eq. (19) in Breivick et al. (2014) )
106         DO ji = 1, jpi
107            ! Stokes drift velocity estimated from Hs and Tmean
108            ztransp = zfac * hsw(ji,jj)*hsw(ji,jj) / MAX( wmp(ji,jj), 0.0000001_wp )
109            ! Stokes surface speed
110            tsd2d(ji,jj) = SQRT( ut0sd(ji,jj)*ut0sd(ji,jj) + vt0sd(ji,jj)*vt0sd(ji,jj))
111            ! Wavenumber scale
112            zk_t(ji,jj) = ABS( tsd2d(ji,jj) ) / MAX( ABS( 5.97_wp*ztransp ), 0.0000001_wp )
113         END DO
114      END DO
115      DO jj = 1, jpjm1              ! exp. wave number & Stokes drift velocity at u- & v-points
116         DO ji = 1, jpim1
117            zk_u(ji,jj) = 0.5_wp * ( zk_t(ji,jj) + zk_t(ji+1,jj) )
118            zk_v(ji,jj) = 0.5_wp * ( zk_t(ji,jj) + zk_t(ji,jj+1) )
119            !
120            zu0_sd(ji,jj) = 0.5_wp * ( ut0sd(ji,jj) + ut0sd(ji+1,jj) )
121            zv0_sd(ji,jj) = 0.5_wp * ( vt0sd(ji,jj) + vt0sd(ji,jj+1) )
122         END DO
123      END DO
124      !
125      !                       !==  horizontal Stokes Drift 3D velocity  ==!
126      DO jk = 1, jpkm1
127         DO jj = 2, jpjm1
128            DO ji = 2, jpim1
129               zdep_u = 0.5_wp * ( gdept_n(ji,jj,jk) + gdept_n(ji+1,jj,jk) )
130               zdep_v = 0.5_wp * ( gdept_n(ji,jj,jk) + gdept_n(ji,jj+1,jk) )
131               !                         
132               zkh_u = zk_u(ji,jj) * zdep_u     ! k * depth
133               zkh_v = zk_v(ji,jj) * zdep_v
134               !                                ! Depth attenuation
135               zda_u = EXP( -2.0_wp*zkh_u ) / ( 1.0_wp + 8.0_wp*zkh_u )
136               zda_v = EXP( -2.0_wp*zkh_v ) / ( 1.0_wp + 8.0_wp*zkh_v )
137               !
138               usd(ji,jj,jk) = zda_u * zk_u(ji,jj) * umask(ji,jj,jk)
139               vsd(ji,jj,jk) = zda_v * zk_v(ji,jj) * vmask(ji,jj,jk)
140            END DO
141         END DO
142      END DO
143      CALL lbc_lnk( usd(:,:,:), 'U', vsd(:,:,:), 'V', -1. )
144      !
145      !                       !==  vertical Stokes Drift 3D velocity  ==!
146      !
147      DO jk = 1, jpkm1               ! Horizontal e3*divergence
148         DO jj = 2, jpj
149            DO ji = fs_2, jpi
150               ze3divh(ji,jj,jk) = (  e2u(ji  ,jj) * e3u_n(ji  ,jj,jk) * usd(ji,  jj,jk)    &
151                  &                 - e2u(ji-1,jj) * e3u_n(ji-1,jj,jk) * usd(ji-1,jj,jk)    &
152                  &                 + e1v(ji,jj  ) * e3v_n(ji,jj  ,jk) * vsd(ji,jj  ,jk)    &
153                  &                 - e1v(ji,jj-1) * e3v_n(ji,jj-1,jk) * vsd(ji,jj-1,jk)  ) * r1_e12t(ji,jj)
154            END DO
155         END DO
156      END DO
157      !
158      IF( .NOT. AGRIF_Root() ) THEN
159         IF( nbondi ==  1 .OR. nbondi == 2 )   ze3divh(nlci-1,   :  ,:) = 0._wp      ! east
160         IF( nbondi == -1 .OR. nbondi == 2 )   ze3divh(  2   ,   :  ,:) = 0._wp      ! west
161         IF( nbondj ==  1 .OR. nbondj == 2 )   ze3divh(  :   ,nlcj-1,:) = 0._wp      ! north
162         IF( nbondj == -1 .OR. nbondj == 2 )   ze3divh(  :   ,  2   ,:) = 0._wp      ! south
163      ENDIF
164      !
165      CALL lbc_lnk( ze3divh, 'T', 1. )
166      !
167      IF( .NOT. lk_vvl ) THEN   ;   ik = 1   ! none zero velocity through the sea surface
168      ELSE                      ;   ik = 2   ! w=0 at the surface (set one for all in sbc_wave_init)
169      ENDIF
170      DO jk = jpkm1, ik, -1          ! integrate from the bottom the hor. divergence (NB: at k=jpk w is always zero)
171         wsd(:,:,jk) = wsd(:,:,jk+1) - ze3divh(:,:,jk)
172      END DO
173#if defined key_bdy
174      IF( lk_bdy ) THEN
175         DO jk = 1, jpkm1
176            wsd(:,:,jk) = wsd(:,:,jk) * bdytmask(:,:)
177         END DO
178      ENDIF
179#endif
180      !                       !==  Horizontal divergence of barotropic Stokes transport  ==!
181      div_sd(:,:) = 0._wp
182      DO jk = 1, jpkm1                                 !
183        div_sd(:,:) = div_sd(:,:) + ze3divh(:,:,jk)
184      END DO
185      !
186      CALL iom_put( "ustokes",  usd  )
187      CALL iom_put( "vstokes",  vsd  )
188      CALL iom_put( "wstokes",  wsd  )
189      !
190      CALL wrk_dealloc( jpi,jpj,jpk,   ze3divh )
191      CALL wrk_dealloc( jpi,jpj,       zk_t, zk_u, zk_v, zu0_sd, zv0_sd )
192      !
193   END SUBROUTINE sbc_stokes
194
195
196   SUBROUTINE sbc_wave( kt )
197      !!---------------------------------------------------------------------
198      !!                     ***  ROUTINE sbc_wave  ***
199      !!
200      !! ** Purpose :   read wave parameters from wave model  in netcdf files.
201      !!
202      !! ** Method  : - Read namelist namsbc_wave
203      !!              - Read Cd_n10 fields in netcdf files
204      !!              - Read stokes drift 2d in netcdf files
205      !!              - Read wave number in netcdf files
206      !!              - Compute 3d stokes drift using Breivik et al.,2014
207      !!                formulation
208      !! ** action 
209      !!---------------------------------------------------------------------
210      INTEGER, INTENT(in   ) ::   kt   ! ocean time step
211      !!---------------------------------------------------------------------
212      !
213      IF( ln_cdgw .AND. .NOT. cpl_wdrag ) THEN     !==  Neutral drag coefficient  ==!
214         CALL fld_read( kt, nn_fsbc, sf_cd )             ! read from external forcing
215         cdn_wave(:,:) = sf_cd(1)%fnow(:,:,1)
216         ! make sure that the interpolation does not write silly fill values in case it fails in a grid point
217         where( cdn_wave > 1.0 ) cdn_wave = 1.5e-3 
218      ENDIF
219
220      IF( ln_tauoc .AND. .NOT. cpl_wstrf ) THEN    !==  Wave induced stress  ==!
221         CALL fld_read( kt, nn_fsbc, sf_tauoc )          ! read wave norm stress from external forcing
222         tauoc_wave(:,:) = sf_tauoc(1)%fnow(:,:,1)
223      ENDIF
224
225      IF( ln_sdw )  THEN                           !==  Computation of the 3d Stokes Drift  ==!
226         !
227         IF( jpfld > 0 ) THEN                            ! Read from file only if the field is not coupled
228            CALL fld_read( kt, nn_fsbc, sf_sd )          ! read wave parameters from external forcing
229            IF( jp_hsw > 0 )   hsw  (:,:) = sf_sd(jp_hsw)%fnow(:,:,1)   ! significant wave height
230            IF( jp_wmp > 0 )   wmp  (:,:) = sf_sd(jp_wmp)%fnow(:,:,1)   ! wave mean period
231            IF( jp_usd > 0 )   ut0sd(:,:) = sf_sd(jp_usd)%fnow(:,:,1)   ! 2D zonal Stokes Drift at T point
232            IF( jp_vsd > 0 )   vt0sd(:,:) = sf_sd(jp_vsd)%fnow(:,:,1)   ! 2D meridional Stokes Drift at T point
233         ENDIF
234         !
235         ! Read also wave number if needed, so that it is available in coupling routines
236         IF( ln_zdfqiao .AND. .NOT.cpl_wnum ) THEN
237            CALL fld_read( kt, nn_fsbc, sf_wn )          ! read wave parameters from external forcing
238            wnum(:,:) = sf_wn(1)%fnow(:,:,1)
239         ENDIF
240           
241         !                                         !==  Computation of the 3d Stokes Drift  ==!
242         !
243         IF( jpfld == 4 )   CALL sbc_stokes()            ! Calculate only if required fields are read
244         !                                               ! In coupled wave model-NEMO case the call is done after coupling
245         !
246      ENDIF
247      !
248   END SUBROUTINE sbc_wave
249
250
251   SUBROUTINE sbc_wave_init
252      !!---------------------------------------------------------------------
253      !!                     ***  ROUTINE sbc_wave_init  ***
254      !!
255      !! ** Purpose :   read wave parameters from wave model  in netcdf files.
256      !!
257      !! ** Method  : - Read namelist namsbc_wave
258      !!              - Read Cd_n10 fields in netcdf files
259      !!              - Read stokes drift 2d in netcdf files
260      !!              - Read wave number in netcdf files
261      !!              - Compute 3d stokes drift using Breivik et al.,2014
262      !!                formulation
263      !! ** action 
264      !!---------------------------------------------------------------------
265      INTEGER ::   ierror, ios   ! local integer
266      INTEGER ::   ifpr
267      !!
268      CHARACTER(len=100)     ::  cn_dir                          ! Root directory for location of drag coefficient files
269      TYPE(FLD_N), ALLOCATABLE, DIMENSION(:) ::   slf_i     ! array of namelist informations on the fields to read
270      TYPE(FLD_N)            ::  sn_cdg, sn_usd, sn_vsd,  &
271                             &   sn_hsw, sn_wmp, sn_wnum, sn_tauoc      ! informations about the fields to be read
272      !
273      NAMELIST/namsbc_wave/  sn_cdg, cn_dir, sn_usd, sn_vsd, sn_hsw, sn_wmp, sn_wnum, sn_tauoc, nn_drag
274      !!---------------------------------------------------------------------
275      !
276      REWIND( numnam_ref )              ! Namelist namsbc_wave in reference namelist : File for drag coeff. from wave model
277      READ  ( numnam_ref, namsbc_wave, IOSTAT = ios, ERR = 901)
278901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_wave in reference namelist', lwp )
279         
280      REWIND( numnam_cfg )              ! Namelist namsbc_wave in configuration namelist : File for drag coeff. from wave model
281      READ  ( numnam_cfg, namsbc_wave, IOSTAT = ios, ERR = 902 )
282902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_wave in configuration namelist', lwp )
283      IF(lwm) WRITE ( numond, namsbc_wave )
284      !
285      IF( ln_cdgw ) THEN
286         ! check the value of nn_drag
287         IF( .NOT. ( nn_drag == jp_ukmo .OR. nn_drag == jp_std )) THEN
288            CALL ctl_stop( 'sbc_wave_init: nn_drag does not specify a valid drag formulation' )
289            RETURN 
290         ENDIF
291           
292         IF( .NOT. cpl_wdrag ) THEN
293            ALLOCATE( sf_cd(1), STAT=ierror )           !* allocate and fill sf_wave with sn_cdg
294            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable to allocate sf_wave structure' )
295            !
296                                   ALLOCATE( sf_cd(1)%fnow(jpi,jpj,1)   )
297            IF( sn_cdg%ln_tint )   ALLOCATE( sf_cd(1)%fdta(jpi,jpj,1,2) )
298            CALL fld_fill( sf_cd, (/ sn_cdg /), cn_dir, 'sbc_wave_init', 'Wave module ', 'namsbc_wave' )
299         ENDIF
300         ALLOCATE( cdn_wave(jpi,jpj) )
301      ENDIF
302
303      IF( ln_tauoc ) THEN
304         IF( .NOT. cpl_wstrf ) THEN
305            ALLOCATE( sf_tauoc(1), STAT=ierror )           !* allocate and fill sf_wave with sn_tauoc
306            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable to allocate sf_wave structure' )
307            !
308                                    ALLOCATE( sf_tauoc(1)%fnow(jpi,jpj,1)   )
309            IF( sn_tauoc%ln_tint )  ALLOCATE( sf_tauoc(1)%fdta(jpi,jpj,1,2) )
310            CALL fld_fill( sf_tauoc, (/ sn_tauoc /), cn_dir, 'sbc_wave_init', 'Wave module', 'namsbc_wave' )
311         ENDIF
312         ALLOCATE( tauoc_wave(jpi,jpj) )
313      ENDIF
314
315      IF( ln_sdw ) THEN   ! Find out how many fields have to be read from file if not coupled
316         jpfld=0
317         jp_usd=0   ;   jp_vsd=0   ;   jp_hsw=0   ;   jp_wmp=0
318         IF( .NOT. cpl_sdrftx ) THEN
319            jpfld  = jpfld + 1
320            jp_usd = jpfld
321         ENDIF
322         IF( .NOT. cpl_sdrfty ) THEN
323            jpfld  = jpfld + 1
324            jp_vsd = jpfld
325         ENDIF
326         IF( .NOT. cpl_hsig ) THEN
327            jpfld  = jpfld + 1
328            jp_hsw = jpfld
329         ENDIF
330         IF( .NOT. cpl_wper ) THEN
331            jpfld  = jpfld + 1
332            jp_wmp = jpfld
333         ENDIF
334
335         ! Read from file only the non-coupled fields
336         IF( jpfld > 0 ) THEN
337            ALLOCATE( slf_i(jpfld) )
338            IF( jp_usd > 0 )   slf_i(jp_usd) = sn_usd
339            IF( jp_vsd > 0 )   slf_i(jp_vsd) = sn_vsd
340            IF( jp_hsw > 0 )   slf_i(jp_hsw) = sn_hsw
341            IF( jp_wmp > 0 )   slf_i(jp_wmp) = sn_wmp
342            ALLOCATE( sf_sd(jpfld), STAT=ierror )   !* allocate and fill sf_sd with stokes drift
343            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable to allocate sf_wave structure' )
344            !
345            DO ifpr= 1, jpfld
346               ALLOCATE( sf_sd(ifpr)%fnow(jpi,jpj,1) )
347               IF( slf_i(ifpr)%ln_tint )   ALLOCATE( sf_sd(ifpr)%fdta(jpi,jpj,1,2) )
348            END DO
349            !
350            CALL fld_fill( sf_sd, slf_i, cn_dir, 'sbc_wave_init', 'Wave module ', 'namsbc_wave' )
351         ENDIF
352         ALLOCATE( usd  (jpi,jpj,jpk), vsd  (jpi,jpj,jpk), wsd(jpi,jpj,jpk) )
353         ALLOCATE( hsw  (jpi,jpj)    , wmp  (jpi,jpj)     )
354         ALLOCATE( ut0sd(jpi,jpj)    , vt0sd(jpi,jpj)     )
355         ALLOCATE( div_sd(jpi,jpj) )
356         ALLOCATE( tsd2d (jpi,jpj) )
357         usd(:,:,:) = 0._wp
358         vsd(:,:,:) = 0._wp
359         wsd(:,:,:) = 0._wp
360         ! Wave number needed only if ln_zdfqiao=T
361         IF( ln_zdfqiao .AND. .NOT.cpl_wnum ) THEN
362            ALLOCATE( sf_wn(1), STAT=ierror )           !* allocate and fill sf_wave with sn_wnum
363            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable toallocate sf_wave structure' )
364                                   ALLOCATE( sf_wn(1)%fnow(jpi,jpj,1)   )
365            IF( sn_wnum%ln_tint )  ALLOCATE( sf_wn(1)%fdta(jpi,jpj,1,2) )
366            CALL fld_fill( sf_wn, (/ sn_wnum /), cn_dir, 'sbc_wave', 'Wave module', 'namsbc_wave' )
367         ENDIF
368         ALLOCATE( wnum(jpi,jpj) )
369      ENDIF
370      !
371   END SUBROUTINE sbc_wave_init
372
373   !!======================================================================
374END MODULE sbcwave
Note: See TracBrowser for help on using the repository browser.