New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcini.F90 in branches/UKMO/v3_6_extra_CMIP6_diagnostics/NEMOGCM/NEMO/TOP_SRC – NEMO

source: branches/UKMO/v3_6_extra_CMIP6_diagnostics/NEMOGCM/NEMO/TOP_SRC/trcini.F90 @ 6550

Last change on this file since 6550 was 6550, checked in by cetlod, 8 years ago

Add an ideal tracer age as a permanent module in TOP, see ticket #1688

File size: 10.0 KB
Line 
1MODULE trcini
2   !!======================================================================
3   !!                         ***  MODULE trcini  ***
4   !! TOP :   Manage the passive tracer initialization
5   !!======================================================================
6   !! History :   -   ! 1991-03 (O. Marti)  original code
7   !!            1.0  ! 2005-03 (O. Aumont, A. El Moussaoui) F90
8   !!            2.0  ! 2005-10 (C. Ethe, G. Madec) revised architecture
9   !!            4.0  ! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation
10   !!----------------------------------------------------------------------
11#if defined key_top
12   !!----------------------------------------------------------------------
13   !!   'key_top'                                                TOP models
14   !!----------------------------------------------------------------------
15   !!   trc_init  :   Initialization for passive tracer
16   !!   top_alloc :   allocate the TOP arrays
17   !!----------------------------------------------------------------------
18   USE oce_trc         ! shared variables between ocean and passive tracers
19   USE trc             ! passive tracers common variables
20   USE trcrst          ! passive tracers restart
21   USE trcnam          ! Namelist read
22   USE trcini_cfc      ! CFC      initialisation
23   USE trcini_pisces   ! PISCES   initialisation
24   USE trcini_c14b     ! C14 bomb initialisation
25   USE trcini_age      ! AGE      initialisation
26   USE trcini_my_trc   ! MY_TRC   initialisation
27   USE trcdta          ! initialisation from files
28   USE daymod          ! calendar manager
29   USE zpshde          ! partial step: hor. derivative   (zps_hde routine)
30   USE prtctl_trc      ! Print control passive tracers (prt_ctl_trc_init routine)
31   USE trcsub          ! variables to substep passive tracers
32   USE lib_mpp         ! distribued memory computing library
33   USE sbc_oce
34   USE trcice          ! tracers in sea ice
35 
36   IMPLICIT NONE
37   PRIVATE
38   
39   PUBLIC   trc_init   ! called by opa
40
41    !! * Substitutions
42#  include "domzgr_substitute.h90"
43   !!----------------------------------------------------------------------
44   !! NEMO/TOP 4.0 , NEMO Consortium (2011)
45   !! $Id$
46   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
47   !!----------------------------------------------------------------------
48CONTAINS
49   
50   SUBROUTINE trc_init
51      !!---------------------------------------------------------------------
52      !!                     ***  ROUTINE trc_init  ***
53      !!
54      !! ** Purpose :   Initialization of the passive tracer fields
55      !!
56      !! ** Method  : - read namelist
57      !!              - control the consistancy
58      !!              - compute specific initialisations
59      !!              - set initial tracer fields (either read restart
60      !!                or read data or analytical formulation
61      !!---------------------------------------------------------------------
62      INTEGER ::   jk, jn, jl    ! dummy loop indices
63      CHARACTER (len=25) :: charout
64      !!---------------------------------------------------------------------
65      !
66      IF( nn_timing == 1 )   CALL timing_start('trc_init')
67      !
68      IF(lwp) WRITE(numout,*)
69      IF(lwp) WRITE(numout,*) 'trc_init : initial set up of the passive tracers'
70      IF(lwp) WRITE(numout,*) '~~~~~~~'
71
72      CALL top_alloc()              ! allocate TOP arrays
73
74      l_trcdm2dc = ln_dm2dc .OR. ( ln_cpl .AND. ncpl_qsr_freq /= 1 )
75      l_trcdm2dc = l_trcdm2dc  .AND. .NOT. lk_offline
76      IF( l_trcdm2dc .AND. lwp ) &
77         &   CALL ctl_warn(' Coupling with passive tracers and used of diurnal cycle. &
78         & Computation of a daily mean shortwave for some biogeochemical models) ')
79
80      IF( nn_cla == 1 )   &
81         &  CALL ctl_stop( ' Cross Land Advection not yet implemented with passive tracer ; nn_cla must be 0' )
82
83      CALL trc_nam      ! read passive tracers namelists
84      !
85      IF(lwp) WRITE(numout,*)
86      !
87      IF( ln_rsttr .AND. .NOT. lk_offline ) CALL trc_rst_cal( nit000, 'READ' )   ! calendar
88      !
89      IF(lwp) WRITE(numout,*)
90                                                              ! masked grid volume
91      !                                                              ! masked grid volume
92      DO jk = 1, jpk
93         cvol(:,:,jk) = e1e2t(:,:) * fse3t(:,:,jk) * tmask(:,:,jk)
94      END DO
95      IF( lk_degrad ) cvol(:,:,:) = cvol(:,:,:) * facvol(:,:,:)      ! degrad option: reduction by facvol
96      !                                                              ! total volume of the ocean
97      areatot = glob_sum( cvol(:,:,:) )
98
99      IF( lk_pisces  )       CALL trc_ini_pisces       ! PISCES  bio-model
100      IF( lk_cfc     )       CALL trc_ini_cfc          ! CFC       tracers
101      IF( lk_c14b    )       CALL trc_ini_c14b         ! C14 bomb  tracer
102      IF( lk_age     )       CALL trc_ini_age          ! AGE       tracer
103      IF( lk_my_trc  )       CALL trc_ini_my_trc       ! MY_TRC    tracers
104
105      CALL trc_ice_ini                                 ! Tracers in sea ice
106
107      IF( lwp ) THEN
108         !
109         CALL ctl_opn( numstr, 'tracer.stat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp , narea )
110         !
111      ENDIF
112
113      IF( ln_trcdta )      CALL trc_dta_init(jptra)
114
115
116      IF( ln_rsttr ) THEN
117        !
118        CALL trc_rst_read              ! restart from a file
119        !
120      ELSE
121        !
122        IF( ln_trcdta .AND. nb_trcdta > 0 ) THEN  ! Initialisation of tracer from a file that may also be used for damping
123            !
124            DO jn = 1, jptra
125               IF( ln_trc_ini(jn) ) THEN      ! update passive tracers arrays with input data read from file
126                  jl = n_trc_index(jn) 
127                  CALL trc_dta( nit000, sf_trcdta(jl) )   ! read tracer data at nit000
128                  trn(:,:,:,jn) = sf_trcdta(jl)%fnow(:,:,:) * tmask(:,:,:) * rf_trfac(jl)
129                  !
130                  IF( .NOT.ln_trcdmp .AND. .NOT.ln_trcdmp_clo ) THEN      !== deallocate data structure   ==!
131                     !                                                    (data used only for initialisation)
132                     IF(lwp) WRITE(numout,*) 'trc_dta: deallocate data arrays as they are only used to initialize the run'
133                                                  DEALLOCATE( sf_trcdta(jl)%fnow )     !  arrays in the structure
134                     IF( sf_trcdta(jl)%ln_tint )  DEALLOCATE( sf_trcdta(jl)%fdta )
135                     !
136                  ENDIF
137               ENDIF
138            ENDDO
139            !
140        ENDIF
141        !
142        trb(:,:,:,:) = trn(:,:,:,:)
143        !
144      ENDIF
145 
146      tra(:,:,:,:) = 0._wp
147      IF( ln_zps .AND. .NOT. lk_c1d .AND. .NOT. ln_isfcav )   &              ! Partial steps: before horizontal gradient of passive
148        &    CALL zps_hde    ( nit000, jptra, trn, gtru, gtrv  )  ! Partial steps: before horizontal gradient
149      IF( ln_zps .AND. .NOT. lk_c1d .AND.       ln_isfcav )   &
150        &    CALL zps_hde_isf( nit000, jptra, trn, pgtu=gtru, pgtv=gtrv, pgtui=gtrui, pgtvi=gtrvi )       ! tracers at the bottom ocean level
151
152
153      !
154      IF( nn_dttrc /= 1 )        CALL trc_sub_ini      ! Initialize variables for substepping passive tracers
155      !
156
157      trai(:) = 0._wp                                                   ! initial content of all tracers
158      DO jn = 1, jptra
159         trai(jn) = trai(jn) + glob_sum( trn(:,:,:,jn) * cvol(:,:,:)   )
160      END DO
161
162      IF(lwp) THEN               ! control print
163         WRITE(numout,*)
164         WRITE(numout,*)
165         WRITE(numout,*) '          *** Total number of passive tracer jptra = ', jptra
166         WRITE(numout,*) '          *** Total volume of ocean                = ', areatot
167         WRITE(numout,*) '          *** Total inital content of all tracers '
168         WRITE(numout,*)
169         DO jn = 1, jptra
170            WRITE(numout,9000) jn, TRIM( ctrcnm(jn) ), trai(jn)
171         ENDDO
172         WRITE(numout,*)
173      ENDIF
174      IF(lwp) WRITE(numout,*)
175      IF(ln_ctl) THEN            ! print mean trends (used for debugging)
176         CALL prt_ctl_trc_init
177         WRITE(charout, FMT="('ini ')")
178         CALL prt_ctl_trc_info( charout )
179         CALL prt_ctl_trc( tab4d=trn, mask=tmask, clinfo=ctrcnm )
180      ENDIF
1819000  FORMAT(' tracer nb : ',i2,'      name :',a10,'      initial content :',e18.10)
182      !
183      IF( nn_timing == 1 )   CALL timing_stop('trc_init')
184      !
185   END SUBROUTINE trc_init
186
187
188   SUBROUTINE top_alloc
189      !!----------------------------------------------------------------------
190      !!                     ***  ROUTINE top_alloc  ***
191      !!
192      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
193      !!----------------------------------------------------------------------
194      USE trcadv        , ONLY:   trc_adv_alloc          ! TOP-related alloc routines...
195      USE trc           , ONLY:   trc_alloc
196      USE trcnxt        , ONLY:   trc_nxt_alloc
197      USE trczdf        , ONLY:   trc_zdf_alloc
198      USE trdtrc_oce    , ONLY:   trd_trc_oce_alloc
199#if defined key_trdmxl_trc 
200      USE trdmxl_trc    , ONLY:   trd_mxl_trc_alloc
201#endif
202      !
203      INTEGER :: ierr
204      !!----------------------------------------------------------------------
205      !
206      ierr =        trc_adv_alloc()          ! Start of TOP-related alloc routines...
207      ierr = ierr + trc_alloc    ()
208      ierr = ierr + trc_nxt_alloc()
209      ierr = ierr + trc_zdf_alloc()
210      ierr = ierr + trd_trc_oce_alloc()
211#if defined key_trdmxl_trc 
212      ierr = ierr + trd_mxl_trc_alloc()
213#endif
214      !
215      IF( lk_mpp    )   CALL mpp_sum( ierr )
216      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'top_alloc : unable to allocate standard ocean arrays' )
217      !
218   END SUBROUTINE top_alloc
219
220#else
221   !!----------------------------------------------------------------------
222   !!  Empty module :                                     No passive tracer
223   !!----------------------------------------------------------------------
224CONTAINS
225   SUBROUTINE trc_init                      ! Dummy routine   
226   END SUBROUTINE trc_init
227#endif
228
229   !!======================================================================
230END MODULE trcini
Note: See TracBrowser for help on using the repository browser.