New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcssm.F90 in branches/dev_r2091_ZTC/NEMO/OPA_SRC/SBC – NEMO

source: branches/dev_r2091_ZTC/NEMO/OPA_SRC/SBC/sbcssm.F90 @ 2116

Last change on this file since 2116 was 2116, checked in by mlelod, 14 years ago

ticket: #720 restart the branch from the latest DEV_r1837_MLF branch revision (2112)
  • Property svn:keywords set to Id
File size: 9.2 KB
Line 
1MODULE sbcssm
2   !!======================================================================
3   !!                       ***  MODULE  sbcssm  ***
4   !! Surface module :  provide time-mean ocean surface variables
5   !!======================================================================
6   !! History :  9.0   !  06-07  (G. Madec)  Original code
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!   sbc_ssm        : calculate sea surface mean currents, temperature, 
11   !!                    and salinity over nn_fsbc time-step
12   !!----------------------------------------------------------------------
13   USE oce             ! ocean dynamics and tracers
14   USE dom_oce         ! ocean space and time domain
15   USE sbc_oce         ! Surface boundary condition: ocean fields
16   USE prtctl          ! Print control                    (prt_ctl routine)
17   USE restart         ! ocean restart
18   USE iom
19   USE in_out_manager  ! I/O manager
20
21   IMPLICIT NONE
22   PRIVATE
23
24   PUBLIC   sbc_ssm    ! routine called by step.F90
25   
26   !! * Substitutions
27#  include "domzgr_substitute.h90"
28   !!----------------------------------------------------------------------
29   !!   OPA 9.0 , LOCEAN-IPSL (2006)
30   !! $Id$
31   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
32   !!----------------------------------------------------------------------
33
34CONTAINS
35
36   SUBROUTINE sbc_ssm( kt )
37      !!---------------------------------------------------------------------
38      !!                     ***  ROUTINE sbc_oce  ***
39      !!                     
40      !! ** Purpose :   provide ocean surface variable to sea-surface boundary
41      !!                condition computation
42      !!               
43      !! ** Method  :   compute mean surface velocity (2 components at U and
44      !!      V-points) [m/s], temperature [Celcius] and salinity [psu] over
45      !!      the periode (kt - nn_fsbc) to kt
46      !!---------------------------------------------------------------------
47      INTEGER, INTENT(in) ::   kt        ! ocean time step
48      !
49      REAL(wp) ::   zcoef       ! temporary scalar
50      REAL(wp) ::   zf_sbc      ! read sbc frequency
51      !!---------------------------------------------------------------------
52      !                                                   ! ---------------------------------------- !
53      IF( nn_fsbc == 1 ) THEN                             !      Instantaneous surface fields        !
54         !                                                ! ---------------------------------------- !
55         IF( kt == nit000 ) THEN
56            IF(lwp) WRITE(numout,*)
57            IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields, nn_fsbc=1 : instantaneous values'
58            IF(lwp) WRITE(numout,*) '~~~~~~~ '
59         ENDIF
60         !
61         ssu_m(:,:) = ub(:,:,1)
62         ssv_m(:,:) = vb(:,:,1)
63         sst_m(:,:) = tn(:,:,1)
64         sss_m(:,:) = sn(:,:,1)
65         ssh_m(:,:) = sshn(:,:)
66         IF( lk_vvl ) fse3t_m(:,:) = fse3t_n(:,:,1)
67         !
68      ELSE
69         !                                                ! ---------------------------------------- !
70         IF( kt == nit000) THEN                           !       Initialisation: 1st time-step      !
71            !                                             ! ---------------------------------------- !
72            IF(lwp) WRITE(numout,*)
73            IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields'
74            !
75            IF( ln_rstart .AND. iom_varid( numror, 'nn_fsbc', ldstop = .FALSE. ) > 0 ) THEN
76               CALL iom_get( numror               , 'nn_fsbc', zf_sbc )   ! sbc frequency of previous run
77               CALL iom_get( numror, jpdom_autoglo, 'ssu_m'  , ssu_m  )   ! sea surface mean velocity    (T-point)
78               CALL iom_get( numror, jpdom_autoglo, 'ssv_m'  , ssv_m  )   !   "         "    velocity    (V-point)
79               CALL iom_get( numror, jpdom_autoglo, 'sst_m'  , sst_m  )   !   "         "    temperature (T-point)
80               CALL iom_get( numror, jpdom_autoglo, 'sss_m'  , sss_m  )   !   "         "    salinity    (T-point)
81               CALL iom_get( numror, jpdom_autoglo, 'ssh_m'  , ssh_m  )   !   "         "    height      (T-point)
82               IF( lk_vvl ) THEN
83                  CALL iom_get( numror, jpdom_autoglo, 'e3t_m'  , fse3t_m  )   !   first ocean level thickness (T-point)
84               ENDIF
85               !
86               IF( zf_sbc /= REAL( nn_fsbc, wp ) ) THEN      ! nn_fsbc has changed between 2 runs
87                  IF(lwp) WRITE(numout,*) '~~~~~~~   restart with a change in the frequency of mean ',   &
88                     &                    'from ', zf_sbc, ' to ', nn_fsbc
89                  zcoef = REAL( nn_fsbc - 1, wp ) / zf_sbc
90                  ssu_m(:,:) = zcoef * ssu_m(:,:)
91                  ssv_m(:,:) = zcoef * ssv_m(:,:)
92                  sst_m(:,:) = zcoef * sst_m(:,:)
93                  sss_m(:,:) = zcoef * sss_m(:,:)
94                  ssh_m(:,:) = zcoef * ssh_m(:,:)
95                  IF( lk_vvl ) fse3t_m(:,:) = zcoef * fse3t_m(:,:)
96               ELSE
97                  IF(lwp) WRITE(numout,*) '~~~~~~~   mean fields read in the ocean restart file'
98               ENDIF
99            ELSE
100               IF(lwp) WRITE(numout,*) '~~~~~~~   mean fields initialised to instantaneous values'
101               zcoef = REAL( nn_fsbc - 1, wp )
102               ssu_m(:,:) = zcoef * ub(:,:,1)
103               ssv_m(:,:) = zcoef * vb(:,:,1)
104               sst_m(:,:) = zcoef * tn(:,:,1)
105               sss_m(:,:) = zcoef * sn(:,:,1)
106               ssh_m(:,:) = zcoef * sshn(:,:)
107               IF( lk_vvl ) fse3t_m(:,:) = zcoef * fse3t_n(:,:,1)
108            ENDIF
109            !                                             ! ---------------------------------------- !
110         ELSEIF( MOD( kt - 2 , nn_fsbc ) == 0 ) THEN      !   Initialisation: New mean computation   !
111            !                                             ! ---------------------------------------- !
112            ssu_m(:,:) = 0.e0      ! reset to zero ocean mean sbc fields
113            ssv_m(:,:) = 0.e0
114            sst_m(:,:) = 0.e0
115            sss_m(:,:) = 0.e0
116            ssh_m(:,:) = 0.e0
117            IF( lk_vvl ) fse3t_m(:,:) = 0.e0
118         ENDIF
119         !                                                ! ---------------------------------------- !
120         !                                                !        Cumulate at each time step        !
121         !                                                ! ---------------------------------------- !
122         ssu_m(:,:) = ssu_m(:,:) + ub(:,:,1)
123         ssv_m(:,:) = ssv_m(:,:) + vb(:,:,1)
124         sst_m(:,:) = sst_m(:,:) + tn(:,:,1)
125         sss_m(:,:) = sss_m(:,:) + sn(:,:,1)
126         ssh_m(:,:) = ssh_m(:,:) + sshn(:,:)
127         IF( lk_vvl ) fse3t_m(:,:) = fse3t_m(:,:) + fse3t_n(:,:,1)
128         !                                                ! ---------------------------------------- !
129         IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
130            !                                             ! ---------------------------------------- !
131            ! - ML - In a pure rigourous implementation, the averaging of sst and sss should be weighted
132            !        by the level thickness in vvl case. We suppose here that the effect is negligible.
133            zcoef = 1. / REAL( nn_fsbc, wp )
134            sst_m(:,:) = sst_m(:,:) * zcoef           ! mean SST             [Celcius]
135            sss_m(:,:) = sss_m(:,:) * zcoef           ! mean SSS             [psu]
136            ssu_m(:,:) = ssu_m(:,:) * zcoef           ! mean suface current  [m/s]
137            ssv_m(:,:) = ssv_m(:,:) * zcoef           !
138            ssh_m(:,:) = ssh_m(:,:) * zcoef           ! mean SSH             [m]
139            IF( lk_vvl ) fse3t_m(:,:) = fse3t_m(:,:) * zcoef  !   first ocean level thickness [m]
140            !
141         ENDIF
142         !                                                ! ---------------------------------------- !
143         IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
144            !                                             ! ---------------------------------------- !
145            IF(lwp) WRITE(numout,*)
146            IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields written in ocean restart file ',   &
147               &                    'at it= ', kt,' date= ', ndastp
148            IF(lwp) WRITE(numout,*) '~~~~~~~'
149            zf_sbc = REAL( nn_fsbc, wp )
150            CALL iom_rstput( kt, nitrst, numrow, 'nn_fsbc', zf_sbc )    ! sbc frequency
151            CALL iom_rstput( kt, nitrst, numrow, 'ssu_m'  , ssu_m  )    ! sea surface mean fields
152            CALL iom_rstput( kt, nitrst, numrow, 'ssv_m'  , ssv_m  )
153            CALL iom_rstput( kt, nitrst, numrow, 'sst_m'  , sst_m  )
154            CALL iom_rstput( kt, nitrst, numrow, 'sss_m'  , sss_m  )
155            CALL iom_rstput( kt, nitrst, numrow, 'ssh_m'  , ssh_m  )
156            IF( lk_vvl ) THEN
157               CALL iom_rstput( kt, nitrst, numrow, 'e3t_m'  , fse3t_m  )
158            ENDIF
159            !
160         ENDIF
161         !
162      ENDIF
163      !
164   END SUBROUTINE sbc_ssm
165
166   !!======================================================================
167END MODULE sbcssm
Note: See TracBrowser for help on using the repository browser.